Subversion Repositories Kolibri OS

Rev

Rev 1314 | Rev 1319 | Go to most recent revision | Blame | Compare with Previous | Last modification | View Log | Download | RSS feed

  1. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  2. ;;
  3. ;; Copyright (C) KolibriOS team 2004-2009. All rights reserved.
  4. ;; PROGRAMMING:
  5. ;; Ivan Poddubny
  6. ;; Marat Zakiyanov (Mario79)
  7. ;; VaStaNi
  8. ;; Trans
  9. ;; Mihail Semenyako (mike.dld)
  10. ;; Sergey Kuzmin (Wildwest)
  11. ;; Andrey Halyavin (halyavin)
  12. ;; Mihail Lisovin (Mihasik)
  13. ;; Andrey Ignatiev (andrew_programmer)
  14. ;; NoName
  15. ;; Evgeny Grechnikov (Diamond)
  16. ;; Iliya Mihailov (Ghost)
  17. ;; Sergey Semyonov (Serge)
  18. ;; Johnny_B
  19. ;; SPraid (simba)
  20. ;; Hidnplayr
  21. ;; Alexey Teplov (<Lrz>)
  22. ;;
  23. ;; Data in this file was originally part of MenuetOS project which is
  24. ;; distributed under the terms of GNU GPL. It is modified and redistributed as
  25. ;; part of KolibriOS project under the terms of GNU GPL.
  26. ;;
  27. ;; Copyright (C) MenuetOS 2000-2004 Ville Mikael Turjanmaa
  28. ;; PROGRAMMING:
  29. ;;
  30. ;; Ville Mikael Turjanmaa, villemt@itu.jyu.fi
  31. ;; - main os coding/design
  32. ;; Jan-Michael Brummer, BUZZ2@gmx.de
  33. ;; Felix Kaiser, info@felix-kaiser.de
  34. ;; Paolo Minazzi, paolo.minazzi@inwind.it
  35. ;; quickcode@mail.ru
  36. ;; Alexey, kgaz@crosswinds.net
  37. ;; Juan M. Caravaca, bitrider@wanadoo.es
  38. ;; kristol@nic.fi
  39. ;; Mike Hibbett, mikeh@oceanfree.net
  40. ;; Lasse Kuusijarvi, kuusijar@lut.fi
  41. ;; Jarek Pelczar, jarekp3@wp.pl
  42. ;;
  43. ;; KolibriOS is distributed in the hope that it will be useful, but WITHOUT ANY
  44. ;; WARRANTY. No author or distributor accepts responsibility to anyone for the
  45. ;; consequences of using it or for whether it serves any particular purpose or
  46. ;; works at all, unless he says so in writing. Refer to the GNU General Public
  47. ;; License (the "GPL") for full details.
  48. ;
  49. ;; Everyone is granted permission to copy, modify and redistribute KolibriOS,
  50. ;; but only under the conditions described in the GPL. A copy of this license
  51. ;; is supposed to have been given to you along with KolibriOS so you can know
  52. ;; your rights and responsibilities. It should be in a file named COPYING.
  53. ;; Among other things, the copyright notice and this notice must be preserved
  54. ;; on all copies.
  55. ;;
  56. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  57.  
  58. include 'macros.inc'
  59.  
  60. $Revision: 1316 $
  61.  
  62.  
  63. USE_COM_IRQ     equ 1      ; make irq 3 and irq 4 available for PCI devices
  64.  
  65. ; Enabling the next line will enable serial output console
  66. ;debug_com_base  equ 0x3f8  ; 0x3f8 is com1, 0x2f8 is com2, 0x3e8 is com3, 0x2e8 is com4, no irq's are used
  67.  
  68. include "proc32.inc"
  69. include "kglobals.inc"
  70. include "lang.inc"
  71.  
  72. include "const.inc"
  73. max_processes   equ   255
  74. tss_step         equ   (128+8192) ; tss & i/o - 65535 ports, * 256=557056*4
  75.  
  76.  
  77. os_stack       equ  (os_data_l-gdts)    ; GDTs
  78. os_code       equ  (os_code_l-gdts)
  79. graph_data     equ  (3+graph_data_l-gdts)
  80. tss0           equ  (tss0_l-gdts)
  81. app_code       equ  (3+app_code_l-gdts)
  82. app_data       equ  (3+app_data_l-gdts)
  83. app_tls       equ  (3+tls_data_l-gdts)
  84. pci_code_sel   equ  (pci_code_32-gdts)
  85. pci_data_sel   equ  (pci_data_32-gdts)
  86.  
  87.  
  88. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  89. ;;
  90. ;;   Included files:
  91. ;;
  92. ;;   Kernel16.inc
  93. ;;    - Booteng.inc   English text for bootup
  94. ;;    - Bootcode.inc  Hardware setup
  95. ;;    - Pci16.inc     PCI functions
  96. ;;
  97. ;;   Kernel32.inc
  98. ;;    - Sys32.inc     Process management
  99. ;;    - Shutdown.inc  Shutdown and restart
  100. ;;    - Fat32.inc     Read / write hd
  101. ;;    - Vesa12.inc    Vesa 1.2 driver
  102. ;;    - Vesa20.inc    Vesa 2.0 driver
  103. ;;    - Vga.inc       VGA driver
  104. ;;    - Stack.inc     Network interface
  105. ;;    - Mouse.inc     Mouse pointer
  106. ;;    - Scincode.inc  Window skinning
  107. ;;    - Pci32.inc     PCI functions
  108. ;;
  109. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  110.  
  111.  
  112. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  113. ;;                                                                      ;;
  114. ;;                  16 BIT ENTRY FROM BOOTSECTOR                        ;;
  115. ;;                                                                      ;;
  116. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  117.  
  118. use16
  119.                   org   0x0
  120.                   jmp   start_of_code
  121.  
  122. version db    'Kolibri OS  version 0.7.5.0      ',13,10,13,10,0
  123.  
  124. include "boot/bootstr.inc"     ; language-independent boot messages
  125. include "boot/preboot.inc"
  126.  
  127. if lang eq en
  128. include "boot/booteng.inc"     ; english system boot messages
  129. else if lang eq ru
  130. include "boot/bootru.inc"      ; russian system boot messages
  131. include "boot/ru.inc"          ; Russian font
  132. else if lang eq et
  133. include "boot/bootet.inc"      ; estonian system boot messages
  134. include "boot/et.inc"          ; Estonian font
  135. else
  136. include "boot/bootge.inc"      ; german system boot messages
  137. end if
  138.  
  139. include "boot/bootcode.inc"    ; 16 bit system boot code
  140. include "bus/pci/pci16.inc"
  141. include "detect/biosdisk.inc"
  142.  
  143. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  144. ;;                                                                      ;;
  145. ;;                  SWITCH TO 32 BIT PROTECTED MODE                     ;;
  146. ;;                                                                      ;;
  147. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  148.  
  149.  
  150. ; CR0 Flags - Protected mode and Paging
  151.  
  152.         mov ecx, CR0_PE
  153.  
  154. ; Enabling 32 bit protected mode
  155.  
  156.         sidt    [cs:old_ints_h]
  157.  
  158.         cli                             ; disable all irqs
  159.         cld
  160.         mov     al,255                  ; mask all irqs
  161.         out     0xa1,al
  162.         out     0x21,al
  163.    l.5: in      al, 0x64                ; Enable A20
  164.         test    al, 2
  165.         jnz     l.5
  166.         mov     al, 0xD1
  167.         out     0x64, al
  168.    l.6: in      al, 0x64
  169.         test    al, 2
  170.         jnz     l.6
  171.         mov     al, 0xDF
  172.         out     0x60, al
  173.    l.7: in      al, 0x64
  174.         test    al, 2
  175.         jnz     l.7
  176.         mov     al, 0xFF
  177.         out     0x64, al
  178.  
  179.         lgdt    [cs:tmp_gdt]            ; Load GDT
  180.         mov     eax, cr0                ; protected mode
  181.         or      eax, ecx
  182.         and     eax, 10011111b *65536*256 + 0xffffff ; caching enabled
  183.         mov     cr0, eax
  184.         jmp     pword os_code:B32       ; jmp to enable 32 bit mode
  185.  
  186. align 8
  187. tmp_gdt:
  188.  
  189.         dw     23
  190.         dd     tmp_gdt+0x10000
  191.         dw     0
  192.  
  193.         dw     0xffff
  194.         dw     0x0000
  195.         db     0x00
  196.         dw     11011111b *256 +10011010b
  197.         db     0x00
  198.  
  199.         dw     0xffff
  200.         dw     0x0000
  201.         db     0x00
  202.         dw     11011111b *256 +10010010b
  203.         db     0x00
  204.  
  205. include "data16.inc"
  206.  
  207. use32
  208. org $+0x10000
  209.  
  210. align 4
  211. B32:
  212.            mov   ax,os_stack       ; Selector for os
  213.            mov   ds,ax
  214.            mov   es,ax
  215.            mov   fs,ax
  216.            mov   gs,ax
  217.            mov   ss,ax
  218.            mov   esp,0x3ec00       ; Set stack
  219.  
  220. ; CLEAR 0x280000 - HEAP_BASE
  221.  
  222.            xor   eax,eax
  223.            mov   edi,0x280000
  224.            mov   ecx,(HEAP_BASE-OS_BASE-0x280000) / 4
  225.            cld
  226.            rep   stosd
  227.  
  228.            mov   edi,0x40000
  229.            mov   ecx,(0x90000-0x40000)/4
  230.            rep   stosd
  231.  
  232. ; CLEAR KERNEL UNDEFINED GLOBALS
  233.            mov   edi, endofcode-OS_BASE
  234.            mov   ecx, (uglobals_size/4)+4
  235.            rep   stosd
  236.  
  237. ; SAVE & CLEAR 0-0xffff
  238.  
  239.            xor   esi, esi
  240.            mov   edi,0x2F0000
  241.            mov   ecx,0x10000 / 4
  242.            rep   movsd
  243.            mov   edi,0x1000
  244.            mov   ecx,0xf000 / 4
  245.            rep   stosd
  246.  
  247.            call test_cpu
  248.            bts [cpu_caps-OS_BASE], CAPS_TSC     ;force use rdtsc
  249.  
  250.            call init_BIOS32
  251. ; MEMORY MODEL
  252.            call mem_test
  253.            call init_mem
  254.            call init_page_map
  255.  
  256. ; ENABLE PAGING
  257.  
  258.            mov eax, sys_pgdir-OS_BASE
  259.            mov cr3, eax
  260.  
  261.            mov eax,cr0
  262.            or eax,CR0_PG+CR0_WP
  263.            mov cr0,eax
  264.  
  265.            lgdt [gdts]
  266.            jmp pword os_code:high_code
  267.  
  268. align 4
  269. bios32_entry    dd ?
  270. tmp_page_tabs   dd ?
  271.  
  272. use16
  273. org $-0x10000
  274. include "boot/shutdown.inc" ; shutdown or restart
  275. org $+0x10000
  276. use32
  277.  
  278. __DEBUG__ fix 1
  279. __DEBUG_LEVEL__ fix 1
  280. include 'init.inc'
  281.  
  282. org OS_BASE+$
  283.  
  284. align 4
  285. high_code:
  286.            mov ax, os_stack
  287.            mov bx, app_data
  288.            mov cx, app_tls
  289.            mov ss, ax
  290.            add esp, OS_BASE
  291.  
  292.            mov ds, bx
  293.            mov es, bx
  294.            mov fs, cx
  295.            mov gs, bx
  296.  
  297.            bt [cpu_caps], CAPS_PGE
  298.            jnc @F
  299.  
  300.            or dword [sys_pgdir+(OS_BASE shr 20)], PG_GLOBAL
  301.  
  302.            mov ebx, cr4
  303.            or ebx, CR4_PGE
  304.            mov cr4, ebx
  305. @@:
  306.            xor eax, eax
  307.            mov dword [sys_pgdir], eax
  308.            mov dword [sys_pgdir+4], eax
  309.  
  310.            mov eax, cr3
  311.            mov cr3, eax           ; flush TLB
  312.  
  313. ; SAVE REAL MODE VARIABLES
  314.         mov     ax, [BOOT_VAR + 0x9031]
  315.         mov     [IDEContrRegsBaseAddr], ax
  316. ; --------------- APM ---------------------
  317.  
  318. ; init selectors
  319.     mov ebx,[BOOT_VAR+0x9040]                   ; offset of APM entry point
  320.     movzx eax,word [BOOT_VAR+0x9050]    ; real-mode segment base address of
  321.                                                                                 ; protected-mode 32-bit code segment
  322.     movzx ecx,word [BOOT_VAR+0x9052]    ; real-mode segment base address of
  323.                                                                                 ; protected-mode 16-bit code segment
  324.     movzx edx,word [BOOT_VAR+0x9054]    ; real-mode segment base address of
  325.                                                                                 ; protected-mode 16-bit data segment
  326.  
  327.     shl    eax, 4
  328.     mov    [dword apm_code_32 + 2], ax
  329.     shr    eax, 16
  330.     mov    [dword apm_code_32 + 4], al
  331.  
  332.     shl    ecx, 4
  333.     mov    [dword apm_code_16 + 2], cx
  334.     shr    ecx, 16
  335.     mov    [dword apm_code_16 + 4], cl
  336.  
  337.     shl    edx, 4
  338.     mov    [dword apm_data_16 + 2], dx
  339.     shr    edx, 16
  340.     mov    [dword apm_data_16 + 4], dl
  341.  
  342.     mov    dword[apm_entry], ebx
  343.     mov    word [apm_entry + 4], apm_code_32 - gdts
  344.  
  345.     mov    eax, [BOOT_VAR + 0x9044]    ; version & flags
  346.     mov    [apm_vf], eax
  347. ; -----------------------------------------
  348. ;        movzx eax,byte [BOOT_VAR+0x9010]       ; mouse port
  349. ;        mov   [0xF604],byte 1  ;al
  350.                 mov     al, [BOOT_VAR+0x901F]           ; DMA access
  351.         mov     [allow_dma_access], al
  352.         movzx eax, byte [BOOT_VAR+0x9000]        ; bpp
  353.         mov [ScreenBPP],al
  354.  
  355.         mov [_display.bpp], eax
  356.         mov [_display.vrefresh], 60
  357.         mov [_display.disable_mouse],  __sys_disable_mouse
  358.  
  359.         movzx eax,word [BOOT_VAR+0x900A]  ; X max
  360.         mov [_display.width], eax
  361.         dec   eax
  362.         mov   [Screen_Max_X],eax
  363.         mov   [screen_workarea.right],eax
  364.         movzx eax,word [BOOT_VAR+0x900C]  ; Y max
  365.         mov [_display.height], eax
  366.         dec   eax
  367.         mov   [Screen_Max_Y],eax
  368.         mov   [screen_workarea.bottom],eax
  369.         movzx eax,word [BOOT_VAR+0x9008]  ; screen mode
  370.         mov   [SCR_MODE],eax
  371.         mov   eax,[BOOT_VAR+0x9014]       ; Vesa 1.2 bnk sw add
  372.         mov   [BANK_SWITCH],eax
  373.         mov   [BytesPerScanLine],word 640*4         ; Bytes PerScanLine
  374.         cmp   [SCR_MODE],word 0x13          ; 320x200
  375.         je    @f
  376.         cmp   [SCR_MODE],word 0x12          ; VGA 640x480
  377.         je    @f
  378.         movzx eax, word[BOOT_VAR+0x9001]        ; for other modes
  379.         mov   [BytesPerScanLine],ax
  380.         mov [_display.pitch], eax
  381. @@:
  382.         mov eax, [_display.width]
  383.         mul [_display.height]
  384.         mov [_WinMapSize], eax
  385.  
  386.         mov     esi, BOOT_VAR+0x9080
  387.         movzx   ecx, byte [esi-1]
  388.         mov     [NumBiosDisks], ecx
  389.         mov     edi, BiosDisksData
  390.         rep     movsd
  391.  
  392. ; GRAPHICS ADDRESSES
  393.  
  394.         and     byte [BOOT_VAR+0x901e],0x0
  395.         mov     eax,[BOOT_VAR+0x9018]
  396.         mov     [LFBAddress],eax
  397.  
  398.         cmp     [SCR_MODE],word 0100000000000000b
  399.         jge     setvesa20
  400.         cmp     [SCR_MODE],word 0x13
  401.         je      v20ga32
  402.         mov     [PUTPIXEL],dword Vesa12_putpixel24  ; Vesa 1.2
  403.         mov     [GETPIXEL],dword Vesa12_getpixel24
  404.         cmp     [ScreenBPP],byte 24
  405.         jz      ga24
  406.         mov     [PUTPIXEL],dword Vesa12_putpixel32
  407.         mov     [GETPIXEL],dword Vesa12_getpixel32
  408.       ga24:
  409.         jmp     v20ga24
  410.       setvesa20:
  411.         mov     [PUTPIXEL],dword Vesa20_putpixel24  ; Vesa 2.0
  412.         mov     [GETPIXEL],dword Vesa20_getpixel24
  413.         cmp     [ScreenBPP],byte 24
  414.         jz      v20ga24
  415.       v20ga32:
  416.         mov     [PUTPIXEL],dword Vesa20_putpixel32
  417.         mov     [GETPIXEL],dword Vesa20_getpixel32
  418.       v20ga24:
  419.         cmp     [SCR_MODE],word 0x12                ; 16 C VGA 640x480
  420.         jne     no_mode_0x12
  421.         mov     [PUTPIXEL],dword VGA_putpixel
  422.         mov     [GETPIXEL],dword Vesa20_getpixel32
  423.       no_mode_0x12:
  424.  
  425. ; -------- Fast System Call init ----------
  426. ; Intel SYSENTER/SYSEXIT (AMD CPU support it too)
  427.            bt [cpu_caps], CAPS_SEP
  428.            jnc .SEnP   ; SysEnter not Present
  429.            xor edx, edx
  430.            mov ecx, MSR_SYSENTER_CS
  431.            mov eax, os_code
  432.            wrmsr
  433.            mov ecx, MSR_SYSENTER_ESP
  434. ;           mov eax, sysenter_stack ; Check it
  435.            xor     eax, eax
  436.            wrmsr
  437.            mov ecx, MSR_SYSENTER_EIP
  438.            mov eax, sysenter_entry
  439.            wrmsr
  440. .SEnP:
  441. ; AMD SYSCALL/SYSRET
  442.            cmp byte[cpu_vendor], 'A'
  443.            jne .noSYSCALL
  444.            mov eax, 0x80000001
  445.            cpuid
  446.            test edx, 0x800  ; bit_11 - SYSCALL/SYSRET support
  447.            jz .noSYSCALL
  448.            mov ecx, MSR_AMD_EFER
  449.            rdmsr
  450.            or eax, 1   ; bit_0 - System Call Extension (SCE)
  451.            wrmsr
  452.  
  453.         ; !!!! It`s dirty hack, fix it !!!
  454.         ; Bits of EDX :
  455.         ; Bit 31Ц16 During the SYSRET instruction, this field is copied into the CS register
  456.         ;  and the contents of this field, plus 8, are copied into the SS register.
  457.         ; Bit 15Ц0 During the SYSCALL instruction, this field is copied into the CS register
  458.         ;  and the contents of this field, plus 8, are copied into the SS register.
  459.  
  460.         ; mov   edx, (os_code + 16) * 65536 + os_code
  461.            mov edx, 0x1B0008
  462.  
  463.            mov eax, syscall_entry
  464.            mov ecx, MSR_AMD_STAR
  465.            wrmsr
  466. .noSYSCALL:
  467. ; -----------------------------------------
  468.         stdcall alloc_page
  469.         stdcall map_page, tss-0xF80, eax, PG_SW
  470.         stdcall alloc_page
  471.         inc     eax
  472.         mov     [SLOT_BASE+256+APPDATA.io_map], eax
  473.         stdcall map_page, tss+0x80, eax, PG_SW
  474.         stdcall alloc_page
  475.         inc     eax
  476.         mov     dword [SLOT_BASE+256+APPDATA.io_map+4], eax
  477.         stdcall map_page, tss+0x1080, eax, PG_SW
  478.  
  479. ; LOAD IDT
  480.  
  481.            call build_interrupt_table ;lidt is executed
  482.           ;lidt [idtreg]
  483.  
  484.            call init_kernel_heap
  485.            stdcall kernel_alloc, RING0_STACK_SIZE+512
  486.            mov [os_stack_seg], eax
  487.  
  488.            lea esp, [eax+RING0_STACK_SIZE]
  489.  
  490.            mov [tss._ss0], os_stack
  491.            mov [tss._esp0], esp
  492.            mov [tss._esp], esp
  493.            mov [tss._cs],os_code
  494.            mov [tss._ss],os_stack
  495.            mov [tss._ds],app_data
  496.            mov [tss._es],app_data
  497.            mov [tss._fs],app_data
  498.            mov [tss._gs],app_data
  499.            mov [tss._io],128
  500. ;Add IO access table - bit array of permitted ports
  501.            mov edi, tss._io_map_0
  502.            xor eax, eax
  503.            not eax
  504.            mov ecx, 8192/4
  505.            rep stosd                 ; access to 4096*8=65536 ports
  506.  
  507.            mov  ax,tss0
  508.            ltr  ax
  509.  
  510.            mov [LFBSize], 0x800000
  511.            call init_LFB
  512.            call init_fpu
  513.            call init_malloc
  514.  
  515.            stdcall alloc_kernel_space, 0x51000
  516.            mov [default_io_map], eax
  517.  
  518.            add eax, 0x2000
  519.            mov [ipc_tmp], eax
  520.            mov ebx, 0x1000
  521.  
  522.            add eax, 0x40000
  523.            mov [proc_mem_map], eax
  524.  
  525.            add eax, 0x8000
  526.            mov [proc_mem_pdir], eax
  527.  
  528.            add eax, ebx
  529.            mov [proc_mem_tab], eax
  530.  
  531.            add eax, ebx
  532.            mov [tmp_task_pdir], eax
  533.  
  534.            add eax, ebx
  535.            mov [tmp_task_ptab], eax
  536.  
  537.            add eax, ebx
  538.            mov [ipc_pdir], eax
  539.  
  540.            add eax, ebx
  541.            mov [ipc_ptab], eax
  542.  
  543.            stdcall kernel_alloc, (unpack.LZMA_BASE_SIZE+(unpack.LZMA_LIT_SIZE shl \
  544.                                  (unpack.lc+unpack.lp)))*4
  545.  
  546.            mov [unpack.p], eax
  547.  
  548.            call init_events
  549.            mov eax, srv.fd-SRV_FD_OFFSET
  550.            mov [srv.fd], eax
  551.            mov [srv.bk], eax
  552.  
  553.            mov edi, irq_tab
  554.            xor eax, eax
  555.            mov ecx, 16
  556.            rep stosd
  557.  
  558. ;Set base of graphic segment to linear address of LFB
  559.         mov     eax,[LFBAddress]          ; set for gs
  560.         mov     [graph_data_l+2],ax
  561.         shr     eax,16
  562.         mov     [graph_data_l+4],al
  563.         mov     [graph_data_l+7],ah
  564.  
  565.         stdcall kernel_alloc, [_WinMapSize]
  566.         mov [_WinMapAddress], eax
  567.  
  568.         xor  eax,eax
  569.         inc  eax
  570.         mov [CURRENT_TASK],eax          ;dword 1
  571.         mov [TASK_COUNT],eax            ;dword 1
  572.         mov [TASK_BASE],dword TASK_DATA
  573.         mov [current_slot], SLOT_BASE+256
  574.  
  575. ; set background
  576.  
  577.         mov   [BgrDrawMode],eax
  578.         mov   [BgrDataWidth],eax
  579.         mov   [BgrDataHeight],eax
  580.         mov    [mem_BACKGROUND], 4
  581.         mov [img_background], static_background_data
  582.  
  583.         mov     [SLOT_BASE + 256 + APPDATA.dir_table], sys_pgdir - OS_BASE
  584.  
  585.         stdcall kernel_alloc, 0x10000/8
  586.         mov     edi, eax
  587.         mov     [network_free_ports], eax
  588.         or      eax, -1
  589.         mov     ecx, 0x10000/32
  590.         rep     stosd
  591.  
  592. ; REDIRECT ALL IRQ'S TO INT'S 0x20-0x2f
  593.  
  594.         call  rerouteirqs
  595.  
  596. ; Initialize system V86 machine
  597.         call    init_sys_v86
  598.  
  599. ; TIMER SET TO 1/100 S
  600.  
  601.         mov   al,0x34              ; set to 100Hz
  602.         out   0x43,al
  603.         mov   al,0x9b              ; lsb    1193180 / 1193
  604.         out   0x40,al
  605.         mov   al,0x2e              ; msb
  606.         out   0x40,al
  607.  
  608. ; Enable timer IRQ (IRQ0) and hard drives IRQs (IRQ14, IRQ15)
  609. ; they are used: when partitions are scanned, hd_read relies on timer
  610. ; Also enable IRQ2, because in some configurations
  611. ; IRQs from slave controller are not delivered until IRQ2 on master is enabled
  612.         mov     al, 0xFA
  613.         out     0x21, al
  614.         mov     al, 0x3F
  615.         out     0xA1, al
  616.  
  617. ;!!!!!!!!!!!!!!!!!!!!!!!!!!
  618. include 'detect/disks.inc'
  619. ;!!!!!!!!!!!!!!!!!!!!!!!!!!
  620.  
  621.   call Parser_params
  622.  
  623. ; READ RAMDISK IMAGE FROM HD
  624.  
  625. ;!!!!!!!!!!!!!!!!!!!!!!!
  626. include 'boot/rdload.inc'
  627. ;!!!!!!!!!!!!!!!!!!!!!!!
  628. ;    mov    [dma_hdd],1
  629. ; CALCULATE FAT CHAIN FOR RAMDISK
  630.  
  631.         call  calculatefatchain
  632.  
  633. ; LOAD VMODE DRIVER
  634.  
  635. ;!!!!!!!!!!!!!!!!!!!!!!!
  636. include 'vmodeld.inc'
  637. ;!!!!!!!!!!!!!!!!!!!!!!!
  638.  
  639. if 0
  640.   mov ax,[OS_BASE+0x10000+bx_from_load]
  641.   cmp ax,'r1'           ; if using not ram disk, then load librares and parameters {SPraid.simba}
  642.   je  no_lib_load
  643. ; LOADING LIBRARES
  644.    stdcall dll.Load,@IMPORT                 ; loading librares for kernel (.obj files)
  645.    call load_file_parse_table               ; prepare file parse table
  646.    call set_kernel_conf                     ; configure devices and gui
  647. no_lib_load:
  648. end if
  649.  
  650. ; LOAD FONTS I and II
  651.  
  652.         stdcall read_file, char, FONT_I, 0, 2304
  653.         stdcall read_file, char2, FONT_II, 0, 2560
  654.  
  655.         mov   esi,boot_fonts
  656.         call  boot_log
  657.  
  658. ; PRINT AMOUNT OF MEMORY
  659.         mov     esi, boot_memdetect
  660.         call    boot_log
  661.  
  662.         movzx   ecx, word [boot_y]
  663.         or      ecx, (10+29*6) shl 16 ; "Determining amount of memory"
  664.         sub     ecx, 10
  665.         mov     edx, 0xFFFFFF
  666.         mov     ebx, [MEM_AMOUNT]
  667.         shr     ebx, 20
  668.         xor     edi,edi
  669.         mov     eax, 0x00040000
  670.                 inc             edi
  671.         call    display_number_force
  672.  
  673. ; BUILD SCHEDULER
  674.  
  675.         call   build_scheduler ; sys32.inc
  676.  
  677.         mov    esi,boot_devices
  678.         call   boot_log
  679.  
  680.         mov  [pci_access_enabled],1
  681.  
  682.  
  683. ; SET PRELIMINARY WINDOW STACK AND POSITIONS
  684.  
  685.         mov   esi,boot_windefs
  686.         call  boot_log
  687.         call  setwindowdefaults
  688.  
  689. ; SET BACKGROUND DEFAULTS
  690.  
  691.         mov   esi,boot_bgr
  692.         call  boot_log
  693.         call  init_background
  694.         call  calculatebackground
  695.  
  696. ; RESERVE SYSTEM IRQ'S JA PORT'S
  697.  
  698.         mov   esi,boot_resirqports
  699.         call  boot_log
  700.         call  reserve_irqs_ports
  701.  
  702. ; SET PORTS FOR IRQ HANDLERS
  703.  
  704.         mov  esi,boot_setrports
  705.         call boot_log
  706.         ;call setirqreadports
  707.  
  708. ; SET UP OS TASK
  709.  
  710.         mov  esi,boot_setostask
  711.         call boot_log
  712.  
  713.         xor  eax, eax
  714.         mov  dword [SLOT_BASE+APPDATA.fpu_state], fpu_data
  715.         mov  dword [SLOT_BASE+APPDATA.exc_handler], eax
  716.         mov  dword [SLOT_BASE+APPDATA.except_mask], eax
  717.  
  718.         ; name for OS/IDLE process
  719.  
  720.         mov dword [SLOT_BASE+256+APPDATA.app_name],   dword 'OS/I'
  721.         mov dword [SLOT_BASE+256+APPDATA.app_name+4], dword 'DLE '
  722.         mov edi, [os_stack_seg]
  723.         mov dword [SLOT_BASE+256+APPDATA.pl0_stack], edi
  724.         add edi, 0x2000-512
  725.         mov dword [SLOT_BASE+256+APPDATA.fpu_state], edi
  726.         mov dword [SLOT_BASE+256+APPDATA.saved_esp0], edi ; just for case
  727.         ; [SLOT_BASE+256+APPDATA.io_map] was set earlier
  728.  
  729.         mov esi, fpu_data
  730.         mov ecx, 512/4
  731.         cld
  732.         rep movsd
  733.  
  734.         mov dword [SLOT_BASE+256+APPDATA.exc_handler], eax
  735.         mov dword [SLOT_BASE+256+APPDATA.except_mask], eax
  736.  
  737.         mov ebx, SLOT_BASE+256+APP_OBJ_OFFSET
  738.         mov  dword [SLOT_BASE+256+APPDATA.fd_obj], ebx
  739.         mov  dword [SLOT_BASE+256+APPDATA.bk_obj], ebx
  740.  
  741.         mov  dword [SLOT_BASE+256+APPDATA.cur_dir], sysdir_path
  742.         mov dword [SLOT_BASE+256+APPDATA.tls_base], eax
  743.  
  744.         ; task list
  745.         mov  dword [TASK_DATA+TASKDATA.mem_start],eax   ; process base address
  746.         inc  eax
  747.         mov  dword [CURRENT_TASK],eax
  748.         mov  dword [TASK_COUNT],eax
  749.         mov  [current_slot], SLOT_BASE+256
  750.         mov  [TASK_BASE],dword TASK_DATA
  751.         mov  byte[TASK_DATA+TASKDATA.wnd_number],al     ; on screen number
  752.         mov  dword [TASK_DATA+TASKDATA.pid], eax        ; process id number
  753.  
  754.         call init_display
  755.         mov eax, [def_cursor]
  756.         mov [SLOT_BASE+APPDATA.cursor],eax
  757.         mov [SLOT_BASE+APPDATA.cursor+256],eax
  758.  
  759.   ; READ TSC / SECOND
  760.  
  761.         mov   esi,boot_tsc
  762.         call  boot_log
  763.         cli
  764.         rdtsc ;call  _rdtsc
  765.         mov   ecx,eax
  766.         mov   esi,250               ; wait 1/4 a second
  767.         call  delay_ms
  768.         rdtsc ;call  _rdtsc
  769.         sti
  770.         sub   eax,ecx
  771.         shl   eax,2
  772.         mov   [CPU_FREQ],eax          ; save tsc / sec
  773. ;       mov ebx, 1000000
  774. ;       div ebx
  775. ; вообще-то производительность в данном конкретном месте
  776. ; совершенно некритична, но чтобы заткнуть любителей
  777. ; оптимизирующих компиляторов ЯВУ...
  778.         mov     edx, 2251799814
  779.         mul     edx
  780.         shr     edx, 19
  781.         mov [stall_mcs], edx
  782. ; PRINT CPU FREQUENCY
  783.         mov     esi, boot_cpufreq
  784.         call    boot_log
  785.  
  786.         mov     ebx, edx
  787.         movzx   ecx, word [boot_y]
  788.         add     ecx, (10+17*6) shl 16 - 10 ; 'CPU frequency is '
  789.         mov     edx, 0xFFFFFF
  790.         xor     edi,edi
  791.         mov     eax, 0x00040000
  792.                 inc             edi
  793.         call    display_number_force
  794.  
  795. ; SET VARIABLES
  796.  
  797.         call  set_variables
  798.  
  799. ; SET MOUSE
  800.  
  801.         ;call   detect_devices
  802.         stdcall load_driver, szPS2MDriver
  803. ;        stdcall load_driver, szCOM_MDriver
  804.  
  805.         mov   esi,boot_setmouse
  806.         call  boot_log
  807.         call  setmouse
  808.  
  809.  
  810. ; STACK AND FDC
  811.  
  812.         call  stack_init
  813.         call  fdc_init
  814.  
  815. ; PALETTE FOR 320x200 and 640x480 16 col
  816.  
  817.         cmp   [SCR_MODE],word 0x12
  818.         jne   no_pal_vga
  819.         mov   esi,boot_pal_vga
  820.         call  boot_log
  821.         call  paletteVGA
  822.       no_pal_vga:
  823.  
  824.         cmp   [SCR_MODE],word 0x13
  825.         jne   no_pal_ega
  826.         mov   esi,boot_pal_ega
  827.         call  boot_log
  828.         call  palette320x200
  829.       no_pal_ega:
  830.  
  831. ; LOAD DEFAULT SKIN
  832.  
  833.         call    load_default_skin
  834.  
  835. ;protect io permission map
  836.  
  837.            mov esi, [default_io_map]
  838.            stdcall map_page,esi,[SLOT_BASE+256+APPDATA.io_map], PG_MAP
  839.            add esi, 0x1000
  840.            stdcall map_page,esi,[SLOT_BASE+256+APPDATA.io_map+4], PG_MAP
  841.  
  842.            stdcall map_page,tss._io_map_0,\
  843.                    [SLOT_BASE+256+APPDATA.io_map], PG_MAP
  844.            stdcall map_page,tss._io_map_1,\
  845.                    [SLOT_BASE+256+APPDATA.io_map+4], PG_MAP
  846.  
  847.   mov ax,[OS_BASE+0x10000+bx_from_load]
  848.   cmp ax,'r1'           ; if not rused ram disk - load network configuration from files {SPraid.simba}
  849.   je  no_st_network
  850.         call set_network_conf
  851.   no_st_network:
  852.  
  853. ; LOAD FIRST APPLICATION
  854.         cli
  855.  
  856.         cmp   byte [BOOT_VAR+0x9030],1
  857.         jne   no_load_vrr_m
  858.  
  859.         mov     ebp, vrr_m
  860.         call    fs_execute_from_sysdir
  861.  
  862. ;        cmp   eax,2                  ; if vrr_m app found (PID=2)
  863.         sub   eax,2
  864.         jz    first_app_found
  865.  
  866. no_load_vrr_m:
  867.  
  868.         mov     ebp, firstapp
  869.         call    fs_execute_from_sysdir
  870.  
  871. ;        cmp   eax,2                  ; continue if a process has been loaded
  872.         sub   eax,2
  873.         jz    first_app_found
  874.  
  875.         mov     esi, boot_failed
  876.         call    boot_log
  877.  
  878.         mov   eax, 0xDEADBEEF        ; otherwise halt
  879.         hlt
  880.  
  881. first_app_found:
  882.  
  883.         cli
  884.  
  885.         ;mov   [TASK_COUNT],dword 2
  886.         push  1
  887.         pop   dword [CURRENT_TASK]      ; set OS task fisrt
  888.  
  889. ; SET KEYBOARD PARAMETERS
  890.         mov   al, 0xf6         ; reset keyboard, scan enabled
  891.         call  kb_write
  892.  
  893.         ; wait until 8042 is ready
  894.         xor ecx,ecx
  895.       @@:
  896.         in     al,64h
  897.         and    al,00000010b
  898.         loopnz @b
  899.  
  900.        ; mov   al, 0xED       ; svetodiody - only for testing!
  901.        ; call  kb_write
  902.        ; call  kb_read
  903.        ; mov   al, 111b
  904.        ; call  kb_write
  905.        ; call  kb_read
  906.  
  907.         mov   al, 0xF3       ; set repeat rate & delay
  908.         call  kb_write
  909. ;        call  kb_read
  910.         mov   al, 0 ; 30 250 ;00100010b ; 24 500  ;00100100b  ; 20 500
  911.         call  kb_write
  912. ;        call  kb_read
  913.      ;// mike.dld [
  914.         call  set_lights
  915.      ;// mike.dld ]
  916.  
  917.  
  918. ; Setup serial output console (if enabled)
  919.  
  920. if defined debug_com_base
  921.  
  922.         ; enable Divisor latch
  923.  
  924.         mov     dx, debug_com_base+3
  925.         mov     al, 1 shl 7
  926.         out     dx, al
  927.  
  928.         ; Set speed to 115200 baud (max speed)
  929.  
  930.         mov     dx, debug_com_base
  931.         mov     al, 0x01
  932.         out     dx, al
  933.  
  934.         mov     dx, debug_com_base+1
  935.         mov     al, 0x00
  936.         out     dx, al
  937.  
  938.         ; No parity, 8bits words, one stop bit, dlab bit back to 0
  939.  
  940.         mov     dx, debug_com_base+3
  941.         mov     al, 3
  942.         out     dx, al
  943.  
  944.         ; disable interrupts
  945.  
  946.         mov     dx, debug_com_base+1
  947.         mov     al, 0
  948.         out     dx, al
  949.  
  950.         ; clear +  enable fifo (64 bits)
  951.  
  952.         mov     dx, debug_com_base+2
  953.         mov     al, 0x7 + 1 shl 5
  954.         out     dx, al
  955.  
  956.  
  957. end if
  958.  
  959. ; START MULTITASKING
  960.  
  961. if preboot_blogesc
  962.         mov     esi, boot_tasking
  963.         call    boot_log
  964. .bll1:  in      al, 0x60        ; wait for ESC key press
  965.         cmp     al, 129
  966.         jne     .bll1
  967. end if
  968.  
  969. ;       mov   [ENABLE_TASKSWITCH],byte 1        ; multitasking enabled
  970.  
  971. ; UNMASK ALL IRQ'S
  972.  
  973.         mov   esi,boot_allirqs
  974.         call  boot_log
  975.  
  976.         cli                          ;guarantee forbidance of interrupts.
  977.         mov   al,0                   ; unmask all irq's
  978.         out   0xA1,al
  979.         out   0x21,al
  980.  
  981.         mov   ecx,32
  982.  
  983.      ready_for_irqs:
  984.  
  985.         mov   al,0x20                ; ready for irqs
  986.         out   0x20,al
  987.         out   0xa0,al
  988.  
  989.         loop  ready_for_irqs         ; flush the queue
  990.  
  991.         stdcall attach_int_handler, dword 1, irq1, dword 0
  992.  
  993. ;        mov    [dma_hdd],1
  994.         cmp     [IDEContrRegsBaseAddr], 0
  995.         setnz   [dma_hdd]
  996.         mov [timer_ticks_enable],1              ; for cd driver
  997.  
  998.         sti
  999.         call change_task
  1000.  
  1001.         jmp osloop
  1002.  
  1003. ;        jmp   $                      ; wait here for timer to take control
  1004.  
  1005.         ; Fly :)
  1006.  
  1007. include 'unpacker.inc'
  1008. include 'fdo.inc'
  1009.  
  1010. align 4
  1011. boot_log:
  1012.          pushad
  1013.  
  1014.         mov   ebx,10*65536
  1015.         mov   bx,word [boot_y]
  1016.         add   [boot_y],dword 10
  1017.         mov   ecx,0x80ffffff   ; ASCIIZ string with white color
  1018.                 xor       edi,edi
  1019.         mov   edx,esi
  1020.                 inc       edi
  1021.         call  dtext
  1022.  
  1023.         mov   [novesachecksum],1000
  1024.         call  checkVga_N13
  1025.  
  1026.         popad
  1027.  
  1028.         ret
  1029.  
  1030. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1031. ;                                                                    ;
  1032. ;                    MAIN OS LOOP START                              ;
  1033. ;                                                                    ;
  1034. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1035. align 32
  1036. osloop:
  1037.         call   [draw_pointer]
  1038.         call   checkbuttons
  1039.         call   checkwindows
  1040. ;       call   check_window_move_request
  1041.         call   checkmisc
  1042.         call   checkVga_N13
  1043.         call   stack_handler
  1044.         call   checkidle
  1045.         call   check_fdd_motor_status
  1046.         call   check_ATAPI_device_event
  1047.         jmp    osloop
  1048. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1049. ;                                                                    ;
  1050. ;                      MAIN OS LOOP END                              ;
  1051. ;                                                                    ;
  1052. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1053. align 4
  1054. checkidle:
  1055.         pushad
  1056.         call    change_task
  1057.         jmp     idle_loop_entry
  1058.   idle_loop:
  1059.         cmp     eax,[idlemem]     ; eax == [timer_ticks]
  1060.         jne     idle_exit
  1061.         rdtsc   ;call _rdtsc
  1062.         mov     ecx,eax
  1063.         hlt
  1064.         rdtsc   ;call _rdtsc
  1065.         sub     eax,ecx
  1066.         add     [idleuse],eax
  1067.   idle_loop_entry:
  1068.         mov     eax,[timer_ticks] ; eax =  [timer_ticks]
  1069.         cmp     [check_idle_semaphore],0
  1070.         je      idle_loop
  1071.         dec     [check_idle_semaphore]
  1072.   idle_exit:
  1073.         mov     [idlemem],eax     ; eax == [timer_ticks]
  1074.         popad
  1075.         ret
  1076.  
  1077. uglobal
  1078.   idlemem               dd   0x0
  1079.   idleuse               dd   0x0
  1080.   idleusesec            dd   0x0
  1081.   check_idle_semaphore  dd   0x0
  1082. endg
  1083.  
  1084.  
  1085.  
  1086. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1087. ;                                                                      ;
  1088. ;                   INCLUDED SYSTEM FILES                              ;
  1089. ;                                                                      ;
  1090. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1091.  
  1092.  
  1093. include "kernel32.inc"
  1094.  
  1095.  
  1096. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1097. ;                                                                      ;
  1098. ;                       KERNEL FUNCTIONS                               ;
  1099. ;                                                                      ;
  1100. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1101.  
  1102. reserve_irqs_ports:
  1103.  
  1104.         push eax
  1105.         xor     eax,eax
  1106.                 inc     eax
  1107.         mov  byte [irq_owner+4*0],al            ;1    ; timer
  1108.         ;mov  [irq_owner+4*1], 1    ; keyboard
  1109.         mov  byte [irq_owner+4*6],al            ;1    ; floppy diskette
  1110.         mov  byte [irq_owner+4*13],al   ;1   ; math co-pros
  1111.         mov  byte [irq_owner+4*14],al   ;1   ; ide I
  1112.         mov  byte [irq_owner+4*15],al   ;1   ; ide II
  1113.         pop  eax
  1114.  
  1115. ; RESERVE PORTS
  1116.         push  4
  1117.         pop   dword [RESERVED_PORTS]    ;,edi
  1118.  
  1119.         push  1
  1120.         pop   dword [RESERVED_PORTS+16+0]       ;,dword 1
  1121.         and   dword [RESERVED_PORTS+16+4],0     ;,dword 0x0
  1122.         mov   dword [RESERVED_PORTS+16+8],0x2d  ;,dword 0x2d
  1123.  
  1124.         push  1
  1125.         pop   dword [RESERVED_PORTS+32+0]       ;,dword 1
  1126.         push  0x30
  1127.         pop   dword [RESERVED_PORTS+32+4]       ;,dword 0x30
  1128.         push  0x4d
  1129.         pop   dword [RESERVED_PORTS+32+8]       ;,dword 0x4d
  1130.  
  1131.         push  1
  1132.         pop   dword [RESERVED_PORTS+48+0]       ;,dword 1
  1133.         push  0x50
  1134.         pop   dword [RESERVED_PORTS+48+4]       ;,dword 0x50
  1135.         mov   dword [RESERVED_PORTS+48+8],0xdf  ;,dword 0xdf
  1136.  
  1137.         push  1
  1138.         pop   dword [RESERVED_PORTS+64+0]       ;,dword 1
  1139.  
  1140.         mov   dword [RESERVED_PORTS+64+4],0xe5  ;,dword 0xe5
  1141.         mov   dword [RESERVED_PORTS+64+8],0xff  ;,dword 0xff
  1142.  
  1143.         ret
  1144.  
  1145. setirqreadports:
  1146.  
  1147.         mov   [irq12read+0],dword 0x60 + 0x01000000  ; read port 0x60 , byte
  1148.             and   dword [irq12read+4],0                   ; end of port list
  1149. ;        mov   [irq12read+4],dword 0                  ; end of port list
  1150.         ;mov   [irq04read+0],dword 0x3f8 + 0x01000000 ; read port 0x3f8 , byte
  1151.         ;mov   [irq04read+4],dword 0                  ; end of port list
  1152.         ;mov   [irq03read+0],dword 0x2f8 + 0x01000000 ; read port 0x2f8 , byte
  1153.         ;mov   [irq03read+4],dword 0                  ; end of port list
  1154.  
  1155.         ret
  1156.  
  1157. iglobal
  1158.   process_number dd 0x1
  1159. endg
  1160.  
  1161. set_variables:
  1162.  
  1163.         mov   ecx,0x100                       ; flush port 0x60
  1164. .fl60:  in    al,0x60
  1165.         loop  .fl60
  1166.         push  eax
  1167.  
  1168.         mov   ax,[BOOT_VAR+0x900c]
  1169.         shr   ax,1
  1170.         shl   eax,16
  1171.         mov   ax,[BOOT_VAR+0x900A]
  1172.         shr   ax,1
  1173.         mov   [MOUSE_X],eax
  1174.  
  1175.         xor   eax,eax
  1176.         mov   [BTN_ADDR],dword BUTTON_INFO    ; address of button list
  1177.  
  1178.         mov   byte [MOUSE_BUFF_COUNT],al                 ; mouse buffer
  1179.         mov   byte [KEY_COUNT],al                 ; keyboard buffer
  1180.         mov   byte [BTN_COUNT],al                 ; button buffer
  1181. ;        mov   [MOUSE_X],dword 100*65536+100    ; mouse x/y
  1182.  
  1183.      ;!! IP 04.02.2005:
  1184.         mov   byte [DONT_SWITCH],al ; change task if possible
  1185.         pop   eax
  1186.         ret
  1187.  
  1188. align 4
  1189. ;input  eax=43,bl-byte of output, ecx - number of port
  1190. sys_outport:
  1191.  
  1192.     mov   edi,ecx          ; separate flag for read / write
  1193.     and   ecx,65535
  1194.  
  1195.     mov   eax,[RESERVED_PORTS]
  1196.     test  eax,eax
  1197.     jnz   .sopl8
  1198.     inc   eax
  1199.         mov   [esp+32],eax
  1200.     ret
  1201.  
  1202.   .sopl8:
  1203.     mov   edx,[TASK_BASE]
  1204.     mov   edx,[edx+0x4]
  1205.     ;and   ecx,65535
  1206.     ;cld - set on interrupt 0x40
  1207.   .sopl1:
  1208.  
  1209.     mov   esi,eax
  1210.     shl   esi,4
  1211.     add   esi,RESERVED_PORTS
  1212.     cmp   edx,[esi+0]
  1213.     jne   .sopl2
  1214.     cmp   ecx,[esi+4]
  1215.     jb    .sopl2
  1216.     cmp   ecx,[esi+8]
  1217.     jg    .sopl2
  1218. .sopl3:
  1219.  
  1220.     test  edi,0x80000000 ; read ?
  1221.     jnz   .sopl4
  1222.  
  1223.         mov       eax,ebx
  1224.     mov   dx,cx          ; write
  1225.     out   dx,al
  1226.     and   [esp+32],dword 0
  1227.     ret
  1228.  
  1229.         .sopl2:
  1230.  
  1231.     dec   eax
  1232.     jnz   .sopl1
  1233.         inc       eax
  1234.     mov   [esp+32],eax
  1235.     ret
  1236.  
  1237.  
  1238.   .sopl4:
  1239.  
  1240.     mov   dx,cx          ; read
  1241.     in    al,dx
  1242.     and   eax,0xff
  1243.     and   [esp+32],dword 0
  1244.     mov   [esp+20],eax
  1245.     ret
  1246.  
  1247. display_number:
  1248.  
  1249. ; eax = print type, al=0 -> ebx is number
  1250. ;                   al=1 -> ebx is pointer
  1251. ;                   ah=0 -> display decimal
  1252. ;                   ah=1 -> display hexadecimal
  1253. ;                   ah=2 -> display binary
  1254. ;                   eax bits 16-21 = number of digits to display (0-32)
  1255. ;                   eax bits 22-31 = reserved
  1256. ;
  1257. ; ebx = number or pointer
  1258. ; ecx = x shl 16 + y
  1259. ; edx = color
  1260.     xor     edi, edi
  1261. display_number_force:
  1262.     push  eax
  1263.     and   eax,0x3fffffff
  1264.     cmp   eax,0xffff            ; length > 0 ?
  1265.     pop   eax
  1266.     jge   cont_displ
  1267.     ret
  1268.    cont_displ:
  1269.      push  eax
  1270.      and   eax,0x3fffffff
  1271.      cmp   eax,61*0x10000        ; length <= 60 ?
  1272.      pop   eax
  1273.      jb    cont_displ2
  1274.      ret
  1275.    cont_displ2:
  1276.  
  1277.      pushad
  1278.  
  1279.      cmp   al,1                  ; ecx is a pointer ?
  1280.      jne   displnl1
  1281.      mov   ebp,ebx
  1282.      add   ebp,4
  1283.      mov   ebp,[ebp+std_application_base_address]
  1284.      mov   ebx,[ebx+std_application_base_address]
  1285.  displnl1:
  1286.      sub   esp,64
  1287.  
  1288.     test   ah,ah                  ; DECIMAL
  1289.     jnz   no_display_desnum
  1290.     shr   eax,16
  1291.     and   eax,0xC03f
  1292. ;     and   eax,0x3f
  1293.     push  eax
  1294.     and   eax,0x3f
  1295.     mov   edi,esp
  1296.     add   edi,4+64-1
  1297.     mov   ecx,eax
  1298.     mov   eax,ebx
  1299.     mov   ebx,10
  1300.  d_desnum:
  1301.      xor   edx,edx
  1302.      call  division_64_bits
  1303.      div   ebx
  1304.      add   dl,48
  1305.      mov   [edi],dl
  1306.      dec   edi
  1307.      loop  d_desnum
  1308.      pop   eax
  1309.      call  normalize_number
  1310.      call  draw_num_text
  1311.      add   esp,64
  1312.      popad
  1313.      ret
  1314.    no_display_desnum:
  1315.  
  1316.      cmp   ah,0x01               ; HEXADECIMAL
  1317.      jne   no_display_hexnum
  1318.      shr   eax,16
  1319.      and   eax,0xC03f
  1320. ;     and   eax,0x3f
  1321.      push  eax
  1322.      and   eax,0x3f
  1323.      mov   edi,esp
  1324.      add   edi,4+64-1
  1325.      mov   ecx,eax
  1326.      mov   eax,ebx
  1327.      mov   ebx,16
  1328.    d_hexnum:
  1329.      xor   edx,edx
  1330.      call  division_64_bits
  1331.      div   ebx
  1332.    hexletters = __fdo_hexdigits
  1333.      add   edx,hexletters
  1334.      mov   dl,[edx]
  1335.      mov   [edi],dl
  1336.      dec   edi
  1337.      loop  d_hexnum
  1338.      pop   eax
  1339.      call  normalize_number
  1340.      call  draw_num_text
  1341.      add   esp,64
  1342.      popad
  1343.      ret
  1344.    no_display_hexnum:
  1345.  
  1346.      cmp   ah,0x02               ; BINARY
  1347.      jne   no_display_binnum
  1348.      shr   eax,16
  1349.      and   eax,0xC03f
  1350. ;     and   eax,0x3f
  1351.      push  eax
  1352.      and   eax,0x3f
  1353.      mov   edi,esp
  1354.      add   edi,4+64-1
  1355.      mov   ecx,eax
  1356.      mov   eax,ebx
  1357.      mov   ebx,2
  1358.    d_binnum:
  1359.      xor   edx,edx
  1360.      call  division_64_bits
  1361.      div   ebx
  1362.      add   dl,48
  1363.      mov   [edi],dl
  1364.      dec   edi
  1365.      loop  d_binnum
  1366.      pop   eax
  1367.      call  normalize_number
  1368.      call  draw_num_text
  1369.      add   esp,64
  1370.      popad
  1371.      ret
  1372.    no_display_binnum:
  1373.  
  1374.      add   esp,64
  1375.      popad
  1376.      ret
  1377.  
  1378. normalize_number:
  1379.      test  ah,0x80
  1380.      jz   .continue
  1381.      mov  ecx,48
  1382.      and   eax,0x3f
  1383. @@:
  1384.      inc   edi
  1385.      cmp   [edi],cl
  1386.      jne   .continue
  1387.      dec   eax
  1388.      cmp   eax,1
  1389.      ja    @r
  1390.      mov   al,1
  1391. .continue:
  1392.      and   eax,0x3f
  1393.      ret
  1394.  
  1395. division_64_bits:
  1396.      test  [esp+1+4],byte 0x40
  1397.      jz   .continue
  1398.      push  eax
  1399.      mov   eax,ebp
  1400.      div   ebx
  1401.      mov   ebp,eax
  1402.      pop   eax
  1403. .continue:
  1404.      ret
  1405.  
  1406. draw_num_text:
  1407.      mov   esi,eax
  1408.      mov   edx,64+4
  1409.      sub   edx,eax
  1410.      add   edx,esp
  1411.      mov   ebx,[esp+64+32-8+4]
  1412. ; add window start x & y
  1413.      mov   ecx,[TASK_BASE]
  1414.  
  1415.      mov   edi,[CURRENT_TASK]
  1416.      shl   edi,8
  1417.  
  1418.      mov   eax,[ecx-twdw+WDATA.box.left]
  1419.      add   eax,[edi+SLOT_BASE+APPDATA.wnd_clientbox.left]
  1420.      shl   eax,16
  1421.      add   eax,[ecx-twdw+WDATA.box.top]
  1422.      add   eax,[edi+SLOT_BASE+APPDATA.wnd_clientbox.top]
  1423.      add   ebx,eax
  1424.      mov   ecx,[esp+64+32-12+4]
  1425.         and     ecx, not 0x80000000     ; force counted string
  1426.         mov     eax, [esp+64+8]         ; background color (if given)
  1427.         mov     edi, [esp+64+4]
  1428.      jmp   dtext
  1429.  
  1430. align 4
  1431.  
  1432. sys_setup:
  1433.  
  1434. ; 1=roland mpu midi base , base io address
  1435. ; 2=keyboard   1, base kaybap 2, shift keymap, 9 country 1eng 2fi 3ger 4rus
  1436. ; 3=cd base    1, pri.master 2, pri slave 3 sec master, 4 sec slave
  1437. ; 5=system language, 1eng 2fi 3ger 4rus
  1438. ; 7=hd base    1, pri.master 2, pri slave 3 sec master, 4 sec slave
  1439. ; 8=fat32 partition in hd
  1440. ; 9
  1441. ; 10 = sound dma channel
  1442. ; 11 = enable lba read
  1443. ; 12 = enable pci access
  1444.  
  1445.  
  1446.         and  [esp+32],dword 0
  1447.         dec     ebx                             ; MIDI
  1448.         jnz  nsyse1
  1449.         cmp  ecx,0x100
  1450.  
  1451.         jb   nsyse1
  1452.         mov     esi,65535
  1453.         cmp     esi,ecx
  1454.  
  1455.         jb   nsyse1
  1456.         mov  [midi_base],cx     ;bx
  1457.         mov  word [mididp],cx   ;bx
  1458.         inc  cx                 ;bx
  1459.         mov  word [midisp],cx   ;bx
  1460.         ret
  1461.  
  1462. iglobal
  1463. midi_base dw 0
  1464. endg
  1465.  
  1466.    nsyse1:
  1467.         dec     ebx                              ; KEYBOARD
  1468.         jnz  nsyse2
  1469.         mov  edi,[TASK_BASE]
  1470.         mov  eax,[edi+TASKDATA.mem_start]
  1471.         add  eax,edx
  1472.  
  1473.         dec     ecx
  1474.         jnz  kbnobase
  1475.         mov  ebx,keymap
  1476.         mov  ecx,128
  1477.         call memmove
  1478.         ret
  1479.    kbnobase:
  1480.         dec  ecx
  1481.         jnz  kbnoshift
  1482.  
  1483.         mov  ebx,keymap_shift
  1484.         mov  ecx,128
  1485.         call memmove
  1486.         ret
  1487.    kbnoshift:
  1488.         dec  ecx
  1489.         jnz  kbnoalt
  1490.         mov  ebx,keymap_alt
  1491.         mov  ecx,128
  1492.         call memmove
  1493.         ret
  1494.    kbnoalt:
  1495.         sub  ecx,6
  1496.         jnz  kbnocountry
  1497.         mov  word [keyboard],dx
  1498.         ret
  1499.    kbnocountry:
  1500.         mov  [esp+32],dword 1
  1501.         ret
  1502.    nsyse2:
  1503.         dec  ebx                            ; CD
  1504.         jnz  nsyse4
  1505.  
  1506.         test ecx,ecx
  1507.         jz   nosesl
  1508.  
  1509.         cmp  ecx, 4
  1510.         ja   nosesl
  1511.         mov  [cd_base],cl
  1512.  
  1513.         dec     ecx
  1514.         jnz  noprma
  1515.         mov  [cdbase],0x1f0
  1516.         mov  [cdid],0xa0
  1517.    noprma:
  1518.  
  1519.         dec     ecx
  1520.         jnz  noprsl
  1521.         mov  [cdbase],0x1f0
  1522.         mov  [cdid],0xb0
  1523.    noprsl:
  1524.         dec     ecx
  1525.         jnz  nosema
  1526.         mov  [cdbase],0x170
  1527.         mov  [cdid],0xa0
  1528.    nosema:
  1529.         dec     ecx
  1530.         jnz  nosesl
  1531.         mov  [cdbase],0x170
  1532.         mov  [cdid],0xb0
  1533.    nosesl:
  1534.         ret
  1535.  
  1536. iglobal
  1537. cd_base db 0
  1538.  
  1539. endg
  1540.    nsyse4:
  1541.                  
  1542.         sub  ebx,2               ; SYSTEM LANGUAGE
  1543.         jnz  nsyse5
  1544.         mov  [syslang],ecx
  1545.         ret
  1546.    nsyse5:
  1547.          
  1548.         sub  ebx,2              ; HD BASE
  1549.         jnz  nsyse7
  1550.  
  1551.         test ecx,ecx
  1552.         jz   nosethd
  1553.  
  1554.         cmp  ecx,4
  1555.         ja   nosethd
  1556.         mov  [hd_base],cl
  1557.  
  1558.         cmp  ecx,1
  1559.         jnz  noprmahd
  1560.         mov  [hdbase],0x1f0
  1561.         and  dword [hdid],0x0
  1562.         mov  dword [hdpos],ecx
  1563. ;     call set_FAT32_variables
  1564.    noprmahd:
  1565.  
  1566.         cmp  ecx,2
  1567.         jnz  noprslhd
  1568.         mov  [hdbase],0x1f0
  1569.         mov  [hdid],0x10
  1570.         mov  dword [hdpos],ecx
  1571. ;     call set_FAT32_variables
  1572.    noprslhd:
  1573.  
  1574.         cmp  ecx,3
  1575.         jnz  nosemahd
  1576.         mov  [hdbase],0x170
  1577.         and  dword [hdid],0x0
  1578.         mov  dword [hdpos],ecx
  1579. ;     call set_FAT32_variables
  1580.    nosemahd:
  1581.  
  1582.         cmp  ecx,4
  1583.         jnz  noseslhd
  1584.         mov  [hdbase],0x170
  1585.         mov  [hdid],0x10
  1586.         mov  dword [hdpos],ecx
  1587. ;     call set_FAT32_variables
  1588.    noseslhd:
  1589.         call  reserve_hd1
  1590.         call  reserve_hd_channel
  1591.         call  free_hd_channel
  1592.         and   dword [hd1_status],0        ; free
  1593.    nosethd:
  1594.         ret
  1595.  
  1596. iglobal
  1597. hd_base db 0
  1598. endg
  1599.  
  1600. nsyse7:
  1601.  
  1602. ;     cmp  eax,8                      ; HD PARTITION
  1603.         dec  ebx
  1604.         jnz  nsyse8
  1605.         mov  [fat32part],ecx
  1606. ;     call set_FAT32_variables
  1607.         call  reserve_hd1
  1608.         call  reserve_hd_channel
  1609.         call  free_hd_channel
  1610. ;       pusha
  1611.         call  choice_necessity_partition_1
  1612. ;       popa
  1613.         and dword [hd1_status],0        ; free
  1614.         ret
  1615.  
  1616. nsyse8:
  1617. ;     cmp  eax,11                     ; ENABLE LBA READ
  1618.         and  ecx,1
  1619.         sub  ebx,3
  1620.         jnz  no_set_lba_read
  1621.         mov  [lba_read_enabled],ecx
  1622.         ret
  1623.  
  1624. no_set_lba_read:
  1625. ;     cmp  eax,12                     ; ENABLE PCI ACCESS
  1626.         dec  ebx
  1627.         jnz  no_set_pci_access
  1628.         mov  [pci_access_enabled],ecx
  1629.         ret
  1630. no_set_pci_access:
  1631.  
  1632. ;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  1633. include 'vmodeint.inc'
  1634. ;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  1635.  
  1636. sys_setup_err:
  1637.         or  [esp+32],dword -1
  1638.         ret
  1639.  
  1640. align 4
  1641.  
  1642. sys_getsetup:
  1643.  
  1644. ; 1=roland mpu midi base , base io address
  1645. ; 2=keyboard   1, base kaybap 2, shift keymap, 9 country 1eng 2fi 3ger 4rus
  1646. ; 3=cd base    1, pri.master 2, pri slave 3 sec master, 4 sec slave
  1647. ; 5=system language, 1eng 2fi 3ger 4rus
  1648. ; 7=hd base    1, pri.master 2, pri slave 3 sec master, 4 sec slave
  1649. ; 8=fat32 partition in hd
  1650. ; 9=get hs timer tic
  1651.  
  1652. ;     cmp  eax,1
  1653.         dec     ebx
  1654.         jnz  ngsyse1
  1655.         movzx eax,[midi_base]
  1656.         mov  [esp+32],eax
  1657.         ret
  1658. ngsyse1:
  1659. ;     cmp  eax,2
  1660.         dec     ebx
  1661.         jnz  ngsyse2
  1662.  
  1663.         mov  edi,[TASK_BASE]
  1664.         mov  ebx,[edi+TASKDATA.mem_start]
  1665.         add  ebx,edx
  1666.  
  1667. ;     cmp  ebx,1
  1668.         dec     ecx
  1669.         jnz  kbnobaseret
  1670.         mov  eax,keymap
  1671.         mov  ecx,128
  1672.         call memmove
  1673.         ret
  1674. kbnobaseret:
  1675. ;     cmp  ebx,2
  1676.         dec     ecx
  1677.         jnz  kbnoshiftret
  1678.  
  1679.         mov  eax,keymap_shift
  1680.         mov  ecx,128
  1681.         call memmove
  1682.         ret
  1683. kbnoshiftret:
  1684. ;     cmp  ebx,3
  1685.         dec     ecx
  1686.         jne  kbnoaltret
  1687.  
  1688.         mov  eax,keymap_alt
  1689.         mov  ecx,128
  1690.         call memmove
  1691.         ret
  1692. kbnoaltret:
  1693. ;     cmp  ebx,9
  1694.         sub     ecx,6
  1695.         jnz  ngsyse2
  1696.         movzx eax,word [keyboard]
  1697.         mov  [esp+32],eax
  1698.         ret
  1699.  
  1700.  
  1701. ngsyse2:
  1702. ;         cmp  eax,3
  1703.         dec     ebx
  1704.         jnz  ngsyse3
  1705.         movzx eax,[cd_base]
  1706.         mov  [esp+32],eax
  1707.         ret
  1708. ngsyse3:
  1709. ;         cmp  eax,5
  1710.         sub     ebx,2
  1711.         jnz  ngsyse5
  1712.         mov  eax,[syslang]
  1713.         mov  [esp+32],eax
  1714.         ret
  1715. ngsyse5:
  1716. ;     cmp  eax,7
  1717.         sub     ebx,2
  1718.         jnz  ngsyse7
  1719.         movzx eax,[hd_base]
  1720.         mov  [esp+32],eax
  1721.         ret
  1722. ngsyse7:
  1723. ;     cmp  eax,8
  1724.         dec     ebx
  1725.         jnz  ngsyse8
  1726.         mov eax,[fat32part]
  1727.         mov  [esp+32],eax
  1728.         ret
  1729. ngsyse8:
  1730. ;     cmp  eax,9
  1731.         dec     ebx
  1732.         jnz  ngsyse9
  1733.         mov  eax,[timer_ticks] ;[0xfdf0]
  1734.         mov  [esp+32],eax
  1735.         ret
  1736. ngsyse9:
  1737. ;     cmp  eax,11
  1738.         sub     ebx,2
  1739.         jnz  ngsyse11
  1740.         mov eax,[lba_read_enabled]
  1741.         mov  [esp+32],eax
  1742.         ret
  1743. ngsyse11:
  1744. ;     cmp  eax,12
  1745.         dec     ebx
  1746.         jnz  ngsyse12
  1747.         mov eax,[pci_access_enabled]
  1748.         mov  [esp+32],eax
  1749.         ret
  1750. ngsyse12:
  1751.         mov  [esp+32],dword 1
  1752.         ret
  1753.  
  1754.        
  1755. get_timer_ticks:
  1756.         mov eax,[timer_ticks]
  1757.         ret
  1758.  
  1759. iglobal
  1760. align 4
  1761. mousefn dd msscreen, mswin, msbutton, msset
  1762.         dd app_load_cursor
  1763.         dd app_set_cursor
  1764.         dd app_delete_cursor
  1765.         dd msz
  1766. endg
  1767.  
  1768. readmousepos:
  1769.  
  1770. ; eax=0 screen relative
  1771. ; eax=1 window relative
  1772. ; eax=2 buttons pressed
  1773. ; eax=3 set mouse pos   ; reserved
  1774. ; eax=4 load cursor
  1775. ; eax=5 set cursor
  1776. ; eax=6 delete cursor   ; reserved
  1777. ; eax=7 get mouse_z
  1778.  
  1779.            cmp ebx, 7
  1780.            ja msset
  1781.            jmp [mousefn+ebx*4]
  1782. msscreen:
  1783.            mov  eax,[MOUSE_X]
  1784.            shl  eax,16
  1785.            mov  ax,[MOUSE_Y]
  1786.            mov  [esp+36-4],eax
  1787.            ret
  1788. mswin:
  1789.            mov  eax,[MOUSE_X]
  1790.            shl  eax,16
  1791.            mov  ax,[MOUSE_Y]
  1792.            mov  esi,[TASK_BASE]
  1793.            mov  bx, word [esi-twdw+WDATA.box.left]
  1794.            shl  ebx,16
  1795.            mov  bx, word [esi-twdw+WDATA.box.top]
  1796.            sub  eax,ebx
  1797.  
  1798.            mov  edi,[CURRENT_TASK]
  1799.            shl  edi,8
  1800.            sub  ax,word[edi+SLOT_BASE+APPDATA.wnd_clientbox.top]
  1801.            rol  eax,16
  1802.            sub  ax,word[edi+SLOT_BASE+APPDATA.wnd_clientbox.left]
  1803.            rol  eax,16
  1804.            mov  [esp+36-4],eax
  1805.            ret
  1806. msbutton:
  1807.            movzx eax,byte [BTN_DOWN]
  1808.            mov  [esp+36-4],eax
  1809.            ret
  1810. msz:
  1811.            mov   edi, [TASK_COUNT]
  1812.            movzx edi, word [WIN_POS + edi*2]
  1813.            cmp   edi, [CURRENT_TASK]
  1814.            jne   @f
  1815.            mov   ax,[MOUSE_SCROLL_H]
  1816.            shl   eax,16
  1817.            mov   ax,[MOUSE_SCROLL_V]
  1818.            mov   [esp+36-4],eax
  1819.            and   [MOUSE_SCROLL_H],word 0
  1820.            and   [MOUSE_SCROLL_V],word 0
  1821.            ret
  1822.        @@:
  1823.            and  [esp+36-4],dword 0
  1824. ;           ret
  1825. msset:
  1826.            ret
  1827.  
  1828. app_load_cursor:
  1829.            cmp ecx, OS_BASE
  1830.            jae msset
  1831.            stdcall load_cursor, ecx, edx
  1832.            mov [esp+36-4], eax
  1833.            ret
  1834.  
  1835. app_set_cursor:
  1836.            stdcall set_cursor, ecx
  1837.            mov [esp+36-4], eax
  1838.            ret
  1839.  
  1840. app_delete_cursor:
  1841.            stdcall delete_cursor, ecx
  1842.            mov [esp+36-4], eax
  1843.            ret
  1844.  
  1845. is_input:
  1846.  
  1847.    push edx
  1848.    mov  dx,word [midisp]
  1849.    in   al,dx
  1850.    and  al,0x80
  1851.    pop  edx
  1852.    ret
  1853.  
  1854. is_output:
  1855.  
  1856.    push edx
  1857.    mov  dx,word [midisp]
  1858.    in   al,dx
  1859.    and  al,0x40
  1860.    pop  edx
  1861.    ret
  1862.  
  1863.  
  1864. get_mpu_in:
  1865.  
  1866.    push edx
  1867.    mov  dx,word [mididp]
  1868.    in   al,dx
  1869.    pop  edx
  1870.    ret
  1871.  
  1872.  
  1873. put_mpu_out:
  1874.  
  1875.    push edx
  1876.    mov  dx,word [mididp]
  1877.    out  dx,al
  1878.    pop  edx
  1879.    ret
  1880.  
  1881.  
  1882.  
  1883. align 4
  1884.  
  1885. sys_midi:
  1886.         cmp  [mididp],0
  1887.         jnz  sm0
  1888.         mov  [esp+36],dword 1
  1889.         ret
  1890. sm0:
  1891.         and  [esp+36],dword 0
  1892.         dec  ebx
  1893.         jnz  smn1
  1894.  ;    call setuart
  1895. su1:
  1896.         call is_output
  1897.         test al,al
  1898.         jnz  su1
  1899.         mov  dx,word [midisp]
  1900.         mov  al,0xff
  1901.         out  dx,al
  1902. su2:
  1903.         mov  dx,word [midisp]
  1904.         mov  al,0xff
  1905.         out  dx,al
  1906.         call is_input
  1907.         test al,al
  1908.         jnz  su2
  1909.         call get_mpu_in
  1910.         cmp  al,0xfe
  1911.         jnz  su2
  1912. su3:
  1913.         call is_output
  1914.         test  al,al
  1915.         jnz  su3
  1916.         mov  dx,word [midisp]
  1917.         mov  al,0x3f
  1918.         out  dx,al
  1919.         ret
  1920. smn1:
  1921.         dec  ebx
  1922.         jnz  smn2
  1923. sm10:
  1924.         call get_mpu_in
  1925.         call is_output
  1926.         test al,al
  1927.         jnz  sm10
  1928.         mov  al,bl
  1929.         call put_mpu_out
  1930.         smn2:
  1931.         ret
  1932.  
  1933. detect_devices:
  1934. ;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  1935. ;include 'detect/commouse.inc'
  1936. ;include 'detect/ps2mouse.inc'
  1937. ;include 'detect/dev_fd.inc'
  1938. ;include 'detect/dev_hdcd.inc'
  1939. ;include 'detect/sear_par.inc'
  1940. ;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  1941.     ret
  1942.  
  1943. sys_end:
  1944.  
  1945.      mov ecx, [current_slot]
  1946.      mov eax, [ecx+APPDATA.tls_base]
  1947.      test eax, eax
  1948.      jz @F
  1949.  
  1950.      stdcall user_free, eax
  1951. @@:
  1952.  
  1953.      mov   eax,[TASK_BASE]
  1954.      mov   [eax+TASKDATA.state], 3  ; terminate this program
  1955.  
  1956.     waitterm:            ; wait here for termination
  1957.      mov   ebx,100
  1958.      call  delay_hs
  1959.      jmp   waitterm
  1960.  
  1961. iglobal
  1962. align 4
  1963. sys_system_table:
  1964.         dd      exit_for_anyone         ; 1 = obsolete
  1965.         dd      sysfn_terminate         ; 2 = terminate thread
  1966.         dd      sysfn_activate          ; 3 = activate window
  1967.         dd      sysfn_getidletime       ; 4 = get idle time
  1968.         dd      sysfn_getcpuclock       ; 5 = get cpu clock
  1969.         dd      sysfn_saveramdisk       ; 6 = save ramdisk
  1970.         dd      sysfn_getactive         ; 7 = get active window
  1971.         dd      sysfn_sound_flag        ; 8 = get/set sound_flag
  1972.         dd      sysfn_shutdown          ; 9 = shutdown with parameter
  1973.         dd      sysfn_minimize          ; 10 = minimize window
  1974.         dd      sysfn_getdiskinfo       ; 11 = get disk subsystem info
  1975.         dd      sysfn_lastkey           ; 12 = get last pressed key
  1976.         dd      sysfn_getversion        ; 13 = get kernel version
  1977.         dd      sysfn_waitretrace       ; 14 = wait retrace
  1978.         dd      sysfn_centermouse       ; 15 = center mouse cursor
  1979.         dd      sysfn_getfreemem        ; 16 = get free memory size
  1980.         dd      sysfn_getallmem         ; 17 = get total memory size
  1981.         dd      sysfn_terminate2        ; 18 = terminate thread using PID
  1982.                                         ;                 instead of slot
  1983.         dd      sysfn_mouse_acceleration; 19 = set/get mouse acceleration
  1984.         dd      sysfn_meminfo           ; 20 = get extended memory info
  1985.         dd      sysfn_pid_to_slot       ; 21 = get slot number for pid
  1986.         dd      sysfn_min_rest_window   ; 22 = minimize and restore any window
  1987. sysfn_num = ($ - sys_system_table)/4
  1988. endg
  1989.  
  1990. sys_system:
  1991.         dec     ebx
  1992.         cmp     ebx, sysfn_num
  1993.         jae     @f
  1994.         jmp     dword [sys_system_table + ebx*4]
  1995. @@:
  1996.         ret
  1997.  
  1998.  
  1999. sysfn_shutdown:          ; 18.9 = system shutdown
  2000.      cmp  ecx,1
  2001.      jl   exit_for_anyone
  2002.      cmp  ecx,4
  2003.      jg   exit_for_anyone
  2004.      mov  [BOOT_VAR+0x9030],cl
  2005.  
  2006.      mov  eax,[TASK_COUNT]
  2007.      mov  [SYS_SHUTDOWN],al
  2008.      mov  [shutdown_processes],eax
  2009.      and  dword [esp+32], 0
  2010.  exit_for_anyone:
  2011.      ret
  2012.   uglobal
  2013.    shutdown_processes: dd 0x0
  2014.   endg
  2015.  
  2016. sysfn_terminate:        ; 18.2 = TERMINATE
  2017.      cmp  ecx,2
  2018.      jb   noprocessterminate
  2019.      mov  edx,[TASK_COUNT]
  2020.      cmp  ecx,edx
  2021.      ja   noprocessterminate
  2022.      mov  eax,[TASK_COUNT]
  2023.      shl  ecx,5
  2024.      mov  edx,[ecx+CURRENT_TASK+TASKDATA.pid]
  2025.      add  ecx,CURRENT_TASK+TASKDATA.state
  2026.      cmp  byte [ecx], 9
  2027.      jz   noprocessterminate
  2028.  
  2029.      ;call MEM_Heap_Lock      ;guarantee that process isn't working with heap
  2030.      mov  [ecx],byte 3       ; clear possible i40's
  2031.      ;call MEM_Heap_UnLock
  2032.  
  2033.      cmp  edx,[application_table_status]    ; clear app table stat
  2034.      jne  noatsc
  2035.      mov  [application_table_status],0
  2036.    noatsc:
  2037.    noprocessterminate:
  2038.      ret
  2039.  
  2040. sysfn_terminate2:
  2041. ;lock application_table_status mutex
  2042. .table_status:
  2043.     cli
  2044.     cmp    [application_table_status],0
  2045.     je     .stf
  2046.     sti
  2047.     call   change_task
  2048.     jmp    .table_status
  2049. .stf:
  2050.     call   set_application_table_status
  2051.     mov    eax,ecx
  2052.     call   pid_to_slot
  2053.     test   eax,eax
  2054.     jz     .not_found
  2055.     mov    ecx,eax
  2056.     cli
  2057.     call   sysfn_terminate
  2058.     mov    [application_table_status],0
  2059.     sti
  2060.     and    dword [esp+32],0
  2061.     ret
  2062. .not_found:
  2063.     mov    [application_table_status],0
  2064.     or     dword [esp+32],-1
  2065.     ret
  2066.  
  2067. sysfn_activate:         ; 18.3 = ACTIVATE WINDOW
  2068.      cmp  ecx,2
  2069.      jb   .nowindowactivate
  2070.      cmp  ecx,[TASK_COUNT]
  2071.      ja   .nowindowactivate
  2072.  
  2073.      mov   [window_minimize], 2   ; restore window if minimized
  2074.  
  2075.      movzx esi, word [WIN_STACK + ecx*2]
  2076.      cmp   esi, [TASK_COUNT]
  2077.      je    .nowindowactivate ; already active
  2078.  
  2079.      mov   edi, ecx
  2080.      shl   edi, 5
  2081.      add   edi, window_data
  2082.      movzx esi, word [WIN_STACK + ecx * 2]
  2083.      lea   esi, [WIN_POS + esi * 2]
  2084.      call  waredraw
  2085. .nowindowactivate:
  2086.      ret
  2087.  
  2088. sysfn_getidletime:              ; 18.4 = GET IDLETIME
  2089.      mov  eax,[idleusesec]
  2090.      mov  [esp+32], eax
  2091.      ret
  2092.  
  2093. sysfn_getcpuclock:              ; 18.5 = GET TSC/SEC
  2094.      mov  eax,[CPU_FREQ]
  2095.      mov  [esp+32], eax
  2096.      ret
  2097.  
  2098. ;  SAVE ramdisk to /hd/1/menuet.img
  2099. ;!!!!!!!!!!!!!!!!!!!!!!!!
  2100.    include 'blkdev/rdsave.inc'
  2101. ;!!!!!!!!!!!!!!!!!!!!!!!!
  2102. align 4
  2103. sysfn_getactive:        ; 18.7 = get active window
  2104.      mov  eax, [TASK_COUNT]
  2105.    movzx  eax, word [WIN_POS + eax*2]
  2106.      mov  [esp+32],eax
  2107.      ret
  2108.  
  2109. sysfn_sound_flag:       ; 18.8 = get/set sound_flag
  2110. ;     cmp  ecx,1
  2111.      dec  ecx
  2112.      jnz  nogetsoundflag
  2113.      movzx  eax,byte [sound_flag] ; get sound_flag
  2114.      mov  [esp+32],eax
  2115.      ret
  2116.  nogetsoundflag:
  2117. ;     cmp  ecx,2
  2118.      dec  ecx
  2119.      jnz  nosoundflag
  2120.      xor  byte [sound_flag], 1
  2121.  nosoundflag:
  2122.      ret
  2123.  
  2124. sysfn_minimize:         ; 18.10 = minimize window
  2125.      mov   [window_minimize],1
  2126.      ret
  2127. align 4
  2128. sysfn_getdiskinfo:      ; 18.11 = get disk info table
  2129. ;     cmp  ecx,1
  2130.      dec  ecx
  2131.      jnz  full_table
  2132.   small_table:
  2133.      call for_all_tables
  2134.      mov ecx,10
  2135.      cld
  2136.      rep movsb
  2137.      ret
  2138.    for_all_tables:
  2139.      mov edi,edx
  2140.      mov esi,DRIVE_DATA
  2141.      ret
  2142.   full_table:
  2143. ;     cmp  ecx,2
  2144.      dec  ecx
  2145.      jnz  exit_for_anyone
  2146.      call for_all_tables
  2147.      mov ecx,16384
  2148.      cld
  2149.      rep movsd
  2150.      ret
  2151.  
  2152. sysfn_lastkey:          ; 18.12 = return 0 (backward compatibility)
  2153.         and     dword [esp+32], 0
  2154.         ret
  2155.  
  2156. sysfn_getversion:       ; 18.13 = get kernel ID and version
  2157.      mov edi,ebx
  2158.      mov esi,version_inf
  2159.      mov ecx,version_end-version_inf
  2160.      rep movsb
  2161.      ret
  2162.  
  2163. sysfn_waitretrace:     ; 18.14 = sys wait retrace
  2164.      ;wait retrace functions
  2165.  sys_wait_retrace:
  2166.      mov edx,0x3da
  2167.  WaitRetrace_loop:
  2168.      in al,dx
  2169.      test al,1000b
  2170.      jz WaitRetrace_loop
  2171.      and [esp+32],dword 0
  2172.      ret
  2173.  
  2174. align 4
  2175. sysfn_centermouse:      ; 18.15 = mouse centered
  2176. ; removed here by <Lrz>
  2177. ;     call  mouse_centered
  2178. ;* mouse centered - start code- Mario79
  2179. ;mouse_centered:
  2180. ;        push  eax
  2181.         mov   eax,[Screen_Max_X]
  2182.         shr   eax,1
  2183.         mov   [MOUSE_X],ax
  2184.         mov   eax,[Screen_Max_Y]
  2185.         shr   eax,1
  2186.         mov   [MOUSE_Y],ax
  2187. ;        ret
  2188. ;* mouse centered - end code- Mario79
  2189.         xor   eax,eax
  2190.         and   [esp+32],eax
  2191. ;        pop   eax
  2192.  
  2193.      ret
  2194. align 4
  2195. sysfn_mouse_acceleration: ; 18.19 = set/get mouse features
  2196.      test ecx,ecx  ; get mouse speed factor
  2197.      jnz  .set_mouse_acceleration
  2198.      xor  eax,eax
  2199.      mov  ax,[mouse_speed_factor]
  2200.      mov  [esp+32],eax
  2201.      ret
  2202.  .set_mouse_acceleration:
  2203. ;     cmp  ecx,1  ; set mouse speed factor
  2204.      dec  ecx
  2205.      jnz  .get_mouse_delay
  2206.      mov  [mouse_speed_factor],dx
  2207.      ret
  2208.  .get_mouse_delay:
  2209. ;     cmp  ecx,2  ; get mouse delay
  2210.      dec  ecx
  2211.      jnz  .set_mouse_delay
  2212.      mov  eax,[mouse_delay]
  2213.      mov  [esp+32],eax
  2214.      ret
  2215.  .set_mouse_delay:
  2216. ;     cmp  ecx,3  ; set mouse delay
  2217.      dec  ecx
  2218.      jnz  .set_pointer_position
  2219.      mov  [mouse_delay],edx
  2220.      ret
  2221.  .set_pointer_position:
  2222. ;     cmp  ecx,4  ; set mouse pointer position
  2223.      dec   ecx
  2224.      jnz  .set_mouse_button
  2225.      mov   [MOUSE_Y],dx    ;y
  2226.      ror   edx,16
  2227.      mov   [MOUSE_X],dx    ;x
  2228.      rol   edx,16
  2229.      ret
  2230.  .set_mouse_button:
  2231. ;     cmp   ecx,5  ; set mouse button features
  2232.      dec   ecx
  2233.      jnz  .end
  2234.      mov   [BTN_DOWN],dl
  2235.      mov   [mouse_active],1
  2236.  .end:
  2237.      ret
  2238.  
  2239. sysfn_getfreemem:
  2240.      mov eax, [pg_data.pages_free]
  2241.      shl eax, 2
  2242.      mov [esp+32],eax
  2243.      ret
  2244.  
  2245. sysfn_getallmem:
  2246.      mov  eax,[MEM_AMOUNT]
  2247.      shr eax, 10
  2248.      mov  [esp+32],eax
  2249.      ret
  2250.  
  2251. ; // Alver, 2007-22-08 // {
  2252. sysfn_pid_to_slot:
  2253.      mov   eax, ecx
  2254.      call  pid_to_slot
  2255.      mov   [esp+32], eax
  2256.      ret
  2257.  
  2258. sysfn_min_rest_window:
  2259.      pushad
  2260.      mov   eax, edx      ; ebx - operating
  2261.      shr   ecx, 1
  2262.      jnc    @f
  2263.      call  pid_to_slot
  2264. @@:
  2265.      or    eax, eax      ; eax - number of slot
  2266.      jz    .error
  2267.      cmp   eax, 255         ; varify maximal slot number
  2268.      ja    .error
  2269.      movzx eax, word [WIN_STACK + eax*2]
  2270.      shr   ecx, 1
  2271.      jc    .restore
  2272.  ; .minimize:
  2273.      call  minimize_window
  2274.      jmp   .exit
  2275. .restore:
  2276.      call  restore_minimized_window
  2277. .exit:
  2278.      popad
  2279.      xor   eax, eax
  2280.      mov   [esp+32], eax
  2281.      ret
  2282. .error:
  2283.      popad
  2284.      xor   eax, eax
  2285.      dec   eax
  2286.      mov   [esp+32], eax
  2287.      ret
  2288. ; } \\ Alver, 2007-22-08 \\
  2289.  
  2290. uglobal
  2291. ;// mike.dld, 2006-29-01 [
  2292. screen_workarea RECT
  2293. ;// mike.dld, 2006-29-01 ]
  2294. window_minimize db 0
  2295. sound_flag      db 0
  2296. endg
  2297.  
  2298. iglobal
  2299. version_inf:
  2300.   db 0,7,5,0  ; version 0.7.5.0
  2301.   db UID_KOLIBRI
  2302.   dd __REV__
  2303. version_end:
  2304. endg
  2305.  
  2306. UID_NONE=0
  2307. UID_MENUETOS=1   ;official
  2308. UID_KOLIBRI=2    ;russian
  2309.  
  2310. sys_cachetodiskette:
  2311.         cmp     ebx, 1
  2312.         jne     .no_floppy_a_save
  2313.         mov     [flp_number], 1
  2314.         jmp     .save_image_on_floppy
  2315. .no_floppy_a_save:
  2316.         cmp     ebx, 2
  2317.         jne     .no_floppy_b_save
  2318.         mov     [flp_number], 2
  2319. .save_image_on_floppy:
  2320.         call    save_image
  2321.         mov     [esp + 32], dword 0
  2322.         cmp     [FDC_Status], 0
  2323.         je      .yes_floppy_save
  2324. .no_floppy_b_save:
  2325.         mov     [esp + 32], dword 1
  2326. .yes_floppy_save:
  2327.         ret
  2328.  
  2329. uglobal
  2330. ;  bgrchanged  dd  0x0
  2331. align 4
  2332. bgrlockpid dd 0
  2333. bgrlock db 0
  2334. endg
  2335.  
  2336. sys_background:
  2337.  
  2338.     cmp   ebx,1                            ; BACKGROUND SIZE
  2339.     jnz   nosb1
  2340.     test  ecx,ecx
  2341. ;    cmp   ecx,0
  2342.     jz    sbgrr
  2343.     test  edx,edx
  2344. ;    cmp   edx,0
  2345.     jz    sbgrr
  2346. @@:
  2347. ;;Maxis use atomic bts for mutexes  4.4.2009
  2348.         bts     dword [bgrlock], 0
  2349.         jnc     @f
  2350.         call    change_task
  2351.         jmp     @b
  2352. @@:
  2353.     mov   [BgrDataWidth],ecx
  2354.     mov   [BgrDataHeight],edx
  2355. ;    mov   [bgrchanged],1
  2356.  
  2357.     pushad
  2358. ; return memory for old background
  2359.         mov     eax, [img_background]
  2360.         cmp     eax, static_background_data
  2361.         jz      @f
  2362.         stdcall kernel_free, eax
  2363. @@:
  2364. ; calculate RAW size
  2365.     xor  eax,eax
  2366.     inc  eax
  2367.     cmp  [BgrDataWidth],eax
  2368.     jae   @f
  2369.     mov [BgrDataWidth],eax
  2370. @@:
  2371.     cmp  [BgrDataHeight],eax
  2372.     jae   @f
  2373.     mov [BgrDataHeight],eax
  2374. @@:
  2375.     mov  eax,[BgrDataWidth]
  2376.     imul eax,[BgrDataHeight]
  2377.     lea  eax,[eax*3]
  2378.     mov  [mem_BACKGROUND],eax
  2379. ; get memory for new background
  2380.     stdcall kernel_alloc, eax
  2381.     test eax, eax
  2382.     jz .memfailed
  2383.     mov [img_background], eax
  2384.     jmp .exit
  2385. .memfailed:
  2386. ; revert to static monotone data
  2387.         mov     [img_background], static_background_data
  2388.         xor     eax, eax
  2389.         inc     eax
  2390.         mov     [BgrDataWidth], eax
  2391.         mov     [BgrDataHeight], eax
  2392.         mov     [mem_BACKGROUND], 4
  2393. .exit:
  2394.     popad
  2395.         mov     [bgrlock], 0
  2396.  
  2397.   sbgrr:
  2398.     ret
  2399.  
  2400. nosb1:
  2401.  
  2402.     cmp   ebx,2                            ; SET PIXEL
  2403.     jnz   nosb2
  2404.  
  2405.     mov   eax, [img_background]
  2406.     test  ecx, ecx
  2407.     jz    @f
  2408.     cmp   eax, static_background_data
  2409.     jz    .ret
  2410. @@:
  2411.     mov ebx, [mem_BACKGROUND]
  2412.     add ebx, 4095
  2413.     and ebx, -4096
  2414.     sub ebx, 4
  2415.     cmp   ecx, ebx
  2416.     ja   .ret
  2417.  
  2418.     mov   ebx,[eax+ecx]
  2419.     and   ebx,0xFF000000 ;255*256*256*256
  2420.     and   edx,0x00FFFFFF ;255*256*256+255*256+255
  2421.     add   edx,ebx
  2422.     mov   [eax+ecx],edx
  2423. .ret:
  2424.     ret
  2425. nosb2:
  2426.  
  2427.     cmp   ebx,3                            ; DRAW BACKGROUND
  2428.     jnz   nosb3
  2429. draw_background_temp:
  2430. ;    cmp   [bgrchanged],1 ;0
  2431. ;    je    nosb31
  2432. ;draw_background_temp:
  2433. ;    mov   [bgrchanged],1 ;0
  2434.     mov    [background_defined], 1
  2435.     call  force_redraw_background
  2436.     mov    [REDRAW_BACKGROUND], byte 2
  2437.    nosb31:
  2438.     ret
  2439.   nosb3:
  2440.  
  2441.     cmp   ebx,4                            ; TILED / STRETCHED
  2442.     jnz   nosb4
  2443.     cmp   ecx,[BgrDrawMode]
  2444.     je    nosb41
  2445.     mov   [BgrDrawMode],ecx
  2446. ;    mov   [bgrchanged],1
  2447.    nosb41:
  2448.     ret
  2449.   nosb4:
  2450.  
  2451.     cmp   ebx,5                            ; BLOCK MOVE TO BGR
  2452.     jnz   nosb5
  2453.     cmp   [img_background], static_background_data
  2454.     jnz   @f
  2455.     test  edx, edx
  2456.     jnz   .fin
  2457.     cmp   esi, 4
  2458.     ja    .fin
  2459.   @@:
  2460.   ; bughere
  2461.     mov   eax, ecx
  2462.     mov   ebx, edx
  2463.     add   ebx, [img_background]   ;IMG_BACKGROUND
  2464.     mov   ecx, esi
  2465.     call  memmove
  2466.   .fin:
  2467.     ret
  2468.   nosb5:
  2469.  
  2470.         cmp     ebx, 6
  2471.         jnz     nosb6
  2472. ;;Maxis use atomic bts for mutex 4.4.2009
  2473. @@:
  2474.         bts     dword [bgrlock], 0
  2475.         jnc     @f
  2476.         call    change_task
  2477.         jmp     @b
  2478. @@:
  2479.         mov     eax, [CURRENT_TASK]
  2480.         mov     [bgrlockpid], eax
  2481.         cmp     [img_background], static_background_data
  2482.         jz      .nomem
  2483.         stdcall user_alloc, [mem_BACKGROUND]
  2484.         mov     [esp+32], eax
  2485.         test    eax, eax
  2486.         jz      .nomem
  2487.         mov     ebx, eax
  2488.         shr     ebx, 12
  2489.         or      dword [page_tabs+(ebx-1)*4], DONT_FREE_BLOCK
  2490.         mov     esi, [img_background]
  2491.         shr     esi, 12
  2492.         mov     ecx, [mem_BACKGROUND]
  2493.         add     ecx, 0xFFF
  2494.         shr     ecx, 12
  2495. .z:
  2496.         mov     eax, [page_tabs+ebx*4]
  2497.         test    al, 1
  2498.         jz      @f
  2499.         call    free_page
  2500. @@:
  2501.         mov     eax, [page_tabs+esi*4]
  2502.         or      al, PG_UW
  2503.         mov     [page_tabs+ebx*4], eax
  2504.         mov     eax, ebx
  2505.         shl     eax, 12
  2506.         invlpg  [eax]
  2507.         inc     ebx
  2508.         inc     esi
  2509.         loop    .z
  2510.         ret
  2511. .nomem:
  2512.         and     [bgrlockpid], 0
  2513.         mov     [bgrlock], 0
  2514. nosb6:
  2515.         cmp     ebx, 7
  2516.         jnz     nosb7
  2517.         cmp     [bgrlock], 0
  2518.         jz      .err
  2519.         mov     eax, [CURRENT_TASK]
  2520.         cmp     [bgrlockpid], eax
  2521.         jnz     .err
  2522.         mov     eax, ecx
  2523.         mov     ebx, ecx
  2524.         shr     eax, 12
  2525.         mov     ecx, [page_tabs+(eax-1)*4]
  2526.         test    cl, USED_BLOCK+DONT_FREE_BLOCK
  2527.         jz      .err
  2528.         jnp     .err
  2529.         push    eax
  2530.         shr     ecx, 12
  2531.         dec     ecx
  2532. @@:
  2533.         and     dword [page_tabs+eax*4], 0
  2534.         mov     edx, eax
  2535.         shl     edx, 12
  2536.         push eax
  2537.         invlpg  [edx]
  2538.         pop eax
  2539.         inc     eax
  2540.         loop    @b
  2541.         pop     eax
  2542.         and     dword [page_tabs+(eax-1)*4], not DONT_FREE_BLOCK
  2543.         stdcall user_free, ebx
  2544.         mov     [esp+32], eax
  2545.         and     [bgrlockpid], 0
  2546.         mov     [bgrlock], 0
  2547.         ret
  2548. .err:
  2549.         and     dword [esp+32], 0
  2550.         ret
  2551.  
  2552. nosb7:
  2553.     ret
  2554.  
  2555. force_redraw_background:
  2556.     and   [draw_data+32 + RECT.left],dword 0
  2557.     and   [draw_data+32 + RECT.top],dword 0
  2558.     push  eax ebx
  2559.     mov   eax,[Screen_Max_X]
  2560.     mov   ebx,[Screen_Max_Y]
  2561.     mov   [draw_data+32 + RECT.right],eax
  2562.     mov   [draw_data+32 + RECT.bottom],ebx
  2563.     pop   ebx eax
  2564.     mov   byte [REDRAW_BACKGROUND], 1
  2565.     ret
  2566.  
  2567. align 4
  2568.  
  2569. sys_getbackground:
  2570. ;    cmp   eax,1                                  ; SIZE
  2571.     dec   ebx
  2572.     jnz   nogb1
  2573.     mov   eax,[BgrDataWidth]
  2574.     shl   eax,16
  2575.     mov   ax,[BgrDataHeight]
  2576.     mov   [esp+32],eax
  2577.     ret
  2578.  
  2579. nogb1:
  2580. ;    cmp   eax,2                                  ; PIXEL
  2581.     dec   ebx
  2582.     jnz   nogb2
  2583.  
  2584.         mov     eax, [img_background]
  2585.         test    ecx, ecx
  2586.         jz      @f
  2587.         cmp     eax, static_background_data
  2588.         jz      .ret
  2589. @@:
  2590.     mov ebx, [mem_BACKGROUND]
  2591.     add ebx, 4095
  2592.     and ebx, -4096
  2593.     sub ebx, 4
  2594.     cmp ecx, ebx
  2595.     ja  .ret
  2596.  
  2597.     mov   eax,[ecx+eax]
  2598.  
  2599.     and   eax, 0xFFFFFF
  2600.     mov   [esp+32],eax
  2601. .ret:
  2602.     ret
  2603.   nogb2:
  2604.  
  2605. ;    cmp   eax,4                                  ; TILED / STRETCHED
  2606.     dec   ebx
  2607.     dec   ebx
  2608.     jnz   nogb4
  2609.     mov   eax,[BgrDrawMode]
  2610.   nogb4:
  2611.     mov   [esp+32],eax
  2612.     ret
  2613.  
  2614. align 4
  2615.  
  2616. sys_getkey:
  2617.         mov     [esp + 32],dword 1
  2618.         ; test main buffer
  2619.         mov     ebx, [CURRENT_TASK]                          ; TOP OF WINDOW STACK
  2620.         movzx   ecx, word [WIN_STACK + ebx * 2]
  2621.         mov     edx, [TASK_COUNT]
  2622.         cmp     ecx, edx
  2623.         jne     .finish
  2624.         cmp     [KEY_COUNT], byte 0
  2625.         je      .finish
  2626.         movzx   eax, byte [KEY_BUFF]
  2627.         shl     eax, 8
  2628.         push    eax
  2629.         dec     byte [KEY_COUNT]
  2630.         and     byte [KEY_COUNT], 127
  2631.         movzx   ecx, byte [KEY_COUNT]
  2632.         add     ecx, 2
  2633.         mov     eax, KEY_BUFF + 1
  2634.         mov     ebx, KEY_BUFF
  2635.         call    memmove
  2636.         pop     eax
  2637. .ret_eax:
  2638.         mov     [esp + 32], eax
  2639.         ret
  2640. .finish:
  2641. ; test hotkeys buffer
  2642.         mov     ecx, hotkey_buffer
  2643. @@:
  2644.         cmp     [ecx], ebx
  2645.         jz      .found
  2646.         add     ecx, 8
  2647.         cmp     ecx, hotkey_buffer + 120 * 8
  2648.         jb      @b
  2649.         ret
  2650. .found:
  2651.         mov     ax, [ecx + 6]
  2652.         shl     eax, 16
  2653.         mov     ah, [ecx + 4]
  2654.         mov     al, 2
  2655.         and     dword [ecx + 4], 0
  2656.         and     dword [ecx], 0
  2657.         jmp     .ret_eax
  2658.  
  2659. align 4
  2660.  
  2661. sys_getbutton:
  2662.  
  2663.         mov     ebx, [CURRENT_TASK]                         ; TOP OF WINDOW STACK
  2664.         mov     [esp + 32], dword 1
  2665.         movzx   ecx, word [WIN_STACK + ebx * 2]
  2666.         mov     edx, [TASK_COUNT] ; less than 256 processes
  2667.         cmp     ecx, edx
  2668.         jne     .exit
  2669.         movzx   eax, byte [BTN_COUNT]
  2670.         test    eax, eax
  2671.         jz      .exit
  2672.         mov     eax, [BTN_BUFF]
  2673.         shl     eax, 8
  2674. ; // Alver 22.06.2008 // {
  2675.         mov       al, byte [btn_down_determ]
  2676.         and       al,0xFE                                       ; delete left button bit
  2677. ; } \\ Alver \\
  2678.         mov     [BTN_COUNT], byte 0
  2679.         mov     [esp + 32], eax
  2680. .exit:
  2681.         ret
  2682.  
  2683.  
  2684. align 4
  2685.  
  2686. sys_cpuusage:
  2687.  
  2688. ;  RETURN:
  2689. ;
  2690. ;  +00 dword     process cpu usage
  2691. ;  +04  word     position in windowing stack
  2692. ;  +06  word     windowing stack value at current position (cpu nro)
  2693. ;  +10 12 bytes  name
  2694. ;  +22 dword     start in mem
  2695. ;  +26 dword     used mem
  2696. ;  +30 dword     PID , process idenfification number
  2697. ;
  2698.  
  2699.     cmp  ecx,-1         ; who am I ?
  2700.     jne  .no_who_am_i
  2701.     mov  ecx,[CURRENT_TASK]
  2702.   .no_who_am_i:
  2703.         cmp     ecx, max_processes
  2704.         ja      .nofillbuf
  2705.  
  2706. ; +4: word: position of the window of thread in the window stack
  2707.         mov     ax, [WIN_STACK + ecx * 2]
  2708.         mov     [ebx+4], ax
  2709. ; +6: word: number of the thread slot, which window has in the window stack
  2710. ;           position ecx (has no relation to the specific thread)
  2711.         mov     ax, [WIN_POS + ecx * 2]
  2712.         mov     [ebx+6], ax
  2713.  
  2714.         shl     ecx, 5
  2715.  
  2716. ; +0: dword: memory usage
  2717.         mov     eax, [ecx+CURRENT_TASK+TASKDATA.cpu_usage]
  2718.         mov     [ebx], eax
  2719. ; +10: 11 bytes: name of the process
  2720.         push    ecx
  2721.         lea     eax, [ecx*8+SLOT_BASE+APPDATA.app_name]
  2722.         add     ebx, 10
  2723.         mov     ecx, 11
  2724.         call    memmove
  2725.         pop     ecx
  2726.  
  2727. ; +22: address of the process in memory
  2728. ; +26: size of used memory - 1
  2729.         push    edi
  2730.         lea     edi, [ebx+12]
  2731.         xor     eax, eax
  2732.         mov     edx, 0x100000*16
  2733.         cmp     ecx, 1 shl 5
  2734.         je      .os_mem
  2735.         mov     edx, [SLOT_BASE+ecx*8+APPDATA.mem_size]
  2736.         mov     eax, std_application_base_address
  2737. .os_mem:
  2738.         stosd
  2739.         lea     eax, [edx-1]
  2740.         stosd
  2741.  
  2742. ; +30: PID/TID
  2743.         mov     eax, [ecx+CURRENT_TASK+TASKDATA.pid]
  2744.         stosd
  2745.  
  2746.     ; window position and size
  2747.         push    esi
  2748.         lea     esi, [ecx + window_data + WDATA.box]
  2749.         movsd
  2750.         movsd
  2751.         movsd
  2752.         movsd
  2753.  
  2754.     ; Process state (+50)
  2755.         mov     eax, dword [ecx+CURRENT_TASK+TASKDATA.state]
  2756.         stosd
  2757.  
  2758.     ; Window client area box
  2759.         lea     esi, [ecx*8 + SLOT_BASE + APPDATA.wnd_clientbox]
  2760.         movsd
  2761.         movsd
  2762.         movsd
  2763.         movsd
  2764.  
  2765.     ; Window state
  2766.         mov     al, [ecx+window_data+WDATA.fl_wstate]
  2767.         stosb
  2768.  
  2769.         pop     esi
  2770.         pop     edi
  2771.  
  2772. .nofillbuf:
  2773.     ; return number of processes
  2774.  
  2775.     mov    eax,[TASK_COUNT]
  2776.     mov    [esp+32],eax
  2777.     ret
  2778.  
  2779. align 4
  2780. sys_clock:
  2781.         cli
  2782.   ; Mikhail Lisovin  xx Jan 2005
  2783.   @@:   mov   al, 10
  2784.         out   0x70, al
  2785.         in    al, 0x71
  2786.         test  al, al
  2787.         jns   @f
  2788.         mov   esi, 1
  2789.         call  delay_ms
  2790.         jmp   @b
  2791.   @@:
  2792.   ; end Lisovin's fix
  2793.  
  2794.         xor   al,al           ; seconds
  2795.         out   0x70,al
  2796.         in    al,0x71
  2797.         movzx ecx,al
  2798.         mov   al,02           ; minutes
  2799.         shl   ecx,16
  2800.         out   0x70,al
  2801.         in    al,0x71
  2802.         movzx edx,al
  2803.         mov   al,04           ; hours
  2804.         shl   edx,8
  2805.         out   0x70,al
  2806.         in    al,0x71
  2807.         add   ecx,edx
  2808.         movzx edx,al
  2809.         add   ecx,edx
  2810.         sti
  2811.         mov     [esp + 32], ecx
  2812.         ret
  2813.  
  2814.  
  2815. align 4
  2816.  
  2817. sys_date:
  2818.  
  2819.         cli
  2820.   @@:   mov   al, 10
  2821.         out   0x70, al
  2822.         in    al, 0x71
  2823.         test  al, al
  2824.         jns   @f
  2825.         mov   esi, 1
  2826.         call  delay_ms
  2827.         jmp   @b
  2828.   @@:
  2829.  
  2830.         mov     ch,0
  2831.         mov     al,7            ; date
  2832.         out     0x70,al
  2833.         in      al,0x71
  2834.         mov     cl,al
  2835.         mov     al,8            ; month
  2836.         shl     ecx,16
  2837.         out     0x70,al
  2838.         in      al,0x71
  2839.         mov     ch,al
  2840.         mov     al,9            ; year
  2841.         out     0x70,al
  2842.         in      al,0x71
  2843.         mov     cl,al
  2844.         sti
  2845.         mov     [esp+32], ecx
  2846.         ret
  2847.  
  2848.  
  2849. ; redraw status
  2850.  
  2851. sys_redrawstat:
  2852.         cmp     ebx, 1
  2853.         jne     no_widgets_away
  2854.         ; buttons away
  2855.         mov     ecx,[CURRENT_TASK]
  2856.   sys_newba2:
  2857.         mov     edi,[BTN_ADDR]
  2858.         cmp     [edi], dword 0  ; empty button list ?
  2859.         je      end_of_buttons_away
  2860.         movzx   ebx, word [edi]
  2861.         inc     ebx
  2862.         mov     eax,edi
  2863.   sys_newba:
  2864.         dec     ebx
  2865.         jz      end_of_buttons_away
  2866.  
  2867.         add     eax, 0x10
  2868.         cmp     cx, [eax]
  2869.         jnz     sys_newba
  2870.  
  2871.         push    eax ebx ecx
  2872.         mov     ecx,ebx
  2873.         inc     ecx
  2874.         shl     ecx, 4
  2875.         mov     ebx, eax
  2876.         add     eax, 0x10
  2877.         call    memmove
  2878.         dec     dword [edi]
  2879.         pop     ecx ebx eax
  2880.  
  2881.         jmp     sys_newba2
  2882.  
  2883.   end_of_buttons_away:
  2884.  
  2885.         ret
  2886.  
  2887.   no_widgets_away:
  2888.  
  2889.         cmp     ebx, 2
  2890.         jnz     srl1
  2891.  
  2892.         mov     edx, [TASK_BASE]      ; return whole screen draw area for this app
  2893.         add     edx, draw_data - CURRENT_TASK
  2894.         mov     [edx + RECT.left], 0
  2895.         mov     [edx + RECT.top],