Subversion Repositories Kolibri OS

Rev

Rev 1391 | Rev 1513 | Go to most recent revision | Blame | Compare with Previous | Last modification | View Log | Download | RSS feed

  1. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  2. ;;                                                              ;;
  3. ;; Copyright (C) KolibriOS team 2004-2007. All rights reserved. ;;
  4. ;; Copyright (C) MenuetOS 2000-2004 Ville Mikael Turjanmaa      ;;
  5. ;; Distributed under terms of the GNU General Public License    ;;
  6. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  7.  
  8. $Revision: 1466 $
  9.  
  10. uglobal
  11. align 4
  12.   event_start   dd ?
  13.   event_end     dd ?
  14.   event_uid     dd 0
  15. endg
  16. EV_SPACE   = 512
  17. FreeEvents = event_start-EVENT.fd    ; "âèðòóàëüíûé" event, èñïîëüçóþòñÿ òîëüêî ïîëÿ:
  18.                                      ;  FreeEvents.fd=event_start è FreeEvents.bk=event_end
  19. align 4
  20. init_events:                                       ;; used from kernel.asm
  21.         stdcall kernel_alloc,EV_SPACE*EVENT.size
  22.         or      eax,eax
  23.         jz      .fail
  24.       ; eax - current event, ebx - previos event below
  25.         mov     ecx,EV_SPACE         ; current - in allocated space
  26.         mov     ebx,FreeEvents       ; previos - íà÷àëî ñïèñêà
  27.         push    ebx                  ; îíî æå è êîíåö ïîòîì áóäåò
  28.   @@:   mov     [ebx+EVENT.fd],eax
  29.         mov     [eax+EVENT.bk],ebx
  30.         mov     ebx,eax              ; previos <- current
  31.         add     eax,EVENT.size       ; new current
  32.         loop    @b
  33.         pop     eax                  ; âîò îíî êîíöîì è ñòàëî
  34.         mov     [ebx+EVENT.fd],eax
  35.         mov     [eax+EVENT.bk],ebx
  36. .fail:  ret
  37.  
  38. EVENT_WATCHED    equ 0x10000000 ;áèò 28
  39. EVENT_SIGNALED   equ 0x20000000 ;áèò 29
  40. MANUAL_RESET     equ 0x40000000 ;áèò 30
  41. MANUAL_DESTROY   equ 0x80000000 ;áèò 31
  42.  
  43. align 4
  44. create_event:                                      ;; EXPORT use
  45. ;info:
  46. ;   Ïåðåíîñèì EVENT èç ñïèñêà FreeEvents â ñïèñîê ObjList òåêóùåãî ñëîòà
  47. ;   EVENT.state óñòàíàâëèâàåì èç ecx, EVENT.code êîñâåííî èç esi (åñëè esi<>0)
  48. ;param:
  49. ;   esi - event data
  50. ;   ecx - flags
  51. ;retval:
  52. ;   eax - event (=0 => fail)
  53. ;   edx - uid
  54. ;scratched: ebx,ecx,esi,edi
  55.         mov     ebx,[current_slot]
  56.         add     ebx,APP_OBJ_OFFSET
  57.         mov     edx,[TASK_BASE]
  58.         mov     edx,[edx+TASKDATA.pid]
  59.         pushfd
  60.         cli
  61.  
  62. set_event:                                         ;; INTERNAL use !!! don't use for Call
  63. ;info:
  64. ;   Áåðåì íîâûé event èç FreeEvents, çàïîëíÿåì åãî ïîëÿ, êàê óêàçàíî â ecx,edx,esi
  65. ;   è óñòàíàâëèâàåì â ñïèñîê, óêàçàííûé â ebx.
  66. ;   Âîçâðàùàåì ñàì event (â eax), è åãî uid (â edx)
  67. ;param:
  68. ;   ebx - start-chain "virtual" event for entry new event Right of him
  69. ;   ecx - flags      (copied to EVENT.state)
  70. ;   edx - pid        (copied to EVENT.pid)
  71. ;   esi - event data (copied to EVENT.code indirect, =0 => skip)
  72. ;retval:
  73. ;   eax - event (=0 => fail)
  74. ;   edx - uid
  75. ;scratched: ebx,ecx,esi,edi
  76.         mov     eax,FreeEvents
  77.         cmp     eax,[eax+EVENT.fd]
  78.         jne     @f  ; not empty ???
  79.         pushad
  80.         call    init_events
  81.         popad
  82.         jz      RemoveEventTo.break ; POPF+RET
  83.   @@:   mov     eax,[eax+EVENT.fd]
  84.         mov     [eax+EVENT.magic],'EVNT'
  85.         mov     [eax+EVENT.destroy],destroy_event.internal
  86.         mov     [eax+EVENT.state],ecx
  87.         mov     [eax+EVENT.pid],edx
  88.         inc     [event_uid]
  89.         Mov     [eax+EVENT.id],edx,[event_uid]
  90.         or      esi,esi
  91.         jz      RemoveEventTo
  92.         lea     edi,[eax+EVENT.code]
  93.         mov     ecx,EVENT.codesize/4
  94.         cld
  95.         rep     movsd
  96.  
  97. RemoveEventTo:                                     ;; INTERNAL use !!! don't use for Call
  98. ;param:
  99. ;   eax - óêàçàòåëü íà event, ÊÎÒÎÐÛÉ âñòàâëÿåì
  100. ;   ebx - óêàçàòåëü íà event, ÏÎÑËÅ êîòîðîãî âñòàâëÿåì
  101. ;scratched: ebx,ecx
  102.         mov     ecx,eax              ; ecx=eax=Self,      ebx=NewLeft
  103.         xchg    ecx,[ebx+EVENT.fd]   ; NewLeft.fd=Self,   ecx=NewRight
  104.         cmp     eax,ecx              ; ñòîï, ñåáå äóìàþ...
  105.         je      .break               ; - à íå äóðàê ëè ÿ?
  106.         mov     [ecx+EVENT.bk],eax   ; NewRight.bk=Self
  107.         xchg    ebx,[eax+EVENT.bk]   ; Self.bk=NewLeft,   ebx=OldLeft
  108.         xchg    ecx,[eax+EVENT.fd]   ; Self.fd=NewRight,  ecx=OldRight
  109.         mov     [ebx+EVENT.fd],ecx   ; OldLeft.fd=OldRight
  110.         mov     [ecx+EVENT.bk],ebx   ; OldRight.bk=OldLeft
  111. .break: popfd
  112.         ret
  113.  
  114. align 4
  115. NotDummyTest:                                      ;; INTERNAL use (not returned for fail !!!)
  116.         pop     edi
  117.         call    DummyTest ; not returned for fail !!!
  118.         mov     ebx,eax
  119.         mov     eax,[ebx+EVENT.pid]
  120.         push    edi
  121. .small: ; êðèâî êàê-òî...
  122.         pop     edi
  123.         pushfd
  124.         cli
  125.         call    pid_to_slot ; saved all registers (eax - retval)
  126.         shl     eax,8
  127.         jz      RemoveEventTo.break ; POPF+RET
  128.         jmp     edi ; øòàòíûé âîçâðàò
  129.  
  130. align 4
  131. raise_event:                                       ;; EXPORT use
  132. ;info:
  133. ;   Óñòàíàâëèâàåì äàííûå EVENT.code
  134. ;   Åñëè òàì ôëàã EVENT_SIGNALED óæå àêòèâåí - áîëüøå íè÷åãî
  135. ;   Èíà÷å: ýòîò ôëàã âçâîäèòñÿ, çà èñêëþ÷åíèåì ñëó÷àÿ íàëè÷èÿ ôëàãà EVENT_WATCHED â edx
  136. ;    ýòîì ñëó÷àå EVENT_SIGNALED âçâîäèòñÿ ëèøü ïðè íàëè÷èå EVENT_WATCHED â ñàìîì ñîáûòèè
  137. ;param:
  138. ;   eax - event
  139. ;   ebx - uid (for Dummy testing)
  140. ;   edx - flags
  141. ;   esi - event data (=0 => skip)
  142. ;scratched: ebx,ecx,esi,edi
  143.         call    NotDummyTest ; not returned for fail !!!
  144.         or      esi,esi
  145.         jz      @f
  146.         lea     edi,[ebx+EVENT.code]
  147.         mov     ecx,EVENT.codesize/4
  148.         cld
  149.         rep     movsd
  150.   @@:
  151.         test    byte[ebx+EVENT.state+3], EVENT_SIGNALED shr 24
  152.         jnz     RemoveEventTo.break  ; POPF+RET
  153.         bt      edx, 28 ;EVENT_WATCHED
  154.         jnc     @f
  155.         test    byte[ebx+EVENT.state+3], EVENT_WATCHED  shr 24
  156.         jz      RemoveEventTo.break  ; POPF+RET
  157.   @@:
  158.         or      byte[ebx+EVENT.state+3], EVENT_SIGNALED shr 24
  159.         add     eax,SLOT_BASE+APP_EV_OFFSET
  160.         xchg    eax,ebx
  161.         jmp     RemoveEventTo
  162.  
  163. align 4
  164. clear_event:                                       ;; EXPORT use
  165. ;info:
  166. ;
  167. ;param:
  168. ;   eax - event
  169. ;   ebx - uid (for Dummy testing)
  170. ;scratched: ebx,ecx
  171.         call    NotDummyTest ; not returned for fail !!!
  172.         add     eax,SLOT_BASE+APP_OBJ_OFFSET
  173.         and     byte[ebx+EVENT.state+3], not((EVENT_SIGNALED+EVENT_WATCHED)shr 24)
  174.         xchg    eax,ebx
  175.         jmp     RemoveEventTo
  176.  
  177. align 4
  178. send_event:                                        ;; EXPORT use
  179. ;info:
  180. ;   Ñîçäàåò íîâûé EVENT (âûòàñêèâàåò èç ñïèñêà FreeEvents) â ñïèñêå EventList
  181. ;   öåëåâîãî ñëîòà (eax=pid), ñ äàííûìè èç esi êîñâåííî, è state=EVENT_SIGNALED
  182. ;param:
  183. ;   eax - slots pid, to sending new event
  184. ;   esi - pointer to sending data (in code field of new event)
  185. ;retval:
  186. ;   eax - event (=0 => fail)
  187. ;   edx - uid
  188. ;warning:
  189. ;   may be used as CDECL with such prefix...
  190. ;       mov     esi,[esp+8]
  191. ;       mov     eax,[esp+4]
  192. ;   but not as STDCALL :(
  193. ;scratched: ebx,ecx,esi,edi
  194.         mov     edx,eax
  195.         call    NotDummyTest.small ; not returned for fail !!!
  196.         lea     ebx,[eax+SLOT_BASE+APP_EV_OFFSET]
  197.         mov     ecx,EVENT_SIGNALED
  198.         jmp     set_event
  199.  
  200. align 4
  201. DummyTest:                                         ;; INTERNAL use (not returned for fail !!!)
  202. ;param:
  203. ;   eax - event
  204. ;   ebx - uid (for Dummy testing)
  205.         cmp     [eax+EVENT.magic],'EVNT'
  206.         jne     @f
  207.         cmp     [eax+EVENT.id],ebx
  208.         je      .ret
  209.   @@:   pop     eax
  210.         xor     eax,eax
  211. .ret:   ret
  212.  
  213.  
  214. align 4
  215. Wait_events:
  216.         or      ebx,-1 ; infinite timeout
  217. Wait_events_ex:
  218. ;info:
  219. ;   Îæèäàíèå "àáñòðàêòíîãî" ñîáûòèÿ ÷åðåç ïåðåâîä ñëîòà â 5-þ ïîçèöèþ.
  220. ;   Àáñòðàêòíîñòü çàêëþ÷åíà â òîì, ÷òî ôàêò ñîáûòèÿ îïðåäåëÿåòñÿ ôóíêöèåé APPDATA.wait_test,
  221. ;   êîòîðàÿ çàäàåòñÿ êëèåíòîì è ìîæåò áûòü ôàêòè÷åñêè ëþáîé.
  222. ;   Ýòî ïîçâîëÿåò shed-ó íàäåæíî îïðåäåëèòü ôàêò ñîáûòèÿ, è íå ñîâåðøàòü "õîëîñòûõ" ïåðåêëþ÷åíèé,
  223. ;   ïðåäíàçíà÷åííûõ äëÿ ðàçáîðîê òèïà "ñâîé/÷óæîé" âíóòðè çàäà÷è.
  224. ;param:
  225. ;   edx - wait_test, êëèåíòñêàÿ ô-ÿ òåñòèðîâàíèÿ (àäðåñ êîäà)
  226. ;   ecx - wait_param, äîïîëíèòåëüíûé ïàðàìåòð, âîçìîæíî íåîáõîäèìûé äëÿ [wait_test]
  227. ;   ebx - wait_timeout
  228. ;retval:
  229. ;   eax - ðåçóëüòàò âûçîâà [wait_test] (=0 => timeout)
  230. ;scratched: esi
  231.         mov     esi,[current_slot]
  232.         mov     [esi+APPDATA.wait_param],ecx
  233.         pushad
  234.         mov     ebx,esi;ïîêà ýòî âîïðîñ, ÷åãî êóäû ñóâàòü..........
  235.         pushfd  ; ýòî ñëåäñòâèå îáùåé êîíöåïöèè: ïóñòü ô-ÿ òåñòèðîâàíèÿ èìååò
  236.         cli     ; ïðàâî ðàññ÷èòûâàòü íà çàêðûòûå ïðåðûâàíèÿ, êàê ïðè âûçîâå èç shed
  237.         call    edx
  238.         popfd
  239.         mov     [esp+28],eax
  240.         popad
  241.         or      eax,eax
  242.         jnz     @f   ;RET
  243.         mov     [esi+APPDATA.wait_test],edx
  244.         mov     [esi+APPDATA.wait_timeout],ebx
  245.         Mov     [esi+APPDATA.wait_begin],eax,[timer_ticks]
  246.         mov     eax,[TASK_BASE]
  247.         mov     [eax+TASKDATA.state], 5
  248.         call    change_task
  249.         mov     eax,[esi+APPDATA.wait_param]
  250.   @@:   ret
  251.  
  252. align 4
  253. wait_event:                                        ;; EXPORT use
  254. ;info:
  255. ;   Îæèäàíèå ôëàãà EVENT_SIGNALED â ñîâåðøåííî êîíêðåòíîì Event
  256. ;   (óñòàíàâëèâàåìîãî, íàäî ïîëàãàòü, ÷åðåç raise_event)
  257. ;   Ïðè àêòèâíîì ôëàãå MANUAL_RESET - áîëüøå íè÷åãî
  258. ;   Èíà÷å: ôëàãè EVENT_SIGNALED è EVENT_WATCHED ó ïîëó÷åííîãî ñîáûòèÿ ñáðàñûâàþòñÿ,
  259. ;   è, ïðè àêòèâíîì MANUAL_DESTROY - ïåðåìåùàåòñÿ â ñïèñîê ObjList òåêóùåãî ñëîòà,
  260. ;   à ïðè íå àêòèâíîì - óíè÷òîæàåòñÿ øòàòíî (destroy_event.internal)
  261. ;param:
  262. ;   eax - event
  263. ;   ebx - uid (for Dummy testing)
  264. ;scratched: ecx,edx,esi
  265.         call    DummyTest
  266.         mov     ecx,eax              ; wait_param
  267.         mov     edx, get_event_alone ; wait_test
  268.         call    Wait_events          ; timeout ignored
  269.         jmp     wait_finish
  270.  
  271. align 4
  272. get_event_ex:                                      ;; f68:14
  273. ;info:
  274. ;   Îæèäàíèå ëþáîãî ñîáûòèÿ â î÷åðåäè EventList òåêóùåãî ñëîòà
  275. ;   Äàííûå ñîáûòèÿ code - êîïèðóþòñÿ â ïàìÿòü ïðèëîæåíèÿ (êîñâåííî ïî edi)
  276. ;   Ïðè àêòèâíîì ôëàãå MANUAL_RESET - áîëüøå íè÷åãî
  277. ;   Èíà÷å: ôëàãè EVENT_SIGNALED è EVENT_WATCHED ó ïîëó÷åííîãî ñîáûòèÿ ñáðàñûâàþòñÿ,
  278. ;   è, ïðè àêòèâíîì MANUAL_DESTROY - ïåðåìåùàåòñÿ â ñïèñîê ObjList òåêóùåãî ñëîòà,
  279. ;   à ïðè íå àêòèâíîì - óíè÷òîæàåòñÿ øòàòíî (destroy_event.internal)
  280. ;param:
  281. ;   edi - àäðåñ â êîäå ïðèëîæåíèÿ äëÿ êîïèðîâàíèÿ äàííûõ èç EVENT.code
  282. ;retval:
  283. ;   eax - ñîáñòâåííî EVENT (áóäåì íàçûâàòü ýòî åãî õýíäëîì)
  284. ;scratched: ebx,ecx,edx,esi,edi
  285.         mov     edx, get_event_queue ; wait_test
  286.         call    Wait_events          ; timeout ignored
  287.         lea     esi,[eax+EVENT.code]
  288.         mov     ecx,EVENT.codesize/4
  289.         cld
  290.         rep     movsd
  291.         mov     [edi-EVENT.codesize+2],cl ;clear priority field
  292. wait_finish:
  293.         test    byte[eax+EVENT.state+3], MANUAL_RESET shr 24
  294.         jnz     get_event_queue.ret  ; RET
  295.         and     byte[eax+EVENT.state+3], not((EVENT_SIGNALED+EVENT_WATCHED)shr 24)
  296.         test    byte[eax+EVENT.state+3], MANUAL_DESTROY shr 24
  297.         jz      destroy_event.internal
  298.         mov     ebx,[current_slot]
  299.         add     ebx,APP_OBJ_OFFSET
  300.         pushfd
  301.         cli
  302.         jmp     RemoveEventTo
  303.  
  304. align 4
  305. destroy_event:                                     ;; EXPORT use
  306. ;info:
  307. ;   Ïåðåíîñèì EVENT â ñïèñîê FreeEvents, ÷èñòèì ïîëÿ magic,destroy,pid,id
  308. ;param:
  309. ;   eax - event
  310. ;   ebx - uid (for Dummy testing)
  311. ;retval:
  312. ;   eax - àäðåñ îáúåêòà EVENT (=0 => fail)
  313. ;scratched: ebx,ecx
  314.         call    DummyTest ; not returned for fail !!!
  315. .internal:
  316.         xor     ecx,ecx   ; clear common header
  317.         pushfd
  318.         cli
  319.         mov     [eax+EVENT.magic],ecx
  320.         mov     [eax+EVENT.destroy],ecx
  321.         mov     [eax+EVENT.pid],ecx
  322.         mov     [eax+EVENT.id],ecx
  323.         mov     ebx,FreeEvents
  324.         jmp     RemoveEventTo
  325.  
  326. align 4
  327. get_event_queue:
  328. ;info:
  329. ;   êëèåíòñêàÿ ô-ÿ òåñòèðîâàíèÿ äëÿ get_event_ex
  330. ;warning:
  331. ;  -don't use [TASK_BASE],[current_slot],[CURRENT_TASK] - it is not for your slot
  332. ;  -may be assumed, that interrupt are disabled
  333. ;  -it is not restriction for scratched registers
  334. ;param:
  335. ;   ebx - àäðåñ APPDATA ñëîòà òåñòèðîâàíèÿ
  336. ;retval:
  337. ;   eax - àäðåñ îáúåêòà EVENT (=0 => fail)
  338.         add     ebx,APP_EV_OFFSET
  339.         mov     eax,[ebx+APPOBJ.bk]  ; âûáèðàåì ñ êîíöà, ïî ïðèíöèïó FIFO
  340.         cmp     eax,ebx  ; empty ???
  341.         je      get_event_alone.ret0
  342. .ret:   ret
  343.  
  344. align 4
  345. get_event_alone:
  346. ;info:
  347. ;   êëèåíòñêàÿ ô-ÿ òåñòèðîâàíèÿ äëÿ wait_event
  348. ;warning:
  349. ;  -don't use [TASK_BASE],[current_slot],[CURRENT_TASK] - it is not for your slot
  350. ;  -may be assumed, that interrupt are disabled
  351. ;  -it is not restriction for scratched registers
  352. ;param:
  353. ;   ebx - àäðåñ APPDATA ñëîòà òåñòèðîâàíèÿ
  354. ;retval:
  355. ;   eax - àäðåñ îáúåêòà EVENT (=0 => fail)
  356.         mov     eax,[ebx+APPDATA.wait_param]
  357.         test    byte[eax+EVENT.state+3], EVENT_SIGNALED shr 24
  358.         jnz     .ret
  359.         or      byte[eax+EVENT.state+3], EVENT_WATCHED shr 24
  360. .ret0:  xor     eax,eax ; NO event!!!
  361. .ret:   ret
  362.  
  363. align 4
  364. sys_sendwindowmsg:                                 ;; f72
  365.         dec     ebx
  366.         jnz     .ret ;subfunction==1 ?
  367.        ;pushfd  ;à íàôèãà?
  368.         cli
  369.         sub     ecx,2
  370.         je      .sendkey
  371.         dec     ecx
  372.         jnz     .retf
  373. .sendbtn:
  374.         cmp     byte[BTN_COUNT],1
  375.         jae     .result ;overflow
  376.         inc     byte[BTN_COUNT]
  377.         shl     edx, 8
  378.         mov     [BTN_BUFF],edx
  379.         jmp     .result
  380. .sendkey:
  381.         movzx   eax,byte[KEY_COUNT]
  382.         cmp     al,120
  383.         jae     .result ;overflow
  384.         inc     byte[KEY_COUNT]
  385.         mov     [KEY_COUNT+1+eax],dl
  386. .result:
  387.         setae   byte[esp+32] ;ñ÷èòàåì, ÷òî èñõîäíî: dword[esp+32]==72
  388. .retf: ;popfd
  389. .ret:   ret
  390.  
  391. align 4
  392. sys_getevent:                                      ;; f11
  393.         mov     ebx,[current_slot] ;ïîêà ýòî âîïðîñ, ÷åãî êóäû ñóâàòü..........
  394.         pushfd  ; ýòî ñëåäñòâèå îáùåé êîíöåïöèè: ïóñòü ô-ÿ òåñòèðîâàíèÿ èìååò
  395.         cli     ; ïðàâî ðàññ÷èòûâàòü íà çàêðûòûå ïðåðûâàíèÿ, êàê ïðè âûçîâå èç shed
  396.         call    get_event_for_app
  397.         popfd
  398.         mov     [esp+32],eax
  399.         ret
  400.  
  401. align 4
  402. sys_waitforevent:                                  ;; f10
  403.         or      ebx,-1 ; infinite timeout
  404. sys_wait_event_timeout:                            ;; f23
  405.         mov     edx,get_event_for_app ; wait_test
  406.         call    Wait_events_ex        ; ebx - timeout
  407.         mov     [esp+32],eax
  408.         ret
  409.  
  410. align 4
  411. get_event_for_app:                                 ;; used from f10,f11,f23
  412. ;info:
  413. ;   êëèåíòñêàÿ ô-ÿ òåñòèðîâàíèÿ äëÿ ïðèëîæåíèé (f10,f23)
  414. ;warning:
  415. ;  -don't use [TASK_BASE],[current_slot],[CURRENT_TASK] - it is not for your slot
  416. ;  -may be assumed, that interrupt are disabled
  417. ;  -it is not restriction for scratched registers
  418. ;param:
  419. ;   ebx - àäðåñ APPDATA ñëîòà òåñòèðîâàíèÿ
  420. ;retval:
  421. ;   eax - íîìåð ñîáûòèÿ (=0 => no events)
  422.         movzx   edi,bh                ; bh  is assumed as [CURRENT_TASK]
  423.         shl     edi,5
  424.         add     edi,CURRENT_TASK      ; edi is assumed as [TASK_BASE]
  425.         mov     ecx,[edi+TASKDATA.event_mask]
  426. .loop: ; ïîêà íå èñ÷åðïàåì âñå áèòû ìàñêè
  427.         bsr     eax,ecx        ; íàõîäèì íåíóëåâîé áèò ìàñêè (31 -> 0)
  428.         jz      .no_events     ; èñ÷åðïàëè âñå áèòû ìàñêè, íî íè÷åãî íå íàøëè ???
  429.         btr     ecx,eax        ; ñáðàñûâàåì ïðîâåðÿåìûé áèò ìàñêè
  430.        ; ïåðåõîäèì íà îáðàáîò÷èê ýòîãî (eax) áèòà
  431.         cmp     eax,16
  432.         jae     .IRQ           ; eax=[16..31]=retvals, events irq0..irq15
  433.         cmp     eax,9
  434.         jae     .loop          ; eax=[9..15], ignored
  435.         cmp     eax,3
  436.         je      .loop          ; eax=3, ignored
  437.         ja      .FlagAutoReset ; eax=[4..8], retvals=eax+1
  438.         cmp     eax,1
  439.         jae     .BtKy          ; eax=[1,2],  retvals=eax+1
  440. .WndRedraw:                    ; eax=0, retval WndRedraw=1
  441.         cmp     [edi-twdw+WDATA.fl_redraw],al ;al==0
  442.         jne     .result
  443.         jmp     .loop
  444.   .no_events:
  445.         xor     eax,eax
  446.         ret
  447. .IRQ:
  448. ;TODO: ñäåëàòü òàê æå, êàê è äëÿ FlagAutoReset (BgrRedraw,Mouse,IPC,Stack,Debug)
  449.         mov     edx,[irq_owner+eax*4-64] ; eax==16+irq
  450.         cmp     edx,[edi+TASKDATA.pid]
  451.         jne     .loop
  452.         mov     edx,eax
  453.         shl     edx,12
  454.         cmp     dword[IRQ_SAVE+edx-0x10000],0 ; edx==(16+irq)*0x1000
  455.         je      .loop          ; empty ???
  456.         ret     ; retval = eax
  457. .FlagAutoReset: ; retvals: BgrRedraw=5, Mouse=6, IPC=7, Stack=8, Debug=9
  458.         cmp     eax,5 ; Mouse 5+1=6
  459.         jne     @f
  460.         push    eax
  461. ; If the window is captured and moved by the user, then no mouse events!!!
  462.         mov     al, [mouse.active_sys_window.action]
  463.         test    al, mouse.WINDOW_MOVE_FLAG
  464.         pop     eax
  465.         jnz     .loop
  466. @@:
  467.         btr     [ebx+APPDATA.event_mask],eax
  468.         jnc     .loop
  469.   .result:      ; retval = eax+1
  470.         inc     eax
  471.         ret
  472.   .BtKy:
  473.         movzx   edx,bh
  474.         movzx   edx, word[WIN_STACK+edx*2]
  475.         je      .Keys          ; eax=1, retval Keys=2
  476. .Buttons:                      ; eax=2, retval Buttons=3
  477.         cmp     byte[BTN_COUNT],0
  478.         je      .loop          ; empty ???
  479.         cmp     edx,[TASK_COUNT]
  480.         jne     .loop          ; not Top ???
  481.         mov     edx, [BTN_BUFF]
  482.         shr     edx, 8
  483.         cmp     edx, 0xFFFF    ;-ID for Minimize-Button of Form
  484.         jne     .result
  485.         mov     [window_minimize],1
  486.         dec     byte[BTN_COUNT]
  487.         jmp     .loop
  488. .Keys:    ; eax==1
  489.         cmp     edx,[TASK_COUNT]
  490.         jne     @f             ; not Top ???
  491.         cmp     [KEY_COUNT],al ; al==1
  492.         jae     .result        ; not empty ???
  493.   @@:   mov     edx, hotkey_buffer
  494.   @@:   cmp     [edx],bh       ; bh - slot for testing
  495.         je      .result
  496.         add     edx,8
  497.         cmp     edx, hotkey_buffer+120*8
  498.         jb      @b
  499.         jmp     .loop
  500. ;end.
  501.