Subversion Repositories Kolibri OS

Rev

Rev 4457 | Blame | Compare with Previous | Last modification | View Log | Download | RSS feed

  1. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  2. ;;
  3. ;; Copyright (C) KolibriOS team 2004-2013. All rights reserved.
  4. ;; PROGRAMMING:
  5. ;; Ivan Poddubny
  6. ;; Marat Zakiyanov (Mario79)
  7. ;; VaStaNi
  8. ;; Trans
  9. ;; Mihail Semenyako (mike.dld)
  10. ;; Sergey Kuzmin (Wildwest)
  11. ;; Andrey Halyavin (halyavin)
  12. ;; Mihail Lisovin (Mihasik)
  13. ;; Andrey Ignatiev (andrew_programmer)
  14. ;; NoName
  15. ;; Evgeny Grechnikov (Diamond)
  16. ;; Iliya Mihailov (Ghost)
  17. ;; Sergey Semyonov (Serge)
  18. ;; Johnny_B
  19. ;; SPraid (simba)
  20. ;; Hidnplayr
  21. ;; Alexey Teplov (<Lrz>)
  22. ;; Rus
  23. ;; Nable
  24. ;; shurf
  25. ;; Alver
  26. ;; Maxis
  27. ;; Galkov
  28. ;; CleverMouse
  29. ;; tsdima
  30. ;; turbanoff
  31. ;; Asper
  32. ;; art_zh
  33. ;;
  34. ;; Data in this file was originally part of MenuetOS project which is
  35. ;; distributed under the terms of GNU GPL. It is modified and redistributed as
  36. ;; part of KolibriOS project under the terms of GNU GPL.
  37. ;;
  38. ;; Copyright (C) MenuetOS 2000-2004 Ville Mikael Turjanmaa
  39. ;; PROGRAMMING:
  40. ;;
  41. ;; Ville Mikael Turjanmaa, villemt@itu.jyu.fi
  42. ;; - main os coding/design
  43. ;; Jan-Michael Brummer, BUZZ2@gmx.de
  44. ;; Felix Kaiser, info@felix-kaiser.de
  45. ;; Paolo Minazzi, paolo.minazzi@inwind.it
  46. ;; quickcode@mail.ru
  47. ;; Alexey, kgaz@crosswinds.net
  48. ;; Juan M. Caravaca, bitrider@wanadoo.es
  49. ;; kristol@nic.fi
  50. ;; Mike Hibbett, mikeh@oceanfree.net
  51. ;; Lasse Kuusijarvi, kuusijar@lut.fi
  52. ;; Jarek Pelczar, jarekp3@wp.pl
  53. ;;
  54. ;; KolibriOS is distributed in the hope that it will be useful, but WITHOUT ANY
  55. ;; WARRANTY. No author or distributor accepts responsibility to anyone for the
  56. ;; consequences of using it or for whether it serves any particular purpose or
  57. ;; works at all, unless he says so in writing. Refer to the GNU General Public
  58. ;; License (the "GPL") for full details.
  59. ;
  60. ;; Everyone is granted permission to copy, modify and redistribute KolibriOS,
  61. ;; but only under the conditions described in the GPL. A copy of this license
  62. ;; is supposed to have been given to you along with KolibriOS so you can know
  63. ;; your rights and responsibilities. It should be in a file named COPYING.
  64. ;; Among other things, the copyright notice and this notice must be preserved
  65. ;; on all copies.
  66. ;;
  67. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  68.  
  69. format binary as "mnt"
  70.  
  71. include 'macros.inc'
  72. include 'struct.inc'
  73.  
  74. $Revision: 4381 $
  75.  
  76.  
  77. USE_FIX_FOR_INVALID_MS_VIRTUAL_PC_2007 equ 0
  78.  
  79. USE_COM_IRQ     equ 1      ; make irq 3 and irq 4 available for PCI devices
  80. VESA_1_2_VIDEO equ 0      ; enable vesa 1.2 bank switch functions
  81.  
  82. ; Enabling the next line will enable serial output console
  83. ;debug_com_base  equ 0x3f8  ; 0x3f8 is com1, 0x2f8 is com2, 0x3e8 is com3, 0x2e8 is com4, no irq's are used
  84.  
  85. include "proc32.inc"
  86. include "kglobals.inc"
  87. include "lang.inc"
  88. include "encoding.inc"
  89.  
  90. include "const.inc"
  91.  
  92. iglobal
  93. ; The following variable, if equal to 1, duplicates debug output to the screen.
  94. debug_direct_print db 0
  95. ; Start the first app (LAUNCHER) after kernel is loaded? (1=yes, 2 or 0=no)
  96. launcher_start db 1
  97. endg
  98.  
  99. max_processes   equ   255
  100. tss_step         equ   (128+8192) ; tss & i/o - 65535 ports, * 256=557056*4
  101.  
  102. os_stack       equ  (os_data_l-gdts)    ; GDTs
  103. os_code       equ  (os_code_l-gdts)
  104. graph_data     equ  (3+graph_data_l-gdts)
  105. tss0           equ  (tss0_l-gdts)
  106. app_code       equ  (3+app_code_l-gdts)
  107. app_data       equ  (3+app_data_l-gdts)
  108. app_tls       equ  (3+tls_data_l-gdts)
  109. pci_code_sel   equ  (pci_code_32-gdts)
  110. pci_data_sel   equ  (pci_data_32-gdts)
  111.  
  112.  
  113. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  114. ;;
  115. ;;   Included files:
  116. ;;
  117. ;;   Kernel16.inc
  118. ;;    - Booteng.inc   English text for bootup
  119. ;;    - Bootcode.inc  Hardware setup
  120. ;;    - Pci16.inc     PCI functions
  121. ;;
  122. ;;   Kernel32.inc
  123. ;;    - Sys32.inc     Process management
  124. ;;    - Shutdown.inc  Shutdown and restart
  125. ;;    - Fat32.inc     Read / write hd
  126. ;;    - Vesa12.inc    Vesa 1.2 driver
  127. ;;    - Vesa20.inc    Vesa 2.0 driver
  128. ;;    - Vga.inc       VGA driver
  129. ;;    - Stack.inc     Network interface
  130. ;;    - Mouse.inc     Mouse pointer
  131. ;;    - Scincode.inc  Window skinning
  132. ;;    - Pci32.inc     PCI functions
  133. ;;
  134. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  135.  
  136.  
  137. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  138. ;;                                                                      ;;
  139. ;;                  16 BIT ENTRY FROM BOOTSECTOR                        ;;
  140. ;;                                                                      ;;
  141. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  142.  
  143. use16
  144.                   org   0x0
  145.         jmp     start_of_code
  146.  
  147. if lang eq sp
  148. include "kernelsp.inc"  ; spanish kernel messages
  149. else if lang eq et
  150. version db    'Kolibri OS  versioon 0.7.7.0+    ',13,10,13,10,0
  151. else
  152. version db    'Kolibri OS  version 0.7.7.0+     ',13,10,13,10,0
  153. end if
  154.  
  155. include "boot/bootstr.inc"     ; language-independent boot messages
  156. include "boot/preboot.inc"
  157.  
  158. if lang eq ge
  159. include "boot/bootge.inc"     ; german system boot messages
  160. else if lang eq sp
  161. include "boot/bootsp.inc"     ; spanish system boot messages
  162. else if lang eq ru
  163. include "boot/bootru.inc"      ; russian system boot messages
  164. include "boot/ru.inc"          ; Russian font
  165. else if lang eq et
  166. include "boot/bootet.inc"      ; estonian system boot messages
  167. include "boot/et.inc"          ; Estonian font
  168. else
  169. include "boot/booten.inc"      ; english system boot messages
  170. end if
  171.  
  172. include "boot/bootcode.inc"    ; 16 bit system boot code
  173. include "bus/pci/pci16.inc"
  174. include "detect/biosdisk.inc"
  175.  
  176. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  177. ;;                                                                      ;;
  178. ;;                  SWITCH TO 32 BIT PROTECTED MODE                     ;;
  179. ;;                                                                      ;;
  180. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  181.  
  182.         cld
  183.  
  184. ; Enabling 32 bit protected mode
  185.  
  186.         mov     ecx, CR0_PE             ; CR0 Flags - Protected mode and Paging
  187.         lgdt    [cs:tmp_gdt]            ; Load GDT
  188.         mov     eax, cr0                ; protected mode
  189.         or      eax, ecx
  190.         and     eax, 10011111b *65536*256 + 0xffffff ; caching enabled
  191.         mov     cr0, eax
  192.         jmp     pword os_code:B32       ; jmp to enable 32 bit mode
  193.  
  194. align 8
  195. tmp_gdt:
  196.  
  197.         dw     23
  198.         dd     tmp_gdt+0x10000
  199.         dw     0
  200.  
  201.         dw     0xffff
  202.         dw     0x0000
  203.         db     0x00
  204.         dw     11011111b *256 +10011010b
  205.         db     0x00
  206.  
  207.         dw     0xffff
  208.         dw     0x0000
  209.         db     0x00
  210.         dw     11011111b *256 +10010010b
  211.         db     0x00
  212.  
  213. include "data16.inc"
  214.  
  215. if ~ lang eq sp
  216. diff16 "end of bootcode",0,$+0x10000
  217. end if
  218.  
  219. use32
  220. org $+0x10000
  221.  
  222. align 4
  223. B32:
  224.         mov     ax, os_stack       ; Selector for os
  225.         mov     ds, ax
  226.         mov     es, ax
  227.         mov     fs, ax
  228.         mov     gs, ax
  229.         mov     ss, ax
  230.         mov     esp, 0x006CC00       ; Set stack
  231.  
  232. ; CLEAR 0x280000 - HEAP_BASE
  233.  
  234.         xor     eax, eax
  235.         mov     edi, CLEAN_ZONE
  236.         mov     ecx, (HEAP_BASE-OS_BASE-CLEAN_ZONE) / 4
  237.         cld
  238.         rep stosd
  239.  
  240. ; CLEAR KERNEL UNDEFINED GLOBALS
  241.         mov     edi, endofcode-OS_BASE
  242.         mov     ecx, 0x90000
  243.         sub     ecx, edi
  244.         shr     ecx, 2
  245.         rep stosd
  246.  
  247. ; SAVE & CLEAR 0-0xffff
  248.  
  249.         mov     edi, 0x1000
  250.         mov     ecx, 0x8000 / 4
  251.         rep stosd
  252.         mov     edi, 0xa000
  253.         mov     ecx, 0x6000 / 4
  254.         rep stosd
  255.  
  256.         call    test_cpu
  257.         bts     [cpu_caps-OS_BASE], CAPS_TSC    ;force use rdtsc
  258.  
  259.         call    check_acpi
  260.         call    init_BIOS32
  261. ; MEMORY MODEL
  262.         call    mem_test
  263.         call    init_mem
  264.         call    init_page_map
  265.  
  266. ; ENABLE PAGING
  267.  
  268.         mov     eax, sys_proc-OS_BASE+PROC.pdt_0
  269.         mov     cr3, eax
  270.  
  271.         mov     eax, cr0
  272.         or      eax, CR0_PG+CR0_WP
  273.         mov     cr0, eax
  274.  
  275.         lgdt    [gdts]
  276.         jmp     pword os_code:high_code
  277.  
  278. align 4
  279. bios32_entry    dd ?
  280. tmp_page_tabs   dd ?
  281.  
  282. use16
  283. org $-0x10000
  284. include "boot/shutdown.inc" ; shutdown or restart
  285. org $+0x10000
  286. use32
  287.  
  288. __DEBUG__ fix 1
  289. __DEBUG_LEVEL__ fix 1
  290. include 'init.inc'
  291.  
  292. org OS_BASE+$
  293.  
  294. include 'fdo.inc'
  295.  
  296. align 4
  297. high_code:
  298.         mov     ax, os_stack
  299.         mov     bx, app_data
  300.         mov     cx, app_tls
  301.         mov     ss, ax
  302.         add     esp, OS_BASE
  303.  
  304.         mov     ds, bx
  305.         mov     es, bx
  306.         mov     fs, cx
  307.         mov     gs, bx
  308.  
  309.         bt      [cpu_caps], CAPS_PGE
  310.         jnc     @F
  311.  
  312.         or      dword [sys_proc+PROC.pdt_0+(OS_BASE shr 20)], PG_GLOBAL
  313.  
  314.         mov     ebx, cr4
  315.         or      ebx, CR4_PGE
  316.         mov     cr4, ebx
  317. @@:
  318.         xor     eax, eax
  319.         mov     dword [sys_proc+PROC.pdt_0], eax
  320.         mov     dword [sys_proc+PROC.pdt_0+4], eax
  321.  
  322.         mov     eax, cr3
  323.         mov     cr3, eax          ; flush TLB
  324.  
  325.         mov     ecx, pg_data.mutex
  326.         call    mutex_init
  327.  
  328.         mov     ecx, disk_list_mutex
  329.         call    mutex_init
  330.  
  331.         mov     ecx, keyboard_list_mutex
  332.         call    mutex_init
  333.  
  334.         mov     ecx, unpack_mutex
  335.         call    mutex_init
  336.  
  337.         mov     ecx, application_table_mutex
  338.         call    mutex_init
  339.  
  340.         mov     ecx, ide_mutex
  341.         call    mutex_init
  342.         mov     ecx, ide_channel1_mutex
  343.         call    mutex_init
  344.         mov     ecx, ide_channel2_mutex
  345.         call    mutex_init
  346. ;-----------------------------------------------------------------------------
  347. ; SAVE REAL MODE VARIABLES
  348. ;-----------------------------------------------------------------------------
  349. save_variables_IDE_controller:
  350.         xor     eax, eax
  351.         mov     ax, [BOOT_VARS + BOOT_IDE_INTERR_16]
  352.         mov     [IDE_Interrupt], ax
  353. ;--------------------------------------
  354.         mov     ax, [BOOT_VARS + BOOT_IDE_PI_16]
  355.         mov     [IDEContrProgrammingInterface], ax
  356. ;--------------------------------------
  357.         mov     ax, [BOOT_VARS + BOOT_IDE_BASE_ADDR]
  358.         mov     [IDEContrRegsBaseAddr], ax
  359. ;--------------------------------------
  360.         mov     ax, [BOOT_VARS + BOOT_IDE_BAR0_16]
  361.         cmp     ax, 0
  362.         je      @f
  363.         cmp     ax, 1
  364.         jne     .no_PATA_BAR0
  365. @@:
  366.         mov     ax, 0x1F0
  367.         jmp     @f
  368. .no_PATA_BAR0:
  369.         and     ax, 0xFFFC
  370. @@:
  371.         mov     [StandardATABases], ax
  372.         mov     [hd_address_table], eax
  373.         mov     [hd_address_table+8], eax
  374.         mov     [IDE_BAR0_val], ax
  375. ;--------------------------------------
  376.         mov     ax, [BOOT_VARS + BOOT_IDE_BAR1_16]
  377.         cmp     ax, 0
  378.         je      @f
  379.         cmp     ax, 1
  380.         jne     .no_PATA_BAR1
  381. @@:
  382.         mov     ax, 0x3F4
  383.         jmp     @f
  384. .no_PATA_BAR1:
  385.         and     ax, 0xFFFC
  386. @@:
  387.         mov     [IDE_BAR1_val], ax
  388. ;--------------------------------------
  389.         mov     ax, [BOOT_VARS + BOOT_IDE_BAR2_16]
  390.         cmp     ax, 0
  391.         je      @f
  392.         cmp     ax, 1
  393.         jne     .no_PATA_BAR2
  394. @@:
  395.         mov     ax, 0x170
  396.         jmp     @f
  397. .no_PATA_BAR2:
  398.         and     ax, 0xFFFC
  399. @@:
  400.         mov     [StandardATABases+2], ax
  401.         mov     [hd_address_table+16], eax
  402.         mov     [hd_address_table+24], eax
  403.         mov     [IDE_BAR2_val], ax
  404. ;--------------------------------------
  405.         mov     ax, [BOOT_VARS + BOOT_IDE_BAR3_16]
  406.         cmp     ax, 0
  407.         je      @f
  408.         cmp     ax, 1
  409.         jne     .no_PATA_BAR3
  410. @@:
  411.         mov     ax, 0x374
  412.         jmp     @f
  413. .no_PATA_BAR3:
  414.         and     ax, 0xFFFC
  415. @@:
  416.         mov     [IDE_BAR3_val], ax
  417.  
  418. ; --------------- APM ---------------------
  419.  
  420. ; init selectors
  421.         mov     ebx, [BOOT_VARS+BOOT_APM_ENTRY]        ; offset of APM entry point
  422.         movzx   eax, word [BOOT_VARS+BOOT_APM_CODE_32] ; real-mode segment base address of
  423.                                                                                 ; protected-mode 32-bit code segment
  424.         movzx   ecx, word [BOOT_VARS+BOOT_APM_CODE_16]; real-mode segment base address of
  425.                                                                                 ; protected-mode 16-bit code segment
  426.         movzx   edx, word [BOOT_VARS+BOOT_APM_DATA_16]; real-mode segment base address of
  427.                                                                                 ; protected-mode 16-bit data segment
  428.  
  429.         shl     eax, 4
  430.         mov     [dword apm_code_32 + 2], ax
  431.         shr     eax, 16
  432.         mov     [dword apm_code_32 + 4], al
  433.  
  434.         shl     ecx, 4
  435.         mov     [dword apm_code_16 + 2], cx
  436.         shr     ecx, 16
  437.         mov     [dword apm_code_16 + 4], cl
  438.  
  439.         shl     edx, 4
  440.         mov     [dword apm_data_16 + 2], dx
  441.         shr     edx, 16
  442.         mov     [dword apm_data_16 + 4], dl
  443.  
  444.         mov     dword[apm_entry], ebx
  445.         mov     word [apm_entry + 4], apm_code_32 - gdts
  446.  
  447.         mov     eax, [BOOT_VARS + BOOT_APM_VERSION] ; version & flags
  448.         mov     [apm_vf], eax
  449. ; -----------------------------------------
  450.         mov     al, [BOOT_VARS+BOOT_DMA]            ; DMA access
  451.         mov     [allow_dma_access], al
  452.         movzx   eax, byte [BOOT_VARS+BOOT_BPP]      ; bpp
  453.         mov     [_display.bpp], eax
  454.         mov     [_display.vrefresh], 60
  455.         mov     al, [BOOT_VARS+BOOT_DEBUG_PRINT]    ; If nonzero, duplicates debug output to the screen
  456.         mov     [debug_direct_print], al
  457.         mov     al, [BOOT_VARS+BOOT_LAUNCHER_START] ; Start the first app (LAUNCHER) after kernel is loaded?
  458.         mov     [launcher_start], al
  459.         movzx   eax, word [BOOT_VARS+BOOT_X_RES]; X max
  460.         mov     [_display.width], eax
  461.         mov     [display_width_standard], eax
  462.         dec     eax
  463.         mov     [Screen_Max_X], eax
  464.         mov     [screen_workarea.right], eax
  465.         movzx   eax, word [BOOT_VARS+BOOT_Y_RES]; Y max
  466.         mov     [_display.height], eax
  467.         mov     [display_height_standard], eax
  468.         dec     eax
  469.         mov     [Screen_Max_Y], eax
  470.         mov     [screen_workarea.bottom], eax
  471.         movzx   eax, word [BOOT_VARS+BOOT_VESA_MODE] ; screen mode
  472.         mov     dword [SCR_MODE], eax
  473. ;        mov     eax, [BOOT_VAR+0x9014]             ; Vesa 1.2 bnk sw add
  474. ;        mov     [BANK_SWITCH], eax
  475.         mov     eax, 640 *4                         ; Bytes PerScanLine
  476.         cmp     [SCR_MODE], word 0x13               ; 320x200
  477.         je      @f
  478.         cmp     [SCR_MODE], word 0x12               ; VGA 640x480
  479.         je      @f
  480.         movzx   eax, word[BOOT_VARS+BOOT_PITCH]      ; for other modes
  481. @@:
  482.         mov     [_display.pitch], eax
  483.         mov     eax, [_display.width]
  484.         mul     [_display.height]
  485.         mov     [_WinMapSize], eax
  486.  
  487.         call    calculate_fast_getting_offset_for_WinMapAddress
  488. ; for Qemu or non standart video cards
  489. ; Unfortunately [BytesPerScanLine] does not always
  490. ;                             equal to [_display.width] * [ScreenBPP] / 8
  491.         call    calculate_fast_getting_offset_for_LFB
  492.  
  493.         mov     esi, BOOT_VARS+0x9080
  494.         movzx   ecx, byte [esi-1]
  495.         mov     [NumBiosDisks], ecx
  496.         mov     edi, BiosDisksData
  497.         rep movsd
  498.  
  499. ; GRAPHICS ADDRESSES
  500.  
  501.         mov     eax, [BOOT_VARS+BOOT_LFB]
  502.         mov     [LFBAddress], eax
  503.  
  504.         cmp     [SCR_MODE], word 0100000000000000b
  505.         jge     setvesa20
  506.         cmp     [SCR_MODE], word 0x13  ; EGA 320*200 256 colors
  507.         je      v20ga32
  508.         jmp     v20ga24
  509.  
  510. setvesa20:
  511.         mov     [PUTPIXEL], dword Vesa20_putpixel24 ; Vesa 2.0
  512.         mov     [GETPIXEL], dword Vesa20_getpixel24
  513.         cmp     byte [_display.bpp], 24
  514.         jz      v20ga24
  515. v20ga32:
  516.         mov     [PUTPIXEL], dword Vesa20_putpixel32
  517.         mov     [GETPIXEL], dword Vesa20_getpixel32
  518.         jmp     no_mode_0x12
  519. v20ga24:
  520.         cmp     [SCR_MODE], word 0x12               ; 16 C VGA 640x480
  521.         jne     no_mode_0x12
  522.         mov     [PUTPIXEL], dword VGA_putpixel
  523.         mov     [GETPIXEL], dword Vesa20_getpixel32
  524. no_mode_0x12:
  525.  
  526.         mov     [MOUSE_PICTURE], dword mousepointer
  527.         mov     [_display.check_mouse], check_mouse_area_for_putpixel
  528.         mov     [_display.check_m_pixel], check_mouse_area_for_getpixel
  529.  
  530. ; -------- Fast System Call init ----------
  531. ; Intel SYSENTER/SYSEXIT (AMD CPU support it too)
  532.         bt      [cpu_caps], CAPS_SEP
  533.         jnc     .SEnP  ; SysEnter not Present
  534.         xor     edx, edx
  535.         mov     ecx, MSR_SYSENTER_CS
  536.         mov     eax, os_code
  537.         wrmsr
  538.         mov     ecx, MSR_SYSENTER_ESP
  539. ;           mov eax, sysenter_stack ; Check it
  540.         xor     eax, eax
  541.         wrmsr
  542.         mov     ecx, MSR_SYSENTER_EIP
  543.         mov     eax, sysenter_entry
  544.         wrmsr
  545. .SEnP:
  546. ; AMD SYSCALL/SYSRET
  547.         cmp     byte[cpu_vendor], 'A'
  548.         jne     .noSYSCALL
  549.         mov     eax, 0x80000001
  550.         cpuid
  551.         test    edx, 0x800  ; bit_11 - SYSCALL/SYSRET support
  552.         jz      .noSYSCALL
  553.         mov     ecx, MSR_AMD_EFER
  554.         rdmsr
  555.         or      eax, 1 ; bit_0 - System Call Extension (SCE)
  556.         wrmsr
  557.  
  558.         ; !!!! It`s dirty hack, fix it !!!
  559.         ; Bits of EDX :
  560.         ; Bit 31–16 During the SYSRET instruction, this field is copied into the CS register
  561.         ;  and the contents of this field, plus 8, are copied into the SS register.
  562.         ; Bit 15–0 During the SYSCALL instruction, this field is copied into the CS register
  563.         ;  and the contents of this field, plus 8, are copied into the SS register.
  564.  
  565.         ; mov   edx, (os_code + 16) * 65536 + os_code
  566.         mov     edx, 0x1B0008
  567.  
  568.         mov     eax, syscall_entry
  569.         mov     ecx, MSR_AMD_STAR
  570.         wrmsr
  571. .noSYSCALL:
  572. ; -----------------------------------------
  573.         stdcall alloc_page
  574.         stdcall map_page, tss-0xF80, eax, PG_SW
  575.         stdcall alloc_page
  576.         stdcall map_page, tss+0x80, eax, PG_SW
  577.         stdcall alloc_page
  578.         stdcall map_page, tss+0x1080, eax, PG_SW
  579.  
  580. ; LOAD IDT
  581.  
  582.         call    build_interrupt_table ;lidt is executed
  583.           ;lidt [idtreg]
  584.  
  585.         call    init_kernel_heap
  586.         stdcall kernel_alloc, (RING0_STACK_SIZE+512) * 2
  587.         mov     [os_stack_seg], eax
  588.  
  589.         lea     esp, [eax+RING0_STACK_SIZE]
  590.  
  591.         mov     [tss._ss0], os_stack
  592.         mov     [tss._esp0], esp
  593.         mov     [tss._esp], esp
  594.         mov     [tss._cs], os_code
  595.         mov     [tss._ss], os_stack
  596.         mov     [tss._ds], app_data
  597.         mov     [tss._es], app_data
  598.         mov     [tss._fs], app_data
  599.         mov     [tss._gs], app_data
  600.         mov     [tss._io], 128
  601. ;Add IO access table - bit array of permitted ports
  602.         mov     edi, tss._io_map_0
  603.         xor     eax, eax
  604.         not     eax
  605.         mov     ecx, 8192/4
  606.         rep stosd                    ; access to 4096*8=65536 ports
  607.  
  608.         mov     ax, tss0
  609.         ltr     ax
  610.  
  611.         mov     [LFBSize], 0xC00000
  612.         call    init_LFB
  613.         call    init_fpu
  614.         call    init_malloc
  615.  
  616.         stdcall alloc_kernel_space, 0x50000         ; FIXME check size
  617.         mov     [default_io_map], eax
  618.  
  619.         add     eax, 0x2000
  620.         mov     [ipc_tmp], eax
  621.         mov     ebx, 0x1000
  622.  
  623.         add     eax, 0x40000
  624.         mov     [proc_mem_map], eax
  625.  
  626.         add     eax, 0x8000
  627.         mov     [proc_mem_pdir], eax
  628.  
  629.         add     eax, ebx
  630.         mov     [proc_mem_tab], eax
  631.  
  632.         add     eax, ebx
  633.         mov     [tmp_task_ptab], eax
  634.  
  635.         add     eax, ebx
  636.         mov     [ipc_pdir], eax
  637.  
  638.         add     eax, ebx
  639.         mov     [ipc_ptab], eax
  640.  
  641.         stdcall kernel_alloc, (unpack.LZMA_BASE_SIZE+(unpack.LZMA_LIT_SIZE shl \
  642.                 (unpack.lc+unpack.lp)))*4
  643.  
  644.         mov     [unpack.p], eax
  645.  
  646.         call    init_events
  647.         mov     eax, srv.fd-SRV.fd
  648.         mov     [srv.fd], eax
  649.         mov     [srv.bk], eax
  650.  
  651. ;Set base of graphic segment to linear address of LFB
  652.         mov     eax, [LFBAddress]         ; set for gs
  653.         mov     [graph_data_l+2], ax
  654.         shr     eax, 16
  655.         mov     [graph_data_l+4], al
  656.         mov     [graph_data_l+7], ah
  657.  
  658.         stdcall kernel_alloc, [_WinMapSize]
  659.         mov     [_WinMapAddress], eax
  660.  
  661.         xor     eax, eax
  662.         inc     eax
  663.  
  664. ; set background
  665.  
  666.         mov     [BgrDrawMode], eax
  667.         mov     [BgrDataWidth], eax
  668.         mov     [BgrDataHeight], eax
  669.         mov     [mem_BACKGROUND], 4
  670.         mov     [img_background], static_background_data
  671.  
  672. ; set clipboard
  673.  
  674.         xor     eax, eax
  675.         mov     [clipboard_slots], eax
  676.         mov     [clipboard_write_lock], eax
  677.         stdcall kernel_alloc, 4096
  678.         test    eax, eax
  679.         jnz     @f
  680.  
  681.         dec     eax
  682. @@:
  683.         mov     [clipboard_main_list], eax
  684.  
  685. ; SET UP OS TASK
  686.  
  687.         mov     esi, boot_setostask
  688.         call    boot_log
  689.  
  690.         mov     edi, sys_proc
  691.         list_init edi
  692.         lea     ecx, [edi+PROC.thr_list]
  693.         list_init ecx
  694.         mov     [edi+PROC.pdt_0_phys], sys_proc-OS_BASE+PROC.pdt_0
  695.  
  696.         mov     eax, -1
  697.         mov     edi, thr_slot_map+4
  698.         mov     [edi-4], dword 0xFFFFFFF8
  699.         stosd
  700.         stosd
  701.         stosd
  702.         stosd
  703.         stosd
  704.         stosd
  705.         stosd
  706.  
  707.         mov     [current_process], sys_proc
  708.  
  709.         mov     edx, SLOT_BASE+256*1
  710.         mov     ebx, [os_stack_seg]
  711.         add     ebx, 0x2000
  712.         call    setup_os_slot
  713.         mov     dword [edx], 'IDLE'
  714.         sub     [edx+APPDATA.saved_esp], 4
  715.         mov     eax, [edx+APPDATA.saved_esp]
  716.         mov     dword [eax], idle_thread
  717.         mov     ecx, IDLE_PRIORITY
  718.         call    scheduler_add_thread
  719.  
  720.         mov     edx, SLOT_BASE+256*2
  721.         mov     ebx, [os_stack_seg]
  722.         call    setup_os_slot
  723.         mov     dword [edx], 'OS'
  724.         xor     ecx, ecx
  725.         call    scheduler_add_thread
  726.  
  727.         mov     dword [CURRENT_TASK], 2
  728.         mov     dword [TASK_COUNT], 2
  729.         mov     dword [current_slot], SLOT_BASE + 256*2
  730.         mov     dword [TASK_BASE], CURRENT_TASK + 32*2
  731.  
  732.  
  733. ; REDIRECT ALL IRQ'S TO INT'S 0x20-0x2f
  734.         mov     esi, boot_initirq
  735.         call    boot_log
  736.         call    init_irqs
  737.  
  738.         mov     esi, boot_picinit
  739.         call    boot_log
  740.         call    PIC_init
  741.  
  742.         mov     esi, boot_v86machine
  743.         call    boot_log
  744. ; Initialize system V86 machine
  745.         call    init_sys_v86
  746.  
  747.         mov     esi, boot_inittimer
  748.         call    boot_log
  749. ; Initialize system timer (IRQ0)
  750.         call    PIT_init
  751.  
  752. ; Register ramdisk file system
  753.         mov     esi, boot_initramdisk
  754.         call    boot_log
  755.         call    ramdisk_init
  756.  
  757.         mov     esi, boot_initapic
  758.         call    boot_log
  759. ; Try to Initialize APIC
  760.         call    APIC_init
  761.  
  762.         mov     esi, boot_enableirq
  763.         call    boot_log
  764. ; Enable timer IRQ (IRQ0) and co-processor IRQ (IRQ13)
  765. ; they are used: when partitions are scanned, hd_read relies on timer
  766.         call    unmask_timer
  767.         stdcall enable_irq, 2               ; @#$%! PIC
  768.         stdcall enable_irq, 13              ; co-processor
  769. ;-----------------------------------------------------------------------------
  770. ; show SVN version of kernel on the message board
  771. ;-----------------------------------------------------------------------------
  772.         mov     eax, [version_inf.rev]
  773.         DEBUGF  1, "K : kernel SVN r%d\n", eax
  774. ;-----------------------------------------------------------------------------
  775. ; show CPU count on the message board
  776. ;-----------------------------------------------------------------------------
  777.         mov     eax, [cpu_count]
  778.         test    eax, eax
  779.         jnz     @F
  780.         mov     al, 1                             ; at least one CPU
  781. @@:
  782.         DEBUGF  1, "K : %d CPU detected\n", eax
  783. ;-----------------------------------------------------------------------------
  784. ; detect Floppy drives
  785. ;-----------------------------------------------------------------------------
  786.         mov     esi, boot_detectfloppy
  787.         call    boot_log
  788. include 'detect/dev_fd.inc'
  789. ;-----------------------------------------------------------------------------
  790. ; START of initialisation IDE ATA code
  791. ;-----------------------------------------------------------------------------
  792.         cmp     [IDEContrProgrammingInterface], 0
  793.         je      @f
  794.  
  795.         mov     esi, boot_disabling_ide
  796.         call    boot_log
  797. ;--------------------------------------
  798. ; Disable IDE interrupts, because the search
  799. ; for IDE partitions is in the PIO mode.
  800. ;--------------------------------------
  801. .disable_IDE_interrupt:
  802. ; Disable interrupts in IDE controller for PIO
  803.         mov     al, 2
  804.         mov     dx, [IDE_BAR1_val] ;0x3F4
  805.         add     dx, 2 ;0x3F6
  806.         out     dx, al
  807.         mov     dx, [IDE_BAR3_val] ;0x374
  808.         add     dx, 2 ;0x376
  809.         out     dx, al
  810. @@:
  811. ; show base variables of IDE controller
  812.         DEBUGF  1, "K : BAR0 %x \n", [IDE_BAR0_val]:4
  813.         DEBUGF  1, "K : BAR1 %x \n", [IDE_BAR1_val]:4
  814.         DEBUGF  1, "K : BAR2 %x \n", [IDE_BAR2_val]:4
  815.         DEBUGF  1, "K : BAR3 %x \n", [IDE_BAR3_val]:4
  816.         DEBUGF  1, "K : BAR4 %x \n", [IDEContrRegsBaseAddr]:4
  817.         DEBUGF  1, "K : IDEContrProgrammingInterface %x \n", [IDEContrProgrammingInterface]:4
  818.         DEBUGF  1, "K : IDE_Interrupt %x \n", [IDE_Interrupt]:4
  819. ;-----------------------------------------------------------------------------
  820.         mov     esi, boot_detecthdcd
  821.         call    boot_log
  822. include 'detect/dev_hdcd.inc'
  823.         mov     esi, boot_getcache
  824.         call    boot_log
  825. include 'detect/getcache.inc'
  826.         mov     esi, boot_detectpart
  827.         call    boot_log
  828. include 'detect/sear_par.inc'
  829. ;-----------------------------------------------------------------------------
  830.         mov     dx, [IDEContrRegsBaseAddr]
  831. ; test whether it is our interrupt?
  832.         add     dx, 2
  833.         in      al, dx
  834.         test    al, 100b
  835.         jz      @f
  836. ; clear Bus Master IDE Status register
  837. ; clear Interrupt bit
  838.         out     dx, al
  839. @@:
  840.         add     dx, 8
  841. ; test whether it is our interrupt?
  842.         in      al, dx
  843.         test    al, 100b
  844.         jz      @f
  845. ; clear Bus Master IDE Status register
  846. ; clear Interrupt bit
  847.         out     dx, al
  848. @@:
  849. ; read status register and remove the interrupt request
  850.         mov     dx, [IDE_BAR0_val] ;0x1F0
  851.         add     dx, 0x7 ;0x1F7
  852.         in      al, dx
  853.         mov     dx, [IDE_BAR2_val] ;0x170
  854.         add     dx, 0x7 ;0x177
  855.         in      al, dx
  856. ;-----------------------------------------------------------------------------
  857.         push    eax edx
  858.         mov     dx, [IDEContrRegsBaseAddr]
  859.         xor     eax, eax
  860.         add     dx, 2
  861.         in      al, dx
  862.         DEBUGF  1, "K : Primary Bus Master IDE Status Register %x\n", eax
  863.  
  864.         add     dx, 8
  865.         in      al, dx
  866.         DEBUGF  1, "K : Secondary Bus Master IDE Status Register %x\n", eax
  867.         pop     edx eax
  868.  
  869.         cmp     [IDEContrRegsBaseAddr], 0
  870.         setnz   [dma_hdd]
  871.  
  872.         cmp     [IDEContrProgrammingInterface], 0
  873.         je      set_interrupts_for_IDE_controllers.continue
  874. ;-----------------------------------------------------------------------------
  875. ; set interrupts for IDE Controller
  876. ;-----------------------------------------------------------------------------
  877.         mov     esi, boot_set_int_IDE
  878.         call    boot_log
  879. set_interrupts_for_IDE_controllers:
  880.         mov     ax, [IDEContrProgrammingInterface]
  881.         cmp     ax, 0x0180
  882.         je      .pata_ide
  883.  
  884.         cmp     ax, 0x018a
  885.         jne     .sata_ide
  886. ;--------------------------------------
  887. .pata_ide:
  888.         cmp     [IDEContrRegsBaseAddr], 0
  889.         je      .end_set_interrupts
  890.  
  891.         stdcall attach_int_handler, 14, IDE_irq_14_handler, 0
  892.         DEBUGF  1, "K : Set IDE IRQ14 return code %x\n", eax
  893.         stdcall attach_int_handler, 15, IDE_irq_15_handler, 0
  894.         DEBUGF  1, "K : Set IDE IRQ15 return code %x\n", eax
  895.         jmp     .enable_IDE_interrupt
  896. ;--------------------------------------
  897. .sata_ide:
  898.         cmp     ax, 0x0185
  899.         je      .sata_ide_1
  900.  
  901.         cmp     ax, 0x018f
  902.         jne     .end_set_interrupts
  903. ;--------------------------------------
  904. .sata_ide_1:
  905.         cmp     [IDEContrRegsBaseAddr], 0
  906.         je      .end_set_interrupts
  907.  
  908.         mov     ax, [IDE_Interrupt]
  909.         movzx   eax, al
  910.         stdcall attach_int_handler, eax, IDE_common_irq_handler, 0
  911.         DEBUGF  1, "K : Set IDE IRQ%d return code %x\n", [IDE_Interrupt]:1, eax
  912. ;--------------------------------------
  913. .enable_IDE_interrupt:
  914.         mov     esi, boot_enabling_ide
  915.         call    boot_log
  916. ; Enable interrupts in IDE controller for DMA
  917.         mov     al, 0
  918.         mov     ah, [DRIVE_DATA+1]
  919.         test    ah, 10100000b
  920.         jz      @f
  921.  
  922.         DEBUGF  1, "K : IDE CH1 PIO, because ATAPI drive present\n"
  923.         jmp     .ch2_check
  924. @@:
  925.         mov     dx, [IDE_BAR1_val] ;0x3F4
  926.         add     dx, 2 ;0x3F6
  927.         out     dx, al
  928.         DEBUGF  1, "K : IDE CH1 DMA enabled\n"
  929. .ch2_check:
  930.         test    ah, 1010b
  931.         jz      @f
  932.  
  933.         DEBUGF  1, "K : IDE CH2 PIO, because ATAPI drive present\n"
  934.         jmp     .end_set_interrupts
  935. @@:
  936.         mov     dx, [IDE_BAR3_val] ;0x374
  937.         add     dx, 2 ;0x376
  938.         out     dx, al
  939.         DEBUGF  1, "K : IDE CH2 DMA enabled\n"
  940. ;--------------------------------------
  941. .end_set_interrupts:
  942. ;-----------------------------------------------------------------------------
  943.         cmp     [dma_hdd], 0
  944.         je      .print_pio
  945. .print_dma:
  946.         DEBUGF  1, "K : IDE DMA mode\n"
  947.         jmp     .continue
  948.  
  949. .print_pio:
  950.         DEBUGF  1, "K : IDE PIO mode\n"
  951. .continue:
  952. ;-----------------------------------------------------------------------------
  953. ; END of initialisation IDE ATA code
  954. ;-----------------------------------------------------------------------------
  955.         mov     esi, boot_init_sys
  956.         call    boot_log
  957.         call    Parser_params
  958.  
  959. if ~ defined extended_primary_loader
  960. ; ramdisk image should be loaded by extended primary loader if it exists
  961. ; READ RAMDISK IMAGE FROM HD
  962.  
  963. ;!!!!!!!!!!!!!!!!!!!!!!!
  964. include 'boot/rdload.inc'
  965. ;!!!!!!!!!!!!!!!!!!!!!!!
  966. end if
  967.  
  968. if 0
  969.         mov     ax, [OS_BASE+0x10000+bx_from_load]
  970.         cmp     ax, 'r1'; if using not ram disk, then load librares and parameters {SPraid.simba}
  971.         je      no_lib_load
  972.  
  973.         mov     esi, boot_loadlibs
  974.         call    boot_log
  975. ; LOADING LIBRARES
  976.         stdcall dll.Load, @IMPORT           ; loading librares for kernel (.obj files)
  977.         call    load_file_parse_table       ; prepare file parse table
  978.         call    set_kernel_conf             ; configure devices and gui
  979. no_lib_load:
  980. end if
  981.  
  982. ; Display APIC status
  983.         mov     esi, boot_APIC_found
  984.         cmp     [irq_mode], IRQ_APIC
  985.         je      @f
  986.         mov     esi, boot_APIC_nfound
  987. @@:
  988.         call    boot_log
  989.  
  990. ; PRINT AMOUNT OF MEMORY
  991.         mov     esi, boot_memdetect
  992.         call    boot_log
  993.  
  994.         movzx   ecx, word [boot_y]
  995.         if lang eq ru
  996.         or      ecx, (10+30*6) shl 16
  997.         else if lang eq sp
  998.         or      ecx, (10+33*6) shl 16
  999.         else
  1000.         or      ecx, (10+29*6) shl 16
  1001.         end if
  1002.         sub     ecx, 10
  1003.         mov     edx, 0xFFFFFF
  1004.         mov     ebx, [MEM_AMOUNT]
  1005.         shr     ebx, 20
  1006.         xor     edi, edi
  1007.         mov     eax, 0x00040000
  1008.         inc     edi
  1009.         call    display_number_force
  1010.  
  1011. ; BUILD SCHEDULER
  1012.  
  1013. ;        call    build_scheduler; sys32.inc
  1014.  
  1015. ;        mov     esi, boot_devices
  1016. ;        call    boot_log
  1017.  
  1018.         mov     [pci_access_enabled], 1
  1019.         call    pci_enum
  1020.         call    clear_pci_ide_interrupts
  1021.  
  1022. include "detect/vortex86.inc"                     ; Vortex86 SoC detection code
  1023.  
  1024.         stdcall load_driver, szVidintel
  1025.  
  1026.         call    usb_init
  1027.  
  1028. ; SET PRELIMINARY WINDOW STACK AND POSITIONS
  1029.  
  1030.         mov     esi, boot_windefs
  1031.         call    boot_log
  1032.         call    set_window_defaults
  1033.  
  1034. ; SET BACKGROUND DEFAULTS
  1035.  
  1036.         mov     esi, boot_bgr
  1037.         call    boot_log
  1038.         call    init_background
  1039.         call    calculatebackground
  1040.  
  1041. ; RESERVE SYSTEM IRQ'S JA PORT'S
  1042.  
  1043.         mov     esi, boot_resirqports
  1044.         call    boot_log
  1045.         call    reserve_irqs_ports
  1046.  
  1047.         call    init_display
  1048.         mov     eax, [def_cursor]
  1049.         mov     [SLOT_BASE+APPDATA.cursor+256], eax
  1050.         mov     [SLOT_BASE+APPDATA.cursor+256*2], eax
  1051.  
  1052. ; PRINT CPU FREQUENCY
  1053.  
  1054.         mov     esi, boot_cpufreq
  1055.         call    boot_log
  1056.  
  1057.         cli                         ;FIXME check IF
  1058.         rdtsc
  1059.         mov     ecx, eax
  1060.         mov     esi, 250            ; wait 1/4 a second
  1061.         call    delay_ms
  1062.         rdtsc
  1063.  
  1064.         sub     eax, ecx
  1065.         xor     edx, edx
  1066.         shld    edx, eax, 2
  1067.         shl     eax, 2
  1068.         mov     dword [cpu_freq], eax
  1069.         mov     dword [cpu_freq+4], edx
  1070.         mov     ebx, 1000000
  1071.         div     ebx
  1072.         mov     ebx, eax
  1073.  
  1074.         movzx   ecx, word [boot_y]
  1075.         if lang eq ru
  1076.         add     ecx, (10+19*6) shl 16 - 10
  1077.         else if lang eq sp
  1078.         add     ecx, (10+25*6) shl 16 - 10
  1079.         else
  1080.         add     ecx, (10+17*6) shl 16 - 10
  1081.         end if
  1082.  
  1083.         mov     edx, 0xFFFFFF
  1084.         xor     edi, edi
  1085.         mov     eax, 0x00040000
  1086.         inc     edi
  1087.         call    display_number_force
  1088.  
  1089. ; SET VARIABLES
  1090.  
  1091.         call    set_variables
  1092.  
  1093. ; STACK AND FDC
  1094.  
  1095. ;        call    stack_init
  1096.         call    fdc_init
  1097.  
  1098. ; PALETTE FOR 320x200 and 640x480 16 col
  1099.  
  1100.         cmp     [SCR_MODE], word 0x12
  1101.         jne     no_pal_vga
  1102.         mov     esi, boot_pal_vga
  1103.         call    boot_log
  1104.         call    paletteVGA
  1105.       no_pal_vga:
  1106.  
  1107.         cmp     [SCR_MODE], word 0x13
  1108.         jne     no_pal_ega
  1109.         mov     esi, boot_pal_ega
  1110.         call    boot_log
  1111.         call    palette320x200
  1112.       no_pal_ega:
  1113.  
  1114. ; LOAD DEFAULT SKIN
  1115.  
  1116.         call    load_default_skin
  1117.  
  1118. ;protect io permission map
  1119.  
  1120.         mov     esi, [default_io_map]
  1121.         stdcall map_page, esi, [SLOT_BASE+256+APPDATA.io_map], PG_MAP
  1122.         add     esi, 0x1000
  1123.         stdcall map_page, esi, [SLOT_BASE+256+APPDATA.io_map+4], PG_MAP
  1124.  
  1125.         stdcall map_page, tss._io_map_0, \
  1126.                 [SLOT_BASE+256+APPDATA.io_map], PG_MAP
  1127.         stdcall map_page, tss._io_map_1, \
  1128.                 [SLOT_BASE+256+APPDATA.io_map+4], PG_MAP
  1129.  
  1130. ; LOAD FIRST APPLICATION
  1131.         cmp     byte [launcher_start], 1        ; Check if starting LAUNCHER is selected on blue screen (1 = yes)
  1132.         jnz     first_app_found
  1133.  
  1134.         cli
  1135.         mov     ebp, firstapp
  1136.         call    fs_execute_from_sysdir
  1137.         test    eax, eax
  1138.         jnz     first_app_found
  1139.  
  1140.         mov     esi, boot_failed
  1141.         call    boot_log
  1142.  
  1143.         mov     eax, 0xDEADBEEF      ; otherwise halt
  1144.         hlt
  1145.  
  1146. first_app_found:
  1147.  
  1148.         cli
  1149.  
  1150. ; SET KEYBOARD PARAMETERS
  1151.         mov     al, 0xf6       ; reset keyboard, scan enabled
  1152.         call    kb_write
  1153.         test    ah, ah
  1154.         jnz     .no_keyboard
  1155.  
  1156.         ; wait until 8042 is ready
  1157.         xor     ecx, ecx
  1158.       @@:
  1159.         in      al, 64h
  1160.         and     al, 00000010b
  1161.         loopnz  @b
  1162.  
  1163. iglobal
  1164. align 4
  1165. ps2_keyboard_functions:
  1166.         dd      .end - $
  1167.         dd      0       ; no close
  1168.         dd      ps2_set_lights
  1169. .end:
  1170. endg
  1171.         stdcall register_keyboard, ps2_keyboard_functions, 0
  1172.        ; mov   al, 0xED       ; Keyboard LEDs - only for testing!
  1173.        ; call  kb_write
  1174.        ; call  kb_read
  1175.        ; mov   al, 111b
  1176.        ; call  kb_write
  1177.        ; call  kb_read
  1178.  
  1179.         mov     al, 0xF3     ; set repeat rate & delay
  1180.         call    kb_write
  1181. ;        call  kb_read
  1182.         mov     al, 0; 30 250 ;00100010b ; 24 500  ;00100100b  ; 20 500
  1183.         call    kb_write
  1184. ;        call  kb_read
  1185.      ;// mike.dld [
  1186.         call    set_lights
  1187.      ;// mike.dld ]
  1188.         stdcall attach_int_handler, 1, irq1, 0
  1189.         DEBUGF  1, "K : IRQ1 error code %x\n", eax
  1190. .no_keyboard:
  1191.  
  1192. ; Load PS/2 mouse driver
  1193.  
  1194.         stdcall load_driver, szPS2MDriver
  1195. ;        stdcall load_driver, szCOM_MDriver
  1196.  
  1197.         mov     esi, boot_setmouse
  1198.         call    boot_log
  1199.         call    setmouse
  1200.  
  1201. ; Setup serial output console (if enabled)
  1202. if defined debug_com_base
  1203.  
  1204.         ; reserve port so nobody else will use it
  1205.         xor     ebx, ebx
  1206.         mov     ecx, debug_com_base
  1207.         mov     edx, debug_com_base+7
  1208.         call    r_f_port_area
  1209.  
  1210.         ; enable Divisor latch
  1211.         mov     dx, debug_com_base+3
  1212.         mov     al, 1 shl 7
  1213.         out     dx, al
  1214.  
  1215.         ; Set speed to 115200 baud (max speed)
  1216.         mov     dx, debug_com_base
  1217.         mov     al, 0x01
  1218.         out     dx, al
  1219.  
  1220.         mov     dx, debug_com_base+1
  1221.         mov     al, 0x00
  1222.         out     dx, al
  1223.  
  1224.         ; No parity, 8bits words, one stop bit, dlab bit back to 0
  1225.         mov     dx, debug_com_base+3
  1226.         mov     al, 3
  1227.         out     dx, al
  1228.  
  1229.         ; disable interrupts
  1230.         mov     dx, debug_com_base+1
  1231.         mov     al, 0
  1232.         out     dx, al
  1233.  
  1234.         ; clear +  enable fifo (64 bits)
  1235.         mov     dx, debug_com_base+2
  1236.         mov     al, 0x7 + 1 shl 5
  1237.         out     dx, al
  1238.  
  1239. end if
  1240. ; START MULTITASKING
  1241.  
  1242. ; A 'All set - press ESC to start' messages if need
  1243. if preboot_blogesc
  1244.         mov     esi, boot_tasking
  1245.         call    boot_log
  1246. .bll1:
  1247.         in      al, 0x60        ; wait for ESC key press
  1248.         cmp     al, 129
  1249.         jne     .bll1
  1250. end if
  1251.  
  1252.         mov     [timer_ticks_enable], 1         ; for cd driver
  1253.  
  1254.         sti
  1255. ;        call    change_task
  1256.  
  1257.         jmp     osloop
  1258.  
  1259.  
  1260.         ; Fly :)
  1261.  
  1262. include 'unpacker.inc'
  1263.  
  1264. align 4
  1265. boot_log:
  1266.         pushad
  1267.  
  1268.         mov     ebx, 10*65536
  1269.         mov     bx, word [boot_y]
  1270.         add     [boot_y], dword 10
  1271.         mov     ecx, 0x80ffffff; ASCIIZ string with white color
  1272.         xor     edi, edi
  1273.         mov     edx, esi
  1274.         inc     edi
  1275.         call    dtext
  1276.  
  1277.         mov     [novesachecksum], 1000
  1278.         call    checkVga_N13
  1279.  
  1280.         popad
  1281.  
  1282.         ret
  1283.  
  1284. ; in: edx -> APPDATA for OS/IDLE slot
  1285. ; in: ebx = stack base
  1286. proc setup_os_slot
  1287.         xor     eax, eax
  1288.         mov     ecx, 256/4
  1289.         mov     edi, edx
  1290.         rep stosd
  1291.  
  1292.         mov     eax, tss+0x80
  1293.         call    get_pg_addr
  1294.         inc     eax
  1295.         mov     [edx+APPDATA.io_map], eax
  1296.         mov     eax, tss+0x1080
  1297.         call    get_pg_addr
  1298.         inc     eax
  1299.         mov     [edx+APPDATA.io_map+4], eax
  1300.  
  1301.         mov     dword [edx+APPDATA.pl0_stack], ebx
  1302.         lea     edi, [ebx+0x2000-512]
  1303.         mov     dword [edx+APPDATA.fpu_state], edi
  1304.         mov     dword [edx+APPDATA.saved_esp0], edi
  1305.         mov     dword [edx+APPDATA.saved_esp], edi
  1306.         mov     dword [edx+APPDATA.terminate_protection], 1 ; make unkillable
  1307.  
  1308.         mov     esi, fpu_data
  1309.         mov     ecx, 512/4
  1310.         cld
  1311.         rep movsd
  1312.  
  1313.         lea     eax, [edx+APP_OBJ_OFFSET]
  1314.         mov     dword [edx+APPDATA.fd_obj], eax
  1315.         mov     dword [edx+APPDATA.bk_obj], eax
  1316.  
  1317.         mov     dword [edx+APPDATA.cur_dir], sysdir_path
  1318.  
  1319.         mov     [edx + APPDATA.process], sys_proc
  1320.  
  1321.         mov     eax, edx
  1322.         shr     eax, 3
  1323.         add     eax, CURRENT_TASK - (SLOT_BASE shr 3)
  1324.         mov     [eax+TASKDATA.wnd_number], dh
  1325.         mov     byte [eax+TASKDATA.pid], dh
  1326.  
  1327.         ret
  1328. endp
  1329.  
  1330. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1331. ;                                                                    ;
  1332. ;                    MAIN OS LOOP START                              ;
  1333. ;                                                                    ;
  1334. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1335. align 32
  1336. osloop:
  1337.         mov     edx, osloop_has_work?
  1338.         xor     ecx, ecx
  1339.         call    Wait_events
  1340.         xor     eax, eax
  1341.         xchg    eax, [osloop_nonperiodic_work]
  1342.         test    eax, eax
  1343.         jz      .no_periodic
  1344. ;        call    [draw_pointer]
  1345.         call    __sys_draw_pointer
  1346.         call    window_check_events
  1347.         call    mouse_check_events
  1348.         call    checkmisc
  1349.         call    checkVga_N13
  1350. .no_periodic:
  1351.         call    stack_handler
  1352.         call    check_fdd_motor_status
  1353.         call    check_ATAPI_device_event
  1354.         call    check_lights_state
  1355.         call    check_timers
  1356.         jmp     osloop
  1357. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1358. ;                                                                    ;
  1359. ;                      MAIN OS LOOP END                              ;
  1360. ;                                                                    ;
  1361. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1362. proc osloop_has_work?
  1363.         cmp     [osloop_nonperiodic_work], 0
  1364.         jnz     .yes
  1365.         call    stack_handler_has_work?
  1366.         jnz     .yes
  1367.         call    check_fdd_motor_status_has_work?
  1368.         jnz     .yes
  1369.         call    check_ATAPI_device_event_has_work?
  1370.         jnz     .yes
  1371.         call    check_lights_state_has_work?
  1372.         jnz     .yes
  1373.         call    check_timers_has_work?
  1374.         jnz     .yes
  1375. .no:
  1376.         xor     eax, eax
  1377.         ret
  1378. .yes:
  1379.         xor     eax, eax
  1380.         inc     eax
  1381.         ret
  1382. endp
  1383.  
  1384. proc wakeup_osloop
  1385.         mov     [osloop_nonperiodic_work], 1
  1386.         ret
  1387. endp
  1388.  
  1389. uglobal
  1390. align 4
  1391. osloop_nonperiodic_work dd      ?
  1392. endg
  1393.  
  1394. align 4
  1395. idle_thread:
  1396.         sti
  1397. idle_loop:
  1398.         hlt
  1399.         jmp     idle_loop
  1400.  
  1401.  
  1402.  
  1403. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1404. ;                                                                      ;
  1405. ;                   INCLUDED SYSTEM FILES                              ;
  1406. ;                                                                      ;
  1407. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1408.  
  1409.  
  1410. include "kernel32.inc"
  1411.  
  1412.  
  1413. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1414. ;                                                                      ;
  1415. ;                       KERNEL FUNCTIONS                               ;
  1416. ;                                                                      ;
  1417. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1418.  
  1419. reserve_irqs_ports:
  1420.  
  1421.  
  1422. ; RESERVE PORTS
  1423.         mov     eax, RESERVED_PORTS
  1424.         mov     ecx, 1
  1425.  
  1426.         mov     [eax], dword 4
  1427.  
  1428.         mov     [eax+16], ecx
  1429.         mov     [eax+16+4], dword 0
  1430.         mov     [eax+16+8], dword 0x2D
  1431.  
  1432.         mov     [eax+32], ecx
  1433.         mov     [eax+32+4], dword 0x30
  1434.         mov     [eax+32+8], dword 0x4D
  1435.  
  1436.         mov     [eax+48], ecx
  1437.         mov     [eax+48+4], dword 0x50
  1438.         mov     [eax+48+8], dword 0xDF
  1439.  
  1440.         mov     [eax+64], ecx
  1441.         mov     [eax+64+4], dword 0xE5
  1442.         mov     [eax+64+8], dword 0xFF
  1443.  
  1444.         ret
  1445.  
  1446.  
  1447. iglobal
  1448.   process_number dd 0x2
  1449. endg
  1450.  
  1451. set_variables:
  1452.  
  1453.         mov     ecx, 0x16                    ; flush port 0x60
  1454. .fl60:
  1455.         in      al, 0x60
  1456.         loop    .fl60
  1457.         push    eax
  1458.  
  1459.         mov     ax, [BOOT_VARS+BOOT_Y_RES]
  1460.         shr     ax, 1
  1461.         shl     eax, 16
  1462.         mov     ax, [BOOT_VARS+BOOT_X_RES]
  1463.         shr     ax, 1
  1464.         mov     [MOUSE_X], eax
  1465.         call    wakeup_osloop
  1466.  
  1467.         xor     eax, eax
  1468.         mov     [BTN_ADDR], dword BUTTON_INFO ; address of button list
  1469.  
  1470.         mov     byte [KEY_COUNT], al              ; keyboard buffer
  1471.         mov     byte [BTN_COUNT], al              ; button buffer
  1472. ;        mov   [MOUSE_X],dword 100*65536+100    ; mouse x/y
  1473.  
  1474.         pop     eax
  1475.         ret
  1476.  
  1477. align 4
  1478. ;input  eax=43,bl-byte of output, ecx - number of port
  1479. sys_outport:
  1480.  
  1481.         mov     edi, ecx   ; separate flag for read / write
  1482.         and     ecx, 65535
  1483.  
  1484.         mov     eax, [RESERVED_PORTS]
  1485.         test    eax, eax
  1486.         jnz     .sopl8
  1487.         inc     eax
  1488.         mov     [esp+32], eax
  1489.         ret
  1490.  
  1491.   .sopl8:
  1492.         mov     edx, [TASK_BASE]
  1493.         mov     edx, [edx+0x4]
  1494.     ;and   ecx,65535
  1495.     ;cld - set on interrupt 0x40
  1496.   .sopl1:
  1497.  
  1498.         mov     esi, eax
  1499.         shl     esi, 4
  1500.         add     esi, RESERVED_PORTS
  1501.         cmp     edx, [esi+0]
  1502.         jne     .sopl2
  1503.         cmp     ecx, [esi+4]
  1504.         jb      .sopl2
  1505.         cmp     ecx, [esi+8]
  1506.         jg      .sopl2
  1507. .sopl3:
  1508.  
  1509.         test    edi, 0x80000000; read ?
  1510.         jnz     .sopl4
  1511.  
  1512.         mov     eax, ebx
  1513.         mov     dx, cx   ; write
  1514.         out     dx, al
  1515.         and     [esp+32], dword 0
  1516.         ret
  1517.  
  1518.         .sopl2:
  1519.  
  1520.         dec     eax
  1521.         jnz     .sopl1
  1522.         inc     eax
  1523.         mov     [esp+32], eax
  1524.         ret
  1525.  
  1526.  
  1527.   .sopl4:
  1528.  
  1529.         mov     dx, cx   ; read
  1530.         in      al, dx
  1531.         and     eax, 0xff
  1532.         and     [esp+32], dword 0
  1533.         mov     [esp+20], eax
  1534.         ret
  1535.  
  1536. display_number:
  1537. ;It is not optimization
  1538.         mov     eax, ebx
  1539.         mov     ebx, ecx
  1540.         mov     ecx, edx
  1541.         mov     edx, esi
  1542.         mov     esi, edi
  1543. ; eax = print type, al=0 -> ebx is number
  1544. ;                   al=1 -> ebx is pointer
  1545. ;                   ah=0 -> display decimal
  1546. ;                   ah=1 -> display hexadecimal
  1547. ;                   ah=2 -> display binary
  1548. ;                   eax bits 16-21 = number of digits to display (0-32)
  1549. ;                   eax bits 22-31 = reserved
  1550. ;
  1551. ; ebx = number or pointer
  1552. ; ecx = x shl 16 + y
  1553. ; edx = color
  1554.         xor     edi, edi
  1555. display_number_force:
  1556.         push    eax
  1557.         and     eax, 0x3fffffff
  1558.         cmp     eax, 0xffff     ; length > 0 ?
  1559.         pop     eax
  1560.         jge     cont_displ
  1561.         ret
  1562.    cont_displ:
  1563.         push    eax
  1564.         and     eax, 0x3fffffff
  1565.         cmp     eax, 61*0x10000  ; length <= 60 ?
  1566.         pop     eax
  1567.         jb      cont_displ2
  1568.         ret
  1569.    cont_displ2:
  1570.  
  1571.         pushad
  1572.  
  1573.         cmp     al, 1            ; ecx is a pointer ?
  1574.         jne     displnl1
  1575.         mov     ebp, ebx
  1576.         add     ebp, 4
  1577.         mov     ebp, [ebp+std_application_base_address]
  1578.         mov     ebx, [ebx+std_application_base_address]
  1579.  displnl1:
  1580.         sub     esp, 64
  1581.  
  1582.         test    ah, ah            ; DECIMAL
  1583.         jnz     no_display_desnum
  1584.         shr     eax, 16
  1585.         and     eax, 0xC03f
  1586. ;     and   eax,0x3f
  1587.         push    eax
  1588.         and     eax, 0x3f
  1589.         mov     edi, esp
  1590.         add     edi, 4+64-1
  1591.         mov     ecx, eax
  1592.         mov     eax, ebx
  1593.         mov     ebx, 10
  1594.  d_desnum:
  1595.         xor     edx, edx
  1596.         call    division_64_bits
  1597.         div     ebx
  1598.         add     dl, 48
  1599.         mov     [edi], dl
  1600.         dec     edi
  1601.         loop    d_desnum
  1602.         pop     eax
  1603.         call    normalize_number
  1604.         call    draw_num_text
  1605.         add     esp, 64
  1606.         popad
  1607.         ret
  1608.    no_display_desnum:
  1609.  
  1610.         cmp     ah, 0x01         ; HEXADECIMAL
  1611.         jne     no_display_hexnum
  1612.         shr     eax, 16
  1613.         and     eax, 0xC03f
  1614. ;     and   eax,0x3f
  1615.         push    eax
  1616.         and     eax, 0x3f
  1617.         mov     edi, esp
  1618.         add     edi, 4+64-1
  1619.         mov     ecx, eax
  1620.         mov     eax, ebx
  1621.         mov     ebx, 16
  1622.    d_hexnum:
  1623.         xor     edx, edx
  1624.         call    division_64_bits
  1625.         div     ebx
  1626.    hexletters = __fdo_hexdigits
  1627.         add     edx, hexletters
  1628.         mov     dl, [edx]
  1629.         mov     [edi], dl
  1630.         dec     edi
  1631.         loop    d_hexnum
  1632.         pop     eax
  1633.         call    normalize_number
  1634.         call    draw_num_text
  1635.         add     esp, 64
  1636.         popad
  1637.         ret
  1638.    no_display_hexnum:
  1639.  
  1640.         cmp     ah, 0x02         ; BINARY
  1641.         jne     no_display_binnum
  1642.         shr     eax, 16
  1643.         and     eax, 0xC03f
  1644. ;     and   eax,0x3f
  1645.         push    eax
  1646.         and     eax, 0x3f
  1647.         mov     edi, esp
  1648.         add     edi, 4+64-1
  1649.         mov     ecx, eax
  1650.         mov     eax, ebx
  1651.         mov     ebx, 2
  1652.    d_binnum:
  1653.         xor     edx, edx
  1654.         call    division_64_bits
  1655.         div     ebx
  1656.         add     dl, 48
  1657.         mov     [edi], dl
  1658.         dec     edi
  1659.         loop    d_binnum
  1660.         pop     eax
  1661.         call    normalize_number
  1662.         call    draw_num_text
  1663.         add     esp, 64
  1664.         popad
  1665.         ret
  1666.    no_display_binnum:
  1667.  
  1668.         add     esp, 64
  1669.         popad
  1670.         ret
  1671.  
  1672. normalize_number:
  1673.         test    ah, 0x80
  1674.         jz      .continue
  1675.         mov     ecx, 48
  1676.         and     eax, 0x3f
  1677. @@:
  1678.         inc     edi
  1679.         cmp     [edi], cl
  1680.         jne     .continue
  1681.         dec     eax
  1682.         cmp     eax, 1
  1683.         ja      @r
  1684.         mov     al, 1
  1685. .continue:
  1686.         and     eax, 0x3f
  1687.         ret
  1688.  
  1689. division_64_bits:
  1690.         test    [esp+1+4], byte 0x40
  1691.         jz      .continue
  1692.         push    eax
  1693.         mov     eax, ebp
  1694.         div     ebx
  1695.         mov     ebp, eax
  1696.         pop     eax
  1697. .continue:
  1698.         ret
  1699.  
  1700. draw_num_text:
  1701.         mov     esi, eax
  1702.         mov     edx, 64+4
  1703.         sub     edx, eax
  1704.         add     edx, esp
  1705.         mov     ebx, [esp+64+32-8+4]
  1706. ; add window start x & y
  1707.         mov     ecx, [TASK_BASE]
  1708.  
  1709.         mov     edi, [CURRENT_TASK]
  1710.         shl     edi, 8
  1711.  
  1712.         mov     eax, [ecx-twdw+WDATA.box.left]
  1713.         add     eax, [edi+SLOT_BASE+APPDATA.wnd_clientbox.left]
  1714.         shl     eax, 16
  1715.         add     eax, [ecx-twdw+WDATA.box.top]
  1716.         add     eax, [edi+SLOT_BASE+APPDATA.wnd_clientbox.top]
  1717.         add     ebx, eax
  1718.         mov     ecx, [esp+64+32-12+4]
  1719.         and     ecx, not 0x80000000     ; force counted string
  1720.         mov     eax, [esp+64+8]         ; background color (if given)
  1721.         mov     edi, [esp+64+4]
  1722.         jmp     dtext
  1723.  
  1724. align 4
  1725.  
  1726. sys_setup:
  1727.  
  1728. ; 1=roland mpu midi base , base io address
  1729. ; 2=keyboard   1, base kaybap 2, shift keymap, 9 country 1eng 2fi 3ger 4rus
  1730. ; 3=cd base    1, pri.master 2, pri slave 3 sec master, 4 sec slave
  1731. ; 5=system language, 1eng 2fi 3ger 4rus
  1732. ; 7=hd base    1, pri.master 2, pri slave 3 sec master, 4 sec slave
  1733. ; 8=fat32 partition in hd
  1734. ; 9
  1735. ; 10 = sound dma channel
  1736. ; 11 = enable lba read
  1737. ; 12 = enable pci access
  1738.  
  1739.  
  1740.         and     [esp+32], dword 0
  1741.         dec     ebx                             ; MIDI
  1742.         jnz     nsyse1
  1743.         cmp     ecx, 0x100
  1744.  
  1745.         jb      nsyse1
  1746.         mov     esi, 65535
  1747.         cmp     esi, ecx
  1748.  
  1749.         jb      nsyse1
  1750.         mov     [midi_base], cx ;bx
  1751.         mov     word [mididp], cx;bx
  1752.         inc     cx              ;bx
  1753.         mov     word [midisp], cx;bx
  1754.         ret
  1755.  
  1756. iglobal
  1757. midi_base dw 0
  1758. endg
  1759.  
  1760.    nsyse1:
  1761.         dec     ebx                              ; KEYBOARD
  1762.         jnz     nsyse2
  1763.         mov     edi, [TASK_BASE]
  1764.         mov     eax, [edi+TASKDATA.mem_start]
  1765.         add     eax, edx
  1766.  
  1767.         dec     ecx
  1768.         jnz     kbnobase
  1769.         mov     ebx, keymap
  1770.         mov     ecx, 128
  1771.         call    memmove
  1772.         ret
  1773.    kbnobase:
  1774.         dec     ecx
  1775.         jnz     kbnoshift
  1776.  
  1777.         mov     ebx, keymap_shift
  1778.         mov     ecx, 128
  1779.         call    memmove
  1780.         ret
  1781.    kbnoshift:
  1782.         dec     ecx
  1783.         jnz     kbnoalt
  1784.         mov     ebx, keymap_alt
  1785.         mov     ecx, 128
  1786.         call    memmove
  1787.         ret
  1788.    kbnoalt:
  1789.         sub     ecx, 6
  1790.         jnz     kbnocountry
  1791.         mov     word [keyboard], dx
  1792.         ret
  1793.    kbnocountry:
  1794.         mov     [esp+32], dword 1
  1795.         ret
  1796.    nsyse2:
  1797.         dec     ebx                         ; CD
  1798.         jnz     nsyse4
  1799.  
  1800.         test    ecx, ecx
  1801.         jz      nosesl
  1802.  
  1803.         cmp     ecx, 4
  1804.         ja      nosesl
  1805.         mov     [cd_base], cl
  1806.  
  1807.         dec     ecx
  1808.         jnz     noprma
  1809.         mov     eax, [hd_address_table]
  1810.         mov     [cdbase], eax   ;0x1f0
  1811.         mov     [cdid], 0xa0
  1812.    noprma:
  1813.  
  1814.         dec     ecx
  1815.         jnz     noprsl
  1816.         mov     eax, [hd_address_table]
  1817.         mov     [cdbase], eax   ;0x1f0
  1818.         mov     [cdid], 0xb0
  1819.    noprsl:
  1820.         dec     ecx
  1821.         jnz     nosema
  1822.         mov     eax, [hd_address_table+16]
  1823.         mov     [cdbase], eax   ;0x170
  1824.         mov     [cdid], 0xa0
  1825.    nosema:
  1826.         dec     ecx
  1827.         jnz     nosesl
  1828.         mov     eax, [hd_address_table+16]
  1829.         mov     [cdbase], eax   ;0x170
  1830.         mov     [cdid], 0xb0
  1831.    nosesl:
  1832.         ret
  1833.  
  1834. iglobal
  1835. cd_base db 0
  1836.  
  1837. endg
  1838.    nsyse4:
  1839.  
  1840.         sub     ebx, 2           ; SYSTEM LANGUAGE
  1841.         jnz     nsyse5
  1842.         mov     [syslang], ecx
  1843.         ret
  1844.    nsyse5:
  1845.  
  1846.         sub     ebx, 2          ; HD BASE - obsolete
  1847.         jnz     nsyse7
  1848.  
  1849.    nosethd:
  1850.         ret
  1851.  
  1852. nsyse7:
  1853.  
  1854. ;     cmp  eax,8                      ; HD PARTITION - obsolete
  1855.         dec     ebx
  1856.         jnz     nsyse8
  1857.         ret
  1858.  
  1859. nsyse8:
  1860. ;     cmp  eax,11                     ; ENABLE LBA READ
  1861.         and     ecx, 1
  1862.         sub     ebx, 3
  1863.         jnz     no_set_lba_read
  1864.         mov     [lba_read_enabled], ecx
  1865.         ret
  1866.  
  1867. no_set_lba_read:
  1868. ;     cmp  eax,12                     ; ENABLE PCI ACCESS
  1869.         dec     ebx
  1870.         jnz     sys_setup_err
  1871.         mov     [pci_access_enabled], ecx
  1872.         ret
  1873.  
  1874. sys_setup_err:
  1875.         or      [esp+32], dword -1
  1876.         ret
  1877.  
  1878. align 4
  1879.  
  1880. sys_getsetup:
  1881.  
  1882. ; 1=roland mpu midi base , base io address
  1883. ; 2=keyboard   1, base kaybap 2, shift keymap, 9 country 1eng 2fi 3ger 4rus
  1884. ; 3=cd base    1, pri.master 2, pri slave 3 sec master, 4 sec slave
  1885. ; 5=system language, 1eng 2fi 3ger 4rus
  1886. ; 7=hd base    1, pri.master 2, pri slave 3 sec master, 4 sec slave
  1887. ; 8=fat32 partition in hd
  1888. ; 9=get hs timer tic
  1889.  
  1890. ;     cmp  eax,1
  1891.         dec     ebx
  1892.         jnz     ngsyse1
  1893.         movzx   eax, [midi_base]
  1894.         mov     [esp+32], eax
  1895.         ret
  1896. ngsyse1:
  1897. ;     cmp  eax,2
  1898.         dec     ebx
  1899.         jnz     ngsyse2
  1900.  
  1901.         mov     edi, [TASK_BASE]
  1902.         mov     ebx, [edi+TASKDATA.mem_start]
  1903.         add     ebx, edx
  1904.  
  1905. ;     cmp  ebx,1
  1906.         dec     ecx
  1907.         jnz     kbnobaseret
  1908.         mov     eax, keymap
  1909.         mov     ecx, 128
  1910.         call    memmove
  1911.         ret
  1912. kbnobaseret:
  1913. ;     cmp  ebx,2
  1914.         dec     ecx
  1915.         jnz     kbnoshiftret
  1916.  
  1917.         mov     eax, keymap_shift
  1918.         mov     ecx, 128
  1919.         call    memmove
  1920.         ret
  1921. kbnoshiftret:
  1922. ;     cmp  ebx,3
  1923.         dec     ecx
  1924.         jne     kbnoaltret
  1925.  
  1926.         mov     eax, keymap_alt
  1927.         mov     ecx, 128
  1928.         call    memmove
  1929.         ret
  1930. kbnoaltret:
  1931. ;     cmp  ebx,9
  1932.         sub     ecx, 6
  1933.         jnz     ngsyse2
  1934.         movzx   eax, word [keyboard]
  1935.         mov     [esp+32], eax
  1936.         ret
  1937.  
  1938.  
  1939. ngsyse2:
  1940. ;         cmp  eax,3
  1941.         dec     ebx
  1942.         jnz     ngsyse3
  1943.         movzx   eax, [cd_base]
  1944.         mov     [esp+32], eax
  1945.         ret
  1946. ngsyse3:
  1947. ;         cmp  eax,5
  1948.         sub     ebx, 2
  1949.         jnz     ngsyse5
  1950.         mov     eax, [syslang]
  1951.         mov     [esp+32], eax
  1952.         ret
  1953. ngsyse5:
  1954. ;     cmp  eax,9
  1955.         sub     ebx, 4
  1956.         jnz     ngsyse9
  1957.         mov     eax, [timer_ticks];[0xfdf0]
  1958.         mov     [esp+32], eax
  1959.         ret
  1960. ngsyse9:
  1961. ;     cmp  eax,11
  1962.         sub     ebx, 2
  1963.         jnz     ngsyse11
  1964.         mov     eax, [lba_read_enabled]
  1965.         mov     [esp+32], eax
  1966.         ret
  1967. ngsyse11:
  1968. ;     cmp  eax,12
  1969.         dec     ebx
  1970.         jnz     ngsyse12
  1971.         mov     eax, [pci_access_enabled]
  1972.         mov     [esp+32], eax
  1973.         ret
  1974. ngsyse12:
  1975.         mov     [esp+32], dword 1
  1976.         ret
  1977.  
  1978.  
  1979. get_timer_ticks:
  1980.         mov     eax, [timer_ticks]
  1981.         ret
  1982.  
  1983. iglobal
  1984. align 4
  1985. mousefn dd msscreen, mswin, msbutton, msset
  1986.         dd app_load_cursor
  1987.         dd app_set_cursor
  1988.         dd app_delete_cursor
  1989.         dd msz
  1990. endg
  1991.  
  1992. readmousepos:
  1993.  
  1994. ; eax=0 screen relative
  1995. ; eax=1 window relative
  1996. ; eax=2 buttons pressed
  1997. ; eax=3 set mouse pos   ; reserved
  1998. ; eax=4 load cursor
  1999. ; eax=5 set cursor
  2000. ; eax=6 delete cursor   ; reserved
  2001. ; eax=7 get mouse_z
  2002.  
  2003.         cmp     ebx, 7
  2004.         ja      msset
  2005.         jmp     [mousefn+ebx*4]
  2006. msscreen:
  2007.         mov     eax, [MOUSE_X]
  2008.         shl     eax, 16
  2009.         mov     ax, [MOUSE_Y]
  2010.         mov     [esp+36-4], eax
  2011.         ret
  2012. mswin:
  2013.         mov     eax, [MOUSE_X]
  2014.         shl     eax, 16
  2015.         mov     ax, [MOUSE_Y]
  2016.         mov     esi, [TASK_BASE]
  2017.         mov     bx, word [esi-twdw+WDATA.box.left]
  2018.         shl     ebx, 16
  2019.         mov     bx, word [esi-twdw+WDATA.box.top]
  2020.         sub     eax, ebx
  2021.  
  2022.         mov     edi, [CURRENT_TASK]
  2023.         shl     edi, 8
  2024.         sub     ax, word[edi+SLOT_BASE+APPDATA.wnd_clientbox.top]
  2025.         rol     eax, 16
  2026.         sub     ax, word[edi+SLOT_BASE+APPDATA.wnd_clientbox.left]
  2027.         rol     eax, 16
  2028.         mov     [esp+36-4], eax
  2029.         ret
  2030. msbutton:
  2031.         movzx   eax, byte [BTN_DOWN]
  2032.         mov     [esp+36-4], eax
  2033.         ret
  2034. msz:
  2035.         mov     edi, [TASK_COUNT]
  2036.         movzx   edi, word [WIN_POS + edi*2]
  2037.         cmp     edi, [CURRENT_TASK]
  2038.         jne     @f
  2039.         mov     ax, [MOUSE_SCROLL_H]
  2040.         shl     eax, 16
  2041.         mov     ax, [MOUSE_SCROLL_V]
  2042.         mov     [esp+36-4], eax
  2043.         and     [MOUSE_SCROLL_H], word 0
  2044.         and     [MOUSE_SCROLL_V], word 0
  2045.         ret
  2046.        @@:
  2047.         and     [esp+36-4], dword 0
  2048. ;           ret
  2049. msset:
  2050.         ret
  2051.  
  2052. app_load_cursor:
  2053.         cmp     ecx, OS_BASE
  2054.         jae     msset
  2055.         stdcall load_cursor, ecx, edx
  2056.         mov     [esp+36-4], eax
  2057.         ret
  2058.  
  2059. app_set_cursor:
  2060.         stdcall set_cursor, ecx
  2061.         mov     [esp+36-4], eax
  2062.         ret
  2063.  
  2064. app_delete_cursor:
  2065.         stdcall delete_cursor, ecx
  2066.         mov     [esp+36-4], eax
  2067.         ret
  2068.  
  2069. is_input:
  2070.  
  2071.         push    edx
  2072.         mov     dx, word [midisp]
  2073.         in      al, dx
  2074.         and     al, 0x80
  2075.         pop     edx
  2076.         ret
  2077.  
  2078. is_output:
  2079.  
  2080.         push    edx
  2081.         mov     dx, word [midisp]
  2082.         in      al, dx
  2083.         and     al, 0x40
  2084.         pop     edx
  2085.         ret
  2086.  
  2087.  
  2088. get_mpu_in:
  2089.  
  2090.         push    edx
  2091.         mov     dx, word [mididp]
  2092.         in      al, dx
  2093.         pop     edx
  2094.         ret
  2095.  
  2096.  
  2097. put_mpu_out:
  2098.  
  2099.         push    edx
  2100.         mov     dx, word [mididp]
  2101.         out     dx, al
  2102.         pop     edx
  2103.         ret
  2104.  
  2105.  
  2106.  
  2107. align 4
  2108.  
  2109. sys_midi:
  2110.         cmp     [mididp], 0
  2111.         jnz     sm0
  2112.         mov     [esp+36], dword 1
  2113.         ret
  2114. sm0:
  2115.         and     [esp+36], dword 0
  2116.         dec     ebx
  2117.         jnz     smn1
  2118.  ;    call setuart
  2119. su1:
  2120.         call    is_output
  2121.         test    al, al
  2122.         jnz     su1
  2123.         mov     dx, word [midisp]
  2124.         mov     al, 0xff
  2125.         out     dx, al
  2126. su2:
  2127.         mov     dx, word [midisp]
  2128.         mov     al, 0xff
  2129.         out     dx, al
  2130.         call    is_input
  2131.         test    al, al
  2132.         jnz     su2
  2133.         call    get_mpu_in
  2134.         cmp     al, 0xfe
  2135.         jnz     su2
  2136. su3:
  2137.         call    is_output
  2138.         test    al, al
  2139.         jnz     su3
  2140.         mov     dx, word [midisp]
  2141.         mov     al, 0x3f
  2142.         out     dx, al
  2143.         ret
  2144. smn1:
  2145.         dec     ebx
  2146.         jnz     smn2
  2147. sm10:
  2148.         call    get_mpu_in
  2149.         call    is_output
  2150.         test    al, al
  2151.         jnz     sm10
  2152.         mov     al, bl
  2153.         call    put_mpu_out
  2154.         smn2:
  2155.         ret
  2156.  
  2157. detect_devices:
  2158. ;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  2159. ;include 'detect/commouse.inc'
  2160. ;include 'detect/ps2mouse.inc'
  2161. ;include 'detect/dev_fd.inc'
  2162. ;include 'detect/dev_hdcd.inc'
  2163. ;include 'detect/sear_par.inc'
  2164. ;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  2165.         ret
  2166.  
  2167. sys_end:
  2168. ;--------------------------------------
  2169.         cmp     [_display.select_cursor], 0
  2170.         je      @f
  2171. ; restore default cursor before killing
  2172.         pusha
  2173.         mov     ecx, [current_slot]
  2174.         call    restore_default_cursor_before_killing
  2175.         popa
  2176. @@:
  2177. ;--------------------------------------
  2178. ; kill all sockets this process owns
  2179.         pusha
  2180.         mov     edx, [TASK_BASE]
  2181.         mov     edx, [edx+TASKDATA.pid]
  2182.         call    SOCKET_process_end
  2183.         popa
  2184. ;--------------------------------------
  2185.         mov     ecx, [current_slot]
  2186.         mov     eax, [ecx+APPDATA.tls_base]
  2187.         test    eax, eax
  2188.         jz      @F
  2189.  
  2190.         stdcall user_free, eax
  2191. @@:
  2192.  
  2193.         mov     eax, [TASK_BASE]
  2194.         mov     [eax+TASKDATA.state], 3; terminate this program
  2195.         call    wakeup_osloop
  2196.  
  2197. .waitterm:            ; wait here for termination
  2198.         call    change_task
  2199.         jmp     .waitterm
  2200. ;------------------------------------------------------------------------------
  2201. align 4
  2202. restore_default_cursor_before_killing:
  2203.         pushfd
  2204.         cli
  2205.         mov     eax, [def_cursor]
  2206.         mov     [ecx+APPDATA.cursor], eax
  2207.  
  2208.         movzx   eax, word [MOUSE_Y]
  2209.         movzx   ebx, word [MOUSE_X]
  2210.         mov     eax, [d_width_calc_area + eax*4]
  2211.  
  2212.         add     eax, [_WinMapAddress]
  2213.         movzx   edx, byte [ebx+eax]
  2214.         shl     edx, 8
  2215.         mov     esi, [edx+SLOT_BASE+APPDATA.cursor]
  2216.  
  2217.         cmp     esi, [current_cursor]
  2218.         je      @f
  2219.  
  2220.         push    esi
  2221.         call    [_display.select_cursor]
  2222.         mov     [current_cursor], esi
  2223. @@:
  2224.         mov     [redrawmouse_unconditional], 1
  2225.         call    wakeup_osloop
  2226.         popfd
  2227.         ret
  2228. ;------------------------------------------------------------------------------
  2229. iglobal
  2230. align 4
  2231. sys_system_table:
  2232.         dd      sysfn_deactivate        ; 1 = deactivate window
  2233.         dd      sysfn_terminate         ; 2 = terminate thread
  2234.         dd      sysfn_activate          ; 3 = activate window
  2235.         dd      sysfn_getidletime       ; 4 = get idle time
  2236.         dd      sysfn_getcpuclock       ; 5 = get cpu clock
  2237.         dd      sysfn_saveramdisk       ; 6 = save ramdisk
  2238.         dd      sysfn_getactive         ; 7 = get active window
  2239.         dd      sysfn_sound_flag        ; 8 = get/set sound_flag
  2240.         dd      sysfn_shutdown          ; 9 = shutdown with parameter
  2241.         dd      sysfn_minimize          ; 10 = minimize window
  2242.         dd      sysfn_getdiskinfo       ; 11 = get disk subsystem info
  2243.         dd      sysfn_lastkey           ; 12 = get last pressed key
  2244.         dd      sysfn_getversion        ; 13 = get kernel version
  2245.         dd      sysfn_waitretrace       ; 14 = wait retrace
  2246.         dd      sysfn_centermouse       ; 15 = center mouse cursor
  2247.         dd      sysfn_getfreemem        ; 16 = get free memory size
  2248.         dd      sysfn_getallmem         ; 17 = get total memory size
  2249.         dd      sysfn_terminate2        ; 18 = terminate thread using PID
  2250.                                         ;                 instead of slot
  2251.         dd      sysfn_mouse_acceleration; 19 = set/get mouse acceleration
  2252.         dd      sysfn_meminfo           ; 20 = get extended memory info
  2253.         dd      sysfn_pid_to_slot       ; 21 = get slot number for pid
  2254.         dd      sysfn_min_rest_window   ; 22 = minimize and restore any window
  2255.         dd      sysfn_min_windows       ; 23 = minimize all windows
  2256.         dd      sysfn_set_screen_sizes  ; 24 = set screen sizes for Vesa
  2257. sysfn_num = ($ - sys_system_table)/4
  2258. endg
  2259. ;------------------------------------------------------------------------------
  2260. sys_system:
  2261.         dec     ebx
  2262.         cmp     ebx, sysfn_num
  2263.         jae     @f
  2264.         jmp     dword [sys_system_table + ebx*4]
  2265. @@:
  2266.         ret
  2267. ;------------------------------------------------------------------------------
  2268. sysfn_shutdown:          ; 18.9 = system shutdown
  2269.         cmp     ecx, 1
  2270.         jl      exit_for_anyone
  2271.         cmp     ecx, 4
  2272.         jg      exit_for_anyone
  2273.         mov     [BOOT_VARS+0x9030], cl
  2274.  
  2275.         mov     eax, [TASK_COUNT]
  2276.         mov     [SYS_SHUTDOWN], al
  2277.         mov     [shutdown_processes], eax
  2278.         call    wakeup_osloop
  2279.         and     dword [esp+32], 0
  2280.  exit_for_anyone:
  2281.         ret
  2282.   uglobal
  2283.    shutdown_processes:
  2284.                        dd 0x0
  2285.   endg
  2286. ;------------------------------------------------------------------------------
  2287. sysfn_terminate:        ; 18.2 = TERMINATE
  2288.         push    ecx
  2289.         cmp     ecx, 2
  2290.         jb      noprocessterminate
  2291.         mov     edx, [TASK_COUNT]
  2292.         cmp     ecx, edx
  2293.         ja      noprocessterminate
  2294.         mov     eax, [TASK_COUNT]
  2295.         shl     ecx, 5
  2296.         mov     edx, [ecx+CURRENT_TASK+TASKDATA.pid]
  2297.         add     ecx, CURRENT_TASK+TASKDATA.state
  2298.         cmp     byte [ecx], 9
  2299.         jz      noprocessterminate
  2300.         push    ecx edx
  2301.         lea     edx, [(ecx-(CURRENT_TASK and 1FFFFFFFh)-TASKDATA.state)*8+SLOT_BASE]
  2302.         call    request_terminate
  2303.         pop     edx ecx
  2304.         test    eax, eax
  2305.         jz      noprocessterminate
  2306. ;--------------------------------------
  2307. ; terminate all network sockets it used
  2308.         pusha
  2309.         mov     eax, edx
  2310.         call    SOCKET_process_end
  2311.         popa
  2312. ;--------------------------------------
  2313.         cmp     [_display.select_cursor], 0
  2314.         je      .restore_end
  2315. ; restore default cursor before killing
  2316.         pusha
  2317.         mov     ecx, [esp+32]
  2318.         shl     ecx, 8
  2319.         add     ecx, SLOT_BASE
  2320.         mov     eax, [def_cursor]
  2321.         cmp     [ecx+APPDATA.cursor], eax
  2322.         je      @f
  2323.         call    restore_default_cursor_before_killing
  2324. @@:
  2325.         popa
  2326. .restore_end:
  2327. ;--------------------------------------
  2328.      ;call MEM_Heap_Lock      ;guarantee that process isn't working with heap
  2329.         mov     [ecx], byte 3; clear possible i40's
  2330.         call    wakeup_osloop
  2331.      ;call MEM_Heap_UnLock
  2332.  
  2333.         cmp     edx, [application_table_owner]; clear app table stat
  2334.         jne     noatsc
  2335.         call    unlock_application_table
  2336. noatsc:
  2337. noprocessterminate:
  2338.         add     esp, 4
  2339.         ret
  2340. ;------------------------------------------------------------------------------
  2341. sysfn_terminate2:
  2342. ;lock application_table_status mutex
  2343. .table_status:
  2344.         call    lock_application_table
  2345.         mov     eax, ecx
  2346.         call    pid_to_slot
  2347.         test    eax, eax
  2348.         jz      .not_found
  2349.         mov     ecx, eax
  2350.         cli
  2351.         call    sysfn_terminate
  2352.         call    unlock_application_table
  2353.         sti
  2354.         and     dword [esp+32], 0
  2355.         ret
  2356. .not_found:
  2357.         call    unlock_application_table
  2358.         or      dword [esp+32], -1
  2359.         ret
  2360. ;------------------------------------------------------------------------------
  2361. sysfn_deactivate:         ; 18.1 = DEACTIVATE WINDOW
  2362.         cmp     ecx, 2
  2363.         jb      .nowindowdeactivate
  2364.         cmp     ecx, [TASK_COUNT]
  2365.         ja      .nowindowdeactivate
  2366.  
  2367.         movzx   esi, word [WIN_STACK + ecx*2]
  2368.         cmp     esi, 1
  2369.         je      .nowindowdeactivate ; already deactive
  2370.  
  2371.         mov     edi, ecx
  2372.         shl     edi, 5
  2373.         add     edi, window_data
  2374.         movzx   esi, word [WIN_STACK + ecx * 2]
  2375.         lea     esi, [WIN_POS + esi * 2]
  2376.         call    window._.window_deactivate
  2377.  
  2378.         call    syscall_display_settings._.calculate_whole_screen
  2379.         call    syscall_display_settings._.redraw_whole_screen
  2380. .nowindowdeactivate:
  2381.         ret
  2382. ;------------------------------------------------------------------------------
  2383. sysfn_activate:         ; 18.3 = ACTIVATE WINDOW
  2384.         cmp     ecx, 2
  2385.         jb      .nowindowactivate
  2386.         cmp     ecx, [TASK_COUNT]
  2387.         ja      .nowindowactivate
  2388. ;-------------------------------------
  2389. @@:
  2390. ; If the window is captured and moved by the user,
  2391. ; then you can't change the position in window stack!!!
  2392.         mov     al, [mouse.active_sys_window.action]
  2393.         and     al, WINDOW_MOVE_AND_RESIZE_FLAGS
  2394.         test    al, al
  2395.         jz      @f
  2396.         call    change_task
  2397.         jmp     @b
  2398. @@:
  2399. ;-------------------------------------
  2400.         mov     [window_minimize], 2; restore window if minimized
  2401.         call    wakeup_osloop
  2402.  
  2403.         movzx   esi, word [WIN_STACK + ecx*2]
  2404.         cmp     esi, [TASK_COUNT]
  2405.         je      .nowindowactivate; already active
  2406.  
  2407.         mov     edi, ecx
  2408.         shl     edi, 5
  2409.         add     edi, window_data
  2410.         movzx   esi, word [WIN_STACK + ecx * 2]
  2411.         lea     esi, [WIN_POS + esi * 2]
  2412.         call    waredraw
  2413. .nowindowactivate:
  2414.         ret
  2415. ;------------------------------------------------------------------------------
  2416. sysfn_getidletime:              ; 18.4 = GET IDLETIME
  2417.         mov     eax, [CURRENT_TASK+32+TASKDATA.cpu_usage]
  2418.         mov     [esp+32], eax
  2419.         ret
  2420. ;------------------------------------------------------------------------------
  2421. sysfn_getcpuclock:              ; 18.5 = GET TSC/SEC
  2422.         mov     eax, dword [cpu_freq]
  2423.         mov     [esp+32], eax
  2424.         ret
  2425. ;------------------------------------------------------------------------------
  2426. get_cpu_freq:
  2427.         mov     eax, dword [cpu_freq]
  2428.         mov     edx, dword [cpu_freq+4]
  2429.         ret
  2430. ;  SAVE ramdisk to /hd/1/menuet.img
  2431. ;!!!!!!!!!!!!!!!!!!!!!!!!
  2432.    include 'blkdev/rdsave.inc'
  2433. ;!!!!!!!!!!!!!!!!!!!!!!!!
  2434. ;------------------------------------------------------------------------------
  2435. align 4
  2436. sysfn_getactive:        ; 18.7 = get active window
  2437.         mov     eax, [TASK_COUNT]
  2438.         movzx   eax, word [WIN_POS + eax*2]
  2439.         mov     [esp+32], eax
  2440.         ret
  2441. ;------------------------------------------------------------------------------
  2442. sysfn_sound_flag:       ; 18.8 = get/set sound_flag
  2443. ;     cmp  ecx,1
  2444.         dec     ecx
  2445.         jnz     nogetsoundflag
  2446.         movzx   eax, byte [sound_flag]; get sound_flag
  2447.         mov     [esp+32], eax
  2448.         ret
  2449.  nogetsoundflag:
  2450. ;     cmp  ecx,2
  2451.         dec     ecx
  2452.         jnz     nosoundflag
  2453.         xor     byte [sound_flag], 1
  2454.  nosoundflag:
  2455.         ret
  2456. ;------------------------------------------------------------------------------
  2457. sysfn_minimize:         ; 18.10 = minimize window
  2458.         mov     [window_minimize], 1
  2459.         call    wakeup_osloop
  2460.         ret
  2461. ;------------------------------------------------------------------------------
  2462. align 4
  2463. sysfn_getdiskinfo:      ; 18.11 = get disk info table
  2464. ;     cmp  ecx,1
  2465.         dec     ecx
  2466.         jnz     full_table
  2467.   small_table:
  2468.         call    for_all_tables
  2469.         mov     ecx, 10
  2470.         cld
  2471.         rep movsb
  2472.         ret
  2473.    for_all_tables:
  2474.         mov     edi, edx
  2475.         mov     esi, DRIVE_DATA
  2476.         ret
  2477.   full_table:
  2478. ;     cmp  ecx,2
  2479.         dec     ecx
  2480.         jnz     exit_for_anyone
  2481.         call    for_all_tables
  2482.         mov     ecx, DRIVE_DATA_SIZE/4
  2483.         cld
  2484.         rep movsd
  2485.         ret
  2486. ;------------------------------------------------------------------------------
  2487. sysfn_lastkey:          ; 18.12 = return 0 (backward compatibility)
  2488.         and     dword [esp+32], 0
  2489.         ret
  2490. ;------------------------------------------------------------------------------
  2491. sysfn_getversion:       ; 18.13 = get kernel ID and version
  2492.         mov     edi, ecx
  2493.         mov     esi, version_inf
  2494.         mov     ecx, version_end-version_inf
  2495.         rep movsb
  2496.         ret
  2497. ;------------------------------------------------------------------------------
  2498. sysfn_waitretrace:     ; 18.14 = sys wait retrace
  2499.      ;wait retrace functions
  2500.  sys_wait_retrace:
  2501.         mov     edx, 0x3da
  2502.  WaitRetrace_loop:
  2503.         in      al, dx
  2504.         test    al, 1000b
  2505.         jz      WaitRetrace_loop
  2506.         and     [esp+32], dword 0
  2507.         ret
  2508. ;------------------------------------------------------------------------------
  2509. align 4
  2510. sysfn_centermouse:      ; 18.15 = mouse centered
  2511. ; removed here by <Lrz>
  2512. ;     call  mouse_centered
  2513. ;* mouse centered - start code- Mario79
  2514. ;mouse_centered:
  2515. ;        push  eax
  2516.         mov     eax, [Screen_Max_X]
  2517.         shr     eax, 1
  2518.         mov     [MOUSE_X], ax
  2519.         mov     eax, [Screen_Max_Y]
  2520.         shr     eax, 1
  2521.         mov     [MOUSE_Y], ax
  2522.         call    wakeup_osloop
  2523. ;        ret
  2524. ;* mouse centered - end code- Mario79
  2525.         xor     eax, eax
  2526.         and     [esp+32], eax
  2527. ;        pop   eax
  2528.         ret
  2529. ;------------------------------------------------------------------------------
  2530. align 4
  2531. sysfn_mouse_acceleration: ; 18.19 = set/get mouse features
  2532.         test    ecx, ecx; get mouse speed factor
  2533.         jnz     .set_mouse_acceleration
  2534.         xor     eax, eax
  2535.         mov     ax, [mouse_speed_factor]
  2536.         mov     [esp+32], eax
  2537.         ret
  2538.  .set_mouse_acceleration:
  2539. ;     cmp  ecx,1  ; set mouse speed factor
  2540.         dec     ecx
  2541.         jnz     .get_mouse_delay
  2542.         mov     [mouse_speed_factor], dx
  2543.         ret
  2544.  .get_mouse_delay:
  2545. ;     cmp  ecx,2  ; get mouse delay
  2546.         dec     ecx
  2547.         jnz     .set_mouse_delay
  2548.         mov     eax, [mouse_delay]
  2549.         mov     [esp+32], eax
  2550.         ret
  2551.  .set_mouse_delay:
  2552. ;     cmp  ecx,3  ; set mouse delay
  2553.         dec     ecx
  2554.         jnz     .set_pointer_position
  2555.         mov     [mouse_delay], edx
  2556.         ret
  2557.  .set_pointer_position:
  2558. ;     cmp  ecx,4  ; set mouse pointer position
  2559.         dec     ecx
  2560.         jnz     .set_mouse_button
  2561.         cmp     dx, word[Screen_Max_Y]
  2562.         ja      .end
  2563.         rol     edx, 16
  2564.         cmp     dx, word[Screen_Max_X]
  2565.         ja      .end
  2566.         mov     [MOUSE_X], edx
  2567.         mov     [mouse_active], 1
  2568.         call    wakeup_osloop
  2569.         ret
  2570.  .set_mouse_button:
  2571. ;     cmp   ecx,5  ; set mouse button features
  2572.         dec     ecx
  2573.         jnz     .end
  2574.         mov     [BTN_DOWN], dl
  2575.         mov     [mouse_active], 1
  2576.         call    wakeup_osloop
  2577.  .end:
  2578.         ret
  2579. ;------------------------------------------------------------------------------
  2580. sysfn_getfreemem:
  2581.         mov     eax, [pg_data.pages_free]
  2582.         shl     eax, 2
  2583.         mov     [esp+32], eax
  2584.         ret
  2585. ;------------------------------------------------------------------------------
  2586. sysfn_getallmem:
  2587.         mov     eax, [MEM_AMOUNT]
  2588.         shr     eax, 10
  2589.         mov     [esp+32], eax
  2590.         ret
  2591. ;------------------------------------------------------------------------------
  2592. sysfn_pid_to_slot:
  2593.         mov     eax, ecx
  2594.         call    pid_to_slot
  2595.         mov     [esp+32], eax
  2596.         ret
  2597. ;------------------------------------------------------------------------------
  2598. sysfn_min_rest_window:
  2599.         pushad
  2600.         mov     eax, edx ; ebx - operating
  2601.         shr     ecx, 1
  2602.         jnc     @f
  2603.         call    pid_to_slot
  2604. @@:
  2605.         or      eax, eax ; eax - number of slot
  2606.         jz      .error
  2607.         cmp     eax, 255    ; varify maximal slot number
  2608.         ja      .error
  2609.         movzx   eax, word [WIN_STACK + eax*2]
  2610.         shr     ecx, 1
  2611.         jc      .restore
  2612.  ; .minimize:
  2613.         call    minimize_window
  2614.         jmp     .exit
  2615. .restore:
  2616.         call    restore_minimized_window
  2617. .exit:
  2618.         popad
  2619.         xor     eax, eax
  2620.         mov     [esp+32], eax
  2621.         ret
  2622. .error:
  2623.         popad
  2624.         xor     eax, eax
  2625.         dec     eax
  2626.         mov     [esp+32], eax
  2627.         ret
  2628. ;------------------------------------------------------------------------------
  2629. sysfn_min_windows:
  2630.         call    minimize_all_window
  2631.         mov     [esp+32], eax
  2632.         call    change_task
  2633.         ret
  2634. ;------------------------------------------------------------------------------
  2635. sysfn_set_screen_sizes:
  2636.         cmp     [SCR_MODE], word 0x13
  2637.         jbe     .exit
  2638.  
  2639.         cmp     [_display.select_cursor], select_cursor
  2640.         jne     .exit
  2641.  
  2642.         cmp     ecx, [display_width_standard]
  2643.         ja      .exit
  2644.  
  2645.         cmp     edx, [display_height_standard]
  2646.         ja      .exit
  2647.  
  2648.         pushfd
  2649.         cli
  2650.         mov     eax, ecx
  2651.         mov     ecx, [_display.pitch]
  2652.         mov     [_display.width], eax
  2653.         dec     eax
  2654.         mov     [_display.height], edx
  2655.         dec     edx
  2656. ; eax - new Screen_Max_X
  2657. ; edx - new Screen_Max_Y
  2658.         mov     [do_not_touch_winmap], 1
  2659.         call    set_screen
  2660.         mov     [do_not_touch_winmap], 0
  2661.         popfd
  2662.         call    change_task
  2663. .exit:
  2664.         ret
  2665. ;------------------------------------------------------------------------------
  2666. uglobal
  2667. screen_workarea RECT
  2668. display_width_standard dd 0
  2669. display_height_standard dd 0
  2670. do_not_touch_winmap db 0
  2671. window_minimize db 0
  2672. sound_flag      db 0
  2673.  
  2674. endg
  2675.  
  2676. UID_NONE=0
  2677. UID_MENUETOS=1   ;official
  2678. UID_KOLIBRI=2    ;russian
  2679.  
  2680. iglobal
  2681. version_inf:
  2682.         db 0,7,7,0  ; version 0.7.7.0
  2683.         db 0
  2684. .rev    dd __REV__
  2685. version_end:
  2686. endg
  2687. ;------------------------------------------------------------------------------
  2688. align 4
  2689. sys_cachetodiskette:
  2690.         cmp     ebx, 1
  2691.         jb      .no_floppy_save
  2692.         cmp     ebx, 2
  2693.         ja      .no_floppy_save
  2694.         call    save_image
  2695.         mov     [esp + 32], eax
  2696.         ret
  2697. .no_floppy_save:
  2698.         mov     [esp + 32], dword 1
  2699.         ret
  2700. ;------------------------------------------------------------------------------
  2701. uglobal
  2702. ;  bgrchanged  dd  0x0
  2703. align 4
  2704. bgrlockpid dd 0
  2705. bgrlock db 0
  2706. endg
  2707. ;------------------------------------------------------------------------------
  2708. align 4
  2709. sys_background:
  2710.         cmp     ebx, 1                     ; BACKGROUND SIZE
  2711.         jnz     nosb1
  2712.         test    ecx, ecx
  2713.         jz      sbgrr
  2714.  
  2715.         test    edx, edx
  2716.         jz      sbgrr
  2717. ;--------------------------------------
  2718. align 4
  2719. @@:
  2720. ;;Maxis use atomic bts for mutexes  4.4.2009
  2721.         bts     dword [bgrlock], 0
  2722.         jnc     @f
  2723.         call    change_task
  2724.         jmp     @b
  2725. ;--------------------------------------
  2726. align 4
  2727. @@:
  2728.         mov     [BgrDataWidth], ecx
  2729.         mov     [BgrDataHeight], edx
  2730. ;    mov   [bgrchanged],1
  2731.  
  2732.         pushad
  2733. ; return memory for old background
  2734.         mov     eax, [img_background]
  2735.         cmp     eax, static_background_data
  2736.         jz      @f
  2737.         stdcall kernel_free, eax
  2738. ;--------------------------------------
  2739. align 4
  2740. @@:
  2741. ; calculate RAW size
  2742.         xor     eax, eax
  2743.         inc     eax
  2744.         cmp     [BgrDataWidth], eax
  2745.         jae     @f
  2746.         mov     [BgrDataWidth], eax
  2747. ;--------------------------------------
  2748. align 4
  2749. @@:
  2750.         cmp     [BgrDataHeight], eax
  2751.         jae     @f
  2752.         mov     [BgrDataHeight], eax
  2753. ;--------------------------------------
  2754. align 4
  2755. @@:
  2756.         mov     eax, [BgrDataWidth]
  2757.         imul    eax, [BgrDataHeight]
  2758.         lea     eax, [eax*3]
  2759. ; it is reserved with aligned to the boundary of 4 KB pages,
  2760. ; otherwise there may be exceptions a page fault for vesa20_drawbackground_tiled
  2761. ; because the 32 bit read is used for  high performance: "mov eax,[esi]"
  2762.         shr     eax, 12
  2763.         inc     eax
  2764.         shl     eax, 12
  2765.         mov     [mem_BACKGROUND], eax
  2766. ; get memory for new background
  2767.         stdcall kernel_alloc, eax
  2768.         test    eax, eax
  2769.         jz      .memfailed
  2770.         mov     [img_background], eax
  2771.         jmp     .exit
  2772. ;--------------------------------------
  2773. align 4
  2774. .memfailed:
  2775. ; revert to static monotone data
  2776.         mov     [img_background], static_background_data
  2777.         xor     eax, eax
  2778.         inc     eax
  2779.         mov     [BgrDataWidth], eax
  2780.         mov     [BgrDataHeight], eax
  2781.         mov     [mem_BACKGROUND], 4
  2782. ;--------------------------------------
  2783. align 4
  2784. .exit:
  2785.         popad
  2786.         mov     [bgrlock], 0
  2787. ;--------------------------------------
  2788. align 4
  2789. sbgrr:
  2790.         ret
  2791. ;------------------------------------------------------------------------------
  2792. align 4
  2793. nosb1:
  2794.         cmp     ebx, 2                     ; SET PIXEL
  2795.         jnz     nosb2
  2796.  
  2797.         mov     eax, [img_background]
  2798.         test    ecx, ecx
  2799.         jz      @f
  2800.         cmp     eax, static_background_data
  2801.         jz      .ret
  2802. ;--------------------------------------
  2803. align 4
  2804. @@:
  2805.         mov     ebx, [mem_BACKGROUND]
  2806.         add     ebx, 4095
  2807.         and     ebx, -4096
  2808.         sub     ebx, 4
  2809.         cmp     ecx, ebx
  2810.         ja      .ret
  2811.  
  2812.         mov     ebx, [eax+ecx]
  2813.         and     ebx, 0xFF000000;255*256*256*256
  2814.         and     edx, 0x00FFFFFF;255*256*256+255*256+255
  2815.         add     edx, ebx
  2816.         mov     [eax+ecx], edx
  2817. ;--------------------------------------
  2818. align 4
  2819. .ret:
  2820.         ret
  2821. ;------------------------------------------------------------------------------
  2822. align 4
  2823. nosb2:
  2824.         cmp     ebx, 3                     ; DRAW BACKGROUND
  2825.         jnz     nosb3
  2826. ;--------------------------------------
  2827. align 4
  2828. draw_background_temp:
  2829.         mov     [background_defined], 1
  2830.         call    force_redraw_background
  2831. ;--------------------------------------
  2832. align 4
  2833. nosb31:
  2834.         ret
  2835. ;------------------------------------------------------------------------------
  2836. align 4
  2837. nosb3:
  2838.         cmp     ebx, 4                     ; TILED / STRETCHED
  2839.         jnz     nosb4
  2840.         cmp     ecx, [BgrDrawMode]
  2841.         je      nosb41
  2842.         mov     [BgrDrawMode], ecx
  2843. ;--------------------------------------
  2844. align 4
  2845. nosb41:
  2846.         ret
  2847. ;------------------------------------------------------------------------------
  2848. align 4
  2849. nosb4:
  2850.         cmp     ebx, 5                     ; BLOCK MOVE TO BGR
  2851.         jnz     nosb5
  2852.         cmp     [img_background], static_background_data
  2853.         jnz     @f
  2854.         test    edx, edx
  2855.         jnz     .fin
  2856.         cmp     esi, 4
  2857.         ja      .fin
  2858. ;--------------------------------------
  2859. align 4
  2860. @@:
  2861.   ; bughere
  2862.         mov     eax, ecx
  2863.         mov     ebx, edx
  2864.         add     ebx, [img_background];IMG_BACKGROUND
  2865.         mov     ecx, esi
  2866.         call    memmove
  2867. ;--------------------------------------
  2868. align 4
  2869. .fin:
  2870.         ret
  2871. ;------------------------------------------------------------------------------
  2872. align 4
  2873. nosb5:
  2874.         cmp     ebx, 6
  2875.         jnz     nosb6
  2876. ;--------------------------------------
  2877. align 4
  2878. ;;Maxis use atomic bts for mutex 4.4.2009
  2879. @@:
  2880.         bts     dword [bgrlock], 0
  2881.         jnc     @f
  2882.         call    change_task
  2883.         jmp     @b
  2884. ;--------------------------------------