Subversion Repositories Kolibri OS

Rev

Rev 1635 | Rev 2439 | Go to most recent revision | Blame | Compare with Previous | Last modification | View Log | Download | RSS feed

  1. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  2. ;;                                                              ;;
  3. ;; Copyright (C) KolibriOS team 2004-2008. All rights reserved. ;;
  4. ;; Distributed under terms of the GNU General Public License    ;;
  5. ;;                                                              ;;
  6. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  7.  
  8. $Revision: 2434 $
  9.  
  10.  
  11. LOAD_FROM_FILE  equ 0
  12. LOAD_FROM_MEM   equ 1
  13. LOAD_INDIRECT   equ 2
  14. LOAD_SYSTEM     equ 3
  15.  
  16. struct  BITMAPINFOHEADER
  17.         Size                    dd ?
  18.         Width                   dd ?
  19.         Height                  dd ?
  20.         Planes                  dw ?
  21.         BitCount                dw ?
  22.         Compression             dd ?
  23.         SizeImage               dd ?
  24.         XPelsPerMeter           dd ?
  25.         YPelsPerMeter           dd ?
  26.         ClrUsed                 dd ?
  27.         ClrImportant            dd ?
  28. ends
  29. ;------------------------------------------------------------------------------
  30. align 4
  31. proc init_cursor stdcall, dst:dword, src:dword
  32.            locals
  33.              rBase    dd ?
  34.              pQuad    dd ?
  35.              pBits    dd ?
  36.              pAnd     dd ?
  37.              width    dd ?
  38.              height   dd ?
  39.              counter  dd ?
  40.            endl
  41.  
  42.         mov     esi, [src]
  43.         add     esi, [esi+18]
  44.         mov     eax, esi
  45.  
  46.         cmp     [esi+BITMAPINFOHEADER.BitCount], 24
  47.         je      .img_24
  48.         cmp     [esi+BITMAPINFOHEADER.BitCount], 8
  49.         je      .img_8
  50.         cmp     [esi+BITMAPINFOHEADER.BitCount], 4
  51.         je      .img_4
  52. ;--------------------------------------
  53. align 4
  54. .img_2:
  55.         add     eax, [esi]
  56.         mov     [pQuad], eax
  57.         add     eax, 8
  58.         mov     [pBits], eax
  59.         add     eax, 128
  60.         mov     [pAnd], eax
  61.         mov     eax, [esi+4]
  62.         mov     [width], eax
  63.         mov     ebx, [esi+8]
  64.         shr     ebx, 1
  65.         mov     [height], ebx
  66.  
  67.         mov     edi, [dst]
  68.         add     edi, 32*31*4
  69.         mov     [rBase], edi
  70.  
  71.         mov     esi, [pQuad]
  72. ;--------------------------------------
  73. align 4
  74. .l21:
  75.         mov     ebx, [pBits]
  76.         mov     ebx, [ebx]
  77.         bswap   ebx
  78.         mov     eax, [pAnd]
  79.         mov     eax, [eax]
  80.         bswap   eax
  81.         mov     [counter], 32
  82. ;--------------------------------------
  83. align 4
  84. @@:
  85.         xor     edx, edx
  86.         shl     eax, 1
  87.         setc    dl
  88.         dec     edx
  89.  
  90.         xor     ecx, ecx
  91.         shl     ebx, 1
  92.         setc    cl
  93.         mov     ecx, [esi+ecx*4]
  94.         and     ecx, edx
  95.         and     edx, 0xFF000000
  96.         or      edx, ecx
  97.         mov     [edi], edx
  98.  
  99.         add     edi, 4
  100.         dec     [counter]
  101.         jnz     @B
  102.  
  103.         add     [pBits], 4
  104.         add     [pAnd], 4
  105.         mov     edi, [rBase]
  106.         sub     edi, 128
  107.         mov     [rBase], edi
  108.         sub     [height], 1
  109.         jnz     .l21
  110.         ret
  111. ;--------------------------------------
  112. align 4
  113. .img_4:
  114.         add     eax, [esi]
  115.         mov     [pQuad], eax
  116.         add     eax, 64
  117.         mov     [pBits], eax
  118.         add     eax, 0x200
  119.         mov     [pAnd], eax
  120.         mov     eax, [esi+4]
  121.         mov     [width], eax
  122.         mov     ebx, [esi+8]
  123.         shr     ebx, 1
  124.         mov     [height], ebx
  125.  
  126.         mov     edi, [dst]
  127.         add     edi, 32*31*4
  128.         mov     [rBase], edi
  129.  
  130.         mov     esi, [pQuad]
  131.         mov     ebx, [pBits]
  132. ;--------------------------------------
  133. align 4
  134. .l4:
  135.         mov     eax, [pAnd]
  136.         mov     eax, [eax]
  137.         bswap   eax
  138.         mov     [counter], 16
  139. ;--------------------------------------
  140. align 4
  141. @@:
  142.         xor     edx, edx
  143.         shl     eax, 1
  144.         setc    dl
  145.         dec     edx
  146.  
  147.         movzx   ecx, byte [ebx]
  148.         and     cl, 0xF0
  149.         shr     ecx, 2
  150.         mov     ecx, [esi+ecx]
  151.         and     ecx, edx
  152.         and     edx, 0xFF000000
  153.         or      edx, ecx
  154.         mov     [edi], edx
  155.  
  156.         xor     edx, edx
  157.         shl     eax, 1
  158.         setc    dl
  159.         dec     edx
  160.  
  161.         movzx   ecx, byte [ebx]
  162.         and     cl, 0x0F
  163.         mov     ecx, [esi+ecx*4]
  164.         and     ecx, edx
  165.         and     edx, 0xFF000000
  166.         or      edx, ecx
  167.         mov     [edi+4], edx
  168.  
  169.         inc     ebx
  170.         add     edi, 8
  171.         dec     [counter]
  172.         jnz     @B
  173.  
  174.         add     [pAnd], 4
  175.         mov     edi, [rBase]
  176.         sub     edi, 128
  177.         mov     [rBase], edi
  178.         sub     [height], 1
  179.         jnz     .l4
  180.         ret
  181. ;--------------------------------------
  182. align 4
  183. .img_8:
  184.         add     eax, [esi]
  185.         mov     [pQuad], eax
  186.         add     eax, 1024
  187.         mov     [pBits], eax
  188.         add     eax, 1024
  189.         mov     [pAnd], eax
  190.         mov     eax, [esi+4]
  191.         mov     [width], eax
  192.         mov     ebx, [esi+8]
  193.         shr     ebx, 1
  194.         mov     [height], ebx
  195.  
  196.         mov     edi, [dst]
  197.         add     edi, 32*31*4
  198.         mov     [rBase], edi
  199.  
  200.         mov     esi, [pQuad]
  201.         mov     ebx, [pBits]
  202. ;--------------------------------------
  203. align 4
  204. .l81:
  205.         mov     eax, [pAnd]
  206.         mov     eax, [eax]
  207.         bswap   eax
  208.         mov     [counter], 32
  209. ;--------------------------------------
  210. align 4
  211. @@:
  212.         xor     edx, edx
  213.         shl     eax, 1
  214.         setc    dl
  215.         dec     edx
  216.  
  217.         movzx   ecx, byte [ebx]
  218.         mov     ecx, [esi+ecx*4]
  219.         and     ecx, edx
  220.         and     edx, 0xFF000000
  221.         or      edx, ecx
  222.         mov     [edi], edx
  223.  
  224.         inc     ebx
  225.         add     edi, 4
  226.         dec     [counter]
  227.         jnz     @B
  228.  
  229.         add     [pAnd], 4
  230.         mov     edi, [rBase]
  231.         sub     edi, 128
  232.         mov     [rBase], edi
  233.         sub     [height], 1
  234.         jnz     .l81
  235.         ret
  236. ;--------------------------------------
  237. align 4
  238. .img_24:
  239.         add     eax, [esi]
  240.         mov     [pQuad], eax
  241.         add     eax, 0xC00
  242.         mov     [pAnd], eax
  243.         mov     eax, [esi+BITMAPINFOHEADER.Width]
  244.         mov     [width], eax
  245.         mov     ebx, [esi+BITMAPINFOHEADER.Height]
  246.         shr     ebx, 1
  247.         mov     [height], ebx
  248.  
  249.         mov     edi, [dst]
  250.         add     edi, 32*31*4
  251.         mov     [rBase], edi
  252.  
  253.         mov     esi, [pAnd]
  254.         mov     ebx, [pQuad]
  255. ;--------------------------------------
  256. align 4
  257. .row_24:
  258.         mov     eax, [esi]
  259.         bswap   eax
  260.         mov     [counter], 32
  261. ;--------------------------------------
  262. align 4
  263. @@:
  264.         xor     edx, edx
  265.         shl     eax, 1
  266.         setc    dl
  267.         dec     edx
  268.  
  269.         mov     ecx, [ebx]
  270.         and     ecx, 0x00FFFFFF
  271.         and     ecx, edx
  272.         and     edx, 0xFF000000
  273.         or      edx, ecx
  274.         mov     [edi], edx
  275.         add     ebx, 3
  276.         add     edi, 4
  277.         dec     [counter]
  278.         jnz     @B
  279.  
  280.         add     esi, 4
  281.         mov     edi, [rBase]
  282.         sub     edi, 128
  283.         mov     [rBase], edi
  284.         sub     [height], 1
  285.         jnz     .row_24
  286.         ret
  287. endp
  288. ;------------------------------------------------------------------------------
  289. align 4
  290. proc set_cursor stdcall, hcursor:dword
  291.         mov     eax, [hcursor]
  292.         cmp     [eax+CURSOR.magic], 'CURS'
  293.         jne     .fail
  294. ;           cmp [eax+CURSOR.size], CURSOR_SIZE
  295. ;           jne .fail
  296.         mov     ebx, [current_slot]
  297.         xchg    eax, [ebx+APPDATA.cursor]
  298.         ret
  299. ;--------------------------------------
  300. align 4
  301. .fail:
  302.         mov     eax, [def_cursor]
  303.         mov     ebx, [current_slot]
  304.         xchg    eax, [ebx+APPDATA.cursor]
  305.         ret
  306. endp
  307. ;------------------------------------------------------------------------------
  308. align 4
  309. ; param
  310. ;  eax= pid
  311. ;  ebx= src
  312. ;  ecx= flags
  313.  
  314. create_cursor:
  315. .src     equ esp
  316. .flags   equ esp+4
  317. .hcursor equ esp+8
  318.  
  319.         sub     esp, 4         ;space for .hcursor
  320.         push    ecx
  321.         push    ebx
  322.  
  323.         mov     ebx, eax
  324.         mov     eax, sizeof.CURSOR
  325.         call    create_kernel_object
  326.         test    eax, eax
  327.         jz      .fail
  328.  
  329.         mov     [.hcursor], eax
  330.  
  331.         xor     ebx, ebx
  332.         mov     [eax+CURSOR.magic], 'CURS'
  333.         mov     [eax+CURSOR.destroy], destroy_cursor
  334.         mov     [eax+CURSOR.hot_x], ebx
  335.         mov     [eax+CURSOR.hot_y], ebx
  336.  
  337.         stdcall kernel_alloc, 0x1000
  338.         test    eax, eax
  339.         jz      .fail
  340.  
  341.         mov     edi, [.hcursor]
  342.         mov     [edi+CURSOR.base], eax
  343.  
  344.         mov     esi, [.src]
  345.         mov     ebx, [.flags]
  346.         cmp     bx, LOAD_INDIRECT
  347.         je      .indirect
  348.  
  349.         movzx   ecx, word [esi+10]
  350.         movzx   edx, word [esi+12]
  351.         mov     [edi+CURSOR.hot_x], ecx
  352.         mov     [edi+CURSOR.hot_y], edx
  353.  
  354.         stdcall init_cursor, eax, esi
  355.  
  356.         mov     ecx, [.hcursor]
  357.         lea     ecx, [ecx+CURSOR.list_next]
  358.         lea     edx, [_display.cr_list.next]
  359.  
  360.         pushfd
  361.         cli
  362.         list_add ecx, edx   ;list_add_tail(new, head)
  363.         popfd
  364.  
  365.         mov     eax, [.hcursor]
  366. ;--------------------------------------
  367. align 4
  368. .check_hw:
  369.         cmp     [_display.init_cursor], 0
  370.         je      .fail
  371.  
  372.         push    eax
  373.         call    [_display.init_cursor]
  374.         add     esp, 4
  375.  
  376.         mov     eax, [.hcursor]
  377. ;--------------------------------------
  378. align 4
  379. .fail:
  380.         add     esp, 12
  381.         ret
  382. ;--------------------------------------
  383. align 4
  384. .indirect:
  385.         shr     ebx, 16
  386.         movzx   ecx, bh
  387.         movzx   edx, bl
  388.         mov     [eax+CURSOR.hot_x], ecx
  389.         mov     [eax+CURSOR.hot_y], edx
  390.  
  391.         xchg    edi, eax
  392.         mov     ecx, 1024
  393.         cld
  394.         rep movsd
  395.         jmp     .check_hw
  396. ;------------------------------------------------------------------------------
  397. align 4
  398. proc load_cursor stdcall, src:dword, flags:dword
  399.            locals
  400.              handle  dd ?
  401.            endl
  402.  
  403.         xor     eax, eax
  404.         cmp     [create_cursor], eax
  405.         je      .fail2
  406.  
  407.         mov     [handle], eax
  408.         cmp     word [flags], LOAD_FROM_FILE
  409.         jne     @F
  410.  
  411.         stdcall load_file, [src]
  412.         test    eax, eax
  413.         jz      .fail
  414.         mov     [src], eax
  415. ;--------------------------------------
  416. align 4
  417. @@:
  418.         push    ebx
  419.         push    esi
  420.         push    edi
  421.  
  422.         mov     eax, [CURRENT_TASK]
  423.         shl     eax, 5
  424.         mov     eax, [CURRENT_TASK+eax+4]
  425.         mov     ebx, [src]
  426.         mov     ecx, [flags]
  427.         call    create_cursor    ;eax, ebx, ecx
  428.         mov     [handle], eax
  429.  
  430.         cmp     word [flags], LOAD_FROM_FILE
  431.         jne     .exit
  432.         stdcall kernel_free, [src]
  433. ;--------------------------------------
  434. align 4
  435. .exit:
  436.         pop     edi
  437.         pop     esi
  438.         pop     ebx
  439. ;--------------------------------------
  440. align 4
  441. .fail:
  442.         mov     eax, [handle]
  443. ;--------------------------------------
  444. align 4
  445. .fail2:
  446.         ret
  447. endp
  448. ;------------------------------------------------------------------------------
  449. align 4
  450. proc delete_cursor stdcall, hcursor:dword
  451.            locals
  452.              hsrv       dd ?
  453.              io_code    dd ?
  454.              input      dd ?
  455.              inp_size   dd ?
  456.              output     dd ?
  457.              out_size   dd ?
  458.            endl
  459.  
  460.         mov     esi, [hcursor]
  461.         cmp     [esi+CURSOR.magic], 'CURS'
  462.         jne     .fail
  463.  
  464.         mov     ebx, [CURRENT_TASK]
  465.         shl     ebx, 5
  466.         mov     ebx, [CURRENT_TASK+ebx+4]
  467.         cmp     ebx, [esi+CURSOR.pid]
  468.         jne     .fail
  469.  
  470.         mov     ebx, [current_slot]
  471.         cmp     esi, [ebx+APPDATA.cursor]
  472.         jne     @F
  473.         mov     eax, [def_cursor]
  474.         mov     [ebx+APPDATA.cursor], eax
  475. ;--------------------------------------
  476. align 4
  477. @@:
  478.         mov     eax, [hcursor]
  479.         call    [eax+APPOBJ.destroy]
  480. ;--------------------------------------
  481. align 4
  482. .fail:
  483.         ret
  484. endp
  485. ;------------------------------------------------------------------------------
  486. align 4
  487. ; param
  488. ;  eax= cursor
  489. destroy_cursor:
  490.  
  491.         push    eax
  492.         stdcall kernel_free, [eax+CURSOR.base]
  493.  
  494.         mov     eax, [esp]
  495.         lea     eax, [eax+CURSOR.list_next]
  496.  
  497.         pushfd
  498.         cli
  499.         list_del eax
  500.         popfd
  501.  
  502.         pop     eax
  503.         call    destroy_kernel_object
  504.         ret
  505. ;------------------------------------------------------------------------------
  506. align 4
  507. select_cursor:
  508.         mov     eax, [esp+4]
  509.         mov     [_display.cursor], eax
  510.         ret     4
  511. ;------------------------------------------------------------------------------
  512. align 4
  513. proc restore_24 stdcall, x:dword, y:dword
  514.  
  515.         push    ebx
  516.  
  517.         mov     ebx, [cur_saved_base]
  518.         mov     edx, [cur.h]
  519.         test    edx, edx
  520.         jz      .ret
  521.  
  522.         push    esi
  523.         push    edi
  524.  
  525.         mov     esi, cur_saved_data
  526.         mov     ecx, [cur.w]
  527.         lea     ecx, [ecx+ecx*2]
  528.         push    ecx
  529. ;--------------------------------------
  530. align 4
  531. @@:
  532.         mov     edi, ebx
  533.         add     ebx, [BytesPerScanLine]
  534.  
  535.         mov     ecx, [esp]
  536.         rep movsb
  537.         dec     edx
  538.         jnz     @B
  539.  
  540.         pop     ecx
  541.         pop     edi
  542.         pop     esi
  543. ;--------------------------------------
  544. align 4
  545. .ret:
  546.         pop     ebx
  547.         ret
  548. endp
  549. ;------------------------------------------------------------------------------
  550. align 4
  551. proc restore_32 stdcall, x:dword, y:dword
  552.  
  553.         push    ebx
  554.  
  555.         mov     ebx, [cur_saved_base]
  556.         mov     edx, [cur.h]
  557.         test    edx, edx
  558.         jz      .ret
  559.  
  560.         push    esi
  561.         push    edi
  562.  
  563.         mov     esi, cur_saved_data
  564. ;--------------------------------------
  565. align 4
  566. @@:
  567.         mov     edi, ebx
  568.         add     ebx, [BytesPerScanLine]
  569.  
  570.         mov     ecx, [cur.w]
  571.         rep movsd
  572.         dec     edx
  573.         jnz     @B
  574.  
  575.         pop     edi
  576. ;--------------------------------------
  577. align 4
  578. .ret:
  579.         pop     esi
  580.         pop     ebx
  581.         ret
  582. endp
  583. ;------------------------------------------------------------------------------
  584. align 4
  585. proc move_cursor_24 stdcall, hcursor:dword, x:dword, y:dword
  586.            locals
  587.              h      dd ?
  588.              _dx     dd ?
  589.              _dy     dd ?
  590.            endl
  591.  
  592.         mov     esi, [hcursor]
  593.         mov     ecx, [x]
  594.         mov     eax, [y]
  595.         mov     ebx, [BytesPerScanLine]
  596.  
  597.         xor     edx, edx
  598.         sub     ecx, [esi+CURSOR.hot_x]
  599.         lea     ebx, [ecx+32-1]
  600.         mov     [x], ecx
  601.         sets    dl
  602.         dec     edx
  603.         and     ecx, edx      ;clip x to 0<=x
  604.         mov     [cur.left], ecx
  605.         mov     edi, ecx
  606.         sub     edi, [x]
  607.         mov     [_dx], edi
  608.  
  609.         xor     edx, edx
  610.         sub     eax, [esi+CURSOR.hot_y]
  611.         lea     edi, [eax+32-1]
  612.         mov     [y], eax
  613.         sets    dl
  614.         dec     edx
  615.         and     eax, edx      ;clip y to 0<=y
  616.         mov     [cur.top], eax
  617.         mov     edx, eax
  618.         sub     edx, [y]
  619.         mov     [_dy], edx
  620.  
  621.         mul     dword [BytesPerScanLine]
  622.         lea     edx, [LFB_BASE+ecx*3]
  623.         add     edx, eax
  624.         mov     [cur_saved_base], edx
  625.  
  626.         cmp     ebx, [Screen_Max_X]
  627.         jbe     @F
  628.         mov     ebx, [Screen_Max_X]
  629. ;--------------------------------------
  630. align 4
  631. @@:
  632.         cmp     edi, [Screen_Max_Y]
  633.         jbe     @F
  634.         mov     edi, [Screen_Max_Y]
  635. ;--------------------------------------
  636. align 4
  637. @@:
  638.         mov     [cur.right], ebx
  639.         mov     [cur.bottom], edi
  640.  
  641.         sub     ebx, [x]
  642.         sub     edi, [y]
  643.         inc     ebx
  644.         inc     edi
  645.  
  646.         mov     [cur.w], ebx
  647.         mov     [cur.h], edi
  648.         mov     [h], edi
  649.  
  650.         mov     eax, edi
  651.         mov     edi, cur_saved_data
  652. ;--------------------------------------
  653. align 4
  654. @@:
  655.         mov     esi, edx
  656.         add     edx, [BytesPerScanLine]
  657.         mov     ecx, [cur.w]
  658.         lea     ecx, [ecx+ecx*2]
  659.         rep movsb
  660.         dec     eax
  661.         jnz     @B
  662.  
  663. ;draw cursor
  664.         mov     ebx, [cur_saved_base]
  665.         mov     eax, [_dy]
  666.         shl     eax, 5
  667.         add     eax, [_dx]
  668.  
  669.         mov     esi, [hcursor]
  670.         mov     esi, [esi+CURSOR.base]
  671.         lea     edx, [esi+eax*4]
  672. ;--------------------------------------
  673. align 4
  674. .row:
  675.         mov     ecx, [cur.w]
  676.         mov     esi, edx
  677.         mov     edi, ebx
  678.         add     edx, 32*4
  679.         add     ebx, [BytesPerScanLine]
  680. ;--------------------------------------
  681. align 4
  682. .pix:
  683.         lodsd
  684.         test    eax, 0xFF000000
  685.         jz      @F
  686.         mov     [edi], ax
  687.         shr     eax, 16
  688.         mov     [edi+2], al
  689. ;--------------------------------------
  690. align 4
  691. @@:
  692.         add     edi, 3
  693.         dec     ecx
  694.         jnz     .pix
  695.  
  696.         dec     [h]
  697.         jnz     .row
  698.         ret
  699. endp
  700. ;------------------------------------------------------------------------------
  701. align 4
  702. proc move_cursor_32 stdcall, hcursor:dword, x:dword, y:dword
  703.            locals
  704.              h      dd ?
  705.              _dx     dd ?
  706.              _dy     dd ?
  707.            endl
  708.  
  709.         mov     esi, [hcursor]
  710.         mov     ecx, [x]
  711.         mov     eax, [y]
  712.  
  713.         xor     edx, edx
  714.         sub     ecx, [esi+CURSOR.hot_x]
  715.         lea     ebx, [ecx+32-1]
  716.         mov     [x], ecx
  717.         sets    dl
  718.         dec     edx
  719.         and     ecx, edx      ;clip x to 0<=x
  720.         mov     [cur.left], ecx
  721.         mov     edi, ecx
  722.         sub     edi, [x]
  723.         mov     [_dx], edi
  724.  
  725.         xor     edx, edx
  726.         sub     eax, [esi+CURSOR.hot_y]
  727.         lea     edi, [eax+32-1]
  728.         mov     [y], eax
  729.         sets    dl
  730.         dec     edx
  731.         and     eax, edx      ;clip y to 0<=y
  732.         mov     [cur.top], eax
  733.         mov     edx, eax
  734.         sub     edx, [y]
  735.         mov     [_dy], edx
  736.  
  737.         mul     dword [BytesPerScanLine]
  738.         lea     edx, [LFB_BASE+eax+ecx*4]
  739.         mov     [cur_saved_base], edx
  740.  
  741.         cmp     ebx, [Screen_Max_X]
  742.         jbe     @F
  743.         mov     ebx, [Screen_Max_X]
  744. ;--------------------------------------
  745. align 4
  746. @@:
  747.         cmp     edi, [Screen_Max_Y]
  748.         jbe     @F
  749.         mov     edi, [Screen_Max_Y]
  750. ;--------------------------------------
  751. align 4
  752. @@:
  753.         mov     [cur.right], ebx
  754.         mov     [cur.bottom], edi
  755.  
  756.         sub     ebx, [x]
  757.         sub     edi, [y]
  758.         inc     ebx
  759.         inc     edi
  760.  
  761.         mov     [cur.w], ebx
  762.         mov     [cur.h], edi
  763.         mov     [h], edi
  764.  
  765.         mov     eax, edi
  766.         mov     edi, cur_saved_data
  767. ;--------------------------------------
  768. align 4
  769. @@:
  770.         mov     esi, edx
  771.         add     edx, [BytesPerScanLine]
  772.         mov     ecx, [cur.w]
  773.         rep movsd
  774.         dec     eax
  775.         jnz     @B
  776.  
  777. ;draw cursor
  778.         mov     ebx, [cur_saved_base]
  779.         mov     eax, [_dy]
  780.         shl     eax, 5
  781.         add     eax, [_dx]
  782.  
  783.         mov     esi, [hcursor]
  784.         mov     esi, [esi+CURSOR.base]
  785.         lea     edx, [esi+eax*4]
  786. ;--------------------------------------
  787. align 4
  788. .row:
  789.         mov     ecx, [cur.w]
  790.         mov     esi, edx
  791.         mov     edi, ebx
  792.         add     edx, 32*4
  793.         add     ebx, [BytesPerScanLine]
  794. ;--------------------------------------
  795. align 4
  796. .pix:
  797.         lodsd
  798.         test    eax, 0xFF000000
  799.         jz      @F
  800.         mov     [edi], eax
  801. ;--------------------------------------
  802. align 4
  803. @@:
  804.         add     edi, 4
  805.         dec     ecx
  806.         jnz     .pix
  807.  
  808.         dec     [h]
  809.         jnz     .row
  810.         ret
  811. endp
  812. ;------------------------------------------------------------------------------
  813. align 4
  814. check_mouse_area_for_getpixel_new:
  815. ; in:
  816. ; eax = x
  817. ; ebx = y
  818. ; out:
  819. ; ecx = new color
  820. ;--------------------------------------
  821. ; check for Y
  822.         cmp     bx, [Y_UNDER_subtraction_CUR_hot_y]
  823.         jb      .no_mouse_area
  824.  
  825.         cmp     bx, [Y_UNDER_sub_CUR_hot_y_add_curh]
  826.         jae     .no_mouse_area
  827. ;--------------------------------------
  828. ; check for X
  829.         cmp     ax, [X_UNDER_subtraction_CUR_hot_x]
  830.         jb      .no_mouse_area
  831.  
  832.         cmp     ax, [X_UNDER_sub_CUR_hot_x_add_curh]
  833.         jae     .no_mouse_area
  834. ;--------------------------------------
  835.         push    eax ebx
  836. ; offset X
  837.         mov     ecx, [X_UNDER_subtraction_CUR_hot_x]
  838.         sub     eax, ecx        ; x1
  839. ; offset Y
  840.         mov     ecx, [Y_UNDER_subtraction_CUR_hot_y]
  841.         sub     ebx, ecx        ; y1
  842. ;--------------------------------------
  843. ; ebx = offset y
  844. ; eax = offset x
  845.         imul    ebx, [cur.w]     ;y
  846.         add     eax, ebx
  847.         mov     ebx, eax
  848.         shl     eax, 2
  849.         cmp     [ScreenBPP], byte 32
  850.         je      @f
  851.         sub     eax, ebx
  852. ;--------------------------------------
  853. align 4
  854. @@:
  855.         add     eax, cur_saved_data
  856.         mov     ecx, [eax]
  857.         and     ecx, 0xffffff
  858.         add     ecx, 0xff000000
  859.         pop     ebx eax
  860.         ret
  861. ;--------------------------------------
  862. align 4
  863. .no_mouse_area:
  864.         xor     ecx, ecx
  865.         ret
  866. ;-----------------------------------------------------------------------------
  867. align 4
  868. check_mouse_area_for_putpixel_new:
  869. ; in:
  870. ; ecx = x shl 16 + y
  871. ; eax = color
  872. ; out:
  873. ; eax = new color
  874. ;--------------------------------------
  875. ; check for Y
  876.         cmp     cx, [Y_UNDER_subtraction_CUR_hot_y]
  877.         jb      .no_mouse_area
  878.  
  879.         cmp     cx, [Y_UNDER_sub_CUR_hot_y_add_curh]
  880.         jae     .no_mouse_area
  881.  
  882.         rol     ecx, 16
  883. ;--------------------------------------
  884. ; check for X
  885.         cmp     cx, [X_UNDER_subtraction_CUR_hot_x]
  886.         jb      .no_mouse_area
  887.  
  888.         cmp     cx, [X_UNDER_sub_CUR_hot_x_add_curh]
  889.         jae     .no_mouse_area
  890. ;--------------------------------------
  891. align 4
  892. .1:
  893.         push    eax
  894. ; offset X
  895.         mov     ax, [X_UNDER_subtraction_CUR_hot_x]
  896.         sub     cx, ax        ; x1
  897.         ror     ecx, 16
  898. ; offset Y
  899.         mov     ax, [Y_UNDER_subtraction_CUR_hot_y]
  900.         sub     cx, ax        ; y1
  901. ;--------------------------------------
  902. ; ecx = (offset x) shl 16 + (offset y)
  903.         push    ebx
  904.         mov     ebx, ecx
  905.         shr     ebx, 16        ; x
  906.         and     ecx, 0xffff    ; y
  907. ; ecx = offset y
  908. ; ebx = offset x
  909.         mov     eax, [esp + 4]
  910.  
  911.         push    ebx ecx
  912.         imul    ecx, [cur.w]    ;y
  913.         add     ecx, ebx
  914.         mov     ebx, ecx
  915.         shl     ecx, 2
  916.         cmp     [ScreenBPP], byte 24
  917.         je      .24
  918.         and     eax, 0xFFFFFF
  919.         mov     [ecx + cur_saved_data], eax   ;store new color  to
  920.         jmp     @f
  921. ;--------------------------------------
  922. align 4
  923. .24:
  924.         sub     ecx, ebx
  925.         mov     [ecx + cur_saved_data], ax      ;store new color  to
  926.         shr     eax, 16
  927.         mov     [ecx + cur_saved_data + 2], al  ;store new color  to
  928. ;--------------------------------------
  929. align 4
  930. @@:
  931.         pop     ecx ebx
  932.  
  933.         shl     ecx, 5
  934.         add     ecx, ebx
  935.  
  936.         mov     eax, [current_cursor]
  937.         mov     eax, [eax+CURSOR.base]
  938.         lea     eax, [eax+ecx*4]
  939.         mov     eax, [eax]
  940.  
  941.         pop     ebx
  942.  
  943.         test    eax, 0xFF000000
  944.         jz      @f
  945.  
  946.         pop     ecx
  947.         ret
  948. ;--------------------------------------
  949. align 4
  950. @@:
  951.         pop     eax
  952. ;--------------------------------------
  953. align 4
  954. .no_mouse_area:
  955.         ret
  956. ;------------------------------------------------------------------------------
  957. align 4
  958. get_display:
  959.         mov     eax, _display
  960.         ret
  961. ;------------------------------------------------------------------------------
  962. align 4
  963. init_display:
  964.         xor     eax, eax
  965.         mov     edi, _display
  966.  
  967.         mov     [edi+display_t.init_cursor], eax
  968.         mov     [edi+display_t.select_cursor], eax
  969.         mov     [edi+display_t.show_cursor], eax
  970.         mov     [edi+display_t.move_cursor], eax
  971.         mov     [edi+display_t.restore_cursor], eax
  972.  
  973.         lea     ecx, [edi+display_t.cr_list.next]
  974.         mov     [edi+display_t.cr_list.next], ecx
  975.         mov     [edi+display_t.cr_list.prev], ecx
  976.  
  977.         cmp     [SCR_MODE], word 0x13
  978.         jbe     .fail
  979.  
  980.         test    word [SCR_MODE], 0x4000
  981.         jz      .fail
  982. ;        jmp      .fail
  983.  
  984.         mov     ebx, restore_32
  985.         mov     ecx, move_cursor_32
  986.         movzx   eax, byte [ScreenBPP]
  987.         cmp     eax, 32
  988.         je      @F
  989.  
  990.         mov     ebx, restore_24
  991.         mov     ecx, move_cursor_24
  992.         cmp     eax, 24
  993.         jne     .fail
  994. ;--------------------------------------
  995. align 4
  996. @@:
  997.         mov     [_display.select_cursor], select_cursor
  998.         mov     [_display.move_cursor], ecx
  999.         mov     [_display.restore_cursor], ebx
  1000.         mov     [_display.check_mouse], check_mouse_area_for_putpixel_new
  1001.         mov     [_display.check_m_pixel], check_mouse_area_for_getpixel_new
  1002.  
  1003.         stdcall load_cursor, def_arrow, dword LOAD_FROM_MEM
  1004.         mov     [def_cursor], eax
  1005.         ret
  1006. ;--------------------------------------
  1007. align 4
  1008. .fail:
  1009.         xor     eax, eax
  1010.         mov     [_display.select_cursor], eax
  1011.         mov     [_display.move_cursor], eax
  1012.         ret
  1013. ;------------------------------------------------------------------------------
  1014. align 4
  1015. def_arrow:
  1016.   file 'arrow.cur'
  1017. ;------------------------------------------------------------------------------
  1018.  
  1019.