Subversion Repositories Kolibri OS

Rev

Rev 357 | Rev 377 | Go to most recent revision | Blame | Compare with Previous | Last modification | View Log | Download | RSS feed

  1.  
  2. DRV_ENTRY   equ  1
  3. DRV_EXIT     equ -1
  4. DRV_COMPAT   equ  3  ;minimal required drivers version
  5. DRV_CURRENT equ  3  ;current drivers model version
  6.  
  7. DRV_VERSION equ (DRV_COMPAT shl 16) or DRV_CURRENT
  8.  
  9. align 4
  10. proc attach_int_handler stdcall, irq:dword, handler:dword
  11.  
  12.          mov ebx, [irq]        ;irq num
  13.          test ebx, ebx
  14.          jz .err
  15.          mov eax, [handler]
  16.          test eax, eax
  17.          jz .err
  18.          mov [irq_tab+ebx*4], eax
  19.          stdcall enable_irq, [irq]
  20.          ret
  21. .err:
  22.          xor eax, eax
  23.          ret
  24. endp
  25.  
  26. align 4
  27. proc  detach_int_handler
  28.  
  29.            ret
  30. endp
  31.  
  32. align 4
  33. proc enable_irq stdcall, irq_line:dword
  34.            mov ebx, [irq_line]
  35.            mov edx, 0x21
  36.            cmp ebx, 8
  37.            jb @F
  38.            mov edx, 0xA1
  39.            sub ebx,8
  40. @@:
  41.            in al,dx
  42.            btr eax, ebx
  43.            out dx, al
  44.            ret
  45. endp
  46.  
  47. align 16
  48. ;; proc irq_serv
  49.  
  50. irq_serv:
  51.  
  52. .irq_1:
  53.            push eax
  54.            mov eax, 1
  55.            jmp .main
  56. align 4
  57. .irq_2:
  58.            push eax
  59.            mov eax, 2
  60.            jmp .main
  61. align 4
  62. .irq_3:
  63.            push eax
  64.            mov eax, 3
  65.            jmp .main
  66. align 4
  67. .irq_4:
  68.            push eax
  69.            mov eax, 4
  70.            jmp .main
  71. align 4
  72. .irq_5:
  73.            push eax
  74.            mov eax, 5
  75.            jmp .main
  76. align 4
  77. .irq_6:
  78.            push eax
  79.            mov eax, 6
  80.            jmp .main
  81. align 4
  82. .irq_7:
  83.            push eax
  84.            mov eax, 7
  85.            jmp .main
  86. align 4
  87. .irq_8:
  88.            push eax
  89.            mov eax, 8
  90.            jmp .main
  91. align 4
  92. .irq_9:
  93.            push eax
  94.            mov eax, 9
  95.            jmp .main
  96. align 4
  97. .irq_10:
  98.            push eax
  99.            mov eax, 10
  100.            jmp .main
  101. align 4
  102. .irq_11:
  103.            push eax
  104.            mov eax, 11
  105.            jmp .main
  106. align 4
  107. .irq_12:
  108.            push eax
  109.            mov eax, 12
  110.            jmp .main
  111. align 4
  112. .irq_13:
  113.            push eax
  114.            mov eax, 13
  115.            jmp .main
  116. align 4
  117. .irq_14:
  118.            push eax
  119.            mov eax, 14
  120.            jmp .main
  121. align 4
  122. .irq_15:
  123.            push eax
  124.            mov eax, 15
  125.            jmp .main
  126.  
  127. align 16
  128. .main:
  129.            save_ring3_context
  130.            mov   bx, os_data
  131.            mov   ds, bx
  132.            mov   es, bx
  133.  
  134.            mov ebx, [irq_tab+eax*4]
  135.            test ebx, ebx
  136.            jz .exit
  137.  
  138.            call ebx
  139.  
  140. .exit:
  141.            restore_ring3_context
  142.  
  143.            cmp eax, 8
  144.            mov al, 0x20
  145.            jb @f
  146.            out 0xa0, al
  147. @@:
  148.            out 0x20, al
  149.  
  150.            pop eax
  151.            iret
  152.  
  153. align 4
  154. proc get_notify stdcall, p_ev:dword
  155.  
  156. .wait:
  157.            mov ebx,[CURRENT_TASK]
  158.            shl ebx,8
  159.            test dword [ebx+PROC_BASE+0xA8],EVENT_NOTIFY
  160.            jz @f
  161.            and dword [ebx+PROC_BASE+0xA8], not EVENT_NOTIFY
  162.            mov edi, [p_ev]
  163.            mov dword [edi], EV_INTR
  164.            mov eax, [ebx+PROC_BASE+APPDATA.event]
  165.            mov dword [edi+4], eax
  166.            ret
  167. @@:
  168.            call change_task
  169.            jmp .wait
  170. endp
  171.  
  172. align 4
  173. proc pci_read32 stdcall, bus:dword, devfn:dword, reg:dword
  174.            xor eax, eax
  175.            xor ebx, ebx
  176.            mov ah, byte [bus]
  177.            mov al, 6
  178.            mov bh, byte [devfn]
  179.            mov bl, byte [reg]
  180.            call pci_read_reg
  181.            ret
  182. endp
  183.  
  184. align 4
  185. proc pci_read8 stdcall, bus:dword, devfn:dword, reg:dword
  186.            xor eax, eax
  187.            xor ebx, ebx
  188.            mov ah, byte [bus]
  189.            mov al, 4
  190.            mov bh, byte [devfn]
  191.            mov bl, byte [reg]
  192.            call pci_read_reg
  193.            ret
  194. endp
  195.  
  196. align 4
  197. proc pci_write8 stdcall, bus:dword, devfn:dword, reg:dword, val:dword
  198.            xor eax, eax
  199.            xor ebx, ebx
  200.            mov ah, byte [bus]
  201.            mov al, 8
  202.            mov bh, byte [devfn]
  203.            mov bl, byte [reg]
  204.            mov ecx, [val]
  205.            call pci_write_reg
  206.            ret
  207. endp
  208.  
  209. handle     equ  IOCTL.handle
  210. io_code   equ  IOCTL.io_code
  211. input     equ  IOCTL.input
  212. inp_size   equ  IOCTL.inp_size
  213. output     equ  IOCTL.output
  214. out_size   equ  IOCTL.out_size
  215.  
  216.  
  217. align 4
  218. proc srv_handler stdcall, ioctl:dword
  219.            mov esi, [ioctl]
  220.            test esi, esi
  221.            jz .err
  222.  
  223.            mov edi, [esi+handle]
  224.            cmp [edi+SRV.magic], ' SRV'
  225.            jne .fail
  226.  
  227.            cmp [edi+SRV.size], SRV_SIZE
  228.            jne .fail
  229.  
  230.            stdcall [edi+SRV.srv_proc], esi
  231.            ret
  232. .fail:
  233.            xor eax, eax
  234.            not eax
  235.            mov [esi+output], eax
  236.            mov [esi+out_size], 4
  237.            ret
  238. .err:
  239.            xor eax, eax
  240.            not eax
  241.            ret
  242. endp
  243.  
  244. align 4
  245. proc srv_handlerEx stdcall, ioctl:dword
  246.            mov esi, [ioctl]
  247.            test esi, esi
  248.            jz .err
  249.            add esi, new_app_base
  250.  
  251.            mov edi, [esi+handle]
  252.            cmp [edi+SRV.magic], ' SRV'
  253.            jne .fail
  254.  
  255.            cmp [edi+SRV.size], SRV_SIZE
  256.            jne .fail
  257.  
  258.            add [esi+input], new_app_base
  259.            add [esi+output], new_app_base
  260.  
  261.            stdcall [edi+SRV.srv_proc], esi
  262.            ret
  263. .fail:
  264.            xor eax, eax
  265.            not eax
  266.            mov [esi+output], eax
  267.            mov [esi+out_size], 4
  268.            ret
  269. .err:
  270.            xor eax, eax
  271.            not eax
  272.            ret
  273. endp
  274.  
  275. restore  handle
  276. restore  io_code
  277. restore  input
  278. restore  inp_size
  279. restore  output
  280. restore  out_size
  281.  
  282. align 4
  283. proc get_service stdcall, sz_name:dword
  284.            mov eax, [sz_name]
  285.            test eax, eax
  286.            jnz @F
  287.            ret
  288. @@:
  289.            mov edx, [srv.fd]
  290. @@:
  291.            cmp edx, srv.fd-SRV_FD_OFFSET
  292.            je .not_load
  293.  
  294.            stdcall strncmp, edx, [sz_name], 16
  295.            test eax, eax
  296.            je .ok
  297.  
  298.            mov edx, [edx+SRV.fd]
  299.            jmp @B
  300. .not_load:
  301.            pop ebp
  302.            jmp load_driver
  303. .ok:
  304.            mov eax, edx
  305.            ret
  306. endp
  307.  
  308. align 4
  309. reg_service:
  310. .sz_name equ esp+4
  311. .handler equ esp+8
  312.            mov eax, [.sz_name]
  313.            test eax, eax
  314.            jz .fail
  315.  
  316.            mov ebx, [.handler]
  317.            test ebx, ebx
  318.            jz .fail
  319.  
  320.            mov eax, SRV_SIZE
  321.            call malloc           ;call alloc_service
  322.            test eax, eax
  323.            jz .fail
  324.  
  325.            mov edi, eax
  326.            mov esi, [.sz_name]
  327.            mov ecx, 16/4
  328.            rep movsd
  329.  
  330.            mov [eax+SRV.magic], ' SRV'
  331.            mov [eax+SRV.size], SRV_SIZE
  332.  
  333.            mov ebx, srv.fd-SRV_FD_OFFSET
  334.            mov edx, [ebx+SRV.fd]
  335.            mov [eax+SRV.fd], edx
  336.            mov [eax+SRV.bk], ebx
  337.            mov [ebx+SRV.fd], eax
  338.            mov [edx+SRV.bk], eax
  339.  
  340.            mov ecx, [.handler]
  341.            mov [eax+SRV.srv_proc], ecx
  342.            ret 8
  343. .fail:
  344.            xor eax, eax
  345.            ret 8
  346.  
  347. align 4
  348. proc get_proc stdcall, exp:dword, sz_name:dword
  349.  
  350.            mov edx, [exp]
  351. .next:
  352.            mov eax, [edx]
  353.            test eax, eax
  354.            jz .end
  355.  
  356.            push edx
  357.            stdcall strncmp, eax, [sz_name], 16
  358.            pop edx
  359.            test eax, eax
  360.            jz .ok
  361.  
  362.            add edx,8
  363.            jmp .next
  364. .ok:
  365.            mov eax, [edx+4]
  366. .end:
  367.            ret
  368. endp
  369.  
  370. align 4
  371. proc get_coff_sym stdcall, pSym:dword,count:dword, sz_sym:dword
  372.  
  373. @@:
  374.            stdcall strncmp, [pSym], [sz_sym], 8
  375.            test eax,eax
  376.            jz .ok
  377.            add [pSym], 18
  378.            dec [count]
  379.            jnz @b
  380.            xor eax, eax
  381.            ret
  382. .ok:
  383.            mov ebx, [pSym]
  384.            mov eax, [ebx+8]
  385.            ret
  386. endp
  387.  
  388. align 4
  389. proc get_curr_task
  390.            mov eax,[CURRENT_TASK]
  391.            shl eax, 8
  392.            ret
  393. endp
  394.  
  395. align 4
  396. proc get_fileinfo stdcall, file_name:dword, info:dword
  397.            locals
  398.              cmd     dd ?
  399.              offset  dd ?
  400.                      dd ?
  401.              count   dd ?
  402.              buff    dd ?
  403.                      db ?
  404.              name    dd ?
  405.            endl
  406.  
  407.            xor eax, eax
  408.            mov ebx, [file_name]
  409.            sub ebx, new_app_base
  410.            mov ecx, [info]
  411.            sub ecx, new_app_base
  412.  
  413.            mov [cmd], 5
  414.            mov [offset], eax
  415.            mov [offset+4], eax
  416.            mov [count], eax
  417.            mov [buff], ecx
  418.            mov byte [buff+4], al
  419.            mov [name], ebx
  420.  
  421.            mov eax, 70
  422.            lea ebx, [cmd]
  423.            sub ebx, new_app_base
  424.            int 0x40
  425.            ret
  426. endp
  427.  
  428. align 4
  429. proc read_file stdcall,file_name:dword, buffer:dword, off:dword,\
  430.                                      bytes:dword
  431.            locals
  432.              cmd     dd ?
  433.              offset  dd ?
  434.                      dd ?
  435.              count   dd ?
  436.              buff    dd ?
  437.                      db ?
  438.              name    dd ?
  439.            endl
  440.  
  441.            xor eax, eax
  442.            mov ebx, [file_name]
  443.            mov ecx, [off]
  444.            mov edx, [bytes]
  445.            mov esi, [buffer]
  446.            sub ebx, new_app_base
  447.            sub esi, new_app_base
  448.  
  449.            mov [cmd], eax
  450.            mov [offset], ecx
  451.            mov [offset+4], eax
  452.            mov [count], edx
  453.            mov [buff], esi
  454.            mov byte [buff+4], al
  455.            mov [name], ebx
  456.  
  457.            mov eax, 70
  458.            lea ebx, [cmd]
  459.            sub ebx, new_app_base
  460.            int 0x40
  461.            ret
  462. endp
  463.  
  464. ; description
  465. ;  allocate kernel memory and loads the specified file
  466. ;
  467. ; param
  468. ;  file_name= full path to file
  469. ;
  470. ; retval
  471. ;  eax= file image in kernel memory
  472. ;  ebx= size of file
  473. ;
  474. ; warging
  475. ;  You mast call kernel_free() to delete each file
  476. ;  loaded by the load_file() function
  477.  
  478. align 4
  479. proc load_file stdcall, file_name:dword
  480.            locals
  481.              attr       dd ?
  482.              flags      dd ?
  483.              cr_time    dd ?
  484.              cr_date    dd ?
  485.              acc_time   dd ?
  486.              acc_date   dd ?
  487.              mod_time   dd ?
  488.              mod_date   dd ?
  489.              file_size  dd ?
  490.  
  491.              file       dd ?
  492.              file2      dd ?
  493.            endl
  494.  
  495.            lea eax, [attr]
  496.            stdcall get_fileinfo, [file_name], eax
  497.            test eax, eax
  498.            jnz .fail
  499.  
  500.            mov eax, [file_size]
  501.            cmp eax, 1024*1024*16
  502.            ja .fail
  503.  
  504.            stdcall kernel_alloc, [file_size]
  505.            mov [file], eax
  506.  
  507.            stdcall read_file, [file_name], eax, dword 0, [file_size]
  508.            cmp ebx, [file_size]
  509.            jne .cleanup
  510.  
  511.            mov eax, [file]
  512.            cmp dword [eax], 0x4B43504B
  513.            jne .exit
  514.            mov ebx, [eax+4]
  515.            mov [file_size], ebx
  516.            stdcall kernel_alloc, ebx
  517.  
  518.            test eax, eax
  519.            jz .cleanup
  520.  
  521.            mov [file2], eax
  522.            stdcall unpack, [file], eax
  523.            stdcall kernel_free, [file]
  524.            mov eax, [file2]
  525.            mov ebx, [file_size]
  526. .exit:
  527.            push eax
  528.            lea edi, [eax+ebx]     ;cleanup remain space
  529.            mov ecx, 4096          ;from file end
  530.            and ebx, 4095
  531.            sub ecx, ebx
  532.            xor eax, eax
  533.            cld
  534.            rep stosb
  535.            mov ebx, [file_size]
  536.            pop eax
  537.            ret
  538. .cleanup:
  539.            stdcall kernel_free, [file]
  540. .fail:
  541.            xor eax, eax
  542.            xor ebx, ebx
  543.            ret
  544. endp
  545.  
  546. align 4
  547. proc get_proc_ex stdcall, proc_name:dword, imports:dword
  548.  
  549. .look_up:
  550.            mov edx, [imports]
  551.            test edx, edx
  552.            jz .end
  553.            mov edx, [edx]
  554.            test edx, edx
  555.            jz .end
  556. .next:
  557.            mov eax, [edx]
  558.            test eax, eax
  559.            jz .next_table
  560.  
  561.            push edx
  562.            stdcall strncmp, eax, [proc_name], 16
  563.            pop edx
  564.            test eax, eax
  565.            jz .ok
  566.  
  567.            add edx,8
  568.            jmp .next
  569. .next_table:
  570.            add [imports], 4
  571.            jmp .look_up
  572. .ok:
  573.            mov eax, [edx+4]
  574.            ret
  575. .end:
  576.            xor eax, eax
  577.            ret
  578. endp
  579.  
  580. align 4
  581. proc fix_coff_symbols stdcall, sec:dword, symbols:dword,\
  582.                       sym_count:dword, strings:dword, imports:dword
  583.            locals
  584.              retval dd ?
  585.            endl
  586.  
  587.            mov edi, [symbols]
  588.            mov [retval], 1
  589. .fix:
  590.            movzx ebx, [edi+CSYM.SectionNumber]
  591.            test ebx, ebx
  592.            jnz .internal
  593.            mov eax, dword [edi+CSYM.Name]
  594.            test eax, eax
  595.            jnz @F
  596.  
  597.            mov edi, [edi+4]
  598.            add edi, [strings]
  599. @@:
  600.            push edi
  601.            stdcall get_proc_ex, edi,[imports]
  602.            pop edi
  603.  
  604.            xor ebx, ebx
  605.            test eax, eax
  606.            jnz @F
  607.  
  608.            mov esi, msg_unresolved
  609.            call sys_msg_board_str
  610.            mov esi, edi
  611.            call sys_msg_board_str
  612.            mov esi, msg_CR
  613.            call sys_msg_board_str
  614.  
  615.            mov [retval],0
  616. @@:
  617.            mov edi, [symbols]
  618.            mov [edi+CSYM.Value], eax
  619.            jmp .next
  620. .internal:
  621.            dec ebx
  622.            shl ebx, 3
  623.            lea ebx, [ebx+ebx*4]
  624.            add ebx, [sec]
  625.  
  626.            mov eax, [ebx+CFS.VirtualAddress]
  627.            add [edi+CSYM.Value], eax
  628. .next:
  629.            add edi, CSYM_SIZE
  630.            mov [symbols], edi
  631.            dec [sym_count]
  632.            jnz .fix
  633.            mov eax, [retval]
  634.            ret
  635. endp
  636.  
  637. align 4
  638. proc fix_coff_relocs stdcall, coff:dword, sec:dword, sym:dword
  639.            locals
  640.              n_sec     dd ?
  641.            endl
  642.  
  643.            mov eax, [coff]
  644.            movzx ebx, [eax+CFH.nSections]
  645.            mov [n_sec], ebx
  646. .fix_sec:
  647.            mov esi, [sec]
  648.            mov edi, [esi+CFS.PtrReloc]
  649.            add edi, [coff]
  650.  
  651.            movzx ecx, [esi+CFS.NumReloc]
  652.            test ecx, ecx
  653.            jz .next
  654. .next_reloc:
  655.            mov ebx, [edi+CRELOC.SymIndex]
  656.            add ebx,ebx
  657.            lea ebx,[ebx+ebx*8]
  658.            add ebx, [sym]
  659.  
  660.            mov edx, [ebx+CSYM.Value]
  661.  
  662.            cmp [edi+CRELOC.Type], 6
  663.            je .dir_32
  664.  
  665.            cmp [edi+CRELOC.Type], 20
  666.            jne .next_reloc
  667. .rel_32:
  668.            mov eax, [edi+CRELOC.VirtualAddress]
  669.            add eax, [esi+CFS.VirtualAddress]
  670.            sub edx, eax
  671.            sub edx, 4
  672.            jmp .fix
  673. .dir_32:
  674.            mov eax, [edi+CRELOC.VirtualAddress]
  675.            add eax, [esi+CFS.VirtualAddress]
  676. .fix:
  677.            add [eax], edx
  678.            add edi, 10
  679.            dec ecx
  680.            jnz .next_reloc
  681. .next:
  682.            add [sec], COFF_SECTION_SIZE
  683.            dec [n_sec]
  684.            jnz .fix_sec
  685. .exit:
  686.            ret
  687. endp
  688.  
  689. align 4
  690. proc load_driver stdcall, driver_name:dword
  691.            locals
  692.              coff      dd ?
  693.              sym       dd ?
  694.              strings   dd ?
  695.              img_size  dd ?
  696.              img_base  dd ?
  697.              start     dd ?
  698.  
  699.              exports   dd ?   ;fake exports table
  700.                        dd ?
  701.              file_name rb 14+16+4+1      ; '/rd/1/drivers/<up-to-16-chars>.obj'
  702.            endl
  703.  
  704.         lea     edx, [file_name]
  705.         mov     dword [edx], '/rd/'
  706.         mov     dword [edx+4], '1/dr'
  707.         mov     dword [edx+8], 'iver'
  708.         mov     word [edx+12], 's/'
  709.         mov     esi, [driver_name]
  710.         lea     edi, [edx+14]
  711.         mov     ecx, 16
  712. @@:
  713.         lodsb
  714.         test    al, al
  715.         jz      @f
  716.         stosb
  717.         loop    @b
  718. @@:
  719.         mov     dword [edi], '.obj'
  720.         mov     byte [edi+4], 0
  721.            stdcall load_file, edx
  722.  
  723.            test eax, eax
  724.            jz .exit
  725.  
  726.            mov [coff], eax
  727.  
  728.            movzx ecx, [eax+CFH.nSections]
  729.            xor ebx, ebx
  730.  
  731.            lea edx, [eax+20]
  732. @@:
  733.            add ebx, [edx+CFS.SizeOfRawData]
  734.            add ebx, 15
  735.            and ebx, not 15
  736.            add edx, COFF_SECTION_SIZE
  737.            dec ecx
  738.            jnz @B
  739.            mov [img_size], ebx
  740.  
  741.            stdcall kernel_alloc, ebx
  742.            test eax, eax
  743.            jz .fail
  744.            mov [img_base], eax
  745.  
  746.            mov edi, eax
  747.            xor eax, eax
  748.            mov ecx, [img_size]
  749.            add ecx, 4095
  750.            and ecx, not 4095
  751.            shr ecx, 2
  752.            cld
  753.            rep stosd
  754.  
  755.            mov edx, [coff]
  756.            movzx ebx, [edx+CFH.nSections]
  757.            mov edi, [img_base]
  758.            lea eax, [edx+20]
  759. @@:
  760.            mov [eax+CFS.VirtualAddress], edi
  761.            mov esi, [eax+CFS.PtrRawData]
  762.            test esi, esi
  763.            jnz .copy
  764.            add edi, [eax+CFS.SizeOfRawData]
  765.            jmp .next
  766. .copy:
  767.            add esi, edx
  768.            mov ecx, [eax+CFS.SizeOfRawData]
  769.            cld
  770.            rep movsb
  771. .next:
  772.            add edi, 15
  773.            and edi, not 15
  774.            add eax, COFF_SECTION_SIZE
  775.            dec ebx
  776.            jnz @B
  777.  
  778.            mov ebx, [edx+CFH.pSymTable]
  779.            add ebx, edx
  780.            mov [sym], ebx
  781.            mov ecx, [edx+CFH.nSymbols]
  782.            add ecx,ecx
  783.            lea ecx,[ecx+ecx*8] ;ecx*=18 = nSymbols*CSYM_SIZE
  784.            add ecx, [sym]
  785.            mov [strings], ecx
  786.  
  787.            lea ebx, [exports]
  788.            mov dword [ebx], kernel_export
  789.            mov dword [ebx+4], 0
  790.            lea eax, [edx+20]
  791.  
  792.            stdcall fix_coff_symbols, eax, [sym], [edx+CFH.nSymbols],\
  793.                                      [strings], ebx
  794.            test eax, eax
  795.            jz .link_fail
  796.  
  797.            mov ebx, [coff]
  798.            add ebx, 20
  799.            stdcall fix_coff_relocs, [coff], ebx, [sym]
  800.  
  801.            mov ebx, [coff]
  802.            stdcall get_coff_sym,[sym],[ebx+CFH.nSymbols],szVersion
  803.            test eax, eax
  804.            jz .link_fail
  805.  
  806.            mov eax, [eax]
  807.            shr eax, 16
  808.            cmp eax, DRV_COMPAT
  809.            jb .ver_fail
  810.  
  811.            cmp eax, DRV_CURRENT
  812.            ja .ver_fail
  813.  
  814.            mov ebx, [coff]
  815.            stdcall get_coff_sym,[sym],[ebx+CFH.nSymbols],szSTART
  816.            mov [start], eax
  817.  
  818.            stdcall kernel_free, [coff]
  819.  
  820.            mov ebx, [start]
  821.            stdcall ebx, DRV_ENTRY
  822.            test eax, eax
  823.            jnz .ok
  824.  
  825.            stdcall kernel_free, [img_base]
  826.            xor eax, eax
  827.            ret
  828. .ok:
  829.            mov ebx, [img_base]
  830.            mov [eax+SRV.base], ebx
  831.            mov ecx, [start]
  832.            mov [eax+SRV.entry], ecx
  833.            ret
  834.  
  835. .ver_fail:
  836.            mov esi, msg_CR
  837.            call sys_msg_board_str
  838.            mov esi, [driver_name]
  839.            call sys_msg_board_str
  840.            mov esi, msg_CR
  841.            call sys_msg_board_str
  842.            mov esi, msg_version
  843.            call sys_msg_board_str
  844.            mov esi, msg_www
  845.            call sys_msg_board_str
  846.            jmp .cleanup
  847.  
  848. .link_fail:
  849.            mov esi, msg_module
  850.            call sys_msg_board_str
  851.            mov esi, [driver_name]
  852.            call sys_msg_board_str
  853.            mov esi, msg_CR
  854.            call sys_msg_board_str
  855. .cleanup:
  856.            stdcall kernel_free,[img_base]
  857. .fail:
  858.            stdcall kernel_free, [coff]
  859. .exit:
  860.            xor eax, eax
  861.            ret
  862. endp
  863.  
  864. align 4
  865. proc load_library stdcall, file_name:dword
  866.            locals
  867.              coff      dd ?
  868.              sym       dd ?
  869.              strings   dd ?
  870.              img_size  dd ?
  871.              img_base  dd ?
  872.              exports   dd ?
  873.            endl
  874.  
  875.            cli
  876.  
  877.            stdcall load_file, [file_name]
  878.            test eax, eax
  879.            jz .fail
  880.  
  881.            mov [coff], eax
  882.            movzx ecx, [eax+CFH.nSections]
  883.            xor ebx, ebx
  884.  
  885.            lea edx, [eax+20]
  886. @@:
  887.            add ebx, [edx+CFS.SizeOfRawData]
  888.            add ebx, 15
  889.            and ebx, not 15
  890.            add edx, COFF_SECTION_SIZE
  891.            dec ecx
  892.            jnz @B
  893.            mov [img_size], ebx
  894.  
  895.            call init_heap
  896.            stdcall user_alloc, [img_size]
  897.  
  898.            test eax, eax
  899.            jz .fail
  900.            mov [img_base], eax
  901.  
  902.            mov edx, [coff]
  903.            movzx ebx, [edx+CFH.nSections]
  904.            mov edi, [img_base]
  905.            lea eax, [edx+20]
  906. @@:
  907.            mov [eax+CFS.VirtualAddress], edi
  908.            mov esi, [eax+CFS.PtrRawData]
  909.            test esi, esi
  910.            jnz .copy
  911.            add edi, [eax+CFS.SizeOfRawData]
  912.            jmp .next
  913. .copy:
  914.            add esi, edx
  915.            add edi, new_app_base
  916.            mov ecx, [eax+CFS.SizeOfRawData]
  917.            cld
  918.            rep movsb
  919. .next:
  920.            add edi, 15-new_app_base
  921.            and edi, not 15
  922.            add eax, COFF_SECTION_SIZE
  923.            dec ebx
  924.            jnz @B
  925.  
  926.            mov ebx, [edx+CFH.pSymTable]
  927.            add ebx, edx
  928.            mov [sym], ebx
  929.            mov ecx, [edx+CFH.nSymbols]
  930.            add ecx,ecx
  931.            lea ecx,[ecx+ecx*8] ;ecx*=18 = nSymbols*CSYM_SIZE
  932.            add ecx, [sym]
  933.            mov [strings], ecx
  934.  
  935.            lea eax, [edx+20]
  936.  
  937.            stdcall fix_coff_symbols, eax, [sym], [edx+CFH.nSymbols],\
  938.                                      [strings], dword 0
  939.            test eax, eax
  940.            jnz @F
  941.  
  942. @@:
  943.            mov edx, [coff]
  944.            movzx ebx, [edx+CFH.nSections]
  945.            mov edi, new_app_base
  946.            lea eax, [edx+20]
  947. @@:
  948.            add [eax+CFS.VirtualAddress], edi  ;patch user space offset
  949.            add eax, COFF_SECTION_SIZE
  950.            dec ebx
  951.            jnz @B
  952.  
  953.            add edx, 20
  954.            stdcall fix_coff_relocs, [coff], edx, [sym]
  955.  
  956.            mov ebx, [coff]
  957.            stdcall get_coff_sym,[sym],[ebx+CFH.nSymbols],szEXPORTS
  958.            mov [exports], eax
  959.  
  960.            stdcall kernel_free, [coff]
  961.            mov eax, [exports]
  962.            ret
  963. .fail:
  964.            xor eax, eax
  965.            ret
  966. endp
  967.  
  968. align 4
  969. proc stop_all_services
  970.  
  971.            mov edx, [srv.fd]
  972. .next:
  973.            cmp edx,  srv.fd-SRV_FD_OFFSET
  974.            je .done
  975.            cmp [edx+SRV.magic], ' SRV'
  976.            jne .next
  977.            cmp [edx+SRV.size], SRV_SIZE
  978.            jne .next
  979.            mov ebx, [edx+SRV.entry]
  980.            mov edx, [edx+SRV.fd]
  981.            push edx
  982.            stdcall ebx, dword -1
  983.            pop edx
  984.            jmp .next
  985. .done:
  986.            ret
  987. endp
  988.  
  989. ; param
  990. ;  eax= size
  991. ;  ebx= pid
  992.  
  993. align 4
  994. create_kernel_object:
  995.  
  996.            push ebx
  997.            call malloc
  998.            pop ebx
  999.            test eax, eax
  1000.            jz .fail
  1001.  
  1002.            mov ecx,[CURRENT_TASK]
  1003.            shl ecx,8
  1004.            add ecx, PROC_BASE+APP_OBJ_OFFSET
  1005.  
  1006.            pushfd
  1007.            cli
  1008.            mov edx, [ecx+APPOBJ.fd]
  1009.            mov [eax+APPOBJ.fd], edx
  1010.            mov [eax+APPOBJ.bk], ecx
  1011.            mov [eax+APPOBJ.pid], ebx
  1012.  
  1013.            mov [ecx+APPOBJ.fd], eax
  1014.            mov [edx+APPOBJ.bk], eax
  1015.            popfd
  1016. .fail:
  1017.            ret
  1018.  
  1019. ; param
  1020. ;  eax= object
  1021.  
  1022. align 4
  1023. destroy_kernel_object:
  1024.  
  1025.            pushfd
  1026.            cli
  1027.            mov ebx, [eax+APPOBJ.fd]
  1028.            mov ecx, [eax+APPOBJ.bk]
  1029.            mov [ebx+APPOBJ.bk], ecx
  1030.            mov [ecx+APPOBJ.fd], ebx
  1031.            popfd
  1032.  
  1033.            xor edx, edx        ;clear common header
  1034.            mov [eax], edx
  1035.            mov [eax+4], edx
  1036.            mov [eax+8], edx
  1037.            mov [eax+12], edx
  1038.            mov [eax+16], edx
  1039.  
  1040.            call free           ;release object memory
  1041.            ret
  1042.  
  1043.  
  1044. ;szSound        db 'SOUND',0
  1045. ;szInfinity     db 'INFINITY',0
  1046. szHwMouse      db 'ATI2D',0
  1047.  
  1048. szSTART        db 'START',0
  1049. szEXPORTS      db 'EXPORTS',0
  1050. szIMPORTS      db 'IMPORTS',0
  1051.  
  1052. msg_unresolved db 'unresolved ',0
  1053. msg_module     db 'in module ',0
  1054. msg_version    db 'incompatible driver version',13,10,0
  1055. msg_www        db 'please visit www.kolibrios.org',13,10,0
  1056. msg_CR         db  13,10,0
  1057.  
  1058. align 4
  1059. create_cursor    dd 0
  1060. set_hw_cursor    dd 0
  1061. hw_restore       dd 0
  1062.