Subversion Repositories Kolibri OS

Rev

Rev 4429 | Blame | Compare with Previous | Last modification | View Log | Download | RSS feed

  1. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  2. ;;                                                              ;;
  3. ;; Copyright (C) KolibriOS team 2004-2011. All rights reserved. ;;
  4. ;; Distributed under terms of the GNU General Public License    ;;
  5. ;;                                                              ;;
  6. ;;                                                              ;;
  7. ;;  MenuetOS process management, protected ring3                ;;
  8. ;;                                                              ;;
  9. ;;  Distributed under GPL. See file COPYING for details.        ;;
  10. ;;  Copyright 2003 Ville Turjanmaa                              ;;
  11. ;;                                                              ;;
  12. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  13.  
  14. $Revision: 4313 $
  15.  
  16. align 4 ;3A08
  17. build_interrupt_table:
  18.         mov     edi, idts
  19.         mov     esi, sys_int
  20.         mov     ecx, 0x40
  21.         mov     eax, (10001110b shl 24) + os_code
  22.   @@:
  23.         movsw   ;low word of code-entry
  24.         stosd   ;interrupt gate type : os_code selector
  25.         movsw   ;high word of code-entry
  26.         loop    @b
  27.         movsd   ;copy low  dword of trap gate for int 0x40
  28.         movsd   ;copy high dword of trap gate for int 0x40
  29.         lidt    [esi]
  30.         ret
  31.  
  32. iglobal
  33.   align 4
  34.   sys_int:
  35.     ;exception handlers addresses (for interrupt gate construction)
  36.         dd      e0,e1,e2,e3,e4,e5,e6,except_7 ; SEE: core/fpu.inc
  37.         dd      e8,e9,e10,e11,e12,e13,page_fault_exc,e15
  38.         dd      e16, e17,e18, e19
  39.         times   12 dd unknown_interrupt ;int_20..int_31
  40.  
  41.     ;interrupt handlers addresses (for interrupt gate construction)
  42.         ; 0x20 .. 0x2F - IRQ handlers
  43.         dd      irq0, irq_serv.irq_1, irq_serv.irq_2
  44.         dd      irq_serv.irq_3, irq_serv.irq_4
  45.         dd      irq_serv.irq_5,  irq_serv.irq_6,  irq_serv.irq_7
  46.         dd      irq_serv.irq_8,  irq_serv.irq_9,  irq_serv.irq_10
  47.         dd      irq_serv.irq_11, irq_serv.irq_12, irqD, irq_serv.irq_14, irq_serv.irq_15
  48.         dd irq_serv.irq_16
  49.         dd irq_serv.irq_17
  50.         dd irq_serv.irq_18
  51.         dd irq_serv.irq_19
  52.         dd irq_serv.irq_20
  53.         dd irq_serv.irq_21
  54.         dd irq_serv.irq_22
  55.         dd irq_serv.irq_23
  56.  
  57.     times 32 - IRQ_RESERVED dd unknown_interrupt
  58.     ;int_0x40 gate trap (for directly copied)
  59.         dw      i40 and 0xFFFF, os_code, 11101111b shl 8, i40 shr 16
  60.  
  61.   idtreg: ; data for LIDT instruction (!!! must be immediately below sys_int data)
  62.         dw      2*($-sys_int-4)-1
  63.         dd      idts ;0x8000B100
  64.         dw      0    ;просто выравнивание
  65.  
  66.   msg_fault_sel dd  msg_exc_8,msg_exc_u,msg_exc_a,msg_exc_b
  67.                 dd  msg_exc_c,msg_exc_d,msg_exc_e
  68.  
  69.   msg_exc_8     db "Double fault", 0
  70.   msg_exc_u     db "Undefined Exception", 0
  71.   msg_exc_a     db "Invalid TSS", 0
  72.   msg_exc_b     db "Segment not present", 0
  73.   msg_exc_c     db "Stack fault", 0
  74.   msg_exc_d     db "General protection fault", 0
  75.   msg_exc_e     db "Page fault", 0
  76.  
  77.   if lang eq sp
  78.     include 'core/sys32-sp.inc'
  79.   else
  80.     msg_sel_ker   db "kernel", 0
  81.     msg_sel_app   db "application", 0
  82.   end if
  83.  
  84. endg
  85.  
  86. macro save_ring3_context {
  87.         pushad
  88. }
  89. macro restore_ring3_context {
  90.         popad
  91. }
  92. macro exc_wo_code [num] {
  93.   e#num :
  94.         save_ring3_context
  95.         mov     bl, num
  96.         jmp     exc_c
  97. } exc_wo_code   0,1,2,3,4,5,6,15,16,19
  98.  
  99. macro exc_w_code [num] {
  100.   e#num :
  101.         add     esp, 4
  102.         save_ring3_context
  103.         mov     bl, num
  104.         jmp     exc_c
  105. } exc_w_code    8,9,10,11,12,13,17,18
  106.  
  107.  
  108. uglobal
  109.   pf_err_code   dd ?
  110. endg
  111.  
  112. page_fault_exc:                 ; дуракоусточивость: селекторы испорчены...
  113.         pop     [ss:pf_err_code]; действительно до следующего #PF
  114.         save_ring3_context
  115.         mov     bl, 14
  116.  
  117. exc_c:                          ; исключения (все, кроме 7-го - #NM)
  118. ; Фрэйм стека при исключении/прерывании из 3-го кольца + pushad (т.е., именно здесь)
  119.   reg_ss       equ esp+0x30
  120.   reg_esp3     equ esp+0x2C
  121.   reg_eflags   equ esp+0x28
  122.   reg_cs3       equ esp+0x24
  123.   reg_eip       equ esp+0x20
  124.  ; это фрэйм от pushad
  125.   reg_eax       equ esp+0x1C
  126.   reg_ecx       equ esp+0x18
  127.   reg_edx       equ esp+0x14
  128.   reg_ebx       equ esp+0x10
  129.   reg_esp0     equ esp+0x0C
  130.   reg_ebp       equ esp+0x08
  131.   reg_esi       equ esp+0x04
  132.   reg_edi       equ esp+0x00
  133.  
  134.         mov     ax, app_data        ;исключение
  135.         mov     ds, ax                  ;загрузим правильные значения
  136.         mov     es, ax                  ;в регистры
  137.         cld                     ; и приводим DF к стандарту
  138.         movzx   ebx, bl
  139. ; redirect to V86 manager? (EFLAGS & 0x20000) != 0?
  140.         test    byte[reg_eflags+2], 2
  141.         jnz     v86_exc_c
  142.         cmp     bl, 14          ; #PF
  143.         jne     @f
  144.         call    page_fault_handler ; SEE: core/memory.inc
  145.   @@:
  146.         mov     esi, [current_slot]
  147.         btr     [esi+APPDATA.except_mask], ebx
  148.         jnc     @f
  149.         mov     eax, [esi+APPDATA.exc_handler]
  150.         test    eax, eax
  151.         jnz     IRetToUserHook
  152.   @@:
  153.         cli
  154.         mov     eax, [esi+APPDATA.debugger_slot]
  155.         test    eax, eax
  156.         jnz     .debug
  157.         sti
  158. ; not debuggee => say error and terminate
  159.         call    show_error_parameters ;; only ONE using, inline ???
  160.        ;mov     edx, [TASK_BASE]
  161.         mov     [edx + TASKDATA.state], byte 4 ; terminate
  162.         call    wakeup_osloop
  163.         call    change_task
  164. ; If we're here, then the main OS thread has crashed before initializing IDLE thread.
  165. ; Or they both have crashed. Anyway, things are hopelessly broken.
  166.         hlt
  167.         jmp     $-1
  168. .debug:
  169. ; we are debugged process, notify debugger and suspend ourself
  170. ; eax=debugger PID
  171.         mov     ecx, 1          ; debug_message code=other_exception
  172.         cmp     bl, 1           ; #DB
  173.         jne     .notify         ; notify debugger and suspend ourself
  174.         mov     ebx, dr6        ; debug_message data=DR6_image
  175.         xor     edx, edx
  176.         mov     dr6, edx
  177.         mov     edx, dr7
  178.         mov     cl, not 8
  179.   .l1:
  180.         shl     dl, 2
  181.         jc      @f
  182.         and     bl, cl
  183.   @@:
  184.         sar     cl, 1
  185.         jc      .l1
  186.         mov     cl, 3           ; debug_message code=debug_exception
  187. .notify:
  188.         push    ebx             ; debug_message data
  189.         mov     ebx, [TASK_BASE]
  190.         push    [ebx+TASKDATA.pid] ; PID
  191.         push    ecx             ; debug_message code ((here: ecx==1/3))
  192.         mov     cl, 12          ; debug_message size
  193.         call    debugger_notify ;; only ONE using, inline ??? SEE: core/debug.inc
  194.         add     esp, 12
  195.         mov     edx, [TASK_BASE]
  196.         mov     byte [edx+TASKDATA.state], 1 ; suspended
  197.         call    change_task     ; SEE: core/shed.inc
  198.         restore_ring3_context
  199.         iretd
  200.  
  201. IRetToUserHook:
  202.         xchg    eax, [reg_eip]
  203.         sub     dword[reg_esp3], 8
  204.         mov     edi, [reg_esp3]
  205.         stosd
  206.         mov     [edi], ebx
  207.         restore_ring3_context
  208. ; simply return control to interrupted process
  209. unknown_interrupt:
  210.         iretd
  211.  
  212. ;-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=
  213. ; bl - error vector
  214. show_error_parameters:
  215.         cmp     bl, 0x06
  216.         jnz     .no_ud
  217.         push    ebx
  218.         mov     ebx, ud_user_message
  219.         mov     ebp, notifyapp
  220.         call    fs_execute_from_sysdir_param
  221.         pop     ebx
  222. .no_ud:
  223.         mov     edx, [TASK_BASE];not scratched below
  224.         if lang eq sp
  225.         DEBUGF  1, "K : Proceso - terminado forzado PID: %x [%s]\n", [edx+TASKDATA.pid], [current_slot]
  226.         else
  227.         DEBUGF  1, "K : Process - forced terminate PID: %x [%s]\n", [edx+TASKDATA.pid], [current_slot]
  228.         end if
  229.         cmp     bl, 0x08
  230.         jb      .l0
  231.         cmp     bl, 0x0e
  232.         jbe     .l1
  233.   .l0:
  234.         mov     bl, 0x09
  235.   .l1:
  236.         mov     eax, [msg_fault_sel+ebx*4 - 0x08*4]
  237.         DEBUGF  1, "K : %s\n", eax
  238.         mov     eax, [reg_cs3+4]
  239.         mov     edi, msg_sel_app
  240.         mov     ebx, [reg_esp3+4]
  241.         cmp     eax, app_code
  242.         je      @f
  243.         mov     edi, msg_sel_ker
  244.         mov     ebx, [reg_esp0+4]
  245.     @@:
  246.         DEBUGF  1, "K : EAX : %x EBX : %x ECX : %x\n", [reg_eax+4], [reg_ebx+4], [reg_ecx+4]
  247.         DEBUGF  1, "K : EDX : %x ESI : %x EDI : %x\n", [reg_edx+4], [reg_esi+4], [reg_edi+4]
  248.         DEBUGF  1, "K : EBP : %x EIP : %x ESP : %x\n", [reg_ebp+4], [reg_eip+4], ebx
  249.         DEBUGF  1, "K : Flags : %x CS : %x (%s)\n", [reg_eflags+4], eax, edi
  250.  
  251.         DEBUGF  1, "K : Stack dump:\n"
  252.         push    eax ebx ecx edx
  253.         call    .check_ESP
  254.         test    eax, eax
  255.         jnz     .error_ESP
  256.         DEBUGF  1, "K : [ESP+00]: %x",[ebx]
  257.         add     ebx, 4
  258.         call    .check_ESP
  259.         test    eax, eax
  260.         jnz     .error_ESP
  261.         DEBUGF  1, " [ESP+04]: %x",[ebx]
  262.         add     ebx, 4
  263.         call    .check_ESP
  264.         test    eax, eax
  265.         jnz     .error_ESP
  266.         DEBUGF  1, " [ESP+08]: %x\n",[ebx]
  267.         add     ebx, 4
  268.         call    .check_ESP
  269.         test    eax, eax
  270.         jnz     .error_ESP
  271.         DEBUGF  1, "K : [ESP+12]: %x",[ebx]
  272.         add     ebx, 4
  273.         call    .check_ESP
  274.         test    eax, eax
  275.         jnz     .error_ESP
  276.         DEBUGF  1, " [ESP+16]: %x",[ebx]
  277.         add     ebx, 4
  278.         call    .check_ESP
  279.         test    eax, eax
  280.         jnz     .error_ESP
  281.         DEBUGF  1, " [ESP+20]: %x\n",[ebx]
  282.         add     ebx, 4
  283.         call    .check_ESP
  284.         test    eax, eax
  285.         jnz     .error_ESP
  286.         DEBUGF  1, "K : [ESP+24]: %x",[ebx]
  287.         add     ebx, 4
  288.         call    .check_ESP
  289.         test    eax, eax
  290.         jnz     .error_ESP
  291.         DEBUGF  1, " [ESP+28]: %x",[ebx]
  292.         add     ebx, 4
  293.         call    .check_ESP
  294.         test    eax, eax
  295.         jnz     .error_ESP
  296.         DEBUGF  1, " [ESP+32]: %x\n",[ebx]
  297.         pop     edx ecx ebx eax
  298.         ret
  299. .error_ESP:
  300.         pop     edx ecx ebx eax
  301.         DEBUGF  1, "\n"
  302.         DEBUGF  1, "K : Unexpected end of the stack\n"
  303.         ret
  304. ;--------------------------------------
  305. .check_ESP:
  306.         push    ebx
  307.         shr     ebx, 12
  308.         mov     ecx, ebx
  309.         shr     ecx, 10
  310.         mov     edx, [master_tab+ecx*4]
  311.         test    edx, PG_MAP
  312.         jz      .fail             ;page table is not created
  313.                                   ;incorrect address in the program
  314.  
  315.         mov     eax, [page_tabs+ebx*4]
  316.         test    eax, 2
  317.         jz      .fail             ;address not reserved for use. error
  318.  
  319.         pop     ebx
  320.         xor     eax, eax
  321.         ret
  322.  
  323. .fail:
  324.         pop     ebx
  325.         xor     eax, eax
  326.         dec     eax
  327.         ret
  328. ;-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=
  329.  
  330.   restore  reg_ss
  331.   restore  reg_esp3
  332.   restore  reg_eflags
  333.   restore  reg_cs
  334.   restore  reg_eip
  335.   restore  reg_eax
  336.   restore  reg_ecx
  337.   restore  reg_edx
  338.   restore  reg_ebx
  339.   restore  reg_esp0
  340.   restore  reg_ebp
  341.   restore  reg_esi
  342.   restore  reg_edi
  343.  
  344.  
  345. align 4
  346. lock_application_table:
  347.         push    eax ecx edx
  348.         mov     ecx, application_table_mutex
  349.         call    mutex_lock
  350.  
  351.         mov     eax, [CURRENT_TASK]
  352.         shl     eax, 5
  353.         add     eax, CURRENT_TASK+TASKDATA.pid
  354.         mov     eax, [eax]
  355.  
  356.         mov     [application_table_owner], eax
  357.  
  358.         pop     edx ecx eax
  359.  
  360.         ret
  361.  
  362. align 4
  363. unlock_application_table:
  364.         push    eax ecx edx
  365.  
  366.         mov     [application_table_owner], 0
  367.         mov     ecx, application_table_mutex
  368.         call    mutex_unlock
  369.  
  370.         pop     edx ecx eax
  371.  
  372.         ret
  373.  
  374. ;  * eax = 64 - номер функции
  375. ;  * ebx = 1 - единственная подфункция
  376. ;  * ecx = новый размер памяти
  377. ;Возвращаемое значение:
  378. ;  * eax = 0 - успешно
  379. ;  * eax = 1 - недостаточно памяти
  380.  
  381. align 4
  382. sys_resize_app_memory:
  383.         ; ebx = 1 - resize
  384.         ; ecx = new amount of memory
  385.  
  386. ;        cmp    eax,1
  387.         dec     ebx
  388.         jnz     .no_application_mem_resize
  389.  
  390.         mov     eax, [pg_data.pages_free]
  391.         shl     eax, 12
  392.         cmp     eax, ecx
  393.         jae     @f
  394.  
  395.         xor     eax, eax
  396.         inc     eax
  397.         jmp     .store_result
  398. @@:
  399.         stdcall new_mem_resize, ecx
  400. .store_result:
  401.         mov     [esp+32], eax
  402. .no_application_mem_resize:
  403.         ret
  404.  
  405. iglobal
  406. ;  process_terminating  db 'K : Process - terminating',13,10,0
  407. ;  process_terminated   db 'K : Process - done',13,10,0
  408.   msg_obj_destroy       db 'K : destroy app object',13,10,0
  409. endg
  410.  
  411. ; param
  412. ;  esi= slot
  413.  
  414. align 4
  415. terminate: ; terminate application
  416. destroy_thread:
  417.  
  418.            .slot equ esp   ;locals
  419.  
  420.         push    esi        ;save .slot
  421.  
  422.         shl     esi, 8
  423.         cmp     [SLOT_BASE+esi+APPDATA.process], 0
  424.         jne     @F
  425.         pop     esi
  426.         shl     esi, 5
  427.         mov     [CURRENT_TASK+esi+TASKDATA.state], 9
  428.         ret
  429. @@:
  430.         lea     edx, [SLOT_BASE+esi]
  431.         call    scheduler_remove_thread
  432.         call    lock_application_table
  433.  
  434. ; if the process is in V86 mode...
  435.         mov     eax, [.slot]
  436.         shl     eax, 8
  437.         mov     esi, [eax+SLOT_BASE+APPDATA.pl0_stack]
  438.         add     esi, RING0_STACK_SIZE
  439.         cmp     [eax+SLOT_BASE+APPDATA.saved_esp0], esi
  440.         jz      .nov86
  441. ; ...it has page directory for V86 mode
  442.         mov     esi, [eax+SLOT_BASE+APPDATA.saved_esp0]
  443.         mov     ecx, [esi+4]
  444.         mov     [eax+SLOT_BASE+APPDATA.process], ecx
  445. ; ...and I/O permission map for V86 mode
  446.         mov     ecx, [esi+12]
  447.         mov     [eax+SLOT_BASE+APPDATA.io_map], ecx
  448.         mov     ecx, [esi+8]
  449.         mov     [eax+SLOT_BASE+APPDATA.io_map+4], ecx
  450. .nov86:
  451. ;destroy per-thread kerlen objects
  452.         mov     esi, [.slot]
  453.         shl     esi, 8
  454.         add     esi, SLOT_BASE+APP_OBJ_OFFSET
  455. @@:
  456.         mov     eax, [esi+APPOBJ.fd]
  457.         test    eax, eax
  458.         jz      @F
  459.  
  460.         cmp     eax, esi
  461.         je      @F
  462.  
  463.         push    esi
  464.         call    [eax+APPOBJ.destroy]
  465.            DEBUGF 1,"%s",msg_obj_destroy
  466.         pop     esi
  467.         jmp     @B
  468. @@:
  469.         mov     esi, [.slot]
  470.         cmp     [fpu_owner], esi ; if user fpu last -> fpu user = 2
  471.         jne     @F
  472.  
  473.         mov     [fpu_owner], 2
  474.         mov     eax, [256*2+SLOT_BASE+APPDATA.fpu_state]
  475.         clts
  476.         bt      [cpu_caps], CAPS_SSE
  477.         jnc     .no_SSE
  478.         fxrstor [eax]
  479.         jmp     @F
  480. .no_SSE:
  481.         fnclex
  482.         frstor  [eax]
  483. @@:
  484.  
  485.         mov     [KEY_COUNT], byte 0    ; empty keyboard buffer
  486.         mov     [BTN_COUNT], byte 0    ; empty button buffer
  487.  
  488.  
  489. ; remove defined hotkeys
  490.         mov     eax, hotkey_list
  491. .loop:
  492.         cmp     [eax+8], esi
  493.         jnz     .cont
  494.         mov     ecx, [eax]
  495.         jecxz   @f
  496.         push    dword [eax+12]
  497.         pop     dword [ecx+12]
  498. @@:
  499.         mov     ecx, [eax+12]
  500.         push    dword [eax]
  501.         pop     dword [ecx]
  502.         xor     ecx, ecx
  503.         mov     [eax], ecx
  504.         mov     [eax+4], ecx
  505.         mov     [eax+8], ecx
  506.         mov     [eax+12], ecx
  507. .cont:
  508.         add     eax, 16
  509.         cmp     eax, hotkey_list+256*16
  510.         jb      .loop
  511. ; get process PID
  512.         mov     eax, esi
  513.         shl     eax, 5
  514.         mov     eax, [eax+CURRENT_TASK+TASKDATA.pid]
  515. ; compare current lock input with process PID
  516.         cmp     eax, [PID_lock_input]
  517.         jne     @f
  518.  
  519.         xor     eax, eax
  520.         mov     [PID_lock_input], eax
  521. @@:
  522. ; remove hotkeys in buffer
  523.         mov     eax, hotkey_buffer
  524. .loop2:
  525.         cmp     [eax], esi
  526.         jnz     .cont2
  527.         and     dword [eax+4], 0
  528.         and     dword [eax], 0
  529. .cont2:
  530.         add     eax, 8
  531.         cmp     eax, hotkey_buffer+120*8
  532.         jb      .loop2
  533.  
  534.         mov     ecx, esi          ; remove buttons
  535.   bnewba2:
  536.         mov     edi, [BTN_ADDR]
  537.         mov     eax, edi
  538.         cld
  539.         movzx   ebx, word [edi]
  540.         inc     bx
  541.   bnewba:
  542.         dec     bx
  543.         jz      bnmba
  544.         add     eax, 0x10
  545.         cmp     cx, [eax]
  546.         jnz     bnewba
  547.         pusha
  548.         mov     ecx, ebx
  549.         inc     ecx
  550.         shl     ecx, 4
  551.         mov     ebx, eax
  552.         add     eax, 0x10
  553.         call    memmove
  554.         dec     dword [edi]
  555.         popa
  556.         jmp     bnewba2
  557.   bnmba:
  558.  
  559.         pusha   ; save window coordinates for window restoring
  560.         cld
  561.         shl     esi, 5
  562.         add     esi, window_data
  563.         mov     eax, [esi+WDATA.box.left]
  564.         mov     [draw_limits.left], eax
  565.         add     eax, [esi+WDATA.box.width]
  566.         mov     [draw_limits.right], eax
  567.         mov     eax, [esi+WDATA.box.top]
  568.         mov     [draw_limits.top], eax
  569.         add     eax, [esi+WDATA.box.height]
  570.         mov     [draw_limits.bottom], eax
  571.  
  572.         xor     eax, eax
  573.         mov     [esi+WDATA.box.left], eax
  574.         mov     [esi+WDATA.box.width], eax
  575.         mov     [esi+WDATA.box.top], eax
  576.         mov     [esi+WDATA.box.height], eax
  577.         mov     [esi+WDATA.cl_workarea], eax
  578.         mov     [esi+WDATA.cl_titlebar], eax
  579.         mov     [esi+WDATA.cl_frames], eax
  580.         mov     dword [esi+WDATA.reserved], eax; clear all flags: wstate, redraw, wdrawn
  581.         lea     edi, [esi-window_data+draw_data]
  582.         mov     ecx, 32/4
  583.         rep stosd
  584.         popa
  585.  
  586. ; debuggee test
  587.         pushad
  588.         mov     edi, esi
  589.         shl     edi, 5
  590.         mov     eax, [SLOT_BASE+edi*8+APPDATA.debugger_slot]
  591.         test    eax, eax
  592.         jz      .nodebug
  593.         movi    ecx, 8
  594.         push    dword [CURRENT_TASK+edi+TASKDATA.pid]; PID
  595.         push    2
  596.         call    debugger_notify
  597.         pop     ecx
  598.         pop     ecx
  599. .nodebug:
  600.         popad
  601.  
  602.         mov     ebx, [.slot]
  603.         shl     ebx, 8
  604.         push    ebx
  605.         mov     ebx, [SLOT_BASE+ebx+APPDATA.pl0_stack]
  606.  
  607.         stdcall kernel_free, ebx
  608.  
  609.         pop     ebx
  610.         mov     ebx, [SLOT_BASE+ebx+APPDATA.cur_dir]
  611.         stdcall kernel_free, ebx
  612.  
  613.         mov     edi, [.slot]
  614.         shl     edi, 8
  615.         add     edi, SLOT_BASE
  616.  
  617.         mov     eax, [edi+APPDATA.io_map]
  618.         cmp     eax, [SLOT_BASE+256+APPDATA.io_map]
  619.         je      @F
  620.         call    free_page
  621. @@:
  622.         mov     eax, [edi+APPDATA.io_map+4]
  623.         cmp     eax, [SLOT_BASE+256+APPDATA.io_map+4]
  624.         je      @F
  625.         call    free_page
  626. @@:
  627.         mov     eax, 0x20202020
  628.         stosd
  629.         stosd
  630.         stosd
  631.         mov     ecx, 244/4
  632.         xor     eax, eax
  633.         rep stosd
  634.  
  635.   ; activate window
  636.         movzx   eax, word [WIN_STACK + esi*2]
  637.         cmp     eax, [TASK_COUNT]
  638.         jne     .dont_activate
  639.         pushad
  640.  .check_next_window:
  641.         dec     eax
  642.         cmp     eax, 1
  643.         jbe     .nothing_to_activate
  644.         lea     esi, [WIN_POS+eax*2]
  645.         movzx   edi, word [esi]              ; edi = process
  646.         shl     edi, 5
  647.         cmp     [CURRENT_TASK + edi + TASKDATA.state], byte 9 ; skip dead slots
  648.         je      .check_next_window
  649.         add     edi, window_data
  650. ; \begin{diamond}[19.09.2006]
  651. ; skip minimized windows
  652.         test    [edi + WDATA.fl_wstate], WSTATE_MINIMIZED
  653.         jnz     .check_next_window
  654. ; \end{diamond}
  655.         call    waredraw
  656.  .nothing_to_activate:
  657.         popad
  658.  .dont_activate:
  659.  
  660.         push    esi     ; remove hd1 & cd & flp reservation
  661.         shl     esi, 5
  662.         mov     esi, [esi+CURRENT_TASK+TASKDATA.pid]
  663.         cmp     [cd_status], esi
  664.         jnz     @f
  665.         call    free_cd_channel
  666.         and     [cd_status], 0
  667. @@:
  668.         pop     esi
  669.         cmp     [bgrlockpid], esi
  670.         jnz     @f
  671.         and     [bgrlockpid], 0
  672.         and     [bgrlock], 0
  673. @@:
  674.  
  675.         pusha                 ; remove all port reservations
  676.         mov     edx, esi
  677.         shl     edx, 5
  678.         add     edx, CURRENT_TASK
  679.         mov     edx, [edx+TASKDATA.pid]
  680.  
  681.   rmpr0:
  682.  
  683.         mov     esi, [RESERVED_PORTS]
  684.  
  685.         test    esi, esi
  686.         jz      rmpr9
  687.  
  688.   rmpr3:
  689.  
  690.         mov     edi, esi
  691.         shl     edi, 4
  692.         add     edi, RESERVED_PORTS
  693.  
  694.         cmp     edx, [edi]
  695.         je      rmpr4
  696.  
  697.         dec     esi
  698.         jnz     rmpr3
  699.  
  700.         jmp     rmpr9
  701.  
  702.   rmpr4:
  703.  
  704.         mov     ecx, 256
  705.         sub     ecx, esi
  706.         shl     ecx, 4
  707.  
  708.         mov     esi, edi
  709.         add     esi, 16
  710.         cld
  711.         rep movsb
  712.  
  713.         dec     dword [RESERVED_PORTS]
  714.  
  715.         jmp     rmpr0
  716.  
  717.   rmpr9:
  718.  
  719.         popa
  720.         mov     edi, esi ; do not run this process slot
  721.         shl     edi, 5
  722.         mov     [edi+CURRENT_TASK + TASKDATA.state], byte 9
  723. ; debugger test - terminate all debuggees
  724.         mov     eax, 2
  725.         mov     ecx, SLOT_BASE+2*0x100+APPDATA.debugger_slot
  726. .xd0:
  727.         cmp     eax, [TASK_COUNT]
  728.         ja      .xd1
  729.         cmp     dword [ecx], esi
  730.         jnz     @f
  731.         and     dword [ecx], 0
  732.         pushad
  733.         xchg    eax, ecx
  734.         mov     ebx, 2
  735.         call    sys_system
  736.         popad
  737. @@:
  738.         inc     eax
  739.         add     ecx, 0x100
  740.         jmp     .xd0
  741. .xd1:
  742. ;release slot
  743.         bts     [thr_slot_map], esi
  744.  
  745.         sti     ; .. and life goes on
  746.  
  747.         mov     eax, [draw_limits.left]
  748.         mov     ebx, [draw_limits.top]
  749.         mov     ecx, [draw_limits.right]
  750.         mov     edx, [draw_limits.bottom]
  751.         call    calculatescreen
  752.         xor     eax, eax
  753.         xor     esi, esi
  754.         call    redrawscreen
  755.  
  756.         call    unlock_application_table
  757.     ;mov   esi,process_terminated
  758.     ;call  sys_msg_board_str
  759.         add     esp, 4
  760.         ret
  761. restore .slot
  762.  
  763.  
  764. ; Three following procedures are used to guarantee that
  765. ; some part of kernel code will not be terminated from outside
  766. ; while it is running.
  767. ; Note: they do not protect a thread from terminating due to errors inside
  768. ; the thread; accessing a nonexisting memory would still terminate it.
  769.  
  770. ; First two procedures must be used in pair by thread-to-be-protected
  771. ; to signal the beginning and the end of an important part.
  772. ; It is OK to have nested areas.
  773.  
  774. ; The last procedure must be used by outside wanna-be-terminators;
  775. ; if it is safe to terminate the given thread immediately, it returns eax=1;
  776. ; otherwise, it returns eax=0 and notifies the target thread that it should
  777. ; terminate itself when leaving a critical area (the last critical area if
  778. ; they are nested).
  779.  
  780. ; Implementation. Those procedures use one dword in APPDATA for the thread,
  781. ; APPDATA.terminate_protection.
  782. ; * The upper bit is 1 during normal operations and 0 when terminate is requested.
  783. ; * Other bits form a number = depth of critical regions,
  784. ;   plus 1 if the upper bit is 1.
  785. ; * When this dword goes to zero, the thread should be destructed,
  786. ;   and the procedure in which it happened becomes responsible for destruction.
  787.  
  788. ; Enter critical area. Called by thread which wants to be protected.
  789. proc protect_from_terminate
  790.         mov     edx, [current_slot]
  791. ; Atomically increment depth of critical areas and get the old value.
  792.         mov     eax, 1
  793.         lock xadd [edx+APPDATA.terminate_protection], eax
  794. ; If the old value was zero, somebody has started to terminate us,
  795. ; so we are destructing and cannot do anything protected.
  796. ; Otherwise, return to the caller.
  797.         test    eax, eax
  798.         jz      @f
  799.         ret
  800. @@:
  801. ; Wait for somebody to finish us.
  802.         call    change_task
  803.         jmp     @b
  804. endp
  805.  
  806. ; Leave critical area. Called by thread which wants to be protected.
  807. proc unprotect_from_terminate
  808.         mov     edx, [current_slot]
  809. ; Atomically decrement depth of critical areas.
  810.         lock dec [edx+APPDATA.terminate_protection]
  811. ; If the result of decrement is zero, somebody has requested termination,
  812. ; but at that moment we were inside a critical area; terminate now.
  813.         jz      sys_end
  814. ; Otherwise, return to the caller.
  815.         ret
  816. endp
  817.  
  818. ; Request termination of thread identified by edx = SLOT_BASE + slot*256.
  819. ; Called by anyone.
  820. proc request_terminate
  821.         xor     eax, eax        ; set return value
  822. ; Atomically clear the upper bit. If it was already zero, then
  823. ; somebody has requested termination before us, so just exit.
  824.         lock btr [edx+APPDATA.terminate_protection], 31
  825.         jnc     .unsafe
  826. ; Atomically decrement depth of critical areas.
  827.         lock dec [edx+APPDATA.terminate_protection]
  828. ; If the result of decrement is nonzero, the target thread is inside a
  829. ; critical area; leave termination to leaving that area.
  830.         jnz     .unsafe
  831. ; Otherwise, it is safe to kill the target now and the caller is responsible
  832. ; for this. Return eax=1.
  833.         inc     eax
  834. .unsafe:
  835.         ret
  836. endp
  837.  
  838.