Subversion Repositories Kolibri OS

Rev

Rev 3451 | Rev 3534 | Go to most recent revision | Blame | Compare with Previous | Last modification | View Log | Download | RSS feed

  1. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  2. ;;                                                              ;;
  3. ;; Copyright (C) KolibriOS team 2004-2012. All rights reserved. ;;
  4. ;; Copyright (C) MenuetOS 2000-2004 Ville Mikael Turjanmaa      ;;
  5. ;; Distributed under terms of the GNU General Public License    ;;
  6. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  7.  
  8. $Revision: 3481 $
  9.  
  10. WINDOW_MOVE_AND_RESIZE_FLAGS = \
  11.   mouse.WINDOW_RESIZE_N_FLAG + \
  12.   mouse.WINDOW_RESIZE_W_FLAG + \
  13.   mouse.WINDOW_RESIZE_S_FLAG + \
  14.   mouse.WINDOW_RESIZE_E_FLAG + \
  15.   mouse.WINDOW_MOVE_FLAG
  16.  
  17. uglobal
  18. align 4
  19.   event_start   dd ?
  20.   event_end     dd ?
  21.   event_uid     dd 0
  22. endg
  23. EV_SPACE   = 512
  24. FreeEvents = event_start-EVENT.fd    ; "âèðòóàëüíûé" event, èñïîëüçóþòñÿ òîëüêî ïîëÿ:
  25.                                      ;  FreeEvents.fd=event_start è FreeEvents.bk=event_end
  26. ;-----------------------------------------------------------------------------
  27. align 4
  28. init_events:                                       ;; used from kernel.asm
  29.         stdcall kernel_alloc, EV_SPACE*sizeof.EVENT
  30.         or      eax, eax
  31.         jz      .fail
  32.       ; eax - current event, ebx - previos event below
  33.         mov     ecx, EV_SPACE        ; current - in allocated space
  34.         mov     ebx, FreeEvents      ; previos - íà÷àëî ñïèñêà
  35.         push    ebx                  ; îíî æå è êîíåö ïîòîì áóäåò
  36. ;--------------------------------------
  37. align 4
  38. @@:
  39.         mov     [ebx+EVENT.fd], eax
  40.         mov     [eax+EVENT.bk], ebx
  41.         mov     ebx, eax             ; previos <- current
  42.         add     eax, sizeof.EVENT    ; new current
  43.         loop    @b
  44.         pop     eax                  ; âîò îíî êîíöîì è ñòàëî
  45.         mov     [ebx+EVENT.fd], eax
  46.         mov     [eax+EVENT.bk], ebx
  47. ;--------------------------------------
  48. align 4
  49. .fail:
  50.         ret
  51. ;-----------------------------------------------------------------------------
  52. EVENT_WATCHED    equ 0x10000000 ;áèò 28
  53. EVENT_SIGNALED   equ 0x20000000 ;áèò 29
  54. MANUAL_RESET     equ 0x40000000 ;áèò 30
  55. MANUAL_DESTROY   equ 0x80000000 ;áèò 31
  56. ;-----------------------------------------------------------------------------
  57. align 4
  58. create_event:                                      ;; EXPORT use
  59. ;info:
  60. ;   Ïåðåíîñèì EVENT èç ñïèñêà FreeEvents â ñïèñîê ObjList òåêóùåãî ñëîòà
  61. ;   EVENT.state óñòàíàâëèâàåì èç ecx, EVENT.code êîñâåííî èç esi (åñëè esi<>0)
  62. ;param:
  63. ;   esi - event data
  64. ;   ecx - flags
  65. ;retval:
  66. ;   eax - event (=0 => fail)
  67. ;   edx - uid
  68. ;scratched: ebx,ecx,esi,edi
  69.         mov     ebx, [current_slot]
  70.         add     ebx, APP_OBJ_OFFSET
  71.         mov     edx, [TASK_BASE]
  72.         mov     edx, [edx+TASKDATA.pid]
  73.         pushfd
  74.         cli
  75. ;--------------------------------------
  76. align 4
  77. set_event:                                         ;; INTERNAL use !!! don't use for Call
  78. ;info:
  79. ;   Áåðåì íîâûé event èç FreeEvents, çàïîëíÿåì åãî ïîëÿ, êàê óêàçàíî â ecx,edx,esi
  80. ;   è óñòàíàâëèâàåì â ñïèñîê, óêàçàííûé â ebx.
  81. ;   Âîçâðàùàåì ñàì event (â eax), è åãî uid (â edx)
  82. ;param:
  83. ;   ebx - start-chain "virtual" event for entry new event Right of him
  84. ;   ecx - flags      (copied to EVENT.state)
  85. ;   edx - pid        (copied to EVENT.pid)
  86. ;   esi - event data (copied to EVENT.code indirect, =0 => skip)
  87. ;retval:
  88. ;   eax - event (=0 => fail)
  89. ;   edx - uid
  90. ;scratched: ebx,ecx,esi,edi
  91.         mov     eax, FreeEvents
  92.         cmp     eax, [eax+EVENT.fd]
  93.         jne     @f  ; not empty ???
  94.         pushad
  95.         call    init_events
  96.         popad
  97.         jz      RemoveEventTo.break ; POPF+RET
  98. ;--------------------------------------
  99. align 4
  100. @@:
  101.         mov     eax, [eax+EVENT.fd]
  102.         mov     [eax+EVENT.magic], 'EVNT'
  103.         mov     [eax+EVENT.destroy], destroy_event.internal
  104.         mov     [eax+EVENT.state], ecx
  105.         mov     [eax+EVENT.pid], edx
  106.         inc     [event_uid]
  107.         Mov     [eax+EVENT.id],edx,[event_uid]
  108.         or      esi, esi
  109.         jz      RemoveEventTo
  110.         lea     edi, [eax+EVENT.code]
  111.         mov     ecx, (sizeof.EVENT -EVENT.code)/4
  112.         cld
  113.         rep movsd
  114. ;--------------------------------------
  115. align 4
  116. RemoveEventTo:                                     ;; INTERNAL use !!! don't use for Call
  117. ;param:
  118. ;   eax - óêàçàòåëü íà event, ÊÎÒÎÐÛÉ âñòàâëÿåì
  119. ;   ebx - óêàçàòåëü íà event, ÏÎÑËÅ êîòîðîãî âñòàâëÿåì
  120. ;scratched: ebx,ecx
  121.         mov     ecx, eax             ; ecx=eax=Self,      ebx=NewLeft
  122.         xchg    ecx, [ebx+EVENT.fd]  ; NewLeft.fd=Self,   ecx=NewRight
  123.         cmp     eax, ecx             ; ñòîï, ñåáå äóìàþ...
  124.         je      .break               ; - à íå äóðàê ëè ÿ?
  125.         mov     [ecx+EVENT.bk], eax  ; NewRight.bk=Self
  126.         xchg    ebx, [eax+EVENT.bk]  ; Self.bk=NewLeft,   ebx=OldLeft
  127.         xchg    ecx, [eax+EVENT.fd]  ; Self.fd=NewRight,  ecx=OldRight
  128.         mov     [ebx+EVENT.fd], ecx  ; OldLeft.fd=OldRight
  129.         mov     [ecx+EVENT.bk], ebx  ; OldRight.bk=OldLeft
  130. ;--------------------------------------
  131. align 4
  132. .break:
  133.         popfd
  134.         ret
  135. ;-----------------------------------------------------------------------------
  136. align 4
  137. NotDummyTest:                                      ;; INTERNAL use (not returned for fail !!!)
  138.         pop     edi
  139.         call    DummyTest ; not returned for fail !!!
  140.         mov     ebx, eax
  141.         mov     eax, [ebx+EVENT.pid]
  142.         push    edi
  143. ;--------------------------------------
  144. align 4
  145. .small: ; êðèâî êàê-òî...
  146.         pop     edi
  147.         pushfd
  148.         cli
  149.         call    pid_to_slot ; saved all registers (eax - retval)
  150.         shl     eax, 8
  151.         jz      RemoveEventTo.break ; POPF+RET
  152.         jmp     edi ; øòàòíûé âîçâðàò
  153. ;-----------------------------------------------------------------------------
  154. align 4
  155. raise_event:                                       ;; EXPORT use
  156. ;info:
  157. ;   Óñòàíàâëèâàåì äàííûå EVENT.code
  158. ;   Åñëè òàì ôëàã EVENT_SIGNALED óæå àêòèâåí - áîëüøå íè÷åãî
  159. ;   Èíà÷å: ýòîò ôëàã âçâîäèòñÿ, çà èñêëþ÷åíèåì ñëó÷àÿ íàëè÷èÿ ôëàãà EVENT_WATCHED â edx
  160. ;    ýòîì ñëó÷àå EVENT_SIGNALED âçâîäèòñÿ ëèøü ïðè íàëè÷èå EVENT_WATCHED â ñàìîì ñîáûòèè
  161. ;param:
  162. ;   eax - event
  163. ;   ebx - uid (for Dummy testing)
  164. ;   edx - flags
  165. ;   esi - event data (=0 => skip)
  166. ;scratched: ebx,ecx,esi,edi
  167.         call    NotDummyTest ; not returned for fail !!!
  168.         mov     [check_idle_semaphore], 5
  169.         or      esi, esi
  170.         jz      @f
  171.         lea     edi, [ebx+EVENT.code]
  172.         mov     ecx, (sizeof.EVENT -EVENT.code)/4
  173.         cld
  174.         rep movsd
  175. ;--------------------------------------
  176. align 4
  177. @@:
  178.         test    byte[ebx+EVENT.state+3], EVENT_SIGNALED shr 24
  179.         jnz     RemoveEventTo.break  ; POPF+RET
  180.         bt      edx, 28 ;EVENT_WATCHED
  181.         jnc     @f
  182.         test    byte[ebx+EVENT.state+3], EVENT_WATCHED shr 24
  183.         jz      RemoveEventTo.break  ; POPF+RET
  184. ;--------------------------------------
  185. align 4
  186. @@:
  187.         or      byte[ebx+EVENT.state+3], EVENT_SIGNALED shr 24
  188.         add     eax, SLOT_BASE+APP_EV_OFFSET
  189.         xchg    eax, ebx
  190.         jmp     RemoveEventTo
  191. ;-----------------------------------------------------------------------------
  192. align 4
  193. clear_event:                                       ;; EXPORT use
  194. ;info:
  195. ;
  196. ;param:
  197. ;   eax - event
  198. ;   ebx - uid (for Dummy testing)
  199. ;scratched: ebx,ecx
  200.         call    NotDummyTest ; not returned for fail !!!
  201.         add     eax, SLOT_BASE+APP_OBJ_OFFSET
  202.         and     byte[ebx+EVENT.state+3], not((EVENT_SIGNALED+EVENT_WATCHED)shr 24)
  203.         xchg    eax, ebx
  204.         jmp     RemoveEventTo
  205. ;-----------------------------------------------------------------------------
  206. align 4
  207. send_event:                                        ;; EXPORT use
  208. ;info:
  209. ;   Ñîçäàåò íîâûé EVENT (âûòàñêèâàåò èç ñïèñêà FreeEvents) â ñïèñêå EventList
  210. ;   öåëåâîãî ñëîòà (eax=pid), ñ äàííûìè èç esi êîñâåííî, è state=EVENT_SIGNALED
  211. ;param:
  212. ;   eax - slots pid, to sending new event
  213. ;   esi - pointer to sending data (in code field of new event)
  214. ;retval:
  215. ;   eax - event (=0 => fail)
  216. ;   edx - uid
  217. ;warning:
  218. ;   may be used as CDECL with such prefix...
  219. ;       mov     esi,[esp+8]
  220. ;       mov     eax,[esp+4]
  221. ;   but not as STDCALL :(
  222. ;scratched: ebx,ecx,esi,edi
  223.         mov     edx, eax
  224.         call    NotDummyTest.small ; not returned for fail !!!
  225.         lea     ebx, [eax+SLOT_BASE+APP_EV_OFFSET]
  226.         mov     ecx, EVENT_SIGNALED
  227.         jmp     set_event
  228. ;-----------------------------------------------------------------------------
  229. align 4
  230. DummyTest:                                         ;; INTERNAL use (not returned for fail !!!)
  231. ;param:
  232. ;   eax - event
  233. ;   ebx - uid (for Dummy testing)
  234.         cmp     [eax+EVENT.magic], 'EVNT'
  235.         jne     @f
  236.         cmp     [eax+EVENT.id], ebx
  237.         je      .ret
  238. ;--------------------------------------
  239. align 4
  240. @@:
  241.         pop     eax
  242.         xor     eax, eax
  243. ;--------------------------------------
  244. align 4
  245. .ret:
  246.         ret
  247. ;-----------------------------------------------------------------------------
  248. align 4
  249. Wait_events:
  250.         or      ebx, -1; infinite timeout
  251. ;--------------------------------------
  252. align 4
  253. Wait_events_ex:
  254. ;info:
  255. ;   Îæèäàíèå "àáñòðàêòíîãî" ñîáûòèÿ ÷åðåç ïåðåâîä ñëîòà â 5-þ ïîçèöèþ.
  256. ;   Àáñòðàêòíîñòü çàêëþ÷åíà â òîì, ÷òî ôàêò ñîáûòèÿ îïðåäåëÿåòñÿ ôóíêöèåé APPDATA.wait_test,
  257. ;   êîòîðàÿ çàäàåòñÿ êëèåíòîì è ìîæåò áûòü ôàêòè÷åñêè ëþáîé.
  258. ;   Ýòî ïîçâîëÿåò shed-ó íàäåæíî îïðåäåëèòü ôàêò ñîáûòèÿ, è íå ñîâåðøàòü "õîëîñòûõ" ïåðåêëþ÷åíèé,
  259. ;   ïðåäíàçíà÷åííûõ äëÿ ðàçáîðîê òèïà "ñâîé/÷óæîé" âíóòðè çàäà÷è.
  260. ;param:
  261. ;   edx - wait_test, êëèåíòñêàÿ ô-ÿ òåñòèðîâàíèÿ (àäðåñ êîäà)
  262. ;   ecx - wait_param, äîïîëíèòåëüíûé ïàðàìåòð, âîçìîæíî íåîáõîäèìûé äëÿ [wait_test]
  263. ;   ebx - wait_timeout
  264. ;retval:
  265. ;   eax - ðåçóëüòàò âûçîâà [wait_test] (=0 => timeout)
  266. ;scratched: esi
  267.         mov     esi, [current_slot]
  268.         mov     [esi+APPDATA.wait_param], ecx
  269.         pushad
  270.         mov     ebx, esi;ïîêà ýòî âîïðîñ, ÷åãî êóäû ñóâàòü..........
  271.         pushfd  ; ýòî ñëåäñòâèå îáùåé êîíöåïöèè: ïóñòü ô-ÿ òåñòèðîâàíèÿ èìååò
  272.         cli     ; ïðàâî ðàññ÷èòûâàòü íà çàêðûòûå ïðåðûâàíèÿ, êàê ïðè âûçîâå èç shed
  273.         call    edx
  274.         popfd
  275.         mov     [esp+28], eax
  276.         popad
  277.         or      eax, eax
  278.         jnz     @f   ;RET
  279.         mov     [esi+APPDATA.wait_test], edx
  280.         mov     [esi+APPDATA.wait_timeout], ebx
  281.         Mov     [esi+APPDATA.wait_begin],eax,[timer_ticks]
  282.         mov     eax, [TASK_BASE]
  283.         mov     [eax+TASKDATA.state], 5
  284.         call    change_task
  285.         mov     eax, [esi+APPDATA.wait_param]
  286. ;--------------------------------------
  287. align 4
  288. @@:
  289.         ret
  290. ;-----------------------------------------------------------------------------
  291. align 4
  292. wait_event:                                        ;; EXPORT use
  293. ;info:
  294. ;   Îæèäàíèå ôëàãà EVENT_SIGNALED â ñîâåðøåííî êîíêðåòíîì Event
  295. ;   (óñòàíàâëèâàåìîãî, íàäî ïîëàãàòü, ÷åðåç raise_event)
  296. ;   Ïðè àêòèâíîì ôëàãå MANUAL_RESET - áîëüøå íè÷åãî
  297. ;   Èíà÷å: ôëàãè EVENT_SIGNALED è EVENT_WATCHED ó ïîëó÷åííîãî ñîáûòèÿ ñáðàñûâàþòñÿ,
  298. ;   è, ïðè àêòèâíîì MANUAL_DESTROY - ïåðåìåùàåòñÿ â ñïèñîê ObjList òåêóùåãî ñëîòà,
  299. ;   à ïðè íå àêòèâíîì - óíè÷òîæàåòñÿ øòàòíî (destroy_event.internal)
  300. ;param:
  301. ;   eax - event
  302. ;   ebx - uid (for Dummy testing)
  303. ;scratched: ecx,edx,esi
  304.         call    DummyTest
  305.         mov     ecx, eax             ; wait_param
  306.         mov     edx, get_event_alone ; wait_test
  307.         call    Wait_events          ; timeout ignored
  308.         jmp     wait_finish
  309. ;-----------------------------------------------------------------------------
  310. align 4
  311. wait_event_timeout:
  312. ;param:
  313. ;   eax - event
  314. ;   ebx - uid (for Dummy testing)
  315. ;   ecx - timeout in timer ticks
  316. ;retval:
  317. ;   eax - EVENT handle or 0 if timeout
  318.         call    DummyTest
  319.         mov     ebx, ecx
  320.         mov     ecx, eax             ; wait_param
  321.         mov     edx, get_event_alone ; wait_test
  322.         call    Wait_events_ex
  323.         test    eax, eax
  324.         jnz     wait_finish
  325.         ret
  326. ;-----------------------------------------------------------------------------
  327. align 4
  328. get_event_ex:                                      ;; f68:14
  329. ;info:
  330. ;   Îæèäàíèå ëþáîãî ñîáûòèÿ â î÷åðåäè EventList òåêóùåãî ñëîòà
  331. ;   Äàííûå ñîáûòèÿ code - êîïèðóþòñÿ â ïàìÿòü ïðèëîæåíèÿ (êîñâåííî ïî edi)
  332. ;   Ïðè àêòèâíîì ôëàãå MANUAL_RESET - áîëüøå íè÷åãî
  333. ;   Èíà÷å: ôëàãè EVENT_SIGNALED è EVENT_WATCHED ó ïîëó÷åííîãî ñîáûòèÿ ñáðàñûâàþòñÿ,
  334. ;   è, ïðè àêòèâíîì MANUAL_DESTROY - ïåðåìåùàåòñÿ â ñïèñîê ObjList òåêóùåãî ñëîòà,
  335. ;   à ïðè íå àêòèâíîì - óíè÷òîæàåòñÿ øòàòíî (destroy_event.internal)
  336. ;param:
  337. ;   edi - àäðåñ â êîäå ïðèëîæåíèÿ äëÿ êîïèðîâàíèÿ äàííûõ èç EVENT.code
  338. ;retval:
  339. ;   eax - ñîáñòâåííî EVENT (áóäåì íàçûâàòü ýòî åãî õýíäëîì)
  340. ;scratched: ebx,ecx,edx,esi,edi
  341.         mov     edx, get_event_queue ; wait_test
  342.         call    Wait_events          ; timeout ignored
  343.         lea     esi, [eax+EVENT.code]
  344.         mov     ecx, (sizeof.EVENT-EVENT.code)/4
  345.         cld
  346.         rep movsd
  347.         mov     byte[edi-(sizeof.EVENT-EVENT.code)+2], cl;clear priority field
  348. ;--------------------------------------
  349. align 4
  350. wait_finish:
  351.         test    byte[eax+EVENT.state+3], MANUAL_RESET shr 24
  352.         jnz     get_event_queue.ret  ; RET
  353.         and     byte[eax+EVENT.state+3], not((EVENT_SIGNALED+EVENT_WATCHED)shr 24)
  354.         test    byte[eax+EVENT.state+3], MANUAL_DESTROY shr 24
  355.         jz      destroy_event.internal
  356.         mov     ebx, [current_slot]
  357.         add     ebx, APP_OBJ_OFFSET
  358.         pushfd
  359.         cli
  360.         jmp     RemoveEventTo
  361. ;-----------------------------------------------------------------------------
  362. align 4
  363. destroy_event:                                     ;; EXPORT use
  364. ;info:
  365. ;   Ïåðåíîñèì EVENT â ñïèñîê FreeEvents, ÷èñòèì ïîëÿ magic,destroy,pid,id
  366. ;param:
  367. ;   eax - event
  368. ;   ebx - uid (for Dummy testing)
  369. ;retval:
  370. ;   eax - àäðåñ îáúåêòà EVENT (=0 => fail)
  371. ;scratched: ebx,ecx
  372.         call    DummyTest ; not returned for fail !!!
  373. ;--------------------------------------
  374. align 4
  375. .internal:
  376.         xor     ecx, ecx  ; clear common header
  377.         pushfd
  378.         cli
  379.         mov     [eax+EVENT.magic], ecx
  380.         mov     [eax+EVENT.destroy], ecx
  381.         mov     [eax+EVENT.pid], ecx
  382.         mov     [eax+EVENT.id], ecx
  383.         mov     ebx, FreeEvents
  384.         jmp     RemoveEventTo
  385. ;-----------------------------------------------------------------------------
  386. align 4
  387. get_event_queue:
  388. ;info:
  389. ;   êëèåíòñêàÿ ô-ÿ òåñòèðîâàíèÿ äëÿ get_event_ex
  390. ;warning:
  391. ;  -don't use [TASK_BASE],[current_slot],[CURRENT_TASK] - it is not for your slot
  392. ;  -may be assumed, that interrupt are disabled
  393. ;  -it is not restriction for scratched registers
  394. ;param:
  395. ;   ebx - àäðåñ APPDATA ñëîòà òåñòèðîâàíèÿ
  396. ;retval:
  397. ;   eax - àäðåñ îáúåêòà EVENT (=0 => fail)
  398.         add     ebx, APP_EV_OFFSET
  399.         mov     eax, [ebx+APPOBJ.bk] ; âûáèðàåì ñ êîíöà, ïî ïðèíöèïó FIFO
  400.         cmp     eax, ebx ; empty ???
  401.         je      get_event_alone.ret0
  402. ;--------------------------------------
  403. align 4
  404. .ret:
  405.         ret
  406. ;-----------------------------------------------------------------------------
  407. align 4
  408. get_event_alone:
  409. ;info:
  410. ;   êëèåíòñêàÿ ô-ÿ òåñòèðîâàíèÿ äëÿ wait_event
  411. ;warning:
  412. ;  -don't use [TASK_BASE],[current_slot],[CURRENT_TASK] - it is not for your slot
  413. ;  -may be assumed, that interrupt are disabled
  414. ;  -it is not restriction for scratched registers
  415. ;param:
  416. ;   ebx - àäðåñ APPDATA ñëîòà òåñòèðîâàíèÿ
  417. ;retval:
  418. ;   eax - àäðåñ îáúåêòà EVENT (=0 => fail)
  419.         mov     eax, [ebx+APPDATA.wait_param]
  420.         test    byte[eax+EVENT.state+3], EVENT_SIGNALED shr 24
  421.         jnz     .ret
  422.         or      byte[eax+EVENT.state+3], EVENT_WATCHED shr 24
  423. ;--------------------------------------
  424. align 4
  425. .ret0:
  426.         xor     eax, eax; NO event!!!
  427. ;--------------------------------------
  428. align 4
  429. .ret:
  430.         ret
  431. ;-----------------------------------------------------------------------------
  432. align 4
  433. sys_sendwindowmsg:                                 ;; f72
  434.         dec     ebx
  435.         jnz     .ret ;subfunction==1 ?
  436.         pushfd
  437.         cli
  438.         sub     ecx, 2
  439.         je      .sendkey
  440.         dec     ecx
  441.         jnz     .retf
  442. ;--------------------------------------
  443. align 4
  444. .sendbtn:
  445.         cmp     byte[BTN_COUNT], 1
  446.         jae     .result ;overflow
  447.         inc     byte[BTN_COUNT]
  448.         shl     edx, 8
  449.         mov     [BTN_BUFF], edx
  450.         jmp     .result
  451. ;--------------------------------------
  452. align 4
  453. .sendkey:
  454.         movzx   eax, byte[KEY_COUNT]
  455.         cmp     al, 120
  456.         jae     .result ;overflow
  457.         inc     byte[KEY_COUNT]
  458.         mov     [KEY_COUNT+1+eax], dl
  459. ;--------------------------------------
  460. align 4
  461. .result:
  462.         setae   byte[esp+32+4] ;ñ÷èòàåì, ÷òî èñõîäíî: dword[esp+32+4]==72
  463. ;--------------------------------------
  464. align 4
  465. .retf:
  466.         popfd
  467. ;--------------------------------------
  468. align 4
  469. .ret:
  470.         ret
  471. ;-----------------------------------------------------------------------------
  472. align 4
  473. sys_getevent:                                      ;; f11
  474.         mov     ebx, [current_slot];ïîêà ýòî âîïðîñ, ÷åãî êóäû ñóâàòü..........
  475.         pushfd  ; ýòî ñëåäñòâèå îáùåé êîíöåïöèè: ïóñòü ô-ÿ òåñòèðîâàíèÿ èìååò
  476.         cli     ; ïðàâî ðàññ÷èòûâàòü íà çàêðûòûå ïðåðûâàíèÿ, êàê ïðè âûçîâå èç shed
  477.         call    get_event_for_app
  478.         popfd
  479.         mov     [esp+32], eax
  480.         ret
  481. ;-----------------------------------------------------------------------------
  482. align 4
  483. sys_waitforevent:                                  ;; f10
  484.         or      ebx, -1; infinite timeout
  485. ;--------------------------------------
  486. align 4
  487. sys_wait_event_timeout:                            ;; f23
  488.         call    unprotect_from_terminate
  489.         mov     edx, get_event_for_app; wait_test
  490.         call    Wait_events_ex        ; ebx - timeout
  491.         mov     [esp+32], eax
  492.         call    protect_from_terminate
  493.         ret
  494. ;-----------------------------------------------------------------------------
  495. align 4
  496. get_event_for_app:                                 ;; used from f10,f11,f23
  497. ;info:
  498. ;   êëèåíòñêàÿ ô-ÿ òåñòèðîâàíèÿ äëÿ ïðèëîæåíèé (f10,f23)
  499. ;warning:
  500. ;  -don't use [TASK_BASE],[current_slot],[CURRENT_TASK] - it is not for your slot
  501. ;  -may be assumed, that interrupt are disabled
  502. ;  -it is not restriction for scratched registers
  503. ;param:
  504. ;   ebx - àäðåñ APPDATA ñëîòà òåñòèðîâàíèÿ
  505. ;retval:
  506. ;   eax - íîìåð ñîáûòèÿ (=0 => no events)
  507.         movzx   edi, bh               ; bh  is assumed as [CURRENT_TASK]
  508.         shl     edi, 5
  509.         add     edi, CURRENT_TASK     ; edi is assumed as [TASK_BASE]
  510.         mov     ecx, [edi+TASKDATA.event_mask]
  511.         and     ecx, 0x7FFFFFFF
  512. ;--------------------------------------
  513. align 4
  514. .loop: ; ïîêà íå èñ÷åðïàåì âñå áèòû ìàñêè
  515.         bsr     eax, ecx       ; íàõîäèì íåíóëåâîé áèò ìàñêè (31 -> 0)
  516.         jz      .no_events     ; èñ÷åðïàëè âñå áèòû ìàñêè, íî íè÷åãî íå íàøëè ???
  517.         btr     ecx, eax       ; ñáðàñûâàåì ïðîâåðÿåìûé áèò ìàñêè
  518.        ; ïåðåõîäèì íà îáðàáîò÷èê ýòîãî (eax) áèòà
  519.         cmp     eax, 9
  520.         jae     .loop          ; eax=[9..31], ignored (event 10...32)
  521.  
  522.         cmp     eax, 3
  523.         je      .loop          ; eax=3, ignored (event 4)
  524.  
  525.         cmp     eax, 4
  526.         je      .FlagAutoReset  ; eax=4, retvals=eax+1 (event 5)
  527.  
  528.         cmp     eax, 5
  529.         je      .mouse_check  ; eax=5, retvals=eax+1 (event 6)
  530.  
  531.         ja      .FlagAutoReset ; eax=[6..8], retvals=eax+1 (event 7...9)
  532.  
  533.         cmp     eax, 1
  534.         jae     .BtKy          ; eax=[1,2],  retvals=eax+1 (event 2,3)
  535. ;--------------------------------------
  536. align 4
  537. .WndRedraw:                    ; eax=0, retval WndRedraw=1
  538.         cmp     [edi-twdw+WDATA.fl_redraw], al;al==0
  539.         jne     .result
  540.         jmp     .loop
  541. ;--------------------------------------
  542. align 4
  543. .no_events:
  544.         xor     eax, eax
  545.         ret
  546. ;--------------------------------------
  547. align 4
  548. .mouse_check:    ; Mouse 5+1=6
  549.         push    eax
  550.         mov     eax, [TASK_BASE]
  551.         mov     eax, [eax + TASKDATA.event_mask]
  552.         test    eax, 0x80000000 ; bit 31: active/inactive filter f.40
  553.         jz      @f
  554.         pop     eax
  555.         jmp     .FlagAutoReset
  556. ;--------------------------------------
  557. align 4
  558. @@:
  559. ; If the window is captured and moved by the user, then no mouse events!!!
  560.         mov     al, [mouse.active_sys_window.action]
  561.         and     al, WINDOW_MOVE_AND_RESIZE_FLAGS
  562.         test    al, al
  563.         pop     eax
  564.         jnz     .loop
  565. ;--------------------------------------
  566. align 4
  567. .FlagAutoReset: ; retvals: BgrRedraw=5, IPC=7, Stack=8, Debug=9
  568.         btr     [ebx+APPDATA.event_mask], eax
  569.         jnc     .loop
  570. ;--------------------------------------
  571. align 4
  572. .result:      ; retval = eax+1
  573.         inc     eax
  574.         ret
  575. ;--------------------------------------
  576. align 4
  577. .BtKy:
  578.         movzx   edx, bh
  579.         movzx   edx, word[WIN_STACK+edx*2]
  580.         je      .Keys          ; eax=1, retval Keys=2
  581. ;--------------------------------------
  582. align 4
  583. .Buttons:                      ; eax=2, retval Buttons=3
  584.         cmp     byte[BTN_COUNT], 0
  585.         je      .loop          ; empty ???
  586.         cmp     edx, [TASK_COUNT]
  587.         jne     .loop          ; not Top ???
  588.         mov     edx, [BTN_BUFF]
  589.         shr     edx, 8
  590.         cmp     edx, 0xFFFF    ;-ID for Minimize-Button of Form
  591.         jne     .result
  592.         mov     [window_minimize], 1
  593.         dec     byte[BTN_COUNT]
  594.         jmp     .loop
  595. ;--------------------------------------
  596. align 4
  597. .Keys:    ; eax==1
  598.         cmp     edx, [TASK_COUNT]
  599.         jne     @f             ; not Top ???
  600.         cmp     [KEY_COUNT], al; al==1
  601.         jae     .result        ; not empty ???
  602. ;--------------------------------------
  603. align 4
  604. @@:
  605.         mov     edx, hotkey_buffer
  606. ;--------------------------------------
  607. align 4
  608. @@:
  609.         cmp     [edx], bh      ; bh - slot for testing
  610.         je      .result
  611.         add     edx, 8
  612.         cmp     edx, hotkey_buffer+120*8
  613.         jb      @b
  614.         jmp     .loop
  615. ;end.
  616. ;-----------------------------------------------------------------------------
  617.