Subversion Repositories Kolibri OS

Rev

Go to most recent revision | Blame | Last modification | View Log | Download | RSS feed

  1. label calc_clipping_rects dword at calculatescreen
  2.  
  3. get_titlebar_height: ; edi = window draw_data pointer
  4.         mov     al,[edi+WDATA.fl_wstyle]
  5.         and     al,0x0F
  6.         cmp     al,0x03
  7.         jne     @f
  8.         mov     eax,[_skinh]
  9.         ret
  10.     @@: mov     eax,21
  11.         ret
  12.  
  13. get_rolledup_height: ; edi = window draw_data pointer
  14.         mov     al,[edi+WDATA.fl_wstyle]
  15.         and     al,0x0F
  16.         cmp     al,0x03
  17.         jne     @f
  18.         mov     eax,[_skinh]
  19.         add     eax,3
  20.         ret
  21.     @@: or      al,al
  22.         jnz     @f
  23.         mov     eax,21
  24.         ret
  25.     @@: mov     eax,21+2
  26.         ret
  27.  
  28.  
  29. setwindowdefaults:
  30.         pushad
  31.  
  32.         xor   eax,eax
  33.         mov   ecx,0xc000
  34.        @@:
  35.         inc   eax
  36.         add   ecx,2
  37.         mov   [ecx+0x000],ax          ; process no
  38.         mov   [ecx+0x400],ax          ; positions in stack
  39.         cmp   ecx,0xc400-2            ; the more high, the more surface
  40.         jnz   @b
  41.  
  42.         popad
  43.         ret
  44.  
  45.  
  46.  
  47. ; eax = cx
  48. ; ebx = cy
  49. ; ecx = ex
  50. ; edx = ey
  51. ; èäåÿ: ïåðåáðàòü âñå îêíà, íà÷èíàÿ ñ ñàìîãî íèæíåãî,
  52. ;       è äëÿ ïîïàâøèõ â çàäàííóþ îáëàñòü
  53. ;       ÷àñòåé îêîí âûçâàòü setscreen
  54. align 4
  55. __sys_calculatescreen:
  56.         pushad
  57.         pushfd
  58.         cli
  59.  
  60.         push    edx ecx ebx eax
  61.  
  62.         mov     esi, 1
  63.         xor   eax, eax
  64.         xor   ebx, ebx
  65.         mov   ecx, [0xFE00]
  66.         mov   edx, [0xFE04]
  67.         call    [setscreen]
  68.  
  69.         mov     ebp, [0x3004]        ; number of processes
  70.         cmp     ebp, 1
  71.         jbe     .finish
  72.         align 4
  73.       .new_wnd:
  74.         movzx   edi, word [0xC400 + esi * 2]
  75.         shl     edi, 5
  76.  
  77.         cmp     [0x3000+edi+TASKDATA.state], byte 9
  78.         je      .not_wnd
  79.  
  80.         add     edi, window_data
  81.         test    [edi+WDATA.fl_wstate], WSTATE_MINIMIZED
  82.         jnz     .not_wnd
  83.  
  84.         mov     eax,[edi+WDATA.box.left]
  85.         cmp     eax, [esp+RECT.right]
  86.         jg      .out_of_bounds
  87.         mov     ebx,[edi+WDATA.box.top]
  88.         cmp     ebx, [esp+RECT.bottom]
  89.         jg      .out_of_bounds
  90.         mov     ecx,[edi+WDATA.box.width]
  91.         add     ecx, eax
  92.         cmp     ecx, [esp+RECT.left]
  93.         jl      .out_of_bounds
  94.         mov     edx,[edi+WDATA.box.height]
  95.         add     edx, ebx
  96.         cmp     edx, [esp+RECT.top]
  97.         jl      .out_of_bounds
  98.  
  99.     cmp     eax, [esp+RECT.left]
  100.         jge     @f
  101.         mov     eax, [esp+RECT.left]
  102.      @@:
  103.     cmp     ebx, [esp+RECT.top]
  104.         jge     @f
  105.         mov     ebx, [esp+RECT.top]
  106.      @@:
  107.     cmp     ecx, [esp+RECT.right]
  108.         jle     @f
  109.         mov     ecx, [esp+RECT.right]
  110.      @@:
  111.     cmp     edx, [esp+RECT.bottom]
  112.         jle     @f
  113.         mov     edx, [esp+RECT.bottom]
  114.      @@:
  115.  
  116.         push    esi
  117.         movzx   esi, word [0xC400 + esi * 2]
  118.         call    [setscreen]
  119.         pop     esi
  120.  
  121.       .not_wnd:
  122.       .out_of_bounds:
  123.         inc     esi
  124.         dec     ebp
  125.         jnz     .new_wnd
  126.       .finish:
  127.  
  128.     pop     eax ebx ecx edx
  129.  
  130.         popfd
  131.         popad
  132. ret
  133.  
  134.  
  135.  
  136. virtual at esp
  137.   ff_x     dd ?
  138.   ff_y     dd ?
  139.   ff_width dd ?
  140.   ff_xsz   dd ?
  141.   ff_ysz   dd ?
  142.   ff_scale dd ?
  143. end virtual
  144.  
  145. __sys_setscreen: ret
  146.  
  147.  
  148. display_settings:
  149.  
  150. ;    eax = 0         ; DISPLAY redraw
  151. ;          ebx = 0   ; all
  152. ;
  153. ;    eax = 1         ; BUTTON type
  154. ;          ebx = 0   ; flat
  155. ;          ebx = 1   ; 3D
  156. ;    eax = 2         ; set WINDOW colours
  157. ;          ebx = pointer to table
  158. ;          ecx = number of bytes define
  159. ;    eax = 3         ; get WINDOW colours
  160. ;          ebx = pointer to table
  161. ;          ecx = number of bytes wanted
  162. ;    eax = 4         ; get skin height
  163. ;          input  : nothing
  164. ;          output : eax = skin height in pixel
  165. ;    eax = 5         ; get screen workarea
  166. ;          input  : nothing
  167. ;          output : eax = [left]*65536+[right]
  168. ;                   ebx = [top]*65536+[bottom]
  169. ;    eax = 6         ; set screen workarea
  170. ;          input  : ecx = [left]*65536+[right]
  171. ;                   edx = [top]*65536+[bottom]
  172. ;          output : nothing
  173. ;    eax = 7         ; get skin margins
  174. ;          input  : nothing
  175. ;          output : eax = [left]*65536+[right]
  176. ;                   ebx = [top]*65536+[bottom]
  177. ;    eax = 8         ; set window skin
  178. ;          input  : ecx = pointer to file info block
  179. ;          output : eax = FS error code
  180.  
  181.  
  182.      pushad
  183.  
  184.      test eax, eax      ; redraw display
  185.      jnz  dspl0
  186.      test ebx, ebx
  187.      jnz  dspl0
  188.      cmp  [windowtypechanged],dword 1
  189.      jne  dspl00
  190.      mov  [windowtypechanged],dword 0
  191.   redraw_screen_direct:
  192.      mov  [dlx],dword 0
  193.      mov  [dly],dword 0
  194.      mov  eax,[0xfe00]
  195.      mov  [dlxe],eax
  196.      mov  eax,[0xfe04]
  197.      mov  [dlye],eax
  198.      mov  eax,window_data
  199.      call redrawscreen
  200.    dspl00:
  201.      popad
  202.      ret
  203.    dspl0:
  204.  
  205.      cmp  eax,1       ; button type
  206.      jne  dspl1
  207.      and  ebx,1
  208.      cmp  ebx,[buttontype]
  209.      je   dspl9
  210.      mov  [buttontype],ebx
  211.      mov  [windowtypechanged],dword 1
  212.     dspl9:
  213.      popad
  214.      ret
  215.    dspl1:
  216.  
  217.      cmp  eax,2       ; set common window colours
  218.      jne  no_com_colours
  219.      mov  [windowtypechanged],dword 1
  220.      mov  esi,[0x3010]
  221.      add  esi,TASKDATA.mem_start
  222.      add  ebx,[esi]
  223.      mov  esi,ebx
  224.      mov  edi,common_colours
  225.      and  ecx,127
  226.      cld
  227.      rep  movsb
  228.      popad
  229.      ret
  230.    no_com_colours:
  231.  
  232.      cmp  eax,3       ; get common window colours
  233.      jne  no_get_com
  234.      mov  esi,[0x3010]
  235.      add  esi,TASKDATA.mem_start
  236.      add  ebx,[esi]
  237.      mov  edi,ebx
  238.      mov  esi,common_colours
  239.      and  ecx,127
  240.      cld
  241.      rep  movsb
  242.      popad
  243.      ret
  244.    no_get_com:
  245.  
  246.      cmp  eax,4       ; get skin height
  247.      jne  no_skin_height
  248.      popad
  249.      mov  eax,[_skinh]
  250.      mov  [esp+36],eax
  251.      ret
  252.    no_skin_height:
  253.  
  254.         cmp     eax,5       ; get screen workarea
  255.         jne     no_get_workarea
  256.         popad
  257.         mov     eax,[screen_workarea.left-2]
  258.         mov     ax,word[screen_workarea.right]
  259.         mov     [esp+36],eax
  260.         mov     eax,[screen_workarea.top-2]
  261.         mov     ax,word[screen_workarea.bottom]
  262.         mov     [esp+24],eax
  263.         ret
  264.    no_get_workarea:
  265.  
  266.         cmp     eax,6       ; set screen workarea
  267.         jne     no_set_workarea
  268.         movsx   eax,word[esp+16+2]
  269.         movsx   ebx,word[esp+16]
  270.         cmp     eax,ebx
  271.         jge     .lp1
  272.         or      eax,eax;[0xFE00]
  273.         jl      @f
  274.         mov     [screen_workarea.left],eax
  275.     @@: cmp     ebx,[0xFE00]
  276.         jg      .lp1
  277.         mov     [screen_workarea.right],ebx
  278.   .lp1: movsx   eax,word[esp+24+2]
  279.         movsx   ebx,word[esp+24]
  280.         cmp     eax,ebx
  281.         jge     .lp2
  282.         or      eax,eax;[0xFE04]
  283.         jl      @f
  284.         mov     [screen_workarea.top],eax
  285.     @@: cmp     ebx,[0xFE04]
  286.         jg      .lp2
  287.         mov     [screen_workarea.bottom],ebx
  288.   .lp2: call    repos_windows
  289.         mov     eax, 0
  290.         mov     ebx, 0
  291.         mov     ecx, [0xfe00]
  292.         mov     edx, [0xfe04]
  293.         call    [calculatescreen]
  294. ;    jmp    redraw_screen_direct
  295.     .exit:
  296.         popad
  297.         ret
  298.    no_set_workarea:
  299.  
  300.         cmp     eax,7       ; get skin margins
  301.         jne     no_get_skinmargins
  302.         popad
  303.         mov     eax,dword[_skinmargins+0]
  304.         mov     [esp+36],eax
  305.         mov     eax,dword[_skinmargins+4]
  306.         mov     [esp+24],eax
  307.         ret
  308.    no_get_skinmargins:
  309.  
  310.         cmp     eax,8       ; set window skin
  311.         jne     no_set_skin
  312.         mov     eax,ebx
  313.         mov     edi,[0x3010]
  314.         add     ebx,[edi+TASKDATA.mem_start]        ; abs start of info block
  315.         pushd   [ebx+0] [ebx+4] [ebx+8] [ebx+12]
  316.         mov     dword[ebx+0],0        ; read
  317.         mov     dword[ebx+4],0        ; from the beginning
  318.         mov     dword[ebx+8],64       ; 32 KBytes maximum
  319.         mov     ecx,skin_data+64*512
  320.         sub     ecx,[edi+0x10]
  321.         mov     dword[ebx+12],ecx     ; destination
  322.         push    eax
  323.         pushad
  324.         call    file_system
  325.         popad
  326.         pop    eax
  327.         popd    [ebx+12] [ebx+8] [ebx+4] [ebx+0]
  328.         cmp     eax,ERROR_SUCCESS
  329.         je      @f
  330.         cmp     eax,ERROR_END_OF_FILE
  331.         jne     .exit
  332.     @@: cmp     [skin_data+64*512+SKIN_HEADER.ident],'SKIN'
  333.         mov     eax,ERROR_UNKNOWN_FS
  334.         jne     .exit
  335.         mov     esi,skin_data+64*512
  336.         mov     edi,skin_data
  337.         mov     ecx,(64*512)/4
  338.         rep     movsd
  339.         call    parse_skin_data
  340.     pushad
  341.         mov     eax, 0
  342.         mov     ebx, 0
  343.         mov     ecx, [0xfe00]
  344.         mov     edx, [0xfe04]
  345.         call    [calculatescreen]
  346.     popad
  347.         mov     dword[esp+32+36],0
  348.         jmp     redraw_screen_direct
  349.   .exit:
  350.         mov     [esp+32+36],eax
  351.         popad
  352.         ret
  353.    no_set_skin:
  354.  
  355.      popad
  356.      ret
  357.  
  358.  
  359. repos_windows:
  360.         mov     ecx,[0x3004]
  361.         mov     esi,0x20*2
  362.     mov    byte[0x0000fff0],1
  363.         dec     ecx
  364.         jge    @f
  365.         ret
  366.     @@: mov    [esi+WDATA.fl_redraw],1
  367.     test    [esi+WDATA.fl_wstate],WSTATE_MAXIMIZED
  368.         jz      .lp2
  369.         mov     eax,[screen_workarea.left]
  370.         mov     [esi+WDATA.box.left],eax
  371.         sub     eax,[screen_workarea.right]
  372.         neg     eax
  373.         mov     [esi+WDATA.box.width],eax
  374.         mov     eax,[screen_workarea.top]
  375.         mov     [esi+WDATA.box.top],eax
  376.         test    [esi+WDATA.fl_wstate],WSTATE_ROLLEDUP
  377.         jnz     .lp1
  378.         sub     eax,[screen_workarea.bottom]
  379.         neg     eax
  380.         mov     [esi+WDATA.box.height],eax
  381.   .lp1: add     esi,0x20
  382.         loop    @b
  383.         ret
  384.   .lp2: mov     eax,[esi+WDATA.box.left]
  385.         add     eax,[esi+WDATA.box.width]
  386.     mov    ebx,[0x0000fe00]
  387. ;    inc    ebx
  388.     cmp    eax,ebx
  389.     jle    .lp4
  390.         mov     eax,[esi+WDATA.box.width]
  391.     sub    eax,ebx
  392.     jle    .lp3
  393.         mov     [esi+WDATA.box.width],ebx
  394.   .lp3: sub     ebx,[esi+WDATA.box.width]
  395.         mov     [esi+WDATA.box.left],ebx
  396.   .lp4: mov     eax,[esi+WDATA.box.top]
  397.         add     eax,[esi+WDATA.box.height]
  398.     mov    ebx,[0x0000fe04]
  399. ;    inc    ebx
  400.     cmp    eax,ebx
  401.     jle    .lp6
  402.         mov     eax,[esi+WDATA.box.height]
  403.     sub    eax,ebx
  404.     jle    .lp5
  405.         mov     [esi+WDATA.box.height],ebx
  406.   .lp5: sub     ebx,[esi+WDATA.box.height]
  407.         mov     [esi+WDATA.box.top],ebx
  408.   .lp6: add     esi,0x20
  409.         loop    @b
  410.     ret
  411.  
  412. uglobal
  413.   common_colours:
  414.      times 128 db 0x0
  415. endg
  416.  
  417.  
  418.  
  419.  
  420. check_window_position:
  421.     ret
  422.  
  423.  
  424. uglobal
  425.   new_window_starting dd 0
  426. endg
  427.  
  428.  
  429. sys_window_mouse:
  430.  
  431.     push  eax
  432.  
  433.     mov   eax,[timer_ticks]
  434.     cmp   [new_window_starting],eax
  435.     jb    swml1
  436.  
  437.     mov   [0xfff4],byte 0  ; no mouse background
  438.     mov   [0xfff5],byte 0  ; draw mouse
  439.  
  440.     mov   [new_window_starting],eax
  441.  
  442.   swml1:
  443.  
  444.     pop   eax
  445.  
  446.     ret
  447.  
  448.  
  449.  
  450.  
  451. drawwindow_I_caption:
  452.  
  453.         mov   ecx,[edx+WDATA.cl_titlebar]   ; grab bar
  454.         push  ecx
  455.         mov   esi,edx
  456.         mov   edx,[esi+WDATA.box.top]
  457.         add   edx,1
  458.         mov   ebx,[esi+WDATA.box.top]
  459.         add   ebx,21
  460.         mov   eax,[esi+WDATA.box.top]
  461.         add   eax,[esi+WDATA.box.height]
  462.         cmp   ebx,eax
  463.         jb    .wdsizeok
  464.         mov   ebx,eax
  465.   .wdsizeok:
  466.         push  ebx
  467.   .drwi:
  468.         mov   ebx,edx
  469.         shl   ebx,16
  470.         add   ebx,edx
  471.         mov   eax,[esi+WDATA.box.left]
  472.         inc   eax
  473.         shl   eax,16
  474.         add   eax,[esi+WDATA.box.left]
  475.         add   eax,[esi+WDATA.box.width]
  476.         sub   eax,1
  477.         mov   ecx,[esi+WDATA.cl_titlebar]
  478.         test    ecx,0x80000000
  479.         jz      .nofa
  480.         sub   ecx,0x00040404
  481.         mov   [esi+WDATA.cl_titlebar],ecx
  482.   .nofa:
  483.   .faj:
  484.         and   ecx,0x00ffffff
  485.         mov   edi,0
  486.         call  [draw_line]
  487.         inc   edx
  488.         cmp   edx,[esp]
  489.         jl    .drwi
  490.         add   esp,4
  491.         pop   ecx
  492.         mov   [esi+WDATA.cl_titlebar],ecx
  493.  
  494.         ret
  495.  
  496.  
  497. drawwindow_I:
  498.  
  499.         pushad
  500.  
  501.         mov   esi,[edx+WDATA.cl_frames]   ; rectangle
  502.         mov   eax,[edx+WDATA.box.left]
  503.         shl   eax,16
  504.         add   eax,[edx+WDATA.box.left]
  505.         add   eax,[edx+WDATA.box.width]
  506.         mov   ebx,[edx+WDATA.box.top]
  507.         shl   ebx,16
  508.         add   ebx,[edx+WDATA.box.top]
  509.         add   ebx,[edx+WDATA.box.height]
  510.         call  draw_rectangle
  511.  
  512.         call    drawwindow_I_caption
  513.  
  514.         mov   edx,[esi+WDATA.box.top]      ; inside work area
  515.         add   edx,21+5
  516.         mov   ebx,[esi+WDATA.box.top]
  517.         add   ebx,[esi+WDATA.box.height]
  518.         cmp   edx,ebx
  519.         jg    noinside
  520.         mov   eax,1
  521.         mov   ebx,21
  522.         mov   ecx,[esi+WDATA.box.width]
  523.         mov   edx,[esi+WDATA.box.height]
  524.         mov   edi,[esi+WDATA.cl_workarea]
  525.         call  [drawbar]
  526.       noinside:
  527.  
  528.         popad
  529.  
  530.         ret
  531.  
  532.  
  533. draw_rectangle:
  534.  
  535. r_eax equ [esp+28]   ; x start
  536. r_ax  equ [esp+30]   ; x end
  537. r_ebx equ [esp+16]   ; y start
  538. r_bx  equ [esp+18]   ; y end
  539. ;esi                 ; color
  540.  
  541.         pushad
  542.  
  543.         mov   ecx,esi          ; yb,xb -> yb,xe
  544.         mov   eax, r_eax
  545.         rol   eax, 16
  546.         mov   ebx,r_ebx
  547.         shl   ebx,16
  548.         mov   bx,r_ebx
  549.         xor   edi, edi
  550.         call  [draw_line]
  551.  
  552.         mov   ebx,r_bx         ; ye,xb -> ye,xe
  553.         shl   ebx,16
  554.         mov   bx,r_bx
  555.         call  [draw_line]
  556.  
  557.         mov   ecx,esi          ; ya,xa -> ye,xa
  558.         mov   eax,r_eax
  559.         shl   eax,16
  560.         mov   ax,r_eax
  561.         mov   ebx,r_ebx
  562.         shl   ebx,16
  563.         mov   bx,r_bx
  564.         mov   edi,0
  565.         call  [draw_line]
  566.  
  567.         mov   eax,r_ax       ; ya,xe -> ye,xe
  568.         shl   eax,16
  569.         mov   ax,r_ax
  570.         call  [draw_line]
  571.  
  572.         popad
  573.         ret
  574.  
  575.  
  576. drawwindow_III_caption:
  577.  
  578.         mov   ecx,[edx+WDATA.cl_titlebar]                       ; GRAB BAR
  579.         push  ecx
  580.         mov   esi,edx
  581.         mov   edx,[esi+WDATA.box.top]
  582.         add   edx,4
  583.         mov   ebx,[esi+WDATA.box.top]
  584.         add   ebx,20
  585.         mov   eax,[esi+WDATA.box.top]
  586.         add   eax,[esi+WDATA.box.height]
  587.         cmp   ebx,eax
  588.         jl    .wdsizeok
  589.         mov   ebx,eax
  590.   .wdsizeok:
  591.         push  ebx
  592.   .drwi:
  593.         mov   ebx,edx
  594.         shl   ebx,16
  595.         add   ebx,edx
  596.         mov   eax,[esi+WDATA.box.left]
  597.         shl   eax,16
  598.         add   eax,[esi+WDATA.box.left]
  599.         add   eax,[esi+WDATA.box.width]
  600.         add   eax,4*65536-4
  601.         mov   ecx,[esi+WDATA.cl_titlebar]
  602.         test  ecx,0x40000000
  603.         jz    .nofa
  604.         add   ecx,0x040404
  605.   .nofa:
  606.         test  ecx,0x80000000
  607.         jz    .nofa2
  608.         sub   ecx,0x040404
  609.   .nofa2:
  610.         mov   [esi+WDATA.cl_titlebar],ecx
  611.         and   ecx,0xffffff
  612.         xor   edi, edi
  613.         call  [draw_line]
  614.         inc   edx
  615.         cmp   edx,[esp]
  616.         jl    .drwi
  617.         add   esp,4
  618.         pop   ecx
  619.         mov   [esi+WDATA.cl_titlebar],ecx
  620.  
  621.         ret
  622.  
  623.  
  624. drawwindow_III:
  625.  
  626.         pushad
  627.  
  628.         mov   edi,edx                              ; RECTANGLE
  629.         mov   eax,[edi+WDATA.box.left]
  630.         shl   eax,16
  631.     mov   ax, word [edi+WDATA.box.left]
  632.     add   ax, word [edi+WDATA.box.width]
  633.         mov   ebx,[edi+WDATA.box.top]
  634.         shl   ebx,16
  635.     mov   bx, word [edi+WDATA.box.top]
  636.     add   bx, word [edi+WDATA.box.height]
  637.         mov   esi,[edi+WDATA.cl_frames]
  638.         shr   esi,1
  639.         and   esi,0x007f7f7f
  640.         push  esi
  641.         call  draw_rectangle
  642.         mov   ecx,3
  643.       dw3l:
  644.         add   eax,1*65536-1
  645.         add   ebx,1*65536-1
  646.         mov   esi,[edi+WDATA.cl_frames]
  647.         call  draw_rectangle
  648.         dec   ecx
  649.         jnz   dw3l
  650.         pop   esi
  651.         add   eax,1*65536-1
  652.         add   ebx,1*65536-1
  653.         call  draw_rectangle
  654.  
  655.         call    drawwindow_III_caption
  656.  
  657.         mov   edx,[esi+WDATA.box.top]                       ; WORK AREA
  658.         add   edx,21+5
  659.         mov   ebx,[esi+WDATA.box.top]
  660.         add   ebx,[esi+WDATA.box.height]
  661.         cmp   edx,ebx
  662.         jg    noinside2
  663.         mov   eax,5
  664.         mov   ebx,20
  665.         mov   ecx,[esi+WDATA.box.width]
  666.         mov   edx,[esi+WDATA.box.height]
  667.         sub   ecx,4
  668.         sub   edx,4
  669.         mov   edi,[esi+WDATA.cl_workarea]
  670.         call  [drawbar]
  671.       noinside2:
  672.  
  673.         popad
  674.  
  675.         ret
  676.  
  677.  
  678.  
  679. ; activate window
  680. align 4
  681. windowactivate:
  682.  
  683.         ; esi = abs mem position in stack 0xC400+
  684.  
  685.         pushad
  686.  
  687.      ; if type of current active window is 3,
  688.      ; it must be redrawn
  689.         mov   eax, [0x3004]
  690.         movzx eax, word [0xC400 + eax*2]
  691.         shl   eax, 5
  692.         add   eax, window_data
  693.         mov   ebx, [eax + WDATA.cl_workarea]
  694.         and   ebx, 0x0f000000
  695.         cmp   ebx, 0x03000000
  696.         jne   @f
  697.         mov   [eax + WDATA.fl_redraw], byte 1
  698.      @@:
  699.  
  700.         push   esi
  701.       movzx   eax, word [esi] ; ax <- process no
  702.       movzx   eax, word [0xC000+eax*2] ; ax <- position in window stack
  703.  
  704.         xor   esi, esi        ; drop others
  705.       waloop:
  706.         cmp   esi, dword [0x3004]
  707.         jae   wacont
  708.         inc   esi
  709.         lea   edi, [0xC000 + esi*2]
  710.         mov   bx, [edi] ; position of the current process
  711.         cmp   bx, ax
  712.         jbe   @f
  713.         dec   bx       ; upper? => drop!
  714.         mov   [edi], bx
  715.       @@:
  716.         jmp   waloop
  717.       wacont:
  718.                             ; set to no 1
  719.         pop   esi           ;   esi = pointer at 0xC400
  720.  
  721.       movzx   eax, word [esi]
  722.         mov   bx, [0x3004]  ; number of processes
  723.         mov   [0xC000+eax*2], bx     ; this is the last (and the upper)
  724.  
  725.         ; update on screen -window stack
  726.         xor   esi, esi
  727.       waloop2:
  728.         cmp     esi,[0x3004]
  729.         jae   wacont2
  730.         inc   esi
  731.         movzx ebx, word [esi*2 + 0xC000]
  732.         mov   [ebx*2 + 0xC400], si
  733.         jmp   waloop2
  734.       wacont2:
  735.         mov   [0xf400], byte 0           ; empty keyboard buffer
  736.         mov   [0xf500], byte 0           ; empty button buffer
  737.         popad
  738.         ret
  739.  
  740.  
  741. ; check if window is necessary to draw
  742.  
  743. checkwindowdraw:
  744.  
  745.         ; edi = position in window_data+
  746.  
  747.         mov   eax, [edi + WDATA.cl_workarea]
  748.         and   eax, 0x0f000000
  749.         cmp   eax, 0x03000000
  750.         je    .return_yes      ; window type 3
  751.  
  752.         mov   esi, edi
  753.         sub   esi, window_data
  754.         shr   esi, 5
  755.  
  756.         ; esi = process number
  757.  
  758.         movzx eax, word [0xC000 + esi * 2] ; get value of the curr process
  759.         lea   esi, [0xC400 + eax * 2]      ; get address of this process at 0xC400
  760.  
  761.         push  esi
  762.  
  763.       .new_check:
  764.  
  765.         pop   esi
  766.         add   esi, 2
  767.         push  esi
  768.  
  769.         mov   eax, [0x3004]
  770.         lea   eax, word [0xC400 + eax * 2] ; number of the upper window
  771.  
  772.         cmp   esi, eax
  773.         ja    .all_wnds_to_top
  774.  
  775.         movzx eax, word [esi]
  776.         shl   eax, 5
  777.         cmp   [0x3000 + eax + TASKDATA.state], byte 9
  778.         je    .new_check                    ; skip dead windows
  779.  
  780.         lea   esi, [eax+window_data]
  781.  
  782.         mov   ebx, [edi+WDATA.box.top]  ; y0
  783.         mov   edx, [edi+WDATA.box.height]
  784.         add   edx, ebx      ; y0e
  785.  
  786.         mov   ecx, [esi+WDATA.box.top]  ; y  ; y check
  787.         cmp   ecx, edx      
  788.         jae   .new_check     ; y < y0e
  789.         mov   eax, [esi+WDATA.box.height]
  790.         add   ecx, eax       ; ye
  791.         cmp   ebx, ecx       ; y0 >= ye
  792.         ja    .new_check
  793.  
  794.         mov   eax, [edi+WDATA.box.left]   ; x0
  795.         mov   ecx, [edi+WDATA.box.width]
  796.         add   ecx, eax       ; x0e
  797.  
  798.         mov   edx, [esi+WDATA.box.left]   ; x ; x check
  799.         cmp   edx, ecx
  800.         jae   .new_check     ; x < x0e
  801.         mov   ecx, [esi+WDATA.box.width]
  802.         add   edx, ecx
  803.         cmp   eax, edx
  804.         ja    .new_check
  805.  
  806.         pop   esi
  807.   .return_yes:
  808.         mov   ecx,1   ; overlap some window
  809.         ret
  810.  
  811.   .all_wnds_to_top:
  812.  
  813.         pop   esi
  814.  
  815.         xor   ecx, ecx       ; passed all windows to top
  816.         ret
  817.  
  818.  
  819.  
  820.  
  821. waredraw:     ; if redraw necessary at activate
  822.  
  823.         pushad
  824.  
  825.         call  checkwindowdraw      ; draw window on activation ?
  826.         test  ecx, ecx
  827.         jz    .do_not_draw
  828.  
  829.         popad
  830.         mov   [0xfb44], byte 1     ; do draw mouse
  831.         call  windowactivate
  832.  
  833.         ; update screen info
  834.         call    [calc_clipping_rects]
  835.         pushad
  836.         mov   edi, [0x3004] ; the last process (number)
  837.         movzx esi, word [0xC400 + edi * 2]
  838.         shl   esi, 5
  839.         add   esi, window_data
  840.  
  841.         ; coordinates of the upper window
  842.     mov   eax, [esi + WDATA.box.left]   ; cx
  843.     mov   ebx, [esi + WDATA.box.top]    ; cy
  844.     mov   ecx, [esi + WDATA.box.width]  ; sx
  845.     mov   edx, [esi + WDATA.box.height] ; sy
  846.  
  847.         add   ecx, eax       ; ecx = x_end
  848.         add   edx, ebx       ; edx = y_end
  849.  
  850.         mov   edi, [0x3004]
  851.         movzx esi, word [0xC400 + edi * 2]
  852.         call  [setscreen]
  853.         popad
  854.  
  855.     mov   [edi + WDATA.fl_redraw], 1  ; redraw flag for app
  856.     mov   [0xfb44],byte 0             ; mouse down checks
  857.  
  858.         ret
  859.  
  860.      .do_not_draw:
  861.  
  862.         popad
  863.  
  864.         call  windowactivate
  865.         mov   [0xfb44],byte 0  ; mouse down checks
  866.         mov   [0xfff4],byte 0  ; no mouse background
  867.         mov   [0xfff5],byte 0  ; draw mouse
  868.         ret
  869.  
  870.  
  871. ; eax = window number on screen
  872. ; corrupts registers and [dl*]
  873. minimize_window:
  874.         movzx eax, word [0xC400+eax*2]
  875.         shl   eax, 5
  876.         add   eax, window_data
  877.         test  [eax+WDATA.fl_wstate], WSTATE_MINIMIZED
  878.         jnz   .skip_redrawings
  879.         pushfd
  880.         cli
  881.         or    [eax+WDATA.fl_wstate], WSTATE_MINIMIZED
  882.         mov   edi, eax
  883.         ;call  calculatescreen
  884.         mov   eax, [edi+WDATA.box.left]
  885.         mov   [dlx], eax
  886.         mov   ecx, eax
  887.         add   ecx, [edi+WDATA.box.width]
  888.         mov   [dlxe], ecx
  889.         mov   ebx, [edi+WDATA.box.top]
  890.         mov   [dly], ebx
  891.         mov   edx, ebx
  892.         add   edx, [edi+WDATA.box.height]
  893.         mov   [dlye], edx
  894.         call  [calculatescreen]
  895.         xor   esi, esi
  896.         xor   eax, eax
  897.         call  redrawscreen
  898.         popfd
  899. .skip_redrawings:
  900.         ret
  901.  
  902. ; eax = window number on screen
  903. ; corrupts registers and [dl*]
  904. restore_minimized_window:
  905.         pushfd
  906.         cli
  907.         movzx esi, word [0xC400+eax*2]
  908.         mov   edi, esi
  909.         shl   edi, 5
  910.         add   edi, window_data
  911.         test  [edi+WDATA.fl_wstate], WSTATE_MINIMIZED
  912.         jz    .skip_redrawings
  913.         mov   [edi+WDATA.fl_redraw], 1
  914.         and   [edi+WDATA.fl_wstate], not WSTATE_MINIMIZED
  915.         cmp   eax, [0x3004] ; the uppermost window
  916.         jnz   .no_uppermost
  917.         mov   eax, [edi+WDATA.box.left]
  918.         mov   ebx, [edi+WDATA.box.top]
  919.         mov   ecx, eax
  920.         mov   edx, ebx
  921.         add   ecx, [edi+WDATA.box.width]
  922.         add   edx, [edi+WDATA.box.height]
  923.         call  [setscreen]
  924.         jmp   .done
  925. .no_uppermost:
  926.         mov   eax, [edi+WDATA.box.left]
  927.         mov   ebx, [edi+WDATA.box.top]
  928.         mov   ecx, eax
  929.         mov   edx, ebx
  930.         add   ecx, [edi+WDATA.box.width]
  931.         add   edx, [edi+WDATA.box.height]
  932.         call  [calculatescreen]
  933. .done:
  934.         mov   [0xfff4],byte 0 ; no mouse under
  935. .skip_redrawings:
  936.         popfd
  937.         ret
  938.  
  939.  
  940. iglobal
  941.   window_moving   db 'K : Window - move/resize',13,10,0
  942.   window_moved    db 'K : Window - done',13,10,0
  943. endg
  944.  
  945. ; check window touch
  946. align 4
  947. checkwindows:
  948.         pushad
  949.  
  950.         cmp   [window_minimize], 0
  951.         je    .no_minimizing
  952.         mov   eax, [0x3004]       ; the uppermost window
  953.         mov   bl, 0
  954.         xchg  [window_minimize], bl
  955.         cmp   bl, 1
  956.         jne   .restore
  957.         call  minimize_window
  958.         jmp   .continue
  959.   .restore:
  960.         call  restore_minimized_window
  961.   .continue:
  962.   .no_minimizing:
  963.  
  964.         cmp   [0xfb40],byte 0    ; mouse buttons pressed ?
  965.         jne   .mouse_buttons_pressed
  966.         popad
  967.         ret
  968.     .mouse_buttons_pressed:
  969.  
  970.         mov   esi,[0x3004]
  971.         inc   esi
  972.  
  973.       cwloop:
  974.         cmp   esi,2
  975.         jb   .exit
  976.  
  977.         dec   esi
  978.         movzx edi, word [0xC400 + esi * 2] ; ebx
  979.         shl   edi, 5
  980.         add   edi, window_data
  981. ;        mov   edi, ebx
  982.     mov   ecx, [edi + WDATA.box.left]
  983.     mov   edx, [edi + WDATA.box.top]
  984.  
  985.         mov   eax,ecx
  986.         mov   ebx,edx
  987.         test    [edi+WDATA.fl_wstate],WSTATE_MINIMIZED
  988.         jnz     cwloop
  989.  
  990.        movzx  eax, word [0xfb0a]
  991.        movzx  ebx, word [0xfb0c]
  992.        
  993.         cmp     eax,ecx
  994.         jl      cwloop
  995.         cmp     ebx,edx
  996.         jl      cwloop
  997.     add   ecx, [edi + WDATA.box.width]
  998.     add   edx, [edi + WDATA.box.height]
  999.         cmp   eax, ecx
  1000.         jg      cwloop
  1001.         cmp   ebx, edx
  1002.         jg      cwloop
  1003.  
  1004.         pushad
  1005.         mov   eax, esi
  1006.         mov   ebx, [0x3004]
  1007.         cmp   eax, ebx      ; is this window active?
  1008.         jz    .move_resize_window
  1009.  
  1010.         ; eax = position in windowing stack
  1011.         ; redraw must ?
  1012.         lea   esi, [0xC400 + esi * 2]
  1013.         call  waredraw
  1014.         add   esp, 32
  1015.  
  1016.       .exit:
  1017.         popad
  1018.         ret
  1019.  
  1020.    .move_resize_window:    ; MOVE OR RESIZE WINDOW
  1021.  
  1022.         popad
  1023.  
  1024.         ; Check for user enabled fixed window
  1025.     mov   edx, [edi + WDATA.cl_titlebar]
  1026.         and   edx, 0x0f000000
  1027.         cmp   edx, 0x01000000
  1028.         jne   .window_move_enabled_for_user
  1029.         popad
  1030.         ret
  1031.       .window_move_enabled_for_user:
  1032.  
  1033.     test    [edi+WDATA.fl_wstate],WSTATE_ROLLEDUP
  1034.         jnz     .no_resize_2
  1035.  
  1036.         mov   [do_resize_from_corner],byte 0   ; resize for skinned window
  1037.     mov   edx, [edi + WDATA.cl_workarea]
  1038.         and   edx, 0x0f000000
  1039.         cmp   edx, 0x02000000
  1040.         jb    .no_resize_2 ; not type 2 wnd
  1041.  
  1042.     mov   edx, [edi + WDATA.box.top]
  1043.     add   edx, [edi + WDATA.box.height]
  1044.         sub   edx, 6       ; edx = y_end - 6
  1045.         cmp   ebx, edx     ; ebx = mouse_y
  1046.         jl    .no_resize_2
  1047.         mov   [do_resize_from_corner],byte 1
  1048.         jmp   .continue
  1049.       .no_resize_2:
  1050.  
  1051.         push    eax
  1052.         call    get_titlebar_height
  1053.     add     eax,[edi + WDATA.box.top]
  1054.         cmp     ebx,eax
  1055.         pop     eax
  1056.         jae     .exit
  1057.  
  1058.      .continue:
  1059.  
  1060.         push  esi
  1061.         mov   esi, window_moving
  1062.         call  sys_msg_board_str
  1063.         pop   esi
  1064.  
  1065.         mov   ecx, [timer_ticks]     ; double-click ?
  1066.         mov   edx, ecx
  1067.         sub   edx, [latest_window_touch]
  1068.         mov   [latest_window_touch], ecx
  1069.         mov   [latest_window_touch_delta], edx
  1070.  
  1071.         mov   cl, [0xfb40]     ; save for shade check
  1072.         mov   [do_resize], cl
  1073.      no_emulation_righ_button:
  1074.     mov   ecx, [edi + WDATA.box.left]
  1075.     mov   edx, [edi + WDATA.box.top]
  1076.  
  1077.         push  eax ecx edx
  1078.         mov   [dlx], ecx      ; save for drawlimits
  1079.         mov   [dly], edx
  1080.         add   ecx, [edi + WDATA.box.width]
  1081.         add   edx, [edi + WDATA.box.height]
  1082.         mov   [dlxe], ecx
  1083.         mov   [dlye], edx
  1084.         pop   edx ecx eax
  1085.  
  1086.         sub   eax, ecx
  1087.         sub   ebx, edx
  1088.  
  1089.         mov   esi, [0xfb0a]
  1090.         mov   [0xf300], esi
  1091.  
  1092.         push  eax;ad           ; wait for putimages to finish
  1093. ;        mov   eax,5
  1094. ;        call  delay_hs
  1095.     mov   eax,[edi + WDATA.box.left]
  1096.         mov   [npx],eax
  1097.     mov   eax,[edi + WDATA.box.top]
  1098.         mov   [npy],eax
  1099.  
  1100.                                   ; save old coordinates
  1101.         mov   eax, [edi + WDATA.box.left]
  1102.         mov   [oldc+BOX.left], eax
  1103.         mov   eax, [edi + WDATA.box.top]
  1104.         mov   [oldc+BOX.top], eax
  1105.         mov   eax, [edi + WDATA.box.width]
  1106.         mov   [oldc+BOX.width], eax
  1107.         mov   [npxe], eax
  1108.         mov   eax, [edi + WDATA.box.height]
  1109.         mov   [oldc+BOX.height], eax
  1110.         mov   [npye], eax
  1111.         pop eax
  1112.  
  1113.         test    [edi+WDATA.fl_wstate],WSTATE_MAXIMIZED
  1114.         jnz     @f
  1115.         call  drawwindowframes
  1116.     @@:
  1117.  
  1118.         mov   [reposition],0
  1119.         mov   [0xfb44],byte 1   ; no reaction to mouse up/down
  1120.  
  1121.         ; move window
  1122.  
  1123.       newchm:
  1124.  
  1125.         mov   [0xfff5],byte 1
  1126.  
  1127.         call  checkidle
  1128.  
  1129.         call  checkVga_N13
  1130.  
  1131.         mov   [0xfff4],byte 0
  1132.  
  1133.         call  [draw_pointer]
  1134.  
  1135.         pushad
  1136.         call   stack_handler
  1137.         popad
  1138.  
  1139.         mov   esi,[0xf300]
  1140.         cmp   esi,[0xfb0a]
  1141.         je    cwb
  1142.  
  1143.         movzx ecx,word[0xfb0a]
  1144.         movzx edx,word[0xfb0c]
  1145.         sub   ecx,eax
  1146.         sub   edx,ebx
  1147.         push  eax
  1148.         push  ebx
  1149.         test    [edi+WDATA.fl_wstate],WSTATE_MAXIMIZED
  1150.         jnz     @f
  1151.         call  drawwindowframes
  1152.     @@:
  1153.  
  1154.         mov   ax,[0xfe00]
  1155.         mov   bx,[0xfe04]
  1156.  
  1157.         cmp   [do_resize_from_corner],1
  1158.         je    no_new_position
  1159.  
  1160.         mov   [reposition],1
  1161.         movsx ecx,cx
  1162.         mov   [npx],ecx
  1163.       noreposx:
  1164.  
  1165.         mov   [reposition],1
  1166.         movsx edx,dx
  1167.         mov   [npy],edx
  1168.       noreposy:
  1169.  
  1170.       no_new_position:
  1171.  
  1172.         cmp   [do_resize_from_corner],0    ; resize from right corner
  1173.         je    norepos_size
  1174.         pushad
  1175.  
  1176.         mov   edx,edi
  1177.         sub   edx,window_data
  1178.         ;shr   edx,5
  1179.         ;shl   edx,8
  1180.         ;add   edx,0x80000                 ; process base at 0x80000+
  1181.     lea   edx, [0x80000 + edx*8]
  1182.  
  1183.         movzx eax,word [0xfb0a]
  1184.     cmp   eax,[edi + WDATA.box.left]
  1185.         jl    nnepx
  1186.     sub   eax,[edi + WDATA.box.left]
  1187.         cmp   eax,32 ; [edx+0x90+8]
  1188.         jge   nnepx2
  1189.         mov   eax,32 ; [edx+0x90+8]
  1190.       nnepx2:
  1191.         mov   [npxe],eax
  1192.       nnepx:
  1193.  
  1194.         call    get_rolledup_height
  1195.         mov     ebx,eax
  1196.         movzx eax,word [0xfb0c]
  1197.     cmp   eax,[edi + WDATA.box.top]
  1198.         jl    nnepy
  1199.     sub   eax,[edi + WDATA.box.top]
  1200.         cmp     eax,ebx ; [edx+0x90+12]
  1201.         jge     nnepy2
  1202.         mov     eax,ebx ; [edx+0x90+12]
  1203.       nnepy2:
  1204.         mov   [npye],eax
  1205.       nnepy:
  1206.  
  1207.         mov   [reposition],1
  1208.  
  1209.         popad
  1210.       norepos_size:
  1211.  
  1212.         pop   ebx
  1213.         pop   eax
  1214.         test    [edi+WDATA.fl_wstate],WSTATE_MAXIMIZED
  1215.         jnz     @f
  1216.         call  drawwindowframes
  1217.     @@:
  1218.  
  1219.         mov   esi,[0xfb0a]
  1220.         mov   [0xf300],esi
  1221.  
  1222.       cwb:
  1223.         cmp   [0xfb40],byte 0
  1224.         jne   newchm
  1225.                                      ; new position done
  1226.         mov     [0xfff5],byte 1
  1227.         mov     cl,0
  1228.         test    [edi+WDATA.fl_wstate],WSTATE_MAXIMIZED
  1229.         jnz     @f
  1230.         mov     cl,[reposition]
  1231.         call    drawwindowframes
  1232.  
  1233.         mov   eax,[npx]
  1234.     mov   [edi + WDATA.box.left],eax
  1235.         mov   eax,[npy]
  1236.     mov   [edi + WDATA.box.top],eax
  1237.         mov   eax,[npxe]
  1238.     mov   [edi + WDATA.box.width],eax
  1239.         mov   eax,[npye]
  1240.     mov   [edi + WDATA.box.height],eax
  1241.  
  1242.     @@: mov     [reposition],cl
  1243.  
  1244.         cmp   [reposition],1         ; save new position and size
  1245.         jne   no_bounds_save
  1246.         push  esi edi ecx
  1247.         mov   esi,edi
  1248.         mov   ecx,2
  1249.         test  [edi+WDATA.fl_wstate],WSTATE_ROLLEDUP or WSTATE_MAXIMIZED
  1250.         jnz   @f
  1251.         add   ecx,2
  1252.     @@: sub   edi,window_data
  1253.         shr   edi,5
  1254.         shl   edi,8
  1255.         add   edi,0x80000+APPDATA.saved_box
  1256.         cld
  1257.         rep   movsd
  1258.         pop   ecx edi esi
  1259.       no_bounds_save:
  1260.  
  1261.         pushad                             ; WINDOW SHADE/FULLSCREEN
  1262.  
  1263.         cmp   [reposition],1
  1264.         je    no_window_sizing
  1265.         mov   edx,edi
  1266.         sub   edx,window_data
  1267.         shr   edx,5
  1268.         shl   edx,8
  1269.         add   edx,0x80000                 ; process base at 0x80000+
  1270.  
  1271.         cmp   [do_resize],2               ; window shade ?
  1272.         jne   no_window_shade
  1273.         mov   [reposition],1
  1274.  
  1275.         test    [edi+WDATA.fl_wstate],WSTATE_ROLLEDUP
  1276.         jnz     wnd_rolldown
  1277.   wnd_rollup:
  1278.         or      [edi+WDATA.fl_wstate],WSTATE_ROLLEDUP
  1279.         call    get_rolledup_height
  1280.         jmp     @f
  1281.   wnd_rolldown:
  1282.         and     [edi+WDATA.fl_wstate],not WSTATE_ROLLEDUP
  1283.     mov     eax,[edx + APPDATA.saved_box.height] ; 0x90+BOX.height
  1284.         test    [edi+WDATA.fl_wstate],WSTATE_MAXIMIZED
  1285.         jz      @f
  1286.         mov     eax,[screen_workarea.bottom]
  1287.         sub     eax,[screen_workarea.top]
  1288.     @@: mov     [edi+WDATA.box.height],eax
  1289.  
  1290.       no_window_shade:
  1291.  
  1292.         cmp   [do_resize],1               ; fullscreen/restore ?
  1293.         jne   no_fullscreen_restore
  1294.         cmp   [latest_window_touch_delta],dword 50
  1295.         jg    no_fullscreen_restore
  1296.         mov   [reposition],1
  1297.         test    [edi+WDATA.fl_wstate],WSTATE_MAXIMIZED
  1298.         jnz     restore_from_fullscreen
  1299.         or      [edi+WDATA.fl_wstate],WSTATE_MAXIMIZED
  1300.         mov     eax,[screen_workarea.left]
  1301.         mov     [edi+WDATA.box.left],eax
  1302.         sub     eax,[screen_workarea.right]
  1303.         neg     eax
  1304.         mov     [edi+WDATA.box.width],eax
  1305.         mov     eax,[screen_workarea.top]
  1306.         mov     [edi+WDATA.box.top],eax
  1307.         test    [edi+WDATA.fl_wstate],WSTATE_ROLLEDUP
  1308.         jnz     @f
  1309.         sub     eax,[screen_workarea.bottom]
  1310.         neg     eax
  1311.         mov     [edi+WDATA.box.height],eax
  1312.     @@:
  1313.         jmp   no_fullscreen_restore
  1314.       restore_from_fullscreen:
  1315.         and     [edi+WDATA.fl_wstate],not WSTATE_MAXIMIZED
  1316.         push    [edi+WDATA.box.height]
  1317.         push  edi                         ; restore
  1318.         lea   esi, [edx + APPDATA.saved_box]
  1319.         mov   ecx,4
  1320.         cld
  1321.         rep   movsd
  1322.         pop   edi
  1323.         pop     eax
  1324.         test    [edi+WDATA.fl_wstate],WSTATE_ROLLEDUP
  1325.         jz      @f
  1326.         mov     [edi+WDATA.box.height],eax
  1327.     @@:
  1328.  
  1329.       no_fullscreen_restore:
  1330.  
  1331.       no_window_sizing:
  1332.  
  1333.         popad
  1334.  
  1335.         cmp   [reposition],0
  1336.         je    retwm
  1337.  
  1338.         mov   [0xfff5],byte 1 ; no mouse
  1339.         call    [calc_clipping_rects]
  1340.  
  1341.         mov   eax,edi
  1342.         call  redrawscreen
  1343.  
  1344.  
  1345.         mov     [edi+WDATA.fl_redraw],1
  1346.  
  1347.         mov   ecx,100         ; wait to avoid mouse residuals
  1348.       waitre2:
  1349.         mov   [0xfff5],byte 1
  1350.         call  checkidle
  1351.         cmp     [edi+WDATA.fl_redraw],0
  1352.         jz    retwm
  1353.         loop  waitre2
  1354.  
  1355.       retwm:
  1356.  
  1357.         mov   [0xfff5],byte 0 ; mouse pointer
  1358.         mov   [0xfff4],byte 0 ; no mouse under
  1359.         mov   [0xfb44],byte 0 ; react to mouse up/down
  1360.  
  1361.         mov    esi,window_moved
  1362.         call   sys_msg_board_str
  1363.  
  1364.         popad
  1365.  
  1366.         ret
  1367.  
  1368.  
  1369. uglobal
  1370.   add_window_data            dd  0
  1371.   do_resize_from_corner      db  0x0
  1372.   reposition                 db  0x0
  1373.   latest_window_touch        dd  0x0
  1374.   latest_window_touch_delta  dd  0x0
  1375.  
  1376.   do_resize db 0x0
  1377.  
  1378.   oldc    dd 0x0,0x0,0x0,0x0
  1379.  
  1380.   dlx     dd 0x0
  1381.   dly     dd 0x0
  1382.   dlxe    dd 0x0
  1383.   dlye    dd 0x0
  1384.  
  1385.   npx     dd 0x0
  1386.   npy     dd 0x0
  1387.   npxe    dd 0x0
  1388.   npye    dd 0x0
  1389.  
  1390.   mpx     dd 0x0
  1391.   mpy     dd 0x0
  1392. endg
  1393.  
  1394.  
  1395. ; draw negative window frames
  1396.  
  1397. drawwindowframes:
  1398.  
  1399.         pushad
  1400.  
  1401.         mov   eax,[npx]
  1402.         shl   eax,16
  1403.         add   eax,[npx]
  1404.         add   eax,[npxe]
  1405.         add   eax,65536*1-1
  1406.         mov   ebx,[npy]
  1407.         shl   ebx,16
  1408.         add   ebx,[npy]
  1409.         mov   ecx,0x01000000
  1410.         push  edi
  1411.         mov   edi,1
  1412.         call  [draw_line]
  1413.         pop   edi
  1414.  
  1415.         mov   eax,[npx]
  1416.         shl   eax,16
  1417.         add   eax,[npx]
  1418.         add   eax,[npxe]
  1419.         add   eax,65536*1-1
  1420.         mov   ebx,[npy]
  1421.         add   ebx,[npye]
  1422.         shl   ebx,16
  1423.         add   ebx,[npy]
  1424.         add   ebx,[npye]
  1425.         mov   ecx,0x01000000
  1426.         push  edi
  1427.         mov   edi,1
  1428.         call  [draw_line]
  1429.         pop   edi
  1430.  
  1431.         mov   eax,[npx]
  1432.         shl   eax,16
  1433.         add   eax,[npx]
  1434.         mov   ebx,[npy]
  1435.         shl   ebx,16
  1436.         add   ebx,[npy]
  1437.         add   ebx,[npye]
  1438.         mov   ecx,0x01000000
  1439.         push  edi
  1440.         mov   edi,1
  1441.         call  [draw_line]
  1442.         pop   edi
  1443.  
  1444.         mov   eax,[npx]
  1445.         add   eax,[npxe]
  1446.         shl   eax,16
  1447.         add   eax,[npx]
  1448.         add   eax,[npxe]
  1449.         mov   ebx,[npy]
  1450.         shl   ebx,16
  1451.         add   ebx,[npy]
  1452.         add   ebx,[npye]
  1453.         mov   ecx,0x01000000
  1454.         push  edi
  1455.         mov   edi,1
  1456.         call  [draw_line]
  1457.         mov   edi,[0x3000]
  1458.         shl   edi,5
  1459.         add   edi,window_data
  1460.         mov   [edi+WDATA.fl_wdrawn],byte 1
  1461.         pop   edi
  1462.  
  1463.         popad
  1464.  
  1465.         ret
  1466.  
  1467.  
  1468.  
  1469. random_shaped_window:
  1470.  
  1471. ;
  1472. ;  eax = 0    giving address of data area
  1473. ;      ebx    address
  1474. ;  eax = 1    shape area scale
  1475. ;      ebx    2^ebx scale
  1476.  
  1477.      test eax, eax
  1478.      jne  rsw_no_address
  1479.      mov  eax,[0x3000]
  1480.      shl  eax,8
  1481.  
  1482.      mov  [eax+0x80000+APPDATA.wnd_shape],ebx
  1483.    rsw_no_address:
  1484.  
  1485.      cmp  eax,1
  1486.      jne  rsw_no_scale
  1487.      mov  eax,[0x3000]
  1488.      shl  eax,8
  1489.      mov  byte [eax+0x80000+APPDATA.wnd_shape_scale], bl
  1490.    rsw_no_scale:
  1491.  
  1492.      ret
  1493.  
  1494.  
  1495.