Subversion Repositories Kolibri OS

Rev

Rev 4434 | Blame | Compare with Previous | Last modification | View Log | Download | RSS feed

  1. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  2. ;;
  3. ;; Copyright (C) KolibriOS team 2004-2013. All rights reserved.
  4. ;; PROGRAMMING:
  5. ;; Ivan Poddubny
  6. ;; Marat Zakiyanov (Mario79)
  7. ;; VaStaNi
  8. ;; Trans
  9. ;; Mihail Semenyako (mike.dld)
  10. ;; Sergey Kuzmin (Wildwest)
  11. ;; Andrey Halyavin (halyavin)
  12. ;; Mihail Lisovin (Mihasik)
  13. ;; Andrey Ignatiev (andrew_programmer)
  14. ;; NoName
  15. ;; Evgeny Grechnikov (Diamond)
  16. ;; Iliya Mihailov (Ghost)
  17. ;; Sergey Semyonov (Serge)
  18. ;; Johnny_B
  19. ;; SPraid (simba)
  20. ;; Hidnplayr
  21. ;; Alexey Teplov (<Lrz>)
  22. ;; Rus
  23. ;; Nable
  24. ;; shurf
  25. ;; Alver
  26. ;; Maxis
  27. ;; Galkov
  28. ;; CleverMouse
  29. ;; tsdima
  30. ;; turbanoff
  31. ;; Asper
  32. ;; art_zh
  33. ;;
  34. ;; Data in this file was originally part of MenuetOS project which is
  35. ;; distributed under the terms of GNU GPL. It is modified and redistributed as
  36. ;; part of KolibriOS project under the terms of GNU GPL.
  37. ;;
  38. ;; Copyright (C) MenuetOS 2000-2004 Ville Mikael Turjanmaa
  39. ;; PROGRAMMING:
  40. ;;
  41. ;; Ville Mikael Turjanmaa, villemt@itu.jyu.fi
  42. ;; - main os coding/design
  43. ;; Jan-Michael Brummer, BUZZ2@gmx.de
  44. ;; Felix Kaiser, info@felix-kaiser.de
  45. ;; Paolo Minazzi, paolo.minazzi@inwind.it
  46. ;; quickcode@mail.ru
  47. ;; Alexey, kgaz@crosswinds.net
  48. ;; Juan M. Caravaca, bitrider@wanadoo.es
  49. ;; kristol@nic.fi
  50. ;; Mike Hibbett, mikeh@oceanfree.net
  51. ;; Lasse Kuusijarvi, kuusijar@lut.fi
  52. ;; Jarek Pelczar, jarekp3@wp.pl
  53. ;;
  54. ;; KolibriOS is distributed in the hope that it will be useful, but WITHOUT ANY
  55. ;; WARRANTY. No author or distributor accepts responsibility to anyone for the
  56. ;; consequences of using it or for whether it serves any particular purpose or
  57. ;; works at all, unless he says so in writing. Refer to the GNU General Public
  58. ;; License (the "GPL") for full details.
  59. ;
  60. ;; Everyone is granted permission to copy, modify and redistribute KolibriOS,
  61. ;; but only under the conditions described in the GPL. A copy of this license
  62. ;; is supposed to have been given to you along with KolibriOS so you can know
  63. ;; your rights and responsibilities. It should be in a file named COPYING.
  64. ;; Among other things, the copyright notice and this notice must be preserved
  65. ;; on all copies.
  66. ;;
  67. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  68.  
  69. format binary as "mnt"
  70.  
  71. include 'macros.inc'
  72. include 'struct.inc'
  73.  
  74. $Revision: 4381 $
  75.  
  76.  
  77. USE_FIX_FOR_INVALID_MS_VIRTUAL_PC_2007 equ 0
  78.  
  79. USE_COM_IRQ     equ 1      ; make irq 3 and irq 4 available for PCI devices
  80. VESA_1_2_VIDEO equ 0      ; enable vesa 1.2 bank switch functions
  81.  
  82. ; Enabling the next line will enable serial output console
  83. ;debug_com_base  equ 0x3f8  ; 0x3f8 is com1, 0x2f8 is com2, 0x3e8 is com3, 0x2e8 is com4, no irq's are used
  84.  
  85. include "proc32.inc"
  86. include "kglobals.inc"
  87. include "lang.inc"
  88. include "encoding.inc"
  89.  
  90. include "const.inc"
  91.  
  92. iglobal
  93. ; The following variable, if equal to 1, duplicates debug output to the screen.
  94. debug_direct_print db 0
  95. ; Start the first app (LAUNCHER) after kernel is loaded? (1=yes, 2 or 0=no)
  96. launcher_start db 1
  97. endg
  98.  
  99. max_processes   equ   255
  100. tss_step         equ   (128+8192) ; tss & i/o - 65535 ports, * 256=557056*4
  101.  
  102. os_stack       equ  (os_data_l-gdts)    ; GDTs
  103. os_code       equ  (os_code_l-gdts)
  104. graph_data     equ  (3+graph_data_l-gdts)
  105. tss0           equ  (tss0_l-gdts)
  106. app_code       equ  (3+app_code_l-gdts)
  107. app_data       equ  (3+app_data_l-gdts)
  108. app_tls       equ  (3+tls_data_l-gdts)
  109. pci_code_sel   equ  (pci_code_32-gdts)
  110. pci_data_sel   equ  (pci_data_32-gdts)
  111.  
  112.  
  113. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  114. ;;
  115. ;;   Included files:
  116. ;;
  117. ;;   Kernel16.inc
  118. ;;    - Booteng.inc   English text for bootup
  119. ;;    - Bootcode.inc  Hardware setup
  120. ;;    - Pci16.inc     PCI functions
  121. ;;
  122. ;;   Kernel32.inc
  123. ;;    - Sys32.inc     Process management
  124. ;;    - Shutdown.inc  Shutdown and restart
  125. ;;    - Fat32.inc     Read / write hd
  126. ;;    - Vesa12.inc    Vesa 1.2 driver
  127. ;;    - Vesa20.inc    Vesa 2.0 driver
  128. ;;    - Vga.inc       VGA driver
  129. ;;    - Stack.inc     Network interface
  130. ;;    - Mouse.inc     Mouse pointer
  131. ;;    - Scincode.inc  Window skinning
  132. ;;    - Pci32.inc     PCI functions
  133. ;;
  134. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  135.  
  136.  
  137. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  138. ;;                                                                      ;;
  139. ;;                  16 BIT ENTRY FROM BOOTSECTOR                        ;;
  140. ;;                                                                      ;;
  141. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  142.  
  143. use16
  144.                   org   0x0
  145.         jmp     start_of_code
  146.  
  147. if lang eq sp
  148. include "kernelsp.inc"  ; spanish kernel messages
  149. else if lang eq et
  150. version db    'Kolibri OS  versioon 0.7.7.0+    ',13,10,13,10,0
  151. else
  152. version db    'Kolibri OS  version 0.7.7.0+     ',13,10,13,10,0
  153. end if
  154.  
  155. include "boot/bootstr.inc"     ; language-independent boot messages
  156. include "boot/preboot.inc"
  157.  
  158. if lang eq ge
  159. include "boot/bootge.inc"     ; german system boot messages
  160. else if lang eq sp
  161. include "boot/bootsp.inc"     ; spanish system boot messages
  162. else if lang eq ru
  163. include "boot/bootru.inc"      ; russian system boot messages
  164. include "boot/ru.inc"          ; Russian font
  165. else if lang eq et
  166. include "boot/bootet.inc"      ; estonian system boot messages
  167. include "boot/et.inc"          ; Estonian font
  168. else
  169. include "boot/booten.inc"      ; english system boot messages
  170. end if
  171.  
  172. include "boot/bootcode.inc"    ; 16 bit system boot code
  173. include "bus/pci/pci16.inc"
  174. include "detect/biosdisk.inc"
  175.  
  176. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  177. ;;                                                                      ;;
  178. ;;                  SWITCH TO 32 BIT PROTECTED MODE                     ;;
  179. ;;                                                                      ;;
  180. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  181.  
  182.         cld
  183.  
  184. ; Enabling 32 bit protected mode
  185.  
  186.         mov     ecx, CR0_PE             ; CR0 Flags - Protected mode and Paging
  187.         lgdt    [cs:tmp_gdt]            ; Load GDT
  188.         mov     eax, cr0                ; protected mode
  189.         or      eax, ecx
  190.         and     eax, 10011111b *65536*256 + 0xffffff ; caching enabled
  191.         mov     cr0, eax
  192.         jmp     pword os_code:B32       ; jmp to enable 32 bit mode
  193.  
  194. align 8
  195. tmp_gdt:
  196.  
  197.         dw     23
  198.         dd     tmp_gdt+0x10000
  199.         dw     0
  200.  
  201.         dw     0xffff
  202.         dw     0x0000
  203.         db     0x00
  204.         dw     11011111b *256 +10011010b
  205.         db     0x00
  206.  
  207.         dw     0xffff
  208.         dw     0x0000
  209.         db     0x00
  210.         dw     11011111b *256 +10010010b
  211.         db     0x00
  212.  
  213. include "data16.inc"
  214.  
  215. if ~ lang eq sp
  216. diff16 "end of bootcode",0,$+0x10000
  217. end if
  218.  
  219. use32
  220. org $+0x10000
  221.  
  222. align 4
  223. B32:
  224.         mov     ax, os_stack       ; Selector for os
  225.         mov     ds, ax
  226.         mov     es, ax
  227.         mov     fs, ax
  228.         mov     gs, ax
  229.         mov     ss, ax
  230.         mov     esp, 0x006CC00       ; Set stack
  231.  
  232. ; CLEAR 0x280000 - HEAP_BASE
  233.  
  234.         xor     eax, eax
  235.         mov     edi, CLEAN_ZONE
  236.         mov     ecx, (HEAP_BASE-OS_BASE-CLEAN_ZONE) / 4
  237.         cld
  238.         rep stosd
  239.  
  240. ; CLEAR KERNEL UNDEFINED GLOBALS
  241.         mov     edi, endofcode-OS_BASE
  242.         mov     ecx, 0x90000
  243.         sub     ecx, edi
  244.         shr     ecx, 2
  245.         rep stosd
  246.  
  247. ; SAVE & CLEAR 0-0xffff
  248.  
  249.         mov     edi, 0x1000
  250.         mov     ecx, 0x8000 / 4
  251.         rep stosd
  252.         mov     edi, 0xa000
  253.         mov     ecx, 0x6000 / 4
  254.         rep stosd
  255.  
  256.         call    test_cpu
  257.         bts     [cpu_caps-OS_BASE], CAPS_TSC    ;force use rdtsc
  258.  
  259.         call    check_acpi
  260.         call    init_BIOS32
  261. ; MEMORY MODEL
  262.         call    mem_test
  263.         call    init_mem
  264.         call    init_page_map
  265.  
  266. ; ENABLE PAGING
  267.  
  268.         mov     eax, sys_proc-OS_BASE+PROC.pdt_0
  269.         mov     cr3, eax
  270.  
  271.         mov     eax, cr0
  272.         or      eax, CR0_PG+CR0_WP
  273.         mov     cr0, eax
  274.  
  275.         lgdt    [gdts]
  276.         jmp     pword os_code:high_code
  277.  
  278. align 4
  279. bios32_entry    dd ?
  280. tmp_page_tabs   dd ?
  281.  
  282. use16
  283. org $-0x10000
  284. include "boot/shutdown.inc" ; shutdown or restart
  285. org $+0x10000
  286. use32
  287.  
  288. __DEBUG__ fix 1
  289. __DEBUG_LEVEL__ fix 1
  290. include 'init.inc'
  291.  
  292. org OS_BASE+$
  293.  
  294. include 'fdo.inc'
  295.  
  296. align 4
  297. high_code:
  298.         mov     ax, os_stack
  299.         mov     bx, app_data
  300.         mov     cx, app_tls
  301.         mov     ss, ax
  302.         add     esp, OS_BASE
  303.  
  304.         mov     ds, bx
  305.         mov     es, bx
  306.         mov     fs, cx
  307.         mov     gs, bx
  308.  
  309.         bt      [cpu_caps], CAPS_PGE
  310.         jnc     @F
  311.  
  312.         or      dword [sys_proc+PROC.pdt_0+(OS_BASE shr 20)], PG_GLOBAL
  313.  
  314.         mov     ebx, cr4
  315.         or      ebx, CR4_PGE
  316.         mov     cr4, ebx
  317. @@:
  318.         xor     eax, eax
  319.         mov     dword [sys_proc+PROC.pdt_0], eax
  320.         mov     dword [sys_proc+PROC.pdt_0+4], eax
  321.  
  322.         mov     eax, cr3
  323.         mov     cr3, eax          ; flush TLB
  324.  
  325.         mov     ecx, pg_data.mutex
  326.         call    mutex_init
  327.  
  328.         mov     ecx, disk_list_mutex
  329.         call    mutex_init
  330.  
  331.         mov     ecx, keyboard_list_mutex
  332.         call    mutex_init
  333.  
  334.         mov     ecx, unpack_mutex
  335.         call    mutex_init
  336.  
  337.         mov     ecx, application_table_mutex
  338.         call    mutex_init
  339.  
  340.         mov     ecx, ide_mutex
  341.         call    mutex_init
  342.         mov     ecx, ide_channel1_mutex
  343.         call    mutex_init
  344.         mov     ecx, ide_channel2_mutex
  345.         call    mutex_init
  346. ;-----------------------------------------------------------------------------
  347. ; SAVE REAL MODE VARIABLES
  348. ;-----------------------------------------------------------------------------
  349. save_variables_IDE_controller:
  350.         xor     eax, eax
  351.         mov     ax, [BOOT_VARS + BOOT_IDE_INTERR_16]
  352.         mov     [IDE_Interrupt], ax
  353. ;--------------------------------------
  354.         mov     ax, [BOOT_VARS + BOOT_IDE_PI_16]
  355.         mov     [IDEContrProgrammingInterface], ax
  356. ;--------------------------------------
  357.         mov     ax, [BOOT_VARS + BOOT_IDE_BASE_ADDR]
  358.         mov     [IDEContrRegsBaseAddr], ax
  359. ;--------------------------------------
  360.         mov     ax, [BOOT_VARS + BOOT_IDE_BAR0_16]
  361.         cmp     ax, 0
  362.         je      @f
  363.         cmp     ax, 1
  364.         jne     .no_PATA_BAR0
  365. @@:
  366.         mov     ax, 0x1F0
  367.         jmp     @f
  368. .no_PATA_BAR0:
  369.         and     ax, 0xFFFC
  370. @@:
  371.         mov     [StandardATABases], ax
  372.         mov     [hd_address_table], eax
  373.         mov     [hd_address_table+8], eax
  374.         mov     [IDE_BAR0_val], ax
  375. ;--------------------------------------
  376.         mov     ax, [BOOT_VARS + BOOT_IDE_BAR1_16]
  377.         cmp     ax, 0
  378.         je      @f
  379.         cmp     ax, 1
  380.         jne     .no_PATA_BAR1
  381. @@:
  382.         mov     ax, 0x3F4
  383.         jmp     @f
  384. .no_PATA_BAR1:
  385.         and     ax, 0xFFFC
  386. @@:
  387.         mov     [IDE_BAR1_val], ax
  388. ;--------------------------------------
  389.         mov     ax, [BOOT_VARS + BOOT_IDE_BAR2_16]
  390.         cmp     ax, 0
  391.         je      @f
  392.         cmp     ax, 1
  393.         jne     .no_PATA_BAR2
  394. @@:
  395.         mov     ax, 0x170
  396.         jmp     @f
  397. .no_PATA_BAR2:
  398.         and     ax, 0xFFFC
  399. @@:
  400.         mov     [StandardATABases+2], ax
  401.         mov     [hd_address_table+16], eax
  402.         mov     [hd_address_table+24], eax
  403.         mov     [IDE_BAR2_val], ax
  404. ;--------------------------------------
  405.         mov     ax, [BOOT_VARS + BOOT_IDE_BAR3_16]
  406.         cmp     ax, 0
  407.         je      @f
  408.         cmp     ax, 1
  409.         jne     .no_PATA_BAR3
  410. @@:
  411.         mov     ax, 0x374
  412.         jmp     @f
  413. .no_PATA_BAR3:
  414.         and     ax, 0xFFFC
  415. @@:
  416.         mov     [IDE_BAR3_val], ax
  417.  
  418. ; --------------- APM ---------------------
  419.  
  420. ; init selectors
  421.         mov     ebx, [BOOT_VARS+BOOT_APM_ENTRY]        ; offset of APM entry point
  422.         movzx   eax, word [BOOT_VARS+BOOT_APM_CODE_32] ; real-mode segment base address of
  423.                                                                                 ; protected-mode 32-bit code segment
  424.         movzx   ecx, word [BOOT_VARS+BOOT_APM_CODE_16]; real-mode segment base address of
  425.                                                                                 ; protected-mode 16-bit code segment
  426.         movzx   edx, word [BOOT_VARS+BOOT_APM_DATA_16]; real-mode segment base address of
  427.                                                                                 ; protected-mode 16-bit data segment
  428.  
  429.         shl     eax, 4
  430.         mov     [dword apm_code_32 + 2], ax
  431.         shr     eax, 16
  432.         mov     [dword apm_code_32 + 4], al
  433.  
  434.         shl     ecx, 4
  435.         mov     [dword apm_code_16 + 2], cx
  436.         shr     ecx, 16
  437.         mov     [dword apm_code_16 + 4], cl
  438.  
  439.         shl     edx, 4
  440.         mov     [dword apm_data_16 + 2], dx
  441.         shr     edx, 16
  442.         mov     [dword apm_data_16 + 4], dl
  443.  
  444.         mov     dword[apm_entry], ebx
  445.         mov     word [apm_entry + 4], apm_code_32 - gdts
  446.  
  447.         mov     eax, [BOOT_VARS + BOOT_APM_VERSION] ; version & flags
  448.         mov     [apm_vf], eax
  449. ; -----------------------------------------
  450.         mov     al, [BOOT_VARS+BOOT_DMA]            ; DMA access
  451.         mov     [allow_dma_access], al
  452.         movzx   eax, byte [BOOT_VARS+BOOT_BPP]      ; bpp
  453.         mov     [_display.bpp], eax
  454.         mov     [_display.vrefresh], 60
  455.         mov     al, [BOOT_VARS+BOOT_DEBUG_PRINT]    ; If nonzero, duplicates debug output to the screen
  456.         mov     [debug_direct_print], al
  457.         mov     al, [BOOT_VARS+BOOT_LAUNCHER_START] ; Start the first app (LAUNCHER) after kernel is loaded?
  458.         mov     [launcher_start], al
  459.         movzx   eax, word [BOOT_VARS+BOOT_X_RES]; X max
  460.         mov     [_display.width], eax
  461.         mov     [display_width_standard], eax
  462.         dec     eax
  463.         mov     [Screen_Max_X], eax
  464.         mov     [screen_workarea.right], eax
  465.         movzx   eax, word [BOOT_VARS+BOOT_Y_RES]; Y max
  466.         mov     [_display.height], eax
  467.         mov     [display_height_standard], eax
  468.         dec     eax
  469.         mov     [Screen_Max_Y], eax
  470.         mov     [screen_workarea.bottom], eax
  471.         movzx   eax, word [BOOT_VARS+BOOT_VESA_MODE] ; screen mode
  472.         mov     dword [SCR_MODE], eax
  473. ;        mov     eax, [BOOT_VAR+0x9014]             ; Vesa 1.2 bnk sw add
  474. ;        mov     [BANK_SWITCH], eax
  475.         mov     eax, 640 *4                         ; Bytes PerScanLine
  476.         cmp     [SCR_MODE], word 0x13               ; 320x200
  477.         je      @f
  478.         cmp     [SCR_MODE], word 0x12               ; VGA 640x480
  479.         je      @f
  480.         movzx   eax, word[BOOT_VARS+BOOT_PITCH]      ; for other modes
  481. @@:
  482.         mov     [_display.pitch], eax
  483.         mov     eax, [_display.width]
  484.         mul     [_display.height]
  485.         mov     [_WinMapSize], eax
  486.  
  487.         call    calculate_fast_getting_offset_for_WinMapAddress
  488. ; for Qemu or non standart video cards
  489. ; Unfortunately [BytesPerScanLine] does not always
  490. ;                             equal to [_display.width] * [ScreenBPP] / 8
  491.         call    calculate_fast_getting_offset_for_LFB
  492.  
  493.         mov     esi, BOOT_VARS+0x9080
  494.         movzx   ecx, byte [esi-1]
  495.         mov     [NumBiosDisks], ecx
  496.         mov     edi, BiosDisksData
  497.         rep movsd
  498.  
  499. ; GRAPHICS ADDRESSES
  500.  
  501.         mov     eax, [BOOT_VARS+BOOT_LFB]
  502.         mov     [LFBAddress], eax
  503.  
  504.         cmp     [SCR_MODE], word 0100000000000000b
  505.         jge     setvesa20
  506.         cmp     [SCR_MODE], word 0x13  ; EGA 320*200 256 colors
  507.         je      v20ga32
  508.         jmp     v20ga24
  509.  
  510. setvesa20:
  511.         mov     [PUTPIXEL], dword Vesa20_putpixel24 ; Vesa 2.0
  512.         mov     [GETPIXEL], dword Vesa20_getpixel24
  513.         cmp     byte [_display.bpp], 24
  514.         jz      v20ga24
  515. v20ga32:
  516.         mov     [PUTPIXEL], dword Vesa20_putpixel32
  517.         mov     [GETPIXEL], dword Vesa20_getpixel32
  518.         jmp     no_mode_0x12
  519. v20ga24:
  520.         cmp     [SCR_MODE], word 0x12               ; 16 C VGA 640x480
  521.         jne     no_mode_0x12
  522.         mov     [PUTPIXEL], dword VGA_putpixel
  523.         mov     [GETPIXEL], dword Vesa20_getpixel32
  524. no_mode_0x12:
  525.  
  526.         mov     [MOUSE_PICTURE], dword mousepointer
  527.         mov     [_display.check_mouse], check_mouse_area_for_putpixel
  528.         mov     [_display.check_m_pixel], check_mouse_area_for_getpixel
  529.  
  530. ; -------- Fast System Call init ----------
  531. ; Intel SYSENTER/SYSEXIT (AMD CPU support it too)
  532.         bt      [cpu_caps], CAPS_SEP
  533.         jnc     .SEnP  ; SysEnter not Present
  534.         xor     edx, edx
  535.         mov     ecx, MSR_SYSENTER_CS
  536.         mov     eax, os_code
  537.         wrmsr
  538.         mov     ecx, MSR_SYSENTER_ESP
  539. ;           mov eax, sysenter_stack ; Check it
  540.         xor     eax, eax
  541.         wrmsr
  542.         mov     ecx, MSR_SYSENTER_EIP
  543.         mov     eax, sysenter_entry
  544.         wrmsr
  545. .SEnP:
  546. ; AMD SYSCALL/SYSRET
  547.         cmp     byte[cpu_vendor], 'A'
  548.         jne     .noSYSCALL
  549.         mov     eax, 0x80000001
  550.         cpuid
  551.         test    edx, 0x800  ; bit_11 - SYSCALL/SYSRET support
  552.         jz      .noSYSCALL
  553.         mov     ecx, MSR_AMD_EFER
  554.         rdmsr
  555.         or      eax, 1 ; bit_0 - System Call Extension (SCE)
  556.         wrmsr
  557.  
  558.         ; !!!! It`s dirty hack, fix it !!!
  559.         ; Bits of EDX :
  560.         ; Bit 31–16 During the SYSRET instruction, this field is copied into the CS register
  561.         ;  and the contents of this field, plus 8, are copied into the SS register.
  562.         ; Bit 15–0 During the SYSCALL instruction, this field is copied into the CS register
  563.         ;  and the contents of this field, plus 8, are copied into the SS register.
  564.  
  565.         ; mov   edx, (os_code + 16) * 65536 + os_code
  566.         mov     edx, 0x1B0008
  567.  
  568.         mov     eax, syscall_entry
  569.         mov     ecx, MSR_AMD_STAR
  570.         wrmsr
  571. .noSYSCALL:
  572. ; -----------------------------------------
  573.         stdcall alloc_page
  574.         stdcall map_page, tss-0xF80, eax, PG_SW
  575.         stdcall alloc_page
  576.         stdcall map_page, tss+0x80, eax, PG_SW
  577.         stdcall alloc_page
  578.         stdcall map_page, tss+0x1080, eax, PG_SW
  579.  
  580. ; LOAD IDT
  581.  
  582.         call    build_interrupt_table ;lidt is executed
  583.           ;lidt [idtreg]
  584.  
  585.         call    init_kernel_heap
  586.         stdcall kernel_alloc, (RING0_STACK_SIZE+512) * 2
  587.         mov     [os_stack_seg], eax
  588.  
  589.         lea     esp, [eax+RING0_STACK_SIZE]
  590.  
  591.         mov     [tss._ss0], os_stack
  592.         mov     [tss._esp0], esp
  593.         mov     [tss._esp], esp
  594.         mov     [tss._cs], os_code
  595.         mov     [tss._ss], os_stack
  596.         mov     [tss._ds], app_data
  597.         mov     [tss._es], app_data
  598.         mov     [tss._fs], app_data
  599.         mov     [tss._gs], app_data
  600.         mov     [tss._io], 128
  601. ;Add IO access table - bit array of permitted ports
  602.         mov     edi, tss._io_map_0
  603.         xor     eax, eax
  604.         not     eax
  605.         mov     ecx, 8192/4
  606.         rep stosd                    ; access to 4096*8=65536 ports
  607.  
  608.         mov     ax, tss0
  609.         ltr     ax
  610.  
  611.         mov     [LFBSize], 0xC00000
  612.         call    init_LFB
  613.         call    init_fpu
  614.         call    init_malloc
  615.  
  616.         stdcall alloc_kernel_space, 0x50000         ; FIXME check size
  617.         mov     [default_io_map], eax
  618.  
  619.         add     eax, 0x2000
  620.         mov     [ipc_tmp], eax
  621.         mov     ebx, 0x1000
  622.  
  623.         add     eax, 0x40000
  624.         mov     [proc_mem_map], eax
  625.  
  626.         add     eax, 0x8000
  627.         mov     [proc_mem_pdir], eax
  628.  
  629.         add     eax, ebx
  630.         mov     [proc_mem_tab], eax
  631.  
  632.         add     eax, ebx
  633.         mov     [tmp_task_ptab], eax
  634.  
  635.         add     eax, ebx
  636.         mov     [ipc_pdir], eax
  637.  
  638.         add     eax, ebx
  639.         mov     [ipc_ptab], eax
  640.  
  641.         stdcall kernel_alloc, (unpack.LZMA_BASE_SIZE+(unpack.LZMA_LIT_SIZE shl \
  642.                 (unpack.lc+unpack.lp)))*4
  643.  
  644.         mov     [unpack.p], eax
  645.  
  646.         call    init_events
  647.         mov     eax, srv.fd-SRV.fd
  648.         mov     [srv.fd], eax
  649.         mov     [srv.bk], eax
  650.  
  651. ;Set base of graphic segment to linear address of LFB
  652.         mov     eax, [LFBAddress]         ; set for gs
  653.         mov     [graph_data_l+2], ax
  654.         shr     eax, 16
  655.         mov     [graph_data_l+4], al
  656.         mov     [graph_data_l+7], ah
  657.  
  658.         stdcall kernel_alloc, [_WinMapSize]
  659.         mov     [_WinMapAddress], eax
  660.  
  661.         xor     eax, eax
  662.         inc     eax
  663.  
  664. ; set background
  665.  
  666.         mov     [BgrDrawMode], eax
  667.         mov     [BgrDataWidth], eax
  668.         mov     [BgrDataHeight], eax
  669.         mov     [mem_BACKGROUND], 4
  670.         mov     [img_background], static_background_data
  671.  
  672. ; set clipboard
  673.  
  674.         xor     eax, eax
  675.         mov     [clipboard_slots], eax
  676.         mov     [clipboard_write_lock], eax
  677.         stdcall kernel_alloc, 4096
  678.         test    eax, eax
  679.         jnz     @f
  680.  
  681.         dec     eax
  682. @@:
  683.         mov     [clipboard_main_list], eax
  684.  
  685. ; SET UP OS TASK
  686.  
  687.         mov     esi, boot_setostask
  688.         call    boot_log
  689.  
  690.         mov     edi, sys_proc
  691.         list_init edi
  692.         lea     ecx, [edi+PROC.thr_list]
  693.         list_init ecx
  694.         mov     [edi+PROC.pdt_0_phys], sys_proc-OS_BASE+PROC.pdt_0
  695.  
  696.         mov     eax, -1
  697.         mov     edi, thr_slot_map+4
  698.         mov     [edi-4], dword 0xFFFFFFF8
  699.         stosd
  700.         stosd
  701.         stosd
  702.         stosd
  703.         stosd
  704.         stosd
  705.         stosd
  706.  
  707.         mov     [current_process], sys_proc
  708.  
  709.         mov     edx, SLOT_BASE+256*1
  710.         mov     ebx, [os_stack_seg]
  711.         add     ebx, 0x2000
  712.         call    setup_os_slot
  713.         mov     dword [edx], 'IDLE'
  714.         sub     [edx+APPDATA.saved_esp], 4
  715.         mov     eax, [edx+APPDATA.saved_esp]
  716.         mov     dword [eax], idle_thread
  717.         mov     ecx, IDLE_PRIORITY
  718.         call    scheduler_add_thread
  719.  
  720.         mov     edx, SLOT_BASE+256*2
  721.         mov     ebx, [os_stack_seg]
  722.         call    setup_os_slot
  723.         mov     dword [edx], 'OS'
  724.         xor     ecx, ecx
  725.         call    scheduler_add_thread
  726.  
  727.         mov     dword [CURRENT_TASK], 2
  728.         mov     dword [TASK_COUNT], 2
  729.         mov     dword [current_slot], SLOT_BASE + 256*2
  730.         mov     dword [TASK_BASE], CURRENT_TASK + 32*2
  731.  
  732.  
  733. ; REDIRECT ALL IRQ'S TO INT'S 0x20-0x2f
  734.         mov     esi, boot_initirq
  735.         call    boot_log
  736.         call    init_irqs
  737.  
  738.         mov     esi, boot_picinit
  739.         call    boot_log
  740.         call    PIC_init
  741.  
  742.         mov     esi, boot_v86machine
  743.         call    boot_log
  744. ; Initialize system V86 machine
  745.         call    init_sys_v86
  746.  
  747.         mov     esi, boot_inittimer
  748.         call    boot_log
  749. ; Initialize system timer (IRQ0)
  750.         call    PIT_init
  751.  
  752. ; Register ramdisk file system
  753.         mov     esi, boot_initramdisk
  754.         call    boot_log
  755.         call    ramdisk_init
  756.  
  757.         mov     esi, boot_initapic
  758.         call    boot_log
  759. ; Try to Initialize APIC
  760.         call    APIC_init
  761.  
  762.         mov     esi, boot_enableirq
  763.         call    boot_log
  764. ; Enable timer IRQ (IRQ0) and co-processor IRQ (IRQ13)
  765. ; they are used: when partitions are scanned, hd_read relies on timer
  766.         call    unmask_timer
  767.         stdcall enable_irq, 2               ; @#$%! PIC
  768.         stdcall enable_irq, 13              ; co-processor
  769.  
  770.         cmp     [IDEContrProgrammingInterface], 0
  771.         je      @f
  772.  
  773.         mov     esi, boot_disabling_ide
  774.         call    boot_log
  775. ;--------------------------------------
  776. ; Disable IDE interrupts, because the search
  777. ; for IDE partitions is in the PIO mode.
  778. ;--------------------------------------
  779. .disable_IDE_interrupt:
  780. ; Disable interrupts in IDE controller for PIO
  781.         mov     al, 2
  782.         mov     dx, [IDE_BAR1_val] ;0x3F4
  783.         add     dx, 2 ;0x3F6
  784.         out     dx, al
  785.         mov     dx, [IDE_BAR3_val] ;0x374
  786.         add     dx, 2 ;0x376
  787.         out     dx, al
  788. @@:
  789. ;-----------------------------------------------------------------------------
  790. ;!!!!!!!!!!!!!!!!!!!!!!!!!!
  791. ;        mov     esi, boot_detectdisks
  792. ;        call    boot_log
  793. ;include 'detect/disks.inc'
  794.         mov     esi, boot_detectfloppy
  795.         call    boot_log
  796. include 'detect/dev_fd.inc'
  797.         mov     esi, boot_detecthdcd
  798.         call    boot_log
  799. include 'detect/dev_hdcd.inc'
  800.         mov     esi, boot_getcache
  801.         call    boot_log
  802. include 'detect/getcache.inc'
  803.         mov     esi, boot_detectpart
  804.         call    boot_log
  805. include 'detect/sear_par.inc'
  806. ;!!!!!!!!!!!!!!!!!!!!!!!!!!
  807.  
  808.         mov     esi, boot_init_sys
  809.         call    boot_log
  810.         call    Parser_params
  811.  
  812. if ~ defined extended_primary_loader
  813. ; ramdisk image should be loaded by extended primary loader if it exists
  814. ; READ RAMDISK IMAGE FROM HD
  815.  
  816. ;!!!!!!!!!!!!!!!!!!!!!!!
  817. include 'boot/rdload.inc'
  818. ;!!!!!!!!!!!!!!!!!!!!!!!
  819. end if
  820. ;    mov    [dma_hdd],1
  821.  
  822. if 0
  823.         mov     ax, [OS_BASE+0x10000+bx_from_load]
  824.         cmp     ax, 'r1'; if using not ram disk, then load librares and parameters {SPraid.simba}
  825.         je      no_lib_load
  826.  
  827.         mov     esi, boot_loadlibs
  828.         call    boot_log
  829. ; LOADING LIBRARES
  830.         stdcall dll.Load, @IMPORT           ; loading librares for kernel (.obj files)
  831.         call    load_file_parse_table       ; prepare file parse table
  832.         call    set_kernel_conf             ; configure devices and gui
  833. no_lib_load:
  834. end if
  835.  
  836. ; Display APIC status
  837.         mov     esi, boot_APIC_found
  838.         cmp     [irq_mode], IRQ_APIC
  839.         je      @f
  840.         mov     esi, boot_APIC_nfound
  841. @@:
  842.         call    boot_log
  843.  
  844. ; PRINT AMOUNT OF MEMORY
  845.         mov     esi, boot_memdetect
  846.         call    boot_log
  847.  
  848.         movzx   ecx, word [boot_y]
  849.         if lang eq ru
  850.         or      ecx, (10+30*6) shl 16
  851.         else if lang eq sp
  852.         or      ecx, (10+33*6) shl 16
  853.         else
  854.         or      ecx, (10+29*6) shl 16
  855.         end if
  856.         sub     ecx, 10
  857.         mov     edx, 0xFFFFFF
  858.         mov     ebx, [MEM_AMOUNT]
  859.         shr     ebx, 20
  860.         xor     edi, edi
  861.         mov     eax, 0x00040000
  862.         inc     edi
  863.         call    display_number_force
  864.  
  865. ; BUILD SCHEDULER
  866.  
  867. ;        call    build_scheduler; sys32.inc
  868.  
  869. ;        mov     esi, boot_devices
  870. ;        call    boot_log
  871.  
  872.         mov     [pci_access_enabled], 1
  873.         call    pci_enum
  874. ;-----------------------------------------------------------------------------
  875.         mov     dx, [IDEContrRegsBaseAddr]
  876. ; test whether it is our interrupt?
  877.         add     dx, 2
  878.         in      al, dx
  879.         test    al, 100b
  880.         jz      @f
  881. ; clear Bus Master IDE Status register
  882. ; clear Interrupt bit
  883.         out     dx, al
  884. @@:
  885.         add     dx, 8
  886. ; test whether it is our interrupt?
  887.         in      al, dx
  888.         test    al, 100b
  889.         jz      @f
  890. ; clear Bus Master IDE Status register
  891. ; clear Interrupt bit
  892.         out     dx, al
  893. @@:
  894. ; read status register and remove the interrupt request
  895.         mov     dx, [IDE_BAR0_val] ;0x1F0
  896.         add     dx, 0x7 ;0x1F7
  897.         in      al, dx
  898.         mov     dx, [IDE_BAR2_val] ;0x170
  899.         add     dx, 0x7 ;0x177
  900.         in      al, dx
  901. ;-----------------------------------------------------------------------------
  902. include "detect/vortex86.inc"                     ; Vortex86 SoC detection code
  903.  
  904.         stdcall load_driver, szVidintel
  905.  
  906.         call    usb_init
  907.  
  908. ; SET PRELIMINARY WINDOW STACK AND POSITIONS
  909.  
  910.         mov     esi, boot_windefs
  911.         call    boot_log
  912.         call    set_window_defaults
  913.  
  914. ; SET BACKGROUND DEFAULTS
  915.  
  916.         mov     esi, boot_bgr
  917.         call    boot_log
  918.         call    init_background
  919.         call    calculatebackground
  920.  
  921. ; RESERVE SYSTEM IRQ'S JA PORT'S
  922.  
  923.         mov     esi, boot_resirqports
  924.         call    boot_log
  925.         call    reserve_irqs_ports
  926.  
  927.         call    init_display
  928.         mov     eax, [def_cursor]
  929.         mov     [SLOT_BASE+APPDATA.cursor+256], eax
  930.         mov     [SLOT_BASE+APPDATA.cursor+256*2], eax
  931.  
  932. ; PRINT CPU FREQUENCY
  933.  
  934.         mov     esi, boot_cpufreq
  935.         call    boot_log
  936.  
  937.         cli                         ;FIXME check IF
  938.         rdtsc
  939.         mov     ecx, eax
  940.         mov     esi, 250            ; wait 1/4 a second
  941.         call    delay_ms
  942.         rdtsc
  943.  
  944.         sub     eax, ecx
  945.         xor     edx, edx
  946.         shld    edx, eax, 2
  947.         shl     eax, 2
  948.         mov     dword [cpu_freq], eax
  949.         mov     dword [cpu_freq+4], edx
  950.         mov     ebx, 1000000
  951.         div     ebx
  952.         mov     ebx, eax
  953.  
  954.         movzx   ecx, word [boot_y]
  955.         if lang eq ru
  956.         add     ecx, (10+19*6) shl 16 - 10
  957.         else if lang eq sp
  958.         add     ecx, (10+25*6) shl 16 - 10
  959.         else
  960.         add     ecx, (10+17*6) shl 16 - 10
  961.         end if
  962.  
  963.         mov     edx, 0xFFFFFF
  964.         xor     edi, edi
  965.         mov     eax, 0x00040000
  966.         inc     edi
  967.         call    display_number_force
  968.  
  969. ; SET VARIABLES
  970.  
  971.         call    set_variables
  972.  
  973. ; STACK AND FDC
  974.  
  975. ;        call    stack_init
  976.         call    fdc_init
  977.  
  978. ; PALETTE FOR 320x200 and 640x480 16 col
  979.  
  980.         cmp     [SCR_MODE], word 0x12
  981.         jne     no_pal_vga
  982.         mov     esi, boot_pal_vga
  983.         call    boot_log
  984.         call    paletteVGA
  985.       no_pal_vga:
  986.  
  987.         cmp     [SCR_MODE], word 0x13
  988.         jne     no_pal_ega
  989.         mov     esi, boot_pal_ega
  990.         call    boot_log
  991.         call    palette320x200
  992.       no_pal_ega:
  993.  
  994. ; LOAD DEFAULT SKIN
  995.  
  996.         call    load_default_skin
  997.  
  998. ;protect io permission map
  999.  
  1000.         mov     esi, [default_io_map]
  1001.         stdcall map_page, esi, [SLOT_BASE+256+APPDATA.io_map], PG_MAP
  1002.         add     esi, 0x1000
  1003.         stdcall map_page, esi, [SLOT_BASE+256+APPDATA.io_map+4], PG_MAP
  1004.  
  1005.         stdcall map_page, tss._io_map_0, \
  1006.                 [SLOT_BASE+256+APPDATA.io_map], PG_MAP
  1007.         stdcall map_page, tss._io_map_1, \
  1008.                 [SLOT_BASE+256+APPDATA.io_map+4], PG_MAP
  1009.  
  1010. ; LOAD FIRST APPLICATION
  1011.         cmp     byte [launcher_start], 1        ; Check if starting LAUNCHER is selected on blue screen (1 = yes)
  1012.         jnz     first_app_found
  1013.  
  1014.         cli
  1015.         mov     ebp, firstapp
  1016.         call    fs_execute_from_sysdir
  1017.         test    eax, eax
  1018.         jnz     first_app_found
  1019.  
  1020.         mov     esi, boot_failed
  1021.         call    boot_log
  1022.  
  1023.         mov     eax, 0xDEADBEEF      ; otherwise halt
  1024.         hlt
  1025.  
  1026. first_app_found:
  1027.  
  1028.         cli
  1029.  
  1030. ; SET KEYBOARD PARAMETERS
  1031.         mov     al, 0xf6       ; reset keyboard, scan enabled
  1032.         call    kb_write
  1033.         test    ah, ah
  1034.         jnz     .no_keyboard
  1035.  
  1036.         ; wait until 8042 is ready
  1037.         xor     ecx, ecx
  1038.       @@:
  1039.         in      al, 64h
  1040.         and     al, 00000010b
  1041.         loopnz  @b
  1042.  
  1043. iglobal
  1044. align 4
  1045. ps2_keyboard_functions:
  1046.         dd      .end - $
  1047.         dd      0       ; no close
  1048.         dd      ps2_set_lights
  1049. .end:
  1050. endg
  1051.         stdcall register_keyboard, ps2_keyboard_functions, 0
  1052.        ; mov   al, 0xED       ; Keyboard LEDs - only for testing!
  1053.        ; call  kb_write
  1054.        ; call  kb_read
  1055.        ; mov   al, 111b
  1056.        ; call  kb_write
  1057.        ; call  kb_read
  1058.  
  1059.         mov     al, 0xF3     ; set repeat rate & delay
  1060.         call    kb_write
  1061. ;        call  kb_read
  1062.         mov     al, 0; 30 250 ;00100010b ; 24 500  ;00100100b  ; 20 500
  1063.         call    kb_write
  1064. ;        call  kb_read
  1065.      ;// mike.dld [
  1066.         call    set_lights
  1067.      ;// mike.dld ]
  1068.         stdcall attach_int_handler, 1, irq1, 0
  1069.         DEBUGF  1, "K : IRQ1 error code %x\n", eax
  1070. .no_keyboard:
  1071.  
  1072. ; SET MOUSE
  1073.  
  1074.         stdcall load_driver, szPS2MDriver
  1075. ;        stdcall load_driver, szCOM_MDriver
  1076.  
  1077.         mov     esi, boot_setmouse
  1078.         call    boot_log
  1079.         call    setmouse
  1080.  
  1081. ; Setup serial output console (if enabled)
  1082.  
  1083. if defined debug_com_base
  1084.  
  1085.         ; enable Divisor latch
  1086.  
  1087.         mov     dx, debug_com_base+3
  1088.         mov     al, 1 shl 7
  1089.         out     dx, al
  1090.  
  1091.         ; Set speed to 115200 baud (max speed)
  1092.  
  1093.         mov     dx, debug_com_base
  1094.         mov     al, 0x01
  1095.         out     dx, al
  1096.  
  1097.         mov     dx, debug_com_base+1
  1098.         mov     al, 0x00
  1099.         out     dx, al
  1100.  
  1101.         ; No parity, 8bits words, one stop bit, dlab bit back to 0
  1102.  
  1103.         mov     dx, debug_com_base+3
  1104.         mov     al, 3
  1105.         out     dx, al
  1106.  
  1107.         ; disable interrupts
  1108.  
  1109.         mov     dx, debug_com_base+1
  1110.         mov     al, 0
  1111.         out     dx, al
  1112.  
  1113.         ; clear +  enable fifo (64 bits)
  1114.  
  1115.         mov     dx, debug_com_base+2
  1116.         mov     al, 0x7 + 1 shl 5
  1117.         out     dx, al
  1118.  
  1119.  
  1120. end if
  1121.         mov     eax, [version_inf.rev]
  1122.         DEBUGF  1, "K : kernel SVN r%d\n", eax
  1123.  
  1124.         mov     eax, [cpu_count]
  1125.         test    eax, eax
  1126.         jnz     @F
  1127.         mov     al, 1                             ; at least one CPU
  1128. @@:
  1129.         DEBUGF  1, "K : %d CPU detected\n", eax
  1130.  
  1131.         DEBUGF  1, "K : BAR0 %x \n", [IDE_BAR0_val]:4
  1132.         DEBUGF  1, "K : BAR1 %x \n", [IDE_BAR1_val]:4
  1133.         DEBUGF  1, "K : BAR2 %x \n", [IDE_BAR2_val]:4
  1134.         DEBUGF  1, "K : BAR3 %x \n", [IDE_BAR3_val]:4
  1135.         DEBUGF  1, "K : BAR4 %x \n", [IDEContrRegsBaseAddr]:4
  1136.         DEBUGF  1, "K : IDEContrProgrammingInterface %x \n", [IDEContrProgrammingInterface]:4
  1137.         DEBUGF  1, "K : IDE_Interrupt %x \n", [IDE_Interrupt]:4
  1138.  
  1139. ; START MULTITASKING
  1140.  
  1141. ; A 'All set - press ESC to start' messages if need
  1142. if preboot_blogesc
  1143.         mov     esi, boot_tasking
  1144.         call    boot_log
  1145. .bll1:
  1146.         in      al, 0x60        ; wait for ESC key press
  1147.         cmp     al, 129
  1148.         jne     .bll1
  1149. end if
  1150.  
  1151.         push    eax edx
  1152.         mov     dx, [IDEContrRegsBaseAddr]
  1153.         xor     eax, eax
  1154.         add     dx, 2
  1155.         in      al, dx
  1156.         DEBUGF  1, "K : Primary Bus Master IDE Status Register %x\n", eax
  1157.  
  1158.         add     dx, 8
  1159.         in      al, dx
  1160.         DEBUGF  1, "K : Secondary Bus Master IDE Status Register %x\n", eax
  1161.         pop     edx eax
  1162.  
  1163.         cmp     [IDEContrRegsBaseAddr], 0
  1164.         setnz   [dma_hdd]
  1165.  
  1166.         cmp     [IDEContrProgrammingInterface], 0
  1167.         je      set_interrupts_for_IDE_controllers.continue
  1168. ;-----------------------------------------------------------------------------
  1169. ; set interrupts for IDE Controller
  1170. ;-----------------------------------------------------------------------------
  1171.         mov     esi, boot_set_int_IDE
  1172.         call    boot_log
  1173. set_interrupts_for_IDE_controllers:
  1174.         mov     ax, [IDEContrProgrammingInterface]
  1175.         cmp     ax, 0x0180
  1176.         je      .pata_ide
  1177.  
  1178.         cmp     ax, 0x018a
  1179.         jne     .sata_ide
  1180. ;--------------------------------------
  1181. .pata_ide:
  1182.         cmp     [IDEContrRegsBaseAddr], 0
  1183.         je      .end_set_interrupts
  1184.  
  1185.         stdcall attach_int_handler, 14, IDE_irq_14_handler, 0
  1186.         DEBUGF  1, "K : Set IDE IRQ14 return code %x\n", eax
  1187.         stdcall attach_int_handler, 15, IDE_irq_15_handler, 0
  1188.         DEBUGF  1, "K : Set IDE IRQ15 return code %x\n", eax
  1189.         jmp     .enable_IDE_interrupt
  1190. ;--------------------------------------
  1191. .sata_ide:
  1192.         cmp     ax, 0x0185
  1193.         je      .sata_ide_1
  1194.  
  1195.         cmp     ax, 0x018f
  1196.         jne     .end_set_interrupts
  1197. ;--------------------------------------
  1198. .sata_ide_1:
  1199.         cmp     [IDEContrRegsBaseAddr], 0
  1200.         je      .end_set_interrupts
  1201.  
  1202.         mov     ax, [IDE_Interrupt]
  1203.         movzx   eax, al
  1204.         stdcall attach_int_handler, eax, IDE_common_irq_handler, 0
  1205.         DEBUGF  1, "K : Set IDE IRQ%d return code %x\n", [IDE_Interrupt]:1, eax
  1206. ;--------------------------------------
  1207. .enable_IDE_interrupt:
  1208.         mov     esi, boot_enabling_ide
  1209.         call    boot_log
  1210. ; Enable interrupts in IDE controller for DMA
  1211.         mov     al, 0
  1212.         mov     ah, [DRIVE_DATA+1]
  1213.         test    ah, 10100000b
  1214.         jz      @f
  1215.  
  1216.         DEBUGF  1, "K : IDE CH1 PIO, because ATAPI drive present\n"
  1217.         jmp     .ch2_check
  1218. @@:
  1219.         mov     dx, [IDE_BAR1_val] ;0x3F4
  1220.         add     dx, 2 ;0x3F6
  1221.         out     dx, al
  1222.         DEBUGF  1, "K : IDE CH1 DMA enabled\n"
  1223. .ch2_check:
  1224.         test    ah, 1010b
  1225.         jz      @f
  1226.  
  1227.         DEBUGF  1, "K : IDE CH2 PIO, because ATAPI drive present\n"
  1228.         jmp     .end_set_interrupts
  1229. @@:
  1230.         mov     dx, [IDE_BAR3_val] ;0x374
  1231.         add     dx, 2 ;0x376
  1232.         out     dx, al
  1233.         DEBUGF  1, "K : IDE CH2 DMA enabled\n"
  1234. ;--------------------------------------
  1235. .end_set_interrupts:
  1236. ;-----------------------------------------------------------------------------
  1237.         cmp     [dma_hdd], 0
  1238.         je      .print_pio
  1239. .print_dma:
  1240.         DEBUGF  1, "K : IDE DMA mode\n"
  1241.         jmp     .continue
  1242.  
  1243. .print_pio:
  1244.         DEBUGF  1, "K : IDE PIO mode\n"
  1245. .continue:
  1246.  
  1247.         mov     [timer_ticks_enable], 1         ; for cd driver
  1248.  
  1249.         sti
  1250. ;        call    change_task
  1251.  
  1252.         jmp     osloop
  1253.  
  1254.  
  1255.         ; Fly :)
  1256.  
  1257. include 'unpacker.inc'
  1258.  
  1259. align 4
  1260. boot_log:
  1261.         pushad
  1262.  
  1263.         mov     ebx, 10*65536
  1264.         mov     bx, word [boot_y]
  1265.         add     [boot_y], dword 10
  1266.         mov     ecx, 0x80ffffff; ASCIIZ string with white color
  1267.         xor     edi, edi
  1268.         mov     edx, esi
  1269.         inc     edi
  1270.         call    dtext
  1271.  
  1272.         mov     [novesachecksum], 1000
  1273.         call    checkVga_N13
  1274.  
  1275.         popad
  1276.  
  1277.         ret
  1278.  
  1279. ; in: edx -> APPDATA for OS/IDLE slot
  1280. ; in: ebx = stack base
  1281. proc setup_os_slot
  1282.         xor     eax, eax
  1283.         mov     ecx, 256/4
  1284.         mov     edi, edx
  1285.         rep stosd
  1286.  
  1287.         mov     eax, tss+0x80
  1288.         call    get_pg_addr
  1289.         inc     eax
  1290.         mov     [edx+APPDATA.io_map], eax
  1291.         mov     eax, tss+0x1080
  1292.         call    get_pg_addr
  1293.         inc     eax
  1294.         mov     [edx+APPDATA.io_map+4], eax
  1295.  
  1296.         mov     dword [edx+APPDATA.pl0_stack], ebx
  1297.         lea     edi, [ebx+0x2000-512]
  1298.         mov     dword [edx+APPDATA.fpu_state], edi
  1299.         mov     dword [edx+APPDATA.saved_esp0], edi
  1300.         mov     dword [edx+APPDATA.saved_esp], edi
  1301.         mov     dword [edx+APPDATA.terminate_protection], 1 ; make unkillable
  1302.  
  1303.         mov     esi, fpu_data
  1304.         mov     ecx, 512/4
  1305.         cld
  1306.         rep movsd
  1307.  
  1308.         lea     eax, [edx+APP_OBJ_OFFSET]
  1309.         mov     dword [edx+APPDATA.fd_obj], eax
  1310.         mov     dword [edx+APPDATA.bk_obj], eax
  1311.  
  1312.         mov     dword [edx+APPDATA.cur_dir], sysdir_path
  1313.  
  1314.         mov     [edx + APPDATA.process], sys_proc
  1315.  
  1316.         mov     eax, edx
  1317.         shr     eax, 3
  1318.         add     eax, CURRENT_TASK - (SLOT_BASE shr 3)
  1319.         mov     [eax+TASKDATA.wnd_number], dh
  1320.         mov     byte [eax+TASKDATA.pid], dh
  1321.  
  1322.         ret
  1323. endp
  1324.  
  1325. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1326. ;                                                                    ;
  1327. ;                    MAIN OS LOOP START                              ;
  1328. ;                                                                    ;
  1329. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1330. align 32
  1331. osloop:
  1332.         mov     edx, osloop_has_work?
  1333.         xor     ecx, ecx
  1334.         call    Wait_events
  1335.         xor     eax, eax
  1336.         xchg    eax, [osloop_nonperiodic_work]
  1337.         test    eax, eax
  1338.         jz      .no_periodic
  1339. ;        call    [draw_pointer]
  1340.         call    __sys_draw_pointer
  1341.         call    window_check_events
  1342.         call    mouse_check_events
  1343.         call    checkmisc
  1344.         call    checkVga_N13
  1345. .no_periodic:
  1346.         call    stack_handler
  1347.         call    check_fdd_motor_status
  1348.         call    check_ATAPI_device_event
  1349.         call    check_lights_state
  1350.         call    check_timers
  1351.         jmp     osloop
  1352. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1353. ;                                                                    ;
  1354. ;                      MAIN OS LOOP END                              ;
  1355. ;                                                                    ;
  1356. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1357. proc osloop_has_work?
  1358.         cmp     [osloop_nonperiodic_work], 0
  1359.         jnz     .yes
  1360.         call    stack_handler_has_work?
  1361.         jnz     .yes
  1362.         call    check_fdd_motor_status_has_work?
  1363.         jnz     .yes
  1364.         call    check_ATAPI_device_event_has_work?
  1365.         jnz     .yes
  1366.         call    check_lights_state_has_work?
  1367.         jnz     .yes
  1368.         call    check_timers_has_work?
  1369.         jnz     .yes
  1370. .no:
  1371.         xor     eax, eax
  1372.         ret
  1373. .yes:
  1374.         xor     eax, eax
  1375.         inc     eax
  1376.         ret
  1377. endp
  1378.  
  1379. proc wakeup_osloop
  1380.         mov     [osloop_nonperiodic_work], 1
  1381.         ret
  1382. endp
  1383.  
  1384. uglobal
  1385. align 4
  1386. osloop_nonperiodic_work dd      ?
  1387. endg
  1388.  
  1389. align 4
  1390. idle_thread:
  1391.         sti
  1392. idle_loop:
  1393.         hlt
  1394.         jmp     idle_loop
  1395.  
  1396.  
  1397.  
  1398. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1399. ;                                                                      ;
  1400. ;                   INCLUDED SYSTEM FILES                              ;
  1401. ;                                                                      ;
  1402. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1403.  
  1404.  
  1405. include "kernel32.inc"
  1406.  
  1407.  
  1408. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1409. ;                                                                      ;
  1410. ;                       KERNEL FUNCTIONS                               ;
  1411. ;                                                                      ;
  1412. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1413.  
  1414. reserve_irqs_ports:
  1415.  
  1416.  
  1417. ; RESERVE PORTS
  1418.         mov     eax, RESERVED_PORTS
  1419.         mov     ecx, 1
  1420.  
  1421.         mov     [eax], dword 4
  1422.  
  1423.         mov     [eax+16], ecx
  1424.         mov     [eax+16+4], dword 0
  1425.         mov     [eax+16+8], dword 0x2D
  1426.  
  1427.         mov     [eax+32], ecx
  1428.         mov     [eax+32+4], dword 0x30
  1429.         mov     [eax+32+8], dword 0x4D
  1430.  
  1431.         mov     [eax+48], ecx
  1432.         mov     [eax+48+4], dword 0x50
  1433.         mov     [eax+48+8], dword 0xDF
  1434.  
  1435.         mov     [eax+64], ecx
  1436.         mov     [eax+64+4], dword 0xE5
  1437.         mov     [eax+64+8], dword 0xFF
  1438.  
  1439.         ret
  1440.  
  1441.  
  1442. iglobal
  1443.   process_number dd 0x2
  1444. endg
  1445.  
  1446. set_variables:
  1447.  
  1448.         mov     ecx, 0x16                    ; flush port 0x60
  1449. .fl60:
  1450.         in      al, 0x60
  1451.         loop    .fl60
  1452.         push    eax
  1453.  
  1454.         mov     ax, [BOOT_VARS+BOOT_Y_RES]
  1455.         shr     ax, 1
  1456.         shl     eax, 16
  1457.         mov     ax, [BOOT_VARS+BOOT_X_RES]
  1458.         shr     ax, 1
  1459.         mov     [MOUSE_X], eax
  1460.         call    wakeup_osloop
  1461.  
  1462.         xor     eax, eax
  1463.         mov     [BTN_ADDR], dword BUTTON_INFO ; address of button list
  1464.  
  1465.         mov     byte [KEY_COUNT], al              ; keyboard buffer
  1466.         mov     byte [BTN_COUNT], al              ; button buffer
  1467. ;        mov   [MOUSE_X],dword 100*65536+100    ; mouse x/y
  1468.  
  1469.         pop     eax
  1470.         ret
  1471.  
  1472. align 4
  1473. ;input  eax=43,bl-byte of output, ecx - number of port
  1474. sys_outport:
  1475.  
  1476.         mov     edi, ecx   ; separate flag for read / write
  1477.         and     ecx, 65535
  1478.  
  1479.         mov     eax, [RESERVED_PORTS]
  1480.         test    eax, eax
  1481.         jnz     .sopl8
  1482.         inc     eax
  1483.         mov     [esp+32], eax
  1484.         ret
  1485.  
  1486.   .sopl8:
  1487.         mov     edx, [TASK_BASE]
  1488.         mov     edx, [edx+0x4]
  1489.     ;and   ecx,65535
  1490.     ;cld - set on interrupt 0x40
  1491.   .sopl1:
  1492.  
  1493.         mov     esi, eax
  1494.         shl     esi, 4
  1495.         add     esi, RESERVED_PORTS
  1496.         cmp     edx, [esi+0]
  1497.         jne     .sopl2
  1498.         cmp     ecx, [esi+4]
  1499.         jb      .sopl2
  1500.         cmp     ecx, [esi+8]
  1501.         jg      .sopl2
  1502. .sopl3:
  1503.  
  1504.         test    edi, 0x80000000; read ?
  1505.         jnz     .sopl4
  1506.  
  1507.         mov     eax, ebx
  1508.         mov     dx, cx   ; write
  1509.         out     dx, al
  1510.         and     [esp+32], dword 0
  1511.         ret
  1512.  
  1513.         .sopl2:
  1514.  
  1515.         dec     eax
  1516.         jnz     .sopl1
  1517.         inc     eax
  1518.         mov     [esp+32], eax
  1519.         ret
  1520.  
  1521.  
  1522.   .sopl4:
  1523.  
  1524.         mov     dx, cx   ; read
  1525.         in      al, dx
  1526.         and     eax, 0xff
  1527.         and     [esp+32], dword 0
  1528.         mov     [esp+20], eax
  1529.         ret
  1530.  
  1531. display_number:
  1532. ;It is not optimization
  1533.         mov     eax, ebx
  1534.         mov     ebx, ecx
  1535.         mov     ecx, edx
  1536.         mov     edx, esi
  1537.         mov     esi, edi
  1538. ; eax = print type, al=0 -> ebx is number
  1539. ;                   al=1 -> ebx is pointer
  1540. ;                   ah=0 -> display decimal
  1541. ;                   ah=1 -> display hexadecimal
  1542. ;                   ah=2 -> display binary
  1543. ;                   eax bits 16-21 = number of digits to display (0-32)
  1544. ;                   eax bits 22-31 = reserved
  1545. ;
  1546. ; ebx = number or pointer
  1547. ; ecx = x shl 16 + y
  1548. ; edx = color
  1549.         xor     edi, edi
  1550. display_number_force:
  1551.         push    eax
  1552.         and     eax, 0x3fffffff
  1553.         cmp     eax, 0xffff     ; length > 0 ?
  1554.         pop     eax
  1555.         jge     cont_displ
  1556.         ret
  1557.    cont_displ:
  1558.         push    eax
  1559.         and     eax, 0x3fffffff
  1560.         cmp     eax, 61*0x10000  ; length <= 60 ?
  1561.         pop     eax
  1562.         jb      cont_displ2
  1563.         ret
  1564.    cont_displ2:
  1565.  
  1566.         pushad
  1567.  
  1568.         cmp     al, 1            ; ecx is a pointer ?
  1569.         jne     displnl1
  1570.         mov     ebp, ebx
  1571.         add     ebp, 4
  1572.         mov     ebp, [ebp+std_application_base_address]
  1573.         mov     ebx, [ebx+std_application_base_address]
  1574.  displnl1:
  1575.         sub     esp, 64
  1576.  
  1577.         test    ah, ah            ; DECIMAL
  1578.         jnz     no_display_desnum
  1579.         shr     eax, 16
  1580.         and     eax, 0xC03f
  1581. ;     and   eax,0x3f
  1582.         push    eax
  1583.         and     eax, 0x3f
  1584.         mov     edi, esp
  1585.         add     edi, 4+64-1
  1586.         mov     ecx, eax
  1587.         mov     eax, ebx
  1588.         mov     ebx, 10
  1589.  d_desnum:
  1590.         xor     edx, edx
  1591.         call    division_64_bits
  1592.         div     ebx
  1593.         add     dl, 48
  1594.         mov     [edi], dl
  1595.         dec     edi
  1596.         loop    d_desnum
  1597.         pop     eax
  1598.         call    normalize_number
  1599.         call    draw_num_text
  1600.         add     esp, 64
  1601.         popad
  1602.         ret
  1603.    no_display_desnum:
  1604.  
  1605.         cmp     ah, 0x01         ; HEXADECIMAL
  1606.         jne     no_display_hexnum
  1607.         shr     eax, 16
  1608.         and     eax, 0xC03f
  1609. ;     and   eax,0x3f
  1610.         push    eax
  1611.         and     eax, 0x3f
  1612.         mov     edi, esp
  1613.         add     edi, 4+64-1
  1614.         mov     ecx, eax
  1615.         mov     eax, ebx
  1616.         mov     ebx, 16
  1617.    d_hexnum:
  1618.         xor     edx, edx
  1619.         call    division_64_bits
  1620.         div     ebx
  1621.    hexletters = __fdo_hexdigits
  1622.         add     edx, hexletters
  1623.         mov     dl, [edx]
  1624.         mov     [edi], dl
  1625.         dec     edi
  1626.         loop    d_hexnum
  1627.         pop     eax
  1628.         call    normalize_number
  1629.         call    draw_num_text
  1630.         add     esp, 64
  1631.         popad
  1632.         ret
  1633.    no_display_hexnum:
  1634.  
  1635.         cmp     ah, 0x02         ; BINARY
  1636.         jne     no_display_binnum
  1637.         shr     eax, 16
  1638.         and     eax, 0xC03f
  1639. ;     and   eax,0x3f
  1640.         push    eax
  1641.         and     eax, 0x3f
  1642.         mov     edi, esp
  1643.         add     edi, 4+64-1
  1644.         mov     ecx, eax
  1645.         mov     eax, ebx
  1646.         mov     ebx, 2
  1647.    d_binnum:
  1648.         xor     edx, edx
  1649.         call    division_64_bits
  1650.         div     ebx
  1651.         add     dl, 48
  1652.         mov     [edi], dl
  1653.         dec     edi
  1654.         loop    d_binnum
  1655.         pop     eax
  1656.         call    normalize_number
  1657.         call    draw_num_text
  1658.         add     esp, 64
  1659.         popad
  1660.         ret
  1661.    no_display_binnum:
  1662.  
  1663.         add     esp, 64
  1664.         popad
  1665.         ret
  1666.  
  1667. normalize_number:
  1668.         test    ah, 0x80
  1669.         jz      .continue
  1670.         mov     ecx, 48
  1671.         and     eax, 0x3f
  1672. @@:
  1673.         inc     edi
  1674.         cmp     [edi], cl
  1675.         jne     .continue
  1676.         dec     eax
  1677.         cmp     eax, 1
  1678.         ja      @r
  1679.         mov     al, 1
  1680. .continue:
  1681.         and     eax, 0x3f
  1682.         ret
  1683.  
  1684. division_64_bits:
  1685.         test    [esp+1+4], byte 0x40
  1686.         jz      .continue
  1687.         push    eax
  1688.         mov     eax, ebp
  1689.         div     ebx
  1690.         mov     ebp, eax
  1691.         pop     eax
  1692. .continue:
  1693.         ret
  1694.  
  1695. draw_num_text:
  1696.         mov     esi, eax
  1697.         mov     edx, 64+4
  1698.         sub     edx, eax
  1699.         add     edx, esp
  1700.         mov     ebx, [esp+64+32-8+4]
  1701. ; add window start x & y
  1702.         mov     ecx, [TASK_BASE]
  1703.  
  1704.         mov     edi, [CURRENT_TASK]
  1705.         shl     edi, 8
  1706.  
  1707.         mov     eax, [ecx-twdw+WDATA.box.left]
  1708.         add     eax, [edi+SLOT_BASE+APPDATA.wnd_clientbox.left]
  1709.         shl     eax, 16
  1710.         add     eax, [ecx-twdw+WDATA.box.top]
  1711.         add     eax, [edi+SLOT_BASE+APPDATA.wnd_clientbox.top]
  1712.         add     ebx, eax
  1713.         mov     ecx, [esp+64+32-12+4]
  1714.         and     ecx, not 0x80000000     ; force counted string
  1715.         mov     eax, [esp+64+8]         ; background color (if given)
  1716.         mov     edi, [esp+64+4]
  1717.         jmp     dtext
  1718.  
  1719. align 4
  1720.  
  1721. sys_setup:
  1722.  
  1723. ; 1=roland mpu midi base , base io address
  1724. ; 2=keyboard   1, base kaybap 2, shift keymap, 9 country 1eng 2fi 3ger 4rus
  1725. ; 3=cd base    1, pri.master 2, pri slave 3 sec master, 4 sec slave
  1726. ; 5=system language, 1eng 2fi 3ger 4rus
  1727. ; 7=hd base    1, pri.master 2, pri slave 3 sec master, 4 sec slave
  1728. ; 8=fat32 partition in hd
  1729. ; 9
  1730. ; 10 = sound dma channel
  1731. ; 11 = enable lba read
  1732. ; 12 = enable pci access
  1733.  
  1734.  
  1735.         and     [esp+32], dword 0
  1736.         dec     ebx                             ; MIDI
  1737.         jnz     nsyse1
  1738.         cmp     ecx, 0x100
  1739.  
  1740.         jb      nsyse1
  1741.         mov     esi, 65535
  1742.         cmp     esi, ecx
  1743.  
  1744.         jb      nsyse1
  1745.         mov     [midi_base], cx ;bx
  1746.         mov     word [mididp], cx;bx
  1747.         inc     cx              ;bx
  1748.         mov     word [midisp], cx;bx
  1749.         ret
  1750.  
  1751. iglobal
  1752. midi_base dw 0
  1753. endg
  1754.  
  1755.    nsyse1:
  1756.         dec     ebx                              ; KEYBOARD
  1757.         jnz     nsyse2
  1758.         mov     edi, [TASK_BASE]
  1759.         mov     eax, [edi+TASKDATA.mem_start]
  1760.         add     eax, edx
  1761.  
  1762.         dec     ecx
  1763.         jnz     kbnobase
  1764.         mov     ebx, keymap
  1765.         mov     ecx, 128
  1766.         call    memmove
  1767.         ret
  1768.    kbnobase:
  1769.         dec     ecx
  1770.         jnz     kbnoshift
  1771.  
  1772.         mov     ebx, keymap_shift
  1773.         mov     ecx, 128
  1774.         call    memmove
  1775.         ret
  1776.    kbnoshift:
  1777.         dec     ecx
  1778.         jnz     kbnoalt
  1779.         mov     ebx, keymap_alt
  1780.         mov     ecx, 128
  1781.         call    memmove
  1782.         ret
  1783.    kbnoalt:
  1784.         sub     ecx, 6
  1785.         jnz     kbnocountry
  1786.         mov     word [keyboard], dx
  1787.         ret
  1788.    kbnocountry:
  1789.         mov     [esp+32], dword 1
  1790.         ret
  1791.    nsyse2:
  1792.         dec     ebx                         ; CD
  1793.         jnz     nsyse4
  1794.  
  1795.         test    ecx, ecx
  1796.         jz      nosesl
  1797.  
  1798.         cmp     ecx, 4
  1799.         ja      nosesl
  1800.         mov     [cd_base], cl
  1801.  
  1802.         dec     ecx
  1803.         jnz     noprma
  1804.         mov     eax, [hd_address_table]
  1805.         mov     [cdbase], eax   ;0x1f0
  1806.         mov     [cdid], 0xa0
  1807.    noprma:
  1808.  
  1809.         dec     ecx
  1810.         jnz     noprsl
  1811.         mov     eax, [hd_address_table]
  1812.         mov     [cdbase], eax   ;0x1f0
  1813.         mov     [cdid], 0xb0
  1814.    noprsl:
  1815.         dec     ecx
  1816.         jnz     nosema
  1817.         mov     eax, [hd_address_table+16]
  1818.         mov     [cdbase], eax   ;0x170
  1819.         mov     [cdid], 0xa0
  1820.    nosema:
  1821.         dec     ecx
  1822.         jnz     nosesl
  1823.         mov     eax, [hd_address_table+16]
  1824.         mov     [cdbase], eax   ;0x170
  1825.         mov     [cdid], 0xb0
  1826.    nosesl:
  1827.         ret
  1828.  
  1829. iglobal
  1830. cd_base db 0
  1831.  
  1832. endg
  1833.    nsyse4:
  1834.  
  1835.         sub     ebx, 2           ; SYSTEM LANGUAGE
  1836.         jnz     nsyse5
  1837.         mov     [syslang], ecx
  1838.         ret
  1839.    nsyse5:
  1840.  
  1841.         sub     ebx, 2          ; HD BASE - obsolete
  1842.         jnz     nsyse7
  1843.  
  1844.    nosethd:
  1845.         ret
  1846.  
  1847. nsyse7:
  1848.  
  1849. ;     cmp  eax,8                      ; HD PARTITION - obsolete
  1850.         dec     ebx
  1851.         jnz     nsyse8
  1852.         ret
  1853.  
  1854. nsyse8:
  1855. ;     cmp  eax,11                     ; ENABLE LBA READ
  1856.         and     ecx, 1
  1857.         sub     ebx, 3
  1858.         jnz     no_set_lba_read
  1859.         mov     [lba_read_enabled], ecx
  1860.         ret
  1861.  
  1862. no_set_lba_read:
  1863. ;     cmp  eax,12                     ; ENABLE PCI ACCESS
  1864.         dec     ebx
  1865.         jnz     sys_setup_err
  1866.         mov     [pci_access_enabled], ecx
  1867.         ret
  1868.  
  1869. sys_setup_err:
  1870.         or      [esp+32], dword -1
  1871.         ret
  1872.  
  1873. align 4
  1874.  
  1875. sys_getsetup:
  1876.  
  1877. ; 1=roland mpu midi base , base io address
  1878. ; 2=keyboard   1, base kaybap 2, shift keymap, 9 country 1eng 2fi 3ger 4rus
  1879. ; 3=cd base    1, pri.master 2, pri slave 3 sec master, 4 sec slave
  1880. ; 5=system language, 1eng 2fi 3ger 4rus
  1881. ; 7=hd base    1, pri.master 2, pri slave 3 sec master, 4 sec slave
  1882. ; 8=fat32 partition in hd
  1883. ; 9=get hs timer tic
  1884.  
  1885. ;     cmp  eax,1
  1886.         dec     ebx
  1887.         jnz     ngsyse1
  1888.         movzx   eax, [midi_base]
  1889.         mov     [esp+32], eax
  1890.         ret
  1891. ngsyse1:
  1892. ;     cmp  eax,2
  1893.         dec     ebx
  1894.         jnz     ngsyse2
  1895.  
  1896.         mov     edi, [TASK_BASE]
  1897.         mov     ebx, [edi+TASKDATA.mem_start]
  1898.         add     ebx, edx
  1899.  
  1900. ;     cmp  ebx,1
  1901.         dec     ecx
  1902.         jnz     kbnobaseret
  1903.         mov     eax, keymap
  1904.         mov     ecx, 128
  1905.         call    memmove
  1906.         ret
  1907. kbnobaseret:
  1908. ;     cmp  ebx,2
  1909.         dec     ecx
  1910.         jnz     kbnoshiftret
  1911.  
  1912.         mov     eax, keymap_shift
  1913.         mov     ecx, 128
  1914.         call    memmove
  1915.         ret
  1916. kbnoshiftret:
  1917. ;     cmp  ebx,3
  1918.         dec     ecx
  1919.         jne     kbnoaltret
  1920.  
  1921.         mov     eax, keymap_alt
  1922.         mov     ecx, 128
  1923.         call    memmove
  1924.         ret
  1925. kbnoaltret:
  1926. ;     cmp  ebx,9
  1927.         sub     ecx, 6
  1928.         jnz     ngsyse2
  1929.         movzx   eax, word [keyboard]
  1930.         mov     [esp+32], eax
  1931.         ret
  1932.  
  1933.  
  1934. ngsyse2:
  1935. ;         cmp  eax,3
  1936.         dec     ebx
  1937.         jnz     ngsyse3
  1938.         movzx   eax, [cd_base]
  1939.         mov     [esp+32], eax
  1940.         ret
  1941. ngsyse3:
  1942. ;         cmp  eax,5
  1943.         sub     ebx, 2
  1944.         jnz     ngsyse5
  1945.         mov     eax, [syslang]
  1946.         mov     [esp+32], eax
  1947.         ret
  1948. ngsyse5:
  1949. ;     cmp  eax,7
  1950.         sub     ebx, 2
  1951.         jnz     ngsyse7
  1952.         xor     eax, eax
  1953.         mov     [esp+32], eax
  1954.         ret
  1955. ngsyse7:
  1956. ;     cmp  eax,8
  1957.         dec     ebx
  1958.         jnz     ngsyse8
  1959.         mov     eax, [fat32part]
  1960.         mov     [esp+32], eax
  1961.         ret
  1962. ngsyse8:
  1963. ;     cmp  eax,9
  1964.         dec     ebx
  1965.         jnz     ngsyse9
  1966.         mov     eax, [timer_ticks];[0xfdf0]
  1967.         mov     [esp+32], eax
  1968.         ret
  1969. ngsyse9:
  1970. ;     cmp  eax,11
  1971.         sub     ebx, 2
  1972.         jnz     ngsyse11
  1973.         mov     eax, [lba_read_enabled]
  1974.         mov     [esp+32], eax
  1975.         ret
  1976. ngsyse11:
  1977. ;     cmp  eax,12
  1978.         dec     ebx
  1979.         jnz     ngsyse12
  1980.         mov     eax, [pci_access_enabled]
  1981.         mov     [esp+32], eax
  1982.         ret
  1983. ngsyse12:
  1984.         mov     [esp+32], dword 1
  1985.         ret
  1986.  
  1987.  
  1988. get_timer_ticks:
  1989.         mov     eax, [timer_ticks]
  1990.         ret
  1991.  
  1992. iglobal
  1993. align 4
  1994. mousefn dd msscreen, mswin, msbutton, msset
  1995.         dd app_load_cursor
  1996.         dd app_set_cursor
  1997.         dd app_delete_cursor
  1998.         dd msz
  1999. endg
  2000.  
  2001. readmousepos:
  2002.  
  2003. ; eax=0 screen relative
  2004. ; eax=1 window relative
  2005. ; eax=2 buttons pressed
  2006. ; eax=3 set mouse pos   ; reserved
  2007. ; eax=4 load cursor
  2008. ; eax=5 set cursor
  2009. ; eax=6 delete cursor   ; reserved
  2010. ; eax=7 get mouse_z
  2011.  
  2012.         cmp     ebx, 7
  2013.         ja      msset
  2014.         jmp     [mousefn+ebx*4]
  2015. msscreen:
  2016.         mov     eax, [MOUSE_X]
  2017.         shl     eax, 16
  2018.         mov     ax, [MOUSE_Y]
  2019.         mov     [esp+36-4], eax
  2020.         ret
  2021. mswin:
  2022.         mov     eax, [MOUSE_X]
  2023.         shl     eax, 16
  2024.         mov     ax, [MOUSE_Y]
  2025.         mov     esi, [TASK_BASE]
  2026.         mov     bx, word [esi-twdw+WDATA.box.left]
  2027.         shl     ebx, 16
  2028.         mov     bx, word [esi-twdw+WDATA.box.top]
  2029.         sub     eax, ebx
  2030.  
  2031.         mov     edi, [CURRENT_TASK]
  2032.         shl     edi, 8
  2033.         sub     ax, word[edi+SLOT_BASE+APPDATA.wnd_clientbox.top]
  2034.         rol     eax, 16
  2035.         sub     ax, word[edi+SLOT_BASE+APPDATA.wnd_clientbox.left]
  2036.         rol     eax, 16
  2037.         mov     [esp+36-4], eax
  2038.         ret
  2039. msbutton:
  2040.         movzx   eax, byte [BTN_DOWN]
  2041.         mov     [esp+36-4], eax
  2042.         ret
  2043. msz:
  2044.         mov     edi, [TASK_COUNT]
  2045.         movzx   edi, word [WIN_POS + edi*2]
  2046.         cmp     edi, [CURRENT_TASK]
  2047.         jne     @f
  2048.         mov     ax, [MOUSE_SCROLL_H]
  2049.         shl     eax, 16
  2050.         mov     ax, [MOUSE_SCROLL_V]
  2051.         mov     [esp+36-4], eax
  2052.         and     [MOUSE_SCROLL_H], word 0
  2053.         and     [MOUSE_SCROLL_V], word 0
  2054.         ret
  2055.        @@:
  2056.         and     [esp+36-4], dword 0
  2057. ;           ret
  2058. msset:
  2059.         ret
  2060.  
  2061. app_load_cursor:
  2062.         cmp     ecx, OS_BASE
  2063.         jae     msset
  2064.         stdcall load_cursor, ecx, edx
  2065.         mov     [esp+36-4], eax
  2066.         ret
  2067.  
  2068. app_set_cursor:
  2069.         stdcall set_cursor, ecx
  2070.         mov     [esp+36-4], eax
  2071.         ret
  2072.  
  2073. app_delete_cursor:
  2074.         stdcall delete_cursor, ecx
  2075.         mov     [esp+36-4], eax
  2076.         ret
  2077.  
  2078. is_input:
  2079.  
  2080.         push    edx
  2081.         mov     dx, word [midisp]
  2082.         in      al, dx
  2083.         and     al, 0x80
  2084.         pop     edx
  2085.         ret
  2086.  
  2087. is_output:
  2088.  
  2089.         push    edx
  2090.         mov     dx, word [midisp]
  2091.         in      al, dx
  2092.         and     al, 0x40
  2093.         pop     edx
  2094.         ret
  2095.  
  2096.  
  2097. get_mpu_in:
  2098.  
  2099.         push    edx
  2100.         mov     dx, word [mididp]
  2101.         in      al, dx
  2102.         pop     edx
  2103.         ret
  2104.  
  2105.  
  2106. put_mpu_out:
  2107.  
  2108.         push    edx
  2109.         mov     dx, word [mididp]
  2110.         out     dx, al
  2111.         pop     edx
  2112.         ret
  2113.  
  2114.  
  2115.  
  2116. align 4
  2117.  
  2118. sys_midi:
  2119.         cmp     [mididp], 0
  2120.         jnz     sm0
  2121.         mov     [esp+36], dword 1
  2122.         ret
  2123. sm0:
  2124.         and     [esp+36], dword 0
  2125.         dec     ebx
  2126.         jnz     smn1
  2127.  ;    call setuart
  2128. su1:
  2129.         call    is_output
  2130.         test    al, al
  2131.         jnz     su1
  2132.         mov     dx, word [midisp]
  2133.         mov     al, 0xff
  2134.         out     dx, al
  2135. su2:
  2136.         mov     dx, word [midisp]
  2137.         mov     al, 0xff
  2138.         out     dx, al
  2139.         call    is_input
  2140.         test    al, al
  2141.         jnz     su2
  2142.         call    get_mpu_in
  2143.         cmp     al, 0xfe
  2144.         jnz     su2
  2145. su3:
  2146.         call    is_output
  2147.         test    al, al
  2148.         jnz     su3
  2149.         mov     dx, word [midisp]
  2150.         mov     al, 0x3f
  2151.         out     dx, al
  2152.         ret
  2153. smn1:
  2154.         dec     ebx
  2155.         jnz     smn2
  2156. sm10:
  2157.         call    get_mpu_in
  2158.         call    is_output
  2159.         test    al, al
  2160.         jnz     sm10
  2161.         mov     al, bl
  2162.         call    put_mpu_out
  2163.         smn2:
  2164.         ret
  2165.  
  2166. detect_devices:
  2167. ;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  2168. ;include 'detect/commouse.inc'
  2169. ;include 'detect/ps2mouse.inc'
  2170. ;include 'detect/dev_fd.inc'
  2171. ;include 'detect/dev_hdcd.inc'
  2172. ;include 'detect/sear_par.inc'
  2173. ;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  2174.         ret
  2175.  
  2176. sys_end:
  2177. ;--------------------------------------
  2178.         cmp     [_display.select_cursor], 0
  2179.         je      @f
  2180. ; restore default cursor before killing
  2181.         pusha
  2182.         mov     ecx, [current_slot]
  2183.         call    restore_default_cursor_before_killing
  2184.         popa
  2185. @@:
  2186. ;--------------------------------------
  2187. ; kill all sockets this process owns
  2188.         pusha
  2189.         mov     edx, [TASK_BASE]
  2190.         mov     edx, [edx+TASKDATA.pid]
  2191.         call    SOCKET_process_end
  2192.         popa
  2193. ;--------------------------------------
  2194.         mov     ecx, [current_slot]
  2195.         mov     eax, [ecx+APPDATA.tls_base]
  2196.         test    eax, eax
  2197.         jz      @F
  2198.  
  2199.         stdcall user_free, eax
  2200. @@:
  2201.  
  2202.         mov     eax, [TASK_BASE]
  2203.         mov     [eax+TASKDATA.state], 3; terminate this program
  2204.         call    wakeup_osloop
  2205.  
  2206. .waitterm:            ; wait here for termination
  2207.         call    change_task
  2208.         jmp     .waitterm
  2209. ;------------------------------------------------------------------------------
  2210. align 4
  2211. restore_default_cursor_before_killing:
  2212.         pushfd
  2213.         cli
  2214.         mov     eax, [def_cursor]
  2215.         mov     [ecx+APPDATA.cursor], eax
  2216.  
  2217.         movzx   eax, word [MOUSE_Y]
  2218.         movzx   ebx, word [MOUSE_X]
  2219. ;        mov     ecx, [Screen_Max_X]
  2220. ;        inc     ecx
  2221. ;        mul     ecx
  2222.         mov     eax, [d_width_calc_area + eax*4]
  2223.  
  2224.         add     eax, [_WinMapAddress]
  2225.         movzx   edx, byte [ebx+eax]
  2226.         shl     edx, 8
  2227.         mov     esi, [edx+SLOT_BASE+APPDATA.cursor]
  2228.  
  2229.         cmp     esi, [current_cursor]
  2230.         je      @f
  2231.  
  2232.         push    esi
  2233.         call    [_display.select_cursor]
  2234.         mov     [current_cursor], esi
  2235. @@:
  2236.         mov     [redrawmouse_unconditional], 1
  2237.         call    wakeup_osloop
  2238.         popfd
  2239.         ret
  2240. ;------------------------------------------------------------------------------
  2241. iglobal
  2242. align 4
  2243. sys_system_table:
  2244.         dd      sysfn_deactivate        ; 1 = deactivate window
  2245.         dd      sysfn_terminate         ; 2 = terminate thread
  2246.         dd      sysfn_activate          ; 3 = activate window
  2247.         dd      sysfn_getidletime       ; 4 = get idle time
  2248.         dd      sysfn_getcpuclock       ; 5 = get cpu clock
  2249.         dd      sysfn_saveramdisk       ; 6 = save ramdisk
  2250.         dd      sysfn_getactive         ; 7 = get active window
  2251.         dd      sysfn_sound_flag        ; 8 = get/set sound_flag
  2252.         dd      sysfn_shutdown          ; 9 = shutdown with parameter
  2253.         dd      sysfn_minimize          ; 10 = minimize window
  2254.         dd      sysfn_getdiskinfo       ; 11 = get disk subsystem info
  2255.         dd      sysfn_lastkey           ; 12 = get last pressed key
  2256.         dd      sysfn_getversion        ; 13 = get kernel version
  2257.         dd      sysfn_waitretrace       ; 14 = wait retrace
  2258.         dd      sysfn_centermouse       ; 15 = center mouse cursor
  2259.         dd      sysfn_getfreemem        ; 16 = get free memory size
  2260.         dd      sysfn_getallmem         ; 17 = get total memory size
  2261.         dd      sysfn_terminate2        ; 18 = terminate thread using PID
  2262.                                         ;                 instead of slot
  2263.         dd      sysfn_mouse_acceleration; 19 = set/get mouse acceleration
  2264.         dd      sysfn_meminfo           ; 20 = get extended memory info
  2265.         dd      sysfn_pid_to_slot       ; 21 = get slot number for pid
  2266.         dd      sysfn_min_rest_window   ; 22 = minimize and restore any window
  2267.         dd      sysfn_min_windows       ; 23 = minimize all windows
  2268.         dd      sysfn_set_screen_sizes  ; 24 = set screen sizes for Vesa
  2269. sysfn_num = ($ - sys_system_table)/4
  2270. endg
  2271. ;------------------------------------------------------------------------------
  2272. sys_system:
  2273.         dec     ebx
  2274.         cmp     ebx, sysfn_num
  2275.         jae     @f
  2276.         jmp     dword [sys_system_table + ebx*4]
  2277. @@:
  2278.         ret
  2279. ;------------------------------------------------------------------------------
  2280. sysfn_shutdown:          ; 18.9 = system shutdown
  2281.         cmp     ecx, 1
  2282.         jl      exit_for_anyone
  2283.         cmp     ecx, 4
  2284.         jg      exit_for_anyone
  2285.         mov     [BOOT_VARS+0x9030], cl
  2286.  
  2287.         mov     eax, [TASK_COUNT]
  2288.         mov     [SYS_SHUTDOWN], al
  2289.         mov     [shutdown_processes], eax
  2290.         call    wakeup_osloop
  2291.         and     dword [esp+32], 0
  2292.  exit_for_anyone:
  2293.         ret
  2294.   uglobal
  2295.    shutdown_processes:
  2296.                        dd 0x0
  2297.   endg
  2298. ;------------------------------------------------------------------------------
  2299. sysfn_terminate:        ; 18.2 = TERMINATE
  2300.         push    ecx
  2301.         cmp     ecx, 2
  2302.         jb      noprocessterminate
  2303.         mov     edx, [TASK_COUNT]
  2304.         cmp     ecx, edx
  2305.         ja      noprocessterminate
  2306.         mov     eax, [TASK_COUNT]
  2307.         shl     ecx, 5
  2308.         mov     edx, [ecx+CURRENT_TASK+TASKDATA.pid]
  2309.         add     ecx, CURRENT_TASK+TASKDATA.state
  2310.         cmp     byte [ecx], 9
  2311.         jz      noprocessterminate
  2312.         push    ecx edx
  2313.         lea     edx, [(ecx-(CURRENT_TASK and 1FFFFFFFh)-TASKDATA.state)*8+SLOT_BASE]
  2314.         call    request_terminate
  2315.         pop     edx ecx
  2316.         test    eax, eax
  2317.         jz      noprocessterminate
  2318. ;--------------------------------------
  2319. ; terminate all network sockets it used
  2320.         pusha
  2321.         mov     eax, edx
  2322.         call    SOCKET_process_end
  2323.         popa
  2324. ;--------------------------------------
  2325.         cmp     [_display.select_cursor], 0
  2326.         je      .restore_end
  2327. ; restore default cursor before killing
  2328.         pusha
  2329.         mov     ecx, [esp+32]
  2330.         shl     ecx, 8
  2331.         add     ecx, SLOT_BASE
  2332.         mov     eax, [def_cursor]
  2333.         cmp     [ecx+APPDATA.cursor], eax
  2334.         je      @f
  2335.         call    restore_default_cursor_before_killing
  2336. @@:
  2337.         popa
  2338. .restore_end:
  2339. ;--------------------------------------
  2340.      ;call MEM_Heap_Lock      ;guarantee that process isn't working with heap
  2341.         mov     [ecx], byte 3; clear possible i40's
  2342.         call    wakeup_osloop
  2343.      ;call MEM_Heap_UnLock
  2344.  
  2345.         cmp     edx, [application_table_owner]; clear app table stat
  2346.         jne     noatsc
  2347.         call    unlock_application_table
  2348. noatsc:
  2349. noprocessterminate:
  2350.         add     esp, 4
  2351.         ret
  2352. ;------------------------------------------------------------------------------
  2353. sysfn_terminate2:
  2354. ;lock application_table_status mutex
  2355. .table_status:
  2356.         call    lock_application_table
  2357.         mov     eax, ecx
  2358.         call    pid_to_slot
  2359.         test    eax, eax
  2360.         jz      .not_found
  2361.         mov     ecx, eax
  2362.         cli
  2363.         call    sysfn_terminate
  2364.         call    unlock_application_table
  2365.         sti
  2366.         and     dword [esp+32], 0
  2367.         ret
  2368. .not_found:
  2369.         call    unlock_application_table
  2370.         or      dword [esp+32], -1
  2371.         ret
  2372. ;------------------------------------------------------------------------------
  2373. sysfn_deactivate:         ; 18.1 = DEACTIVATE WINDOW
  2374.         cmp     ecx, 2
  2375.         jb      .nowindowdeactivate
  2376.         cmp     ecx, [TASK_COUNT]
  2377.         ja      .nowindowdeactivate
  2378.  
  2379.         movzx   esi, word [WIN_STACK + ecx*2]
  2380.         cmp     esi, 1
  2381.         je      .nowindowdeactivate ; already deactive
  2382.  
  2383.         mov     edi, ecx
  2384.         shl     edi, 5
  2385.         add     edi, window_data
  2386.         movzx   esi, word [WIN_STACK + ecx * 2]
  2387.         lea     esi, [WIN_POS + esi * 2]
  2388.         call    window._.window_deactivate
  2389.  
  2390.         call    syscall_display_settings._.calculate_whole_screen
  2391.         call    syscall_display_settings._.redraw_whole_screen
  2392. .nowindowdeactivate:
  2393.         ret
  2394. ;------------------------------------------------------------------------------
  2395. sysfn_activate:         ; 18.3 = ACTIVATE WINDOW
  2396.         cmp     ecx, 2
  2397.         jb      .nowindowactivate
  2398.         cmp     ecx, [TASK_COUNT]
  2399.         ja      .nowindowactivate
  2400. ;-------------------------------------
  2401. @@:
  2402. ; If the window is captured and moved by the user,
  2403. ; then you can't change the position in window stack!!!
  2404.         mov     al, [mouse.active_sys_window.action]
  2405.         and     al, WINDOW_MOVE_AND_RESIZE_FLAGS
  2406.         test    al, al
  2407.         jz      @f
  2408.         call    change_task
  2409.         jmp     @b
  2410. @@:
  2411. ;-------------------------------------
  2412.         mov     [window_minimize], 2; restore window if minimized
  2413.         call    wakeup_osloop
  2414.  
  2415.         movzx   esi, word [WIN_STACK + ecx*2]
  2416.         cmp     esi, [TASK_COUNT]
  2417.         je      .nowindowactivate; already active
  2418.  
  2419.         mov     edi, ecx
  2420.         shl     edi, 5
  2421.         add     edi, window_data
  2422.         movzx   esi, word [WIN_STACK + ecx * 2]
  2423.         lea     esi, [WIN_POS + esi * 2]
  2424.         call    waredraw
  2425. .nowindowactivate:
  2426.         ret
  2427. ;------------------------------------------------------------------------------
  2428. sysfn_getidletime:              ; 18.4 = GET IDLETIME
  2429.         mov     eax, [CURRENT_TASK+32+TASKDATA.cpu_usage]
  2430.         mov     [esp+32], eax
  2431.         ret
  2432. ;------------------------------------------------------------------------------
  2433. sysfn_getcpuclock:              ; 18.5 = GET TSC/SEC
  2434.         mov     eax, dword [cpu_freq]
  2435.         mov     [esp+32], eax
  2436.         ret
  2437. ;------------------------------------------------------------------------------
  2438. get_cpu_freq:
  2439.         mov     eax, dword [cpu_freq]
  2440.         mov     edx, dword [cpu_freq+4]
  2441.         ret
  2442. ;  SAVE ramdisk to /hd/1/menuet.img
  2443. ;!!!!!!!!!!!!!!!!!!!!!!!!
  2444.    include 'blkdev/rdsave.inc'
  2445. ;!!!!!!!!!!!!!!!!!!!!!!!!
  2446. ;------------------------------------------------------------------------------
  2447. align 4
  2448. sysfn_getactive:        ; 18.7 = get active window
  2449.         mov     eax, [TASK_COUNT]
  2450.         movzx   eax, word [WIN_POS + eax*2]
  2451.         mov     [esp+32], eax
  2452.         ret
  2453. ;------------------------------------------------------------------------------
  2454. sysfn_sound_flag:       ; 18.8 = get/set sound_flag
  2455. ;     cmp  ecx,1
  2456.         dec     ecx
  2457.         jnz     nogetsoundflag
  2458.         movzx   eax, byte [sound_flag]; get sound_flag
  2459.         mov     [esp+32], eax
  2460.         ret
  2461.  nogetsoundflag:
  2462. ;     cmp  ecx,2
  2463.         dec     ecx
  2464.         jnz     nosoundflag
  2465.         xor     byte [sound_flag], 1
  2466.  nosoundflag:
  2467.         ret
  2468. ;------------------------------------------------------------------------------
  2469. sysfn_minimize:         ; 18.10 = minimize window
  2470.         mov     [window_minimize], 1
  2471.         call    wakeup_osloop
  2472.         ret
  2473. ;------------------------------------------------------------------------------
  2474. align 4
  2475. sysfn_getdiskinfo:      ; 18.11 = get disk info table
  2476. ;     cmp  ecx,1
  2477.         dec     ecx
  2478.         jnz     full_table
  2479.   small_table:
  2480.         call    for_all_tables
  2481.         mov     ecx, 10
  2482.         cld
  2483.         rep movsb
  2484.         ret
  2485.    for_all_tables:
  2486.         mov     edi, edx
  2487.         mov     esi, DRIVE_DATA
  2488.         ret
  2489.   full_table:
  2490. ;     cmp  ecx,2
  2491.         dec     ecx
  2492.         jnz     exit_for_anyone
  2493.         call    for_all_tables
  2494.         mov     ecx, DRIVE_DATA_SIZE/4
  2495.         cld
  2496.         rep movsd
  2497.         ret
  2498. ;------------------------------------------------------------------------------
  2499. sysfn_lastkey:          ; 18.12 = return 0 (backward compatibility)
  2500.         and     dword [esp+32], 0
  2501.         ret
  2502. ;------------------------------------------------------------------------------
  2503. sysfn_getversion:       ; 18.13 = get kernel ID and version
  2504.         mov     edi, ecx
  2505.         mov     esi, version_inf
  2506.         mov     ecx, version_end-version_inf
  2507.         rep movsb
  2508.         ret
  2509. ;------------------------------------------------------------------------------
  2510. sysfn_waitretrace:     ; 18.14 = sys wait retrace
  2511.      ;wait retrace functions
  2512.  sys_wait_retrace:
  2513.         mov     edx, 0x3da
  2514.  WaitRetrace_loop:
  2515.         in      al, dx
  2516.         test    al, 1000b
  2517.         jz      WaitRetrace_loop
  2518.         and     [esp+32], dword 0
  2519.         ret
  2520. ;------------------------------------------------------------------------------
  2521. align 4
  2522. sysfn_centermouse:      ; 18.15 = mouse centered
  2523. ; removed here by <Lrz>
  2524. ;     call  mouse_centered
  2525. ;* mouse centered - start code- Mario79
  2526. ;mouse_centered:
  2527. ;        push  eax
  2528.         mov     eax, [Screen_Max_X]
  2529.         shr     eax, 1
  2530.         mov     [MOUSE_X], ax
  2531.         mov     eax, [Screen_Max_Y]
  2532.         shr     eax, 1
  2533.         mov     [MOUSE_Y], ax
  2534.         call    wakeup_osloop
  2535. ;        ret
  2536. ;* mouse centered - end code- Mario79
  2537.         xor     eax, eax
  2538.         and     [esp+32], eax
  2539. ;        pop   eax
  2540.         ret
  2541. ;------------------------------------------------------------------------------
  2542. align 4
  2543. sysfn_mouse_acceleration: ; 18.19 = set/get mouse features
  2544.         test    ecx, ecx; get mouse speed factor
  2545.         jnz     .set_mouse_acceleration
  2546.         xor     eax, eax
  2547.         mov     ax, [mouse_speed_factor]
  2548.         mov     [esp+32], eax
  2549.         ret
  2550.  .set_mouse_acceleration:
  2551. ;     cmp  ecx,1  ; set mouse speed factor
  2552.         dec     ecx
  2553.         jnz     .get_mouse_delay
  2554.         mov     [mouse_speed_factor], dx
  2555.         ret
  2556.  .get_mouse_delay:
  2557. ;     cmp  ecx,2  ; get mouse delay
  2558.         dec     ecx
  2559.         jnz     .set_mouse_delay
  2560.         mov     eax, [mouse_delay]
  2561.         mov     [esp+32], eax
  2562.         ret
  2563.  .set_mouse_delay:
  2564. ;     cmp  ecx,3  ; set mouse delay
  2565.         dec     ecx
  2566.         jnz     .set_pointer_position
  2567.         mov     [mouse_delay], edx
  2568.         ret
  2569.  .set_pointer_position:
  2570. ;     cmp  ecx,4  ; set mouse pointer position
  2571.         dec     ecx
  2572.         jnz     .set_mouse_button
  2573.         cmp     dx, word[Screen_Max_Y]
  2574.         ja      .end
  2575.         rol     edx, 16
  2576.         cmp     dx, word[Screen_Max_X]
  2577.         ja      .end
  2578.         mov     [MOUSE_X], edx
  2579.         mov     [mouse_active], 1
  2580.         call    wakeup_osloop
  2581.         ret
  2582.  .set_mouse_button:
  2583. ;     cmp   ecx,5  ; set mouse button features
  2584.         dec     ecx
  2585.         jnz     .end
  2586.         mov     [BTN_DOWN], dl
  2587.         mov     [mouse_active], 1
  2588.         call    wakeup_osloop
  2589.  .end:
  2590.         ret
  2591. ;------------------------------------------------------------------------------
  2592. sysfn_getfreemem:
  2593.         mov     eax, [pg_data.pages_free]
  2594.         shl     eax, 2
  2595.         mov     [esp+32], eax
  2596.         ret
  2597. ;------------------------------------------------------------------------------
  2598. sysfn_getallmem:
  2599.         mov     eax, [MEM_AMOUNT]
  2600.         shr     eax, 10
  2601.         mov     [esp+32], eax
  2602.         ret
  2603. ;------------------------------------------------------------------------------
  2604. sysfn_pid_to_slot:
  2605.         mov     eax, ecx
  2606.         call    pid_to_slot
  2607.         mov     [esp+32], eax
  2608.         ret
  2609. ;------------------------------------------------------------------------------
  2610. sysfn_min_rest_window:
  2611.         pushad
  2612.         mov     eax, edx ; ebx - operating
  2613.         shr     ecx, 1
  2614.         jnc     @f
  2615.         call    pid_to_slot
  2616. @@:
  2617.         or      eax, eax ; eax - number of slot
  2618.         jz      .error
  2619.         cmp     eax, 255    ; varify maximal slot number
  2620.         ja      .error
  2621.         movzx   eax, word [WIN_STACK + eax*2]
  2622.         shr     ecx, 1
  2623.         jc      .restore
  2624.  ; .minimize:
  2625.         call    minimize_window
  2626.         jmp     .exit
  2627. .restore:
  2628.         call    restore_minimized_window
  2629. .exit:
  2630.         popad
  2631.         xor     eax, eax
  2632.         mov     [esp+32], eax
  2633.         ret
  2634. .error:
  2635.         popad
  2636.         xor     eax, eax
  2637.         dec     eax
  2638.         mov     [esp+32], eax
  2639.         ret
  2640. ;------------------------------------------------------------------------------
  2641. sysfn_min_windows:
  2642.         call    minimize_all_window
  2643.         mov     [esp+32], eax
  2644.         call    change_task
  2645.         ret
  2646. ;------------------------------------------------------------------------------
  2647. sysfn_set_screen_sizes:
  2648.         cmp     [SCR_MODE], word 0x13
  2649.         jbe     .exit
  2650.  
  2651.         cmp     [_display.select_cursor], select_cursor
  2652.         jne     .exit
  2653.  
  2654.         cmp     ecx, [display_width_standard]
  2655.         ja      .exit
  2656.  
  2657.         cmp     edx, [display_height_standard]
  2658.         ja      .exit
  2659.  
  2660.         pushfd
  2661.         cli
  2662.         mov     eax, ecx
  2663.         mov     ecx, [_display.pitch]
  2664.         mov     [_display.width], eax
  2665.         dec     eax
  2666.         mov     [_display.height], edx
  2667.         dec     edx
  2668. ; eax - new Screen_Max_X
  2669. ; edx - new Screen_Max_Y
  2670.         mov     [do_not_touch_winmap], 1
  2671.         call    set_screen
  2672.         mov     [do_not_touch_winmap], 0
  2673.         popfd
  2674.         call    change_task
  2675. .exit:
  2676.         ret
  2677. ;------------------------------------------------------------------------------
  2678. uglobal
  2679. screen_workarea RECT
  2680. display_width_standard dd 0
  2681. display_height_standard dd 0
  2682. do_not_touch_winmap db 0
  2683. window_minimize db 0
  2684. sound_flag      db 0
  2685.  
  2686. endg
  2687.  
  2688. UID_NONE=0
  2689. UID_MENUETOS=1   ;official
  2690. UID_KOLIBRI=2    ;russian
  2691.  
  2692. iglobal
  2693. version_inf:
  2694.         db 0,7,7,0  ; version 0.7.7.0
  2695.         db 0
  2696. .rev    dd __REV__
  2697. version_end:
  2698. endg
  2699. ;------------------------------------------------------------------------------
  2700. align 4
  2701. sys_cachetodiskette:
  2702.         cmp     ebx, 1
  2703.         jb      .no_floppy_save
  2704.         cmp     ebx, 2
  2705.         ja      .no_floppy_save
  2706.         call    save_image
  2707.         mov     [esp + 32], eax
  2708.         ret
  2709. .no_floppy_save:
  2710.         mov     [esp + 32], dword 1
  2711.         ret
  2712. ;------------------------------------------------------------------------------
  2713. uglobal
  2714. ;  bgrchanged  dd  0x0
  2715. align 4
  2716. bgrlockpid dd 0
  2717. bgrlock db 0
  2718. endg
  2719. ;------------------------------------------------------------------------------
  2720. align 4
  2721. sys_background:
  2722.         cmp     ebx, 1                     ; BACKGROUND SIZE
  2723.         jnz     nosb1
  2724.         test    ecx, ecx
  2725.         jz      sbgrr
  2726.  
  2727.         test    edx, edx
  2728.         jz      sbgrr
  2729. ;--------------------------------------
  2730. align 4
  2731. @@:
  2732. ;;Maxis use atomic bts for mutexes  4.4.2009
  2733.         bts     dword [bgrlock], 0
  2734.         jnc     @f
  2735.         call    change_task
  2736.         jmp     @b
  2737. ;--------------------------------------
  2738. align 4
  2739. @@:
  2740.         mov     [BgrDataWidth], ecx
  2741.         mov     [BgrDataHeight], edx
  2742. ;    mov   [bgrchanged],1
  2743.  
  2744.         pushad
  2745. ; return memory for old background
  2746.         mov     eax, [img_background]
  2747.         cmp     eax, static_background_data
  2748.         jz      @f
  2749.         stdcall kernel_free, eax
  2750. ;--------------------------------------
  2751. align 4
  2752. @@:
  2753. ; calculate RAW size
  2754.         xor     eax, eax
  2755.         inc     eax
  2756.         cmp     [BgrDataWidth], eax
  2757.         jae     @f
  2758.         mov     [BgrDataWidth], eax
  2759. ;--------------------------------------
  2760. align 4
  2761. @@:
  2762.         cmp     [BgrDataHeight], eax
  2763.         jae     @f
  2764.         mov     [BgrDataHeight], eax
  2765. ;--------------------------------------
  2766. align 4
  2767. @@:
  2768.         mov     eax, [BgrDataWidth]
  2769.         imul    eax, [BgrDataHeight]
  2770.         lea     eax, [eax*3]
  2771. ; it is reserved with aligned to the boundary of 4 KB pages,
  2772. ; otherwise there may be exceptions a page fault for vesa20_drawbackground_tiled
  2773. ; because the 32 bit read is used for  high performance: "mov eax,[esi]"
  2774.         shr     eax, 12
  2775.         inc     eax
  2776.         shl     eax, 12
  2777.         mov     [mem_BACKGROUND], eax
  2778. ; get memory for new background
  2779.         stdcall kernel_alloc, eax
  2780.         test    eax, eax
  2781.         jz      .memfailed
  2782.         mov     [img_background], eax
  2783.         jmp     .exit
  2784. ;--------------------------------------
  2785. align 4
  2786. .memfailed:
  2787. ; revert to static monotone data
  2788.         mov     [img_background], static_background_data
  2789.         xor     eax, eax
  2790.         inc     eax
  2791.         mov     [BgrDataWidth], eax
  2792.         mov     [BgrDataHeight], eax
  2793.         mov     [mem_BACKGROUND], 4
  2794. ;--------------------------------------
  2795. align 4
  2796. .exit:
  2797.         popad
  2798.         mov     [bgrlock], 0
  2799. ;--------------------------------------
  2800. align 4
  2801. sbgrr:
  2802.         ret
  2803. ;------------------------------------------------------------------------------
  2804. align 4
  2805. nosb1:
  2806.         cmp     ebx, 2                     ; SET PIXEL
  2807.         jnz     nosb2
  2808.  
  2809.         mov     eax, [img_background]
  2810.         test    ecx, ecx
  2811.         jz      @f
  2812.         cmp     eax, static_background_data
  2813.         jz      .ret
  2814. ;--------------------------------------
  2815. align 4
  2816. @@:
  2817.         mov     ebx, [mem_BACKGROUND]
  2818.         add     ebx, 4095
  2819.         and     ebx, -4096
  2820.         sub     ebx, 4
  2821.         cmp     ecx, ebx
  2822.         ja      .ret
  2823.  
  2824.         mov     ebx, [eax+ecx]
  2825.         and     ebx, 0xFF000000;255*256*256*256
  2826.         and     edx, 0x00FFFFFF;255*256*256+255*256+255
  2827.         add     edx, ebx
  2828.         mov     [eax+ecx], edx
  2829. ;--------------------------------------
  2830. align 4
  2831. .ret:
  2832.         ret
  2833. ;------------------------------------------------------------------------------
  2834. align 4
  2835. nosb2:
  2836.         cmp     ebx, 3                     ; DRAW BACKGROUND
  2837.         jnz     nosb3
  2838. ;--------------------------------------
  2839. align 4
  2840. draw_background_temp:
  2841.         mov     [background_defined], 1
  2842.         call    force_redraw_background
  2843. ;--------------------------------------
  2844. align 4
  2845. nosb31:
  2846.         ret
  2847. ;------------------------------------------------------------------------------
  2848. align 4
  2849. nosb3:
  2850.         cmp     ebx, 4                     ; TILED / STRETCHED
  2851.         jnz     nosb4
  2852.         cmp     ecx, [BgrDrawMode]
  2853.         je      nosb41
  2854.         mov     [BgrDrawMode], ecx
  2855. ;--------------------------------------
  2856. align 4
  2857. nosb41:
  2858.         ret
  2859. ;------------------------------------------------------------------------------
  2860. align 4
  2861. nosb4:
  2862.         cmp     ebx, 5                     ; BLOCK MOVE TO BGR
  2863.         jnz     nosb5
  2864.         cmp     [img_background], static_background_data
  2865.         jnz     @f
  2866.         test    edx, edx
  2867.         jnz     .fin
  2868.         cmp     esi, 4
  2869.         ja      .fin
  2870. ;--------------------------------------
  2871. align 4
  2872. @@:
  2873.   ; bughere
  2874.         mov     eax, ecx
  2875.         mov     ebx, edx
  2876.         add     ebx, [img_background];IMG_BACKGROUND
  2877.         mov     ecx, esi
  2878.         call    memmove
  2879. ;--------------------------------------
  2880. align 4
  2881. .fin:
  2882.         ret
  2883. ;------------------------------------------------------------------------------
  2884. align 4
  2885. nosb5:
  2886.         cmp     ebx, 6
  2887.         jnz     nosb6
  2888. ;--------------------------------------