Subversion Repositories Kolibri OS

Rev

Rev 4993 | Blame | Compare with Previous | Last modification | View Log | Download | RSS feed

  1. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  2. ;;
  3. ;; Copyright (C) KolibriOS team 2004-2013. All rights reserved.
  4. ;; PROGRAMMING:
  5. ;; Ivan Poddubny
  6. ;; Marat Zakiyanov (Mario79)
  7. ;; VaStaNi
  8. ;; Trans
  9. ;; Mihail Semenyako (mike.dld)
  10. ;; Sergey Kuzmin (Wildwest)
  11. ;; Andrey Halyavin (halyavin)
  12. ;; Mihail Lisovin (Mihasik)
  13. ;; Andrey Ignatiev (andrew_programmer)
  14. ;; NoName
  15. ;; Evgeny Grechnikov (Diamond)
  16. ;; Iliya Mihailov (Ghost)
  17. ;; Sergey Semyonov (Serge)
  18. ;; Johnny_B
  19. ;; SPraid (simba)
  20. ;; Hidnplayr
  21. ;; Alexey Teplov (<Lrz>)
  22. ;; Rus
  23. ;; Nable
  24. ;; shurf
  25. ;; Alver
  26. ;; Maxis
  27. ;; Galkov
  28. ;; CleverMouse
  29. ;; tsdima
  30. ;; turbanoff
  31. ;; Asper
  32. ;; art_zh
  33. ;;
  34. ;; Data in this file was originally part of MenuetOS project which is
  35. ;; distributed under the terms of GNU GPL. It is modified and redistributed as
  36. ;; part of KolibriOS project under the terms of GNU GPL.
  37. ;;
  38. ;; Copyright (C) MenuetOS 2000-2004 Ville Mikael Turjanmaa
  39. ;; PROGRAMMING:
  40. ;;
  41. ;; Ville Mikael Turjanmaa, villemt@itu.jyu.fi
  42. ;; - main os coding/design
  43. ;; Jan-Michael Brummer, BUZZ2@gmx.de
  44. ;; Felix Kaiser, info@felix-kaiser.de
  45. ;; Paolo Minazzi, paolo.minazzi@inwind.it
  46. ;; quickcode@mail.ru
  47. ;; Alexey, kgaz@crosswinds.net
  48. ;; Juan M. Caravaca, bitrider@wanadoo.es
  49. ;; kristol@nic.fi
  50. ;; Mike Hibbett, mikeh@oceanfree.net
  51. ;; Lasse Kuusijarvi, kuusijar@lut.fi
  52. ;; Jarek Pelczar, jarekp3@wp.pl
  53. ;;
  54. ;; KolibriOS is distributed in the hope that it will be useful, but WITHOUT ANY
  55. ;; WARRANTY. No author or distributor accepts responsibility to anyone for the
  56. ;; consequences of using it or for whether it serves any particular purpose or
  57. ;; works at all, unless he says so in writing. Refer to the GNU General Public
  58. ;; License (the "GPL") for full details.
  59. ;
  60. ;; Everyone is granted permission to copy, modify and redistribute KolibriOS,
  61. ;; but only under the conditions described in the GPL. A copy of this license
  62. ;; is supposed to have been given to you along with KolibriOS so you can know
  63. ;; your rights and responsibilities. It should be in a file named COPYING.
  64. ;; Among other things, the copyright notice and this notice must be preserved
  65. ;; on all copies.
  66. ;;
  67. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  68.  
  69. format binary as "mnt"
  70.  
  71. include 'macros.inc'
  72. include 'struct.inc'
  73.  
  74. $Revision: 4381 $
  75.  
  76.  
  77. USE_COM_IRQ     equ 1      ; make irq 3 and irq 4 available for PCI devices
  78. VESA_1_2_VIDEO equ 0      ; enable vesa 1.2 bank switch functions
  79.  
  80. ; Enabling the next line will enable serial output console
  81. ;debug_com_base  equ 0x3f8  ; 0x3f8 is com1, 0x2f8 is com2, 0x3e8 is com3, 0x2e8 is com4, no irq's are used
  82.  
  83. include "proc32.inc"
  84. include "kglobals.inc"
  85. include "lang.inc"
  86. include "encoding.inc"
  87.  
  88. include "const.inc"
  89.  
  90. iglobal
  91. ; The following variable, if equal to 1, duplicates debug output to the screen.
  92. debug_direct_print db 0
  93. ; Start the first app (LAUNCHER) after kernel is loaded? (1=yes, 2 or 0=no)
  94. launcher_start db 1
  95. endg
  96.  
  97. max_processes   equ   255
  98. tss_step         equ   (128+8192) ; tss & i/o - 65535 ports, * 256=557056*4
  99.  
  100. os_stack       equ  (os_data_l-gdts)    ; GDTs
  101. os_code       equ  (os_code_l-gdts)
  102. graph_data     equ  (3+graph_data_l-gdts)
  103. tss0           equ  (tss0_l-gdts)
  104. app_code       equ  (3+app_code_l-gdts)
  105. app_data       equ  (3+app_data_l-gdts)
  106. app_tls       equ  (3+tls_data_l-gdts)
  107. pci_code_sel   equ  (pci_code_32-gdts)
  108. pci_data_sel   equ  (pci_data_32-gdts)
  109.  
  110.  
  111. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  112. ;;
  113. ;;   Included files:
  114. ;;
  115. ;;   Kernel16.inc
  116. ;;    - Booteng.inc   English text for bootup
  117. ;;    - Bootcode.inc  Hardware setup
  118. ;;    - Pci16.inc     PCI functions
  119. ;;
  120. ;;   Kernel32.inc
  121. ;;    - Sys32.inc     Process management
  122. ;;    - Shutdown.inc  Shutdown and restart
  123. ;;    - Fat32.inc     Read / write hd
  124. ;;    - Vesa12.inc    Vesa 1.2 driver
  125. ;;    - Vesa20.inc    Vesa 2.0 driver
  126. ;;    - Vga.inc       VGA driver
  127. ;;    - Stack.inc     Network interface
  128. ;;    - Mouse.inc     Mouse pointer
  129. ;;    - Scincode.inc  Window skinning
  130. ;;    - Pci32.inc     PCI functions
  131. ;;
  132. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  133.  
  134.  
  135. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  136. ;;                                                                      ;;
  137. ;;                  16 BIT ENTRY FROM BOOTSECTOR                        ;;
  138. ;;                                                                      ;;
  139. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  140.  
  141. use16
  142.                   org   0x0
  143.         jmp     start_of_code
  144.  
  145. if lang eq sp
  146. include "kernelsp.inc"  ; spanish kernel messages
  147. else if lang eq et
  148. version db    'Kolibri OS  versioon 0.7.7.0+    ',13,10,13,10,0
  149. else
  150. version db    'Kolibri OS  version 0.7.7.0+     ',13,10,13,10,0
  151. end if
  152.  
  153. include "boot/bootstr.inc"     ; language-independent boot messages
  154. include "boot/preboot.inc"
  155.  
  156. if lang eq ge
  157. include "boot/bootge.inc"     ; german system boot messages
  158. else if lang eq sp
  159. include "boot/bootsp.inc"     ; spanish system boot messages
  160. else if lang eq ru
  161. include "boot/bootru.inc"      ; russian system boot messages
  162. include "boot/ru.inc"          ; Russian font
  163. else if lang eq et
  164. include "boot/bootet.inc"      ; estonian system boot messages
  165. include "boot/et.inc"          ; Estonian font
  166. else
  167. include "boot/booten.inc"      ; english system boot messages
  168. end if
  169.  
  170. include "boot/bootcode.inc"    ; 16 bit system boot code
  171. include "bus/pci/pci16.inc"
  172. include "detect/biosdisk.inc"
  173.  
  174. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  175. ;;                                                                      ;;
  176. ;;                  SWITCH TO 32 BIT PROTECTED MODE                     ;;
  177. ;;                                                                      ;;
  178. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  179.  
  180.         cld
  181.  
  182. ; Enabling 32 bit protected mode
  183.  
  184.         mov     ecx, CR0_PE             ; CR0 Flags - Protected mode and Paging
  185.         lgdt    [cs:tmp_gdt]            ; Load GDT
  186.         mov     eax, cr0                ; protected mode
  187.         or      eax, ecx
  188.         and     eax, 10011111b *65536*256 + 0xffffff ; caching enabled
  189.         mov     cr0, eax
  190.         jmp     pword os_code:B32       ; jmp to enable 32 bit mode
  191.  
  192. align 8
  193. tmp_gdt:
  194.  
  195.         dw     23
  196.         dd     tmp_gdt+0x10000
  197.         dw     0
  198.  
  199.         dw     0xffff
  200.         dw     0x0000
  201.         db     0x00
  202.         dw     11011111b *256 +10011010b
  203.         db     0x00
  204.  
  205.         dw     0xffff
  206.         dw     0x0000
  207.         db     0x00
  208.         dw     11011111b *256 +10010010b
  209.         db     0x00
  210.  
  211. include "data16.inc"
  212.  
  213. if ~ lang eq sp
  214. diff16 "end of bootcode",0,$+0x10000
  215. end if
  216.  
  217. use32
  218. org $+0x10000
  219.  
  220. align 4
  221. B32:
  222.         mov     ax, os_stack       ; Selector for os
  223.         mov     ds, ax
  224.         mov     es, ax
  225.         mov     fs, ax
  226.         mov     gs, ax
  227.         mov     ss, ax
  228.         mov     esp, 0x006CC00       ; Set stack
  229.  
  230. ; CLEAR 0x280000 - HEAP_BASE
  231.  
  232.         xor     eax, eax
  233.         mov     edi, CLEAN_ZONE
  234.         mov     ecx, (HEAP_BASE-OS_BASE-CLEAN_ZONE) / 4
  235.         cld
  236.         rep stosd
  237.  
  238. ; CLEAR KERNEL UNDEFINED GLOBALS
  239.         mov     edi, endofcode-OS_BASE
  240.         mov     ecx, 0x90000
  241.         sub     ecx, edi
  242.         shr     ecx, 2
  243.         rep stosd
  244.  
  245. ; SAVE & CLEAR 0-0xffff
  246.  
  247.         mov     edi, 0x1000
  248.         mov     ecx, 0x8000 / 4
  249.         rep stosd
  250.         mov     edi, 0xa000
  251.         mov     ecx, 0x6000 / 4
  252.         rep stosd
  253.  
  254.         call    test_cpu
  255.         bts     [cpu_caps-OS_BASE], CAPS_TSC    ;force use rdtsc
  256.  
  257.         call    check_acpi
  258.         call    init_BIOS32
  259. ; MEMORY MODEL
  260.         call    mem_test
  261.         call    init_mem
  262.         call    init_page_map
  263.  
  264. ; ENABLE PAGING
  265.  
  266.         mov     eax, sys_proc-OS_BASE+PROC.pdt_0
  267.         mov     cr3, eax
  268.  
  269.         mov     eax, cr0
  270.         or      eax, CR0_PG+CR0_WP
  271.         mov     cr0, eax
  272.  
  273.         lgdt    [gdts]
  274.         jmp     pword os_code:high_code
  275.  
  276. align 4
  277. bios32_entry    dd ?
  278. tmp_page_tabs   dd ?
  279.  
  280. use16
  281. org $-0x10000
  282. include "boot/shutdown.inc" ; shutdown or restart
  283. org $+0x10000
  284.  
  285. ap_init16:
  286.         cli
  287.         lgdt    [cs:gdts_ap-ap_init16]
  288.         mov     eax, [cs:cr3_ap-ap_init16]
  289.         mov     cr3, eax
  290.         mov     eax, [cs:cr4_ap-ap_init16]
  291.         mov     cr4, eax
  292.         mov     eax, CR0_PE+CR0_PG+CR0_WP
  293.         mov     cr0, eax
  294.         jmp     pword os_code:ap_init_high
  295. align 16
  296. gdts_ap:
  297.         dw     gdte-gdts-1
  298.         dd     gdts
  299.         dw     0
  300. cr3_ap  dd     ?
  301. cr4_ap  dd     ?
  302. ap_init16_size = $ - ap_init16
  303. use32
  304.  
  305. __DEBUG__ fix 1
  306. __DEBUG_LEVEL__ fix 1
  307. include 'init.inc'
  308.  
  309. org OS_BASE+$
  310.  
  311. include 'fdo.inc'
  312.  
  313. align 4
  314. high_code:
  315.         mov     ax, os_stack
  316.         mov     bx, app_data
  317.         mov     cx, app_tls
  318.         mov     ss, ax
  319.         add     esp, OS_BASE
  320.  
  321.         mov     ds, bx
  322.         mov     es, bx
  323.         mov     fs, cx
  324.         mov     gs, bx
  325.  
  326.         bt      [cpu_caps], CAPS_PGE
  327.         jnc     @F
  328.  
  329.         or      dword [sys_proc+PROC.pdt_0+(OS_BASE shr 20)], PG_GLOBAL
  330.  
  331.         mov     ebx, cr4
  332.         or      ebx, CR4_PGE
  333.         mov     cr4, ebx
  334. @@:
  335.         xor     eax, eax
  336.         mov     dword [sys_proc+PROC.pdt_0], eax
  337.         mov     dword [sys_proc+PROC.pdt_0+4], eax
  338.  
  339.         mov     eax, cr3
  340.         mov     cr3, eax          ; flush TLB
  341.  
  342.         mov     ecx, pg_data.mutex
  343.         call    mutex_init
  344.  
  345.         mov     ecx, disk_list_mutex
  346.         call    mutex_init
  347.  
  348.         mov     ecx, keyboard_list_mutex
  349.         call    mutex_init
  350.  
  351.         mov     ecx, unpack_mutex
  352.         call    mutex_init
  353.  
  354.         mov     ecx, application_table_mutex
  355.         call    mutex_init
  356.  
  357.         mov     ecx, ide_mutex
  358.         call    mutex_init
  359.         mov     ecx, ide_channel1_mutex
  360.         call    mutex_init
  361.         mov     ecx, ide_channel2_mutex
  362.         call    mutex_init
  363.         mov     ecx, ide_channel3_mutex
  364.         call    mutex_init
  365.         mov     ecx, ide_channel4_mutex
  366.         call    mutex_init
  367.         mov     ecx, ide_channel5_mutex
  368.         call    mutex_init
  369.         mov     ecx, ide_channel6_mutex
  370.         call    mutex_init
  371. ;-----------------------------------------------------------------------------
  372. ; SAVE REAL MODE VARIABLES
  373. ;-----------------------------------------------------------------------------
  374. ; --------------- APM ---------------------
  375.  
  376. ; init selectors
  377.         mov     ebx, [BOOT_VARS+BOOT_APM_ENTRY]        ; offset of APM entry point
  378.         movzx   eax, word [BOOT_VARS+BOOT_APM_CODE_32] ; real-mode segment base address of
  379.                                                                                 ; protected-mode 32-bit code segment
  380.         movzx   ecx, word [BOOT_VARS+BOOT_APM_CODE_16]; real-mode segment base address of
  381.                                                                                 ; protected-mode 16-bit code segment
  382.         movzx   edx, word [BOOT_VARS+BOOT_APM_DATA_16]; real-mode segment base address of
  383.                                                                                 ; protected-mode 16-bit data segment
  384.  
  385.         shl     eax, 4
  386.         mov     [dword apm_code_32 + 2], ax
  387.         shr     eax, 16
  388.         mov     [dword apm_code_32 + 4], al
  389.  
  390.         shl     ecx, 4
  391.         mov     [dword apm_code_16 + 2], cx
  392.         shr     ecx, 16
  393.         mov     [dword apm_code_16 + 4], cl
  394.  
  395.         shl     edx, 4
  396.         mov     [dword apm_data_16 + 2], dx
  397.         shr     edx, 16
  398.         mov     [dword apm_data_16 + 4], dl
  399.  
  400.         mov     dword[apm_entry], ebx
  401.         mov     word [apm_entry + 4], apm_code_32 - gdts
  402.  
  403.         mov     eax, [BOOT_VARS + BOOT_APM_VERSION] ; version & flags
  404.         mov     [apm_vf], eax
  405. ; -----------------------------------------
  406.         mov     al, [BOOT_VARS+BOOT_DMA]            ; DMA access
  407.         mov     [allow_dma_access], al
  408.         movzx   eax, byte [BOOT_VARS+BOOT_BPP]      ; bpp
  409.         mov     [_display.bpp], eax
  410.         mov     [_display.vrefresh], 60
  411.         mov     al, [BOOT_VARS+BOOT_DEBUG_PRINT]    ; If nonzero, duplicates debug output to the screen
  412.         mov     [debug_direct_print], al
  413.         mov     al, [BOOT_VARS+BOOT_LAUNCHER_START] ; Start the first app (LAUNCHER) after kernel is loaded?
  414.         mov     [launcher_start], al
  415.         movzx   eax, word [BOOT_VARS+BOOT_X_RES]; X max
  416.         mov     [_display.width], eax
  417.         mov     [display_width_standard], eax
  418.         dec     eax
  419.         mov     [Screen_Max_X], eax
  420.         mov     [screen_workarea.right], eax
  421.         movzx   eax, word [BOOT_VARS+BOOT_Y_RES]; Y max
  422.         mov     [_display.height], eax
  423.         mov     [display_height_standard], eax
  424.         dec     eax
  425.         mov     [Screen_Max_Y], eax
  426.         mov     [screen_workarea.bottom], eax
  427.         movzx   eax, word [BOOT_VARS+BOOT_VESA_MODE] ; screen mode
  428.         mov     dword [SCR_MODE], eax
  429. ;        mov     eax, [BOOT_VAR+0x9014]             ; Vesa 1.2 bnk sw add
  430. ;        mov     [BANK_SWITCH], eax
  431.         mov     eax, 640 *4                         ; Bytes PerScanLine
  432.         cmp     [SCR_MODE], word 0x13               ; 320x200
  433.         je      @f
  434.         cmp     [SCR_MODE], word 0x12               ; VGA 640x480
  435.         je      @f
  436.         movzx   eax, word[BOOT_VARS+BOOT_PITCH]      ; for other modes
  437. @@:
  438.         mov     [_display.pitch], eax
  439.         mov     eax, [_display.width]
  440.         mul     [_display.height]
  441.         mov     [_WinMapSize], eax
  442.  
  443.         call    calculate_fast_getting_offset_for_WinMapAddress
  444. ; for Qemu or non standart video cards
  445. ; Unfortunately [BytesPerScanLine] does not always
  446. ;                             equal to [_display.width] * [ScreenBPP] / 8
  447.         call    calculate_fast_getting_offset_for_LFB
  448.  
  449.         mov     esi, BOOT_VARS+0x9080
  450.         movzx   ecx, byte [esi-1]
  451.         mov     [NumBiosDisks], ecx
  452.         mov     edi, BiosDisksData
  453.         rep movsd
  454.  
  455. ; GRAPHICS ADDRESSES
  456.  
  457.         mov     eax, [BOOT_VARS+BOOT_LFB]
  458.         mov     [LFBAddress], eax
  459.  
  460.         cmp     [SCR_MODE], word 0100000000000000b
  461.         jge     setvesa20
  462.         cmp     [SCR_MODE], word 0x13  ; EGA 320*200 256 colors
  463.         je      v20ga32
  464.         jmp     v20ga24
  465.  
  466. setvesa20:
  467.         mov     [PUTPIXEL], dword Vesa20_putpixel24 ; Vesa 2.0
  468.         mov     [GETPIXEL], dword Vesa20_getpixel24
  469.         cmp     byte [_display.bpp], 24
  470.         jz      v20ga24
  471. v20ga32:
  472.         mov     [PUTPIXEL], dword Vesa20_putpixel32
  473.         mov     [GETPIXEL], dword Vesa20_getpixel32
  474.         jmp     no_mode_0x12
  475. v20ga24:
  476.         cmp     [SCR_MODE], word 0x12               ; 16 C VGA 640x480
  477.         jne     no_mode_0x12
  478.         mov     [PUTPIXEL], dword VGA_putpixel
  479.         mov     [GETPIXEL], dword Vesa20_getpixel32
  480. no_mode_0x12:
  481.  
  482.         mov     [MOUSE_PICTURE], dword mousepointer
  483.         mov     [_display.check_mouse], check_mouse_area_for_putpixel
  484.         mov     [_display.check_m_pixel], check_mouse_area_for_getpixel
  485.  
  486. ; -------- Fast System Call init ----------
  487. ; Intel SYSENTER/SYSEXIT (AMD CPU support it too)
  488.         bt      [cpu_caps], CAPS_SEP
  489.         jnc     .SEnP  ; SysEnter not Present
  490.         xor     edx, edx
  491.         mov     ecx, MSR_SYSENTER_CS
  492.         mov     eax, os_code
  493.         wrmsr
  494.         mov     ecx, MSR_SYSENTER_ESP
  495. ;           mov eax, sysenter_stack ; Check it
  496.         xor     eax, eax
  497.         wrmsr
  498.         mov     ecx, MSR_SYSENTER_EIP
  499.         mov     eax, sysenter_entry
  500.         wrmsr
  501. .SEnP:
  502. ; AMD SYSCALL/SYSRET
  503.         cmp     byte[cpu_vendor], 'A'
  504.         jne     .noSYSCALL
  505.         mov     eax, 0x80000001
  506.         cpuid
  507.         test    edx, 0x800  ; bit_11 - SYSCALL/SYSRET support
  508.         jz      .noSYSCALL
  509.         mov     ecx, MSR_AMD_EFER
  510.         rdmsr
  511.         or      eax, 1 ; bit_0 - System Call Extension (SCE)
  512.         wrmsr
  513.  
  514.         ; !!!! It`s dirty hack, fix it !!!
  515.         ; Bits of EDX :
  516.         ; Bit 31–16 During the SYSRET instruction, this field is copied into the CS register
  517.         ;  and the contents of this field, plus 8, are copied into the SS register.
  518.         ; Bit 15–0 During the SYSCALL instruction, this field is copied into the CS register
  519.         ;  and the contents of this field, plus 8, are copied into the SS register.
  520.  
  521.         ; mov   edx, (os_code + 16) * 65536 + os_code
  522.         mov     edx, 0x1B0008
  523.  
  524.         mov     eax, syscall_entry
  525.         mov     ecx, MSR_AMD_STAR
  526.         wrmsr
  527. .noSYSCALL:
  528. ; -----------------------------------------
  529.         stdcall alloc_page
  530.         stdcall map_page, tss-0xF80, eax, PG_SW
  531.         stdcall alloc_page
  532.         stdcall map_page, tss+0x80, eax, PG_SW
  533.         stdcall alloc_page
  534.         stdcall map_page, tss+0x1080, eax, PG_SW
  535.  
  536. ; LOAD IDT
  537.  
  538.         call    build_interrupt_table ;lidt is executed
  539.           ;lidt [idtreg]
  540.  
  541.         call    init_kernel_heap
  542.         stdcall kernel_alloc, (RING0_STACK_SIZE+512) * 2
  543.         mov     [os_stack_seg], eax
  544.  
  545.         lea     esp, [eax+RING0_STACK_SIZE]
  546.  
  547.         mov     [tss._ss0], os_stack
  548.         mov     [tss._esp0], esp
  549.         mov     [tss._esp], esp
  550.         mov     [tss._cs], os_code
  551.         mov     [tss._ss], os_stack
  552.         mov     [tss._ds], app_data
  553.         mov     [tss._es], app_data
  554.         mov     [tss._fs], app_data
  555.         mov     [tss._gs], app_data
  556.         mov     [tss._io], 128
  557. ;Add IO access table - bit array of permitted ports
  558.         mov     edi, tss._io_map_0
  559.         xor     eax, eax
  560.         not     eax
  561.         mov     ecx, 8192/4
  562.         rep stosd                    ; access to 4096*8=65536 ports
  563.  
  564.         mov     ax, tss0
  565.         ltr     ax
  566.  
  567.         mov     [LFBSize], 0xC00000
  568.         call    init_LFB
  569.         call    init_fpu
  570.         call    init_malloc
  571.  
  572.         stdcall alloc_kernel_space, 0x50000         ; FIXME check size
  573.         mov     [default_io_map], eax
  574.  
  575.         add     eax, 0x2000
  576.         mov     [ipc_tmp], eax
  577.         mov     ebx, 0x1000
  578.  
  579.         add     eax, 0x40000
  580.         mov     [proc_mem_map], eax
  581.  
  582.         add     eax, 0x8000
  583.         mov     [proc_mem_pdir], eax
  584.  
  585.         add     eax, ebx
  586.         mov     [proc_mem_tab], eax
  587.  
  588.         add     eax, ebx
  589.         mov     [tmp_task_ptab], eax
  590.  
  591.         add     eax, ebx
  592.         mov     [ipc_pdir], eax
  593.  
  594.         add     eax, ebx
  595.         mov     [ipc_ptab], eax
  596.  
  597.         stdcall kernel_alloc, (unpack.LZMA_BASE_SIZE+(unpack.LZMA_LIT_SIZE shl \
  598.                 (unpack.lc+unpack.lp)))*4
  599.  
  600.         mov     [unpack.p], eax
  601.  
  602.         call    init_events
  603.         mov     eax, srv.fd-SRV.fd
  604.         mov     [srv.fd], eax
  605.         mov     [srv.bk], eax
  606.  
  607. ;Set base of graphic segment to linear address of LFB
  608.         mov     eax, [LFBAddress]         ; set for gs
  609.         mov     [graph_data_l+2], ax
  610.         shr     eax, 16
  611.         mov     [graph_data_l+4], al
  612.         mov     [graph_data_l+7], ah
  613.  
  614.         stdcall kernel_alloc, [_WinMapSize]
  615.         mov     [_WinMapAddress], eax
  616.  
  617.         xor     eax, eax
  618.         inc     eax
  619.  
  620. ; set background
  621.  
  622.         mov     [BgrDrawMode], eax
  623.         mov     [BgrDataWidth], eax
  624.         mov     [BgrDataHeight], eax
  625.         mov     [mem_BACKGROUND], 4
  626.         mov     [img_background], static_background_data
  627.  
  628. ; set clipboard
  629.  
  630.         xor     eax, eax
  631.         mov     [clipboard_slots], eax
  632.         mov     [clipboard_write_lock], eax
  633.         stdcall kernel_alloc, 4096
  634.         test    eax, eax
  635.         jnz     @f
  636.  
  637.         dec     eax
  638. @@:
  639.         mov     [clipboard_main_list], eax
  640.  
  641. ; SET UP OS TASK
  642.  
  643.         mov     esi, boot_setostask
  644.         call    boot_log
  645.  
  646.         mov     edi, sys_proc
  647.         list_init edi
  648.         lea     ecx, [edi+PROC.thr_list]
  649.         list_init ecx
  650.         mov     [edi+PROC.pdt_0_phys], sys_proc-OS_BASE+PROC.pdt_0
  651.  
  652.         mov     eax, -1
  653.         mov     edi, thr_slot_map+4
  654.         mov     [edi-4], dword 0xFFFFFFF8
  655.         stosd
  656.         stosd
  657.         stosd
  658.         stosd
  659.         stosd
  660.         stosd
  661.         stosd
  662.  
  663.         mov     [current_process], sys_proc
  664.  
  665.         mov     edx, SLOT_BASE+256*1
  666.         mov     ebx, [os_stack_seg]
  667.         add     ebx, 0x2000
  668.         call    setup_os_slot
  669.         mov     dword [edx], 'IDLE'
  670.         sub     [edx+APPDATA.saved_esp], 4
  671.         mov     eax, [edx+APPDATA.saved_esp]
  672.         mov     dword [eax], idle_thread
  673.         mov     ecx, IDLE_PRIORITY
  674.         call    scheduler_add_thread
  675.  
  676.         mov     edx, SLOT_BASE+256*2
  677.         mov     ebx, [os_stack_seg]
  678.         call    setup_os_slot
  679.         mov     dword [edx], 'OS'
  680.         xor     ecx, ecx
  681.         call    scheduler_add_thread
  682.  
  683.         mov     dword [CURRENT_TASK], 2
  684.         mov     dword [TASK_COUNT], 2
  685.         mov     dword [current_slot], SLOT_BASE + 256*2
  686.         mov     dword [TASK_BASE], CURRENT_TASK + 32*2
  687.  
  688. ; Move other CPUs to deep sleep, if it is useful
  689. uglobal
  690. use_mwait_for_idle db 0
  691. endg
  692.         cmp     [cpu_vendor+8], 'ntel'
  693.         jnz     .no_wake_cpus
  694.         bt      [cpu_caps+4], CAPS_MONITOR-32
  695.         jnc     .no_wake_cpus
  696.         dbgstr 'using mwait for idle loop'
  697.         inc     [use_mwait_for_idle]
  698.         mov     ebx, [cpu_count]
  699.         cmp     ebx, 1
  700.         jbe     .no_wake_cpus
  701.         call    create_trampoline_pgmap
  702.         mov     [cr3_ap+OS_BASE], eax
  703.         mov     eax, cr4
  704.         mov     [cr4_ap+OS_BASE], eax
  705.         mov     esi, OS_BASE + ap_init16
  706.         mov     edi, OS_BASE + 8000h
  707.         mov     ecx, (ap_init16_size + 3) / 4
  708.         rep movsd
  709.         stdcall map_io_mem, [acpi_lapic_base], 0x1000, PG_SW+PG_NOCACHE
  710.         mov     [LAPIC_BASE], eax
  711.         lea     edi, [eax+300h]
  712.         mov     esi, smpt+4
  713.         dec     ebx
  714. .wake_cpus_loop:
  715.         lodsd
  716.         push    esi
  717.         xor     esi, esi
  718.         inc     esi
  719.         shl     eax, 24
  720.         mov     [edi+10h], eax
  721. ; assert INIT IPI
  722.         mov     dword [edi], 0C500h
  723.         call    delay_ms
  724. @@:
  725.         test    dword [edi], 1000h
  726.         jnz     @b
  727. ; deassert INIT IPI
  728.         mov     dword [edi], 8500h
  729.         call    delay_ms
  730. @@:
  731.         test    dword [edi], 1000h
  732.         jnz     @b
  733. ; send STARTUP IPI
  734.         mov     dword [edi], 600h + (8000h shr 12)
  735.         call    delay_ms
  736. @@:
  737.         test    dword [edi], 1000h
  738.         jnz     @b
  739.         pop     esi
  740.         dec     ebx
  741.         jnz     .wake_cpus_loop
  742.         mov     eax, [cpu_count]
  743.         dec     eax
  744. @@:
  745.         cmp     [ap_initialized], eax
  746.         jnz     @b
  747.         mov     eax, [cr3_ap+OS_BASE]
  748.         call    free_page
  749. .no_wake_cpus:
  750.  
  751.  
  752. ; REDIRECT ALL IRQ'S TO INT'S 0x20-0x2f
  753.         mov     esi, boot_initirq
  754.         call    boot_log
  755.         call    init_irqs
  756.  
  757.         mov     esi, boot_picinit
  758.         call    boot_log
  759.         call    PIC_init
  760.  
  761.         mov     esi, boot_v86machine
  762.         call    boot_log
  763. ; Initialize system V86 machine
  764.         call    init_sys_v86
  765.  
  766.         mov     esi, boot_inittimer
  767.         call    boot_log
  768. ; Initialize system timer (IRQ0)
  769.         call    PIT_init
  770.  
  771. ; Register ramdisk file system
  772.         cmp     [boot_dev+OS_BASE+0x10000], 1
  773.         je      @f
  774.  
  775.         call    register_ramdisk
  776. ;--------------------------------------
  777. @@:
  778.         mov     esi, boot_initapic
  779.         call    boot_log
  780. ; Try to Initialize APIC
  781.         call    APIC_init
  782.  
  783.         mov     esi, boot_enableirq
  784.         call    boot_log
  785. ; Enable timer IRQ (IRQ0) and co-processor IRQ (IRQ13)
  786. ; they are used: when partitions are scanned, hd_read relies on timer
  787.         call    unmask_timer
  788.         stdcall enable_irq, 2               ; @#$%! PIC
  789.         stdcall enable_irq, 13              ; co-processor
  790.  
  791. ; Setup serial output console (if enabled)
  792. if defined debug_com_base
  793.  
  794.         ; reserve port so nobody else will use it
  795.         xor     ebx, ebx
  796.         mov     ecx, debug_com_base
  797.         mov     edx, debug_com_base+7
  798.         call    r_f_port_area
  799.  
  800.         ; enable Divisor latch
  801.         mov     dx, debug_com_base+3
  802.         mov     al, 1 shl 7
  803.         out     dx, al
  804.  
  805.         ; Set speed to 115200 baud (max speed)
  806.         mov     dx, debug_com_base
  807.         mov     al, 0x01
  808.         out     dx, al
  809.  
  810.         mov     dx, debug_com_base+1
  811.         mov     al, 0x00
  812.         out     dx, al
  813.  
  814.         ; No parity, 8bits words, one stop bit, dlab bit back to 0
  815.         mov     dx, debug_com_base+3
  816.         mov     al, 3
  817.         out     dx, al
  818.  
  819.         ; disable interrupts
  820.         mov     dx, debug_com_base+1
  821.         mov     al, 0
  822.         out     dx, al
  823.  
  824.         ; clear +  enable fifo (64 bits)
  825.         mov     dx, debug_com_base+2
  826.         mov     al, 0x7 + 1 shl 5
  827.         out     dx, al
  828.  
  829. end if
  830.  
  831.  
  832. ;-----------------------------------------------------------------------------
  833. ; show SVN version of kernel on the message board
  834. ;-----------------------------------------------------------------------------
  835.         mov     eax, [version_inf.rev]
  836.         DEBUGF  1, "K : kernel SVN r%d\n", eax
  837. ;-----------------------------------------------------------------------------
  838. ; show CPU count on the message board
  839. ;-----------------------------------------------------------------------------
  840.         mov     eax, [cpu_count]
  841.         test    eax, eax
  842.         jnz     @F
  843.         mov     al, 1                             ; at least one CPU
  844. @@:
  845.         DEBUGF  1, "K : %d CPU detected\n", eax
  846. ;-----------------------------------------------------------------------------
  847. ; detect Floppy drives
  848. ;-----------------------------------------------------------------------------
  849.         mov     esi, boot_detectfloppy
  850.         call    boot_log
  851. include 'detect/dev_fd.inc'
  852. ;-----------------------------------------------------------------------------
  853. ; create pci-devices list
  854. ;-----------------------------------------------------------------------------
  855.         mov     [pci_access_enabled], 1
  856.         call    pci_enum
  857. ;-----------------------------------------------------------------------------
  858. ; initialisation IDE ATA code
  859. ;-----------------------------------------------------------------------------
  860. include 'detect/init_ata.inc'
  861. ;-----------------------------------------------------------------------------
  862. if 0
  863.         mov     ax, [OS_BASE+0x10000+bx_from_load]
  864.         cmp     ax, 'r1'; if using not ram disk, then load librares and parameters {SPraid.simba}
  865.         je      no_lib_load
  866.  
  867.         mov     esi, boot_loadlibs
  868.         call    boot_log
  869. ; LOADING LIBRARES
  870.         stdcall dll.Load, @IMPORT           ; loading librares for kernel (.obj files)
  871.         call    load_file_parse_table       ; prepare file parse table
  872.         call    set_kernel_conf             ; configure devices and gui
  873. no_lib_load:
  874. end if
  875.  
  876. ; Display APIC status
  877.         mov     esi, boot_APIC_found
  878.         cmp     [irq_mode], IRQ_APIC
  879.         je      @f
  880.         mov     esi, boot_APIC_nfound
  881. @@:
  882.         call    boot_log
  883.  
  884. ; PRINT AMOUNT OF MEMORY
  885.         mov     esi, boot_memdetect
  886.         call    boot_log
  887.  
  888.         movzx   ecx, word [boot_y]
  889.         if lang eq ru
  890.         or      ecx, (10+30*6) shl 16
  891.         else if lang eq sp
  892.         or      ecx, (10+33*6) shl 16
  893.         else
  894.         or      ecx, (10+29*6) shl 16
  895.         end if
  896.         sub     ecx, 10
  897.         mov     edx, 0xFFFFFF
  898.         mov     ebx, [MEM_AMOUNT]
  899.         shr     ebx, 20
  900.         xor     edi, edi
  901.         mov     eax, 0x00040000
  902.         inc     edi
  903.         call    display_number_force
  904.  
  905. ; BUILD SCHEDULER
  906.  
  907. ;        call    build_scheduler; sys32.inc
  908.  
  909. ;        mov     esi, boot_devices
  910. ;        call    boot_log
  911.  
  912.         call    clear_pci_ide_interrupts
  913.  
  914. include "detect/vortex86.inc"                     ; Vortex86 SoC detection code
  915.  
  916.         stdcall load_pe_driver, szVidintel, 0
  917.  
  918.         call    usb_init
  919.  
  920. ; SET PRELIMINARY WINDOW STACK AND POSITIONS
  921.  
  922.         mov     esi, boot_windefs
  923.         call    boot_log
  924.         call    set_window_defaults
  925.  
  926. ; SET BACKGROUND DEFAULTS
  927.  
  928.         mov     esi, boot_bgr
  929.         call    boot_log
  930.         call    init_background
  931.         call    calculatebackground
  932.  
  933. ; RESERVE SYSTEM IRQ'S JA PORT'S
  934.  
  935.         mov     esi, boot_resirqports
  936.         call    boot_log
  937.         call    reserve_irqs_ports
  938.  
  939.         call    init_display
  940.         mov     eax, [def_cursor]
  941.         mov     [SLOT_BASE+APPDATA.cursor+256], eax
  942.         mov     [SLOT_BASE+APPDATA.cursor+256*2], eax
  943.  
  944. ; PRINT CPU FREQUENCY
  945.  
  946.         mov     esi, boot_cpufreq
  947.         call    boot_log
  948.  
  949.         cli                         ;FIXME check IF
  950.         rdtsc
  951.         mov     ecx, eax
  952.         mov     esi, 250            ; wait 1/4 a second
  953.         call    delay_ms
  954.         rdtsc
  955.         sti
  956.  
  957.         sub     eax, ecx
  958.         xor     edx, edx
  959.         shld    edx, eax, 2
  960.         shl     eax, 2
  961.         mov     dword [cpu_freq], eax
  962.         mov     dword [cpu_freq+4], edx
  963.         mov     ebx, 1000000
  964.         div     ebx
  965.         mov     ebx, eax
  966.  
  967.         movzx   ecx, word [boot_y]
  968.         if lang eq ru
  969.         add     ecx, (10+19*6) shl 16 - 10
  970.         else if lang eq sp
  971.         add     ecx, (10+25*6) shl 16 - 10
  972.         else
  973.         add     ecx, (10+17*6) shl 16 - 10
  974.         end if
  975.  
  976.         mov     edx, 0xFFFFFF
  977.         xor     edi, edi
  978.         mov     eax, 0x00040000
  979.         inc     edi
  980.         call    display_number_force
  981.  
  982. ; SET VARIABLES
  983.  
  984.         call    set_variables
  985.  
  986. ; STACK AND FDC
  987.  
  988.         call    stack_init
  989.         call    fdc_init
  990.  
  991. ; PALETTE FOR 320x200 and 640x480 16 col
  992.  
  993.         cmp     [SCR_MODE], word 0x12
  994.         jne     no_pal_vga
  995.         mov     esi, boot_pal_vga
  996.         call    boot_log
  997.         call    paletteVGA
  998.       no_pal_vga:
  999.  
  1000.         cmp     [SCR_MODE], word 0x13
  1001.         jne     no_pal_ega
  1002.         mov     esi, boot_pal_ega
  1003.         call    boot_log
  1004.         call    palette320x200
  1005.       no_pal_ega:
  1006.  
  1007. ; LOAD DEFAULT SKIN
  1008.  
  1009.         call    load_default_skin
  1010.  
  1011. ;protect io permission map
  1012.  
  1013.         mov     esi, [default_io_map]
  1014.         stdcall map_page, esi, [SLOT_BASE+256+APPDATA.io_map], PG_MAP
  1015.         add     esi, 0x1000
  1016.         stdcall map_page, esi, [SLOT_BASE+256+APPDATA.io_map+4], PG_MAP
  1017.  
  1018.         stdcall map_page, tss._io_map_0, \
  1019.                 [SLOT_BASE+256+APPDATA.io_map], PG_MAP
  1020.         stdcall map_page, tss._io_map_1, \
  1021.                 [SLOT_BASE+256+APPDATA.io_map+4], PG_MAP
  1022.  
  1023. ; SET KEYBOARD PARAMETERS
  1024.         mov     al, 0xf6       ; reset keyboard, scan enabled
  1025.         call    kb_write_wait_ack
  1026.         test    ah, ah
  1027.         jnz     .no_keyboard
  1028.  
  1029. iglobal
  1030. align 4
  1031. ps2_keyboard_functions:
  1032.         dd      .end - $
  1033.         dd      0       ; no close
  1034.         dd      ps2_set_lights
  1035. .end:
  1036. endg
  1037.         stdcall register_keyboard, ps2_keyboard_functions, 0
  1038.        ; mov   al, 0xED       ; Keyboard LEDs - only for testing!
  1039.        ; call  kb_write_wait_ack
  1040.        ; mov   al, 111b
  1041.        ; call  kb_write_wait_ack
  1042.  
  1043.         mov     al, 0xF3     ; set repeat rate & delay
  1044.         call    kb_write_wait_ack
  1045.         mov     al, 0; 30 250 ;00100010b ; 24 500  ;00100100b  ; 20 500
  1046.         call    kb_write_wait_ack
  1047.      ;// mike.dld [
  1048.         call    set_lights
  1049.      ;// mike.dld ]
  1050.         stdcall attach_int_handler, 1, irq1, 0
  1051.         DEBUGF  1, "K : IRQ1 return code %x\n", eax
  1052. .no_keyboard:
  1053.  
  1054. ; Load PS/2 mouse driver
  1055.  
  1056.         stdcall load_pe_driver, szPS2MDriver, 0
  1057.  
  1058.         mov     esi, boot_setmouse
  1059.         call    boot_log
  1060.         call    setmouse
  1061.  
  1062. ; LOAD FIRST APPLICATION
  1063.         cmp     byte [launcher_start], 1        ; Check if starting LAUNCHER is selected on blue screen (1 = yes)
  1064.         jnz     first_app_found
  1065.  
  1066.         cli
  1067.         mov     ebp, firstapp
  1068.         call    fs_execute_from_sysdir
  1069.         test    eax, eax
  1070.         jns     first_app_found
  1071.  
  1072.         mov     esi, boot_failed
  1073.         call    boot_log
  1074.  
  1075.         mov     eax, 0xDEADBEEF      ; otherwise halt
  1076.         hlt
  1077.  
  1078. first_app_found:
  1079.  
  1080. ; START MULTITASKING
  1081.  
  1082. ; A 'All set - press ESC to start' messages if need
  1083. if preboot_blogesc
  1084.         mov     esi, boot_tasking
  1085.         call    boot_log
  1086. .bll1:
  1087.         in      al, 0x60        ; wait for ESC key press
  1088.         cmp     al, 129
  1089.         jne     .bll1
  1090. end if
  1091.  
  1092.         mov     [timer_ticks_enable], 1         ; for cd driver
  1093.  
  1094.         sti
  1095.  
  1096.         call    mtrr_validate
  1097.  
  1098.         jmp     osloop
  1099.  
  1100.  
  1101.         ; Fly :)
  1102.  
  1103. uglobal
  1104. align 4
  1105. ap_initialized  dd      0
  1106. endg
  1107.  
  1108. ap_init_high:
  1109.         mov     ax, os_stack
  1110.         mov     bx, app_data
  1111.         mov     cx, app_tls
  1112.         mov     ss, ax
  1113.         mov     ds, bx
  1114.         mov     es, bx
  1115.         mov     fs, cx
  1116.         mov     gs, bx
  1117.         xor     esp, esp
  1118.         mov     eax, sys_proc-OS_BASE+PROC.pdt_0
  1119.         mov     cr3, eax
  1120.         lock inc [ap_initialized]
  1121.         jmp     idle_loop
  1122.  
  1123.  
  1124. include 'unpacker.inc'
  1125.  
  1126. align 4
  1127. boot_log:
  1128.         pushad
  1129.  
  1130.         mov     ebx, 10*65536
  1131.         mov     bx, word [boot_y]
  1132.         add     [boot_y], dword 10
  1133.         mov     ecx, 0x80ffffff; ASCIIZ string with white color
  1134.         xor     edi, edi
  1135.         mov     edx, esi
  1136.         inc     edi
  1137.         call    dtext
  1138.  
  1139.         mov     [novesachecksum], 1000
  1140.         call    checkVga_N13
  1141.  
  1142.         popad
  1143.  
  1144.         ret
  1145.  
  1146. ; in: edx -> APPDATA for OS/IDLE slot
  1147. ; in: ebx = stack base
  1148. proc setup_os_slot
  1149.         xor     eax, eax
  1150.         mov     ecx, 256/4
  1151.         mov     edi, edx
  1152.         rep stosd
  1153.  
  1154.         mov     eax, tss+0x80
  1155.         call    get_pg_addr
  1156.         inc     eax
  1157.         mov     [edx+APPDATA.io_map], eax
  1158.         mov     eax, tss+0x1080
  1159.         call    get_pg_addr
  1160.         inc     eax
  1161.         mov     [edx+APPDATA.io_map+4], eax
  1162.  
  1163.         mov     dword [edx+APPDATA.pl0_stack], ebx
  1164.         lea     edi, [ebx+0x2000-512]
  1165.         mov     dword [edx+APPDATA.fpu_state], edi
  1166.         mov     dword [edx+APPDATA.saved_esp0], edi
  1167.         mov     dword [edx+APPDATA.saved_esp], edi
  1168.         mov     dword [edx+APPDATA.terminate_protection], 1 ; make unkillable
  1169.  
  1170.         mov     esi, fpu_data
  1171.         mov     ecx, 512/4
  1172.         cld
  1173.         rep movsd
  1174.  
  1175.         lea     eax, [edx+APP_OBJ_OFFSET]
  1176.         mov     dword [edx+APPDATA.fd_obj], eax
  1177.         mov     dword [edx+APPDATA.bk_obj], eax
  1178.  
  1179.         mov     dword [edx+APPDATA.cur_dir], sysdir_path
  1180.  
  1181.         mov     [edx + APPDATA.process], sys_proc
  1182.  
  1183.         mov     eax, edx
  1184.         shr     eax, 3
  1185.         add     eax, CURRENT_TASK - (SLOT_BASE shr 3)
  1186.         mov     [eax+TASKDATA.wnd_number], dh
  1187.         mov     byte [eax+TASKDATA.pid], dh
  1188.  
  1189.         ret
  1190. endp
  1191.  
  1192. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1193. ;                                                                    ;
  1194. ;                    MAIN OS LOOP START                              ;
  1195. ;                                                                    ;
  1196. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1197. align 32
  1198. osloop:
  1199.         mov     edx, osloop_has_work?
  1200.         xor     ecx, ecx
  1201.         call    Wait_events
  1202.         xor     eax, eax
  1203.         xchg    eax, [osloop_nonperiodic_work]
  1204.         test    eax, eax
  1205.         jz      .no_periodic
  1206.  
  1207.         call    __sys_draw_pointer
  1208.         call    window_check_events
  1209.         call    mouse_check_events
  1210.         call    checkmisc
  1211.         call    checkVga_N13
  1212. ;--------------------------------------
  1213. .no_periodic:
  1214.         call    stack_handler
  1215.         call    check_fdd_motor_status
  1216.         call    check_ATAPI_device_event
  1217.         call    check_lights_state
  1218.         call    check_timers
  1219.  
  1220.         jmp     osloop
  1221. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1222. ;                                                                    ;
  1223. ;                      MAIN OS LOOP END                              ;
  1224. ;                                                                    ;
  1225. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1226. proc osloop_has_work?
  1227.         cmp     [osloop_nonperiodic_work], 0
  1228.         jnz     .yes
  1229.         call    stack_handler_has_work?
  1230.         jnz     .yes
  1231.         call    check_fdd_motor_status_has_work?
  1232.         jnz     .yes
  1233.         call    check_ATAPI_device_event_has_work?
  1234.         jnz     .yes
  1235.         call    check_lights_state_has_work?
  1236.         jnz     .yes
  1237.         call    check_timers_has_work?
  1238.         jnz     .yes
  1239. .no:
  1240.         xor     eax, eax
  1241.         ret
  1242. .yes:
  1243.         xor     eax, eax
  1244.         inc     eax
  1245.         ret
  1246. endp
  1247.  
  1248. proc wakeup_osloop
  1249.         mov     [osloop_nonperiodic_work], 1
  1250.         ret
  1251. endp
  1252.  
  1253. uglobal
  1254. align 4
  1255. osloop_nonperiodic_work dd      ?
  1256. endg
  1257.  
  1258. uglobal
  1259. align 64
  1260. idle_addr       rb      64
  1261. endg
  1262.  
  1263. idle_thread:
  1264.         sti
  1265.  
  1266. ; The following code can be executed by all CPUs in the system.
  1267. ; All other parts of the kernel do not expect multi-CPU.
  1268. ; Also, APs don't even have a stack here.
  1269. ; Beware. Don't do anything here. Anything at all.
  1270. idle_loop:
  1271.         cmp     [use_mwait_for_idle], 0
  1272.         jnz     idle_loop_mwait
  1273.  
  1274. idle_loop_hlt:
  1275.         hlt
  1276.         jmp     idle_loop_hlt
  1277.  
  1278. idle_loop_mwait:
  1279.         mov     eax, idle_addr
  1280.         xor     ecx, ecx
  1281.         xor     edx, edx
  1282.         monitor
  1283.         xor     ecx, ecx
  1284.         mov     eax, 20h        ; or 10h
  1285.         mwait
  1286.         jmp     idle_loop_mwait
  1287.  
  1288.  
  1289. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1290. ;                                                                      ;
  1291. ;                   INCLUDED SYSTEM FILES                              ;
  1292. ;                                                                      ;
  1293. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1294.  
  1295.  
  1296. include "kernel32.inc"
  1297.  
  1298.  
  1299. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1300. ;                                                                      ;
  1301. ;                       KERNEL FUNCTIONS                               ;
  1302. ;                                                                      ;
  1303. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1304.  
  1305. reserve_irqs_ports:
  1306.  
  1307.  
  1308. ; RESERVE PORTS
  1309.         mov     eax, RESERVED_PORTS
  1310.         mov     ecx, 1
  1311.  
  1312.         mov     [eax], dword 4
  1313.  
  1314.         mov     [eax+16], ecx
  1315.         mov     [eax+16+4], dword 0
  1316.         mov     [eax+16+8], dword 0x2D
  1317.  
  1318.         mov     [eax+32], ecx
  1319.         mov     [eax+32+4], dword 0x30
  1320.         mov     [eax+32+8], dword 0x4D
  1321.  
  1322.         mov     [eax+48], ecx
  1323.         mov     [eax+48+4], dword 0x50
  1324.         mov     [eax+48+8], dword 0xDF
  1325.  
  1326.         mov     [eax+64], ecx
  1327.         mov     [eax+64+4], dword 0xE5
  1328.         mov     [eax+64+8], dword 0xFF
  1329.  
  1330.         ret
  1331.  
  1332.  
  1333. iglobal
  1334.   process_number dd 0x2
  1335. endg
  1336.  
  1337. set_variables:
  1338.  
  1339.         mov     ecx, 0x16                    ; flush port 0x60
  1340. .fl60:
  1341.         in      al, 0x60
  1342.         loop    .fl60
  1343.         push    eax
  1344.  
  1345.         mov     ax, [BOOT_VARS+BOOT_Y_RES]
  1346.         shr     ax, 1
  1347.         shl     eax, 16
  1348.         mov     ax, [BOOT_VARS+BOOT_X_RES]
  1349.         shr     ax, 1
  1350.         mov     [MOUSE_X], eax
  1351.         call    wakeup_osloop
  1352.  
  1353.         xor     eax, eax
  1354.         mov     [BTN_ADDR], dword BUTTON_INFO ; address of button list
  1355.  
  1356.         mov     byte [KEY_COUNT], al              ; keyboard buffer
  1357.         mov     byte [BTN_COUNT], al              ; button buffer
  1358. ;        mov   [MOUSE_X],dword 100*65536+100    ; mouse x/y
  1359.  
  1360.         pop     eax
  1361.         ret
  1362.  
  1363. align 4
  1364. ;input  eax=43,bl-byte of output, ecx - number of port
  1365. sys_outport:
  1366.  
  1367.         mov     edi, ecx   ; separate flag for read / write
  1368.         and     ecx, 65535
  1369.  
  1370.         mov     eax, [RESERVED_PORTS]
  1371.         test    eax, eax
  1372.         jnz     .sopl8
  1373.         inc     eax
  1374.         mov     [esp+32], eax
  1375.         ret
  1376.  
  1377.   .sopl8:
  1378.         mov     edx, [TASK_BASE]
  1379.         mov     edx, [edx+0x4]
  1380.     ;and   ecx,65535
  1381.     ;cld - set on interrupt 0x40
  1382.   .sopl1:
  1383.  
  1384.         mov     esi, eax
  1385.         shl     esi, 4
  1386.         add     esi, RESERVED_PORTS
  1387.         cmp     edx, [esi+0]
  1388.         jne     .sopl2
  1389.         cmp     ecx, [esi+4]
  1390.         jb      .sopl2
  1391.         cmp     ecx, [esi+8]
  1392.         jg      .sopl2
  1393. .sopl3:
  1394.  
  1395.         test    edi, 0x80000000; read ?
  1396.         jnz     .sopl4
  1397.  
  1398.         mov     eax, ebx
  1399.         mov     dx, cx   ; write
  1400.         out     dx, al
  1401.         and     [esp+32], dword 0
  1402.         ret
  1403.  
  1404.         .sopl2:
  1405.  
  1406.         dec     eax
  1407.         jnz     .sopl1
  1408.         inc     eax
  1409.         mov     [esp+32], eax
  1410.         ret
  1411.  
  1412.  
  1413.   .sopl4:
  1414.  
  1415.         mov     dx, cx   ; read
  1416.         in      al, dx
  1417.         and     eax, 0xff
  1418.         and     [esp+32], dword 0
  1419.         mov     [esp+20], eax
  1420.         ret
  1421.  
  1422. display_number:
  1423. ;It is not optimization
  1424.         mov     eax, ebx
  1425.         mov     ebx, ecx
  1426.         mov     ecx, edx
  1427.         mov     edx, esi
  1428.         mov     esi, edi
  1429. ; eax = print type, al=0 -> ebx is number
  1430. ;                   al=1 -> ebx is pointer
  1431. ;                   ah=0 -> display decimal
  1432. ;                   ah=1 -> display hexadecimal
  1433. ;                   ah=2 -> display binary
  1434. ;                   eax bits 16-21 = number of digits to display (0-32)
  1435. ;                   eax bits 22-31 = reserved
  1436. ;
  1437. ; ebx = number or pointer
  1438. ; ecx = x shl 16 + y
  1439. ; edx = color
  1440.         xor     edi, edi
  1441. display_number_force:
  1442.         push    eax
  1443.         and     eax, 0x3fffffff
  1444.         cmp     eax, 0xffff     ; length > 0 ?
  1445.         pop     eax
  1446.         jge     cont_displ
  1447.         ret
  1448.    cont_displ:
  1449.         push    eax
  1450.         and     eax, 0x3fffffff
  1451.         cmp     eax, 61*0x10000  ; length <= 60 ?
  1452.         pop     eax
  1453.         jb      cont_displ2
  1454.         ret
  1455.    cont_displ2:
  1456.  
  1457.         pushad
  1458.  
  1459.         cmp     al, 1            ; ecx is a pointer ?
  1460.         jne     displnl1
  1461.         mov     ebp, ebx
  1462.         add     ebp, 4
  1463.         mov     ebp, [ebp+std_application_base_address]
  1464.         mov     ebx, [ebx+std_application_base_address]
  1465.  displnl1:
  1466.         sub     esp, 64
  1467.  
  1468.         test    ah, ah            ; DECIMAL
  1469.         jnz     no_display_desnum
  1470.         shr     eax, 16
  1471.         and     eax, 0xC03f
  1472. ;     and   eax,0x3f
  1473.         push    eax
  1474.         and     eax, 0x3f
  1475.         mov     edi, esp
  1476.         add     edi, 4+64-1
  1477.         mov     ecx, eax
  1478.         mov     eax, ebx
  1479.         mov     ebx, 10
  1480.  d_desnum:
  1481.         xor     edx, edx
  1482.         call    division_64_bits
  1483.         div     ebx
  1484.         add     dl, 48
  1485.         mov     [edi], dl
  1486.         dec     edi
  1487.         loop    d_desnum
  1488.         pop     eax
  1489.         call    normalize_number
  1490.         call    draw_num_text
  1491.         add     esp, 64
  1492.         popad
  1493.         ret
  1494.    no_display_desnum:
  1495.  
  1496.         cmp     ah, 0x01         ; HEXADECIMAL
  1497.         jne     no_display_hexnum
  1498.         shr     eax, 16
  1499.         and     eax, 0xC03f
  1500. ;     and   eax,0x3f
  1501.         push    eax
  1502.         and     eax, 0x3f
  1503.         mov     edi, esp
  1504.         add     edi, 4+64-1
  1505.         mov     ecx, eax
  1506.         mov     eax, ebx
  1507.         mov     ebx, 16
  1508.    d_hexnum:
  1509.         xor     edx, edx
  1510.         call    division_64_bits
  1511.         div     ebx
  1512.    hexletters = __fdo_hexdigits
  1513.         add     edx, hexletters
  1514.         mov     dl, [edx]
  1515.         mov     [edi], dl
  1516.         dec     edi
  1517.         loop    d_hexnum
  1518.         pop     eax
  1519.         call    normalize_number
  1520.         call    draw_num_text
  1521.         add     esp, 64
  1522.         popad
  1523.         ret
  1524.    no_display_hexnum:
  1525.  
  1526.         cmp     ah, 0x02         ; BINARY
  1527.         jne     no_display_binnum
  1528.         shr     eax, 16
  1529.         and     eax, 0xC03f
  1530. ;     and   eax,0x3f
  1531.         push    eax
  1532.         and     eax, 0x3f
  1533.         mov     edi, esp
  1534.         add     edi, 4+64-1
  1535.         mov     ecx, eax
  1536.         mov     eax, ebx
  1537.         mov     ebx, 2
  1538.    d_binnum:
  1539.         xor     edx, edx
  1540.         call    division_64_bits
  1541.         div     ebx
  1542.         add     dl, 48
  1543.         mov     [edi], dl
  1544.         dec     edi
  1545.         loop    d_binnum
  1546.         pop     eax
  1547.         call    normalize_number
  1548.         call    draw_num_text
  1549.         add     esp, 64
  1550.         popad
  1551.         ret
  1552.    no_display_binnum:
  1553.  
  1554.         add     esp, 64
  1555.         popad
  1556.         ret
  1557.  
  1558. normalize_number:
  1559.         test    ah, 0x80
  1560.         jz      .continue
  1561.         mov     ecx, 48
  1562.         and     eax, 0x3f
  1563. @@:
  1564.         inc     edi
  1565.         cmp     [edi], cl
  1566.         jne     .continue
  1567.         dec     eax
  1568.         cmp     eax, 1
  1569.         ja      @r
  1570.         mov     al, 1
  1571. .continue:
  1572.         and     eax, 0x3f
  1573.         ret
  1574.  
  1575. division_64_bits:
  1576.         test    [esp+1+4], byte 0x40
  1577.         jz      .continue
  1578.         push    eax
  1579.         mov     eax, ebp
  1580.         div     ebx
  1581.         mov     ebp, eax
  1582.         pop     eax
  1583. .continue:
  1584.         ret
  1585.  
  1586. draw_num_text:
  1587.         mov     esi, eax
  1588.         mov     edx, 64+4
  1589.         sub     edx, eax
  1590.         add     edx, esp
  1591.         mov     ebx, [esp+64+32-8+4]
  1592. ; add window start x & y
  1593.         mov     ecx, [TASK_BASE]
  1594.  
  1595.         mov     edi, [CURRENT_TASK]
  1596.         shl     edi, 8
  1597.  
  1598.         mov     eax, [ecx-twdw+WDATA.box.left]
  1599.         add     eax, [edi+SLOT_BASE+APPDATA.wnd_clientbox.left]
  1600.         shl     eax, 16
  1601.         add     eax, [ecx-twdw+WDATA.box.top]
  1602.         add     eax, [edi+SLOT_BASE+APPDATA.wnd_clientbox.top]
  1603.         add     ebx, eax
  1604.         mov     ecx, [esp+64+32-12+4]
  1605.         and     ecx, not 0x80000000     ; force counted string
  1606.         mov     eax, [esp+64+8]         ; background color (if given)
  1607.         mov     edi, [esp+64+4]
  1608.         jmp     dtext
  1609. ;-----------------------------------------------------------------------------
  1610. iglobal
  1611. midi_base dw 0
  1612. endg
  1613. ;-----------------------------------------------------------------------------
  1614. align 4
  1615. sys_setup:
  1616. ;  1 = roland mpu midi base , base io address
  1617. ;  2 = keyboard   1, base kaybap 2, shift keymap, 9 country 1eng 2fi 3ger 4rus
  1618. ;  3 = not used
  1619. ;  4 = not used
  1620. ;  5 = system language, 1eng 2fi 3ger 4rus
  1621. ;  6 = not used
  1622. ;  7 = not used
  1623. ;  8 = not used
  1624. ;  9 = not used
  1625. ; 10 = not used
  1626. ; 11 = enable lba read
  1627. ; 12 = enable pci access
  1628. ;-----------------------------------------------------------------------------
  1629.         and     [esp+32], dword 0
  1630. ; F.21.1 - set MPU MIDI base port
  1631.         dec     ebx
  1632.         jnz     @f
  1633.  
  1634.         cmp     ecx, 0x100
  1635.         jb      @f
  1636.  
  1637.         mov     esi, 65535
  1638.         cmp     esi, ecx
  1639.         jb      @f
  1640.  
  1641.         mov     [midi_base], cx
  1642.         mov     word [mididp], cx
  1643.         inc     cx
  1644.         mov     word [midisp], cx
  1645.         ret
  1646. ;--------------------------------------
  1647. @@:
  1648. ; F.21.2 - set keyboard layout
  1649.         dec     ebx
  1650.         jnz     @f
  1651.  
  1652.         mov     edi, [TASK_BASE]
  1653.         mov     eax, [edi+TASKDATA.mem_start]
  1654.         add     eax, edx
  1655. ; 1 = normal layout
  1656.         dec     ecx
  1657.         jnz     .shift
  1658.  
  1659.         mov     ebx, keymap
  1660.         mov     ecx, 128
  1661.         call    memmove
  1662.         ret
  1663. ;--------------------------------------
  1664. .shift:
  1665. ; 2 = layout at pressed Shift
  1666.         dec     ecx
  1667.         jnz     .alt
  1668.  
  1669.         mov     ebx, keymap_shift
  1670.         mov     ecx, 128
  1671.         call    memmove
  1672.         ret
  1673. ;--------------------------------------
  1674. .alt:
  1675. ; 3 = layout at pressed Alt
  1676.         dec     ecx
  1677.         jnz     .country
  1678.  
  1679.         mov     ebx, keymap_alt
  1680.         mov     ecx, 128
  1681.         call    memmove
  1682.         ret
  1683. ;--------------------------------------
  1684. .country:
  1685. ; country identifier
  1686.         sub     ecx, 6
  1687.         jnz     .error
  1688.  
  1689.         mov     word [keyboard], dx
  1690.         ret
  1691. ;--------------------------------------
  1692. @@:
  1693. ; F.21.5 - set system language
  1694.         sub     ebx, 3
  1695.         jnz     @f
  1696.  
  1697.         mov     [syslang], ecx
  1698.         ret
  1699. ;--------------------------------------
  1700. @@:
  1701. ; F.21.11 - enable/disable low-level access to HD
  1702.         and     ecx, 1
  1703.         sub     ebx, 6
  1704.         jnz     @f
  1705.  
  1706.         mov     [lba_read_enabled], ecx
  1707.         ret
  1708. ;--------------------------------------
  1709. @@:
  1710. ; F.21.12 - enable/disable low-level access to PCI
  1711.         dec     ebx
  1712.         jnz     .error
  1713.  
  1714.         mov     [pci_access_enabled], ecx
  1715.         ret
  1716. ;--------------------------------------
  1717. .error:
  1718.         or      [esp+32], dword -1
  1719.         ret
  1720. ;-----------------------------------------------------------------------------
  1721. align 4
  1722. sys_getsetup:
  1723. ;  1 = roland mpu midi base , base io address
  1724. ;  2 = keyboard   1, base kaybap 2, shift keymap, 9 country 1eng 2fi 3ger 4rus
  1725. ;  3 = not used
  1726. ;  4 = not used
  1727. ;  5 = system language, 1eng 2fi 3ger 4rus
  1728. ;  6 = not used
  1729. ;  7 = not used
  1730. ;  8 = not used
  1731. ;  9 = get hs timer tic
  1732. ; 10 = not used
  1733. ; 11 = get the state "lba read"
  1734. ; 12 = get the state "pci access"
  1735. ;-----------------------------------------------------------------------------
  1736. ; F.26.1 - get MPU MIDI base port
  1737.         dec     ebx
  1738.         jnz     @f
  1739.  
  1740.         movzx   eax, [midi_base]
  1741.         mov     [esp+32], eax
  1742.         ret
  1743. ;--------------------------------------
  1744. @@:
  1745. ; F.26.2 - get keyboard layout
  1746.         dec     ebx
  1747.         jnz     @f
  1748.  
  1749.         mov     edi, [TASK_BASE]
  1750.         mov     ebx, [edi+TASKDATA.mem_start]
  1751.         add     ebx, edx
  1752. ; 1 = normal layout
  1753.         dec     ecx
  1754.         jnz     .shift
  1755.  
  1756.         mov     eax, keymap
  1757.         mov     ecx, 128
  1758.         call    memmove
  1759.         ret
  1760. ;--------------------------------------
  1761. .shift:
  1762. ; 2 = layout with pressed Shift
  1763.         dec     ecx
  1764.         jnz     .alt
  1765.  
  1766.         mov     eax, keymap_shift
  1767.         mov     ecx, 128
  1768.         call    memmove
  1769.         ret
  1770. ;--------------------------------------
  1771. .alt:
  1772. ; 3 = layout with pressed Alt
  1773.         dec     ecx
  1774.         jne     .country
  1775.  
  1776.         mov     eax, keymap_alt
  1777.         mov     ecx, 128
  1778.         call    memmove
  1779.         ret
  1780. ;--------------------------------------
  1781. .country:
  1782. ; 9 = country identifier
  1783.         sub     ecx, 6
  1784.         jnz     .error
  1785.  
  1786.         movzx   eax, word [keyboard]
  1787.         mov     [esp+32], eax
  1788.         ret
  1789. ;--------------------------------------
  1790. @@:
  1791. ; F.26.5 - get system language
  1792.         sub     ebx, 3
  1793.         jnz     @f
  1794.  
  1795.         mov     eax, [syslang]
  1796.         mov     [esp+32], eax
  1797.         ret
  1798. ;--------------------------------------
  1799. @@:
  1800. ; F.26.9 - get the value of the time counter
  1801.         sub     ebx, 4
  1802.         jnz     @f
  1803.  
  1804.         mov     eax, [timer_ticks]
  1805.         mov     [esp+32], eax
  1806.         ret
  1807. ;--------------------------------------
  1808. @@:
  1809. ; F.26.11 - Find out whether low-level HD access is enabled
  1810.         sub     ebx, 2
  1811.         jnz     @f
  1812.  
  1813.         mov     eax, [lba_read_enabled]
  1814.         mov     [esp+32], eax
  1815.         ret
  1816. ;--------------------------------------
  1817. @@:
  1818. ; F.26.12 - Find out whether low-level PCI access is enabled
  1819.         dec     ebx
  1820.         jnz     .error
  1821.  
  1822.         mov     eax, [pci_access_enabled]
  1823.         mov     [esp+32], eax
  1824.         ret
  1825. ;--------------------------------------
  1826. .error:
  1827.         or      [esp+32], dword -1
  1828.         ret
  1829. ;-----------------------------------------------------------------------------
  1830. get_timer_ticks:
  1831.         mov     eax, [timer_ticks]
  1832.         ret
  1833. ;-----------------------------------------------------------------------------
  1834. iglobal
  1835. align 4
  1836. mousefn dd msscreen, mswin, msbutton, msset
  1837.         dd app_load_cursor
  1838.         dd app_set_cursor
  1839.         dd app_delete_cursor
  1840.         dd msz
  1841. endg
  1842. ;-----------------------------------------------------------------------------
  1843. readmousepos:
  1844.  
  1845. ; eax=0 screen relative
  1846. ; eax=1 window relative
  1847. ; eax=2 buttons pressed
  1848. ; eax=3 set mouse pos   ; reserved
  1849. ; eax=4 load cursor
  1850. ; eax=5 set cursor
  1851. ; eax=6 delete cursor   ; reserved
  1852. ; eax=7 get mouse_z
  1853.  
  1854.         cmp     ebx, 7
  1855.         ja      msset
  1856.         jmp     [mousefn+ebx*4]
  1857. msscreen:
  1858.         mov     eax, [MOUSE_X]
  1859.         shl     eax, 16
  1860.         mov     ax, [MOUSE_Y]
  1861.         mov     [esp+36-4], eax
  1862.         ret
  1863. mswin:
  1864.         mov     eax, [MOUSE_X]
  1865.         shl     eax, 16
  1866.         mov     ax, [MOUSE_Y]
  1867.         mov     esi, [TASK_BASE]
  1868.         mov     bx, word [esi-twdw+WDATA.box.left]
  1869.         shl     ebx, 16
  1870.         mov     bx, word [esi-twdw+WDATA.box.top]
  1871.         sub     eax, ebx
  1872.  
  1873.         mov     edi, [CURRENT_TASK]
  1874.         shl     edi, 8
  1875.         sub     ax, word[edi+SLOT_BASE+APPDATA.wnd_clientbox.top]
  1876.         rol     eax, 16
  1877.         sub     ax, word[edi+SLOT_BASE+APPDATA.wnd_clientbox.left]
  1878.         rol     eax, 16
  1879.         mov     [esp+36-4], eax
  1880.         ret
  1881. msbutton:
  1882.         movzx   eax, byte [BTN_DOWN]
  1883.         mov     [esp+36-4], eax
  1884.         ret
  1885. msz:
  1886.         mov     edi, [TASK_COUNT]
  1887.         movzx   edi, word [WIN_POS + edi*2]
  1888.         cmp     edi, [CURRENT_TASK]
  1889.         jne     @f
  1890.         mov     ax, [MOUSE_SCROLL_H]
  1891.         shl     eax, 16
  1892.         mov     ax, [MOUSE_SCROLL_V]
  1893.         mov     [esp+36-4], eax
  1894.         and     [MOUSE_SCROLL_H], word 0
  1895.         and     [MOUSE_SCROLL_V], word 0
  1896.         ret
  1897.        @@:
  1898.         and     [esp+36-4], dword 0
  1899. ;           ret
  1900. msset:
  1901.         ret
  1902.  
  1903. app_load_cursor:
  1904.         cmp     ecx, OS_BASE
  1905.         jae     msset
  1906.         stdcall load_cursor, ecx, edx
  1907.         mov     [esp+36-4], eax
  1908.         ret
  1909.  
  1910. app_set_cursor:
  1911.         stdcall set_cursor, ecx
  1912.         mov     [esp+36-4], eax
  1913.         ret
  1914.  
  1915. app_delete_cursor:
  1916.         stdcall delete_cursor, ecx
  1917.         mov     [esp+36-4], eax
  1918.         ret
  1919.  
  1920. is_input:
  1921.  
  1922.         push    edx
  1923.         mov     dx, word [midisp]
  1924.         in      al, dx
  1925.         and     al, 0x80
  1926.         pop     edx
  1927.         ret
  1928.  
  1929. is_output:
  1930.  
  1931.         push    edx
  1932.         mov     dx, word [midisp]
  1933.         in      al, dx
  1934.         and     al, 0x40
  1935.         pop     edx
  1936.         ret
  1937.  
  1938.  
  1939. get_mpu_in:
  1940.  
  1941.         push    edx
  1942.         mov     dx, word [mididp]
  1943.         in      al, dx
  1944.         pop     edx
  1945.         ret
  1946.  
  1947.  
  1948. put_mpu_out:
  1949.  
  1950.         push    edx
  1951.         mov     dx, word [mididp]
  1952.         out     dx, al
  1953.         pop     edx
  1954.         ret
  1955.  
  1956.  
  1957.  
  1958. align 4
  1959.  
  1960. sys_midi:
  1961.         cmp     [mididp], 0
  1962.         jnz     sm0
  1963.         mov     [esp+36], dword 1
  1964.         ret
  1965. sm0:
  1966.         and     [esp+36], dword 0
  1967.         dec     ebx
  1968.         jnz     smn1
  1969.  ;    call setuart
  1970. su1:
  1971.         call    is_output
  1972.         test    al, al
  1973.         jnz     su1
  1974.         mov     dx, word [midisp]
  1975.         mov     al, 0xff
  1976.         out     dx, al
  1977. su2:
  1978.         mov     dx, word [midisp]
  1979.         mov     al, 0xff
  1980.         out     dx, al
  1981.         call    is_input
  1982.         test    al, al
  1983.         jnz     su2
  1984.         call    get_mpu_in
  1985.         cmp     al, 0xfe
  1986.         jnz     su2
  1987. su3:
  1988.         call    is_output
  1989.         test    al, al
  1990.         jnz     su3
  1991.         mov     dx, word [midisp]
  1992.         mov     al, 0x3f
  1993.         out     dx, al
  1994.         ret
  1995. smn1:
  1996.         dec     ebx
  1997.         jnz     smn2
  1998. sm10:
  1999.         call    get_mpu_in
  2000.         call    is_output
  2001.         test    al, al
  2002.         jnz     sm10
  2003.         mov     al, bl
  2004.         call    put_mpu_out
  2005.         smn2:
  2006.         ret
  2007.  
  2008. detect_devices:
  2009. ;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  2010. ;include 'detect/commouse.inc'
  2011. ;include 'detect/ps2mouse.inc'
  2012. ;include 'detect/dev_fd.inc'
  2013. ;include 'detect/dev_hdcd.inc'
  2014. ;include 'detect/sear_par.inc'
  2015. ;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  2016.         ret
  2017.  
  2018. sys_end:
  2019. ;--------------------------------------
  2020.         cmp     [_display.select_cursor], 0
  2021.         je      @f
  2022. ; restore default cursor before killing
  2023.         pusha
  2024.         mov     ecx, [current_slot]
  2025.         call    restore_default_cursor_before_killing
  2026.         popa
  2027. @@:
  2028. ;--------------------------------------
  2029. ; kill all sockets this process owns
  2030.         pusha
  2031.         mov     edx, [TASK_BASE]
  2032.         mov     edx, [edx+TASKDATA.pid]
  2033.         call    SOCKET_process_end
  2034.         popa
  2035. ;--------------------------------------
  2036.         mov     ecx, [current_slot]
  2037.         mov     eax, [ecx+APPDATA.tls_base]
  2038.         test    eax, eax
  2039.         jz      @F
  2040.  
  2041.         stdcall user_free, eax
  2042. @@:
  2043.  
  2044.         mov     eax, [TASK_BASE]
  2045.         mov     [eax+TASKDATA.state], 3; terminate this program
  2046.         call    wakeup_osloop
  2047.  
  2048. .waitterm:            ; wait here for termination
  2049.         call    change_task
  2050.         jmp     .waitterm
  2051. ;------------------------------------------------------------------------------
  2052. align 4
  2053. restore_default_cursor_before_killing:
  2054.         pushfd
  2055.         cli
  2056.         mov     eax, [def_cursor]
  2057.         mov     [ecx+APPDATA.cursor], eax
  2058.  
  2059.         movzx   eax, word [MOUSE_Y]
  2060.         movzx   ebx, word [MOUSE_X]
  2061.         mov     eax, [d_width_calc_area + eax*4]
  2062.  
  2063.         add     eax, [_WinMapAddress]
  2064.         movzx   edx, byte [ebx+eax]
  2065.         shl     edx, 8
  2066.         mov     esi, [edx+SLOT_BASE+APPDATA.cursor]
  2067.  
  2068.         cmp     esi, [current_cursor]
  2069.         je      @f
  2070.  
  2071.         push    esi
  2072.         call    [_display.select_cursor]
  2073.         mov     [current_cursor], esi
  2074. @@:
  2075.         mov     [redrawmouse_unconditional], 1
  2076.         call    wakeup_osloop
  2077.         popfd
  2078.         ret
  2079. ;------------------------------------------------------------------------------
  2080. iglobal
  2081. align 4
  2082. sys_system_table:
  2083.         dd      sysfn_deactivate        ; 1 = deactivate window
  2084.         dd      sysfn_terminate         ; 2 = terminate thread
  2085.         dd      sysfn_activate          ; 3 = activate window
  2086.         dd      sysfn_getidletime       ; 4 = get idle time
  2087.         dd      sysfn_getcpuclock       ; 5 = get cpu clock
  2088.         dd      sysfn_saveramdisk       ; 6 = save ramdisk
  2089.         dd      sysfn_getactive         ; 7 = get active window
  2090.         dd      sysfn_sound_flag        ; 8 = get/set sound_flag
  2091.         dd      sysfn_shutdown          ; 9 = shutdown with parameter
  2092.         dd      sysfn_minimize          ; 10 = minimize window
  2093.         dd      sysfn_getdiskinfo       ; 11 = get disk subsystem info
  2094.         dd      sysfn_lastkey           ; 12 = get last pressed key
  2095.         dd      sysfn_getversion        ; 13 = get kernel version
  2096.         dd      sysfn_waitretrace       ; 14 = wait retrace
  2097.         dd      sysfn_centermouse       ; 15 = center mouse cursor
  2098.         dd      sysfn_getfreemem        ; 16 = get free memory size
  2099.         dd      sysfn_getallmem         ; 17 = get total memory size
  2100.         dd      sysfn_terminate2        ; 18 = terminate thread using PID
  2101.                                         ;                 instead of slot
  2102.         dd      sysfn_mouse_acceleration; 19 = set/get mouse acceleration
  2103.         dd      sysfn_meminfo           ; 20 = get extended memory info
  2104.         dd      sysfn_pid_to_slot       ; 21 = get slot number for pid
  2105.         dd      sysfn_min_rest_window   ; 22 = minimize and restore any window
  2106.         dd      sysfn_min_windows       ; 23 = minimize all windows
  2107.         dd      sysfn_set_screen_sizes  ; 24 = set screen sizes for Vesa
  2108. sysfn_num = ($ - sys_system_table)/4
  2109. endg
  2110. ;------------------------------------------------------------------------------
  2111. sys_system:
  2112.         dec     ebx
  2113.         cmp     ebx, sysfn_num
  2114.         jae     @f
  2115.         jmp     dword [sys_system_table + ebx*4]
  2116. @@:
  2117.         ret
  2118. ;------------------------------------------------------------------------------
  2119. sysfn_shutdown:          ; 18.9 = system shutdown
  2120.         cmp     ecx, 1
  2121.         jl      exit_for_anyone
  2122.         cmp     ecx, 4
  2123.         jg      exit_for_anyone
  2124.         mov     [BOOT_VARS+0x9030], cl
  2125.  
  2126.         mov     eax, [TASK_COUNT]
  2127.         mov     [SYS_SHUTDOWN], al
  2128.         mov     [shutdown_processes], eax
  2129.         call    wakeup_osloop
  2130.         and     dword [esp+32], 0
  2131.  exit_for_anyone:
  2132.         ret
  2133.   uglobal
  2134.    shutdown_processes:
  2135.                        dd 0x0
  2136.   endg
  2137. ;------------------------------------------------------------------------------
  2138. sysfn_terminate:        ; 18.2 = TERMINATE
  2139.         push    ecx
  2140.         cmp     ecx, 2
  2141.         jb      noprocessterminate
  2142.         mov     edx, [TASK_COUNT]
  2143.         cmp     ecx, edx
  2144.         ja      noprocessterminate
  2145.         mov     eax, [TASK_COUNT]
  2146.         shl     ecx, 5
  2147.         mov     edx, [ecx+CURRENT_TASK+TASKDATA.pid]
  2148.         add     ecx, CURRENT_TASK+TASKDATA.state
  2149.         cmp     byte [ecx], 9
  2150.         jz      noprocessterminate
  2151.         push    ecx edx
  2152.         lea     edx, [(ecx-(CURRENT_TASK and 1FFFFFFFh)-TASKDATA.state)*8+SLOT_BASE]
  2153.         call    request_terminate
  2154.         pop     edx ecx
  2155.         test    eax, eax
  2156.         jz      noprocessterminate
  2157. ;--------------------------------------
  2158. ; terminate all network sockets it used
  2159.         pusha
  2160.         mov     eax, edx
  2161.         call    SOCKET_process_end
  2162.         popa
  2163. ;--------------------------------------
  2164.         cmp     [_display.select_cursor], 0
  2165.         je      .restore_end
  2166. ; restore default cursor before killing
  2167.         pusha
  2168.         mov     ecx, [esp+32]
  2169.         shl     ecx, 8
  2170.         add     ecx, SLOT_BASE
  2171.         mov     eax, [def_cursor]
  2172.         cmp     [ecx+APPDATA.cursor], eax
  2173.         je      @f
  2174.         call    restore_default_cursor_before_killing
  2175. @@:
  2176.         popa
  2177. .restore_end:
  2178. ;--------------------------------------
  2179.      ;call MEM_Heap_Lock      ;guarantee that process isn't working with heap
  2180.         mov     [ecx], byte 3; clear possible i40's
  2181.         call    wakeup_osloop
  2182.      ;call MEM_Heap_UnLock
  2183.  
  2184.         cmp     edx, [application_table_owner]; clear app table stat
  2185.         jne     noatsc
  2186.         call    unlock_application_table
  2187. noatsc:
  2188. noprocessterminate:
  2189.         add     esp, 4
  2190.         ret
  2191. ;------------------------------------------------------------------------------
  2192. sysfn_terminate2:
  2193. ;lock application_table_status mutex
  2194. .table_status:
  2195.         call    lock_application_table
  2196.         mov     eax, ecx
  2197.         call    pid_to_slot
  2198.         test    eax, eax
  2199.         jz      .not_found
  2200.         mov     ecx, eax
  2201.         cli
  2202.         call    sysfn_terminate
  2203.         call    unlock_application_table
  2204.         sti
  2205.         and     dword [esp+32], 0
  2206.         ret
  2207. .not_found:
  2208.         call    unlock_application_table
  2209.         or      dword [esp+32], -1
  2210.         ret
  2211. ;------------------------------------------------------------------------------
  2212. sysfn_deactivate:         ; 18.1 = DEACTIVATE WINDOW
  2213.         cmp     ecx, 2
  2214.         jb      .nowindowdeactivate
  2215.         cmp     ecx, [TASK_COUNT]
  2216.         ja      .nowindowdeactivate
  2217.  
  2218.         movzx   esi, word [WIN_STACK + ecx*2]
  2219.         cmp     esi, 1
  2220.         je      .nowindowdeactivate ; already deactive
  2221.  
  2222.         mov     edi, ecx
  2223.         shl     edi, 5
  2224.         add     edi, window_data
  2225.         movzx   esi, word [WIN_STACK + ecx * 2]
  2226.         lea     esi, [WIN_POS + esi * 2]
  2227.         call    window._.window_deactivate
  2228.  
  2229.         call    syscall_display_settings._.calculate_whole_screen
  2230.         call    syscall_display_settings._.redraw_whole_screen
  2231. .nowindowdeactivate:
  2232.         ret
  2233. ;------------------------------------------------------------------------------
  2234. sysfn_activate:         ; 18.3 = ACTIVATE WINDOW
  2235.         cmp     ecx, 2
  2236.         jb      .nowindowactivate
  2237.         cmp     ecx, [TASK_COUNT]
  2238.         ja      .nowindowactivate
  2239. ;-------------------------------------
  2240. @@:
  2241. ; If the window is captured and moved by the user,
  2242. ; then you can't change the position in window stack!!!
  2243.         mov     al, [mouse.active_sys_window.action]
  2244.         and     al, WINDOW_MOVE_AND_RESIZE_FLAGS
  2245.         test    al, al
  2246.         jz      @f
  2247.         call    change_task
  2248.         jmp     @b
  2249. @@:
  2250. ;-------------------------------------
  2251.         mov     [window_minimize], 2; restore window if minimized
  2252.         call    wakeup_osloop
  2253.  
  2254.         movzx   esi, word [WIN_STACK + ecx*2]
  2255.         cmp     esi, [TASK_COUNT]
  2256.         je      .nowindowactivate; already active
  2257.  
  2258.         mov     edi, ecx
  2259.         shl     edi, 5
  2260.         add     edi, window_data
  2261.         movzx   esi, word [WIN_STACK + ecx * 2]
  2262.         lea     esi, [WIN_POS + esi * 2]
  2263.         call    waredraw
  2264. .nowindowactivate:
  2265.         ret
  2266. ;------------------------------------------------------------------------------
  2267. sysfn_getidletime:              ; 18.4 = GET IDLETIME
  2268.         mov     eax, [CURRENT_TASK+32+TASKDATA.cpu_usage]
  2269.         mov     [esp+32], eax
  2270.         ret
  2271. ;------------------------------------------------------------------------------
  2272. sysfn_getcpuclock:              ; 18.5 = GET TSC/SEC
  2273.         mov     eax, dword [cpu_freq]
  2274.         mov     [esp+32], eax
  2275.         ret
  2276. ;------------------------------------------------------------------------------
  2277. get_cpu_freq:
  2278.         mov     eax, dword [cpu_freq]
  2279.         mov     edx, dword [cpu_freq+4]
  2280.         ret
  2281. ;  SAVE ramdisk to /hd/1/menuet.img
  2282. ;!!!!!!!!!!!!!!!!!!!!!!!!
  2283.    include 'blkdev/rdsave.inc'
  2284. ;!!!!!!!!!!!!!!!!!!!!!!!!
  2285. ;------------------------------------------------------------------------------
  2286. align 4
  2287. sysfn_getactive:        ; 18.7 = get active window
  2288.         mov     eax, [TASK_COUNT]
  2289.         movzx   eax, word [WIN_POS + eax*2]
  2290.         mov     [esp+32], eax
  2291.         ret
  2292. ;------------------------------------------------------------------------------
  2293. sysfn_sound_flag:       ; 18.8 = get/set sound_flag
  2294. ;     cmp  ecx,1
  2295.         dec     ecx
  2296.         jnz     nogetsoundflag
  2297.         movzx   eax, byte [sound_flag]; get sound_flag
  2298.         mov     [esp+32], eax
  2299.         ret
  2300.  nogetsoundflag:
  2301. ;     cmp  ecx,2
  2302.         dec     ecx
  2303.         jnz     nosoundflag
  2304.         xor     byte [sound_flag], 1
  2305.  nosoundflag:
  2306.         ret
  2307. ;------------------------------------------------------------------------------
  2308. sysfn_minimize:         ; 18.10 = minimize window
  2309.         mov     [window_minimize], 1
  2310.         call    wakeup_osloop
  2311.         ret
  2312. ;------------------------------------------------------------------------------
  2313. align 4
  2314. sysfn_getdiskinfo:      ; 18.11 = get disk info table
  2315.         dec     ecx
  2316.         jnz     .exit
  2317. .small_table:
  2318.         mov     edi, edx
  2319.         mov     esi, DRIVE_DATA
  2320.         mov     ecx, DRIVE_DATA_SIZE ;10
  2321.         cld
  2322.         rep movsb
  2323. .exit:
  2324.         ret
  2325. ;------------------------------------------------------------------------------
  2326. sysfn_lastkey:          ; 18.12 = return 0 (backward compatibility)
  2327.         and     dword [esp+32], 0
  2328.         ret
  2329. ;------------------------------------------------------------------------------
  2330. sysfn_getversion:       ; 18.13 = get kernel ID and version
  2331.         mov     edi, ecx
  2332.         mov     esi, version_inf
  2333.         mov     ecx, version_end-version_inf
  2334.         rep movsb
  2335.         ret
  2336. ;------------------------------------------------------------------------------
  2337. sysfn_waitretrace:     ; 18.14 = sys wait retrace
  2338.      ;wait retrace functions
  2339.  sys_wait_retrace:
  2340.         mov     edx, 0x3da
  2341.  WaitRetrace_loop:
  2342.         in      al, dx
  2343.         test    al, 1000b
  2344.         jz      WaitRetrace_loop
  2345.         and     [esp+32], dword 0
  2346.         ret
  2347. ;------------------------------------------------------------------------------
  2348. align 4
  2349. sysfn_centermouse:      ; 18.15 = mouse centered
  2350. ; removed here by <Lrz>
  2351. ;     call  mouse_centered
  2352. ;* mouse centered - start code- Mario79
  2353. ;mouse_centered:
  2354. ;        push  eax
  2355.         mov     eax, [Screen_Max_X]
  2356.         shr     eax, 1
  2357.         mov     [MOUSE_X], ax
  2358.         mov     eax, [Screen_Max_Y]
  2359.         shr     eax, 1
  2360.         mov     [MOUSE_Y], ax
  2361.         call    wakeup_osloop
  2362. ;        ret
  2363. ;* mouse centered - end code- Mario79
  2364.         xor     eax, eax
  2365.         and     [esp+32], eax
  2366. ;        pop   eax
  2367.         ret
  2368. ;------------------------------------------------------------------------------
  2369. align 4
  2370. sysfn_mouse_acceleration: ; 18.19 = set/get mouse features
  2371.         test    ecx, ecx; get mouse speed factor
  2372.         jnz     .set_mouse_acceleration
  2373.         xor     eax, eax
  2374.         mov     ax, [mouse_speed_factor]
  2375.         mov     [esp+32], eax
  2376.         ret
  2377.  .set_mouse_acceleration:
  2378. ;     cmp  ecx,1  ; set mouse speed factor
  2379.         dec     ecx
  2380.         jnz     .get_mouse_delay
  2381.         mov     [mouse_speed_factor], dx
  2382.         ret
  2383.  .get_mouse_delay:
  2384. ;     cmp  ecx,2  ; get mouse delay
  2385.         dec     ecx
  2386.         jnz     .set_mouse_delay
  2387.         mov     eax, [mouse_delay]
  2388.         mov     [esp+32], eax
  2389.         ret
  2390.  .set_mouse_delay:
  2391. ;     cmp  ecx,3  ; set mouse delay
  2392.         dec     ecx
  2393.         jnz     .set_pointer_position
  2394.         mov     [mouse_delay], edx
  2395.         ret
  2396.  .set_pointer_position:
  2397. ;     cmp  ecx,4  ; set mouse pointer position
  2398.         dec     ecx
  2399.         jnz     .set_mouse_button
  2400.         cmp     dx, word[Screen_Max_Y]
  2401.         ja      .end
  2402.         rol     edx, 16
  2403.         cmp     dx, word[Screen_Max_X]
  2404.         ja      .end
  2405.         mov     [MOUSE_X], edx
  2406.         mov     [mouse_active], 1
  2407.         call    wakeup_osloop
  2408.         ret
  2409.  .set_mouse_button:
  2410. ;     cmp   ecx,5  ; set mouse button features
  2411.         dec     ecx
  2412.         jnz     .end
  2413.         mov     [BTN_DOWN], dl
  2414.         mov     [mouse_active], 1
  2415.         call    wakeup_osloop
  2416.  .end:
  2417.         ret
  2418. ;------------------------------------------------------------------------------
  2419. sysfn_getfreemem:
  2420.         mov     eax, [pg_data.pages_free]
  2421.         shl     eax, 2
  2422.         mov     [esp+32], eax
  2423.         ret
  2424. ;------------------------------------------------------------------------------
  2425. sysfn_getallmem:
  2426.         mov     eax, [MEM_AMOUNT]
  2427.         shr     eax, 10
  2428.         mov     [esp+32], eax
  2429.         ret
  2430. ;------------------------------------------------------------------------------
  2431. sysfn_pid_to_slot:
  2432.         mov     eax, ecx
  2433.         call    pid_to_slot
  2434.         mov     [esp+32], eax
  2435.         ret
  2436. ;------------------------------------------------------------------------------
  2437. sysfn_min_rest_window:
  2438.         pushad
  2439.         mov     eax, edx ; ebx - operating
  2440.         shr     ecx, 1
  2441.         jnc     @f
  2442.         call    pid_to_slot
  2443. @@:
  2444.         or      eax, eax ; eax - number of slot
  2445.         jz      .error
  2446.         cmp     eax, 255    ; varify maximal slot number
  2447.         ja      .error
  2448.         movzx   eax, word [WIN_STACK + eax*2]
  2449.         shr     ecx, 1
  2450.         jc      .restore
  2451.  ; .minimize:
  2452.         call    minimize_window
  2453.         jmp     .exit
  2454. .restore:
  2455.         call    restore_minimized_window
  2456. .exit:
  2457.         popad
  2458.         xor     eax, eax
  2459.         mov     [esp+32], eax
  2460.         ret
  2461. .error:
  2462.         popad
  2463.         xor     eax, eax
  2464.         dec     eax
  2465.         mov     [esp+32], eax
  2466.         ret
  2467. ;------------------------------------------------------------------------------
  2468. sysfn_min_windows:
  2469.         call    minimize_all_window
  2470.         mov     [esp+32], eax
  2471.         call    change_task
  2472.         ret
  2473. ;------------------------------------------------------------------------------
  2474. sysfn_set_screen_sizes:
  2475.         cmp     [SCR_MODE], word 0x13
  2476.         jbe     .exit
  2477.  
  2478.         cmp     [_display.select_cursor], select_cursor
  2479.         jne     .exit
  2480.  
  2481.         cmp     ecx, [display_width_standard]
  2482.         ja      .exit
  2483.  
  2484.         cmp     edx, [display_height_standard]
  2485.         ja      .exit
  2486.  
  2487.         pushfd
  2488.         cli
  2489.         mov     eax, ecx
  2490.         mov     ecx, [_display.pitch]
  2491.         mov     [_display.width], eax
  2492.         dec     eax
  2493.         mov     [_display.height], edx
  2494.         dec     edx
  2495. ; eax - new Screen_Max_X
  2496. ; edx - new Screen_Max_Y
  2497.         mov     [do_not_touch_winmap], 1
  2498.         call    set_screen
  2499.         mov     [do_not_touch_winmap], 0
  2500.         popfd
  2501.         call    change_task
  2502. .exit:
  2503.         ret
  2504. ;------------------------------------------------------------------------------
  2505. uglobal
  2506. screen_workarea RECT
  2507. display_width_standard dd 0
  2508. display_height_standard dd 0
  2509. do_not_touch_winmap db 0
  2510. window_minimize db 0
  2511. sound_flag      db 0
  2512.  
  2513. endg
  2514.  
  2515. UID_NONE=0
  2516. UID_MENUETOS=1   ;official
  2517. UID_KOLIBRI=2    ;russian
  2518.  
  2519. iglobal
  2520. version_inf:
  2521.         db 0,7,7,0  ; version 0.7.7.0
  2522.         db 0
  2523. .rev    dd __REV__
  2524. version_end:
  2525. endg
  2526. ;------------------------------------------------------------------------------
  2527. align 4
  2528. sys_cachetodiskette:
  2529.         cmp     ebx, 1
  2530.         jb      .no_floppy_save
  2531.         cmp     ebx, 2
  2532.         ja      .no_floppy_save
  2533.         call    save_image
  2534.         mov     [esp + 32], eax
  2535.         ret
  2536. .no_floppy_save:
  2537.         mov     [esp + 32], dword 1
  2538.         ret
  2539. ;------------------------------------------------------------------------------
  2540. uglobal
  2541. ;  bgrchanged  dd  0x0
  2542. align 4
  2543. bgrlockpid dd 0
  2544. bgrlock db 0
  2545. endg
  2546. ;------------------------------------------------------------------------------
  2547. align 4
  2548. sys_background:
  2549.         cmp     ebx, 1                     ; BACKGROUND SIZE
  2550.         jnz     nosb1
  2551.         test    ecx, ecx
  2552.         jz      sbgrr
  2553.  
  2554.         test    edx, edx
  2555.         jz      sbgrr
  2556. ;--------------------------------------
  2557. align 4
  2558. @@:
  2559. ;;Maxis use atomic bts for mutexes  4.4.2009
  2560.         bts     dword [bgrlock], 0
  2561.         jnc     @f
  2562.         call    change_task
  2563.         jmp     @b
  2564. ;--------------------------------------
  2565. align 4
  2566. @@:
  2567.         mov     [BgrDataWidth], ecx
  2568.         mov     [BgrDataHeight], edx
  2569. ;    mov   [bgrchanged],1
  2570.  
  2571.         pushad
  2572. ; return memory for old background
  2573.         mov     eax, [img_background]
  2574.         cmp     eax, static_background_data
  2575.         jz      @f
  2576.         stdcall kernel_free, eax
  2577. ;--------------------------------------
  2578. align 4
  2579. @@:
  2580. ; calculate RAW size
  2581.         xor     eax, eax
  2582.         inc     eax
  2583.         cmp     [BgrDataWidth], eax
  2584.         jae     @f
  2585.         mov     [BgrDataWidth], eax
  2586. ;--------------------------------------
  2587. align 4
  2588. @@:
  2589.         cmp     [BgrDataHeight], eax
  2590.         jae     @f
  2591.         mov     [BgrDataHeight], eax
  2592. ;--------------------------------------
  2593. align 4
  2594. @@:
  2595.         mov     eax, [BgrDataWidth]
  2596.         imul    eax, [BgrDataHeight]
  2597.         lea     eax, [eax*3]
  2598. ; it is reserved with aligned to the boundary of 4 KB pages,
  2599. ; otherwise there may be exceptions a page fault for vesa20_drawbackground_tiled
  2600. ; because the 32 bit read is used for  high performance: "mov eax,[esi]"
  2601.         shr     eax, 12
  2602.         inc     eax
  2603.         shl     eax, 12
  2604.         mov     [mem_BACKGROUND], eax
  2605. ; get memory for new background
  2606.         stdcall kernel_alloc, eax
  2607.         test    eax, eax
  2608.         jz      .memfailed
  2609.         mov     [img_background], eax
  2610.         jmp     .exit
  2611. ;--------------------------------------
  2612. align 4
  2613. .memfailed:
  2614. ; revert to static monotone data
  2615.         mov     [img_background], static_background_data
  2616.         xor     eax, eax
  2617.         inc     eax
  2618.         mov     [BgrDataWidth], eax
  2619.         mov     [BgrDataHeight], eax
  2620.         mov     [mem_BACKGROUND], 4
  2621. ;--------------------------------------
  2622. align 4
  2623. .exit:
  2624.         popad
  2625.         mov     [bgrlock], 0
  2626. ;--------------------------------------
  2627. align 4
  2628. sbgrr:
  2629.         ret
  2630. ;------------------------------------------------------------------------------
  2631. align 4
  2632. nosb1:
  2633.         cmp     ebx, 2                     ; SET PIXEL
  2634.         jnz     nosb2
  2635.  
  2636.         mov     eax, [img_background]
  2637.         test    ecx, ecx
  2638.         jz      @f
  2639.         cmp     eax, static_background_data
  2640.         jz      .ret
  2641. ;--------------------------------------
  2642. align 4
  2643. @@:
  2644.         mov     ebx, [mem_BACKGROUND]
  2645.         add     ebx, 4095
  2646.         and     ebx, -4096
  2647.         sub     ebx, 4
  2648.         cmp     ecx, ebx
  2649.         ja      .ret
  2650.  
  2651.         mov     ebx, [eax+ecx]
  2652.         and     ebx, 0xFF000000;255*256*256*256
  2653.         and     edx, 0x00FFFFFF;255*256*256+255*256+255
  2654.         add     edx, ebx
  2655.         mov     [eax+ecx], edx
  2656. ;--------------------------------------
  2657. align 4
  2658. .ret:
  2659.         ret
  2660. ;------------------------------------------------------------------------------
  2661. align 4
  2662. nosb2:
  2663.         cmp     ebx, 3                     ; DRAW BACKGROUND
  2664.         jnz     nosb3
  2665. ;--------------------------------------
  2666. align 4
  2667. draw_background_temp:
  2668.         mov     [background_defined], 1
  2669.         call    force_redraw_background
  2670. ;--------------------------------------
  2671. align 4
  2672. nosb31:
  2673.         ret
  2674. ;------------------------------------------------------------------------------
  2675. align 4
  2676. nosb3:
  2677.         cmp     ebx, 4                     ; TILED / STRETCHED
  2678.         jnz     nosb4
  2679.         cmp     ecx, [BgrDrawMode]
  2680.         je      nosb41
  2681.         mov     [BgrDrawMode], ecx
  2682. ;--------------------------------------
  2683. align 4
  2684. nosb41:
  2685.         ret
  2686. ;------------------------------------------------------------------------------
  2687. align 4
  2688. nosb4:
  2689.         cmp     ebx, 5                     ; BLOCK MOVE TO BGR
  2690.         jnz     nosb5
  2691.         cmp     [img_background], static_background_data
  2692.         jnz     @f
  2693.         test    edx, edx
  2694.         jnz     .fin
  2695.         cmp     esi, 4
  2696.         ja      .fin
  2697. ;--------------------------------------
  2698. align 4
  2699. @@:
  2700.   ; bughere
  2701.         mov     eax, ecx
  2702.         mov     ebx, edx
  2703.         add     ebx, [img_background];IMG_BACKGROUND
  2704.         mov     ecx, esi
  2705.         call    memmove
  2706. ;--------------------------------------
  2707. align 4
  2708. .fin:
  2709.         ret
  2710. ;------------------------------------------------------------------------------
  2711. align 4
  2712. nosb5:
  2713.         cmp     ebx, 6
  2714.         jnz     nosb6
  2715. ;--------------------------------------
  2716. align 4
  2717. ;;Maxis use atomic bts for mutex 4.4.2009
  2718. @@:
  2719.         bts     dword [bgrlock], 0
  2720.         jnc     @f
  2721.         call    change_task
  2722.         jmp     @b
  2723. ;--------------------------------------
  2724. align 4
  2725. @@:
  2726.         mov     eax, [CURRENT_TASK]
  2727.         mov     [bgrlockpid], eax
  2728.         cmp     [img_background], static_background_data
  2729.         jz      .nomem
  2730.         stdcall user_alloc, [mem_BACKGROUND]
  2731.         mov     [esp+32], eax
  2732.         test    eax, eax
  2733.         jz      .nomem
  2734.         mov     ebx, eax
  2735.         shr     ebx, 12
  2736.         or      dword [page_tabs+(ebx-1)*4], DONT_FREE_BLOCK
  2737.         mov     esi, [img_background]
  2738.         shr     esi, 12
  2739.         mov     ecx, [mem_BACKGROUND]
  2740.         add     ecx, 0xFFF
  2741.         shr     ecx, 12
  2742. ;--------------------------------------
  2743. align 4
  2744. .z:
  2745.         mov     eax, [page_tabs+ebx*4]
  2746.         test    al, 1
  2747.         jz      @f
  2748.         call    free_page
  2749. ;--------------------------------------
  2750. align 4
  2751. @@:
  2752.         mov     eax, [page_tabs+esi*4]
  2753.         or      al, PG_UW
  2754.         mov     [page_tabs+ebx*4], eax
  2755.         mov     eax, ebx
  2756.         shl     eax, 12
  2757.         invlpg  [eax]
  2758.         inc     ebx
  2759.         inc     esi
  2760.         loop    .z
  2761.         ret
  2762. ;--------------------------------------
  2763. align 4
  2764. .nomem:
  2765.         and     [bgrlockpid], 0
  2766.         mov     [bgrlock], 0
  2767. ;------------------------------------------------------------------------------
  2768. align 4
  2769. nosb6:
  2770.         cmp     ebx, 7
  2771.         jnz     nosb7
  2772.         cmp     [bgrlock], 0
  2773.         jz      .err
  2774.         mov     eax, [CURRENT_TASK]
  2775.         cmp     [bgrlockpid], eax
  2776.         jnz     .err
  2777.         mov     eax, ecx
  2778.         mov     ebx, ecx
  2779.         shr     eax, 12
  2780.         mov     ecx, [page_tabs+(eax-1)*4]
  2781.         test    cl, USED_BLOCK+DONT_FREE_BLOCK
  2782.         jz      .err
  2783.         jnp     .err
  2784.         push    eax
  2785.         shr     ecx, 12
  2786.         dec     ecx
  2787. ;--------------------------------------
  2788. align 4
  2789. @@:
  2790.         and     dword [page_tabs+eax*4], 0
  2791.         mov     edx, eax
  2792.         shl     edx, 12
  2793.         push    eax
  2794.         invlpg  [edx]
  2795.         pop     eax
  2796.         inc     eax
  2797.         loop    @b
  2798.         pop     eax
  2799.         and     dword [page_tabs+(eax-1)*4], not DONT_FREE_BLOCK
  2800.         stdcall user_free, ebx
  2801.         mov     [esp+32], eax
  2802.         and     [bgrlockpid], 0
  2803.         mov     [bgrlock], 0
  2804.         ret
  2805. ;--------------------------------------
  2806. align 4
  2807. .err:
  2808.         and     dword [esp+32], 0
  2809.         ret
  2810. ;------------------------------------------------------------------------------
  2811. align 4
  2812. nosb7:
  2813.         cmp     ebx, 8
  2814.         jnz     nosb8
  2815.  
  2816.         mov     ecx, [current_slot]
  2817.         xor     eax, eax
  2818.         xchg    eax, [ecx+APPDATA.draw_bgr_x]
  2819.         mov     [esp + 32], eax ; eax = [left]*65536 + [right]
  2820.         xor     eax, eax
  2821.         xchg    eax, [ecx+APPDATA.draw_bgr_y]
  2822.         mov     [esp + 20], eax ; ebx = [top]*65536 + [bottom]
  2823.         ret
  2824. ;------------------------------------------------------------------------------
  2825. align 4
  2826. nosb8:
  2827.         cmp     ebx, 9
  2828.         jnz     nosb9
  2829. ; ecx = [left]*65536 + [right]
  2830. ; edx = [top]*65536 + [bottom]
  2831.         mov     eax, [Screen_Max_X]
  2832.         mov     ebx, [Screen_Max_Y]
  2833. ; check [right]
  2834.         cmp     cx, ax
  2835.         ja      .exit
  2836. ; check [left]
  2837.         ror     ecx, 16
  2838.         cmp     cx, ax
  2839.         ja      .exit
  2840. ; check [bottom]
  2841.         cmp     dx, bx
  2842.         ja      .exit
  2843. ; check [top]
  2844.         ror     edx, 16
  2845.         cmp     dx, bx
  2846.         ja      .exit
  2847.  
  2848.         movzx   eax, cx  ; [left]
  2849.         movzx   ebx, dx  ; [top]
  2850.  
  2851.         shr     ecx, 16 ; [right]
  2852.         shr     edx, 16 ; [bottom]
  2853.  
  2854.         mov     [background_defined], 1
  2855.  
  2856.         mov     [draw_data+32 + RECT.left], eax
  2857.         mov     [draw_data+32 + RECT.top], ebx
  2858.  
  2859.         mov     [draw_data+32 + RECT.right], ecx
  2860.         mov     [draw_data+32 + RECT.bottom], edx
  2861.  
  2862.         inc     byte[REDRAW_BACKGROUND]
  2863.         call    wakeup_osloop
  2864. ;--------------------------------------
  2865. align 4
  2866. .exit:
  2867.         ret
  2868. ;------------------------------------------------------------------------------
  2869. align 4
  2870. nosb9:
  2871.         ret
  2872. ;------------------------------------------------------------------------------
  2873. align 4
  2874. uglobal
  2875.   BG_Rect_X_left_right  dd   0x0
  2876.   BG_Rect_Y_top_bottom  dd   0x0