Subversion Repositories Kolibri OS

Rev

Rev 6319 | Blame | Compare with Previous | Last modification | View Log | Download | RSS feed

  1. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  2. ;;
  3. ;; Copyright (C) KolibriOS team 2004-2016. All rights reserved.
  4. ;; PROGRAMMING:
  5. ;; Ivan Poddubny
  6. ;; Marat Zakiyanov (Mario79)
  7. ;; VaStaNi
  8. ;; Trans
  9. ;; Mihail Semenyako (mike.dld)
  10. ;; Sergey Kuzmin (Wildwest)
  11. ;; Andrey Halyavin (halyavin)
  12. ;; Mihail Lisovin (Mihasik)
  13. ;; Andrey Ignatiev (andrew_programmer)
  14. ;; NoName
  15. ;; Evgeny Grechnikov (Diamond)
  16. ;; Iliya Mihailov (Ghost)
  17. ;; Sergey Semyonov (Serge)
  18. ;; Johnny_B
  19. ;; SPraid (simba)
  20. ;; Hidnplayr
  21. ;; Alexey Teplov (<Lrz>)
  22. ;; Rus
  23. ;; Nable
  24. ;; shurf
  25. ;; Alver
  26. ;; Maxis
  27. ;; Galkov
  28. ;; CleverMouse
  29. ;; tsdima
  30. ;; turbanoff
  31. ;; Asper
  32. ;; art_zh
  33. ;;
  34. ;; Data in this file was originally part of MenuetOS project which is
  35. ;; distributed under the terms of GNU GPL. It is modified and redistributed as
  36. ;; part of KolibriOS project under the terms of GNU GPL.
  37. ;;
  38. ;; Copyright (C) MenuetOS 2000-2004 Ville Mikael Turjanmaa
  39. ;; PROGRAMMING:
  40. ;;
  41. ;; Ville Mikael Turjanmaa, villemt@itu.jyu.fi
  42. ;; - main os coding/design
  43. ;; Jan-Michael Brummer, BUZZ2@gmx.de
  44. ;; Felix Kaiser, info@felix-kaiser.de
  45. ;; Paolo Minazzi, paolo.minazzi@inwind.it
  46. ;; quickcode@mail.ru
  47. ;; Alexey, kgaz@crosswinds.net
  48. ;; Juan M. Caravaca, bitrider@wanadoo.es
  49. ;; kristol@nic.fi
  50. ;; Mike Hibbett, mikeh@oceanfree.net
  51. ;; Lasse Kuusijarvi, kuusijar@lut.fi
  52. ;; Jarek Pelczar, jarekp3@wp.pl
  53. ;;
  54. ;; KolibriOS is distributed in the hope that it will be useful, but WITHOUT ANY
  55. ;; WARRANTY. No author or distributor accepts responsibility to anyone for the
  56. ;; consequences of using it or for whether it serves any particular purpose or
  57. ;; works at all, unless he says so in writing. Refer to the GNU General Public
  58. ;; License (the "GPL") for full details.
  59. ;
  60. ;; Everyone is granted permission to copy, modify and redistribute KolibriOS,
  61. ;; but only under the conditions described in the GPL. A copy of this license
  62. ;; is supposed to have been given to you along with KolibriOS so you can know
  63. ;; your rights and responsibilities. It should be in a file named COPYING.
  64. ;; Among other things, the copyright notice and this notice must be preserved
  65. ;; on all copies.
  66. ;;
  67. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  68.  
  69. format binary as "mnt"
  70.  
  71. include 'macros.inc'
  72. include 'struct.inc'
  73.  
  74. $Revision: 6339 $
  75.  
  76.  
  77. USE_COM_IRQ     equ 1      ; make irq 3 and irq 4 available for PCI devices
  78. VESA_1_2_VIDEO equ 0      ; enable vesa 1.2 bank switch functions
  79.  
  80. ; Enabling the next line will enable serial output console
  81. ;debug_com_base  equ 0x3f8  ; 0x3f8 is com1, 0x2f8 is com2, 0x3e8 is com3, 0x2e8 is com4, no irq's are used
  82.  
  83. include "proc32.inc"
  84. include "kglobals.inc"
  85. include "lang.inc"
  86. include "encoding.inc"
  87.  
  88. include "const.inc"
  89.  
  90. iglobal
  91. ; The following variable, if equal to 1, duplicates debug output to the screen.
  92. debug_direct_print db 0
  93. ; Start the first app (LAUNCHER) after kernel is loaded? (1=yes, 2 or 0=no)
  94. launcher_start db 1
  95. endg
  96.  
  97. max_processes   equ   255
  98. tss_step         equ   (128+8192) ; tss & i/o - 65535 ports, * 256=557056*4
  99.  
  100. os_stack       equ  (os_data_l-gdts)    ; GDTs
  101. os_code       equ  (os_code_l-gdts)
  102. graph_data     equ  (3+graph_data_l-gdts)
  103. tss0           equ  (tss0_l-gdts)
  104. app_code       equ  (3+app_code_l-gdts)
  105. app_data       equ  (3+app_data_l-gdts)
  106. app_tls       equ  (3+tls_data_l-gdts)
  107. pci_code_sel   equ  (pci_code_32-gdts)
  108. pci_data_sel   equ  (pci_data_32-gdts)
  109.  
  110.  
  111. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  112. ;;
  113. ;;   Included files:
  114. ;;
  115. ;;   Kernel16.inc
  116. ;;    - Booteng.inc   English text for bootup
  117. ;;    - Bootcode.inc  Hardware setup
  118. ;;    - Pci16.inc     PCI functions
  119. ;;
  120. ;;   Kernel32.inc
  121. ;;    - Sys32.inc     Process management
  122. ;;    - Shutdown.inc  Shutdown and restart
  123. ;;    - Fat32.inc     Read / write hd
  124. ;;    - Vesa12.inc    Vesa 1.2 driver
  125. ;;    - Vesa20.inc    Vesa 2.0 driver
  126. ;;    - Vga.inc       VGA driver
  127. ;;    - Stack.inc     Network interface
  128. ;;    - Mouse.inc     Mouse pointer
  129. ;;    - Scincode.inc  Window skinning
  130. ;;    - Pci32.inc     PCI functions
  131. ;;
  132. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  133.  
  134.  
  135. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  136. ;;                                                                      ;;
  137. ;;                  16 BIT ENTRY FROM BOOTSECTOR                        ;;
  138. ;;                                                                      ;;
  139. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  140.  
  141. use16
  142.                   org   0x0
  143.         jmp     start_of_code
  144.  
  145. if lang eq sp
  146. include "kernelsp.inc"  ; spanish kernel messages
  147. else if lang eq et
  148. version db    'Kolibri OS  versioon 0.7.7.0+    ',13,10,13,10,0
  149. else
  150. version db    'Kolibri OS  version 0.7.7.0+     ',13,10,13,10,0
  151. end if
  152.  
  153. include "boot/bootstr.inc"     ; language-independent boot messages
  154. include "boot/preboot.inc"
  155.  
  156. if lang eq ge
  157. include "boot/bootge.inc"     ; german system boot messages
  158. else if lang eq sp
  159. include "boot/bootsp.inc"     ; spanish system boot messages
  160. else if lang eq ru
  161. include "boot/bootru.inc"      ; russian system boot messages
  162. include "boot/ru.inc"          ; Russian font
  163. else if lang eq et
  164. include "boot/bootet.inc"      ; estonian system boot messages
  165. include "boot/et.inc"          ; Estonian font
  166. else
  167. include "boot/booten.inc"      ; english system boot messages
  168. end if
  169.  
  170. include "boot/bootcode.inc"    ; 16 bit system boot code
  171. include "bus/pci/pci16.inc"
  172. include "detect/biosdisk.inc"
  173.  
  174. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  175. ;;                                                                      ;;
  176. ;;                  SWITCH TO 32 BIT PROTECTED MODE                     ;;
  177. ;;                                                                      ;;
  178. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  179.  
  180.  
  181. ; CR0 Flags - Protected mode and Paging
  182.  
  183.         mov     ecx, CR0_PE
  184.  
  185. ; Enabling 32 bit protected mode
  186.  
  187.         sidt    [cs:old_ints_h]
  188.  
  189.         cli                             ; disable all irqs
  190.         cld
  191.         mov     al, 255                 ; mask all irqs
  192.         out     0xa1, al
  193.         out     0x21, al
  194.    l.5:
  195.         in      al, 0x64                ; Enable A20
  196.         test    al, 2
  197.         jnz     l.5
  198.         mov     al, 0xD1
  199.         out     0x64, al
  200.    l.6:
  201.         in      al, 0x64
  202.         test    al, 2
  203.         jnz     l.6
  204.         mov     al, 0xDF
  205.         out     0x60, al
  206.    l.7:
  207.         in      al, 0x64
  208.         test    al, 2
  209.         jnz     l.7
  210.         mov     al, 0xFF
  211.         out     0x64, al
  212.  
  213.         lgdt    [cs:tmp_gdt]            ; Load GDT
  214.         mov     eax, cr0                ; protected mode
  215.         or      eax, ecx
  216.         and     eax, 10011111b *65536*256 + 0xffffff ; caching enabled
  217.         mov     cr0, eax
  218.         jmp     pword os_code:B32       ; jmp to enable 32 bit mode
  219.  
  220. align 8
  221. tmp_gdt:
  222.  
  223.         dw     23
  224.         dd     tmp_gdt+0x10000
  225.         dw     0
  226.  
  227.         dw     0xffff
  228.         dw     0x0000
  229.         db     0x00
  230.         dw     11011111b *256 +10011010b
  231.         db     0x00
  232.  
  233.         dw     0xffff
  234.         dw     0x0000
  235.         db     0x00
  236.         dw     11011111b *256 +10010010b
  237.         db     0x00
  238.  
  239. include "data16.inc"
  240.  
  241. if ~ lang eq sp
  242. diff16 "end of bootcode",0,$+0x10000
  243. end if
  244.  
  245. use32
  246. org $+0x10000
  247.  
  248. align 4
  249. B32:
  250.         mov     ax, os_stack       ; Selector for os
  251.         mov     ds, ax
  252.         mov     es, ax
  253.         mov     fs, ax
  254.         mov     gs, ax
  255.         mov     ss, ax
  256.         mov     esp, TMP_STACK_TOP       ; Set stack
  257.  
  258. ; CLEAR 0x280000 - HEAP_BASE
  259.  
  260.         xor     eax, eax
  261.         mov     edi, CLEAN_ZONE
  262.         mov     ecx, (HEAP_BASE-OS_BASE-CLEAN_ZONE) / 4
  263.         cld
  264.         rep stosd
  265.  
  266. ; CLEAR KERNEL UNDEFINED GLOBALS
  267.         mov     edi, endofcode-OS_BASE
  268.         mov     ecx, 0x90000
  269.         sub     ecx, edi
  270.         shr     ecx, 2
  271.         rep stosd
  272.  
  273. ; SAVE & CLEAR 0-0xffff
  274.  
  275.         mov     edi, 0x1000
  276.         mov     ecx, 0x8000 / 4
  277.         rep stosd
  278.         mov     edi, 0xa000
  279.         mov     ecx, 0x6000 / 4
  280.         rep stosd
  281.  
  282.         call    test_cpu
  283.         bts     [cpu_caps-OS_BASE], CAPS_TSC    ;force use rdtsc
  284.  
  285.         call    check_acpi
  286.         call    init_hpet
  287.         call    init_BIOS32
  288. ; MEMORY MODEL
  289.         call    mem_test
  290.         call    init_mem
  291.         call    init_page_map
  292.  
  293. ; ENABLE PAGING
  294.  
  295.         mov     eax, sys_pml3-OS_BASE
  296.         mov     cr3, eax
  297.  
  298.         mov     eax, cr0
  299.         or      eax, CR0_PG+CR0_WP
  300.         mov     cr0, eax
  301.  
  302.         lgdt    [gdts]
  303.         jmp     pword os_code:high_code
  304.  
  305. align 4
  306. bios32_entry    dd ?
  307. tmp_page_tabs   dd ?
  308. use16
  309. ap_init16:
  310.         cli
  311.         lgdt    [cs:gdts_ap-ap_init16]
  312.         mov     eax, [cs:cr3_ap-ap_init16]
  313.         mov     cr3, eax
  314.         mov     eax, [cs:cr4_ap-ap_init16]
  315.         mov     cr4, eax
  316.         mov     eax, CR0_PE+CR0_PG+CR0_WP
  317.         mov     cr0, eax
  318.         jmp     pword os_code:ap_init_high
  319. align 16
  320. gdts_ap:
  321.         dw     gdte-gdts-1
  322.         dd     gdts
  323.         dw     0
  324. cr3_ap  dd     ?
  325. cr4_ap  dd     ?
  326. ap_init16_size = $ - ap_init16
  327. use32
  328.  
  329. __DEBUG__ fix 1
  330. __DEBUG_LEVEL__ fix 1
  331. include 'init.inc'
  332.  
  333. org OS_BASE+$
  334.  
  335. include 'fdo.inc'
  336.  
  337. align 4
  338. high_code:
  339.         mov     ax, os_stack
  340.         mov     bx, app_data
  341.         mov     cx, app_tls
  342.         mov     ss, ax
  343.         add     esp, OS_BASE
  344.  
  345.         mov     ds, bx
  346.         mov     es, bx
  347.         mov     fs, cx
  348.         mov     gs, bx
  349.  
  350.         xor     eax, eax
  351.         mov     ebx, 0xFFFFF000+PG_SHARED+PG_NOCACHE+PG_UWR
  352.         bt      [cpu_caps], CAPS_PAT
  353.         setc    al
  354.         shl     eax, 7
  355.         or      ebx, eax
  356.  
  357.         mov     eax, PG_GLOBAL
  358.         bt      [cpu_caps], CAPS_PGE
  359.         jnc     @F
  360.  
  361.         or      [sys_pml2], eax
  362.         or      [sys_pml2+8], eax
  363.         or      ebx, eax
  364.  
  365.         mov     eax, cr4
  366.         or      eax, CR4_PGE
  367.         mov     cr4, eax
  368. @@:
  369.         mov     [pte_valid_mask], ebx
  370.  
  371.         xor     eax, eax
  372.         mov     dword [sys_proc+PROC.pdt_0], eax
  373.         mov     dword [sys_proc+PROC.pdt_0+8], eax
  374.  
  375.         mov     eax, cr3
  376.         mov     cr3, eax          ; flush TLB
  377.  
  378.         mov     ecx, pg_data.mutex
  379.         call    mutex_init
  380.  
  381.         mov     ecx, disk_list_mutex
  382.         call    mutex_init
  383.  
  384.         mov     ecx, keyboard_list_mutex
  385.         call    mutex_init
  386.  
  387.         mov     ecx, unpack_mutex
  388.         call    mutex_init
  389.  
  390.         mov     ecx, application_table_mutex
  391.         call    mutex_init
  392.  
  393.         mov     ecx, ide_mutex
  394.         call    mutex_init
  395.         mov     ecx, ide_channel1_mutex
  396.         call    mutex_init
  397.         mov     ecx, ide_channel2_mutex
  398.         call    mutex_init
  399.         mov     ecx, ide_channel3_mutex
  400.         call    mutex_init
  401.         mov     ecx, ide_channel4_mutex
  402.         call    mutex_init
  403.         mov     ecx, ide_channel5_mutex
  404.         call    mutex_init
  405.         mov     ecx, ide_channel6_mutex
  406.         call    mutex_init
  407. ;-----------------------------------------------------------------------------
  408. ; SAVE REAL MODE VARIABLES
  409. ;-----------------------------------------------------------------------------
  410. ; --------------- APM ---------------------
  411.  
  412. ; init selectors
  413.         mov     ebx, [BOOT_VARS+BOOT_APM_ENTRY]        ; offset of APM entry point
  414.         movzx   eax, word [BOOT_VARS+BOOT_APM_CODE_32] ; real-mode segment base address of
  415.                                                                                 ; protected-mode 32-bit code segment
  416.         movzx   ecx, word [BOOT_VARS+BOOT_APM_CODE_16]; real-mode segment base address of
  417.                                                                                 ; protected-mode 16-bit code segment
  418.         movzx   edx, word [BOOT_VARS+BOOT_APM_DATA_16]; real-mode segment base address of
  419.                                                                                 ; protected-mode 16-bit data segment
  420.  
  421.         shl     eax, 4
  422.         mov     [dword apm_code_32 + 2], ax
  423.         shr     eax, 16
  424.         mov     [dword apm_code_32 + 4], al
  425.  
  426.         shl     ecx, 4
  427.         mov     [dword apm_code_16 + 2], cx
  428.         shr     ecx, 16
  429.         mov     [dword apm_code_16 + 4], cl
  430.  
  431.         shl     edx, 4
  432.         mov     [dword apm_data_16 + 2], dx
  433.         shr     edx, 16
  434.         mov     [dword apm_data_16 + 4], dl
  435.  
  436.         mov     dword[apm_entry], ebx
  437.         mov     word [apm_entry + 4], apm_code_32 - gdts
  438.  
  439.         mov     eax, [BOOT_VARS + BOOT_APM_VERSION] ; version & flags
  440.         mov     [apm_vf], eax
  441. ; -----------------------------------------
  442.         mov     al, [BOOT_VARS+BOOT_DMA]            ; DMA access
  443.         mov     [allow_dma_access], al
  444.  
  445.         mov     al, [BOOT_VARS+BOOT_DEBUG_PRINT]    ; If nonzero, duplicates debug output to the screen
  446.         mov     [debug_direct_print], al
  447.  
  448.         mov     al, [BOOT_VARS+BOOT_LAUNCHER_START] ; Start the first app (LAUNCHER) after kernel is loaded?
  449.         mov     [launcher_start], al
  450.  
  451.         mov     esi, BOOT_VARS+0x9080
  452.         movzx   ecx, byte [esi-1]
  453.         mov     [NumBiosDisks], ecx
  454.         mov     edi, BiosDisksData
  455.         rep movsd
  456.  
  457. ; -------- Fast System Call init ----------
  458. ; Intel SYSENTER/SYSEXIT (AMD CPU support it too)
  459.         bt      [cpu_caps], CAPS_SEP
  460.         jnc     .SEnP  ; SysEnter not Present
  461.         xor     edx, edx
  462.         mov     ecx, MSR_SYSENTER_CS
  463.         mov     eax, os_code
  464.         wrmsr
  465.         mov     ecx, MSR_SYSENTER_ESP
  466. ;           mov eax, sysenter_stack ; Check it
  467.         xor     eax, eax
  468.         wrmsr
  469.         mov     ecx, MSR_SYSENTER_EIP
  470.         mov     eax, sysenter_entry
  471.         wrmsr
  472. .SEnP:
  473. ; AMD SYSCALL/SYSRET
  474.         cmp     byte[cpu_vendor], 'A'
  475.         jne     .noSYSCALL
  476.         mov     eax, 0x80000001
  477.         cpuid
  478.         test    edx, 0x800  ; bit_11 - SYSCALL/SYSRET support
  479.         jz      .noSYSCALL
  480.         mov     ecx, MSR_AMD_EFER
  481.         rdmsr
  482.         or      eax, 1 ; bit_0 - System Call Extension (SCE)
  483.         wrmsr
  484.  
  485.         ; !!!! It`s dirty hack, fix it !!!
  486.         ; Bits of EDX :
  487.         ; Bit 31–16 During the SYSRET instruction, this field is copied into the CS register
  488.         ;  and the contents of this field, plus 8, are copied into the SS register.
  489.         ; Bit 15–0 During the SYSCALL instruction, this field is copied into the CS register
  490.         ;  and the contents of this field, plus 8, are copied into the SS register.
  491.  
  492.         ; mov   edx, (os_code + 16) * 65536 + os_code
  493.         mov     edx, 0x1B0008
  494.  
  495.         mov     eax, syscall_entry
  496.         mov     ecx, MSR_AMD_STAR
  497.         wrmsr
  498. .noSYSCALL:
  499. ; -----------------------------------------
  500.         stdcall alloc_page
  501.         stdcall map_page, tss-0xF80, eax, PG_SWR
  502.         stdcall alloc_page
  503.         stdcall map_page, tss+0x80, eax, PG_SWR
  504.         stdcall alloc_page
  505.         stdcall map_page, tss+0x1080, eax, PG_SWR
  506.  
  507. ; LOAD IDT
  508.  
  509.         call    build_interrupt_table ;lidt is executed
  510.           ;lidt [idtreg]
  511.  
  512.         call    init_kernel_heap
  513.         stdcall kernel_alloc, (RING0_STACK_SIZE+512) * 2
  514.         mov     [os_stack_seg], eax
  515.  
  516.         lea     esp, [eax+RING0_STACK_SIZE]
  517.  
  518.         mov     [tss._ss0], os_stack
  519.         mov     [tss._esp0], esp
  520.         mov     [tss._esp], esp
  521.         mov     [tss._cs], os_code
  522.         mov     [tss._ss], os_stack
  523.         mov     [tss._ds], app_data
  524.         mov     [tss._es], app_data
  525.         mov     [tss._fs], app_data
  526.         mov     [tss._gs], app_data
  527.         mov     [tss._io], 128
  528. ;Add IO access table - bit array of permitted ports
  529.         mov     edi, tss._io_map_0
  530.         xor     eax, eax
  531.         not     eax
  532.         mov     ecx, 8192/4
  533.         rep stosd                           ; access to 4096*8=65536 ports
  534.  
  535.         mov     ax, tss0
  536.         ltr     ax
  537.  
  538.         mov     eax, sys_proc
  539.         list_init eax
  540.         add     eax, PROC.thr_list
  541.         list_init eax
  542.  
  543.         call    init_video
  544.         call    init_mtrr
  545.         mov     [LFBAddress], LFB_BASE
  546.         mov     ecx, bios_fb
  547.         call    set_framebuffer
  548.         call    init_fpu
  549.         call    init_malloc
  550.  
  551.         stdcall alloc_kernel_space, 0x50000         ; FIXME check size
  552.         mov     [default_io_map], eax
  553.  
  554.         add     eax, 0x2000
  555.         mov     [ipc_tmp], eax
  556.         mov     ebx, 0x1000
  557.  
  558.         add     eax, 0x40000
  559.         mov     [proc_mem_map], eax
  560.  
  561.         add     eax, 0x8000
  562.         mov     [proc_mem_pdir], eax
  563.  
  564.         add     eax, ebx
  565.         mov     [proc_mem_tab], eax
  566.  
  567.         add     eax, ebx
  568.         mov     [tmp_task_ptab], eax
  569.  
  570.         add     eax, ebx
  571.         mov     [ipc_pdir], eax
  572.  
  573.         add     eax, ebx
  574.         mov     [ipc_ptab], eax
  575.  
  576.         stdcall kernel_alloc, (unpack.LZMA_BASE_SIZE+(unpack.LZMA_LIT_SIZE shl \
  577.                 (unpack.lc+unpack.lp)))*4
  578.  
  579.         mov     [unpack.p], eax
  580.  
  581.         call    init_events
  582.         mov     eax, srv.fd-SRV.fd
  583.         mov     [srv.fd], eax
  584.         mov     [srv.bk], eax
  585.  
  586. ;Set base of graphic segment to linear address of LFB
  587.         mov     eax, [LFBAddress]         ; set for gs
  588.         mov     [graph_data_l+2], ax
  589.         shr     eax, 16
  590.         mov     [graph_data_l+4], al
  591.         mov     [graph_data_l+7], ah
  592.  
  593.         stdcall kernel_alloc, [_display.win_map_size]
  594.         mov     [_display.win_map], eax
  595.  
  596.         xor     eax, eax
  597.         inc     eax
  598.  
  599. ; set background
  600.  
  601.         mov     [BgrDrawMode], eax
  602.         mov     [BgrDataWidth], eax
  603.         mov     [BgrDataHeight], eax
  604.         mov     [mem_BACKGROUND], 4
  605.         mov     [img_background], static_background_data
  606.  
  607. ; set clipboard
  608.  
  609.         xor     eax, eax
  610.         mov     [clipboard_slots], eax
  611.         mov     [clipboard_write_lock], eax
  612.         stdcall kernel_alloc, 4096
  613.         test    eax, eax
  614.         jnz     @f
  615.  
  616.         dec     eax
  617. @@:
  618.         mov     [clipboard_main_list], eax
  619.  
  620.         mov     eax, [hpet_base]
  621.         test    eax, eax
  622.         jz      @F
  623.         mov     eax, [hpet_base]
  624.         stdcall map_io_mem, [hpet_base], 1024, PG_GLOBAL+PAT_UC+PG_SWR
  625.         mov     [hpet_base], eax
  626.         mov     eax, [eax]
  627.         DEBUGF  1, "K : HPET caps %x\n", eax
  628. @@:
  629. ; SET UP OS TASK
  630.  
  631.         mov     esi, boot_setostask
  632.         call    boot_log
  633.  
  634.         mov     edi, sys_proc+PROC.heap_lock
  635.         mov     ecx, (PROC.ht_free-PROC.heap_lock)/4
  636.  
  637.         xor     eax, eax
  638.         cld
  639.         rep stosd
  640.  
  641.         mov     [edi], dword (PROC.pdt_0 - PROC.htab)/4 - 3
  642.         mov     [edi+4], dword 3           ;reserve handles for stdin stdout and stderr
  643.         mov     ecx, (PROC.pdt_0 - PROC.htab)/4
  644.         add     edi, 8
  645.         inc     eax
  646. @@:
  647.         stosd
  648.         inc     eax
  649.         cmp     eax, ecx
  650.         jbe     @B
  651.  
  652.         mov     [sys_proc+PROC.pdt_0_phys], sys_proc-OS_BASE+PROC.pdt_0
  653.         mov     [sys_proc+PROC.pdt_1_phys], sys_proc-OS_BASE+PROC.pdt_0+4096
  654.  
  655.         mov     eax, -1
  656.         mov     edi, thr_slot_map+4
  657.         mov     [edi-4], dword 0xFFFFFFF8
  658.         stosd
  659.         stosd
  660.         stosd
  661.         stosd
  662.         stosd
  663.         stosd
  664.         stosd
  665.  
  666.         mov     [current_process], sys_proc
  667.  
  668.         mov     edx, SLOT_BASE+256*1
  669.         mov     ebx, [os_stack_seg]
  670.         add     ebx, 0x2000
  671.         call    setup_os_slot
  672.         mov     dword [edx], 'IDLE'
  673.         sub     [edx+APPDATA.saved_esp], 4
  674.         mov     eax, [edx+APPDATA.saved_esp]
  675.         mov     dword [eax], idle_thread
  676.         mov     ecx, IDLE_PRIORITY
  677.         call    scheduler_add_thread
  678.  
  679.         mov     edx, SLOT_BASE+256*2
  680.         mov     ebx, [os_stack_seg]
  681.         call    setup_os_slot
  682.         mov     dword [edx], 'OS'
  683.         xor     ecx, ecx
  684.         call    scheduler_add_thread
  685.  
  686.         mov     dword [CURRENT_TASK], 2
  687.         mov     dword [TASK_COUNT], 2
  688.         mov     dword [current_slot], SLOT_BASE + 256*2
  689.         mov     dword [TASK_BASE], CURRENT_TASK + 32*2
  690.  
  691. ; Move other CPUs to deep sleep, if it is useful
  692. uglobal
  693. use_mwait_for_idle db 0
  694. endg
  695.         cmp     [cpu_vendor+8], 'ntel'
  696.         jnz     .no_wake_cpus
  697.         bt      [cpu_caps+4], CAPS_MONITOR-32
  698.         jnc     .no_wake_cpus
  699.         dbgstr 'using mwait for idle loop'
  700.         inc     [use_mwait_for_idle]
  701.         mov     ebx, [cpu_count]
  702.         cmp     ebx, 1
  703.         jbe     .no_wake_cpus
  704.         call    create_trampoline_pgmap
  705.         mov     [cr3_ap+OS_BASE], eax
  706.         mov     eax, cr4
  707.         mov     [cr4_ap+OS_BASE], eax
  708.         mov     esi, OS_BASE + ap_init16
  709.         mov     edi, OS_BASE + 8000h
  710.         mov     ecx, (ap_init16_size + 3) / 4
  711.         rep movsd
  712.         stdcall map_io_mem, [acpi_lapic_base], 0x1000, PG_GLOBAL+PG_NOCACHE+PG_SWR
  713.         mov     [LAPIC_BASE], eax
  714.         lea     edi, [eax+300h]
  715.         mov     esi, smpt+4
  716.         dec     ebx
  717. .wake_cpus_loop:
  718.         lodsd
  719.         push    esi
  720.         xor     esi, esi
  721.         inc     esi
  722.         shl     eax, 24
  723.         mov     [edi+10h], eax
  724. ; assert INIT IPI
  725.         mov     dword [edi], 0C500h
  726.         call    delay_ms
  727. @@:
  728.         test    dword [edi], 1000h
  729.         jnz     @b
  730. ; deassert INIT IPI
  731.         mov     dword [edi], 8500h
  732.         call    delay_ms
  733. @@:
  734.         test    dword [edi], 1000h
  735.         jnz     @b
  736. ; send STARTUP IPI
  737.         mov     dword [edi], 600h + (8000h shr 12)
  738.         call    delay_ms
  739. @@:
  740.         test    dword [edi], 1000h
  741.         jnz     @b
  742.         pop     esi
  743.         dec     ebx
  744.         jnz     .wake_cpus_loop
  745.         mov     eax, [cpu_count]
  746.         dec     eax
  747. @@:
  748.         cmp     [ap_initialized], eax
  749.         jnz     @b
  750.         mov     eax, [cr3_ap+OS_BASE]
  751.         call    free_page
  752. .no_wake_cpus:
  753.  
  754. ; REDIRECT ALL IRQ'S TO INT'S 0x20-0x2f
  755.         mov     esi, boot_initirq
  756.         call    boot_log
  757.         call    init_irqs
  758.  
  759.         mov     esi, boot_picinit
  760.         call    boot_log
  761.         call    PIC_init
  762.  
  763.         mov     esi, boot_v86machine
  764.         call    boot_log
  765. ; Initialize system V86 machine
  766. ;        call    init_sys_v86
  767.  
  768.         mov     esi, boot_inittimer
  769.         call    boot_log
  770. ; Initialize system timer (IRQ0)
  771.         call    PIT_init
  772.  
  773. ; Register ramdisk file system
  774.         cmp     [boot_dev+OS_BASE+0x10000], 1
  775.         je      @f
  776.  
  777.         call    register_ramdisk
  778. ;--------------------------------------
  779. @@:
  780.         mov     esi, boot_initapic
  781.         call    boot_log
  782. ; Try to Initialize APIC
  783.         call    APIC_init
  784.  
  785.         mov     esi, boot_enableirq
  786.         call    boot_log
  787. ; Enable timer IRQ (IRQ0) and co-processor IRQ (IRQ13)
  788. ; they are used: when partitions are scanned, hd_read relies on timer
  789.         call    unmask_timer
  790.         stdcall enable_irq, 2               ; @#$%! PIC
  791.         stdcall enable_irq, 13              ; co-processor
  792.  
  793. ; Setup serial output console (if enabled)
  794. if defined debug_com_base
  795.  
  796.         ; reserve port so nobody else will use it
  797.         xor     ebx, ebx
  798.         mov     ecx, debug_com_base
  799.         mov     edx, debug_com_base+7
  800.         call    r_f_port_area
  801.  
  802.         ; enable Divisor latch
  803.         mov     dx, debug_com_base+3
  804.         mov     al, 1 shl 7
  805.         out     dx, al
  806.  
  807.         ; Set speed to 115200 baud (max speed)
  808.         mov     dx, debug_com_base
  809.         mov     al, 0x01
  810.         out     dx, al
  811.  
  812.         mov     dx, debug_com_base+1
  813.         mov     al, 0x00
  814.         out     dx, al
  815.  
  816.         ; No parity, 8bits words, one stop bit, dlab bit back to 0
  817.         mov     dx, debug_com_base+3
  818.         mov     al, 3
  819.         out     dx, al
  820.  
  821.         ; disable interrupts
  822.         mov     dx, debug_com_base+1
  823.         mov     al, 0
  824.         out     dx, al
  825.  
  826.         ; clear +  enable fifo (64 bits)
  827.         mov     dx, debug_com_base+2
  828.         mov     al, 0x7 + 1 shl 5
  829.         out     dx, al
  830.  
  831. end if
  832.  
  833.  
  834. ;-----------------------------------------------------------------------------
  835. ; show SVN version of kernel on the message board
  836. ;-----------------------------------------------------------------------------
  837.         mov     eax, [version_inf.rev]
  838.         DEBUGF  1, "K : kernel SVN r%d\n", eax
  839. ;-----------------------------------------------------------------------------
  840. ; show CPU count on the message board
  841. ;-----------------------------------------------------------------------------
  842.         mov     eax, [cpu_count]
  843.         test    eax, eax
  844.         jnz     @F
  845.         mov     al, 1                             ; at least one CPU
  846. @@:
  847.         DEBUGF  1, "K : %d CPU detected\n", eax
  848. ;-----------------------------------------------------------------------------
  849. ; detect Floppy drives
  850. ;-----------------------------------------------------------------------------
  851.         mov     esi, boot_detectfloppy
  852.         call    boot_log
  853. include 'detect/dev_fd.inc'
  854. ;-----------------------------------------------------------------------------
  855. ; create pci-devices list
  856. ;-----------------------------------------------------------------------------
  857.         mov     [pci_access_enabled], 1
  858.         call    pci_enum
  859. ;-----------------------------------------------------------------------------
  860. ; initialisation IDE ATA code
  861. ;-----------------------------------------------------------------------------
  862. include 'detect/init_ata.inc'
  863. ;-----------------------------------------------------------------------------
  864.  
  865.         cli
  866. ; Display APIC status
  867.         mov     esi, boot_APIC_found
  868.         cmp     [irq_mode], IRQ_APIC
  869.         je      @f
  870.         mov     esi, boot_APIC_nfound
  871. @@:
  872.         call    boot_log
  873.  
  874. ; PRINT AMOUNT OF MEMORY
  875.         mov     esi, boot_memdetect
  876.         call    boot_log
  877.  
  878.         movzx   ecx, word [boot_y]
  879.         if lang eq ru
  880.         or      ecx, (10+30*6) shl 16
  881.         else if lang eq sp
  882.         or      ecx, (10+33*6) shl 16
  883.         else
  884.         or      ecx, (10+29*6) shl 16
  885.         end if
  886.         sub     ecx, 10
  887.         mov     edx, 0xFFFFFF
  888.         mov     ebx, [MEM_AMOUNT]
  889.         shr     ebx, 20
  890.         xor     edi, edi
  891.         mov     eax, 0x00040000
  892.         inc     edi
  893.         call    display_number_force
  894.  
  895. include "detect/vortex86.inc"                     ; Vortex86 SoC detection code
  896.  
  897. ;        stdcall load_pe_driver, szVidintel, 0
  898.  
  899.         call    usb_init
  900.  
  901. ; SET PRELIMINARY WINDOW STACK AND POSITIONS
  902.  
  903.         mov     esi, boot_windefs
  904.         call    boot_log
  905.         call    set_window_defaults
  906.  
  907. ; SET BACKGROUND DEFAULTS
  908.  
  909.         mov     esi, boot_bgr
  910.         call    boot_log
  911.         call    init_background
  912.         call    calculatebackground
  913.  
  914. ; RESERVE SYSTEM IRQ'S JA PORT'S
  915.  
  916.         mov     esi, boot_resirqports
  917.         call    boot_log
  918.         call    reserve_irqs_ports
  919.  
  920.         call    init_display
  921.         mov     eax, [def_cursor]
  922.         mov     [SLOT_BASE+APPDATA.cursor+256], eax
  923.         mov     [SLOT_BASE+APPDATA.cursor+256*2], eax
  924.  
  925. ; PRINT CPU FREQUENCY
  926.  
  927.         mov     esi, boot_cpufreq
  928.         call    boot_log
  929.  
  930.         cli
  931.         mov     ebx, [hpet_base]
  932.         test    ebx, ebx
  933.         jz      @F
  934.         mov     ebx, [ebx+0xF0]
  935.  
  936.         rdtsc
  937.         mov     ecx, 1000
  938.         sub     eax, [hpet_tsc_start]
  939.         sbb     edx, [hpet_tsc_start+4]
  940.         shld    edx, eax, 10
  941.         shl     eax, 10
  942.         mov     esi, eax
  943.         mov     eax, edx
  944.         mul     ecx
  945.         xchg    eax, esi
  946.         mul     ecx
  947.         adc     edx, esi
  948.         div     ebx
  949.         mul     ecx
  950.         div     [hpet_period]
  951.         mul     ecx
  952.         DEBUGF  1, "K : cpu frequency %u Hz\n", eax
  953.         jmp     .next
  954. @@:
  955.         rdtsc
  956.         mov     ecx, eax
  957.         mov     esi, 250            ; wait 1/4 a second
  958.         call    delay_ms
  959.         rdtsc
  960.  
  961.         sub     eax, ecx
  962.         xor     edx, edx
  963.         shld    edx, eax, 2
  964.         shl     eax, 2
  965. .next:
  966.         mov     dword [cpu_freq], eax
  967.         mov     dword [cpu_freq+4], edx
  968.         mov     ebx, 1000000
  969.         div     ebx
  970.         mov     ebx, eax
  971.  
  972.         movzx   ecx, word [boot_y]
  973.         if lang eq ru
  974.         add     ecx, (10+19*6) shl 16 - 10
  975.         else if lang eq sp
  976.         add     ecx, (10+25*6) shl 16 - 10
  977.         else
  978.         add     ecx, (10+17*6) shl 16 - 10
  979.         end if
  980.  
  981.         mov     edx, 0xFFFFFF
  982.         xor     edi, edi
  983.         mov     eax, 0x00040000
  984.         inc     edi
  985.         call    display_number_force
  986.  
  987. ; SET VARIABLES
  988.  
  989.         call    set_variables
  990.  
  991. ; STACK AND FDC
  992.  
  993.         call    stack_init
  994.         call    fdc_init
  995.  
  996. ; PALETTE FOR 320x200 and 640x480 16 col
  997.  
  998.         cmp     [SCR_MODE], word 0x12
  999.         jne     no_pal_vga
  1000.         mov     esi, boot_pal_vga
  1001.         call    boot_log
  1002.         call    paletteVGA
  1003.       no_pal_vga:
  1004.  
  1005.         cmp     [SCR_MODE], word 0x13
  1006.         jne     no_pal_ega
  1007.         mov     esi, boot_pal_ega
  1008.         call    boot_log
  1009.         call    palette320x200
  1010.       no_pal_ega:
  1011.  
  1012. ; LOAD DEFAULT SKIN
  1013.  
  1014.         call    load_default_skin
  1015.  
  1016. ; Protect I/O permission map
  1017.  
  1018.         mov     esi, [default_io_map]
  1019.         stdcall map_page, esi, [SLOT_BASE+256+APPDATA.io_map], PG_READ
  1020.         add     esi, 0x1000
  1021.         stdcall map_page, esi, [SLOT_BASE+256+APPDATA.io_map+4], PG_READ
  1022.  
  1023.         stdcall map_page, tss._io_map_0, \
  1024.                 [SLOT_BASE+256+APPDATA.io_map], PG_READ
  1025.         stdcall map_page, tss._io_map_1, \
  1026.                 [SLOT_BASE+256+APPDATA.io_map+4], PG_READ
  1027.  
  1028. ; SET KEYBOARD PARAMETERS
  1029.         mov     al, 0xf6       ; reset keyboard, scan enabled
  1030.         call    kb_write_wait_ack
  1031.         test    ah, ah
  1032.         jnz     .no_keyboard
  1033.  
  1034. iglobal
  1035. align 4
  1036. ps2_keyboard_functions:
  1037.         dd      .end - $
  1038.         dd      0       ; no close
  1039.         dd      ps2_set_lights
  1040. .end:
  1041. endg
  1042.         stdcall register_keyboard, ps2_keyboard_functions, 0
  1043.        ; mov   al, 0xED       ; Keyboard LEDs - only for testing!
  1044.        ; call  kb_write_wait_ack
  1045.        ; mov   al, 111b
  1046.        ; call  kb_write_wait_ack
  1047.  
  1048.         mov     al, 0xF3     ; set repeat rate & delay
  1049.         call    kb_write_wait_ack
  1050.         mov     al, 0; 30 250 ;00100010b ; 24 500  ;00100100b  ; 20 500
  1051.         call    kb_write_wait_ack
  1052.      ;// mike.dld [
  1053.         call    set_lights
  1054.      ;// mike.dld ]
  1055.         stdcall attach_int_handler, 1, irq1, 0
  1056.         DEBUGF  1, "K : IRQ1 return code %x\n", eax
  1057. .no_keyboard:
  1058.  
  1059. ; Load PS/2 mouse driver
  1060.  
  1061.         stdcall load_pe_driver, szPS2MDriver, 0
  1062.  
  1063.         mov     esi, boot_setmouse
  1064.         call    boot_log
  1065.         call    setmouse
  1066.  
  1067. ; LOAD FIRST APPLICATION
  1068.         cmp     byte [launcher_start], 1        ; Check if starting LAUNCHER is selected on blue screen (1 = yes)
  1069.         jnz     first_app_found
  1070.  
  1071.         cli
  1072.         mov     ebp, firstapp
  1073.         call    fs_execute_from_sysdir
  1074.         test    eax, eax
  1075.         jns     first_app_found
  1076.  
  1077.         mov     esi, boot_failed
  1078.         call    boot_log
  1079.  
  1080.         mov     eax, 0xDEADBEEF      ; otherwise halt
  1081.         hlt
  1082.  
  1083. first_app_found:
  1084.  
  1085. ; START MULTITASKING
  1086.  
  1087. ; A 'All set - press ESC to start' messages if need
  1088. if preboot_blogesc
  1089.         mov     esi, boot_tasking
  1090.         call    boot_log
  1091. .bll1:
  1092.         in      al, 0x60        ; wait for ESC key press
  1093.         cmp     al, 129
  1094.         jne     .bll1
  1095. end if
  1096.  
  1097.         mov     [timer_ticks_enable], 1         ; for cd driver
  1098.  
  1099.         sti
  1100.  
  1101. ;        call    mtrr_validate
  1102.  
  1103.         jmp     osloop
  1104.  
  1105.  
  1106.         ; Fly :)
  1107.  
  1108. uglobal
  1109. align 4
  1110. ap_initialized  dd      0
  1111. endg
  1112.  
  1113. ap_init_high:
  1114.         mov     ax, os_stack
  1115.         mov     bx, app_data
  1116.         mov     cx, app_tls
  1117.         mov     ss, ax
  1118.         mov     ds, bx
  1119.         mov     es, bx
  1120.         mov     fs, cx
  1121.         mov     gs, bx
  1122.         xor     esp, esp
  1123.         mov     eax, sys_proc-OS_BASE+PROC.pdt_0
  1124.         mov     cr3, eax
  1125.         lock inc [ap_initialized]
  1126.         jmp     idle_loop
  1127.  
  1128.  
  1129. include 'unpacker.inc'
  1130.  
  1131. align 4
  1132. boot_log:
  1133.         pushad
  1134.  
  1135.         mov     ebx, 10*65536
  1136.         mov     bx, word [boot_y]
  1137.         add     [boot_y], dword 10
  1138.         mov     ecx, 0x80ffffff; ASCIIZ string with white color
  1139.         xor     edi, edi
  1140.         mov     edx, esi
  1141.         inc     edi
  1142.         call    dtext
  1143.  
  1144.         mov     [novesachecksum], 1000
  1145.         call    checkVga_N13
  1146.  
  1147.         popad
  1148.  
  1149.         ret
  1150.  
  1151. ; in: edx -> APPDATA for OS/IDLE slot
  1152. ; in: ebx = stack base
  1153. proc setup_os_slot
  1154.         xor     eax, eax
  1155.         mov     ecx, 256/4
  1156.         mov     edi, edx
  1157.         rep stosd
  1158.  
  1159.         mov     eax, tss+0x80
  1160.         call    get_pg_addr
  1161.         inc     eax
  1162.         mov     [edx+APPDATA.io_map], eax
  1163.         mov     eax, tss+0x1080
  1164.         call    get_pg_addr
  1165.         inc     eax
  1166.         mov     [edx+APPDATA.io_map+4], eax
  1167.  
  1168.         mov     dword [edx+APPDATA.pl0_stack], ebx
  1169.         lea     edi, [ebx+0x2000-512]
  1170.         mov     dword [edx+APPDATA.fpu_state], edi
  1171.         mov     dword [edx+APPDATA.saved_esp0], edi
  1172.         mov     dword [edx+APPDATA.saved_esp], edi
  1173.         mov     dword [edx+APPDATA.terminate_protection], 1 ; make unkillable
  1174.  
  1175.         mov     esi, fpu_data
  1176.         mov     ecx, 512/4
  1177.         cld
  1178.         rep movsd
  1179.  
  1180.         lea     eax, [edx+APP_OBJ_OFFSET]
  1181.         mov     dword [edx+APPDATA.fd_obj], eax
  1182.         mov     dword [edx+APPDATA.bk_obj], eax
  1183.  
  1184.         mov     dword [edx+APPDATA.cur_dir], sysdir_path
  1185.  
  1186.         mov     [edx + APPDATA.process], sys_proc
  1187.  
  1188.         lea     ebx, [edx+APPDATA.list]
  1189.         lea     ecx, [sys_proc+PROC.thr_list]
  1190.         list_add_tail ebx, ecx
  1191.  
  1192.         mov     eax, edx
  1193.         shr     eax, 3
  1194.         add     eax, CURRENT_TASK - (SLOT_BASE shr 3)
  1195.         mov     [eax+TASKDATA.wnd_number], dh
  1196.         mov     byte [eax+TASKDATA.pid], dh
  1197.  
  1198.         ret
  1199. endp
  1200.  
  1201. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1202. ;                                                                    ;
  1203. ;                    MAIN OS LOOP START                              ;
  1204. ;                                                                    ;
  1205. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1206. align 32
  1207. osloop:
  1208.         mov     edx, osloop_has_work?
  1209.         xor     ecx, ecx
  1210.         call    Wait_events
  1211.         xor     eax, eax
  1212.         xchg    eax, [osloop_nonperiodic_work]
  1213.         test    eax, eax
  1214.         jz      .no_periodic
  1215.  
  1216.         call    __sys_draw_pointer
  1217.         call    window_check_events
  1218.         call    mouse_check_events
  1219.         call    checkmisc
  1220.         call    checkVga_N13
  1221. ;--------------------------------------
  1222. .no_periodic:
  1223.         call    stack_handler
  1224.         call    check_fdd_motor_status
  1225.         call    check_ATAPI_device_event
  1226.         call    check_lights_state
  1227.         call    check_timers
  1228.  
  1229.         jmp     osloop
  1230. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1231. ;                                                                    ;
  1232. ;                      MAIN OS LOOP END                              ;
  1233. ;                                                                    ;
  1234. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1235. proc osloop_has_work?
  1236.         cmp     [osloop_nonperiodic_work], 0
  1237.         jnz     .yes
  1238.         call    stack_handler_has_work?
  1239.         jnz     .yes
  1240.         call    check_fdd_motor_status_has_work?
  1241.         jnz     .yes
  1242.         call    check_ATAPI_device_event_has_work?
  1243.         jnz     .yes
  1244.         call    check_lights_state_has_work?
  1245.         jnz     .yes
  1246.         call    check_timers_has_work?
  1247.         jnz     .yes
  1248. .no:
  1249.         xor     eax, eax
  1250.         ret
  1251. .yes:
  1252.         xor     eax, eax
  1253.         inc     eax
  1254.         ret
  1255. endp
  1256.  
  1257. proc wakeup_osloop
  1258.         mov     [osloop_nonperiodic_work], 1
  1259.         ret
  1260. endp
  1261.  
  1262. uglobal
  1263. align 4
  1264. osloop_nonperiodic_work dd      ?
  1265. endg
  1266.  
  1267. uglobal
  1268. align 64
  1269. idle_addr       rb      64
  1270. endg
  1271.  
  1272. idle_thread:
  1273.         sti
  1274.  
  1275. ; The following code can be executed by all CPUs in the system.
  1276. ; All other parts of the kernel do not expect multi-CPU.
  1277. ; Also, APs don't even have a stack here.
  1278. ; Beware. Don't do anything here. Anything at all.
  1279. idle_loop:
  1280.         cmp     [use_mwait_for_idle], 0
  1281.         jnz     idle_loop_mwait
  1282.  
  1283. idle_loop_hlt:
  1284.         hlt
  1285.         jmp     idle_loop_hlt
  1286.  
  1287. idle_loop_mwait:
  1288.         mov     eax, idle_addr
  1289.         xor     ecx, ecx
  1290.         xor     edx, edx
  1291.         monitor
  1292.         xor     ecx, ecx
  1293.         mov     eax, 20h        ; or 10h
  1294.         mwait
  1295.         jmp     idle_loop_mwait
  1296.  
  1297.  
  1298. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1299. ;                                                                      ;
  1300. ;                   INCLUDED SYSTEM FILES                              ;
  1301. ;                                                                      ;
  1302. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1303.  
  1304.  
  1305. include "kernel32.inc"
  1306.  
  1307.  
  1308. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1309. ;                                                                      ;
  1310. ;                       KERNEL FUNCTIONS                               ;
  1311. ;                                                                      ;
  1312. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1313.  
  1314. reserve_irqs_ports:
  1315.  
  1316.  
  1317. ; RESERVE PORTS
  1318.         mov     eax, RESERVED_PORTS
  1319.         mov     ecx, 1
  1320.  
  1321.         mov     [eax], dword 4
  1322.  
  1323.         mov     [eax+16], ecx
  1324.         mov     [eax+16+4], dword 0
  1325.         mov     [eax+16+8], dword 0x2D
  1326.  
  1327.         mov     [eax+32], ecx
  1328.         mov     [eax+32+4], dword 0x30
  1329.         mov     [eax+32+8], dword 0x4D
  1330.  
  1331.         mov     [eax+48], ecx
  1332.         mov     [eax+48+4], dword 0x50
  1333.         mov     [eax+48+8], dword 0xDF
  1334.  
  1335.         mov     [eax+64], ecx
  1336.         mov     [eax+64+4], dword 0xE5
  1337.         mov     [eax+64+8], dword 0xFF
  1338.  
  1339.         ret
  1340.  
  1341.  
  1342. iglobal
  1343.   process_number dd 0x2
  1344. endg
  1345.  
  1346. set_variables:
  1347.  
  1348.         mov     ecx, 0x16                    ; flush port 0x60
  1349. .fl60:
  1350.         in      al, 0x60
  1351.         loop    .fl60
  1352.         push    eax
  1353.  
  1354.         mov     ax, [BOOT_VARS+BOOT_Y_RES]
  1355.         shr     ax, 1
  1356.         shl     eax, 16
  1357.         mov     ax, [BOOT_VARS+BOOT_X_RES]
  1358.         shr     ax, 1
  1359.         mov     [MOUSE_X], eax
  1360.         call    wakeup_osloop
  1361.  
  1362.         xor     eax, eax
  1363.         mov     [BTN_ADDR], dword BUTTON_INFO ; address of button list
  1364.  
  1365.         mov     byte [KEY_COUNT], al              ; keyboard buffer
  1366.         mov     byte [BTN_COUNT], al              ; button buffer
  1367. ;        mov   [MOUSE_X],dword 100*65536+100    ; mouse x/y
  1368.  
  1369.         pop     eax
  1370.         ret
  1371.  
  1372. align 4
  1373. ;input  eax=43,bl-byte of output, ecx - number of port
  1374. sys_outport:
  1375.  
  1376.         mov     edi, ecx   ; separate flag for read / write
  1377.         and     ecx, 65535
  1378.  
  1379.         mov     eax, [RESERVED_PORTS]
  1380.         test    eax, eax
  1381.         jnz     .sopl8
  1382.         inc     eax
  1383.         mov     [esp+32], eax
  1384.         ret
  1385.  
  1386.   .sopl8:
  1387.         mov     edx, [TASK_BASE]
  1388.         mov     edx, [edx+0x4]
  1389.     ;and   ecx,65535
  1390.     ;cld - set on interrupt 0x40
  1391.   .sopl1:
  1392.  
  1393.         mov     esi, eax
  1394.         shl     esi, 4
  1395.         add     esi, RESERVED_PORTS
  1396.         cmp     edx, [esi+0]
  1397.         jne     .sopl2
  1398.         cmp     ecx, [esi+4]
  1399.         jb      .sopl2
  1400.         cmp     ecx, [esi+8]
  1401.         jg      .sopl2
  1402. .sopl3:
  1403.  
  1404.         test    edi, 0x80000000; read ?
  1405.         jnz     .sopl4
  1406.  
  1407.         mov     eax, ebx
  1408.         mov     dx, cx   ; write
  1409.         out     dx, al
  1410.         and     [esp+32], dword 0
  1411.         ret
  1412.  
  1413.         .sopl2:
  1414.  
  1415.         dec     eax
  1416.         jnz     .sopl1
  1417.         inc     eax
  1418.         mov     [esp+32], eax
  1419.         ret
  1420.  
  1421.  
  1422.   .sopl4:
  1423.  
  1424.         mov     dx, cx   ; read
  1425.         in      al, dx
  1426.         and     eax, 0xff
  1427.         and     [esp+32], dword 0
  1428.         mov     [esp+20], eax
  1429.         ret
  1430.  
  1431. display_number:
  1432. ;It is not optimization
  1433.         mov     eax, ebx
  1434.         mov     ebx, ecx
  1435.         mov     ecx, edx
  1436.         mov     edx, esi
  1437.         mov     esi, edi
  1438. ; eax = print type, al=0 -> ebx is number
  1439. ;                   al=1 -> ebx is pointer
  1440. ;                   ah=0 -> display decimal
  1441. ;                   ah=1 -> display hexadecimal
  1442. ;                   ah=2 -> display binary
  1443. ;                   eax bits 16-21 = number of digits to display (0-32)
  1444. ;                   eax bits 22-31 = reserved
  1445. ;
  1446. ; ebx = number or pointer
  1447. ; ecx = x shl 16 + y
  1448. ; edx = color
  1449.         xor     edi, edi
  1450. display_number_force:
  1451.         push    eax
  1452.         and     eax, 0x3fffffff
  1453.         cmp     eax, 0xffff     ; length > 0 ?
  1454.         pop     eax
  1455.         jge     cont_displ
  1456.         ret
  1457.    cont_displ:
  1458.         push    eax
  1459.         and     eax, 0x3fffffff
  1460.         cmp     eax, 61*0x10000  ; length <= 60 ?
  1461.         pop     eax
  1462.         jb      cont_displ2
  1463.         ret
  1464.    cont_displ2:
  1465.  
  1466.         pushad
  1467.  
  1468.         cmp     al, 1            ; ecx is a pointer ?
  1469.         jne     displnl1
  1470.         mov     ebp, ebx
  1471.         add     ebp, 4
  1472.         mov     ebp, [ebp+std_application_base_address]
  1473.         mov     ebx, [ebx+std_application_base_address]
  1474.  displnl1:
  1475.         sub     esp, 64
  1476.  
  1477.         test    ah, ah            ; DECIMAL
  1478.         jnz     no_display_desnum
  1479.         shr     eax, 16
  1480.         and     eax, 0xC03f
  1481. ;     and   eax,0x3f
  1482.         push    eax
  1483.         and     eax, 0x3f
  1484.         mov     edi, esp
  1485.         add     edi, 4+64-1
  1486.         mov     ecx, eax
  1487.         mov     eax, ebx
  1488.         mov     ebx, 10
  1489.  d_desnum:
  1490.         xor     edx, edx
  1491.         call    division_64_bits
  1492.         div     ebx
  1493.         add     dl, 48
  1494.         mov     [edi], dl
  1495.         dec     edi
  1496.         loop    d_desnum
  1497.         pop     eax
  1498.         call    normalize_number
  1499.         call    draw_num_text
  1500.         add     esp, 64
  1501.         popad
  1502.         ret
  1503.    no_display_desnum:
  1504.  
  1505.         cmp     ah, 0x01         ; HEXADECIMAL
  1506.         jne     no_display_hexnum
  1507.         shr     eax, 16
  1508.         and     eax, 0xC03f
  1509. ;     and   eax,0x3f
  1510.         push    eax
  1511.         and     eax, 0x3f
  1512.         mov     edi, esp
  1513.         add     edi, 4+64-1
  1514.         mov     ecx, eax
  1515.         mov     eax, ebx
  1516.         mov     ebx, 16
  1517.    d_hexnum:
  1518.         xor     edx, edx
  1519.         call    division_64_bits
  1520.         div     ebx
  1521.    hexletters = __fdo_hexdigits
  1522.         add     edx, hexletters
  1523.         mov     dl, [edx]
  1524.         mov     [edi], dl
  1525.         dec     edi
  1526.         loop    d_hexnum
  1527.         pop     eax
  1528.         call    normalize_number
  1529.         call    draw_num_text
  1530.         add     esp, 64
  1531.         popad
  1532.         ret
  1533.    no_display_hexnum:
  1534.  
  1535.         cmp     ah, 0x02         ; BINARY
  1536.         jne     no_display_binnum
  1537.         shr     eax, 16
  1538.         and     eax, 0xC03f
  1539. ;     and   eax,0x3f
  1540.         push    eax
  1541.         and     eax, 0x3f
  1542.         mov     edi, esp
  1543.         add     edi, 4+64-1
  1544.         mov     ecx, eax
  1545.         mov     eax, ebx
  1546.         mov     ebx, 2
  1547.    d_binnum:
  1548.         xor     edx, edx
  1549.         call    division_64_bits
  1550.         div     ebx
  1551.         add     dl, 48
  1552.         mov     [edi], dl
  1553.         dec     edi
  1554.         loop    d_binnum
  1555.         pop     eax
  1556.         call    normalize_number
  1557.         call    draw_num_text
  1558.         add     esp, 64
  1559.         popad
  1560.         ret
  1561.    no_display_binnum:
  1562.  
  1563.         add     esp, 64
  1564.         popad
  1565.         ret
  1566.  
  1567. normalize_number:
  1568.         test    ah, 0x80
  1569.         jz      .continue
  1570.         mov     ecx, 48
  1571.         and     eax, 0x3f
  1572. @@:
  1573.         inc     edi
  1574.         cmp     [edi], cl
  1575.         jne     .continue
  1576.         dec     eax
  1577.         cmp     eax, 1
  1578.         ja      @r
  1579.         mov     al, 1
  1580. .continue:
  1581.         and     eax, 0x3f
  1582.         ret
  1583.  
  1584. division_64_bits:
  1585.         test    [esp+1+4], byte 0x40
  1586.         jz      .continue
  1587.         push    eax
  1588.         mov     eax, ebp
  1589.         div     ebx
  1590.         mov     ebp, eax
  1591.         pop     eax
  1592. .continue:
  1593.         ret
  1594.  
  1595. draw_num_text:
  1596.         mov     esi, eax
  1597.         mov     edx, 64+4
  1598.         sub     edx, eax
  1599.         add     edx, esp
  1600.         mov     ebx, [esp+64+32-8+4]
  1601. ; add window start x & y
  1602.         mov     ecx, [TASK_BASE]
  1603.  
  1604.         mov     edi, [CURRENT_TASK]
  1605.         shl     edi, 8
  1606.  
  1607.         mov     eax, [ecx-twdw+WDATA.box.left]
  1608.         add     eax, [edi+SLOT_BASE+APPDATA.wnd_clientbox.left]
  1609.         shl     eax, 16
  1610.         add     eax, [ecx-twdw+WDATA.box.top]
  1611.         add     eax, [edi+SLOT_BASE+APPDATA.wnd_clientbox.top]
  1612.         add     ebx, eax
  1613.         mov     ecx, [esp+64+32-12+4]
  1614.         mov     eax, [esp+64+8]         ; background color (if given)
  1615.         mov     edi, [esp+64+4]
  1616.         and     ecx, 5FFFFFFFh
  1617.         bt      ecx, 27
  1618.         jnc     @f
  1619.         mov     edi, eax
  1620. @@:
  1621.         jmp     dtext
  1622. ;-----------------------------------------------------------------------------
  1623. iglobal
  1624. midi_base dw 0
  1625. endg
  1626. ;-----------------------------------------------------------------------------
  1627. align 4
  1628. sys_setup:
  1629. ;  1 = roland mpu midi base , base io address
  1630. ;  2 = keyboard   1, base kaybap 2, shift keymap, 9 country 1eng 2fi 3ger 4rus
  1631. ;  3 = not used
  1632. ;  4 = not used
  1633. ;  5 = system language, 1eng 2fi 3ger 4rus
  1634. ;  6 = not used
  1635. ;  7 = not used
  1636. ;  8 = not used
  1637. ;  9 = not used
  1638. ; 10 = not used
  1639. ; 11 = enable lba read
  1640. ; 12 = enable pci access
  1641. ;-----------------------------------------------------------------------------
  1642.         and     [esp+32], dword 0
  1643. ; F.21.1 - set MPU MIDI base port
  1644.         dec     ebx
  1645.         jnz     @f
  1646.  
  1647.         cmp     ecx, 0x100
  1648.         jb      @f
  1649.  
  1650.         mov     esi, 65535
  1651.         cmp     esi, ecx
  1652.         jb      @f
  1653.  
  1654.         mov     [midi_base], cx
  1655.         mov     word [mididp], cx
  1656.         inc     cx
  1657.         mov     word [midisp], cx
  1658.         ret
  1659. ;--------------------------------------
  1660. @@:
  1661. ; F.21.2 - set keyboard layout
  1662.         dec     ebx
  1663.         jnz     @f
  1664.  
  1665.         mov     edi, [TASK_BASE]
  1666.         mov     eax, [edi+TASKDATA.mem_start]
  1667.         add     eax, edx
  1668. ; 1 = normal layout
  1669.         dec     ecx
  1670.         jnz     .shift
  1671.  
  1672.         mov     ebx, keymap
  1673.         mov     ecx, 128
  1674.         call    memmove
  1675.         ret
  1676. ;--------------------------------------
  1677. .shift:
  1678. ; 2 = layout at pressed Shift
  1679.         dec     ecx
  1680.         jnz     .alt
  1681.  
  1682.         mov     ebx, keymap_shift
  1683.         mov     ecx, 128
  1684.         call    memmove
  1685.         ret
  1686. ;--------------------------------------
  1687. .alt:
  1688. ; 3 = layout at pressed Alt
  1689.         dec     ecx
  1690.         jnz     .country
  1691.  
  1692.         mov     ebx, keymap_alt
  1693.         mov     ecx, 128
  1694.         call    memmove
  1695.         ret
  1696. ;--------------------------------------
  1697. .country:
  1698. ; country identifier
  1699.         sub     ecx, 6
  1700.         jnz     .error
  1701.  
  1702.         mov     word [keyboard], dx
  1703.         ret
  1704. ;--------------------------------------
  1705. @@:
  1706. ; F.21.5 - set system language
  1707.         sub     ebx, 3
  1708.         jnz     @f
  1709.  
  1710.         mov     [syslang], ecx
  1711.         ret
  1712. ;--------------------------------------
  1713. @@:
  1714. ; F.21.11 - enable/disable low-level access to HD
  1715.         and     ecx, 1
  1716.         sub     ebx, 6
  1717.         jnz     @f
  1718.  
  1719.         mov     [lba_read_enabled], ecx
  1720.         ret
  1721. ;--------------------------------------
  1722. @@:
  1723. ; F.21.12 - enable/disable low-level access to PCI
  1724.         dec     ebx
  1725.         jnz     .error
  1726.  
  1727.         mov     [pci_access_enabled], ecx
  1728.         ret
  1729. ;--------------------------------------
  1730. .error:
  1731.         or      [esp+32], dword -1
  1732.         ret
  1733. ;-----------------------------------------------------------------------------
  1734. align 4
  1735. sys_getsetup:
  1736. ;  1 = roland mpu midi base , base io address
  1737. ;  2 = keyboard   1, base kaybap 2, shift keymap, 9 country 1eng 2fi 3ger 4rus
  1738. ;  3 = not used
  1739. ;  4 = not used
  1740. ;  5 = system language, 1eng 2fi 3ger 4rus
  1741. ;  6 = not used
  1742. ;  7 = not used
  1743. ;  8 = not used
  1744. ;  9 = get hs timer tic
  1745. ; 10 = not used
  1746. ; 11 = get the state "lba read"
  1747. ; 12 = get the state "pci access"
  1748. ;-----------------------------------------------------------------------------
  1749. ; F.26.1 - get MPU MIDI base port
  1750.         dec     ebx
  1751.         jnz     @f
  1752.  
  1753.         movzx   eax, [midi_base]
  1754.         mov     [esp+32], eax
  1755.         ret
  1756. ;--------------------------------------
  1757. @@:
  1758. ; F.26.2 - get keyboard layout
  1759.         dec     ebx
  1760.         jnz     @f
  1761.  
  1762.         mov     edi, [TASK_BASE]
  1763.         mov     ebx, [edi+TASKDATA.mem_start]
  1764.         add     ebx, edx
  1765. ; 1 = normal layout
  1766.         dec     ecx
  1767.         jnz     .shift
  1768.  
  1769.         mov     eax, keymap
  1770.         mov     ecx, 128
  1771.         call    memmove
  1772.         ret
  1773. ;--------------------------------------
  1774. .shift:
  1775. ; 2 = layout with pressed Shift
  1776.         dec     ecx
  1777.         jnz     .alt
  1778.  
  1779.         mov     eax, keymap_shift
  1780.         mov     ecx, 128
  1781.         call    memmove
  1782.         ret
  1783. ;--------------------------------------
  1784. .alt:
  1785. ; 3 = layout with pressed Alt
  1786.         dec     ecx
  1787.         jne     .country
  1788.  
  1789.         mov     eax, keymap_alt
  1790.         mov     ecx, 128
  1791.         call    memmove
  1792.         ret
  1793. ;--------------------------------------
  1794. .country:
  1795. ; 9 = country identifier
  1796.         sub     ecx, 6
  1797.         jnz     .error
  1798.  
  1799.         movzx   eax, word [keyboard]
  1800.         mov     [esp+32], eax
  1801.         ret
  1802. ;--------------------------------------
  1803. @@:
  1804. ; F.26.5 - get system language
  1805.         sub     ebx, 3
  1806.         jnz     @f
  1807.  
  1808.         mov     eax, [syslang]
  1809.         mov     [esp+32], eax
  1810.         ret
  1811. ;--------------------------------------
  1812. @@:
  1813. ; F.26.9 - get the value of the time counter
  1814.         sub     ebx, 4
  1815.         jnz     @f
  1816.  
  1817.         mov     eax, [timer_ticks]
  1818.         mov     [esp+32], eax
  1819.         ret
  1820. ;--------------------------------------
  1821. @@:
  1822. ; F.26.10 - get the time from kernel launch in nanoseconds
  1823.         sub     ebx, 1
  1824.         jnz     @f
  1825.  
  1826.         call    get_clock_ns
  1827.         mov     [esp+24], edx
  1828.         mov     [esp+32], eax
  1829.         ret
  1830. ;--------------------------------------
  1831. @@:
  1832. ; F.26.11 - Find out whether low-level HD access is enabled
  1833.         sub     ebx, 1
  1834.         jnz     @f
  1835.  
  1836.         mov     eax, [lba_read_enabled]
  1837.         mov     [esp+32], eax
  1838.         ret
  1839. ;--------------------------------------
  1840. @@:
  1841. ; F.26.12 - Find out whether low-level PCI access is enabled
  1842.         dec     ebx
  1843.         jnz     .error
  1844.  
  1845.         mov     eax, [pci_access_enabled]
  1846.         mov     [esp+32], eax
  1847.         ret
  1848. ;--------------------------------------
  1849. .error:
  1850.         or      [esp+32], dword -1
  1851.         ret
  1852. ;-----------------------------------------------------------------------------
  1853. get_timer_ticks:
  1854.         mov     eax, [timer_ticks]
  1855.         ret
  1856. ;-----------------------------------------------------------------------------
  1857. iglobal
  1858. align 4
  1859. mousefn dd msscreen
  1860.         dd mswin
  1861.         dd msbutton
  1862.         dd msbuttonExt
  1863.         dd app_load_cursor
  1864.         dd app_set_cursor
  1865.         dd app_delete_cursor
  1866.         dd msz
  1867. endg
  1868. ;-----------------------------------------------------------------------------
  1869. readmousepos:
  1870.  
  1871. ; eax=0 screen relative
  1872. ; eax=1 window relative
  1873. ; eax=2 buttons pressed
  1874. ; eax=3 buttons pressed ext
  1875. ; eax=4 load cursor
  1876. ; eax=5 set cursor
  1877. ; eax=6 delete cursor
  1878. ; eax=7 get mouse_z
  1879.  
  1880.         cmp     ebx, 7
  1881.         ja      @f
  1882.         jmp     [mousefn+ebx*4]
  1883.  
  1884. msscreen:
  1885.         mov     eax, [MOUSE_X]
  1886.         shl     eax, 16
  1887.         mov     ax, [MOUSE_Y]
  1888.         mov     [esp+36-4], eax
  1889. @@:
  1890.         ret
  1891.  
  1892. mswin:
  1893.         mov     eax, [MOUSE_X]
  1894.         shl     eax, 16
  1895.         mov     ax, [MOUSE_Y]
  1896.         mov     esi, [TASK_BASE]
  1897.         mov     bx, word [esi-twdw+WDATA.box.left]
  1898.         shl     ebx, 16
  1899.         mov     bx, word [esi-twdw+WDATA.box.top]
  1900.         sub     eax, ebx
  1901.         mov     edi, [CURRENT_TASK]
  1902.         shl     edi, 8
  1903.         sub     ax, word[edi+SLOT_BASE+APPDATA.wnd_clientbox.top]
  1904.         rol     eax, 16
  1905.         sub     ax, word[edi+SLOT_BASE+APPDATA.wnd_clientbox.left]
  1906.         rol     eax, 16
  1907.         mov     [esp+36-4], eax
  1908.         ret
  1909.  
  1910. msbutton:
  1911.         movzx   eax, byte [BTN_DOWN]
  1912.         mov     [esp+36-4], eax
  1913.         ret
  1914.  
  1915. msbuttonExt:
  1916.         mov     eax, [BTN_DOWN]
  1917.         mov     [esp+36-4], eax
  1918.         ret
  1919.  
  1920. app_load_cursor:
  1921.         cmp     ecx, OS_BASE
  1922.         jae     @f
  1923.         stdcall load_cursor, ecx, edx
  1924.         mov     [esp+36-4], eax
  1925. @@:
  1926.         ret
  1927.  
  1928. app_set_cursor:
  1929.         stdcall set_cursor, ecx
  1930.         mov     [esp+36-4], eax
  1931.         ret
  1932.  
  1933. app_delete_cursor:
  1934.         stdcall delete_cursor, ecx
  1935.         mov     [esp+36-4], eax
  1936.         ret
  1937.  
  1938. msz:
  1939.         mov     edi, [TASK_COUNT]
  1940.         movzx   edi, word [WIN_POS + edi*2]
  1941.         cmp     edi, [CURRENT_TASK]
  1942.         jne     @f
  1943.         mov     ax, [MOUSE_SCROLL_H]
  1944.         shl     eax, 16
  1945.         mov     ax, [MOUSE_SCROLL_V]
  1946.         mov     [esp+36-4], eax
  1947.         and     [MOUSE_SCROLL_H], word 0
  1948.         and     [MOUSE_SCROLL_V], word 0
  1949.         ret
  1950. @@:
  1951.         and     [esp+36-4], dword 0
  1952.         ret
  1953.  
  1954. is_input:
  1955.  
  1956.         push    edx
  1957.         mov     dx, word [midisp]
  1958.         in      al, dx
  1959.         and     al, 0x80
  1960.         pop     edx
  1961.         ret
  1962.  
  1963. is_output:
  1964.  
  1965.         push    edx
  1966.         mov     dx, word [midisp]
  1967.         in      al, dx
  1968.         and     al, 0x40
  1969.         pop     edx
  1970.         ret
  1971.  
  1972.  
  1973. get_mpu_in:
  1974.  
  1975.         push    edx
  1976.         mov     dx, word [mididp]
  1977.         in      al, dx
  1978.         pop     edx
  1979.         ret
  1980.  
  1981.  
  1982. put_mpu_out:
  1983.  
  1984.         push    edx
  1985.         mov     dx, word [mididp]
  1986.         out     dx, al
  1987.         pop     edx
  1988.         ret
  1989.  
  1990.  
  1991.  
  1992. align 4
  1993.  
  1994. sys_midi:
  1995.         cmp     [mididp], 0
  1996.         jnz     sm0
  1997.         mov     [esp+36], dword 1
  1998.         ret
  1999. sm0:
  2000.         and     [esp+36], dword 0
  2001.         dec     ebx
  2002.         jnz     smn1
  2003.  ;    call setuart
  2004. su1:
  2005.         call    is_output
  2006.         test    al, al
  2007.         jnz     su1
  2008.         mov     dx, word [midisp]
  2009.         mov     al, 0xff
  2010.         out     dx, al
  2011. su2:
  2012.         mov     dx, word [midisp]
  2013.         mov     al, 0xff
  2014.         out     dx, al
  2015.         call    is_input
  2016.         test    al, al
  2017.         jnz     su2
  2018.         call    get_mpu_in
  2019.         cmp     al, 0xfe
  2020.         jnz     su2
  2021. su3:
  2022.         call    is_output
  2023.         test    al, al
  2024.         jnz     su3
  2025.         mov     dx, word [midisp]
  2026.         mov     al, 0x3f
  2027.         out     dx, al
  2028.         ret
  2029. smn1:
  2030.         dec     ebx
  2031.         jnz     smn2
  2032. sm10:
  2033.         call    get_mpu_in
  2034.         call    is_output
  2035.         test    al, al
  2036.         jnz     sm10
  2037.         mov     al, bl
  2038.         call    put_mpu_out
  2039.         smn2:
  2040.         ret
  2041.  
  2042. detect_devices:
  2043. ;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  2044. ;include 'detect/commouse.inc'
  2045. ;include 'detect/ps2mouse.inc'
  2046. ;include 'detect/dev_fd.inc'
  2047. ;include 'detect/dev_hdcd.inc'
  2048. ;include 'detect/sear_par.inc'
  2049. ;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  2050.         ret
  2051.  
  2052. sys_end:
  2053. ;--------------------------------------
  2054.         cmp     [_display.select_cursor], 0
  2055.         je      @f
  2056. ; restore default cursor before killing
  2057.         pusha
  2058.         mov     ecx, [current_slot]
  2059.         call    restore_default_cursor_before_killing
  2060.         popa
  2061. @@:
  2062. ;--------------------------------------
  2063. ; kill all sockets this process owns
  2064.         pusha
  2065.         mov     edx, [TASK_BASE]
  2066.         mov     edx, [edx+TASKDATA.pid]
  2067.         call    socket_process_end
  2068.         popa
  2069. ;--------------------------------------
  2070.         mov     ecx, [current_slot]
  2071.         mov     eax, [ecx+APPDATA.tls_base]
  2072.         test    eax, eax
  2073.         jz      @F
  2074.  
  2075.         stdcall user_free, eax
  2076. @@:
  2077.  
  2078.         mov     eax, [TASK_BASE]
  2079.         mov     [eax+TASKDATA.state], TSTATE_ZOMBIE
  2080.         call    wakeup_osloop
  2081.  
  2082. .waitterm:            ; wait here for termination
  2083.         call    change_task
  2084.         jmp     .waitterm
  2085. ;------------------------------------------------------------------------------
  2086. align 4
  2087. restore_default_cursor_before_killing:
  2088.         pushfd
  2089.         cli
  2090.         mov     eax, [def_cursor]
  2091.         mov     [ecx+APPDATA.cursor], eax
  2092.  
  2093.         movzx   eax, word [MOUSE_Y]
  2094.         movzx   ebx, word [MOUSE_X]
  2095.         mov     eax, [d_width_calc_area + eax*4]
  2096.  
  2097.         add     eax, [_display.win_map]
  2098.         movzx   edx, byte [ebx+eax]
  2099.         shl     edx, 8
  2100.         mov     esi, [edx+SLOT_BASE+APPDATA.cursor]
  2101.  
  2102.         cmp     esi, [current_cursor]
  2103.         je      @f
  2104.  
  2105.         push    esi
  2106.         call    [_display.select_cursor]
  2107.         mov     [current_cursor], esi
  2108. @@:
  2109.         mov     [redrawmouse_unconditional], 1
  2110.         call    wakeup_osloop
  2111.         popfd
  2112.         ret
  2113. ;------------------------------------------------------------------------------
  2114. iglobal
  2115. align 4
  2116. sys_system_table:
  2117.         dd      sysfn_deactivate        ; 1 = deactivate window
  2118.         dd      sysfn_terminate         ; 2 = terminate thread
  2119.         dd      sysfn_activate          ; 3 = activate window
  2120.         dd      sysfn_getidletime       ; 4 = get idle time
  2121.         dd      sysfn_getcpuclock       ; 5 = get cpu clock
  2122.         dd      sysfn_saveramdisk       ; 6 = save ramdisk
  2123.         dd      sysfn_getactive         ; 7 = get active window
  2124.         dd      sysfn_sound_flag        ; 8 = get/set sound_flag
  2125.         dd      sysfn_shutdown          ; 9 = shutdown with parameter
  2126.         dd      sysfn_minimize          ; 10 = minimize window
  2127.         dd      sysfn_getdiskinfo       ; 11 = get disk subsystem info
  2128.         dd      sysfn_lastkey           ; 12 = get last pressed key
  2129.         dd      sysfn_getversion        ; 13 = get kernel version
  2130.         dd      sysfn_waitretrace       ; 14 = wait retrace
  2131.         dd      sysfn_centermouse       ; 15 = center mouse cursor
  2132.         dd      sysfn_getfreemem        ; 16 = get free memory size
  2133.         dd      sysfn_getallmem         ; 17 = get total memory size
  2134.         dd      sysfn_terminate2        ; 18 = terminate thread using PID
  2135.                                         ;                 instead of slot
  2136.         dd      sysfn_mouse_acceleration; 19 = set/get mouse acceleration
  2137.         dd      sysfn_meminfo           ; 20 = get extended memory info
  2138.         dd      sysfn_pid_to_slot       ; 21 = get slot number for pid
  2139.         dd      sysfn_min_rest_window   ; 22 = minimize and restore any window
  2140.         dd      sysfn_min_windows       ; 23 = minimize all windows
  2141.         dd      sysfn_set_screen_sizes  ; 24 = set screen sizes for Vesa
  2142.  
  2143.         dd      sysfn_zmodif            ; 25 = get/set window z modifier  ;Fantomer
  2144. sysfn_num = ($ - sys_system_table)/4
  2145. endg
  2146. ;------------------------------------------------------------------------------
  2147. sys_system:
  2148.         dec     ebx
  2149.         cmp     ebx, sysfn_num
  2150.         jae     @f
  2151.         jmp     dword [sys_system_table + ebx*4]
  2152. @@:
  2153.         ret
  2154. ;------------------------------------------------------------------------------
  2155. sysfn_shutdown:          ; 18.9 = system shutdown
  2156.         cmp     ecx, 1
  2157.         jl      exit_for_anyone
  2158.         cmp     ecx, 4
  2159.         jg      exit_for_anyone
  2160.         mov     [BOOT_VARS+0x9030], cl
  2161.  
  2162.         mov     eax, [TASK_COUNT]
  2163.         mov     [SYS_SHUTDOWN], al
  2164.         mov     [shutdown_processes], eax
  2165.         call    wakeup_osloop
  2166.         and     dword [esp+32], 0
  2167.  exit_for_anyone:
  2168.         ret
  2169.   uglobal
  2170.    shutdown_processes:
  2171.                        dd 0x0
  2172.   endg
  2173. ;------------------------------------------------------------------------------
  2174. sysfn_terminate:        ; 18.2 = TERMINATE
  2175.         push    ecx
  2176.         cmp     ecx, 2
  2177.         jb      noprocessterminate
  2178.         mov     edx, [TASK_COUNT]
  2179.         cmp     ecx, edx
  2180.         ja      noprocessterminate
  2181.         mov     eax, [TASK_COUNT]
  2182.         shl     ecx, 5
  2183.         mov     edx, [ecx+CURRENT_TASK+TASKDATA.pid]
  2184.         add     ecx, CURRENT_TASK+TASKDATA.state
  2185.         cmp     byte [ecx], 9
  2186.         jz      noprocessterminate
  2187.         push    ecx edx
  2188.         lea     edx, [(ecx-(CURRENT_TASK and 1FFFFFFFh)-TASKDATA.state)*8+SLOT_BASE]
  2189.         call    request_terminate
  2190.         pop     edx ecx
  2191.         test    eax, eax
  2192.         jz      noprocessterminate
  2193. ;--------------------------------------
  2194. ; terminate all network sockets it used
  2195.         pusha
  2196.         mov     eax, edx
  2197.         call    socket_process_end
  2198.         popa
  2199. ;--------------------------------------
  2200.         cmp     [_display.select_cursor], 0
  2201.         je      .restore_end
  2202. ; restore default cursor before killing
  2203.         pusha
  2204.         mov     ecx, [esp+32]
  2205.         shl     ecx, 8
  2206.         add     ecx, SLOT_BASE
  2207.         mov     eax, [def_cursor]
  2208.         cmp     [ecx+APPDATA.cursor], eax
  2209.         je      @f
  2210.         call    restore_default_cursor_before_killing
  2211. @@:
  2212.         popa
  2213. .restore_end:
  2214. ;--------------------------------------
  2215.      ;call MEM_Heap_Lock      ;guarantee that process isn't working with heap
  2216.         mov     [ecx], byte 3; clear possible i40's
  2217.         call    wakeup_osloop
  2218.      ;call MEM_Heap_UnLock
  2219.  
  2220.         cmp     edx, [application_table_owner]; clear app table stat
  2221.         jne     noatsc
  2222.         call    unlock_application_table
  2223. noatsc:
  2224. noprocessterminate:
  2225.         add     esp, 4
  2226.         ret
  2227. ;------------------------------------------------------------------------------
  2228. sysfn_terminate2:
  2229. ;lock application_table_status mutex
  2230. .table_status:
  2231.         call    lock_application_table
  2232.         mov     eax, ecx
  2233.         call    pid_to_slot
  2234.         test    eax, eax
  2235.         jz      .not_found
  2236.         mov     ecx, eax
  2237.         cli
  2238.         call    sysfn_terminate
  2239.         call    unlock_application_table
  2240. ;        sti
  2241.         and     dword [esp+32], 0
  2242.         ret
  2243. .not_found:
  2244.         call    unlock_application_table
  2245.         or      dword [esp+32], -1
  2246.         ret
  2247. ;------------------------------------------------------------------------------
  2248. sysfn_deactivate:         ; 18.1 = DEACTIVATE WINDOW
  2249.         cmp     ecx, 2
  2250.         jb      .nowindowdeactivate
  2251.         cmp     ecx, [TASK_COUNT]
  2252.         ja      .nowindowdeactivate
  2253.  
  2254.         movzx   esi, word [WIN_STACK + ecx*2]
  2255.         cmp     esi, 1
  2256.         je      .nowindowdeactivate ; already deactive
  2257.  
  2258.         mov     edi, ecx
  2259.         shl     edi, 5
  2260.         add     edi, window_data
  2261.         movzx   esi, word [WIN_STACK + ecx * 2]
  2262.         lea     esi, [WIN_POS + esi * 2]
  2263.         call    window._.window_deactivate
  2264.  
  2265.         call    syscall_display_settings._.calculate_whole_screen
  2266.         call    syscall_display_settings._.redraw_whole_screen
  2267. .nowindowdeactivate:
  2268.         ret
  2269. ;------------------------------------------------------------------------------
  2270. sysfn_activate:         ; 18.3 = ACTIVATE WINDOW
  2271.         cmp     ecx, 2
  2272.         jb      .nowindowactivate
  2273.         cmp     ecx, [TASK_COUNT]
  2274.         ja      .nowindowactivate
  2275. ;-------------------------------------
  2276. @@:
  2277. ; If the window is captured and moved by the user,
  2278. ; then you can't change the position in window stack!!!
  2279.         mov     al, [mouse.active_sys_window.action]
  2280.         and     al, WINDOW_MOVE_AND_RESIZE_FLAGS
  2281.         test    al, al
  2282.         jz      @f
  2283.         call    change_task
  2284.         jmp     @b
  2285. @@:
  2286. ;-------------------------------------
  2287.         mov     [window_minimize], 2; restore window if minimized
  2288.         call    wakeup_osloop
  2289.  
  2290.         movzx   esi, word [WIN_STACK + ecx*2]
  2291.         cmp     esi, [TASK_COUNT]
  2292.         je      .nowindowactivate; already active
  2293.  
  2294.         mov     edi, ecx
  2295.         shl     edi, 5
  2296.         add     edi, window_data
  2297.         movzx   esi, word [WIN_STACK + ecx * 2]
  2298.         lea     esi, [WIN_POS + esi * 2]
  2299.         call    waredraw
  2300. .nowindowactivate:
  2301.         ret
  2302. ;------------------------------------------------------------------------------
  2303. align 4
  2304. sysfn_zmodif:
  2305. ;18,25,1 - get z_modif
  2306. ;18,25,2 - set z_modif
  2307. ;edx = -1(for current task) or TID
  2308. ;esi(for 2) = new value z_modif
  2309. ;return:
  2310. ;1:   eax = z_modif
  2311. ;2: eax=0(fail),1(success) for set z_modif
  2312.  
  2313.         cmp     edx, -1
  2314.         jne     @f
  2315.         mov     edx, [CURRENT_TASK]
  2316.      @@:
  2317.         cmp     edx, [TASK_COUNT]
  2318.         ja      .fail
  2319.         cmp     edx, 1
  2320.         je      .fail
  2321.  
  2322.         mov     eax, edx
  2323.         shl     edx, 5
  2324.  
  2325.         cmp     [edx + CURRENT_TASK + TASKDATA.state], 9
  2326.         je      .fail
  2327.  
  2328.         cmp     ecx, 1
  2329.         jnz     .set_zmod
  2330.  
  2331.         mov     al, [edx + window_data + WDATA.z_modif]
  2332.         jmp     .exit
  2333.  
  2334. .set_zmod:
  2335.         cmp     ecx, 2
  2336.         jnz     .fail
  2337.  
  2338.         mov     ebx, esi
  2339.         mov     esi, eax
  2340.  
  2341.         cmp     bl, ZPOS_ALWAYS_TOP
  2342.         jg      .fail
  2343.  
  2344.         mov     [edx + window_data + WDATA.z_modif], bl
  2345.  
  2346.         mov     eax, [edx + window_data + WDATA.box.left]
  2347.         mov     ebx, [edx + window_data + WDATA.box.top]
  2348.         mov     ecx, [edx + window_data + WDATA.box.width]
  2349.         mov     edx, [edx + window_data + WDATA.box.height]
  2350.         add     ecx, eax
  2351.         add     edx, ebx
  2352.         call    window._.set_screen
  2353.         call    window._.set_top_wnd
  2354.         call    window._.redraw_top_wnd
  2355.  
  2356.         shl     esi, 5
  2357.         mov     [esi + window_data + WDATA.fl_redraw], 1
  2358.  
  2359.  
  2360.         mov     eax, 1
  2361.         jmp     .exit
  2362. .fail:
  2363.         xor     eax, eax
  2364. .exit:
  2365.         mov     [esp+32], eax
  2366.         ret
  2367.  
  2368. ;------------------------------------------------------------------------------
  2369. sysfn_getidletime:              ; 18.4 = GET IDLETIME
  2370.         mov     eax, [CURRENT_TASK+32+TASKDATA.cpu_usage]
  2371.         mov     [esp+32], eax
  2372.         ret
  2373. ;------------------------------------------------------------------------------
  2374. sysfn_getcpuclock:              ; 18.5 = GET TSC/SEC
  2375.         mov     eax, dword [cpu_freq]
  2376.         mov     [esp+32], eax
  2377.         ret
  2378. ;------------------------------------------------------------------------------
  2379. get_cpu_freq:
  2380.         mov     eax, dword [cpu_freq]
  2381.         mov     edx, dword [cpu_freq+4]
  2382.         ret
  2383. ;  SAVE ramdisk to /hd/1/menuet.img
  2384. ;!!!!!!!!!!!!!!!!!!!!!!!!
  2385.    include 'blkdev/rdsave.inc'
  2386. ;!!!!!!!!!!!!!!!!!!!!!!!!
  2387. ;------------------------------------------------------------------------------
  2388. align 4
  2389. sysfn_getactive:        ; 18.7 = get active window
  2390.         mov     eax, [TASK_COUNT]
  2391.         movzx   eax, word [WIN_POS + eax*2]
  2392.         mov     [esp+32], eax
  2393.         ret
  2394. ;------------------------------------------------------------------------------
  2395. sysfn_sound_flag:       ; 18.8 = get/set sound_flag
  2396. ;     cmp  ecx,1
  2397.         dec     ecx
  2398.         jnz     nogetsoundflag
  2399.         movzx   eax, byte [sound_flag]; get sound_flag
  2400.         mov     [esp+32], eax
  2401.         ret
  2402.  nogetsoundflag:
  2403. ;     cmp  ecx,2
  2404.         dec     ecx
  2405.         jnz     nosoundflag
  2406.         xor     byte [sound_flag], 1
  2407.  nosoundflag:
  2408.         ret
  2409. ;------------------------------------------------------------------------------
  2410. sysfn_minimize:         ; 18.10 = minimize window
  2411.         mov     [window_minimize], 1
  2412.         call    wakeup_osloop
  2413.         ret
  2414. ;------------------------------------------------------------------------------
  2415. align 4
  2416. sysfn_getdiskinfo:      ; 18.11 = get disk info table
  2417.         dec     ecx
  2418.         jnz     .exit
  2419. .small_table:
  2420.         mov     edi, edx
  2421.         mov     esi, DRIVE_DATA
  2422.         mov     ecx, DRIVE_DATA_SIZE ;10
  2423.         cld
  2424.         rep movsb
  2425. .exit:
  2426.         ret
  2427. ;------------------------------------------------------------------------------
  2428. sysfn_lastkey:          ; 18.12 = return 0 (backward compatibility)
  2429.         and     dword [esp+32], 0
  2430.         ret
  2431. ;------------------------------------------------------------------------------
  2432. sysfn_getversion:       ; 18.13 = get kernel ID and version
  2433.         mov     edi, ecx
  2434.         mov     esi, version_inf
  2435.         mov     ecx, version_end-version_inf
  2436.         rep movsb
  2437.         ret
  2438. ;------------------------------------------------------------------------------
  2439. sysfn_waitretrace:     ; 18.14 = sys wait retrace
  2440.      ;wait retrace functions
  2441.  sys_wait_retrace:
  2442.         mov     edx, 0x3da
  2443.  WaitRetrace_loop:
  2444.         in      al, dx
  2445.         test    al, 1000b
  2446.         jz      WaitRetrace_loop
  2447.         and     [esp+32], dword 0
  2448.         ret
  2449. ;------------------------------------------------------------------------------
  2450. align 4
  2451. sysfn_centermouse:      ; 18.15 = mouse centered
  2452.         mov     eax, [_display.width]
  2453.         shr     eax, 1
  2454.         mov     [MOUSE_X], ax
  2455.         mov     eax, [_display.height]
  2456.         shr     eax, 1
  2457.         mov     [MOUSE_Y], ax
  2458.         call    wakeup_osloop
  2459.         xor     eax, eax
  2460.         and     [esp+32], eax
  2461.         ret
  2462. ;------------------------------------------------------------------------------
  2463. sysfn_mouse_acceleration:       ; 18.19 = set/get mouse features
  2464.         cmp     ecx, 8
  2465.         jnc     @f
  2466.         jmp     dword [.table+ecx*4]
  2467. .get_mouse_acceleration:
  2468.         xor     eax, eax
  2469.         mov     ax, [mouse_speed_factor]
  2470.         mov     [esp+32], eax
  2471.         ret
  2472. .set_mouse_acceleration:
  2473.         mov     [mouse_speed_factor], dx
  2474.         ret
  2475. .get_mouse_delay:
  2476.         xor     eax, eax
  2477.         mov     al, [mouse_delay]
  2478.         mov     [esp+32], eax
  2479.         ret
  2480. .set_mouse_delay:
  2481.         mov     [mouse_delay], dl
  2482. @@:
  2483.         ret
  2484. .set_pointer_position:
  2485.         cmp     dx, word[_display.height]
  2486.         jae     @b
  2487.         rol     edx, 16
  2488.         cmp     dx, word[_display.width]
  2489.         jae     @b
  2490.         mov     [MOUSE_X], edx
  2491.         mov     [mouse_active], 1
  2492.         jmp     wakeup_osloop
  2493. .set_mouse_button:
  2494.         mov     [BTN_DOWN], edx
  2495.         mov     [mouse_active], 1
  2496.         jmp     wakeup_osloop
  2497. .get_doubleclick_delay:
  2498.         xor     eax, eax
  2499.         mov     al, [mouse_doubleclick_delay]
  2500.         mov     [esp+32], eax
  2501.         ret
  2502. .set_doubleclick_delay:
  2503.         mov     [mouse_doubleclick_delay], dl
  2504.         ret
  2505. align 4
  2506. .table:
  2507. dd      .get_mouse_acceleration
  2508. dd      .set_mouse_acceleration
  2509. dd      .get_mouse_delay
  2510. dd      .set_mouse_delay
  2511. dd      .set_pointer_position
  2512. dd      .set_mouse_button
  2513. dd      .get_doubleclick_delay
  2514. dd      .set_doubleclick_delay
  2515. ;------------------------------------------------------------------------------
  2516. sysfn_getfreemem:
  2517.         mov     eax, [pg_data.pages_free]
  2518.         shl     eax, 2
  2519.         mov     [esp+32], eax
  2520.         ret
  2521. ;------------------------------------------------------------------------------
  2522. sysfn_getallmem:
  2523.         mov     eax, [MEM_AMOUNT]
  2524.         shr     eax, 10
  2525.         mov     [esp+32], eax
  2526.         ret
  2527. ;------------------------------------------------------------------------------
  2528. sysfn_pid_to_slot:
  2529.         mov     eax, ecx
  2530.         call    pid_to_slot
  2531.         mov     [esp+32], eax
  2532.         ret
  2533. ;------------------------------------------------------------------------------
  2534. sysfn_min_rest_window:
  2535.         pushad
  2536.         mov     eax, edx ; ebx - operating
  2537.         shr     ecx, 1
  2538.         jnc     @f
  2539.         call    pid_to_slot
  2540. @@:
  2541.         or      eax, eax ; eax - number of slot
  2542.         jz      .error
  2543.         cmp     eax, 255    ; varify maximal slot number
  2544.         ja      .error
  2545.         movzx   eax, word [WIN_STACK + eax*2]
  2546.         shr     ecx, 1
  2547.         jc      .restore
  2548.  ; .minimize:
  2549.         call    minimize_window
  2550.         jmp     .exit
  2551. .restore:
  2552.         call    restore_minimized_window
  2553. .exit:
  2554.         popad
  2555.         xor     eax, eax
  2556.         mov     [esp+32], eax
  2557.         ret
  2558. .error:
  2559.         popad
  2560.         xor     eax, eax
  2561.         dec     eax
  2562.         mov     [esp+32], eax
  2563.         ret
  2564. ;------------------------------------------------------------------------------
  2565. sysfn_min_windows:
  2566.         call    minimize_all_window
  2567.         mov     [esp+32], eax
  2568.         call    change_task
  2569.         ret
  2570. ;------------------------------------------------------------------------------
  2571. sysfn_set_screen_sizes:
  2572.         cmp     [SCR_MODE], word 0x13
  2573.         jbe     .exit
  2574.  
  2575.         cmp     [_display.select_cursor], select_cursor
  2576.         jne     .exit
  2577.  
  2578.         cmp     ecx, [display_width_standard]
  2579.         ja      .exit
  2580.  
  2581.         cmp     edx, [display_height_standard]
  2582.         ja      .exit
  2583.  
  2584.         pushfd
  2585.         cli
  2586.         mov     eax, ecx
  2587.         mov     ecx, [_display.lfb_pitch]
  2588.         mov     [_display.width], eax
  2589.         dec     eax
  2590.         mov     [_display.height], edx
  2591.         dec     edx
  2592. ; eax - new Screen_Max_X
  2593. ; edx - new Screen_Max_Y
  2594.         mov     [do_not_touch_winmap], 1
  2595.         call    set_screen
  2596.         mov     [do_not_touch_winmap], 0
  2597.         popfd
  2598.         call    change_task
  2599. .exit:
  2600.         ret
  2601. ;------------------------------------------------------------------------------
  2602. uglobal
  2603. screen_workarea RECT
  2604. display_width_standard dd 0
  2605. display_height_standard dd 0
  2606. do_not_touch_winmap db 0
  2607. window_minimize db 0
  2608. sound_flag      db 0
  2609.  
  2610. endg
  2611.  
  2612. UID_NONE=0
  2613. UID_MENUETOS=1   ;official
  2614. UID_KOLIBRI=2    ;russian
  2615.  
  2616. iglobal
  2617. version_inf:
  2618.         db 0,7,7,0  ; version 0.7.7.0
  2619.         db 0
  2620. .rev    dd __REV__
  2621. version_end:
  2622. endg
  2623. ;------------------------------------------------------------------------------
  2624. align 4
  2625. sys_cachetodiskette:
  2626.         cmp     ebx, 1
  2627.         jb      .no_floppy_save
  2628.         cmp     ebx, 2
  2629.         ja      .no_floppy_save
  2630.         call    save_image
  2631.         mov     [esp + 32], eax
  2632.         ret
  2633. .no_floppy_save:
  2634.         mov     [esp + 32], dword 1
  2635.         ret
  2636. ;------------------------------------------------------------------------------
  2637. uglobal
  2638. ;  bgrchanged  dd  0x0
  2639. align 4
  2640. bgrlockpid dd 0
  2641. bgrlock db 0
  2642. endg
  2643. ;------------------------------------------------------------------------------
  2644. align 4
  2645. sys_background:
  2646.         cmp     ebx, 1                     ; BACKGROUND SIZE
  2647.         jnz     nosb1
  2648.         test    ecx, ecx
  2649.         jz      sbgrr
  2650.  
  2651.         test    edx, edx
  2652.         jz      sbgrr
  2653. ;--------------------------------------
  2654. align 4
  2655. @@:
  2656. ;;Maxis use atomic bts for mutexes  4.4.2009
  2657.         bts     dword [bgrlock], 0
  2658.         jnc     @f
  2659.         call    change_task
  2660.         jmp     @b
  2661. ;--------------------------------------
  2662. align 4
  2663. @@:
  2664.         mov     [BgrDataWidth], ecx
  2665.         mov     [BgrDataHeight], edx
  2666. ;    mov   [bgrchanged],1
  2667.  
  2668.         pushad
  2669. ; return memory for old background
  2670.         mov     eax, [img_background]
  2671.         cmp     eax, static_background_data
  2672.         jz      @f
  2673.         stdcall kernel_free, eax
  2674. ;--------------------------------------
  2675. align 4
  2676. @@:
  2677. ; calculate RAW size
  2678.         xor     eax, eax
  2679.         inc     eax
  2680.         cmp     [BgrDataWidth], eax
  2681.         jae     @f
  2682.         mov     [BgrDataWidth], eax
  2683. ;--------------------------------------
  2684. align 4
  2685. @@:
  2686.         cmp     [BgrDataHeight], eax
  2687.         jae     @f
  2688.         mov     [BgrDataHeight], eax
  2689. ;--------------------------------------
  2690. align 4
  2691. @@:
  2692.         mov     eax, [BgrDataWidth]
  2693.         imul    eax, [BgrDataHeight]
  2694.         lea     eax, [eax*3]
  2695. ; it is reserved with aligned to the boundary of 4 KB pages,
  2696. ; otherwise there may be exceptions a page fault for vesa20_drawbackground_tiled
  2697. ; because the 32 bit read is used for  high performance: "mov eax,[esi]"
  2698.         shr     eax, 12
  2699.         inc     eax
  2700.         shl     eax, 12
  2701.         mov     [mem_BACKGROUND], eax
  2702. ; get memory for new background
  2703.         stdcall kernel_alloc, eax
  2704.         test    eax, eax
  2705.         jz      .memfailed
  2706.         mov     [img_background], eax
  2707.         jmp     .exit
  2708. ;--------------------------------------
  2709. align 4
  2710. .memfailed:
  2711. ; revert to static monotone data
  2712.         mov     [img_background], static_background_data
  2713.         xor     eax, eax
  2714.         inc     eax
  2715.         mov     [BgrDataWidth], eax
  2716.         mov     [BgrDataHeight], eax
  2717.         mov     [mem_BACKGROUND], 4
  2718. ;--------------------------------------
  2719. align 4
  2720. .exit:
  2721.         popad
  2722.         mov     [bgrlock], 0
  2723. ;--------------------------------------
  2724. align 4
  2725. sbgrr:
  2726.         ret
  2727. ;------------------------------------------------------------------------------
  2728. align 4
  2729. nosb1:
  2730.         cmp     ebx, 2                     ; SET PIXEL
  2731.         jnz     nosb2
  2732.  
  2733.         mov     eax, [img_background]
  2734.         test    ecx, ecx
  2735.         jz      @f
  2736.         cmp     eax, static_background_data
  2737.         jz      .ret
  2738. ;--------------------------------------
  2739. align 4
  2740. @@:
  2741.         mov     ebx, [mem_BACKGROUND]
  2742.         add     ebx, 4095
  2743.         and     ebx, -4096
  2744.         sub     ebx, 4
  2745.         cmp     ecx, ebx
  2746.         ja      .ret
  2747.  
  2748.         mov     ebx, [eax+ecx]
  2749.         and     ebx, 0xFF000000;255*256*256*256
  2750.         and     edx, 0x00FFFFFF;255*256*256+255*256+255
  2751.         add     edx, ebx
  2752.         mov     [eax+ecx], edx
  2753. ;--------------------------------------
  2754. align 4
  2755. .ret:
  2756.         ret
  2757. ;------------------------------------------------------------------------------
  2758. align 4
  2759. nosb2:
  2760.         cmp     ebx, 3                     ; DRAW BACKGROUND
  2761.         jnz     nosb3
  2762. ;--------------------------------------
  2763. align 4
  2764. draw_background_temp:
  2765.         mov     [background_defined], 1
  2766.         call    force_redraw_background
  2767. ;--------------------------------------
  2768. align 4
  2769. nosb31:
  2770.         ret
  2771. ;------------------------------------------------------------------------------
  2772. align 4
  2773. nosb3:
  2774.         cmp     ebx, 4                     ; TILED / STRETCHED
  2775.         jnz     nosb4
  2776.         cmp     ecx, [BgrDrawMode]
  2777.         je      nosb41
  2778.         mov     [BgrDrawMode], ecx
  2779. ;--------------------------------------
  2780. align 4
  2781. nosb41:
  2782.         ret
  2783. ;------------------------------------------------------------------------------
  2784. align 4
  2785. nosb4:
  2786.         cmp     ebx, 5                     ; BLOCK MOVE TO BGR
  2787.         jnz     nosb5
  2788.         cmp     [img_background], static_background_data
  2789.         jnz     @f
  2790.         test    edx, edx
  2791.         jnz     .fin
  2792.         cmp     esi, 4
  2793.         ja      .fin
  2794. ;--------------------------------------
  2795. align 4
  2796. @@:
  2797.   ; bughere
  2798.         mov     eax, ecx
  2799.         mov     ebx, edx
  2800.         add     ebx, [img_background];IMG_BACKGROUND
  2801.         mov     ecx, esi
  2802.         call    memmove
  2803. ;--------------------------------------
  2804. align 4
  2805. .fin:
  2806.         ret
  2807. ;------------------------------------------------------------------------------
  2808. align 4
  2809. nosb5:
  2810.         cmp     ebx, 6
  2811.         jnz     nosb6
  2812. ;--------------------------------------
  2813. align 4
  2814. ;;Maxis use atomic bts for mutex 4.4.2009
  2815. @@:
  2816.         bts     dword [bgrlock], 0
  2817.         jnc     @f
  2818.         call    change_task
  2819.         jmp     @b
  2820. ;--------------------------------------
  2821. align 4
  2822. @@:
  2823.         mov     eax, [CURRENT_TASK]
  2824.         mov     [bgrlockpid], eax
  2825.         cmp     [img_background], static_background_data
  2826.         jz      .nomem
  2827.         stdcall user_alloc, [mem_BACKGROUND]
  2828.         mov     [esp+32], eax
  2829.         test    eax, eax
  2830.         jz      .nomem
  2831.         mov     ebx, eax
  2832.         shr     ebx, 12
  2833.         or      dword [page_tabs+(ebx-1)*8], DONT_FREE_BLOCK
  2834.         mov     esi, [img_background]
  2835.         shr     esi, 12
  2836.         mov     ecx, [mem_BACKGROUND]
  2837.         add     ecx, 0xFFF
  2838.         shr     ecx, 12
  2839. ;--------------------------------------
  2840. align 4
  2841. .z:
  2842.         mov     eax, [page_tabs+ebx*8]
  2843.         test    al, 1
  2844.         jz      @f
  2845.         call    free_page
  2846. ;--------------------------------------
  2847. align 4
  2848. @@:
  2849.         mov     eax, [page_tabs+esi*8]
  2850.         or      al, PG_UWR
  2851.         mov     [page_tabs+ebx*8], eax
  2852.         mov     eax, ebx
  2853.         shl     eax, 12
  2854.         invlpg  [eax]
  2855.         inc     ebx
  2856.         inc     esi
  2857.         loop    .z
  2858.         ret
  2859. ;--------------------------------------
  2860. align 4
  2861. .nomem:
  2862.         and     [bgrlockpid], 0
  2863.         mov     [bgrlock], 0
  2864. ;------------------------------------------------------------------------------
  2865. align 4
  2866. nosb6:
  2867.         cmp     ebx, 7
  2868.         jnz     nosb7
  2869.         cmp     [bgrlock], 0
  2870.         jz      .err
  2871.         mov     eax, [CURRENT_TASK]
  2872.         cmp     [bgrlockpid], eax
  2873.         jnz     .err
  2874.         mov     eax, ecx
  2875.         mov     ebx, ecx
  2876.         shr     eax, 12
  2877.         mov     ecx, [page_tabs+(eax-1)*8]
  2878.         test    cl, USED_BLOCK+DONT_FREE_BLOCK
  2879.         jz      .err
  2880.         jnp     .err
  2881.         push    eax
  2882.         shr     ecx, 12
  2883.         dec     ecx
  2884. ;--------------------------------------
  2885. align 4