Subversion Repositories Kolibri OS

Rev

Rev 6246 | Rev 6261 | Go to most recent revision | Blame | Compare with Previous | Last modification | View Log | Download | RSS feed

  1. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  2. ;;
  3. ;; Copyright (C) KolibriOS team 2004-2016. All rights reserved.
  4. ;; PROGRAMMING:
  5. ;; Ivan Poddubny
  6. ;; Marat Zakiyanov (Mario79)
  7. ;; VaStaNi
  8. ;; Trans
  9. ;; Mihail Semenyako (mike.dld)
  10. ;; Sergey Kuzmin (Wildwest)
  11. ;; Andrey Halyavin (halyavin)
  12. ;; Mihail Lisovin (Mihasik)
  13. ;; Andrey Ignatiev (andrew_programmer)
  14. ;; NoName
  15. ;; Evgeny Grechnikov (Diamond)
  16. ;; Iliya Mihailov (Ghost)
  17. ;; Sergey Semyonov (Serge)
  18. ;; Johnny_B
  19. ;; SPraid (simba)
  20. ;; Hidnplayr
  21. ;; Alexey Teplov (<Lrz>)
  22. ;; Rus
  23. ;; Nable
  24. ;; shurf
  25. ;; Alver
  26. ;; Maxis
  27. ;; Galkov
  28. ;; CleverMouse
  29. ;; tsdima
  30. ;; turbanoff
  31. ;; Asper
  32. ;; art_zh
  33. ;;
  34. ;; Data in this file was originally part of MenuetOS project which is
  35. ;; distributed under the terms of GNU GPL. It is modified and redistributed as
  36. ;; part of KolibriOS project under the terms of GNU GPL.
  37. ;;
  38. ;; Copyright (C) MenuetOS 2000-2004 Ville Mikael Turjanmaa
  39. ;; PROGRAMMING:
  40. ;;
  41. ;; Ville Mikael Turjanmaa, villemt@itu.jyu.fi
  42. ;; - main os coding/design
  43. ;; Jan-Michael Brummer, BUZZ2@gmx.de
  44. ;; Felix Kaiser, info@felix-kaiser.de
  45. ;; Paolo Minazzi, paolo.minazzi@inwind.it
  46. ;; quickcode@mail.ru
  47. ;; Alexey, kgaz@crosswinds.net
  48. ;; Juan M. Caravaca, bitrider@wanadoo.es
  49. ;; kristol@nic.fi
  50. ;; Mike Hibbett, mikeh@oceanfree.net
  51. ;; Lasse Kuusijarvi, kuusijar@lut.fi
  52. ;; Jarek Pelczar, jarekp3@wp.pl
  53. ;;
  54. ;; KolibriOS is distributed in the hope that it will be useful, but WITHOUT ANY
  55. ;; WARRANTY. No author or distributor accepts responsibility to anyone for the
  56. ;; consequences of using it or for whether it serves any particular purpose or
  57. ;; works at all, unless he says so in writing. Refer to the GNU General Public
  58. ;; License (the "GPL") for full details.
  59. ;
  60. ;; Everyone is granted permission to copy, modify and redistribute KolibriOS,
  61. ;; but only under the conditions described in the GPL. A copy of this license
  62. ;; is supposed to have been given to you along with KolibriOS so you can know
  63. ;; your rights and responsibilities. It should be in a file named COPYING.
  64. ;; Among other things, the copyright notice and this notice must be preserved
  65. ;; on all copies.
  66. ;;
  67. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  68.  
  69. format binary as "mnt"
  70.  
  71. include 'macros.inc'
  72. include 'struct.inc'
  73.  
  74. $Revision: 6252 $
  75.  
  76.  
  77. USE_COM_IRQ     equ 1      ; make irq 3 and irq 4 available for PCI devices
  78. VESA_1_2_VIDEO equ 0      ; enable vesa 1.2 bank switch functions
  79.  
  80. ; Enabling the next line will enable serial output console
  81. ;debug_com_base  equ 0x3f8  ; 0x3f8 is com1, 0x2f8 is com2, 0x3e8 is com3, 0x2e8 is com4, no irq's are used
  82.  
  83. include "proc32.inc"
  84. include "kglobals.inc"
  85. include "lang.inc"
  86. include "encoding.inc"
  87.  
  88. include "const.inc"
  89.  
  90. iglobal
  91. ; The following variable, if equal to 1, duplicates debug output to the screen.
  92. debug_direct_print db 0
  93. ; Start the first app (LAUNCHER) after kernel is loaded? (1=yes, 2 or 0=no)
  94. launcher_start db 1
  95. endg
  96.  
  97. max_processes   equ   255
  98. tss_step         equ   (128+8192) ; tss & i/o - 65535 ports, * 256=557056*4
  99.  
  100. os_stack       equ  (os_data_l-gdts)    ; GDTs
  101. os_code       equ  (os_code_l-gdts)
  102. graph_data     equ  (3+graph_data_l-gdts)
  103. tss0           equ  (tss0_l-gdts)
  104. app_code       equ  (3+app_code_l-gdts)
  105. app_data       equ  (3+app_data_l-gdts)
  106. app_tls       equ  (3+tls_data_l-gdts)
  107. pci_code_sel   equ  (pci_code_32-gdts)
  108. pci_data_sel   equ  (pci_data_32-gdts)
  109.  
  110.  
  111. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  112. ;;
  113. ;;   Included files:
  114. ;;
  115. ;;   Kernel16.inc
  116. ;;    - Booteng.inc   English text for bootup
  117. ;;    - Bootcode.inc  Hardware setup
  118. ;;    - Pci16.inc     PCI functions
  119. ;;
  120. ;;   Kernel32.inc
  121. ;;    - Sys32.inc     Process management
  122. ;;    - Shutdown.inc  Shutdown and restart
  123. ;;    - Fat32.inc     Read / write hd
  124. ;;    - Vesa12.inc    Vesa 1.2 driver
  125. ;;    - Vesa20.inc    Vesa 2.0 driver
  126. ;;    - Vga.inc       VGA driver
  127. ;;    - Stack.inc     Network interface
  128. ;;    - Mouse.inc     Mouse pointer
  129. ;;    - Scincode.inc  Window skinning
  130. ;;    - Pci32.inc     PCI functions
  131. ;;
  132. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  133.  
  134.  
  135. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  136. ;;                                                                      ;;
  137. ;;                  16 BIT ENTRY FROM BOOTSECTOR                        ;;
  138. ;;                                                                      ;;
  139. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  140.  
  141. use16
  142.                   org   0x0
  143.         jmp     start_of_code
  144.  
  145. if lang eq sp
  146. include "kernelsp.inc"  ; spanish kernel messages
  147. else if lang eq et
  148. version db    'Kolibri OS  versioon 0.7.7.0+    ',13,10,13,10,0
  149. else
  150. version db    'Kolibri OS  version 0.7.7.0+     ',13,10,13,10,0
  151. end if
  152.  
  153. include "boot/bootstr.inc"     ; language-independent boot messages
  154. include "boot/preboot.inc"
  155.  
  156. if lang eq ge
  157. include "boot/bootge.inc"     ; german system boot messages
  158. else if lang eq sp
  159. include "boot/bootsp.inc"     ; spanish system boot messages
  160. else if lang eq ru
  161. include "boot/bootru.inc"      ; russian system boot messages
  162. include "boot/ru.inc"          ; Russian font
  163. else if lang eq et
  164. include "boot/bootet.inc"      ; estonian system boot messages
  165. include "boot/et.inc"          ; Estonian font
  166. else
  167. include "boot/booten.inc"      ; english system boot messages
  168. end if
  169.  
  170. include "boot/bootcode.inc"    ; 16 bit system boot code
  171. include "bus/pci/pci16.inc"
  172. include "detect/biosdisk.inc"
  173.  
  174. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  175. ;;                                                                      ;;
  176. ;;                  SWITCH TO 32 BIT PROTECTED MODE                     ;;
  177. ;;                                                                      ;;
  178. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  179.  
  180.  
  181. ; CR0 Flags - Protected mode and Paging
  182.  
  183.         mov     ecx, CR0_PE
  184.  
  185. ; Enabling 32 bit protected mode
  186.  
  187.         sidt    [cs:old_ints_h]
  188.  
  189.         cli                             ; disable all irqs
  190.         cld
  191.         mov     al, 255                 ; mask all irqs
  192.         out     0xa1, al
  193.         out     0x21, al
  194.    l.5:
  195.         in      al, 0x64                ; Enable A20
  196.         test    al, 2
  197.         jnz     l.5
  198.         mov     al, 0xD1
  199.         out     0x64, al
  200.    l.6:
  201.         in      al, 0x64
  202.         test    al, 2
  203.         jnz     l.6
  204.         mov     al, 0xDF
  205.         out     0x60, al
  206.    l.7:
  207.         in      al, 0x64
  208.         test    al, 2
  209.         jnz     l.7
  210.         mov     al, 0xFF
  211.         out     0x64, al
  212.  
  213.         lgdt    [cs:tmp_gdt]            ; Load GDT
  214.         mov     eax, cr0                ; protected mode
  215.         or      eax, ecx
  216.         and     eax, 10011111b *65536*256 + 0xffffff ; caching enabled
  217.         mov     cr0, eax
  218.         jmp     pword os_code:B32       ; jmp to enable 32 bit mode
  219.  
  220. align 8
  221. tmp_gdt:
  222.  
  223.         dw     23
  224.         dd     tmp_gdt+0x10000
  225.         dw     0
  226.  
  227.         dw     0xffff
  228.         dw     0x0000
  229.         db     0x00
  230.         dw     11011111b *256 +10011010b
  231.         db     0x00
  232.  
  233.         dw     0xffff
  234.         dw     0x0000
  235.         db     0x00
  236.         dw     11011111b *256 +10010010b
  237.         db     0x00
  238.  
  239. include "data16.inc"
  240.  
  241. if ~ lang eq sp
  242. diff16 "end of bootcode",0,$+0x10000
  243. end if
  244.  
  245. use32
  246. org $+0x10000
  247.  
  248. align 4
  249. B32:
  250.         mov     ax, os_stack       ; Selector for os
  251.         mov     ds, ax
  252.         mov     es, ax
  253.         mov     fs, ax
  254.         mov     gs, ax
  255.         mov     ss, ax
  256.         mov     esp, TMP_STACK_TOP       ; Set stack
  257.  
  258. ; CLEAR 0x280000 - HEAP_BASE
  259.  
  260.         xor     eax, eax
  261.         mov     edi, CLEAN_ZONE
  262.         mov     ecx, (HEAP_BASE-OS_BASE-CLEAN_ZONE) / 4
  263.         cld
  264.         rep stosd
  265.  
  266. ; CLEAR KERNEL UNDEFINED GLOBALS
  267.         mov     edi, endofcode-OS_BASE
  268.         mov     ecx, 0x90000
  269.         sub     ecx, edi
  270.         shr     ecx, 2
  271.         rep stosd
  272.  
  273. ; SAVE & CLEAR 0-0xffff
  274.  
  275.         mov     edi, 0x1000
  276.         mov     ecx, 0x8000 / 4
  277.         rep stosd
  278.         mov     edi, 0xa000
  279.         mov     ecx, 0x6000 / 4
  280.         rep stosd
  281.  
  282.         call    test_cpu
  283.         bts     [cpu_caps-OS_BASE], CAPS_TSC    ;force use rdtsc
  284.  
  285.         call    check_acpi
  286.         call    init_hpet
  287.         call    init_BIOS32
  288. ; MEMORY MODEL
  289.         call    mem_test
  290.         call    init_mem
  291.         call    init_page_map
  292.  
  293. ; ENABLE PAGING
  294.  
  295.         mov     eax, sys_proc-OS_BASE+PROC.pdt_0
  296.         mov     cr3, eax
  297.  
  298.         mov     eax, cr0
  299.         or      eax, CR0_PG+CR0_WP
  300.         mov     cr0, eax
  301.  
  302.         lgdt    [gdts]
  303.         jmp     pword os_code:high_code
  304.  
  305. align 4
  306. bios32_entry    dd ?
  307. tmp_page_tabs   dd ?
  308. use16
  309. ap_init16:
  310.         cli
  311.         lgdt    [cs:gdts_ap-ap_init16]
  312.         mov     eax, [cs:cr3_ap-ap_init16]
  313.         mov     cr3, eax
  314.         mov     eax, [cs:cr4_ap-ap_init16]
  315.         mov     cr4, eax
  316.         mov     eax, CR0_PE+CR0_PG+CR0_WP
  317.         mov     cr0, eax
  318.         jmp     pword os_code:ap_init_high
  319. align 16
  320. gdts_ap:
  321.         dw     gdte-gdts-1
  322.         dd     gdts
  323.         dw     0
  324. cr3_ap  dd     ?
  325. cr4_ap  dd     ?
  326. ap_init16_size = $ - ap_init16
  327. use32
  328.  
  329. __DEBUG__ fix 1
  330. __DEBUG_LEVEL__ fix 1
  331. include 'init.inc'
  332.  
  333. org OS_BASE+$
  334.  
  335. include 'fdo.inc'
  336.  
  337. align 4
  338. high_code:
  339.         mov     ax, os_stack
  340.         mov     bx, app_data
  341.         mov     cx, app_tls
  342.         mov     ss, ax
  343.         add     esp, OS_BASE
  344.  
  345.         mov     ds, bx
  346.         mov     es, bx
  347.         mov     fs, cx
  348.         mov     gs, bx
  349.  
  350.         xor     eax, eax
  351.         mov     ebx, 0xFFFFF000+PG_SHARED+PG_NOCACHE+PG_UWR
  352.         bt      [cpu_caps], CAPS_PAT
  353.         setc    al
  354.         shl     eax, 7
  355.         or      ebx, eax
  356.  
  357.         mov     eax, PG_GLOBAL
  358.         bt      [cpu_caps], CAPS_PGE
  359.         jnc     @F
  360.  
  361.         or      [sys_proc+PROC.pdt_0+(OS_BASE shr 20)], eax
  362.         or      ebx, eax
  363.  
  364.         mov     eax, cr4
  365.         or      eax, CR4_PGE
  366.         mov     cr4, eax
  367. @@:
  368.         mov     [pte_valid_mask], ebx
  369.  
  370.         xor     eax, eax
  371.         mov     dword [sys_proc+PROC.pdt_0], eax
  372.         mov     dword [sys_proc+PROC.pdt_0+4], eax
  373.  
  374.         mov     eax, cr3
  375.         mov     cr3, eax          ; flush TLB
  376.  
  377.         mov     ecx, pg_data.mutex
  378.         call    mutex_init
  379.  
  380.         mov     ecx, disk_list_mutex
  381.         call    mutex_init
  382.  
  383.         mov     ecx, keyboard_list_mutex
  384.         call    mutex_init
  385.  
  386.         mov     ecx, unpack_mutex
  387.         call    mutex_init
  388.  
  389.         mov     ecx, application_table_mutex
  390.         call    mutex_init
  391.  
  392.         mov     ecx, ide_mutex
  393.         call    mutex_init
  394.         mov     ecx, ide_channel1_mutex
  395.         call    mutex_init
  396.         mov     ecx, ide_channel2_mutex
  397.         call    mutex_init
  398.         mov     ecx, ide_channel3_mutex
  399.         call    mutex_init
  400.         mov     ecx, ide_channel4_mutex
  401.         call    mutex_init
  402.         mov     ecx, ide_channel5_mutex
  403.         call    mutex_init
  404.         mov     ecx, ide_channel6_mutex
  405.         call    mutex_init
  406. ;-----------------------------------------------------------------------------
  407. ; SAVE REAL MODE VARIABLES
  408. ;-----------------------------------------------------------------------------
  409. ; --------------- APM ---------------------
  410.  
  411. ; init selectors
  412.         mov     ebx, [BOOT_VARS+BOOT_APM_ENTRY]        ; offset of APM entry point
  413.         movzx   eax, word [BOOT_VARS+BOOT_APM_CODE_32] ; real-mode segment base address of
  414.                                                                                 ; protected-mode 32-bit code segment
  415.         movzx   ecx, word [BOOT_VARS+BOOT_APM_CODE_16]; real-mode segment base address of
  416.                                                                                 ; protected-mode 16-bit code segment
  417.         movzx   edx, word [BOOT_VARS+BOOT_APM_DATA_16]; real-mode segment base address of
  418.                                                                                 ; protected-mode 16-bit data segment
  419.  
  420.         shl     eax, 4
  421.         mov     [dword apm_code_32 + 2], ax
  422.         shr     eax, 16
  423.         mov     [dword apm_code_32 + 4], al
  424.  
  425.         shl     ecx, 4
  426.         mov     [dword apm_code_16 + 2], cx
  427.         shr     ecx, 16
  428.         mov     [dword apm_code_16 + 4], cl
  429.  
  430.         shl     edx, 4
  431.         mov     [dword apm_data_16 + 2], dx
  432.         shr     edx, 16
  433.         mov     [dword apm_data_16 + 4], dl
  434.  
  435.         mov     dword[apm_entry], ebx
  436.         mov     word [apm_entry + 4], apm_code_32 - gdts
  437.  
  438.         mov     eax, [BOOT_VARS + BOOT_APM_VERSION] ; version & flags
  439.         mov     [apm_vf], eax
  440. ; -----------------------------------------
  441.         mov     al, [BOOT_VARS+BOOT_DMA]            ; DMA access
  442.         mov     [allow_dma_access], al
  443.  
  444.         mov     al, [BOOT_VARS+BOOT_DEBUG_PRINT]    ; If nonzero, duplicates debug output to the screen
  445.         mov     [debug_direct_print], al
  446.  
  447.         mov     al, [BOOT_VARS+BOOT_LAUNCHER_START] ; Start the first app (LAUNCHER) after kernel is loaded?
  448.         mov     [launcher_start], al
  449.  
  450.         mov     esi, BOOT_VARS+0x9080
  451.         movzx   ecx, byte [esi-1]
  452.         mov     [NumBiosDisks], ecx
  453.         mov     edi, BiosDisksData
  454.         rep movsd
  455.  
  456. ; -------- Fast System Call init ----------
  457. ; Intel SYSENTER/SYSEXIT (AMD CPU support it too)
  458.         bt      [cpu_caps], CAPS_SEP
  459.         jnc     .SEnP  ; SysEnter not Present
  460.         xor     edx, edx
  461.         mov     ecx, MSR_SYSENTER_CS
  462.         mov     eax, os_code
  463.         wrmsr
  464.         mov     ecx, MSR_SYSENTER_ESP
  465. ;           mov eax, sysenter_stack ; Check it
  466.         xor     eax, eax
  467.         wrmsr
  468.         mov     ecx, MSR_SYSENTER_EIP
  469.         mov     eax, sysenter_entry
  470.         wrmsr
  471. .SEnP:
  472. ; AMD SYSCALL/SYSRET
  473.         cmp     byte[cpu_vendor], 'A'
  474.         jne     .noSYSCALL
  475.         mov     eax, 0x80000001
  476.         cpuid
  477.         test    edx, 0x800  ; bit_11 - SYSCALL/SYSRET support
  478.         jz      .noSYSCALL
  479.         mov     ecx, MSR_AMD_EFER
  480.         rdmsr
  481.         or      eax, 1 ; bit_0 - System Call Extension (SCE)
  482.         wrmsr
  483.  
  484.         ; !!!! It`s dirty hack, fix it !!!
  485.         ; Bits of EDX :
  486.         ; Bit 31–16 During the SYSRET instruction, this field is copied into the CS register
  487.         ;  and the contents of this field, plus 8, are copied into the SS register.
  488.         ; Bit 15–0 During the SYSCALL instruction, this field is copied into the CS register
  489.         ;  and the contents of this field, plus 8, are copied into the SS register.
  490.  
  491.         ; mov   edx, (os_code + 16) * 65536 + os_code
  492.         mov     edx, 0x1B0008
  493.  
  494.         mov     eax, syscall_entry
  495.         mov     ecx, MSR_AMD_STAR
  496.         wrmsr
  497. .noSYSCALL:
  498. ; -----------------------------------------
  499.         stdcall alloc_page
  500.         stdcall map_page, tss-0xF80, eax, PG_SWR
  501.         stdcall alloc_page
  502.         stdcall map_page, tss+0x80, eax, PG_SWR
  503.         stdcall alloc_page
  504.         stdcall map_page, tss+0x1080, eax, PG_SWR
  505.  
  506. ; LOAD IDT
  507.  
  508.         call    build_interrupt_table ;lidt is executed
  509.           ;lidt [idtreg]
  510.  
  511.         call    init_kernel_heap
  512.         stdcall kernel_alloc, (RING0_STACK_SIZE+512) * 2
  513.         mov     [os_stack_seg], eax
  514.  
  515.         lea     esp, [eax+RING0_STACK_SIZE]
  516.  
  517.         mov     [tss._ss0], os_stack
  518.         mov     [tss._esp0], esp
  519.         mov     [tss._esp], esp
  520.         mov     [tss._cs], os_code
  521.         mov     [tss._ss], os_stack
  522.         mov     [tss._ds], app_data
  523.         mov     [tss._es], app_data
  524.         mov     [tss._fs], app_data
  525.         mov     [tss._gs], app_data
  526.         mov     [tss._io], 128
  527. ;Add IO access table - bit array of permitted ports
  528.         mov     edi, tss._io_map_0
  529.         xor     eax, eax
  530.         not     eax
  531.         mov     ecx, 8192/4
  532.         rep stosd                           ; access to 4096*8=65536 ports
  533.  
  534.         mov     ax, tss0
  535.         ltr     ax
  536.  
  537.         mov     eax, sys_proc
  538.         list_init eax
  539.         add     eax, PROC.thr_list
  540.         list_init eax
  541.  
  542.         call    init_video
  543.         call    init_mtrr
  544.         mov     [LFBAddress], LFB_BASE
  545.         mov     ecx, bios_fb
  546.         call    set_framebuffer
  547.         call    init_fpu
  548.         call    init_malloc
  549.  
  550.         stdcall alloc_kernel_space, 0x50000         ; FIXME check size
  551.         mov     [default_io_map], eax
  552.  
  553.         add     eax, 0x2000
  554.         mov     [ipc_tmp], eax
  555.         mov     ebx, 0x1000
  556.  
  557.         add     eax, 0x40000
  558.         mov     [proc_mem_map], eax
  559.  
  560.         add     eax, 0x8000
  561.         mov     [proc_mem_pdir], eax
  562.  
  563.         add     eax, ebx
  564.         mov     [proc_mem_tab], eax
  565.  
  566.         add     eax, ebx
  567.         mov     [tmp_task_ptab], eax
  568.  
  569.         add     eax, ebx
  570.         mov     [ipc_pdir], eax
  571.  
  572.         add     eax, ebx
  573.         mov     [ipc_ptab], eax
  574.  
  575.         stdcall kernel_alloc, (unpack.LZMA_BASE_SIZE+(unpack.LZMA_LIT_SIZE shl \
  576.                 (unpack.lc+unpack.lp)))*4
  577.  
  578.         mov     [unpack.p], eax
  579.  
  580.         call    init_events
  581.         mov     eax, srv.fd-SRV.fd
  582.         mov     [srv.fd], eax
  583.         mov     [srv.bk], eax
  584.  
  585. ;Set base of graphic segment to linear address of LFB
  586.         mov     eax, [LFBAddress]         ; set for gs
  587.         mov     [graph_data_l+2], ax
  588.         shr     eax, 16
  589.         mov     [graph_data_l+4], al
  590.         mov     [graph_data_l+7], ah
  591.  
  592.         stdcall kernel_alloc, [_display.win_map_size]
  593.         mov     [_display.win_map], eax
  594.  
  595.         xor     eax, eax
  596.         inc     eax
  597.  
  598. ; set background
  599.  
  600.         mov     [BgrDrawMode], eax
  601.         mov     [BgrDataWidth], eax
  602.         mov     [BgrDataHeight], eax
  603.         mov     [mem_BACKGROUND], 4
  604.         mov     [img_background], static_background_data
  605.  
  606. ; set clipboard
  607.  
  608.         xor     eax, eax
  609.         mov     [clipboard_slots], eax
  610.         mov     [clipboard_write_lock], eax
  611.         stdcall kernel_alloc, 4096
  612.         test    eax, eax
  613.         jnz     @f
  614.  
  615.         dec     eax
  616. @@:
  617.         mov     [clipboard_main_list], eax
  618.  
  619.         mov     eax, [hpet_base]
  620.         test    eax, eax
  621.         jz      @F
  622.         mov     eax, [hpet_base]
  623.         stdcall map_io_mem, [hpet_base], 1024, PG_GLOBAL+PAT_UC+PG_SWR
  624.         mov     [hpet_base], eax
  625.         mov     eax, [eax]
  626.         DEBUGF  1, "K : HPET caps %x\n", eax
  627. @@:
  628. ; SET UP OS TASK
  629.  
  630.         mov     esi, boot_setostask
  631.         call    boot_log
  632.  
  633.         mov     edi, sys_proc+PROC.heap_lock
  634.         mov     ecx, (PROC.ht_free-PROC.heap_lock)/4
  635.  
  636.         xor     eax, eax
  637.         cld
  638.         rep stosd
  639.  
  640.         mov     [edi], dword (PROC.pdt_0 - PROC.htab)/4 - 3
  641.         mov     [edi+4], dword 3           ;reserve handles for stdin stdout and stderr
  642.         mov     ecx, (PROC.pdt_0 - PROC.htab)/4
  643.         add     edi, 8
  644.         inc     eax
  645. @@:
  646.         stosd
  647.         inc     eax
  648.         cmp     eax, ecx
  649.         jbe     @B
  650.  
  651.         mov     [sys_proc+PROC.pdt_0_phys], sys_proc-OS_BASE+PROC.pdt_0
  652.  
  653.         mov     eax, -1
  654.         mov     edi, thr_slot_map+4
  655.         mov     [edi-4], dword 0xFFFFFFF8
  656.         stosd
  657.         stosd
  658.         stosd
  659.         stosd
  660.         stosd
  661.         stosd
  662.         stosd
  663.  
  664.         mov     [current_process], sys_proc
  665.  
  666.         mov     edx, SLOT_BASE+256*1
  667.         mov     ebx, [os_stack_seg]
  668.         add     ebx, 0x2000
  669.         call    setup_os_slot
  670.         mov     dword [edx], 'IDLE'
  671.         sub     [edx+APPDATA.saved_esp], 4
  672.         mov     eax, [edx+APPDATA.saved_esp]
  673.         mov     dword [eax], idle_thread
  674.         mov     ecx, IDLE_PRIORITY
  675.         call    scheduler_add_thread
  676.  
  677.         mov     edx, SLOT_BASE+256*2
  678.         mov     ebx, [os_stack_seg]
  679.         call    setup_os_slot
  680.         mov     dword [edx], 'OS'
  681.         xor     ecx, ecx
  682.         call    scheduler_add_thread
  683.  
  684.         mov     dword [CURRENT_TASK], 2
  685.         mov     dword [TASK_COUNT], 2
  686.         mov     dword [current_slot], SLOT_BASE + 256*2
  687.         mov     dword [TASK_BASE], CURRENT_TASK + 32*2
  688.  
  689. ; Move other CPUs to deep sleep, if it is useful
  690. uglobal
  691. use_mwait_for_idle db 0
  692. endg
  693.         cmp     [cpu_vendor+8], 'ntel'
  694.         jnz     .no_wake_cpus
  695.         bt      [cpu_caps+4], CAPS_MONITOR-32
  696.         jnc     .no_wake_cpus
  697.         dbgstr 'using mwait for idle loop'
  698.         inc     [use_mwait_for_idle]
  699.         mov     ebx, [cpu_count]
  700.         cmp     ebx, 1
  701.         jbe     .no_wake_cpus
  702.         call    create_trampoline_pgmap
  703.         mov     [cr3_ap+OS_BASE], eax
  704.         mov     eax, cr4
  705.         mov     [cr4_ap+OS_BASE], eax
  706.         mov     esi, OS_BASE + ap_init16
  707.         mov     edi, OS_BASE + 8000h
  708.         mov     ecx, (ap_init16_size + 3) / 4
  709.         rep movsd
  710.         stdcall map_io_mem, [acpi_lapic_base], 0x1000, PG_GLOBAL+PG_NOCACHE+PG_SWR
  711.         mov     [LAPIC_BASE], eax
  712.         lea     edi, [eax+300h]
  713.         mov     esi, smpt+4
  714.         dec     ebx
  715. .wake_cpus_loop:
  716.         lodsd
  717.         push    esi
  718.         xor     esi, esi
  719.         inc     esi
  720.         shl     eax, 24
  721.         mov     [edi+10h], eax
  722. ; assert INIT IPI
  723.         mov     dword [edi], 0C500h
  724.         call    delay_ms
  725. @@:
  726.         test    dword [edi], 1000h
  727.         jnz     @b
  728. ; deassert INIT IPI
  729.         mov     dword [edi], 8500h
  730.         call    delay_ms
  731. @@:
  732.         test    dword [edi], 1000h
  733.         jnz     @b
  734. ; send STARTUP IPI
  735.         mov     dword [edi], 600h + (8000h shr 12)
  736.         call    delay_ms
  737. @@:
  738.         test    dword [edi], 1000h
  739.         jnz     @b
  740.         pop     esi
  741.         dec     ebx
  742.         jnz     .wake_cpus_loop
  743.         mov     eax, [cpu_count]
  744.         dec     eax
  745. @@:
  746.         cmp     [ap_initialized], eax
  747.         jnz     @b
  748.         mov     eax, [cr3_ap+OS_BASE]
  749.         call    free_page
  750. .no_wake_cpus:
  751.  
  752. ; REDIRECT ALL IRQ'S TO INT'S 0x20-0x2f
  753.         mov     esi, boot_initirq
  754.         call    boot_log
  755.         call    init_irqs
  756.  
  757.         mov     esi, boot_picinit
  758.         call    boot_log
  759.         call    PIC_init
  760.  
  761.         mov     esi, boot_v86machine
  762.         call    boot_log
  763. ; Initialize system V86 machine
  764.         call    init_sys_v86
  765.  
  766.         mov     esi, boot_inittimer
  767.         call    boot_log
  768. ; Initialize system timer (IRQ0)
  769.         call    PIT_init
  770.  
  771. ; Register ramdisk file system
  772.         cmp     [boot_dev+OS_BASE+0x10000], 1
  773.         je      @f
  774.  
  775.         call    register_ramdisk
  776. ;--------------------------------------
  777. @@:
  778.         mov     esi, boot_initapic
  779.         call    boot_log
  780. ; Try to Initialize APIC
  781.         call    APIC_init
  782.  
  783.         mov     esi, boot_enableirq
  784.         call    boot_log
  785. ; Enable timer IRQ (IRQ0) and co-processor IRQ (IRQ13)
  786. ; they are used: when partitions are scanned, hd_read relies on timer
  787.         call    unmask_timer
  788.         stdcall enable_irq, 2               ; @#$%! PIC
  789.         stdcall enable_irq, 13              ; co-processor
  790.  
  791. ; Setup serial output console (if enabled)
  792. if defined debug_com_base
  793.  
  794.         ; reserve port so nobody else will use it
  795.         xor     ebx, ebx
  796.         mov     ecx, debug_com_base
  797.         mov     edx, debug_com_base+7
  798.         call    r_f_port_area
  799.  
  800.         ; enable Divisor latch
  801.         mov     dx, debug_com_base+3
  802.         mov     al, 1 shl 7
  803.         out     dx, al
  804.  
  805.         ; Set speed to 115200 baud (max speed)
  806.         mov     dx, debug_com_base
  807.         mov     al, 0x01
  808.         out     dx, al
  809.  
  810.         mov     dx, debug_com_base+1
  811.         mov     al, 0x00
  812.         out     dx, al
  813.  
  814.         ; No parity, 8bits words, one stop bit, dlab bit back to 0
  815.         mov     dx, debug_com_base+3
  816.         mov     al, 3
  817.         out     dx, al
  818.  
  819.         ; disable interrupts
  820.         mov     dx, debug_com_base+1
  821.         mov     al, 0
  822.         out     dx, al
  823.  
  824.         ; clear +  enable fifo (64 bits)
  825.         mov     dx, debug_com_base+2
  826.         mov     al, 0x7 + 1 shl 5
  827.         out     dx, al
  828.  
  829. end if
  830.  
  831.  
  832. ;-----------------------------------------------------------------------------
  833. ; show SVN version of kernel on the message board
  834. ;-----------------------------------------------------------------------------
  835.         mov     eax, [version_inf.rev]
  836.         DEBUGF  1, "K : kernel SVN r%d\n", eax
  837. ;-----------------------------------------------------------------------------
  838. ; show CPU count on the message board
  839. ;-----------------------------------------------------------------------------
  840.         mov     eax, [cpu_count]
  841.         test    eax, eax
  842.         jnz     @F
  843.         mov     al, 1                             ; at least one CPU
  844. @@:
  845.         DEBUGF  1, "K : %d CPU detected\n", eax
  846. ;-----------------------------------------------------------------------------
  847. ; detect Floppy drives
  848. ;-----------------------------------------------------------------------------
  849.         mov     esi, boot_detectfloppy
  850.         call    boot_log
  851. include 'detect/dev_fd.inc'
  852. ;-----------------------------------------------------------------------------
  853. ; create pci-devices list
  854. ;-----------------------------------------------------------------------------
  855.         mov     [pci_access_enabled], 1
  856.         call    pci_enum
  857. ;-----------------------------------------------------------------------------
  858. ; initialisation IDE ATA code
  859. ;-----------------------------------------------------------------------------
  860. include 'detect/init_ata.inc'
  861. ;-----------------------------------------------------------------------------
  862. if 0
  863.         mov     ax, [OS_BASE+0x10000+bx_from_load]
  864.         cmp     ax, 'r1'; if using not ram disk, then load librares and parameters {SPraid.simba}
  865.         je      no_lib_load
  866.  
  867.         mov     esi, boot_loadlibs
  868.         call    boot_log
  869. ; LOADING LIBRARES
  870.         stdcall dll.Load, @IMPORT           ; loading librares for kernel (.obj files)
  871.         call    load_file_parse_table       ; prepare file parse table
  872.         call    set_kernel_conf             ; configure devices and gui
  873. no_lib_load:
  874. end if
  875.  
  876. ; Display APIC status
  877.         mov     esi, boot_APIC_found
  878.         cmp     [irq_mode], IRQ_APIC
  879.         je      @f
  880.         mov     esi, boot_APIC_nfound
  881. @@:
  882.         call    boot_log
  883.  
  884. ; PRINT AMOUNT OF MEMORY
  885.         mov     esi, boot_memdetect
  886.         call    boot_log
  887.  
  888.         movzx   ecx, word [boot_y]
  889.         if lang eq ru
  890.         or      ecx, (10+30*6) shl 16
  891.         else if lang eq sp
  892.         or      ecx, (10+33*6) shl 16
  893.         else
  894.         or      ecx, (10+29*6) shl 16
  895.         end if
  896.         sub     ecx, 10
  897.         mov     edx, 0xFFFFFF
  898.         mov     ebx, [MEM_AMOUNT]
  899.         shr     ebx, 20
  900.         xor     edi, edi
  901.         mov     eax, 0x00040000
  902.         inc     edi
  903.         call    display_number_force
  904.  
  905. ; BUILD SCHEDULER
  906.  
  907. ;        call    build_scheduler; sys32.inc
  908.  
  909. ;        mov     esi, boot_devices
  910. ;        call    boot_log
  911.  
  912. include "detect/vortex86.inc"                     ; Vortex86 SoC detection code
  913.  
  914.         stdcall load_pe_driver, szVidintel, 0
  915.  
  916.         call    usb_init
  917.  
  918. ; SET PRELIMINARY WINDOW STACK AND POSITIONS
  919.  
  920.         mov     esi, boot_windefs
  921.         call    boot_log
  922.         call    set_window_defaults
  923.  
  924. ; SET BACKGROUND DEFAULTS
  925.  
  926.         mov     esi, boot_bgr
  927.         call    boot_log
  928.         call    init_background
  929.         call    calculatebackground
  930.  
  931. ; RESERVE SYSTEM IRQ'S JA PORT'S
  932.  
  933.         mov     esi, boot_resirqports
  934.         call    boot_log
  935.         call    reserve_irqs_ports
  936.  
  937.         call    init_display
  938.         mov     eax, [def_cursor]
  939.         mov     [SLOT_BASE+APPDATA.cursor+256], eax
  940.         mov     [SLOT_BASE+APPDATA.cursor+256*2], eax
  941.  
  942. ; PRINT CPU FREQUENCY
  943.  
  944.         mov     esi, boot_cpufreq
  945.         call    boot_log
  946.  
  947.         cli
  948.         mov     ebx, [hpet_base]
  949.         test    ebx, ebx
  950.         jz      @F
  951.         mov     ebx, [ebx+0xF0]
  952.  
  953.         rdtsc
  954.         mov     ecx, 1000
  955.         sub     eax, [hpet_tsc_start]
  956.         sbb     edx, [hpet_tsc_start+4]
  957.         shld    edx, eax, 10
  958.         shl     eax, 10
  959.         mov     esi, eax
  960.         mov     eax, edx
  961.         mul     ecx
  962.         xchg    eax, esi
  963.         mul     ecx
  964.         adc     edx, esi
  965.         div     ebx
  966.         mul     ecx
  967.         div     [hpet_period]
  968.         mul     ecx
  969.         DEBUGF  1, "K : cpu frequency %u Hz\n", eax
  970.         jmp     .next
  971. @@:
  972.         rdtsc
  973.         mov     ecx, eax
  974.         mov     esi, 250            ; wait 1/4 a second
  975.         call    delay_ms
  976.         rdtsc
  977.         sti
  978.  
  979.         sub     eax, ecx
  980.         xor     edx, edx
  981.         shld    edx, eax, 2
  982.         shl     eax, 2
  983. .next:
  984.         mov     dword [cpu_freq], eax
  985.         mov     dword [cpu_freq+4], edx
  986.         mov     ebx, 1000000
  987.         div     ebx
  988.         mov     ebx, eax
  989.  
  990.         movzx   ecx, word [boot_y]
  991.         if lang eq ru
  992.         add     ecx, (10+19*6) shl 16 - 10
  993.         else if lang eq sp
  994.         add     ecx, (10+25*6) shl 16 - 10
  995.         else
  996.         add     ecx, (10+17*6) shl 16 - 10
  997.         end if
  998.  
  999.         mov     edx, 0xFFFFFF
  1000.         xor     edi, edi
  1001.         mov     eax, 0x00040000
  1002.         inc     edi
  1003.         call    display_number_force
  1004.  
  1005. ; SET VARIABLES
  1006.  
  1007.         call    set_variables
  1008.  
  1009. ; STACK AND FDC
  1010.  
  1011.         call    stack_init
  1012.         call    fdc_init
  1013.  
  1014. ; PALETTE FOR 320x200 and 640x480 16 col
  1015.  
  1016.         cmp     [SCR_MODE], word 0x12
  1017.         jne     no_pal_vga
  1018.         mov     esi, boot_pal_vga
  1019.         call    boot_log
  1020.         call    paletteVGA
  1021.       no_pal_vga:
  1022.  
  1023.         cmp     [SCR_MODE], word 0x13
  1024.         jne     no_pal_ega
  1025.         mov     esi, boot_pal_ega
  1026.         call    boot_log
  1027.         call    palette320x200
  1028.       no_pal_ega:
  1029.  
  1030. ; LOAD DEFAULT SKIN
  1031.  
  1032.         call    load_default_skin
  1033.  
  1034. ; Protect I/O permission map
  1035.  
  1036.         mov     esi, [default_io_map]
  1037.         stdcall map_page, esi, [SLOT_BASE+256+APPDATA.io_map], PG_READ
  1038.         add     esi, 0x1000
  1039.         stdcall map_page, esi, [SLOT_BASE+256+APPDATA.io_map+4], PG_READ
  1040.  
  1041.         stdcall map_page, tss._io_map_0, \
  1042.                 [SLOT_BASE+256+APPDATA.io_map], PG_READ
  1043.         stdcall map_page, tss._io_map_1, \
  1044.                 [SLOT_BASE+256+APPDATA.io_map+4], PG_READ
  1045.  
  1046. ; SET KEYBOARD PARAMETERS
  1047.         mov     al, 0xf6       ; reset keyboard, scan enabled
  1048.         call    kb_write_wait_ack
  1049.         test    ah, ah
  1050.         jnz     .no_keyboard
  1051.  
  1052. iglobal
  1053. align 4
  1054. ps2_keyboard_functions:
  1055.         dd      .end - $
  1056.         dd      0       ; no close
  1057.         dd      ps2_set_lights
  1058. .end:
  1059. endg
  1060.         stdcall register_keyboard, ps2_keyboard_functions, 0
  1061.        ; mov   al, 0xED       ; Keyboard LEDs - only for testing!
  1062.        ; call  kb_write_wait_ack
  1063.        ; mov   al, 111b
  1064.        ; call  kb_write_wait_ack
  1065.  
  1066.         mov     al, 0xF3     ; set repeat rate & delay
  1067.         call    kb_write_wait_ack
  1068.         mov     al, 0; 30 250 ;00100010b ; 24 500  ;00100100b  ; 20 500
  1069.         call    kb_write_wait_ack
  1070.      ;// mike.dld [
  1071.         call    set_lights
  1072.      ;// mike.dld ]
  1073.         stdcall attach_int_handler, 1, irq1, 0
  1074.         DEBUGF  1, "K : IRQ1 return code %x\n", eax
  1075. .no_keyboard:
  1076.  
  1077. ; Load PS/2 mouse driver
  1078.  
  1079.         stdcall load_pe_driver, szPS2MDriver, 0
  1080.  
  1081.         mov     esi, boot_setmouse
  1082.         call    boot_log
  1083.         call    setmouse
  1084.  
  1085. ; LOAD FIRST APPLICATION
  1086.         cmp     byte [launcher_start], 1        ; Check if starting LAUNCHER is selected on blue screen (1 = yes)
  1087.         jnz     first_app_found
  1088.  
  1089.         cli
  1090.         mov     ebp, firstapp
  1091.         call    fs_execute_from_sysdir
  1092.         test    eax, eax
  1093.         jns     first_app_found
  1094.  
  1095.         mov     esi, boot_failed
  1096.         call    boot_log
  1097.  
  1098.         mov     eax, 0xDEADBEEF      ; otherwise halt
  1099.         hlt
  1100.  
  1101. first_app_found:
  1102.  
  1103. ; START MULTITASKING
  1104.  
  1105. ; A 'All set - press ESC to start' messages if need
  1106. if preboot_blogesc
  1107.         mov     esi, boot_tasking
  1108.         call    boot_log
  1109. .bll1:
  1110.         in      al, 0x60        ; wait for ESC key press
  1111.         cmp     al, 129
  1112.         jne     .bll1
  1113. end if
  1114.  
  1115.         mov     [timer_ticks_enable], 1         ; for cd driver
  1116.  
  1117.         sti
  1118.  
  1119.         call    mtrr_validate
  1120.  
  1121.         jmp     osloop
  1122.  
  1123.  
  1124.         ; Fly :)
  1125.  
  1126. uglobal
  1127. align 4
  1128. ap_initialized  dd      0
  1129. endg
  1130.  
  1131. ap_init_high:
  1132.         mov     ax, os_stack
  1133.         mov     bx, app_data
  1134.         mov     cx, app_tls
  1135.         mov     ss, ax
  1136.         mov     ds, bx
  1137.         mov     es, bx
  1138.         mov     fs, cx
  1139.         mov     gs, bx
  1140.         xor     esp, esp
  1141.         mov     eax, sys_proc-OS_BASE+PROC.pdt_0
  1142.         mov     cr3, eax
  1143.         lock inc [ap_initialized]
  1144.         jmp     idle_loop
  1145.  
  1146.  
  1147. include 'unpacker.inc'
  1148.  
  1149. align 4
  1150. boot_log:
  1151.         pushad
  1152.  
  1153.         mov     ebx, 10*65536
  1154.         mov     bx, word [boot_y]
  1155.         add     [boot_y], dword 10
  1156.         mov     ecx, 0x80ffffff; ASCIIZ string with white color
  1157.         xor     edi, edi
  1158.         mov     edx, esi
  1159.         inc     edi
  1160.         call    dtext
  1161.  
  1162.         mov     [novesachecksum], 1000
  1163.         call    checkVga_N13
  1164.  
  1165.         popad
  1166.  
  1167.         ret
  1168.  
  1169. ; in: edx -> APPDATA for OS/IDLE slot
  1170. ; in: ebx = stack base
  1171. proc setup_os_slot
  1172.         xor     eax, eax
  1173.         mov     ecx, 256/4
  1174.         mov     edi, edx
  1175.         rep stosd
  1176.  
  1177.         mov     eax, tss+0x80
  1178.         call    get_pg_addr
  1179.         inc     eax
  1180.         mov     [edx+APPDATA.io_map], eax
  1181.         mov     eax, tss+0x1080
  1182.         call    get_pg_addr
  1183.         inc     eax
  1184.         mov     [edx+APPDATA.io_map+4], eax
  1185.  
  1186.         mov     dword [edx+APPDATA.pl0_stack], ebx
  1187.         lea     edi, [ebx+0x2000-512]
  1188.         mov     dword [edx+APPDATA.fpu_state], edi
  1189.         mov     dword [edx+APPDATA.saved_esp0], edi
  1190.         mov     dword [edx+APPDATA.saved_esp], edi
  1191.         mov     dword [edx+APPDATA.terminate_protection], 1 ; make unkillable
  1192.  
  1193.         mov     esi, fpu_data
  1194.         mov     ecx, 512/4
  1195.         cld
  1196.         rep movsd
  1197.  
  1198.         lea     eax, [edx+APP_OBJ_OFFSET]
  1199.         mov     dword [edx+APPDATA.fd_obj], eax
  1200.         mov     dword [edx+APPDATA.bk_obj], eax
  1201.  
  1202.         mov     dword [edx+APPDATA.cur_dir], sysdir_path
  1203.  
  1204.         mov     [edx + APPDATA.process], sys_proc
  1205.  
  1206.         lea     ebx, [edx+APPDATA.list]
  1207.         lea     ecx, [sys_proc+PROC.thr_list]
  1208.         list_add_tail ebx, ecx
  1209.  
  1210.         mov     eax, edx
  1211.         shr     eax, 3
  1212.         add     eax, CURRENT_TASK - (SLOT_BASE shr 3)
  1213.         mov     [eax+TASKDATA.wnd_number], dh
  1214.         mov     byte [eax+TASKDATA.pid], dh
  1215.  
  1216.         ret
  1217. endp
  1218.  
  1219. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1220. ;                                                                    ;
  1221. ;                    MAIN OS LOOP START                              ;
  1222. ;                                                                    ;
  1223. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1224. align 32
  1225. osloop:
  1226.         mov     edx, osloop_has_work?
  1227.         xor     ecx, ecx
  1228.         call    Wait_events
  1229.         xor     eax, eax
  1230.         xchg    eax, [osloop_nonperiodic_work]
  1231.         test    eax, eax
  1232.         jz      .no_periodic
  1233.  
  1234.         call    __sys_draw_pointer
  1235.         call    window_check_events
  1236.         call    mouse_check_events
  1237.         call    checkmisc
  1238.         call    checkVga_N13
  1239. ;--------------------------------------
  1240. .no_periodic:
  1241.         call    stack_handler
  1242.         call    check_fdd_motor_status
  1243.         call    check_ATAPI_device_event
  1244.         call    check_lights_state
  1245.         call    check_timers
  1246.  
  1247.         jmp     osloop
  1248. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1249. ;                                                                    ;
  1250. ;                      MAIN OS LOOP END                              ;
  1251. ;                                                                    ;
  1252. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1253. proc osloop_has_work?
  1254.         cmp     [osloop_nonperiodic_work], 0
  1255.         jnz     .yes
  1256.         call    stack_handler_has_work?
  1257.         jnz     .yes
  1258.         call    check_fdd_motor_status_has_work?
  1259.         jnz     .yes
  1260.         call    check_ATAPI_device_event_has_work?
  1261.         jnz     .yes
  1262.         call    check_lights_state_has_work?
  1263.         jnz     .yes
  1264.         call    check_timers_has_work?
  1265.         jnz     .yes
  1266. .no:
  1267.         xor     eax, eax
  1268.         ret
  1269. .yes:
  1270.         xor     eax, eax
  1271.         inc     eax
  1272.         ret
  1273. endp
  1274.  
  1275. proc wakeup_osloop
  1276.         mov     [osloop_nonperiodic_work], 1
  1277.         ret
  1278. endp
  1279.  
  1280. uglobal
  1281. align 4
  1282. osloop_nonperiodic_work dd      ?
  1283. endg
  1284.  
  1285. uglobal
  1286. align 64
  1287. idle_addr       rb      64
  1288. endg
  1289.  
  1290. idle_thread:
  1291.         sti
  1292.  
  1293. ; The following code can be executed by all CPUs in the system.
  1294. ; All other parts of the kernel do not expect multi-CPU.
  1295. ; Also, APs don't even have a stack here.
  1296. ; Beware. Don't do anything here. Anything at all.
  1297. idle_loop:
  1298.         cmp     [use_mwait_for_idle], 0
  1299.         jnz     idle_loop_mwait
  1300.  
  1301. idle_loop_hlt:
  1302.         hlt
  1303.         jmp     idle_loop_hlt
  1304.  
  1305. idle_loop_mwait:
  1306.         mov     eax, idle_addr
  1307.         xor     ecx, ecx
  1308.         xor     edx, edx
  1309.         monitor
  1310.         xor     ecx, ecx
  1311.         mov     eax, 20h        ; or 10h
  1312.         mwait
  1313.         jmp     idle_loop_mwait
  1314.  
  1315.  
  1316. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1317. ;                                                                      ;
  1318. ;                   INCLUDED SYSTEM FILES                              ;
  1319. ;                                                                      ;
  1320. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1321.  
  1322.  
  1323. include "kernel32.inc"
  1324.  
  1325.  
  1326. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1327. ;                                                                      ;
  1328. ;                       KERNEL FUNCTIONS                               ;
  1329. ;                                                                      ;
  1330. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1331.  
  1332. reserve_irqs_ports:
  1333.  
  1334.  
  1335. ; RESERVE PORTS
  1336.         mov     eax, RESERVED_PORTS
  1337.         mov     ecx, 1
  1338.  
  1339.         mov     [eax], dword 4
  1340.  
  1341.         mov     [eax+16], ecx
  1342.         mov     [eax+16+4], dword 0
  1343.         mov     [eax+16+8], dword 0x2D
  1344.  
  1345.         mov     [eax+32], ecx
  1346.         mov     [eax+32+4], dword 0x30
  1347.         mov     [eax+32+8], dword 0x4D
  1348.  
  1349.         mov     [eax+48], ecx
  1350.         mov     [eax+48+4], dword 0x50
  1351.         mov     [eax+48+8], dword 0xDF
  1352.  
  1353.         mov     [eax+64], ecx
  1354.         mov     [eax+64+4], dword 0xE5
  1355.         mov     [eax+64+8], dword 0xFF
  1356.  
  1357.         ret
  1358.  
  1359.  
  1360. iglobal
  1361.   process_number dd 0x2
  1362. endg
  1363.  
  1364. set_variables:
  1365.  
  1366.         mov     ecx, 0x16                    ; flush port 0x60
  1367. .fl60:
  1368.         in      al, 0x60
  1369.         loop    .fl60
  1370.         push    eax
  1371.  
  1372.         mov     ax, [BOOT_VARS+BOOT_Y_RES]
  1373.         shr     ax, 1
  1374.         shl     eax, 16
  1375.         mov     ax, [BOOT_VARS+BOOT_X_RES]
  1376.         shr     ax, 1
  1377.         mov     [MOUSE_X], eax
  1378.         call    wakeup_osloop
  1379.  
  1380.         xor     eax, eax
  1381.         mov     [BTN_ADDR], dword BUTTON_INFO ; address of button list
  1382.  
  1383.         mov     byte [KEY_COUNT], al              ; keyboard buffer
  1384.         mov     byte [BTN_COUNT], al              ; button buffer
  1385. ;        mov   [MOUSE_X],dword 100*65536+100    ; mouse x/y
  1386.  
  1387.         pop     eax
  1388.         ret
  1389.  
  1390. align 4
  1391. ;input  eax=43,bl-byte of output, ecx - number of port
  1392. sys_outport:
  1393.  
  1394.         mov     edi, ecx   ; separate flag for read / write
  1395.         and     ecx, 65535
  1396.  
  1397.         mov     eax, [RESERVED_PORTS]
  1398.         test    eax, eax
  1399.         jnz     .sopl8
  1400.         inc     eax
  1401.         mov     [esp+32], eax
  1402.         ret
  1403.  
  1404.   .sopl8:
  1405.         mov     edx, [TASK_BASE]
  1406.         mov     edx, [edx+0x4]
  1407.     ;and   ecx,65535
  1408.     ;cld - set on interrupt 0x40
  1409.   .sopl1:
  1410.  
  1411.         mov     esi, eax
  1412.         shl     esi, 4
  1413.         add     esi, RESERVED_PORTS
  1414.         cmp     edx, [esi+0]
  1415.         jne     .sopl2
  1416.         cmp     ecx, [esi+4]
  1417.         jb      .sopl2
  1418.         cmp     ecx, [esi+8]
  1419.         jg      .sopl2
  1420. .sopl3:
  1421.  
  1422.         test    edi, 0x80000000; read ?
  1423.         jnz     .sopl4
  1424.  
  1425.         mov     eax, ebx
  1426.         mov     dx, cx   ; write
  1427.         out     dx, al
  1428.         and     [esp+32], dword 0
  1429.         ret
  1430.  
  1431.         .sopl2:
  1432.  
  1433.         dec     eax
  1434.         jnz     .sopl1
  1435.         inc     eax
  1436.         mov     [esp+32], eax
  1437.         ret
  1438.  
  1439.  
  1440.   .sopl4:
  1441.  
  1442.         mov     dx, cx   ; read
  1443.         in      al, dx
  1444.         and     eax, 0xff
  1445.         and     [esp+32], dword 0
  1446.         mov     [esp+20], eax
  1447.         ret
  1448.  
  1449. display_number:
  1450. ;It is not optimization
  1451.         mov     eax, ebx
  1452.         mov     ebx, ecx
  1453.         mov     ecx, edx
  1454.         mov     edx, esi
  1455.         mov     esi, edi
  1456. ; eax = print type, al=0 -> ebx is number
  1457. ;                   al=1 -> ebx is pointer
  1458. ;                   ah=0 -> display decimal
  1459. ;                   ah=1 -> display hexadecimal
  1460. ;                   ah=2 -> display binary
  1461. ;                   eax bits 16-21 = number of digits to display (0-32)
  1462. ;                   eax bits 22-31 = reserved
  1463. ;
  1464. ; ebx = number or pointer
  1465. ; ecx = x shl 16 + y
  1466. ; edx = color
  1467.         xor     edi, edi
  1468. display_number_force:
  1469.         push    eax
  1470.         and     eax, 0x3fffffff
  1471.         cmp     eax, 0xffff     ; length > 0 ?
  1472.         pop     eax
  1473.         jge     cont_displ
  1474.         ret
  1475.    cont_displ:
  1476.         push    eax
  1477.         and     eax, 0x3fffffff
  1478.         cmp     eax, 61*0x10000  ; length <= 60 ?
  1479.         pop     eax
  1480.         jb      cont_displ2
  1481.         ret
  1482.    cont_displ2:
  1483.  
  1484.         pushad
  1485.  
  1486.         cmp     al, 1            ; ecx is a pointer ?
  1487.         jne     displnl1
  1488.         mov     ebp, ebx
  1489.         add     ebp, 4
  1490.         mov     ebp, [ebp+std_application_base_address]
  1491.         mov     ebx, [ebx+std_application_base_address]
  1492.  displnl1:
  1493.         sub     esp, 64
  1494.  
  1495.         test    ah, ah            ; DECIMAL
  1496.         jnz     no_display_desnum
  1497.         shr     eax, 16
  1498.         and     eax, 0xC03f
  1499. ;     and   eax,0x3f
  1500.         push    eax
  1501.         and     eax, 0x3f
  1502.         mov     edi, esp
  1503.         add     edi, 4+64-1
  1504.         mov     ecx, eax
  1505.         mov     eax, ebx
  1506.         mov     ebx, 10
  1507.  d_desnum:
  1508.         xor     edx, edx
  1509.         call    division_64_bits
  1510.         div     ebx
  1511.         add     dl, 48
  1512.         mov     [edi], dl
  1513.         dec     edi
  1514.         loop    d_desnum
  1515.         pop     eax
  1516.         call    normalize_number
  1517.         call    draw_num_text
  1518.         add     esp, 64
  1519.         popad
  1520.         ret
  1521.    no_display_desnum:
  1522.  
  1523.         cmp     ah, 0x01         ; HEXADECIMAL
  1524.         jne     no_display_hexnum
  1525.         shr     eax, 16
  1526.         and     eax, 0xC03f
  1527. ;     and   eax,0x3f
  1528.         push    eax
  1529.         and     eax, 0x3f
  1530.         mov     edi, esp
  1531.         add     edi, 4+64-1
  1532.         mov     ecx, eax
  1533.         mov     eax, ebx
  1534.         mov     ebx, 16
  1535.    d_hexnum:
  1536.         xor     edx, edx
  1537.         call    division_64_bits
  1538.         div     ebx
  1539.    hexletters = __fdo_hexdigits
  1540.         add     edx, hexletters
  1541.         mov     dl, [edx]
  1542.         mov     [edi], dl
  1543.         dec     edi
  1544.         loop    d_hexnum
  1545.         pop     eax
  1546.         call    normalize_number
  1547.         call    draw_num_text
  1548.         add     esp, 64
  1549.         popad
  1550.         ret
  1551.    no_display_hexnum:
  1552.  
  1553.         cmp     ah, 0x02         ; BINARY
  1554.         jne     no_display_binnum
  1555.         shr     eax, 16
  1556.         and     eax, 0xC03f
  1557. ;     and   eax,0x3f
  1558.         push    eax
  1559.         and     eax, 0x3f
  1560.         mov     edi, esp
  1561.         add     edi, 4+64-1
  1562.         mov     ecx, eax
  1563.         mov     eax, ebx
  1564.         mov     ebx, 2
  1565.    d_binnum:
  1566.         xor     edx, edx
  1567.         call    division_64_bits
  1568.         div     ebx
  1569.         add     dl, 48
  1570.         mov     [edi], dl
  1571.         dec     edi
  1572.         loop    d_binnum
  1573.         pop     eax
  1574.         call    normalize_number
  1575.         call    draw_num_text
  1576.         add     esp, 64
  1577.         popad
  1578.         ret
  1579.    no_display_binnum:
  1580.  
  1581.         add     esp, 64
  1582.         popad
  1583.         ret
  1584.  
  1585. normalize_number:
  1586.         test    ah, 0x80
  1587.         jz      .continue
  1588.         mov     ecx, 48
  1589.         and     eax, 0x3f
  1590. @@:
  1591.         inc     edi
  1592.         cmp     [edi], cl
  1593.         jne     .continue
  1594.         dec     eax
  1595.         cmp     eax, 1
  1596.         ja      @r
  1597.         mov     al, 1
  1598. .continue:
  1599.         and     eax, 0x3f
  1600.         ret
  1601.  
  1602. division_64_bits:
  1603.         test    [esp+1+4], byte 0x40
  1604.         jz      .continue
  1605.         push    eax
  1606.         mov     eax, ebp
  1607.         div     ebx
  1608.         mov     ebp, eax
  1609.         pop     eax
  1610. .continue:
  1611.         ret
  1612.  
  1613. draw_num_text:
  1614.         mov     esi, eax
  1615.         mov     edx, 64+4
  1616.         sub     edx, eax
  1617.         add     edx, esp
  1618.         mov     ebx, [esp+64+32-8+4]
  1619. ; add window start x & y
  1620.         mov     ecx, [TASK_BASE]
  1621.  
  1622.         mov     edi, [CURRENT_TASK]
  1623.         shl     edi, 8
  1624.  
  1625.         mov     eax, [ecx-twdw+WDATA.box.left]
  1626.         add     eax, [edi+SLOT_BASE+APPDATA.wnd_clientbox.left]
  1627.         shl     eax, 16
  1628.         add     eax, [ecx-twdw+WDATA.box.top]
  1629.         add     eax, [edi+SLOT_BASE+APPDATA.wnd_clientbox.top]
  1630.         add     ebx, eax
  1631.         mov     ecx, [esp+64+32-12+4]
  1632.         and     ecx, not 0x80000000     ; force counted string
  1633.         mov     eax, [esp+64+8]         ; background color (if given)
  1634.         mov     edi, [esp+64+4]
  1635.         jmp     dtext
  1636. ;-----------------------------------------------------------------------------
  1637. iglobal
  1638. midi_base dw 0
  1639. endg
  1640. ;-----------------------------------------------------------------------------
  1641. align 4
  1642. sys_setup:
  1643. ;  1 = roland mpu midi base , base io address
  1644. ;  2 = keyboard   1, base kaybap 2, shift keymap, 9 country 1eng 2fi 3ger 4rus
  1645. ;  3 = not used
  1646. ;  4 = not used
  1647. ;  5 = system language, 1eng 2fi 3ger 4rus
  1648. ;  6 = not used
  1649. ;  7 = not used
  1650. ;  8 = not used
  1651. ;  9 = not used
  1652. ; 10 = not used
  1653. ; 11 = enable lba read
  1654. ; 12 = enable pci access
  1655. ;-----------------------------------------------------------------------------
  1656.         and     [esp+32], dword 0
  1657. ; F.21.1 - set MPU MIDI base port
  1658.         dec     ebx
  1659.         jnz     @f
  1660.  
  1661.         cmp     ecx, 0x100
  1662.         jb      @f
  1663.  
  1664.         mov     esi, 65535
  1665.         cmp     esi, ecx
  1666.         jb      @f
  1667.  
  1668.         mov     [midi_base], cx
  1669.         mov     word [mididp], cx
  1670.         inc     cx
  1671.         mov     word [midisp], cx
  1672.         ret
  1673. ;--------------------------------------
  1674. @@:
  1675. ; F.21.2 - set keyboard layout
  1676.         dec     ebx
  1677.         jnz     @f
  1678.  
  1679.         mov     edi, [TASK_BASE]
  1680.         mov     eax, [edi+TASKDATA.mem_start]
  1681.         add     eax, edx
  1682. ; 1 = normal layout
  1683.         dec     ecx
  1684.         jnz     .shift
  1685.  
  1686.         mov     ebx, keymap
  1687.         mov     ecx, 128
  1688.         call    memmove
  1689.         ret
  1690. ;--------------------------------------
  1691. .shift:
  1692. ; 2 = layout at pressed Shift
  1693.         dec     ecx
  1694.         jnz     .alt
  1695.  
  1696.         mov     ebx, keymap_shift
  1697.         mov     ecx, 128
  1698.         call    memmove
  1699.         ret
  1700. ;--------------------------------------
  1701. .alt:
  1702. ; 3 = layout at pressed Alt
  1703.         dec     ecx
  1704.         jnz     .country
  1705.  
  1706.         mov     ebx, keymap_alt
  1707.         mov     ecx, 128
  1708.         call    memmove
  1709.         ret
  1710. ;--------------------------------------
  1711. .country:
  1712. ; country identifier
  1713.         sub     ecx, 6
  1714.         jnz     .error
  1715.  
  1716.         mov     word [keyboard], dx
  1717.         ret
  1718. ;--------------------------------------
  1719. @@:
  1720. ; F.21.5 - set system language
  1721.         sub     ebx, 3
  1722.         jnz     @f
  1723.  
  1724.         mov     [syslang], ecx
  1725.         ret
  1726. ;--------------------------------------
  1727. @@:
  1728. ; F.21.11 - enable/disable low-level access to HD
  1729.         and     ecx, 1
  1730.         sub     ebx, 6
  1731.         jnz     @f
  1732.  
  1733.         mov     [lba_read_enabled], ecx
  1734.         ret
  1735. ;--------------------------------------
  1736. @@:
  1737. ; F.21.12 - enable/disable low-level access to PCI
  1738.         dec     ebx
  1739.         jnz     .error
  1740.  
  1741.         mov     [pci_access_enabled], ecx
  1742.         ret
  1743. ;--------------------------------------
  1744. .error:
  1745.         or      [esp+32], dword -1
  1746.         ret
  1747. ;-----------------------------------------------------------------------------
  1748. align 4
  1749. sys_getsetup:
  1750. ;  1 = roland mpu midi base , base io address
  1751. ;  2 = keyboard   1, base kaybap 2, shift keymap, 9 country 1eng 2fi 3ger 4rus
  1752. ;  3 = not used
  1753. ;  4 = not used
  1754. ;  5 = system language, 1eng 2fi 3ger 4rus
  1755. ;  6 = not used
  1756. ;  7 = not used
  1757. ;  8 = not used
  1758. ;  9 = get hs timer tic
  1759. ; 10 = not used
  1760. ; 11 = get the state "lba read"
  1761. ; 12 = get the state "pci access"
  1762. ;-----------------------------------------------------------------------------
  1763. ; F.26.1 - get MPU MIDI base port
  1764.         dec     ebx
  1765.         jnz     @f
  1766.  
  1767.         movzx   eax, [midi_base]
  1768.         mov     [esp+32], eax
  1769.         ret
  1770. ;--------------------------------------
  1771. @@:
  1772. ; F.26.2 - get keyboard layout
  1773.         dec     ebx
  1774.         jnz     @f
  1775.  
  1776.         mov     edi, [TASK_BASE]
  1777.         mov     ebx, [edi+TASKDATA.mem_start]
  1778.         add     ebx, edx
  1779. ; 1 = normal layout
  1780.         dec     ecx
  1781.         jnz     .shift
  1782.  
  1783.         mov     eax, keymap
  1784.         mov     ecx, 128
  1785.         call    memmove
  1786.         ret
  1787. ;--------------------------------------
  1788. .shift:
  1789. ; 2 = layout with pressed Shift
  1790.         dec     ecx
  1791.         jnz     .alt
  1792.  
  1793.         mov     eax, keymap_shift
  1794.         mov     ecx, 128
  1795.         call    memmove
  1796.         ret
  1797. ;--------------------------------------
  1798. .alt:
  1799. ; 3 = layout with pressed Alt
  1800.         dec     ecx
  1801.         jne     .country
  1802.  
  1803.         mov     eax, keymap_alt
  1804.         mov     ecx, 128
  1805.         call    memmove
  1806.         ret
  1807. ;--------------------------------------
  1808. .country:
  1809. ; 9 = country identifier
  1810.         sub     ecx, 6
  1811.         jnz     .error
  1812.  
  1813.         movzx   eax, word [keyboard]
  1814.         mov     [esp+32], eax
  1815.         ret
  1816. ;--------------------------------------
  1817. @@:
  1818. ; F.26.5 - get system language
  1819.         sub     ebx, 3
  1820.         jnz     @f
  1821.  
  1822.         mov     eax, [syslang]
  1823.         mov     [esp+32], eax
  1824.         ret
  1825. ;--------------------------------------
  1826. @@:
  1827. ; F.26.9 - get the value of the time counter
  1828.         sub     ebx, 4
  1829.         jnz     @f
  1830.  
  1831.         mov     eax, [timer_ticks]
  1832.         mov     [esp+32], eax
  1833.         ret
  1834. ;--------------------------------------
  1835. @@:
  1836. ; F.26.10 - get the time from kernel launch in nanoseconds
  1837.         sub     ebx, 1
  1838.         jnz     @f
  1839.  
  1840.         call    get_clock_ns
  1841.         mov     [esp+24], edx
  1842.         mov     [esp+32], eax
  1843.         ret
  1844. ;--------------------------------------
  1845. @@:
  1846. ; F.26.11 - Find out whether low-level HD access is enabled
  1847.         sub     ebx, 1
  1848.         jnz     @f
  1849.  
  1850.         mov     eax, [lba_read_enabled]
  1851.         mov     [esp+32], eax
  1852.         ret
  1853. ;--------------------------------------
  1854. @@:
  1855. ; F.26.12 - Find out whether low-level PCI access is enabled
  1856.         dec     ebx
  1857.         jnz     .error
  1858.  
  1859.         mov     eax, [pci_access_enabled]
  1860.         mov     [esp+32], eax
  1861.         ret
  1862. ;--------------------------------------
  1863. .error:
  1864.         or      [esp+32], dword -1
  1865.         ret
  1866. ;-----------------------------------------------------------------------------
  1867. get_timer_ticks:
  1868.         mov     eax, [timer_ticks]
  1869.         ret
  1870. ;-----------------------------------------------------------------------------
  1871. iglobal
  1872. align 4
  1873. mousefn dd msscreen
  1874.         dd mswin
  1875.         dd msbutton
  1876.         dd msbuttonExt
  1877.         dd app_load_cursor
  1878.         dd app_set_cursor
  1879.         dd app_delete_cursor
  1880.         dd msz
  1881. endg
  1882. ;-----------------------------------------------------------------------------
  1883. readmousepos:
  1884.  
  1885. ; eax=0 screen relative
  1886. ; eax=1 window relative
  1887. ; eax=2 buttons pressed
  1888. ; eax=3 buttons pressed ext
  1889. ; eax=4 load cursor
  1890. ; eax=5 set cursor
  1891. ; eax=6 delete cursor
  1892. ; eax=7 get mouse_z
  1893.  
  1894.         cmp     ebx, 7
  1895.         ja      @f
  1896.         jmp     [mousefn+ebx*4]
  1897.  
  1898. msscreen:
  1899.         mov     eax, [MOUSE_X]
  1900.         shl     eax, 16
  1901.         mov     ax, [MOUSE_Y]
  1902.         mov     [esp+36-4], eax
  1903. @@:
  1904.         ret
  1905.  
  1906. mswin:
  1907.         mov     eax, [MOUSE_X]
  1908.         shl     eax, 16
  1909.         mov     ax, [MOUSE_Y]
  1910.         mov     esi, [TASK_BASE]
  1911.         mov     bx, word [esi-twdw+WDATA.box.left]
  1912.         shl     ebx, 16
  1913.         mov     bx, word [esi-twdw+WDATA.box.top]
  1914.         sub     eax, ebx
  1915.         mov     edi, [CURRENT_TASK]
  1916.         shl     edi, 8
  1917.         sub     ax, word[edi+SLOT_BASE+APPDATA.wnd_clientbox.top]
  1918.         rol     eax, 16
  1919.         sub     ax, word[edi+SLOT_BASE+APPDATA.wnd_clientbox.left]
  1920.         rol     eax, 16
  1921.         mov     [esp+36-4], eax
  1922.         ret
  1923.  
  1924. msbutton:
  1925.         movzx   eax, byte [BTN_DOWN]
  1926.         mov     [esp+36-4], eax
  1927.         ret
  1928.  
  1929. msbuttonExt:
  1930.         mov     eax, [BTN_DOWN]
  1931.         mov     [esp+36-4], eax
  1932.         ret
  1933.  
  1934. app_load_cursor:
  1935.         cmp     ecx, OS_BASE
  1936.         jae     @f
  1937.         stdcall load_cursor, ecx, edx
  1938.         mov     [esp+36-4], eax
  1939. @@:
  1940.         ret
  1941.  
  1942. app_set_cursor:
  1943.         stdcall set_cursor, ecx
  1944.         mov     [esp+36-4], eax
  1945.         ret
  1946.  
  1947. app_delete_cursor:
  1948.         stdcall delete_cursor, ecx
  1949.         mov     [esp+36-4], eax
  1950.         ret
  1951.  
  1952. msz:
  1953.         mov     edi, [TASK_COUNT]
  1954.         movzx   edi, word [WIN_POS + edi*2]
  1955.         cmp     edi, [CURRENT_TASK]
  1956.         jne     @f
  1957.         mov     ax, [MOUSE_SCROLL_H]
  1958.         shl     eax, 16
  1959.         mov     ax, [MOUSE_SCROLL_V]
  1960.         mov     [esp+36-4], eax
  1961.         and     [MOUSE_SCROLL_H], word 0
  1962.         and     [MOUSE_SCROLL_V], word 0
  1963.         ret
  1964. @@:
  1965.         and     [esp+36-4], dword 0
  1966.         ret
  1967.  
  1968. is_input:
  1969.  
  1970.         push    edx
  1971.         mov     dx, word [midisp]
  1972.         in      al, dx
  1973.         and     al, 0x80
  1974.         pop     edx
  1975.         ret
  1976.  
  1977. is_output:
  1978.  
  1979.         push    edx
  1980.         mov     dx, word [midisp]
  1981.         in      al, dx
  1982.         and     al, 0x40
  1983.         pop     edx
  1984.         ret
  1985.  
  1986.  
  1987. get_mpu_in:
  1988.  
  1989.         push    edx
  1990.         mov     dx, word [mididp]
  1991.         in      al, dx
  1992.         pop     edx
  1993.         ret
  1994.  
  1995.  
  1996. put_mpu_out:
  1997.  
  1998.         push    edx
  1999.         mov     dx, word [mididp]
  2000.         out     dx, al
  2001.         pop     edx
  2002.         ret
  2003.  
  2004.  
  2005.  
  2006. align 4
  2007.  
  2008. sys_midi:
  2009.         cmp     [mididp], 0
  2010.         jnz     sm0
  2011.         mov     [esp+36], dword 1
  2012.         ret
  2013. sm0:
  2014.         and     [esp+36], dword 0
  2015.         dec     ebx
  2016.         jnz     smn1
  2017.  ;    call setuart
  2018. su1:
  2019.         call    is_output
  2020.         test    al, al
  2021.         jnz     su1
  2022.         mov     dx, word [midisp]
  2023.         mov     al, 0xff
  2024.         out     dx, al
  2025. su2:
  2026.         mov     dx, word [midisp]
  2027.         mov     al, 0xff
  2028.         out     dx, al
  2029.         call    is_input
  2030.         test    al, al
  2031.         jnz     su2
  2032.         call    get_mpu_in
  2033.         cmp     al, 0xfe
  2034.         jnz     su2
  2035. su3:
  2036.         call    is_output
  2037.         test    al, al
  2038.         jnz     su3
  2039.         mov     dx, word [midisp]
  2040.         mov     al, 0x3f
  2041.         out     dx, al
  2042.         ret
  2043. smn1:
  2044.         dec     ebx
  2045.         jnz     smn2
  2046. sm10:
  2047.         call    get_mpu_in
  2048.         call    is_output
  2049.         test    al, al
  2050.         jnz     sm10
  2051.         mov     al, bl
  2052.         call    put_mpu_out
  2053.         smn2:
  2054.         ret
  2055.  
  2056. detect_devices:
  2057. ;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  2058. ;include 'detect/commouse.inc'
  2059. ;include 'detect/ps2mouse.inc'
  2060. ;include 'detect/dev_fd.inc'
  2061. ;include 'detect/dev_hdcd.inc'
  2062. ;include 'detect/sear_par.inc'
  2063. ;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  2064.         ret
  2065.  
  2066. sys_end:
  2067. ;--------------------------------------
  2068.         cmp     [_display.select_cursor], 0
  2069.         je      @f
  2070. ; restore default cursor before killing
  2071.         pusha
  2072.         mov     ecx, [current_slot]
  2073.         call    restore_default_cursor_before_killing
  2074.         popa
  2075. @@:
  2076. ;--------------------------------------
  2077. ; kill all sockets this process owns
  2078.         pusha
  2079.         mov     edx, [TASK_BASE]
  2080.         mov     edx, [edx+TASKDATA.pid]
  2081.         call    socket_process_end
  2082.         popa
  2083. ;--------------------------------------
  2084.         mov     ecx, [current_slot]
  2085.         mov     eax, [ecx+APPDATA.tls_base]
  2086.         test    eax, eax
  2087.         jz      @F
  2088.  
  2089.         stdcall user_free, eax
  2090. @@:
  2091.  
  2092.         mov     eax, [TASK_BASE]
  2093.         mov     [eax+TASKDATA.state], TSTATE_ZOMBIE
  2094.         call    wakeup_osloop
  2095.  
  2096. .waitterm:            ; wait here for termination
  2097.         call    change_task
  2098.         jmp     .waitterm
  2099. ;------------------------------------------------------------------------------
  2100. align 4
  2101. restore_default_cursor_before_killing:
  2102.         pushfd
  2103.         cli
  2104.         mov     eax, [def_cursor]
  2105.         mov     [ecx+APPDATA.cursor], eax
  2106.  
  2107.         movzx   eax, word [MOUSE_Y]
  2108.         movzx   ebx, word [MOUSE_X]
  2109.         mov     eax, [d_width_calc_area + eax*4]
  2110.  
  2111.         add     eax, [_display.win_map]
  2112.         movzx   edx, byte [ebx+eax]
  2113.         shl     edx, 8
  2114.         mov     esi, [edx+SLOT_BASE+APPDATA.cursor]
  2115.  
  2116.         cmp     esi, [current_cursor]
  2117.         je      @f
  2118.  
  2119.         push    esi
  2120.         call    [_display.select_cursor]
  2121.         mov     [current_cursor], esi
  2122. @@:
  2123.         mov     [redrawmouse_unconditional], 1
  2124.         call    wakeup_osloop
  2125.         popfd
  2126.         ret
  2127. ;------------------------------------------------------------------------------
  2128. iglobal
  2129. align 4
  2130. sys_system_table:
  2131.         dd      sysfn_deactivate        ; 1 = deactivate window
  2132.         dd      sysfn_terminate         ; 2 = terminate thread
  2133.         dd      sysfn_activate          ; 3 = activate window
  2134.         dd      sysfn_getidletime       ; 4 = get idle time
  2135.         dd      sysfn_getcpuclock       ; 5 = get cpu clock
  2136.         dd      sysfn_saveramdisk       ; 6 = save ramdisk
  2137.         dd      sysfn_getactive         ; 7 = get active window
  2138.         dd      sysfn_sound_flag        ; 8 = get/set sound_flag
  2139.         dd      sysfn_shutdown          ; 9 = shutdown with parameter
  2140.         dd      sysfn_minimize          ; 10 = minimize window
  2141.         dd      sysfn_getdiskinfo       ; 11 = get disk subsystem info
  2142.         dd      sysfn_lastkey           ; 12 = get last pressed key
  2143.         dd      sysfn_getversion        ; 13 = get kernel version
  2144.         dd      sysfn_waitretrace       ; 14 = wait retrace
  2145.         dd      sysfn_centermouse       ; 15 = center mouse cursor
  2146.         dd      sysfn_getfreemem        ; 16 = get free memory size
  2147.         dd      sysfn_getallmem         ; 17 = get total memory size
  2148.         dd      sysfn_terminate2        ; 18 = terminate thread using PID
  2149.                                         ;                 instead of slot
  2150.         dd      sysfn_mouse_acceleration; 19 = set/get mouse acceleration
  2151.         dd      sysfn_meminfo           ; 20 = get extended memory info
  2152.         dd      sysfn_pid_to_slot       ; 21 = get slot number for pid
  2153.         dd      sysfn_min_rest_window   ; 22 = minimize and restore any window
  2154.         dd      sysfn_min_windows       ; 23 = minimize all windows
  2155.         dd      sysfn_set_screen_sizes  ; 24 = set screen sizes for Vesa
  2156.  
  2157.         dd      sysfn_zmodif            ; 25 = get/set window z modifier  ;Fantomer
  2158. sysfn_num = ($ - sys_system_table)/4
  2159. endg
  2160. ;------------------------------------------------------------------------------
  2161. sys_system:
  2162.         dec     ebx
  2163.         cmp     ebx, sysfn_num
  2164.         jae     @f
  2165.         jmp     dword [sys_system_table + ebx*4]
  2166. @@:
  2167.         ret
  2168. ;------------------------------------------------------------------------------
  2169. sysfn_shutdown:          ; 18.9 = system shutdown
  2170.         cmp     ecx, 1
  2171.         jl      exit_for_anyone
  2172.         cmp     ecx, 4
  2173.         jg      exit_for_anyone
  2174.         mov     [BOOT_VARS+0x9030], cl
  2175.  
  2176.         mov     eax, [TASK_COUNT]
  2177.         mov     [SYS_SHUTDOWN], al
  2178.         mov     [shutdown_processes], eax
  2179.         call    wakeup_osloop
  2180.         and     dword [esp+32], 0
  2181.  exit_for_anyone:
  2182.         ret
  2183.   uglobal
  2184.    shutdown_processes:
  2185.                        dd 0x0
  2186.   endg
  2187. ;------------------------------------------------------------------------------
  2188. sysfn_terminate:        ; 18.2 = TERMINATE
  2189.         push    ecx
  2190.         cmp     ecx, 2
  2191.         jb      noprocessterminate
  2192.         mov     edx, [TASK_COUNT]
  2193.         cmp     ecx, edx
  2194.         ja      noprocessterminate
  2195.         mov     eax, [TASK_COUNT]
  2196.         shl     ecx, 5
  2197.         mov     edx, [ecx+CURRENT_TASK+TASKDATA.pid]
  2198.         add     ecx, CURRENT_TASK+TASKDATA.state
  2199.         cmp     byte [ecx], 9
  2200.         jz      noprocessterminate
  2201.         push    ecx edx
  2202.         lea     edx, [(ecx-(CURRENT_TASK and 1FFFFFFFh)-TASKDATA.state)*8+SLOT_BASE]
  2203.         call    request_terminate
  2204.         pop     edx ecx
  2205.         test    eax, eax
  2206.         jz      noprocessterminate
  2207. ;--------------------------------------
  2208. ; terminate all network sockets it used
  2209.         pusha
  2210.         mov     eax, edx
  2211.         call    socket_process_end
  2212.         popa
  2213. ;--------------------------------------
  2214.         cmp     [_display.select_cursor], 0
  2215.         je      .restore_end
  2216. ; restore default cursor before killing
  2217.         pusha
  2218.         mov     ecx, [esp+32]
  2219.         shl     ecx, 8
  2220.         add     ecx, SLOT_BASE
  2221.         mov     eax, [def_cursor]
  2222.         cmp     [ecx+APPDATA.cursor], eax
  2223.         je      @f
  2224.         call    restore_default_cursor_before_killing
  2225. @@:
  2226.         popa
  2227. .restore_end:
  2228. ;--------------------------------------
  2229.      ;call MEM_Heap_Lock      ;guarantee that process isn't working with heap
  2230.         mov     [ecx], byte 3; clear possible i40's
  2231.         call    wakeup_osloop
  2232.      ;call MEM_Heap_UnLock
  2233.  
  2234.         cmp     edx, [application_table_owner]; clear app table stat
  2235.         jne     noatsc
  2236.         call    unlock_application_table
  2237. noatsc:
  2238. noprocessterminate:
  2239.         add     esp, 4
  2240.         ret
  2241. ;------------------------------------------------------------------------------
  2242. sysfn_terminate2:
  2243. ;lock application_table_status mutex
  2244. .table_status:
  2245.         call    lock_application_table
  2246.         mov     eax, ecx
  2247.         call    pid_to_slot
  2248.         test    eax, eax
  2249.         jz      .not_found
  2250.         mov     ecx, eax
  2251.         cli
  2252.         call    sysfn_terminate
  2253.         call    unlock_application_table
  2254.         sti
  2255.         and     dword [esp+32], 0
  2256.         ret
  2257. .not_found:
  2258.         call    unlock_application_table
  2259.         or      dword [esp+32], -1
  2260.         ret
  2261. ;------------------------------------------------------------------------------
  2262. sysfn_deactivate:         ; 18.1 = DEACTIVATE WINDOW
  2263.         cmp     ecx, 2
  2264.         jb      .nowindowdeactivate
  2265.         cmp     ecx, [TASK_COUNT]
  2266.         ja      .nowindowdeactivate
  2267.  
  2268.         movzx   esi, word [WIN_STACK + ecx*2]
  2269.         cmp     esi, 1
  2270.         je      .nowindowdeactivate ; already deactive
  2271.  
  2272.         mov     edi, ecx
  2273.         shl     edi, 5
  2274.         add     edi, window_data
  2275.         movzx   esi, word [WIN_STACK + ecx * 2]
  2276.         lea     esi, [WIN_POS + esi * 2]
  2277.         call    window._.window_deactivate
  2278.  
  2279.         call    syscall_display_settings._.calculate_whole_screen
  2280.         call    syscall_display_settings._.redraw_whole_screen
  2281. .nowindowdeactivate:
  2282.         ret
  2283. ;------------------------------------------------------------------------------
  2284. sysfn_activate:         ; 18.3 = ACTIVATE WINDOW
  2285.         cmp     ecx, 2
  2286.         jb      .nowindowactivate
  2287.         cmp     ecx, [TASK_COUNT]
  2288.         ja      .nowindowactivate
  2289. ;-------------------------------------
  2290. @@:
  2291. ; If the window is captured and moved by the user,
  2292. ; then you can't change the position in window stack!!!
  2293.         mov     al, [mouse.active_sys_window.action]
  2294.         and     al, WINDOW_MOVE_AND_RESIZE_FLAGS
  2295.         test    al, al
  2296.         jz      @f
  2297.         call    change_task
  2298.         jmp     @b
  2299. @@:
  2300. ;-------------------------------------
  2301.         mov     [window_minimize], 2; restore window if minimized
  2302.         call    wakeup_osloop
  2303.  
  2304.         movzx   esi, word [WIN_STACK + ecx*2]
  2305.         cmp     esi, [TASK_COUNT]
  2306.         je      .nowindowactivate; already active
  2307.  
  2308.         mov     edi, ecx
  2309.         shl     edi, 5
  2310.         add     edi, window_data
  2311.         movzx   esi, word [WIN_STACK + ecx * 2]
  2312.         lea     esi, [WIN_POS + esi * 2]
  2313.         call    waredraw
  2314. .nowindowactivate:
  2315.         ret
  2316. ;------------------------------------------------------------------------------
  2317. align 4
  2318. sysfn_zmodif:
  2319. ;18,25,1 - get z_modif
  2320. ;18,25,2 - set z_modif
  2321. ;edx = -1(for current task) or TID
  2322. ;esi(for 2) = new value z_modif
  2323. ;return:
  2324. ;1:   eax = z_modif
  2325. ;2: eax=0(fail),1(success) for set z_modif
  2326.  
  2327.         cmp     edx, -1
  2328.         jne     @f
  2329.         mov     edx, [CURRENT_TASK]
  2330.      @@:
  2331.         cmp     edx, [TASK_COUNT]
  2332.         ja      .fail
  2333.         cmp     edx, 1
  2334.         je      .fail
  2335.  
  2336.         mov     eax, edx
  2337.         shl     edx, 5
  2338.  
  2339.         cmp     [edx + CURRENT_TASK + TASKDATA.state], 9
  2340.         je      .fail
  2341.  
  2342.         cmp     ecx, 1
  2343.         jnz     .set_zmod
  2344.  
  2345.         mov     al, [edx + window_data + WDATA.z_modif]
  2346.         jmp     .exit
  2347.  
  2348. .set_zmod:
  2349.         cmp     ecx, 2
  2350.         jnz     .fail
  2351.  
  2352.         mov     ebx, esi
  2353.         mov     esi, eax
  2354.  
  2355.         cmp     bl, ZPOS_ALWAYS_TOP
  2356.         jg      .fail
  2357.  
  2358.         mov     [edx + window_data + WDATA.z_modif], bl
  2359.  
  2360.         mov     eax, [edx + window_data + WDATA.box.left]
  2361.         mov     ebx, [edx + window_data + WDATA.box.top]
  2362.         mov     ecx, [edx + window_data + WDATA.box.width]
  2363.         mov     edx, [edx + window_data + WDATA.box.height]
  2364.         add     ecx, eax
  2365.         add     edx, ebx
  2366.         call    window._.set_screen
  2367.         call    window._.set_top_wnd
  2368.         call    window._.redraw_top_wnd
  2369.  
  2370.         shl     esi, 5
  2371.         mov     [esi + window_data + WDATA.fl_redraw], 1
  2372.  
  2373.  
  2374.         mov     eax, 1
  2375.         jmp     .exit
  2376. .fail:
  2377.         xor     eax, eax
  2378. .exit:
  2379.         mov     [esp+32], eax
  2380.         ret
  2381.  
  2382. ;------------------------------------------------------------------------------
  2383. sysfn_getidletime:              ; 18.4 = GET IDLETIME
  2384.         mov     eax, [CURRENT_TASK+32+TASKDATA.cpu_usage]
  2385.         mov     [esp+32], eax
  2386.         ret
  2387. ;------------------------------------------------------------------------------
  2388. sysfn_getcpuclock:              ; 18.5 = GET TSC/SEC
  2389.         mov     eax, dword [cpu_freq]
  2390.         mov     [esp+32], eax
  2391.         ret
  2392. ;------------------------------------------------------------------------------
  2393. get_cpu_freq:
  2394.         mov     eax, dword [cpu_freq]
  2395.         mov     edx, dword [cpu_freq+4]
  2396.         ret
  2397. ;  SAVE ramdisk to /hd/1/menuet.img
  2398. ;!!!!!!!!!!!!!!!!!!!!!!!!
  2399.    include 'blkdev/rdsave.inc'
  2400. ;!!!!!!!!!!!!!!!!!!!!!!!!
  2401. ;------------------------------------------------------------------------------
  2402. align 4
  2403. sysfn_getactive:        ; 18.7 = get active window
  2404.         mov     eax, [TASK_COUNT]
  2405.         movzx   eax, word [WIN_POS + eax*2]
  2406.         mov     [esp+32], eax
  2407.         ret
  2408. ;------------------------------------------------------------------------------
  2409. sysfn_sound_flag:       ; 18.8 = get/set sound_flag
  2410. ;     cmp  ecx,1
  2411.         dec     ecx
  2412.         jnz     nogetsoundflag
  2413.         movzx   eax, byte [sound_flag]; get sound_flag
  2414.         mov     [esp+32], eax
  2415.         ret
  2416.  nogetsoundflag:
  2417. ;     cmp  ecx,2
  2418.         dec     ecx
  2419.         jnz     nosoundflag
  2420.         xor     byte [sound_flag], 1
  2421.  nosoundflag:
  2422.         ret
  2423. ;------------------------------------------------------------------------------
  2424. sysfn_minimize:         ; 18.10 = minimize window
  2425.         mov     [window_minimize], 1
  2426.         call    wakeup_osloop
  2427.         ret
  2428. ;------------------------------------------------------------------------------
  2429. align 4
  2430. sysfn_getdiskinfo:      ; 18.11 = get disk info table
  2431.         dec     ecx
  2432.         jnz     .exit
  2433. .small_table:
  2434.         mov     edi, edx
  2435.         mov     esi, DRIVE_DATA
  2436.         mov     ecx, DRIVE_DATA_SIZE ;10
  2437.         cld
  2438.         rep movsb
  2439. .exit:
  2440.         ret
  2441. ;------------------------------------------------------------------------------
  2442. sysfn_lastkey:          ; 18.12 = return 0 (backward compatibility)
  2443.         and     dword [esp+32], 0
  2444.         ret
  2445. ;------------------------------------------------------------------------------
  2446. sysfn_getversion:       ; 18.13 = get kernel ID and version
  2447.         mov     edi, ecx
  2448.         mov     esi, version_inf
  2449.         mov     ecx, version_end-version_inf
  2450.         rep movsb
  2451.         ret
  2452. ;------------------------------------------------------------------------------
  2453. sysfn_waitretrace:     ; 18.14 = sys wait retrace
  2454.      ;wait retrace functions
  2455.  sys_wait_retrace:
  2456.         mov     edx, 0x3da
  2457.  WaitRetrace_loop:
  2458.         in      al, dx
  2459.         test    al, 1000b
  2460.         jz      WaitRetrace_loop
  2461.         and     [esp+32], dword 0
  2462.         ret
  2463. ;------------------------------------------------------------------------------
  2464. align 4
  2465. sysfn_centermouse:      ; 18.15 = mouse centered
  2466.         mov     eax, [_display.width]
  2467.         shr     eax, 1
  2468.         mov     [MOUSE_X], ax
  2469.         mov     eax, [_display.height]
  2470.         shr     eax, 1
  2471.         mov     [MOUSE_Y], ax
  2472.         call    wakeup_osloop
  2473.         xor     eax, eax
  2474.         and     [esp+32], eax
  2475.         ret
  2476. ;------------------------------------------------------------------------------
  2477. sysfn_mouse_acceleration:       ; 18.19 = set/get mouse features
  2478.         cmp     ecx, 8
  2479.         jnc     @f
  2480.         jmp     dword [.table+ecx*4]
  2481. .get_mouse_acceleration:
  2482.         xor     eax, eax
  2483.         mov     ax, [mouse_speed_factor]
  2484.         mov     [esp+32], eax
  2485.         ret
  2486. .set_mouse_acceleration:
  2487.         mov     [mouse_speed_factor], dx
  2488.         ret
  2489. .get_mouse_delay:
  2490.         xor     eax, eax
  2491.         mov     al, [mouse_delay]
  2492.         mov     [esp+32], eax
  2493.         ret
  2494. .set_mouse_delay:
  2495.         mov     [mouse_delay], dl
  2496. @@:
  2497.         ret
  2498. .set_pointer_position:
  2499.         cmp     dx, word[_display.height]
  2500.         jae     @b
  2501.         rol     edx, 16
  2502.         cmp     dx, word[_display.width]
  2503.         jae     @b
  2504.         mov     [MOUSE_X], edx
  2505.         mov     [mouse_active], 1
  2506.         jmp     wakeup_osloop
  2507. .set_mouse_button:
  2508.         mov     [BTN_DOWN], edx
  2509.         mov     [mouse_active], 1
  2510.         jmp     wakeup_osloop
  2511. .get_doubleclick_delay:
  2512.         xor     eax, eax
  2513.         mov     al, [mouse_doubleclick_delay]
  2514.         mov     [esp+32], eax
  2515.         ret
  2516. .set_doubleclick_delay:
  2517.         mov     [mouse_doubleclick_delay], dl
  2518.         ret
  2519. align 4
  2520. .table:
  2521. dd      .get_mouse_acceleration
  2522. dd      .set_mouse_acceleration
  2523. dd      .get_mouse_delay
  2524. dd      .set_mouse_delay
  2525. dd      .set_pointer_position
  2526. dd      .set_mouse_button
  2527. dd      .get_doubleclick_delay
  2528. dd      .set_doubleclick_delay
  2529. ;------------------------------------------------------------------------------
  2530. sysfn_getfreemem:
  2531.         mov     eax, [pg_data.pages_free]
  2532.         shl     eax, 2
  2533.         mov     [esp+32], eax
  2534.         ret
  2535. ;------------------------------------------------------------------------------
  2536. sysfn_getallmem:
  2537.         mov     eax, [MEM_AMOUNT]
  2538.         shr     eax, 10
  2539.         mov     [esp+32], eax
  2540.         ret
  2541. ;------------------------------------------------------------------------------
  2542. sysfn_pid_to_slot:
  2543.         mov     eax, ecx
  2544.         call    pid_to_slot
  2545.         mov     [esp+32], eax
  2546.         ret
  2547. ;------------------------------------------------------------------------------
  2548. sysfn_min_rest_window:
  2549.         pushad
  2550.         mov     eax, edx ; ebx - operating
  2551.         shr     ecx, 1
  2552.         jnc     @f
  2553.         call    pid_to_slot
  2554. @@:
  2555.         or      eax, eax ; eax - number of slot
  2556.         jz      .error
  2557.         cmp     eax, 255    ; varify maximal slot number
  2558.         ja      .error
  2559.         movzx   eax, word [WIN_STACK + eax*2]
  2560.         shr     ecx, 1
  2561.         jc      .restore
  2562.  ; .minimize:
  2563.         call    minimize_window
  2564.         jmp     .exit
  2565. .restore:
  2566.         call    restore_minimized_window
  2567. .exit:
  2568.         popad
  2569.         xor     eax, eax
  2570.         mov     [esp+32], eax
  2571.         ret
  2572. .error:
  2573.         popad
  2574.         xor     eax, eax
  2575.         dec     eax
  2576.         mov     [esp+32], eax
  2577.         ret
  2578. ;------------------------------------------------------------------------------
  2579. sysfn_min_windows:
  2580.         call    minimize_all_window
  2581.         mov     [esp+32], eax
  2582.         call    change_task
  2583.         ret
  2584. ;------------------------------------------------------------------------------
  2585. sysfn_set_screen_sizes:
  2586.         cmp     [SCR_MODE], word 0x13
  2587.         jbe     .exit
  2588.  
  2589.         cmp     [_display.select_cursor], select_cursor
  2590.         jne     .exit
  2591.  
  2592.         cmp     ecx, [display_width_standard]
  2593.         ja      .exit
  2594.  
  2595.         cmp     edx, [display_height_standard]
  2596.         ja      .exit
  2597.  
  2598.         pushfd
  2599.         cli
  2600.         mov     eax, ecx
  2601.         mov     ecx, [_display.lfb_pitch]
  2602.         mov     [_display.width], eax
  2603.         dec     eax
  2604.         mov     [_display.height], edx
  2605.         dec     edx
  2606. ; eax - new Screen_Max_X
  2607. ; edx - new Screen_Max_Y
  2608.         mov     [do_not_touch_winmap], 1
  2609.         call    set_screen
  2610.         mov     [do_not_touch_winmap], 0
  2611.         popfd
  2612.         call    change_task
  2613. .exit:
  2614.         ret
  2615. ;------------------------------------------------------------------------------
  2616. uglobal
  2617. screen_workarea RECT
  2618. display_width_standard dd 0
  2619. display_height_standard dd 0
  2620. do_not_touch_winmap db 0
  2621. window_minimize db 0
  2622. sound_flag      db 0
  2623.  
  2624. endg
  2625.  
  2626. UID_NONE=0
  2627. UID_MENUETOS=1   ;official
  2628. UID_KOLIBRI=2    ;russian
  2629.  
  2630. iglobal
  2631. version_inf:
  2632.         db 0,7,7,0  ; version 0.7.7.0
  2633.         db 0
  2634. .rev    dd __REV__
  2635. version_end:
  2636. endg
  2637. ;------------------------------------------------------------------------------
  2638. align 4
  2639. sys_cachetodiskette:
  2640.         cmp     ebx, 1
  2641.         jb      .no_floppy_save
  2642.         cmp     ebx, 2
  2643.         ja      .no_floppy_save
  2644.         call    save_image
  2645.         mov     [esp + 32], eax
  2646.         ret
  2647. .no_floppy_save:
  2648.         mov     [esp + 32], dword 1
  2649.         ret
  2650. ;------------------------------------------------------------------------------
  2651. uglobal
  2652. ;  bgrchanged  dd  0x0
  2653. align 4
  2654. bgrlockpid dd 0
  2655. bgrlock db 0
  2656. endg
  2657. ;------------------------------------------------------------------------------
  2658. align 4
  2659. sys_background:
  2660.         cmp     ebx, 1                     ; BACKGROUND SIZE
  2661.         jnz     nosb1
  2662.         test    ecx, ecx
  2663.         jz      sbgrr
  2664.  
  2665.         test    edx, edx
  2666.         jz      sbgrr
  2667. ;--------------------------------------
  2668. align 4
  2669. @@:
  2670. ;;Maxis use atomic bts for mutexes  4.4.2009
  2671.         bts     dword [bgrlock], 0
  2672.         jnc     @f
  2673.         call    change_task
  2674.         jmp     @b
  2675. ;--------------------------------------
  2676. align 4
  2677. @@:
  2678.         mov     [BgrDataWidth], ecx
  2679.         mov     [BgrDataHeight], edx
  2680. ;    mov   [bgrchanged],1
  2681.  
  2682.         pushad
  2683. ; return memory for old background
  2684.         mov     eax, [img_background]
  2685.         cmp     eax, static_background_data
  2686.         jz      @f
  2687.         stdcall kernel_free, eax
  2688. ;--------------------------------------
  2689. align 4
  2690. @@:
  2691. ; calculate RAW size
  2692.         xor     eax, eax
  2693.         inc     eax
  2694.         cmp     [BgrDataWidth], eax
  2695.         jae     @f
  2696.         mov     [BgrDataWidth], eax
  2697. ;--------------------------------------
  2698. align 4
  2699. @@:
  2700.         cmp     [BgrDataHeight], eax
  2701.         jae     @f
  2702.         mov     [BgrDataHeight], eax
  2703. ;--------------------------------------
  2704. align 4
  2705. @@:
  2706.         mov     eax, [BgrDataWidth]
  2707.         imul    eax, [BgrDataHeight]
  2708.         lea     eax, [eax*3]
  2709. ; it is reserved with aligned to the boundary of 4 KB pages,
  2710. ; otherwise there may be exceptions a page fault for vesa20_drawbackground_tiled
  2711. ; because the 32 bit read is used for  high performance: "mov eax,[esi]"
  2712.         shr     eax, 12
  2713.         inc     eax
  2714.         shl     eax, 12
  2715.         mov     [mem_BACKGROUND], eax
  2716. ; get memory for new background
  2717.         stdcall kernel_alloc, eax
  2718.         test    eax, eax
  2719.         jz      .memfailed
  2720.         mov     [img_background], eax
  2721.         jmp     .exit
  2722. ;--------------------------------------
  2723. align 4
  2724. .memfailed:
  2725. ; revert to static monotone data
  2726.         mov     [img_background], static_background_data
  2727.         xor     eax, eax
  2728.         inc     eax
  2729.         mov     [BgrDataWidth], eax
  2730.         mov     [BgrDataHeight], eax
  2731.         mov     [mem_BACKGROUND], 4
  2732. ;--------------------------------------
  2733. align 4
  2734. .exit:
  2735.         popad
  2736.         mov     [bgrlock], 0
  2737. ;--------------------------------------
  2738. align 4
  2739. sbgrr:
  2740.         ret
  2741. ;------------------------------------------------------------------------------
  2742. align 4
  2743. nosb1:
  2744.         cmp     ebx, 2                     ; SET PIXEL
  2745.         jnz     nosb2
  2746.  
  2747.         mov     eax, [img_background]
  2748.         test    ecx, ecx
  2749.         jz      @f
  2750.         cmp     eax, static_background_data
  2751.         jz      .ret
  2752. ;--------------------------------------
  2753. align 4
  2754. @@:
  2755.         mov     ebx, [mem_BACKGROUND]
  2756.         add     ebx, 4095
  2757.         and     ebx, -4096
  2758.         sub     ebx, 4
  2759.         cmp     ecx, ebx
  2760.         ja      .ret
  2761.  
  2762.         mov     ebx, [eax+ecx]
  2763.         and     ebx, 0xFF000000;255*256*256*256
  2764.         and     edx, 0x00FFFFFF;255*256*256+255*256+255
  2765.         add     edx, ebx
  2766.         mov     [eax+ecx], edx
  2767. ;--------------------------------------
  2768. align 4
  2769. .ret:
  2770.         ret
  2771. ;------------------------------------------------------------------------------
  2772. align 4
  2773. nosb2:
  2774.         cmp     ebx, 3                     ; DRAW BACKGROUND
  2775.         jnz     nosb3
  2776. ;--------------------------------------
  2777. align 4
  2778. draw_background_temp:
  2779.         mov     [background_defined], 1
  2780.         call    force_redraw_background
  2781. ;--------------------------------------
  2782. align 4
  2783. nosb31:
  2784.         ret
  2785. ;------------------------------------------------------------------------------
  2786. align 4
  2787. nosb3:
  2788.         cmp     ebx, 4                     ; TILED / STRETCHED
  2789.         jnz     nosb4
  2790.         cmp     ecx, [BgrDrawMode]
  2791.         je      nosb41
  2792.         mov     [BgrDrawMode], ecx
  2793. ;--------------------------------------
  2794. align 4
  2795. nosb41:
  2796.         ret
  2797. ;------------------------------------------------------------------------------
  2798. align 4
  2799. nosb4:
  2800.         cmp     ebx, 5                     ; BLOCK MOVE TO BGR
  2801.         jnz     nosb5
  2802.         cmp     [img_background], static_background_data
  2803.         jnz     @f
  2804.         test    edx, edx
  2805.         jnz     .fin
  2806.         cmp     esi, 4
  2807.         ja      .fin
  2808. ;--------------------------------------
  2809. align 4
  2810. @@:
  2811.   ; bughere
  2812.         mov     eax, ecx
  2813.         mov     ebx, edx
  2814.         add     ebx, [img_background];IMG_BACKGROUND
  2815.         mov     ecx, esi
  2816.         call    memmove
  2817. ;--------------------------------------
  2818. align 4
  2819. .fin:
  2820.         ret
  2821. ;------------------------------------------------------------------------------
  2822. align 4
  2823. nosb5:
  2824.         cmp     ebx, 6
  2825.         jnz     nosb6
  2826. ;--------------------------------------
  2827. align 4
  2828. ;;Maxis use atomic bts for mutex 4.4.2009
  2829. @@:
  2830.         bts     dword [bgrlock], 0
  2831.         jnc     @f
  2832.         call    change_task
  2833.         jmp     @b
  2834. ;--------------------------------------
  2835. align 4
  2836. @@:
  2837.         mov     eax, [CURRENT_TASK]
  2838.         mov     [bgrlockpid], eax
  2839.         cmp     [img_background], static_background_data
  2840.         jz      .nomem
  2841.         stdcall user_alloc, [mem_BACKGROUND]
  2842.         mov     [esp+32], eax
  2843.         test    eax, eax
  2844.         jz      .nomem
  2845.         mov     ebx, eax
  2846.         shr     ebx, 12
  2847.         or      dword [page_tabs+(ebx-1)*4], DONT_FREE_BLOCK
  2848.         mov     esi, [img_background]
  2849.         shr     esi, 12
  2850.         mov     ecx, [mem_BACKGROUND]
  2851.         add     ecx, 0xFFF
  2852.         shr     ecx, 12
  2853. ;--------------------------------------
  2854. align 4
  2855. .z:
  2856.         mov     eax, [page_tabs+ebx*4]
  2857.         test    al, 1
  2858.         jz      @f
  2859.         call    free_page
  2860. ;--------------------------------------
  2861. align 4
  2862. @@:
  2863.         mov     eax, [page_tabs+esi*4]
  2864.         or      al, PG_UWR
  2865.         mov     [page_tabs+ebx*4], eax
  2866.         mov     eax, ebx
  2867.         shl     eax, 12
  2868.         invlpg  [eax]
  2869.         inc     ebx
  2870.         inc     esi
  2871.         loop    .z
  2872.         ret
  2873. ;--------------------------------------
  2874. align 4
  2875. .nomem:
  2876.         and     [bgrlockpid], 0
  2877.         mov     [bgrlock], 0
  2878. ;------------------------------------------------------------------------------
  2879. align 4
  2880. nosb6:
  2881.         cmp     ebx, 7
  2882.         jnz     nosb7
  2883.         cmp     [bgrlock], 0
  2884.         jz      .err
  2885.         mov     eax, [CURRENT_TASK]
  2886.         cmp     [bgrlockpid], eax
  2887.         jnz     .err