Subversion Repositories Kolibri OS

Rev

Rev 3481 | Rev 3539 | Go to most recent revision | Blame | Compare with Previous | Last modification | View Log | Download | RSS feed

  1. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  2. ;;                                                              ;;
  3. ;; Copyright (C) KolibriOS team 2004-2012. All rights reserved. ;;
  4. ;; Copyright (C) MenuetOS 2000-2004 Ville Mikael Turjanmaa      ;;
  5. ;; Distributed under terms of the GNU General Public License    ;;
  6. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  7.  
  8. $Revision: 3534 $
  9.  
  10. WINDOW_MOVE_AND_RESIZE_FLAGS = \
  11.   mouse.WINDOW_RESIZE_N_FLAG + \
  12.   mouse.WINDOW_RESIZE_W_FLAG + \
  13.   mouse.WINDOW_RESIZE_S_FLAG + \
  14.   mouse.WINDOW_RESIZE_E_FLAG + \
  15.   mouse.WINDOW_MOVE_FLAG
  16.  
  17. uglobal
  18. align 4
  19.   event_start   dd ?
  20.   event_end     dd ?
  21.   event_uid     dd 0
  22. endg
  23. EV_SPACE   = 512
  24. FreeEvents = event_start-EVENT.fd    ; "âèðòóàëüíûé" event, èñïîëüçóþòñÿ òîëüêî ïîëÿ:
  25.                                      ;  FreeEvents.fd=event_start è FreeEvents.bk=event_end
  26. ;-----------------------------------------------------------------------------
  27. align 4
  28. init_events:                                       ;; used from kernel.asm
  29.         stdcall kernel_alloc, EV_SPACE*sizeof.EVENT
  30.         or      eax, eax
  31.         jz      .fail
  32.       ; eax - current event, ebx - previos event below
  33.         mov     ecx, EV_SPACE        ; current - in allocated space
  34.         mov     ebx, FreeEvents      ; previos - íà÷àëî ñïèñêà
  35.         push    ebx                  ; îíî æå è êîíåö ïîòîì áóäåò
  36. ;--------------------------------------
  37. align 4
  38. @@:
  39.         mov     [ebx+EVENT.fd], eax
  40.         mov     [eax+EVENT.bk], ebx
  41.         mov     ebx, eax             ; previos <- current
  42.         add     eax, sizeof.EVENT    ; new current
  43.         loop    @b
  44.         pop     eax                  ; âîò îíî êîíöîì è ñòàëî
  45.         mov     [ebx+EVENT.fd], eax
  46.         mov     [eax+EVENT.bk], ebx
  47. ;--------------------------------------
  48. align 4
  49. .fail:
  50.         ret
  51. ;-----------------------------------------------------------------------------
  52. EVENT_WATCHED    equ 0x10000000 ;áèò 28
  53. EVENT_SIGNALED   equ 0x20000000 ;áèò 29
  54. MANUAL_RESET     equ 0x40000000 ;áèò 30
  55. MANUAL_DESTROY   equ 0x80000000 ;áèò 31
  56. ;-----------------------------------------------------------------------------
  57. align 4
  58. create_event:                                      ;; EXPORT use
  59. ;info:
  60. ;   Ïåðåíîñèì EVENT èç ñïèñêà FreeEvents â ñïèñîê ObjList òåêóùåãî ñëîòà
  61. ;   EVENT.state óñòàíàâëèâàåì èç ecx, EVENT.code êîñâåííî èç esi (åñëè esi<>0)
  62. ;param:
  63. ;   esi - event data
  64. ;   ecx - flags
  65. ;retval:
  66. ;   eax - event (=0 => fail)
  67. ;   edx - uid
  68. ;scratched: ebx,ecx,esi,edi
  69.         mov     ebx, [current_slot]
  70.         add     ebx, APP_OBJ_OFFSET
  71.         mov     edx, [TASK_BASE]
  72.         mov     edx, [edx+TASKDATA.pid]
  73.         pushfd
  74.         cli
  75. ;--------------------------------------
  76. align 4
  77. set_event:                                         ;; INTERNAL use !!! don't use for Call
  78. ;info:
  79. ;   Áåðåì íîâûé event èç FreeEvents, çàïîëíÿåì åãî ïîëÿ, êàê óêàçàíî â ecx,edx,esi
  80. ;   è óñòàíàâëèâàåì â ñïèñîê, óêàçàííûé â ebx.
  81. ;   Âîçâðàùàåì ñàì event (â eax), è åãî uid (â edx)
  82. ;param:
  83. ;   ebx - start-chain "virtual" event for entry new event Right of him
  84. ;   ecx - flags      (copied to EVENT.state)
  85. ;   edx - pid        (copied to EVENT.pid)
  86. ;   esi - event data (copied to EVENT.code indirect, =0 => skip)
  87. ;retval:
  88. ;   eax - event (=0 => fail)
  89. ;   edx - uid
  90. ;scratched: ebx,ecx,esi,edi
  91.         mov     eax, FreeEvents
  92.         cmp     eax, [eax+EVENT.fd]
  93.         jne     @f  ; not empty ???
  94.         pushad
  95.         call    init_events
  96.         popad
  97.         jz      RemoveEventTo.break ; POPF+RET
  98. ;--------------------------------------
  99. align 4
  100. @@:
  101.         mov     eax, [eax+EVENT.fd]
  102.         mov     [eax+EVENT.magic], 'EVNT'
  103.         mov     [eax+EVENT.destroy], destroy_event.internal
  104.         mov     [eax+EVENT.state], ecx
  105.         mov     [eax+EVENT.pid], edx
  106.         inc     [event_uid]
  107.         Mov     [eax+EVENT.id],edx,[event_uid]
  108.         or      esi, esi
  109.         jz      RemoveEventTo
  110.         lea     edi, [eax+EVENT.code]
  111.         mov     ecx, (sizeof.EVENT -EVENT.code)/4
  112.         cld
  113.         rep movsd
  114. ;--------------------------------------
  115. align 4
  116. RemoveEventTo:                                     ;; INTERNAL use !!! don't use for Call
  117. ;param:
  118. ;   eax - óêàçàòåëü íà event, ÊÎÒÎÐÛÉ âñòàâëÿåì
  119. ;   ebx - óêàçàòåëü íà event, ÏÎÑËÅ êîòîðîãî âñòàâëÿåì
  120. ;scratched: ebx,ecx
  121.         mov     ecx, eax             ; ecx=eax=Self,      ebx=NewLeft
  122.         xchg    ecx, [ebx+EVENT.fd]  ; NewLeft.fd=Self,   ecx=NewRight
  123.         cmp     eax, ecx             ; ñòîï, ñåáå äóìàþ...
  124.         je      .break               ; - à íå äóðàê ëè ÿ?
  125.         mov     [ecx+EVENT.bk], eax  ; NewRight.bk=Self
  126.         xchg    ebx, [eax+EVENT.bk]  ; Self.bk=NewLeft,   ebx=OldLeft
  127.         xchg    ecx, [eax+EVENT.fd]  ; Self.fd=NewRight,  ecx=OldRight
  128.         mov     [ebx+EVENT.fd], ecx  ; OldLeft.fd=OldRight
  129.         mov     [ecx+EVENT.bk], ebx  ; OldRight.bk=OldLeft
  130. ;--------------------------------------
  131. align 4
  132. .break:
  133.         popfd
  134.         ret
  135. ;-----------------------------------------------------------------------------
  136. align 4
  137. NotDummyTest:                                      ;; INTERNAL use (not returned for fail !!!)
  138.         pop     edi
  139.         call    DummyTest ; not returned for fail !!!
  140.         mov     ebx, eax
  141.         mov     eax, [ebx+EVENT.pid]
  142.         push    edi
  143. ;--------------------------------------
  144. align 4
  145. .small: ; êðèâî êàê-òî...
  146.         pop     edi
  147.         pushfd
  148.         cli
  149.         call    pid_to_slot ; saved all registers (eax - retval)
  150.         shl     eax, 8
  151.         jz      RemoveEventTo.break ; POPF+RET
  152.         jmp     edi ; øòàòíûé âîçâðàò
  153. ;-----------------------------------------------------------------------------
  154. align 4
  155. raise_event:                                       ;; EXPORT use
  156. ;info:
  157. ;   Óñòàíàâëèâàåì äàííûå EVENT.code
  158. ;   Åñëè òàì ôëàã EVENT_SIGNALED óæå àêòèâåí - áîëüøå íè÷åãî
  159. ;   Èíà÷å: ýòîò ôëàã âçâîäèòñÿ, çà èñêëþ÷åíèåì ñëó÷àÿ íàëè÷èÿ ôëàãà EVENT_WATCHED â edx
  160. ;    ýòîì ñëó÷àå EVENT_SIGNALED âçâîäèòñÿ ëèøü ïðè íàëè÷èå EVENT_WATCHED â ñàìîì ñîáûòèè
  161. ;param:
  162. ;   eax - event
  163. ;   ebx - uid (for Dummy testing)
  164. ;   edx - flags
  165. ;   esi - event data (=0 => skip)
  166. ;scratched: ebx,ecx,esi,edi
  167.         call    NotDummyTest ; not returned for fail !!!
  168.         or      esi, esi
  169.         jz      @f
  170.         lea     edi, [ebx+EVENT.code]
  171.         mov     ecx, (sizeof.EVENT -EVENT.code)/4
  172.         cld
  173.         rep movsd
  174. ;--------------------------------------
  175. align 4
  176. @@:
  177.         test    byte[ebx+EVENT.state+3], EVENT_SIGNALED shr 24
  178.         jnz     RemoveEventTo.break  ; POPF+RET
  179.         bt      edx, 28 ;EVENT_WATCHED
  180.         jnc     @f
  181.         test    byte[ebx+EVENT.state+3], EVENT_WATCHED shr 24
  182.         jz      RemoveEventTo.break  ; POPF+RET
  183. ;--------------------------------------
  184. align 4
  185. @@:
  186.         or      byte[ebx+EVENT.state+3], EVENT_SIGNALED shr 24
  187.         add     eax, SLOT_BASE+APP_EV_OFFSET
  188.         xchg    eax, ebx
  189.         jmp     RemoveEventTo
  190. ;-----------------------------------------------------------------------------
  191. align 4
  192. clear_event:                                       ;; EXPORT use
  193. ;info:
  194. ;
  195. ;param:
  196. ;   eax - event
  197. ;   ebx - uid (for Dummy testing)
  198. ;scratched: ebx,ecx
  199.         call    NotDummyTest ; not returned for fail !!!
  200.         add     eax, SLOT_BASE+APP_OBJ_OFFSET
  201.         and     byte[ebx+EVENT.state+3], not((EVENT_SIGNALED+EVENT_WATCHED)shr 24)
  202.         xchg    eax, ebx
  203.         jmp     RemoveEventTo
  204. ;-----------------------------------------------------------------------------
  205. align 4
  206. send_event:                                        ;; EXPORT use
  207. ;info:
  208. ;   Ñîçäàåò íîâûé EVENT (âûòàñêèâàåò èç ñïèñêà FreeEvents) â ñïèñêå EventList
  209. ;   öåëåâîãî ñëîòà (eax=pid), ñ äàííûìè èç esi êîñâåííî, è state=EVENT_SIGNALED
  210. ;param:
  211. ;   eax - slots pid, to sending new event
  212. ;   esi - pointer to sending data (in code field of new event)
  213. ;retval:
  214. ;   eax - event (=0 => fail)
  215. ;   edx - uid
  216. ;warning:
  217. ;   may be used as CDECL with such prefix...
  218. ;       mov     esi,[esp+8]
  219. ;       mov     eax,[esp+4]
  220. ;   but not as STDCALL :(
  221. ;scratched: ebx,ecx,esi,edi
  222.         mov     edx, eax
  223.         call    NotDummyTest.small ; not returned for fail !!!
  224.         lea     ebx, [eax+SLOT_BASE+APP_EV_OFFSET]
  225.         mov     ecx, EVENT_SIGNALED
  226.         jmp     set_event
  227. ;-----------------------------------------------------------------------------
  228. align 4
  229. DummyTest:                                         ;; INTERNAL use (not returned for fail !!!)
  230. ;param:
  231. ;   eax - event
  232. ;   ebx - uid (for Dummy testing)
  233.         cmp     [eax+EVENT.magic], 'EVNT'
  234.         jne     @f
  235.         cmp     [eax+EVENT.id], ebx
  236.         je      .ret
  237. ;--------------------------------------
  238. align 4
  239. @@:
  240.         pop     eax
  241.         xor     eax, eax
  242. ;--------------------------------------
  243. align 4
  244. .ret:
  245.         ret
  246. ;-----------------------------------------------------------------------------
  247. align 4
  248. Wait_events:
  249.         or      ebx, -1; infinite timeout
  250. ;--------------------------------------
  251. align 4
  252. Wait_events_ex:
  253. ;info:
  254. ;   Îæèäàíèå "àáñòðàêòíîãî" ñîáûòèÿ ÷åðåç ïåðåâîä ñëîòà â 5-þ ïîçèöèþ.
  255. ;   Àáñòðàêòíîñòü çàêëþ÷åíà â òîì, ÷òî ôàêò ñîáûòèÿ îïðåäåëÿåòñÿ ôóíêöèåé APPDATA.wait_test,
  256. ;   êîòîðàÿ çàäàåòñÿ êëèåíòîì è ìîæåò áûòü ôàêòè÷åñêè ëþáîé.
  257. ;   Ýòî ïîçâîëÿåò shed-ó íàäåæíî îïðåäåëèòü ôàêò ñîáûòèÿ, è íå ñîâåðøàòü "õîëîñòûõ" ïåðåêëþ÷åíèé,
  258. ;   ïðåäíàçíà÷åííûõ äëÿ ðàçáîðîê òèïà "ñâîé/÷óæîé" âíóòðè çàäà÷è.
  259. ;param:
  260. ;   edx - wait_test, êëèåíòñêàÿ ô-ÿ òåñòèðîâàíèÿ (àäðåñ êîäà)
  261. ;   ecx - wait_param, äîïîëíèòåëüíûé ïàðàìåòð, âîçìîæíî íåîáõîäèìûé äëÿ [wait_test]
  262. ;   ebx - wait_timeout
  263. ;retval:
  264. ;   eax - ðåçóëüòàò âûçîâà [wait_test] (=0 => timeout)
  265. ;scratched: esi
  266.         mov     esi, [current_slot]
  267.         mov     [esi+APPDATA.wait_param], ecx
  268.         pushad
  269.         mov     ebx, esi;ïîêà ýòî âîïðîñ, ÷åãî êóäû ñóâàòü..........
  270.         pushfd  ; ýòî ñëåäñòâèå îáùåé êîíöåïöèè: ïóñòü ô-ÿ òåñòèðîâàíèÿ èìååò
  271.         cli     ; ïðàâî ðàññ÷èòûâàòü íà çàêðûòûå ïðåðûâàíèÿ, êàê ïðè âûçîâå èç shed
  272.         call    edx
  273.         popfd
  274.         mov     [esp+28], eax
  275.         popad
  276.         or      eax, eax
  277.         jnz     @f   ;RET
  278.         mov     [esi+APPDATA.wait_test], edx
  279.         mov     [esi+APPDATA.wait_timeout], ebx
  280.         Mov     [esi+APPDATA.wait_begin],eax,[timer_ticks]
  281.         mov     eax, [TASK_BASE]
  282.         mov     [eax+TASKDATA.state], 5
  283.         call    change_task
  284.         mov     eax, [esi+APPDATA.wait_param]
  285. ;--------------------------------------
  286. align 4
  287. @@:
  288.         ret
  289. ;-----------------------------------------------------------------------------
  290. align 4
  291. wait_event:                                        ;; EXPORT use
  292. ;info:
  293. ;   Îæèäàíèå ôëàãà EVENT_SIGNALED â ñîâåðøåííî êîíêðåòíîì Event
  294. ;   (óñòàíàâëèâàåìîãî, íàäî ïîëàãàòü, ÷åðåç raise_event)
  295. ;   Ïðè àêòèâíîì ôëàãå MANUAL_RESET - áîëüøå íè÷åãî
  296. ;   Èíà÷å: ôëàãè EVENT_SIGNALED è EVENT_WATCHED ó ïîëó÷åííîãî ñîáûòèÿ ñáðàñûâàþòñÿ,
  297. ;   è, ïðè àêòèâíîì MANUAL_DESTROY - ïåðåìåùàåòñÿ â ñïèñîê ObjList òåêóùåãî ñëîòà,
  298. ;   à ïðè íå àêòèâíîì - óíè÷òîæàåòñÿ øòàòíî (destroy_event.internal)
  299. ;param:
  300. ;   eax - event
  301. ;   ebx - uid (for Dummy testing)
  302. ;scratched: ecx,edx,esi
  303.         call    DummyTest
  304.         mov     ecx, eax             ; wait_param
  305.         mov     edx, get_event_alone ; wait_test
  306.         call    Wait_events          ; timeout ignored
  307.         jmp     wait_finish
  308. ;-----------------------------------------------------------------------------
  309. align 4
  310. wait_event_timeout:
  311. ;param:
  312. ;   eax - event
  313. ;   ebx - uid (for Dummy testing)
  314. ;   ecx - timeout in timer ticks
  315. ;retval:
  316. ;   eax - EVENT handle or 0 if timeout
  317.         call    DummyTest
  318.         mov     ebx, ecx
  319.         mov     ecx, eax             ; wait_param
  320.         mov     edx, get_event_alone ; wait_test
  321.         call    Wait_events_ex
  322.         test    eax, eax
  323.         jnz     wait_finish
  324.         ret
  325. ;-----------------------------------------------------------------------------
  326. align 4
  327. get_event_ex:                                      ;; f68:14
  328. ;info:
  329. ;   Îæèäàíèå ëþáîãî ñîáûòèÿ â î÷åðåäè EventList òåêóùåãî ñëîòà
  330. ;   Äàííûå ñîáûòèÿ code - êîïèðóþòñÿ â ïàìÿòü ïðèëîæåíèÿ (êîñâåííî ïî edi)
  331. ;   Ïðè àêòèâíîì ôëàãå MANUAL_RESET - áîëüøå íè÷åãî
  332. ;   Èíà÷å: ôëàãè EVENT_SIGNALED è EVENT_WATCHED ó ïîëó÷åííîãî ñîáûòèÿ ñáðàñûâàþòñÿ,
  333. ;   è, ïðè àêòèâíîì MANUAL_DESTROY - ïåðåìåùàåòñÿ â ñïèñîê ObjList òåêóùåãî ñëîòà,
  334. ;   à ïðè íå àêòèâíîì - óíè÷òîæàåòñÿ øòàòíî (destroy_event.internal)
  335. ;param:
  336. ;   edi - àäðåñ â êîäå ïðèëîæåíèÿ äëÿ êîïèðîâàíèÿ äàííûõ èç EVENT.code
  337. ;retval:
  338. ;   eax - ñîáñòâåííî EVENT (áóäåì íàçûâàòü ýòî åãî õýíäëîì)
  339. ;scratched: ebx,ecx,edx,esi,edi
  340.         mov     edx, get_event_queue ; wait_test
  341.         call    Wait_events          ; timeout ignored
  342.         lea     esi, [eax+EVENT.code]
  343.         mov     ecx, (sizeof.EVENT-EVENT.code)/4
  344.         cld
  345.         rep movsd
  346.         mov     byte[edi-(sizeof.EVENT-EVENT.code)+2], cl;clear priority field
  347. ;--------------------------------------
  348. align 4
  349. wait_finish:
  350.         test    byte[eax+EVENT.state+3], MANUAL_RESET shr 24
  351.         jnz     get_event_queue.ret  ; RET
  352.         and     byte[eax+EVENT.state+3], not((EVENT_SIGNALED+EVENT_WATCHED)shr 24)
  353.         test    byte[eax+EVENT.state+3], MANUAL_DESTROY shr 24
  354.         jz      destroy_event.internal
  355.         mov     ebx, [current_slot]
  356.         add     ebx, APP_OBJ_OFFSET
  357.         pushfd
  358.         cli
  359.         jmp     RemoveEventTo
  360. ;-----------------------------------------------------------------------------
  361. align 4
  362. destroy_event:                                     ;; EXPORT use
  363. ;info:
  364. ;   Ïåðåíîñèì EVENT â ñïèñîê FreeEvents, ÷èñòèì ïîëÿ magic,destroy,pid,id
  365. ;param:
  366. ;   eax - event
  367. ;   ebx - uid (for Dummy testing)
  368. ;retval:
  369. ;   eax - àäðåñ îáúåêòà EVENT (=0 => fail)
  370. ;scratched: ebx,ecx
  371.         call    DummyTest ; not returned for fail !!!
  372. ;--------------------------------------
  373. align 4
  374. .internal:
  375.         xor     ecx, ecx  ; clear common header
  376.         pushfd
  377.         cli
  378.         mov     [eax+EVENT.magic], ecx
  379.         mov     [eax+EVENT.destroy], ecx
  380.         mov     [eax+EVENT.pid], ecx
  381.         mov     [eax+EVENT.id], ecx
  382.         mov     ebx, FreeEvents
  383.         jmp     RemoveEventTo
  384. ;-----------------------------------------------------------------------------
  385. align 4
  386. get_event_queue:
  387. ;info:
  388. ;   êëèåíòñêàÿ ô-ÿ òåñòèðîâàíèÿ äëÿ get_event_ex
  389. ;warning:
  390. ;  -don't use [TASK_BASE],[current_slot],[CURRENT_TASK] - it is not for your slot
  391. ;  -may be assumed, that interrupt are disabled
  392. ;  -it is not restriction for scratched registers
  393. ;param:
  394. ;   ebx - àäðåñ APPDATA ñëîòà òåñòèðîâàíèÿ
  395. ;retval:
  396. ;   eax - àäðåñ îáúåêòà EVENT (=0 => fail)
  397.         add     ebx, APP_EV_OFFSET
  398.         mov     eax, [ebx+APPOBJ.bk] ; âûáèðàåì ñ êîíöà, ïî ïðèíöèïó FIFO
  399.         cmp     eax, ebx ; empty ???
  400.         je      get_event_alone.ret0
  401. ;--------------------------------------
  402. align 4
  403. .ret:
  404.         ret
  405. ;-----------------------------------------------------------------------------
  406. align 4
  407. get_event_alone:
  408. ;info:
  409. ;   êëèåíòñêàÿ ô-ÿ òåñòèðîâàíèÿ äëÿ wait_event
  410. ;warning:
  411. ;  -don't use [TASK_BASE],[current_slot],[CURRENT_TASK] - it is not for your slot
  412. ;  -may be assumed, that interrupt are disabled
  413. ;  -it is not restriction for scratched registers
  414. ;param:
  415. ;   ebx - àäðåñ APPDATA ñëîòà òåñòèðîâàíèÿ
  416. ;retval:
  417. ;   eax - àäðåñ îáúåêòà EVENT (=0 => fail)
  418.         mov     eax, [ebx+APPDATA.wait_param]
  419.         test    byte[eax+EVENT.state+3], EVENT_SIGNALED shr 24
  420.         jnz     .ret
  421.         or      byte[eax+EVENT.state+3], EVENT_WATCHED shr 24
  422. ;--------------------------------------
  423. align 4
  424. .ret0:
  425.         xor     eax, eax; NO event!!!
  426. ;--------------------------------------
  427. align 4
  428. .ret:
  429.         ret
  430. ;-----------------------------------------------------------------------------
  431. align 4
  432. sys_sendwindowmsg:                                 ;; f72
  433.         dec     ebx
  434.         jnz     .ret ;subfunction==1 ?
  435.         pushfd
  436.         cli
  437.         sub     ecx, 2
  438.         je      .sendkey
  439.         dec     ecx
  440.         jnz     .retf
  441. ;--------------------------------------
  442. align 4
  443. .sendbtn:
  444.         cmp     byte[BTN_COUNT], 1
  445.         jae     .result ;overflow
  446.         inc     byte[BTN_COUNT]
  447.         shl     edx, 8
  448.         mov     [BTN_BUFF], edx
  449.         jmp     .result
  450. ;--------------------------------------
  451. align 4
  452. .sendkey:
  453.         movzx   eax, byte[KEY_COUNT]
  454.         cmp     al, 120
  455.         jae     .result ;overflow
  456.         inc     byte[KEY_COUNT]
  457.         mov     [KEY_COUNT+1+eax], dl
  458. ;--------------------------------------
  459. align 4
  460. .result:
  461.         setae   byte[esp+32+4] ;ñ÷èòàåì, ÷òî èñõîäíî: dword[esp+32+4]==72
  462. ;--------------------------------------
  463. align 4
  464. .retf:
  465.         popfd
  466. ;--------------------------------------
  467. align 4
  468. .ret:
  469.         ret
  470. ;-----------------------------------------------------------------------------
  471. align 4
  472. sys_getevent:                                      ;; f11
  473.         mov     ebx, [current_slot];ïîêà ýòî âîïðîñ, ÷åãî êóäû ñóâàòü..........
  474.         pushfd  ; ýòî ñëåäñòâèå îáùåé êîíöåïöèè: ïóñòü ô-ÿ òåñòèðîâàíèÿ èìååò
  475.         cli     ; ïðàâî ðàññ÷èòûâàòü íà çàêðûòûå ïðåðûâàíèÿ, êàê ïðè âûçîâå èç shed
  476.         call    get_event_for_app
  477.         popfd
  478.         mov     [esp+32], eax
  479.         ret
  480. ;-----------------------------------------------------------------------------
  481. align 4
  482. sys_waitforevent:                                  ;; f10
  483.         or      ebx, -1; infinite timeout
  484. ;--------------------------------------
  485. align 4
  486. sys_wait_event_timeout:                            ;; f23
  487.         call    unprotect_from_terminate
  488.         mov     edx, get_event_for_app; wait_test
  489.         call    Wait_events_ex        ; ebx - timeout
  490.         mov     [esp+32], eax
  491.         call    protect_from_terminate
  492.         ret
  493. ;-----------------------------------------------------------------------------
  494. align 4
  495. get_event_for_app:                                 ;; used from f10,f11,f23
  496. ;info:
  497. ;   êëèåíòñêàÿ ô-ÿ òåñòèðîâàíèÿ äëÿ ïðèëîæåíèé (f10,f23)
  498. ;warning:
  499. ;  -don't use [TASK_BASE],[current_slot],[CURRENT_TASK] - it is not for your slot
  500. ;  -may be assumed, that interrupt are disabled
  501. ;  -it is not restriction for scratched registers
  502. ;param:
  503. ;   ebx - àäðåñ APPDATA ñëîòà òåñòèðîâàíèÿ
  504. ;retval:
  505. ;   eax - íîìåð ñîáûòèÿ (=0 => no events)
  506.         movzx   edi, bh               ; bh  is assumed as [CURRENT_TASK]
  507.         shl     edi, 5
  508.         add     edi, CURRENT_TASK     ; edi is assumed as [TASK_BASE]
  509.         mov     ecx, [edi+TASKDATA.event_mask]
  510.         and     ecx, 0x7FFFFFFF
  511. ;--------------------------------------
  512. align 4
  513. .loop: ; ïîêà íå èñ÷åðïàåì âñå áèòû ìàñêè
  514.         bsr     eax, ecx       ; íàõîäèì íåíóëåâîé áèò ìàñêè (31 -> 0)
  515.         jz      .no_events     ; èñ÷åðïàëè âñå áèòû ìàñêè, íî íè÷åãî íå íàøëè ???
  516.         btr     ecx, eax       ; ñáðàñûâàåì ïðîâåðÿåìûé áèò ìàñêè
  517.        ; ïåðåõîäèì íà îáðàáîò÷èê ýòîãî (eax) áèòà
  518.         cmp     eax, 9
  519.         jae     .loop          ; eax=[9..31], ignored (event 10...32)
  520.  
  521.         cmp     eax, 3
  522.         je      .loop          ; eax=3, ignored (event 4)
  523.  
  524.         cmp     eax, 4
  525.         je      .FlagAutoReset  ; eax=4, retvals=eax+1 (event 5)
  526.  
  527.         cmp     eax, 5
  528.         je      .mouse_check  ; eax=5, retvals=eax+1 (event 6)
  529.  
  530.         ja      .FlagAutoReset ; eax=[6..8], retvals=eax+1 (event 7...9)
  531.  
  532.         cmp     eax, 1
  533.         jae     .BtKy          ; eax=[1,2],  retvals=eax+1 (event 2,3)
  534. ;--------------------------------------
  535. align 4
  536. .WndRedraw:                    ; eax=0, retval WndRedraw=1
  537.         cmp     [edi-twdw+WDATA.fl_redraw], al;al==0
  538.         jne     .result
  539.         jmp     .loop
  540. ;--------------------------------------
  541. align 4
  542. .no_events:
  543.         xor     eax, eax
  544.         ret
  545. ;--------------------------------------
  546. align 4
  547. .mouse_check:    ; Mouse 5+1=6
  548.         push    eax
  549.         mov     eax, [TASK_BASE]
  550.         mov     eax, [eax + TASKDATA.event_mask]
  551.         test    eax, 0x80000000 ; bit 31: active/inactive filter f.40
  552.         jz      @f
  553.         pop     eax
  554.         jmp     .FlagAutoReset
  555. ;--------------------------------------
  556. align 4
  557. @@:
  558. ; If the window is captured and moved by the user, then no mouse events!!!
  559.         mov     al, [mouse.active_sys_window.action]
  560.         and     al, WINDOW_MOVE_AND_RESIZE_FLAGS
  561.         test    al, al
  562.         pop     eax
  563.         jnz     .loop
  564. ;--------------------------------------
  565. align 4
  566. .FlagAutoReset: ; retvals: BgrRedraw=5, IPC=7, Stack=8, Debug=9
  567.         btr     [ebx+APPDATA.event_mask], eax
  568.         jnc     .loop
  569. ;--------------------------------------
  570. align 4
  571. .result:      ; retval = eax+1
  572.         inc     eax
  573.         ret
  574. ;--------------------------------------
  575. align 4
  576. .BtKy:
  577.         movzx   edx, bh
  578.         movzx   edx, word[WIN_STACK+edx*2]
  579.         je      .Keys          ; eax=1, retval Keys=2
  580. ;--------------------------------------
  581. align 4
  582. .Buttons:                      ; eax=2, retval Buttons=3
  583.         cmp     byte[BTN_COUNT], 0
  584.         je      .loop          ; empty ???
  585.         cmp     edx, [TASK_COUNT]
  586.         jne     .loop          ; not Top ???
  587.         mov     edx, [BTN_BUFF]
  588.         shr     edx, 8
  589.         cmp     edx, 0xFFFF    ;-ID for Minimize-Button of Form
  590.         jne     .result
  591.         mov     [window_minimize], 1
  592.         call    wakeup_osloop
  593.         dec     byte[BTN_COUNT]
  594.         jmp     .loop
  595. ;--------------------------------------
  596. align 4
  597. .Keys:    ; eax==1
  598.         cmp     edx, [TASK_COUNT]
  599.         jne     @f             ; not Top ???
  600.         cmp     [KEY_COUNT], al; al==1
  601.         jae     .result        ; not empty ???
  602. ;--------------------------------------
  603. align 4
  604. @@:
  605.         mov     edx, hotkey_buffer
  606. ;--------------------------------------
  607. align 4
  608. @@:
  609.         cmp     [edx], bh      ; bh - slot for testing
  610.         je      .result
  611.         add     edx, 8
  612.         cmp     edx, hotkey_buffer+120*8
  613.         jb      @b
  614.         jmp     .loop
  615. ;end.
  616. ;-----------------------------------------------------------------------------
  617.