Subversion Repositories Kolibri OS

Rev

Rev 4429 | Blame | Compare with Previous | Last modification | View Log | Download | RSS feed

  1. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  2. ;;                                                              ;;
  3. ;; Copyright (C) KolibriOS team 2004-2012. All rights reserved. ;;
  4. ;; Copyright (C) MenuetOS 2000-2004 Ville Mikael Turjanmaa      ;;
  5. ;; Distributed under terms of the GNU General Public License    ;;
  6. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  7.  
  8. $Revision: 3565 $
  9.  
  10. WINDOW_MOVE_AND_RESIZE_FLAGS = \
  11.   mouse.WINDOW_RESIZE_N_FLAG + \
  12.   mouse.WINDOW_RESIZE_W_FLAG + \
  13.   mouse.WINDOW_RESIZE_S_FLAG + \
  14.   mouse.WINDOW_RESIZE_E_FLAG + \
  15.   mouse.WINDOW_MOVE_FLAG
  16.  
  17. uglobal
  18. align 4
  19.   event_start   dd ?
  20.   event_end     dd ?
  21.   event_uid     dd 0
  22. endg
  23. EV_SPACE   = 512
  24. FreeEvents = event_start-EVENT.fd    ; "виртуальный" event, используются только поля:
  25.                                      ;  FreeEvents.fd=event_start и FreeEvents.bk=event_end
  26. ;-----------------------------------------------------------------------------
  27. align 4
  28. init_events:                                       ;; used from kernel.asm
  29.         stdcall kernel_alloc, EV_SPACE*sizeof.EVENT
  30.         or      eax, eax
  31.         jz      .fail
  32.       ; eax - current event, ebx - previos event below
  33.         mov     ecx, EV_SPACE        ; current - in allocated space
  34.         mov     ebx, FreeEvents      ; previos - начало списка
  35.         push    ebx                  ; оно же и конец потом будет
  36. ;--------------------------------------
  37. align 4
  38. @@:
  39.         mov     [ebx+EVENT.fd], eax
  40.         mov     [eax+EVENT.bk], ebx
  41.         mov     ebx, eax             ; previos <- current
  42.         add     eax, sizeof.EVENT    ; new current
  43.         loop    @b
  44.         pop     eax                  ; вот оно концом и стало
  45.         mov     [ebx+EVENT.fd], eax
  46.         mov     [eax+EVENT.bk], ebx
  47. ;--------------------------------------
  48. align 4
  49. .fail:
  50.         ret
  51. ;-----------------------------------------------------------------------------
  52. EVENT_WATCHED   equ 0x10000000 ;бит 28
  53. EVENT_SIGNALED   equ 0x20000000 ;бит 29
  54. MANUAL_RESET     equ 0x40000000 ;бит 30
  55. MANUAL_DESTROY   equ 0x80000000 ;бит 31
  56. ;-----------------------------------------------------------------------------
  57. align 4
  58. create_event:                                      ;; EXPORT use
  59. ;info:
  60. ;   Переносим EVENT из списка FreeEvents в список ObjList текущего слота
  61. ;   EVENT.state устанавливаем из ecx, EVENT.code косвенно из esi (если esi<>0)
  62. ;param:
  63. ;   esi - event data
  64. ;   ecx - flags
  65. ;retval:
  66. ;   eax - event (=0 => fail)
  67. ;   edx - uid
  68. ;scratched: ebx,ecx,esi,edi
  69.         mov     ebx, [current_slot]
  70.         add     ebx, APP_OBJ_OFFSET
  71.         mov     edx, [TASK_BASE]
  72.         mov     edx, [edx+TASKDATA.pid]
  73.         pushfd
  74.         cli
  75. ;--------------------------------------
  76. align 4
  77. set_event:                                         ;; INTERNAL use !!! don't use for Call
  78. ;info:
  79. ;   Берем новый event из FreeEvents, заполняем его поля, как указано в ecx,edx,esi
  80. ;   и устанавливаем в список, указанный в ebx.
  81. ;   Возвращаем сам event (в eax), и его uid (в edx)
  82. ;param:
  83. ;   ebx - start-chain "virtual" event for entry new event Right of him
  84. ;   ecx - flags      (copied to EVENT.state)
  85. ;   edx - pid        (copied to EVENT.pid)
  86. ;   esi - event data (copied to EVENT.code indirect, =0 => skip)
  87. ;retval:
  88. ;   eax - event (=0 => fail)
  89. ;   edx - uid
  90. ;scratched: ebx,ecx,esi,edi
  91.         mov     eax, FreeEvents
  92.         cmp     eax, [eax+EVENT.fd]
  93.         jne     @f  ; not empty ???
  94.         pushad
  95.         call    init_events
  96.         popad
  97.         jz      RemoveEventTo.break ; POPF+RET
  98. ;--------------------------------------
  99. align 4
  100. @@:
  101.         mov     eax, [eax+EVENT.fd]
  102.         mov     [eax+EVENT.magic], 'EVNT'
  103.         mov     [eax+EVENT.destroy], destroy_event.internal
  104.         mov     [eax+EVENT.state], ecx
  105.         mov     [eax+EVENT.pid], edx
  106.         inc     [event_uid]
  107.         Mov     [eax+EVENT.id],edx,[event_uid]
  108.         or      esi, esi
  109.         jz      RemoveEventTo
  110.         lea     edi, [eax+EVENT.code]
  111.         mov     ecx, (sizeof.EVENT -EVENT.code)/4
  112.         cld
  113.         rep movsd
  114. ;--------------------------------------
  115. align 4
  116. RemoveEventTo:                                     ;; INTERNAL use !!! don't use for Call
  117. ;param:
  118. ;   eax - указатель на event, КОТОРЫЙ вставляем
  119. ;   ebx - указатель на event, ПОСЛЕ которого вставляем
  120. ;scratched: ebx,ecx
  121.         mov     ecx, eax             ; ecx=eax=Self,      ebx=NewLeft
  122.         xchg    ecx, [ebx+EVENT.fd]  ; NewLeft.fd=Self,   ecx=NewRight
  123.         cmp     eax, ecx             ; стоп, себе думаю...
  124.         je      .break               ; - а не дурак ли я?
  125.         mov     [ecx+EVENT.bk], eax  ; NewRight.bk=Self
  126.         xchg    ebx, [eax+EVENT.bk]  ; Self.bk=NewLeft,   ebx=OldLeft
  127.         xchg    ecx, [eax+EVENT.fd]  ; Self.fd=NewRight,  ecx=OldRight
  128.         mov     [ebx+EVENT.fd], ecx  ; OldLeft.fd=OldRight
  129.         mov     [ecx+EVENT.bk], ebx  ; OldRight.bk=OldLeft
  130. ;--------------------------------------
  131. align 4
  132. .break:
  133.         popfd
  134.         ret
  135. ;-----------------------------------------------------------------------------
  136. align 4
  137. NotDummyTest:                                      ;; INTERNAL use (not returned for fail !!!)
  138.         pop     edi
  139.         call    DummyTest ; not returned for fail !!!
  140.         mov     ebx, eax
  141.         mov     eax, [ebx+EVENT.pid]
  142.         push    edi
  143. ;--------------------------------------
  144. align 4
  145. .small: ; криво как-то...
  146.         pop     edi
  147.         pushfd
  148.         cli
  149.         call    pid_to_slot ; saved all registers (eax - retval)
  150.         shl     eax, 8
  151.         jz      RemoveEventTo.break ; POPF+RET
  152.         jmp     edi ; штатный возврат
  153. ;-----------------------------------------------------------------------------
  154. align 4
  155. raise_event:                                       ;; EXPORT use
  156. ;info:
  157. ;   Устанавливаем данные EVENT.code
  158. ;   Если там флаг EVENT_SIGNALED уже активен - больше ничего
  159. ;   Иначе: этот флаг взводится, за исключением случая наличия флага EVENT_WATCHED в edx
  160. ;   В этом случае EVENT_SIGNALED взводится лишь при наличие EVENT_WATCHED в самом событии
  161. ;param:
  162. ;   eax - event
  163. ;   ebx - uid (for Dummy testing)
  164. ;   edx - flags
  165. ;   esi - event data (=0 => skip)
  166. ;scratched: ebx,ecx,esi,edi
  167.         call    NotDummyTest ; not returned for fail !!!
  168.         or      esi, esi
  169.         jz      @f
  170.         lea     edi, [ebx+EVENT.code]
  171.         mov     ecx, (sizeof.EVENT -EVENT.code)/4
  172.         cld
  173.         rep movsd
  174. ;--------------------------------------
  175. align 4
  176. @@:
  177.         test    byte[ebx+EVENT.state+3], EVENT_SIGNALED shr 24
  178.         jnz     RemoveEventTo.break  ; POPF+RET
  179.         bt      edx, 28 ;EVENT_WATCHED
  180.         jnc     @f
  181.         test    byte[ebx+EVENT.state+3], EVENT_WATCHED shr 24
  182.         jz      RemoveEventTo.break  ; POPF+RET
  183. ;--------------------------------------
  184. align 4
  185. @@:
  186.         or      byte[ebx+EVENT.state+3], EVENT_SIGNALED shr 24
  187.         add     eax, SLOT_BASE+APP_EV_OFFSET
  188.         xchg    eax, ebx
  189.         jmp     RemoveEventTo
  190. ;-----------------------------------------------------------------------------
  191. align 4
  192. clear_event:                                       ;; EXPORT use
  193. ;info:
  194. ;
  195. ;param:
  196. ;   eax - event
  197. ;   ebx - uid (for Dummy testing)
  198. ;scratched: ebx,ecx
  199.         call    NotDummyTest ; not returned for fail !!!
  200.         add     eax, SLOT_BASE+APP_OBJ_OFFSET
  201.         and     byte[ebx+EVENT.state+3], not((EVENT_SIGNALED+EVENT_WATCHED)shr 24)
  202.         xchg    eax, ebx
  203.         jmp     RemoveEventTo
  204. ;-----------------------------------------------------------------------------
  205. align 4
  206. send_event:                                        ;; EXPORT use
  207. ;info:
  208. ;   Создает новый EVENT (вытаскивает из списка FreeEvents) в списке EventList
  209. ;   целевого слота (eax=pid), с данными из esi косвенно, и state=EVENT_SIGNALED
  210. ;param:
  211. ;   eax - slots pid, to sending new event
  212. ;   esi - pointer to sending data (in code field of new event)
  213. ;retval:
  214. ;   eax - event (=0 => fail)
  215. ;   edx - uid
  216. ;warning:
  217. ;   may be used as CDECL with such prefix...
  218. ;       mov     esi,[esp+8]
  219. ;       mov     eax,[esp+4]
  220. ;   but not as STDCALL :(
  221. ;scratched: ebx,ecx,esi,edi
  222.         mov     edx, eax
  223.         call    NotDummyTest.small ; not returned for fail !!!
  224.         lea     ebx, [eax+SLOT_BASE+APP_EV_OFFSET]
  225.         mov     ecx, EVENT_SIGNALED
  226.         jmp     set_event
  227. ;-----------------------------------------------------------------------------
  228. align 4
  229. DummyTest:                                         ;; INTERNAL use (not returned for fail !!!)
  230. ;param:
  231. ;   eax - event
  232. ;   ebx - uid (for Dummy testing)
  233.         cmp     [eax+EVENT.magic], 'EVNT'
  234.         jne     @f
  235.         cmp     [eax+EVENT.id], ebx
  236.         je      .ret
  237. ;--------------------------------------
  238. align 4
  239. @@:
  240.         pop     eax
  241.         xor     eax, eax
  242. ;--------------------------------------
  243. align 4
  244. .ret:
  245.         ret
  246. ;-----------------------------------------------------------------------------
  247. align 4
  248. Wait_events:
  249.         or      ebx, -1; infinite timeout
  250. ;--------------------------------------
  251. align 4
  252. Wait_events_ex:
  253. ;info:
  254. ;   Ожидание "абстрактного" события через перевод слота в 5-ю позицию.
  255. ;   Абстрактность заключена в том, что факт события определяется функцией APPDATA.wait_test,
  256. ;   которая задается клиентом и может быть фактически любой.
  257. ;   Это позволяет shed-у надежно определить факт события, и не совершать "холостых" переключений,
  258. ;   предназначенных для разборок типа "свой/чужой" внутри задачи.
  259. ;param:
  260. ;   edx - wait_test, клиентская ф-я тестирования (адрес кода)
  261. ;   ecx - wait_param, дополнительный параметр, возможно необходимый для [wait_test]
  262. ;   ebx - wait_timeout
  263. ;retval:
  264. ;   eax - результат вызова [wait_test] (=0 => timeout)
  265. ;scratched: esi
  266.         mov     esi, [current_slot]
  267.         mov     [esi+APPDATA.wait_param], ecx
  268.         pushad
  269.         mov     ebx, esi;пока это вопрос, чего куды сувать..........
  270.         pushfd  ; это следствие общей концепции: пусть ф-я тестирования имеет
  271.         cli     ; право рассчитывать на закрытые прерывания, как при вызове из shed
  272.         call    edx
  273.         popfd
  274.         mov     [esp+28], eax
  275.         popad
  276.         or      eax, eax
  277.         jnz     @f   ;RET
  278.         mov     [esi+APPDATA.wait_test], edx
  279.         mov     [esi+APPDATA.wait_timeout], ebx
  280.         Mov     [esi+APPDATA.wait_begin],eax,[timer_ticks]
  281.         mov     eax, [TASK_BASE]
  282.         mov     [eax+TASKDATA.state], 5
  283.         call    change_task
  284.         mov     eax, [esi+APPDATA.wait_param]
  285. ;--------------------------------------
  286. align 4
  287. @@:
  288.         ret
  289. ;-----------------------------------------------------------------------------
  290. align 4
  291. wait_event:                                        ;; EXPORT use
  292. ;info:
  293. ;   Ожидание флага EVENT_SIGNALED в совершенно конкретном Event
  294. ;   (устанавливаемого, надо полагать, через raise_event)
  295. ;   При активном флаге MANUAL_RESET - больше ничего
  296. ;   Иначе: флаги EVENT_SIGNALED и EVENT_WATCHED у полученного события сбрасываются,
  297. ;   и, при активном MANUAL_DESTROY - перемещается в список ObjList текущего слота,
  298. ;   а при не активном - уничтожается штатно (destroy_event.internal)
  299. ;param:
  300. ;   eax - event
  301. ;   ebx - uid (for Dummy testing)
  302. ;scratched: ecx,edx,esi
  303.         call    DummyTest
  304.         mov     ecx, eax             ; wait_param
  305.         mov     edx, get_event_alone ; wait_test
  306.         call    Wait_events          ; timeout ignored
  307.         jmp     wait_finish
  308. ;-----------------------------------------------------------------------------
  309. align 4
  310. wait_event_timeout:
  311. ;param:
  312. ;   eax - event
  313. ;   ebx - uid (for Dummy testing)
  314. ;   ecx - timeout in timer ticks
  315. ;retval:
  316. ;   eax - EVENT handle or 0 if timeout
  317.         call    DummyTest
  318.         mov     ebx, ecx
  319.         mov     ecx, eax             ; wait_param
  320.         mov     edx, get_event_alone ; wait_test
  321.         call    Wait_events_ex
  322.         test    eax, eax
  323.         jnz     wait_finish
  324.         ret
  325. ;-----------------------------------------------------------------------------
  326. align 4
  327. get_event_ex:                                      ;; f68:14
  328. ;info:
  329. ;   Ожидание любого события в очереди EventList текущего слота
  330. ;   Данные события code - копируются в память приложения (косвенно по edi)
  331. ;   При активном флаге MANUAL_RESET - больше ничего
  332. ;   Иначе: флаги EVENT_SIGNALED и EVENT_WATCHED у полученного события сбрасываются,
  333. ;   и, при активном MANUAL_DESTROY - перемещается в список ObjList текущего слота,
  334. ;   а при не активном - уничтожается штатно (destroy_event.internal)
  335. ;param:
  336. ;   edi - адрес в коде приложения для копирования данных из EVENT.code
  337. ;retval:
  338. ;   eax - собственно EVENT (будем называть это его хэндлом)
  339. ;scratched: ebx,ecx,edx,esi,edi
  340.         mov     edx, get_event_queue ; wait_test
  341.         call    Wait_events          ; timeout ignored
  342.         lea     esi, [eax+EVENT.code]
  343.         mov     ecx, (sizeof.EVENT-EVENT.code)/4
  344.         cld
  345.         rep movsd
  346.         mov     byte[edi-(sizeof.EVENT-EVENT.code)+2], cl;clear priority field
  347. ;--------------------------------------
  348. align 4
  349. wait_finish:
  350.         test    byte[eax+EVENT.state+3], MANUAL_RESET shr 24
  351.         jnz     get_event_queue.ret  ; RET
  352.         and     byte[eax+EVENT.state+3], not((EVENT_SIGNALED+EVENT_WATCHED)shr 24)
  353.         test    byte[eax+EVENT.state+3], MANUAL_DESTROY shr 24
  354.         jz      destroy_event.internal
  355.         mov     ebx, [current_slot]
  356.         add     ebx, APP_OBJ_OFFSET
  357.         pushfd
  358.         cli
  359.         jmp     RemoveEventTo
  360. ;-----------------------------------------------------------------------------
  361. align 4
  362. destroy_event:                                     ;; EXPORT use
  363. ;info:
  364. ;   Переносим EVENT в список FreeEvents, чистим поля magic,destroy,pid,id
  365. ;param:
  366. ;   eax - event
  367. ;   ebx - uid (for Dummy testing)
  368. ;retval:
  369. ;   eax - адрес объекта EVENT (=0 => fail)
  370. ;scratched: ebx,ecx
  371.         call    DummyTest ; not returned for fail !!!
  372. ;--------------------------------------
  373. align 4
  374. .internal:
  375.         xor     ecx, ecx  ; clear common header
  376.         pushfd
  377.         cli
  378.         mov     [eax+EVENT.magic], ecx
  379.         mov     [eax+EVENT.destroy], ecx
  380.         mov     [eax+EVENT.pid], ecx
  381.         mov     [eax+EVENT.id], ecx
  382.         mov     ebx, FreeEvents
  383.         jmp     RemoveEventTo
  384. ;-----------------------------------------------------------------------------
  385. align 4
  386. get_event_queue:
  387. ;info:
  388. ;   клиентская ф-я тестирования для get_event_ex
  389. ;warning:
  390. ;  -don't use [TASK_BASE],[current_slot],[CURRENT_TASK] - it is not for your slot
  391. ;  -may be assumed, that interrupt are disabled
  392. ;  -it is not restriction for scratched registers
  393. ;param:
  394. ;   ebx - адрес APPDATA слота тестирования
  395. ;retval:
  396. ;   eax - адрес объекта EVENT (=0 => fail)
  397.         add     ebx, APP_EV_OFFSET
  398.         mov     eax, [ebx+APPOBJ.bk] ; выбираем с конца, по принципу FIFO
  399.         cmp     eax, ebx ; empty ???
  400.         je      get_event_alone.ret0
  401. ;--------------------------------------
  402. align 4
  403. .ret:
  404.         ret
  405. ;-----------------------------------------------------------------------------
  406. align 4
  407. get_event_alone:
  408. ;info:
  409. ;   клиентская ф-я тестирования для wait_event
  410. ;warning:
  411. ;  -don't use [TASK_BASE],[current_slot],[CURRENT_TASK] - it is not for your slot
  412. ;  -may be assumed, that interrupt are disabled
  413. ;  -it is not restriction for scratched registers
  414. ;param:
  415. ;   ebx - адрес APPDATA слота тестирования
  416. ;retval:
  417. ;   eax - адрес объекта EVENT (=0 => fail)
  418.         mov     eax, [ebx+APPDATA.wait_param]
  419.         test    byte[eax+EVENT.state+3], EVENT_SIGNALED shr 24
  420.         jnz     .ret
  421.         or      byte[eax+EVENT.state+3], EVENT_WATCHED shr 24
  422. ;--------------------------------------
  423. align 4
  424. .ret0:
  425.         xor     eax, eax; NO event!!!
  426. ;--------------------------------------
  427. align 4
  428. .ret:
  429.         ret
  430. ;-----------------------------------------------------------------------------
  431. align 4
  432. sys_sendwindowmsg:                                 ;; f72
  433.         dec     ebx
  434.         jnz     .ret ;subfunction==1 ?
  435.         pushfd
  436.         cli
  437.         sub     ecx, 2
  438.         je      .sendkey
  439.         dec     ecx
  440.         jnz     .retf
  441. ;--------------------------------------
  442. align 4
  443. .sendbtn:
  444.         cmp     byte[BTN_COUNT], 1
  445.         jae     .result ;overflow
  446.         inc     byte[BTN_COUNT]
  447.         shl     edx, 8
  448.         mov     [BTN_BUFF], edx
  449.         jmp     .result
  450. ;--------------------------------------
  451. align 4
  452. .sendkey:
  453.         movzx   eax, byte[KEY_COUNT]
  454.         cmp     al, 120
  455.         jae     .result ;overflow
  456.         inc     byte[KEY_COUNT]
  457.         mov     [KEY_BUFF+eax], dl
  458. ; store empty scancode
  459.         add     eax, 120+2
  460.         mov     [KEY_BUFF+eax], byte 0
  461.         sub     eax, 120+2
  462. ;--------------------------------------
  463. align 4
  464. .result:
  465.         setae   byte[esp+32+4] ;считаем, что исходно: dword[esp+32+4]==72
  466. ;--------------------------------------
  467. align 4
  468. .retf:
  469.         popfd
  470. ;--------------------------------------
  471. align 4
  472. .ret:
  473.         ret
  474. ;-----------------------------------------------------------------------------
  475. align 4
  476. sys_getevent:                                      ;; f11
  477.         mov     ebx, [current_slot];пока это вопрос, чего куды сувать..........
  478.         pushfd  ; это следствие общей концепции: пусть ф-я тестирования имеет
  479.         cli     ; право рассчитывать на закрытые прерывания, как при вызове из shed
  480.         call    get_event_for_app
  481.         popfd
  482.         mov     [esp+32], eax
  483.         ret
  484. ;-----------------------------------------------------------------------------
  485. align 4
  486. sys_waitforevent:                                  ;; f10
  487.         or      ebx, -1; infinite timeout
  488. ;--------------------------------------
  489. align 4
  490. sys_wait_event_timeout:                            ;; f23
  491.         call    unprotect_from_terminate
  492.         mov     edx, get_event_for_app; wait_test
  493.         call    Wait_events_ex        ; ebx - timeout
  494.         mov     [esp+32], eax
  495.         call    protect_from_terminate
  496.         ret
  497. ;-----------------------------------------------------------------------------
  498. align 4
  499. get_event_for_app:                                 ;; used from f10,f11,f23
  500. ;info:
  501. ;   клиентская ф-я тестирования для приложений (f10,f23)
  502. ;warning:
  503. ;  -don't use [TASK_BASE],[current_slot],[CURRENT_TASK] - it is not for your slot
  504. ;  -may be assumed, that interrupt are disabled
  505. ;  -it is not restriction for scratched registers
  506. ;param:
  507. ;   ebx - адрес APPDATA слота тестирования
  508. ;retval:
  509. ;   eax - номер события (=0 => no events)
  510.         movzx   edi, bh               ; bh  is assumed as [CURRENT_TASK]
  511.         shl     edi, 5
  512.         add     edi, CURRENT_TASK     ; edi is assumed as [TASK_BASE]
  513.         mov     ecx, [edi+TASKDATA.event_mask]
  514.         and     ecx, 0x7FFFFFFF
  515. ;--------------------------------------
  516. align 4
  517. .loop: ; пока не исчерпаем все биты маски
  518.         bsr     eax, ecx       ; находим ненулевой бит маски (31 -> 0)
  519.         jz      .no_events     ; исчерпали все биты маски, но ничего не нашли ???
  520.         btr     ecx, eax       ; сбрасываем проверяемый бит маски
  521.        ; переходим на обработчик этого (eax) бита
  522.         cmp     eax, 10
  523.         jae     .loop          ; eax=[10..31], ignored (event 11...32)
  524.  
  525.         cmp     eax, 3
  526.         je      .loop          ; eax=3, ignored (event 4)
  527.  
  528.         cmp     eax, 4
  529.         je      .FlagAutoReset  ; eax=4, retvals=eax+1 (event 5)
  530.  
  531.         cmp     eax, 5
  532.         je      .mouse_check  ; eax=5, retvals=eax+1 (event 6)
  533.  
  534.         ja      .FlagAutoReset ; eax=[6..9], retvals=eax+1 (event 7...10)
  535.  
  536.         cmp     eax, 1
  537.         jae     .BtKy          ; eax=[1,2],  retvals=eax+1 (event 2,3)
  538. ;--------------------------------------
  539. align 4
  540. .WndRedraw:                    ; eax=0, retval WndRedraw=1
  541.         cmp     [edi-twdw+WDATA.fl_redraw], al;al==0
  542.         jne     .result
  543.         jmp     .loop
  544. ;--------------------------------------
  545. align 4
  546. .no_events:
  547.         xor     eax, eax
  548.         ret
  549. ;--------------------------------------
  550. align 4
  551. .mouse_check:    ; Mouse 5+1=6
  552.         push    eax
  553.         mov     eax, [TASK_BASE]
  554.         mov     eax, [eax + TASKDATA.event_mask]
  555.         test    eax, 0x80000000 ; bit 31: active/inactive filter f.40
  556.         jz      @f
  557.         pop     eax
  558.         jmp     .FlagAutoReset
  559. ;--------------------------------------
  560. align 4
  561. @@:
  562. ; If the window is captured and moved by the user, then no mouse events!!!
  563.         mov     al, [mouse.active_sys_window.action]
  564.         and     al, WINDOW_MOVE_AND_RESIZE_FLAGS
  565.         test    al, al
  566.         pop     eax
  567.         jnz     .loop
  568. ;--------------------------------------
  569. align 4
  570. .FlagAutoReset: ; retvals: BgrRedraw=5, IPC=7, Stack=8, Debug=9
  571.         btr     [ebx+APPDATA.event_mask], eax
  572.         jnc     .loop
  573. ;--------------------------------------
  574. align 4
  575. .result:      ; retval = eax+1
  576.         inc     eax
  577.         ret
  578. ;--------------------------------------
  579. align 4
  580. .BtKy:
  581.         movzx   edx, bh
  582.         movzx   edx, word[WIN_STACK+edx*2]
  583.         je      .Keys          ; eax=1, retval Keys=2
  584. ;--------------------------------------
  585. align 4
  586. .Buttons:                      ; eax=2, retval Buttons=3
  587.         cmp     byte[BTN_COUNT], 0
  588.         je      .loop          ; empty ???
  589.         cmp     edx, [TASK_COUNT]
  590.         jne     .loop          ; not Top ???
  591.         mov     edx, [BTN_BUFF]
  592.         shr     edx, 8
  593.         cmp     edx, 0xFFFF    ;-ID for Minimize-Button of Form
  594.         jne     .result
  595.         mov     [window_minimize], 1
  596.         call    wakeup_osloop
  597.         dec     byte[BTN_COUNT]
  598.         jmp     .loop
  599. ;--------------------------------------
  600. align 4
  601. .Keys:    ; eax==1
  602.         cmp     edx, [TASK_COUNT]
  603.         jne     @f             ; not Top ???
  604.         cmp     [KEY_COUNT], al; al==1
  605.         jae     .result        ; not empty ???
  606. ;--------------------------------------
  607. align 4
  608. @@:
  609.         mov     edx, hotkey_buffer
  610. ;--------------------------------------
  611. align 4
  612. @@:
  613.         cmp     [edx], bh      ; bh - slot for testing
  614.         je      .result
  615.         add     edx, 8
  616.         cmp     edx, hotkey_buffer+120*8
  617.         jb      @b
  618.         jmp     .loop
  619. ;end.
  620. ;-----------------------------------------------------------------------------
  621.