Subversion Repositories Kolibri OS

Rev

Rev 5596 | Rev 5645 | Go to most recent revision | Blame | Compare with Previous | Last modification | View Log | Download | RSS feed

  1. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  2. ;;
  3. ;; Copyright (C) KolibriOS team 2004-2015. All rights reserved.
  4. ;; PROGRAMMING:
  5. ;; Ivan Poddubny
  6. ;; Marat Zakiyanov (Mario79)
  7. ;; VaStaNi
  8. ;; Trans
  9. ;; Mihail Semenyako (mike.dld)
  10. ;; Sergey Kuzmin (Wildwest)
  11. ;; Andrey Halyavin (halyavin)
  12. ;; Mihail Lisovin (Mihasik)
  13. ;; Andrey Ignatiev (andrew_programmer)
  14. ;; NoName
  15. ;; Evgeny Grechnikov (Diamond)
  16. ;; Iliya Mihailov (Ghost)
  17. ;; Sergey Semyonov (Serge)
  18. ;; Johnny_B
  19. ;; SPraid (simba)
  20. ;; Hidnplayr
  21. ;; Alexey Teplov (<Lrz>)
  22. ;; Rus
  23. ;; Nable
  24. ;; shurf
  25. ;; Alver
  26. ;; Maxis
  27. ;; Galkov
  28. ;; CleverMouse
  29. ;; tsdima
  30. ;; turbanoff
  31. ;; Asper
  32. ;; art_zh
  33. ;;
  34. ;; Data in this file was originally part of MenuetOS project which is
  35. ;; distributed under the terms of GNU GPL. It is modified and redistributed as
  36. ;; part of KolibriOS project under the terms of GNU GPL.
  37. ;;
  38. ;; Copyright (C) MenuetOS 2000-2004 Ville Mikael Turjanmaa
  39. ;; PROGRAMMING:
  40. ;;
  41. ;; Ville Mikael Turjanmaa, villemt@itu.jyu.fi
  42. ;; - main os coding/design
  43. ;; Jan-Michael Brummer, BUZZ2@gmx.de
  44. ;; Felix Kaiser, info@felix-kaiser.de
  45. ;; Paolo Minazzi, paolo.minazzi@inwind.it
  46. ;; quickcode@mail.ru
  47. ;; Alexey, kgaz@crosswinds.net
  48. ;; Juan M. Caravaca, bitrider@wanadoo.es
  49. ;; kristol@nic.fi
  50. ;; Mike Hibbett, mikeh@oceanfree.net
  51. ;; Lasse Kuusijarvi, kuusijar@lut.fi
  52. ;; Jarek Pelczar, jarekp3@wp.pl
  53. ;;
  54. ;; KolibriOS is distributed in the hope that it will be useful, but WITHOUT ANY
  55. ;; WARRANTY. No author or distributor accepts responsibility to anyone for the
  56. ;; consequences of using it or for whether it serves any particular purpose or
  57. ;; works at all, unless he says so in writing. Refer to the GNU General Public
  58. ;; License (the "GPL") for full details.
  59. ;
  60. ;; Everyone is granted permission to copy, modify and redistribute KolibriOS,
  61. ;; but only under the conditions described in the GPL. A copy of this license
  62. ;; is supposed to have been given to you along with KolibriOS so you can know
  63. ;; your rights and responsibilities. It should be in a file named COPYING.
  64. ;; Among other things, the copyright notice and this notice must be preserved
  65. ;; on all copies.
  66. ;;
  67. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  68.  
  69. format binary as "mnt"
  70.  
  71. include 'macros.inc'
  72. include 'struct.inc'
  73.  
  74. $Revision: 5629 $
  75.  
  76.  
  77. USE_COM_IRQ     equ 1      ; make irq 3 and irq 4 available for PCI devices
  78. VESA_1_2_VIDEO equ 0      ; enable vesa 1.2 bank switch functions
  79.  
  80. ; Enabling the next line will enable serial output console
  81. ;debug_com_base  equ 0x3f8  ; 0x3f8 is com1, 0x2f8 is com2, 0x3e8 is com3, 0x2e8 is com4, no irq's are used
  82.  
  83. include "proc32.inc"
  84. include "kglobals.inc"
  85. include "lang.inc"
  86. include "encoding.inc"
  87.  
  88. include "const.inc"
  89.  
  90. iglobal
  91. ; The following variable, if equal to 1, duplicates debug output to the screen.
  92. debug_direct_print db 0
  93. ; Start the first app (LAUNCHER) after kernel is loaded? (1=yes, 2 or 0=no)
  94. launcher_start db 1
  95. endg
  96.  
  97. max_processes   equ   255
  98. tss_step         equ   (128+8192) ; tss & i/o - 65535 ports, * 256=557056*4
  99.  
  100. os_stack       equ  (os_data_l-gdts)    ; GDTs
  101. os_code       equ  (os_code_l-gdts)
  102. graph_data     equ  (3+graph_data_l-gdts)
  103. tss0           equ  (tss0_l-gdts)
  104. app_code       equ  (3+app_code_l-gdts)
  105. app_data       equ  (3+app_data_l-gdts)
  106. app_tls       equ  (3+tls_data_l-gdts)
  107. pci_code_sel   equ  (pci_code_32-gdts)
  108. pci_data_sel   equ  (pci_data_32-gdts)
  109.  
  110.  
  111. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  112. ;;
  113. ;;   Included files:
  114. ;;
  115. ;;   Kernel16.inc
  116. ;;    - Booteng.inc   English text for bootup
  117. ;;    - Bootcode.inc  Hardware setup
  118. ;;    - Pci16.inc     PCI functions
  119. ;;
  120. ;;   Kernel32.inc
  121. ;;    - Sys32.inc     Process management
  122. ;;    - Shutdown.inc  Shutdown and restart
  123. ;;    - Fat32.inc     Read / write hd
  124. ;;    - Vesa12.inc    Vesa 1.2 driver
  125. ;;    - Vesa20.inc    Vesa 2.0 driver
  126. ;;    - Vga.inc       VGA driver
  127. ;;    - Stack.inc     Network interface
  128. ;;    - Mouse.inc     Mouse pointer
  129. ;;    - Scincode.inc  Window skinning
  130. ;;    - Pci32.inc     PCI functions
  131. ;;
  132. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  133.  
  134.  
  135. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  136. ;;                                                                      ;;
  137. ;;                  16 BIT ENTRY FROM BOOTSECTOR                        ;;
  138. ;;                                                                      ;;
  139. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  140.  
  141. use16
  142.                   org   0x0
  143.         jmp     start_of_code
  144.  
  145. if lang eq sp
  146. include "kernelsp.inc"  ; spanish kernel messages
  147. else if lang eq et
  148. version db    'Kolibri OS  versioon 0.7.7.0+    ',13,10,13,10,0
  149. else
  150. version db    'Kolibri OS  version 0.7.7.0+     ',13,10,13,10,0
  151. end if
  152.  
  153. include "boot/bootstr.inc"     ; language-independent boot messages
  154. include "boot/preboot.inc"
  155.  
  156. if lang eq ge
  157. include "boot/bootge.inc"     ; german system boot messages
  158. else if lang eq sp
  159. include "boot/bootsp.inc"     ; spanish system boot messages
  160. else if lang eq ru
  161. include "boot/bootru.inc"      ; russian system boot messages
  162. include "boot/ru.inc"          ; Russian font
  163. else if lang eq et
  164. include "boot/bootet.inc"      ; estonian system boot messages
  165. include "boot/et.inc"          ; Estonian font
  166. else
  167. include "boot/booten.inc"      ; english system boot messages
  168. end if
  169.  
  170. include "boot/bootcode.inc"    ; 16 bit system boot code
  171. include "bus/pci/pci16.inc"
  172. include "detect/biosdisk.inc"
  173.  
  174. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  175. ;;                                                                      ;;
  176. ;;                  SWITCH TO 32 BIT PROTECTED MODE                     ;;
  177. ;;                                                                      ;;
  178. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  179.  
  180.  
  181. ; CR0 Flags - Protected mode and Paging
  182.  
  183.         mov     ecx, CR0_PE
  184.  
  185. ; Enabling 32 bit protected mode
  186.  
  187.         sidt    [cs:old_ints_h]
  188.  
  189.         cli                             ; disable all irqs
  190.         cld
  191.         mov     al, 255                 ; mask all irqs
  192.         out     0xa1, al
  193.         out     0x21, al
  194.    l.5:
  195.         in      al, 0x64                ; Enable A20
  196.         test    al, 2
  197.         jnz     l.5
  198.         mov     al, 0xD1
  199.         out     0x64, al
  200.    l.6:
  201.         in      al, 0x64
  202.         test    al, 2
  203.         jnz     l.6
  204.         mov     al, 0xDF
  205.         out     0x60, al
  206.    l.7:
  207.         in      al, 0x64
  208.         test    al, 2
  209.         jnz     l.7
  210.         mov     al, 0xFF
  211.         out     0x64, al
  212.  
  213.         lgdt    [cs:tmp_gdt]            ; Load GDT
  214.         mov     eax, cr0                ; protected mode
  215.         or      eax, ecx
  216.         and     eax, 10011111b *65536*256 + 0xffffff ; caching enabled
  217.         mov     cr0, eax
  218.         jmp     pword os_code:B32       ; jmp to enable 32 bit mode
  219.  
  220. align 8
  221. tmp_gdt:
  222.  
  223.         dw     23
  224.         dd     tmp_gdt+0x10000
  225.         dw     0
  226.  
  227.         dw     0xffff
  228.         dw     0x0000
  229.         db     0x00
  230.         dw     11011111b *256 +10011010b
  231.         db     0x00
  232.  
  233.         dw     0xffff
  234.         dw     0x0000
  235.         db     0x00
  236.         dw     11011111b *256 +10010010b
  237.         db     0x00
  238.  
  239. include "data16.inc"
  240.  
  241. if ~ lang eq sp
  242. diff16 "end of bootcode",0,$+0x10000
  243. end if
  244.  
  245. use32
  246. org $+0x10000
  247.  
  248. align 4
  249. B32:
  250.         mov     ax, os_stack       ; Selector for os
  251.         mov     ds, ax
  252.         mov     es, ax
  253.         mov     fs, ax
  254.         mov     gs, ax
  255.         mov     ss, ax
  256.         mov     esp, 0x006CC00       ; Set stack
  257.  
  258. ; CLEAR 0x280000 - HEAP_BASE
  259.  
  260.         xor     eax, eax
  261.         mov     edi, CLEAN_ZONE
  262.         mov     ecx, (HEAP_BASE-OS_BASE-CLEAN_ZONE) / 4
  263.         cld
  264.         rep stosd
  265.  
  266. ; CLEAR KERNEL UNDEFINED GLOBALS
  267.         mov     edi, endofcode-OS_BASE
  268.         mov     ecx, 0x90000
  269.         sub     ecx, edi
  270.         shr     ecx, 2
  271.         rep stosd
  272.  
  273. ; SAVE & CLEAR 0-0xffff
  274.  
  275.         mov     edi, 0x1000
  276.         mov     ecx, 0x8000 / 4
  277.         rep stosd
  278.         mov     edi, 0xa000
  279.         mov     ecx, 0x6000 / 4
  280.         rep stosd
  281.  
  282.         call    test_cpu
  283.         bts     [cpu_caps-OS_BASE], CAPS_TSC    ;force use rdtsc
  284.  
  285.         call    check_acpi
  286.         call    init_hpet
  287.         call    init_BIOS32
  288. ; MEMORY MODEL
  289.         call    mem_test
  290.         call    init_mem
  291.         call    init_page_map
  292.  
  293. ; ENABLE PAGING
  294.  
  295.         mov     eax, sys_proc-OS_BASE+PROC.pdt_0
  296.         mov     cr3, eax
  297.  
  298.         mov     eax, cr0
  299.         or      eax, CR0_PG+CR0_WP
  300.         mov     cr0, eax
  301.  
  302.         lgdt    [gdts]
  303.         jmp     pword os_code:high_code
  304.  
  305. align 4
  306. bios32_entry    dd ?
  307. tmp_page_tabs   dd ?
  308.  
  309. use16
  310. org $-0x10000
  311. include "boot/shutdown.inc" ; shutdown or restart
  312. org $+0x10000
  313.  
  314. ap_init16:
  315.         cli
  316.         lgdt    [cs:gdts_ap-ap_init16]
  317.         mov     eax, [cs:cr3_ap-ap_init16]
  318.         mov     cr3, eax
  319.         mov     eax, [cs:cr4_ap-ap_init16]
  320.         mov     cr4, eax
  321.         mov     eax, CR0_PE+CR0_PG+CR0_WP
  322.         mov     cr0, eax
  323.         jmp     pword os_code:ap_init_high
  324. align 16
  325. gdts_ap:
  326.         dw     gdte-gdts-1
  327.         dd     gdts
  328.         dw     0
  329. cr3_ap  dd     ?
  330. cr4_ap  dd     ?
  331. ap_init16_size = $ - ap_init16
  332. use32
  333.  
  334. __DEBUG__ fix 1
  335. __DEBUG_LEVEL__ fix 1
  336. include 'init.inc'
  337.  
  338. org OS_BASE+$
  339.  
  340. include 'fdo.inc'
  341.  
  342. align 4
  343. high_code:
  344.         mov     ax, os_stack
  345.         mov     bx, app_data
  346.         mov     cx, app_tls
  347.         mov     ss, ax
  348.         add     esp, OS_BASE
  349.  
  350.         mov     ds, bx
  351.         mov     es, bx
  352.         mov     fs, cx
  353.         mov     gs, bx
  354.  
  355.         xor     eax, eax
  356.         mov     ebx, 0xFFFFF000+PG_SHARED+PG_NOCACHE+PG_UWR
  357.         bt      [cpu_caps], CAPS_PAT
  358.         setc    al
  359.         shl     eax, 7
  360.         or      ebx, eax
  361.  
  362.         mov     eax, PG_GLOBAL
  363.         bt      [cpu_caps], CAPS_PGE
  364.         jnc     @F
  365.  
  366.         or      [sys_proc+PROC.pdt_0+(OS_BASE shr 20)], eax
  367.         or      ebx, eax
  368.  
  369.         mov     eax, cr4
  370.         or      eax, CR4_PGE
  371.         mov     cr4, eax
  372. @@:
  373.         mov     [pte_valid_mask], ebx
  374.  
  375.         xor     eax, eax
  376.         mov     dword [sys_proc+PROC.pdt_0], eax
  377.         mov     dword [sys_proc+PROC.pdt_0+4], eax
  378.  
  379.         mov     eax, cr3
  380.         mov     cr3, eax          ; flush TLB
  381.  
  382.         mov     ecx, pg_data.mutex
  383.         call    mutex_init
  384.  
  385.         mov     ecx, disk_list_mutex
  386.         call    mutex_init
  387.  
  388.         mov     ecx, keyboard_list_mutex
  389.         call    mutex_init
  390.  
  391.         mov     ecx, unpack_mutex
  392.         call    mutex_init
  393.  
  394.         mov     ecx, application_table_mutex
  395.         call    mutex_init
  396.  
  397.         mov     ecx, ide_mutex
  398.         call    mutex_init
  399.         mov     ecx, ide_channel1_mutex
  400.         call    mutex_init
  401.         mov     ecx, ide_channel2_mutex
  402.         call    mutex_init
  403.         mov     ecx, ide_channel3_mutex
  404.         call    mutex_init
  405.         mov     ecx, ide_channel4_mutex
  406.         call    mutex_init
  407.         mov     ecx, ide_channel5_mutex
  408.         call    mutex_init
  409.         mov     ecx, ide_channel6_mutex
  410.         call    mutex_init
  411. ;-----------------------------------------------------------------------------
  412. ; SAVE REAL MODE VARIABLES
  413. ;-----------------------------------------------------------------------------
  414. ; --------------- APM ---------------------
  415.  
  416. ; init selectors
  417.         mov     ebx, [BOOT_VARS+BOOT_APM_ENTRY]        ; offset of APM entry point
  418.         movzx   eax, word [BOOT_VARS+BOOT_APM_CODE_32] ; real-mode segment base address of
  419.                                                                                 ; protected-mode 32-bit code segment
  420.         movzx   ecx, word [BOOT_VARS+BOOT_APM_CODE_16]; real-mode segment base address of
  421.                                                                                 ; protected-mode 16-bit code segment
  422.         movzx   edx, word [BOOT_VARS+BOOT_APM_DATA_16]; real-mode segment base address of
  423.                                                                                 ; protected-mode 16-bit data segment
  424.  
  425.         shl     eax, 4
  426.         mov     [dword apm_code_32 + 2], ax
  427.         shr     eax, 16
  428.         mov     [dword apm_code_32 + 4], al
  429.  
  430.         shl     ecx, 4
  431.         mov     [dword apm_code_16 + 2], cx
  432.         shr     ecx, 16
  433.         mov     [dword apm_code_16 + 4], cl
  434.  
  435.         shl     edx, 4
  436.         mov     [dword apm_data_16 + 2], dx
  437.         shr     edx, 16
  438.         mov     [dword apm_data_16 + 4], dl
  439.  
  440.         mov     dword[apm_entry], ebx
  441.         mov     word [apm_entry + 4], apm_code_32 - gdts
  442.  
  443.         mov     eax, [BOOT_VARS + BOOT_APM_VERSION] ; version & flags
  444.         mov     [apm_vf], eax
  445. ; -----------------------------------------
  446.         mov     al, [BOOT_VARS+BOOT_DMA]            ; DMA access
  447.         mov     [allow_dma_access], al
  448.         movzx   eax, byte [BOOT_VARS+BOOT_BPP]      ; bpp
  449.         mov     [_display.bits_per_pixel], eax
  450.         mov     [_display.vrefresh], 60
  451.         mov     al, [BOOT_VARS+BOOT_DEBUG_PRINT]    ; If nonzero, duplicates debug output to the screen
  452.         mov     [debug_direct_print], al
  453.         mov     al, [BOOT_VARS+BOOT_LAUNCHER_START] ; Start the first app (LAUNCHER) after kernel is loaded?
  454.         mov     [launcher_start], al
  455.         movzx   eax, word [BOOT_VARS+BOOT_X_RES]; X max
  456.         mov     [_display.width], eax
  457.         mov     [display_width_standard], eax
  458.         dec     eax
  459.         mov     [screen_workarea.right], eax
  460.         movzx   eax, word [BOOT_VARS+BOOT_Y_RES]; Y max
  461.         mov     [_display.height], eax
  462.         mov     [display_height_standard], eax
  463.         dec     eax
  464.         mov     [screen_workarea.bottom], eax
  465.         movzx   eax, word [BOOT_VARS+BOOT_VESA_MODE] ; screen mode
  466.         mov     dword [SCR_MODE], eax
  467. ;        mov     eax, [BOOT_VAR+0x9014]             ; Vesa 1.2 bnk sw add
  468. ;        mov     [BANK_SWITCH], eax
  469.         mov     eax, 640 *4                         ; Bytes PerScanLine
  470.         cmp     [SCR_MODE], word 0x13               ; 320x200
  471.         je      @f
  472.         cmp     [SCR_MODE], word 0x12               ; VGA 640x480
  473.         je      @f
  474.         movzx   eax, word[BOOT_VARS+BOOT_PITCH]      ; for other modes
  475. @@:
  476.         mov     [_display.lfb_pitch], eax
  477.         mov     eax, [_display.width]
  478.         mul     [_display.height]
  479.         mov     [_display.win_map_size], eax
  480.  
  481.         call    calculate_fast_getting_offset_for_WinMapAddress
  482. ; for Qemu or non standart video cards
  483. ; Unfortunately [BytesPerScanLine] does not always
  484. ;                             equal to [_display.width] * [ScreenBPP] / 8
  485.         call    calculate_fast_getting_offset_for_LFB
  486.  
  487.         mov     esi, BOOT_VARS+0x9080
  488.         movzx   ecx, byte [esi-1]
  489.         mov     [NumBiosDisks], ecx
  490.         mov     edi, BiosDisksData
  491.         rep movsd
  492.  
  493. setvideomode:
  494.  
  495.         mov     eax, [BOOT_VARS+BOOT_LFB]
  496.         mov     [LFBAddress], eax
  497.  
  498.         cmp     word [SCR_MODE], 0x0012                 ; VGA (640x480 16 colors)
  499.         je      .vga
  500.         cmp     word [SCR_MODE], 0x0013                 ; MCGA (320*200 256 colors)
  501.         je      .32bpp
  502.         cmp     byte [_display.bits_per_pixel], 32
  503.         je      .32bpp
  504.         cmp     byte [_display.bits_per_pixel], 24
  505.         je      .24bpp
  506.         cmp     byte [_display.bits_per_pixel], 16
  507.         je      .16bpp
  508. ;        cmp     byte [_display.bits_per_pixel], 15
  509. ;        je      .15bpp
  510.  
  511.   .vga:
  512.         mov     [PUTPIXEL], VGA_putpixel
  513.         mov     [GETPIXEL], Vesa20_getpixel32           ; Conversion buffer is 32 bpp
  514.         mov     [_display.bytes_per_pixel], 4           ; Conversion buffer is 32 bpp
  515.         jmp     .finish
  516.  
  517. ;  .15bpp:
  518. ;        mov     [PUTPIXEL], Vesa20_putpixel15
  519. ;        mov     [GETPIXEL], Vesa20_getpixel15
  520. ;        mov     [_display.bytes_per_pixel], 2
  521. ;        jmp     .finish
  522.  
  523.   .16bpp:
  524.         mov     [PUTPIXEL], Vesa20_putpixel16
  525.         mov     [GETPIXEL], Vesa20_getpixel16
  526.         mov     [_display.bytes_per_pixel], 2
  527.         jmp     .finish
  528.  
  529.   .24bpp:
  530.         mov     [PUTPIXEL], Vesa20_putpixel24
  531.         mov     [GETPIXEL], Vesa20_getpixel24
  532.         mov     [_display.bytes_per_pixel], 3
  533.         jmp     .finish
  534.  
  535.   .32bpp:
  536.         mov     [PUTPIXEL], Vesa20_putpixel32
  537.         mov     [GETPIXEL], Vesa20_getpixel32
  538.         mov     [_display.bytes_per_pixel], 4
  539. ;        jmp     .finish
  540.  
  541.   .finish:
  542.         mov     [MOUSE_PICTURE], mousepointer
  543.         mov     [_display.check_mouse], check_mouse_area_for_putpixel
  544.         mov     [_display.check_m_pixel], check_mouse_area_for_getpixel
  545.  
  546. ; -------- Fast System Call init ----------
  547. ; Intel SYSENTER/SYSEXIT (AMD CPU support it too)
  548.         bt      [cpu_caps], CAPS_SEP
  549.         jnc     .SEnP  ; SysEnter not Present
  550.         xor     edx, edx
  551.         mov     ecx, MSR_SYSENTER_CS
  552.         mov     eax, os_code
  553.         wrmsr
  554.         mov     ecx, MSR_SYSENTER_ESP
  555. ;           mov eax, sysenter_stack ; Check it
  556.         xor     eax, eax
  557.         wrmsr
  558.         mov     ecx, MSR_SYSENTER_EIP
  559.         mov     eax, sysenter_entry
  560.         wrmsr
  561. .SEnP:
  562. ; AMD SYSCALL/SYSRET
  563.         cmp     byte[cpu_vendor], 'A'
  564.         jne     .noSYSCALL
  565.         mov     eax, 0x80000001
  566.         cpuid
  567.         test    edx, 0x800  ; bit_11 - SYSCALL/SYSRET support
  568.         jz      .noSYSCALL
  569.         mov     ecx, MSR_AMD_EFER
  570.         rdmsr
  571.         or      eax, 1 ; bit_0 - System Call Extension (SCE)
  572.         wrmsr
  573.  
  574.         ; !!!! It`s dirty hack, fix it !!!
  575.         ; Bits of EDX :
  576.         ; Bit 31–16 During the SYSRET instruction, this field is copied into the CS register
  577.         ;  and the contents of this field, plus 8, are copied into the SS register.
  578.         ; Bit 15–0 During the SYSCALL instruction, this field is copied into the CS register
  579.         ;  and the contents of this field, plus 8, are copied into the SS register.
  580.  
  581.         ; mov   edx, (os_code + 16) * 65536 + os_code
  582.         mov     edx, 0x1B0008
  583.  
  584.         mov     eax, syscall_entry
  585.         mov     ecx, MSR_AMD_STAR
  586.         wrmsr
  587. .noSYSCALL:
  588. ; -----------------------------------------
  589.         stdcall alloc_page
  590.         stdcall map_page, tss-0xF80, eax, PG_SWR
  591.         stdcall alloc_page
  592.         stdcall map_page, tss+0x80, eax, PG_SWR
  593.         stdcall alloc_page
  594.         stdcall map_page, tss+0x1080, eax, PG_SWR
  595.  
  596. ; LOAD IDT
  597.  
  598.         call    build_interrupt_table ;lidt is executed
  599.           ;lidt [idtreg]
  600.  
  601.         call    init_kernel_heap
  602.         stdcall kernel_alloc, (RING0_STACK_SIZE+512) * 2
  603.         mov     [os_stack_seg], eax
  604.  
  605.         lea     esp, [eax+RING0_STACK_SIZE]
  606.  
  607.         mov     [tss._ss0], os_stack
  608.         mov     [tss._esp0], esp
  609.         mov     [tss._esp], esp
  610.         mov     [tss._cs], os_code
  611.         mov     [tss._ss], os_stack
  612.         mov     [tss._ds], app_data
  613.         mov     [tss._es], app_data
  614.         mov     [tss._fs], app_data
  615.         mov     [tss._gs], app_data
  616.         mov     [tss._io], 128
  617. ;Add IO access table - bit array of permitted ports
  618.         mov     edi, tss._io_map_0
  619.         xor     eax, eax
  620.         not     eax
  621.         mov     ecx, 8192/4
  622.         rep stosd                    ; access to 4096*8=65536 ports
  623.  
  624.         mov     ax, tss0
  625.         ltr     ax
  626.  
  627.         mov     [LFBSize], 0xC00000
  628.         call    init_LFB
  629.         call    init_fpu
  630.         call    init_malloc
  631.  
  632.         stdcall alloc_kernel_space, 0x50000         ; FIXME check size
  633.         mov     [default_io_map], eax
  634.  
  635.         add     eax, 0x2000
  636.         mov     [ipc_tmp], eax
  637.         mov     ebx, 0x1000
  638.  
  639.         add     eax, 0x40000
  640.         mov     [proc_mem_map], eax
  641.  
  642.         add     eax, 0x8000
  643.         mov     [proc_mem_pdir], eax
  644.  
  645.         add     eax, ebx
  646.         mov     [proc_mem_tab], eax
  647.  
  648.         add     eax, ebx
  649.         mov     [tmp_task_ptab], eax
  650.  
  651.         add     eax, ebx
  652.         mov     [ipc_pdir], eax
  653.  
  654.         add     eax, ebx
  655.         mov     [ipc_ptab], eax
  656.  
  657.         stdcall kernel_alloc, (unpack.LZMA_BASE_SIZE+(unpack.LZMA_LIT_SIZE shl \
  658.                 (unpack.lc+unpack.lp)))*4
  659.  
  660.         mov     [unpack.p], eax
  661.  
  662.         call    init_events
  663.         mov     eax, srv.fd-SRV.fd
  664.         mov     [srv.fd], eax
  665.         mov     [srv.bk], eax
  666.  
  667. ;Set base of graphic segment to linear address of LFB
  668.         mov     eax, [LFBAddress]         ; set for gs
  669.         mov     [graph_data_l+2], ax
  670.         shr     eax, 16
  671.         mov     [graph_data_l+4], al
  672.         mov     [graph_data_l+7], ah
  673.  
  674.         stdcall kernel_alloc, [_display.win_map_size]
  675.         mov     [_display.win_map], eax
  676.  
  677.         xor     eax, eax
  678.         inc     eax
  679.  
  680. ; set background
  681.  
  682.         mov     [BgrDrawMode], eax
  683.         mov     [BgrDataWidth], eax
  684.         mov     [BgrDataHeight], eax
  685.         mov     [mem_BACKGROUND], 4
  686.         mov     [img_background], static_background_data
  687.  
  688. ; set clipboard
  689.  
  690.         xor     eax, eax
  691.         mov     [clipboard_slots], eax
  692.         mov     [clipboard_write_lock], eax
  693.         stdcall kernel_alloc, 4096
  694.         test    eax, eax
  695.         jnz     @f
  696.  
  697.         dec     eax
  698. @@:
  699.         mov     [clipboard_main_list], eax
  700.  
  701.         mov eax, [acpi_hpet_base]
  702.         DEBUGF  1, "K : ACPI HPET base %x\n", eax
  703.         mov eax, [hpet_base]
  704.         DEBUGF  1, "K : HPET base %x\n", eax
  705.         mov eax, [hpet_period]
  706.         DEBUGF  1, "K : HPET period %d\n", eax
  707.  
  708.         mov     eax, [hpet_base]
  709.         stdcall map_io_mem, [hpet_base], 1024, PG_GLOBAL+PAT_UC+PG_SWR
  710.         mov     [hpet_base], eax
  711.  
  712. ; SET UP OS TASK
  713.  
  714.         mov     esi, boot_setostask
  715.         call    boot_log
  716.  
  717.         mov     eax, sys_proc
  718.         lea     edi, [eax+PROC.heap_lock]
  719.         mov     ecx, (PROC.ht_free-PROC.heap_lock)/4
  720.  
  721.         list_init eax
  722.         add     eax, PROC.thr_list
  723.         list_init eax
  724.  
  725.         xor     eax, eax
  726.         cld
  727.         rep stosd
  728.  
  729.         mov     [edi], dword (PROC.pdt_0 - PROC.htab)/4 - 3
  730.         mov     [edi+4], dword 3           ;reserve handles for stdin stdout and stderr
  731.         mov     ecx, (PROC.pdt_0 - PROC.htab)/4
  732.         add     edi, 8
  733.         inc     eax
  734. @@:
  735.         stosd
  736.         inc     eax
  737.         cmp     eax, ecx
  738.         jbe     @B
  739.  
  740.         mov     [sys_proc+PROC.pdt_0_phys], sys_proc-OS_BASE+PROC.pdt_0
  741.  
  742.         mov     eax, -1
  743.         mov     edi, thr_slot_map+4
  744.         mov     [edi-4], dword 0xFFFFFFF8
  745.         stosd
  746.         stosd
  747.         stosd
  748.         stosd
  749.         stosd
  750.         stosd
  751.         stosd
  752.  
  753.         mov     [current_process], sys_proc
  754.  
  755.         mov     edx, SLOT_BASE+256*1
  756.         mov     ebx, [os_stack_seg]
  757.         add     ebx, 0x2000
  758.         call    setup_os_slot
  759.         mov     dword [edx], 'IDLE'
  760.         sub     [edx+APPDATA.saved_esp], 4
  761.         mov     eax, [edx+APPDATA.saved_esp]
  762.         mov     dword [eax], idle_thread
  763.         mov     ecx, IDLE_PRIORITY
  764.         call    scheduler_add_thread
  765.  
  766.         mov     edx, SLOT_BASE+256*2
  767.         mov     ebx, [os_stack_seg]
  768.         call    setup_os_slot
  769.         mov     dword [edx], 'OS'
  770.         xor     ecx, ecx
  771.         call    scheduler_add_thread
  772.  
  773.         mov     dword [CURRENT_TASK], 2
  774.         mov     dword [TASK_COUNT], 2
  775.         mov     dword [current_slot], SLOT_BASE + 256*2
  776.         mov     dword [TASK_BASE], CURRENT_TASK + 32*2
  777.  
  778. ; Move other CPUs to deep sleep, if it is useful
  779. uglobal
  780. use_mwait_for_idle db 0
  781. endg
  782.         cmp     [cpu_vendor+8], 'ntel'
  783.         jnz     .no_wake_cpus
  784.         bt      [cpu_caps+4], CAPS_MONITOR-32
  785.         jnc     .no_wake_cpus
  786.         dbgstr 'using mwait for idle loop'
  787.         inc     [use_mwait_for_idle]
  788.         mov     ebx, [cpu_count]
  789.         cmp     ebx, 1
  790.         jbe     .no_wake_cpus
  791.         call    create_trampoline_pgmap
  792.         mov     [cr3_ap+OS_BASE], eax
  793.         mov     eax, cr4
  794.         mov     [cr4_ap+OS_BASE], eax
  795.         mov     esi, OS_BASE + ap_init16
  796.         mov     edi, OS_BASE + 8000h
  797.         mov     ecx, (ap_init16_size + 3) / 4
  798.         rep movsd
  799.         stdcall map_io_mem, [acpi_lapic_base], 0x1000, PG_GLOBAL+PG_NOCACHE+PG_SWR
  800.         mov     [LAPIC_BASE], eax
  801.         lea     edi, [eax+300h]
  802.         mov     esi, smpt+4
  803.         dec     ebx
  804. .wake_cpus_loop:
  805.         lodsd
  806.         push    esi
  807.         xor     esi, esi
  808.         inc     esi
  809.         shl     eax, 24
  810.         mov     [edi+10h], eax
  811. ; assert INIT IPI
  812.         mov     dword [edi], 0C500h
  813.         call    delay_ms
  814. @@:
  815.         test    dword [edi], 1000h
  816.         jnz     @b
  817. ; deassert INIT IPI
  818.         mov     dword [edi], 8500h
  819.         call    delay_ms
  820. @@:
  821.         test    dword [edi], 1000h
  822.         jnz     @b
  823. ; send STARTUP IPI
  824.         mov     dword [edi], 600h + (8000h shr 12)
  825.         call    delay_ms
  826. @@:
  827.         test    dword [edi], 1000h
  828.         jnz     @b
  829.         pop     esi
  830.         dec     ebx
  831.         jnz     .wake_cpus_loop
  832.         mov     eax, [cpu_count]
  833.         dec     eax
  834. @@:
  835.         cmp     [ap_initialized], eax
  836.         jnz     @b
  837.         mov     eax, [cr3_ap+OS_BASE]
  838.         call    free_page
  839. .no_wake_cpus:
  840.  
  841. ; REDIRECT ALL IRQ'S TO INT'S 0x20-0x2f
  842.         mov     esi, boot_initirq
  843.         call    boot_log
  844.         call    init_irqs
  845.  
  846.         mov     esi, boot_picinit
  847.         call    boot_log
  848.         call    PIC_init
  849.  
  850.         mov     esi, boot_v86machine
  851.         call    boot_log
  852. ; Initialize system V86 machine
  853.         call    init_sys_v86
  854.  
  855.         mov     esi, boot_inittimer
  856.         call    boot_log
  857. ; Initialize system timer (IRQ0)
  858.         call    PIT_init
  859.  
  860. ; Register ramdisk file system
  861.         cmp     [boot_dev+OS_BASE+0x10000], 1
  862.         je      @f
  863.  
  864.         call    register_ramdisk
  865. ;--------------------------------------
  866. @@:
  867.         mov     esi, boot_initapic
  868.         call    boot_log
  869. ; Try to Initialize APIC
  870.         call    APIC_init
  871.  
  872.         mov     esi, boot_enableirq
  873.         call    boot_log
  874. ; Enable timer IRQ (IRQ0) and co-processor IRQ (IRQ13)
  875. ; they are used: when partitions are scanned, hd_read relies on timer
  876.         call    unmask_timer
  877.         stdcall enable_irq, 2               ; @#$%! PIC
  878.         stdcall enable_irq, 13              ; co-processor
  879.  
  880. ; Setup serial output console (if enabled)
  881. if defined debug_com_base
  882.  
  883.         ; reserve port so nobody else will use it
  884.         xor     ebx, ebx
  885.         mov     ecx, debug_com_base
  886.         mov     edx, debug_com_base+7
  887.         call    r_f_port_area
  888.  
  889.         ; enable Divisor latch
  890.         mov     dx, debug_com_base+3
  891.         mov     al, 1 shl 7
  892.         out     dx, al
  893.  
  894.         ; Set speed to 115200 baud (max speed)
  895.         mov     dx, debug_com_base
  896.         mov     al, 0x01
  897.         out     dx, al
  898.  
  899.         mov     dx, debug_com_base+1
  900.         mov     al, 0x00
  901.         out     dx, al
  902.  
  903.         ; No parity, 8bits words, one stop bit, dlab bit back to 0
  904.         mov     dx, debug_com_base+3
  905.         mov     al, 3
  906.         out     dx, al
  907.  
  908.         ; disable interrupts
  909.         mov     dx, debug_com_base+1
  910.         mov     al, 0
  911.         out     dx, al
  912.  
  913.         ; clear +  enable fifo (64 bits)
  914.         mov     dx, debug_com_base+2
  915.         mov     al, 0x7 + 1 shl 5
  916.         out     dx, al
  917.  
  918. end if
  919.  
  920.  
  921. ;-----------------------------------------------------------------------------
  922. ; show SVN version of kernel on the message board
  923. ;-----------------------------------------------------------------------------
  924.         mov     eax, [version_inf.rev]
  925.         DEBUGF  1, "K : kernel SVN r%d\n", eax
  926. ;-----------------------------------------------------------------------------
  927. ; show CPU count on the message board
  928. ;-----------------------------------------------------------------------------
  929.         mov     eax, [cpu_count]
  930.         test    eax, eax
  931.         jnz     @F
  932.         mov     al, 1                             ; at least one CPU
  933. @@:
  934.         DEBUGF  1, "K : %d CPU detected\n", eax
  935. ;-----------------------------------------------------------------------------
  936. ; detect Floppy drives
  937. ;-----------------------------------------------------------------------------
  938.         mov     esi, boot_detectfloppy
  939.         call    boot_log
  940. include 'detect/dev_fd.inc'
  941. ;-----------------------------------------------------------------------------
  942. ; create pci-devices list
  943. ;-----------------------------------------------------------------------------
  944.         mov     [pci_access_enabled], 1
  945.         call    pci_enum
  946. ;-----------------------------------------------------------------------------
  947. ; initialisation IDE ATA code
  948. ;-----------------------------------------------------------------------------
  949. include 'detect/init_ata.inc'
  950. ;-----------------------------------------------------------------------------
  951. if 0
  952.         mov     ax, [OS_BASE+0x10000+bx_from_load]
  953.         cmp     ax, 'r1'; if using not ram disk, then load librares and parameters {SPraid.simba}
  954.         je      no_lib_load
  955.  
  956.         mov     esi, boot_loadlibs
  957.         call    boot_log
  958. ; LOADING LIBRARES
  959.         stdcall dll.Load, @IMPORT           ; loading librares for kernel (.obj files)
  960.         call    load_file_parse_table       ; prepare file parse table
  961.         call    set_kernel_conf             ; configure devices and gui
  962. no_lib_load:
  963. end if
  964.  
  965. ; Display APIC status
  966.         mov     esi, boot_APIC_found
  967.         cmp     [irq_mode], IRQ_APIC
  968.         je      @f
  969.         mov     esi, boot_APIC_nfound
  970. @@:
  971.         call    boot_log
  972.  
  973. ; PRINT AMOUNT OF MEMORY
  974.         mov     esi, boot_memdetect
  975.         call    boot_log
  976.  
  977.         movzx   ecx, word [boot_y]
  978.         if lang eq ru
  979.         or      ecx, (10+30*6) shl 16
  980.         else if lang eq sp
  981.         or      ecx, (10+33*6) shl 16
  982.         else
  983.         or      ecx, (10+29*6) shl 16
  984.         end if
  985.         sub     ecx, 10
  986.         mov     edx, 0xFFFFFF
  987.         mov     ebx, [MEM_AMOUNT]
  988.         shr     ebx, 20
  989.         xor     edi, edi
  990.         mov     eax, 0x00040000
  991.         inc     edi
  992.         call    display_number_force
  993.  
  994. ; BUILD SCHEDULER
  995.  
  996. ;        call    build_scheduler; sys32.inc
  997.  
  998. ;        mov     esi, boot_devices
  999. ;        call    boot_log
  1000.  
  1001.         call    clear_pci_ide_interrupts
  1002.  
  1003. include "detect/vortex86.inc"                     ; Vortex86 SoC detection code
  1004.  
  1005.         stdcall load_pe_driver, szVidintel, 0
  1006.  
  1007.         call    usb_init
  1008.  
  1009. ; SET PRELIMINARY WINDOW STACK AND POSITIONS
  1010.  
  1011.         mov     esi, boot_windefs
  1012.         call    boot_log
  1013.         call    set_window_defaults
  1014.  
  1015. ; SET BACKGROUND DEFAULTS
  1016.  
  1017.         mov     esi, boot_bgr
  1018.         call    boot_log
  1019.         call    init_background
  1020.         call    calculatebackground
  1021.  
  1022. ; RESERVE SYSTEM IRQ'S JA PORT'S
  1023.  
  1024.         mov     esi, boot_resirqports
  1025.         call    boot_log
  1026.         call    reserve_irqs_ports
  1027.  
  1028.         call    init_display
  1029.         mov     eax, [def_cursor]
  1030.         mov     [SLOT_BASE+APPDATA.cursor+256], eax
  1031.         mov     [SLOT_BASE+APPDATA.cursor+256*2], eax
  1032.  
  1033. ; PRINT CPU FREQUENCY
  1034.  
  1035.         mov     esi, boot_cpufreq
  1036.         call    boot_log
  1037.  
  1038.         cli                         ;FIXME check IF
  1039.         rdtsc
  1040.         mov     ecx, eax
  1041.         mov     esi, 250            ; wait 1/4 a second
  1042.         call    delay_ms
  1043.         rdtsc
  1044.         sti
  1045.  
  1046.         sub     eax, ecx
  1047.         xor     edx, edx
  1048.         shld    edx, eax, 2
  1049.         shl     eax, 2
  1050.         mov     dword [cpu_freq], eax
  1051.         mov     dword [cpu_freq+4], edx
  1052.         mov     ebx, 1000000
  1053.         div     ebx
  1054.         mov     ebx, eax
  1055.  
  1056.         movzx   ecx, word [boot_y]
  1057.         if lang eq ru
  1058.         add     ecx, (10+19*6) shl 16 - 10
  1059.         else if lang eq sp
  1060.         add     ecx, (10+25*6) shl 16 - 10
  1061.         else
  1062.         add     ecx, (10+17*6) shl 16 - 10
  1063.         end if
  1064.  
  1065.         mov     edx, 0xFFFFFF
  1066.         xor     edi, edi
  1067.         mov     eax, 0x00040000
  1068.         inc     edi
  1069.         call    display_number_force
  1070.  
  1071. ; SET VARIABLES
  1072.  
  1073.         call    set_variables
  1074.  
  1075. ; STACK AND FDC
  1076.  
  1077.         call    stack_init
  1078.         call    fdc_init
  1079.  
  1080. ; PALETTE FOR 320x200 and 640x480 16 col
  1081.  
  1082.         cmp     [SCR_MODE], word 0x12
  1083.         jne     no_pal_vga
  1084.         mov     esi, boot_pal_vga
  1085.         call    boot_log
  1086.         call    paletteVGA
  1087.       no_pal_vga:
  1088.  
  1089.         cmp     [SCR_MODE], word 0x13
  1090.         jne     no_pal_ega
  1091.         mov     esi, boot_pal_ega
  1092.         call    boot_log
  1093.         call    palette320x200
  1094.       no_pal_ega:
  1095.  
  1096. ; LOAD DEFAULT SKIN
  1097.  
  1098.         call    load_default_skin
  1099.  
  1100. ;protect io permission map
  1101.  
  1102.         mov     esi, [default_io_map]
  1103.         stdcall map_page, esi, [SLOT_BASE+256+APPDATA.io_map], PG_READ
  1104.         add     esi, 0x1000
  1105.         stdcall map_page, esi, [SLOT_BASE+256+APPDATA.io_map+4], PG_READ
  1106.  
  1107.         stdcall map_page, tss._io_map_0, \
  1108.                 [SLOT_BASE+256+APPDATA.io_map], PG_READ
  1109.         stdcall map_page, tss._io_map_1, \
  1110.                 [SLOT_BASE+256+APPDATA.io_map+4], PG_READ
  1111.  
  1112. ; SET KEYBOARD PARAMETERS
  1113.         mov     al, 0xf6       ; reset keyboard, scan enabled
  1114.         call    kb_write_wait_ack
  1115.         test    ah, ah
  1116.         jnz     .no_keyboard
  1117.  
  1118. iglobal
  1119. align 4
  1120. ps2_keyboard_functions:
  1121.         dd      .end - $
  1122.         dd      0       ; no close
  1123.         dd      ps2_set_lights
  1124. .end:
  1125. endg
  1126.         stdcall register_keyboard, ps2_keyboard_functions, 0
  1127.        ; mov   al, 0xED       ; Keyboard LEDs - only for testing!
  1128.        ; call  kb_write_wait_ack
  1129.        ; mov   al, 111b
  1130.        ; call  kb_write_wait_ack
  1131.  
  1132.         mov     al, 0xF3     ; set repeat rate & delay
  1133.         call    kb_write_wait_ack
  1134.         mov     al, 0; 30 250 ;00100010b ; 24 500  ;00100100b  ; 20 500
  1135.         call    kb_write_wait_ack
  1136.      ;// mike.dld [
  1137.         call    set_lights
  1138.      ;// mike.dld ]
  1139.         stdcall attach_int_handler, 1, irq1, 0
  1140.         DEBUGF  1, "K : IRQ1 return code %x\n", eax
  1141. .no_keyboard:
  1142.  
  1143. ; Load PS/2 mouse driver
  1144.  
  1145.         stdcall load_pe_driver, szPS2MDriver, 0
  1146.  
  1147.         mov     esi, boot_setmouse
  1148.         call    boot_log
  1149.         call    setmouse
  1150.  
  1151. ; LOAD FIRST APPLICATION
  1152.         cmp     byte [launcher_start], 1        ; Check if starting LAUNCHER is selected on blue screen (1 = yes)
  1153.         jnz     first_app_found
  1154.  
  1155.         cli
  1156.         mov     ebp, firstapp
  1157.         call    fs_execute_from_sysdir
  1158.         test    eax, eax
  1159.         jns     first_app_found
  1160.  
  1161.         mov     esi, boot_failed
  1162.         call    boot_log
  1163.  
  1164.         mov     eax, 0xDEADBEEF      ; otherwise halt
  1165.         hlt
  1166.  
  1167. first_app_found:
  1168.  
  1169. ; START MULTITASKING
  1170.  
  1171. ; A 'All set - press ESC to start' messages if need
  1172. if preboot_blogesc
  1173.         mov     esi, boot_tasking
  1174.         call    boot_log
  1175. .bll1:
  1176.         in      al, 0x60        ; wait for ESC key press
  1177.         cmp     al, 129
  1178.         jne     .bll1
  1179. end if
  1180.  
  1181.         mov     [timer_ticks_enable], 1         ; for cd driver
  1182.  
  1183.         sti
  1184.  
  1185.         call    mtrr_validate
  1186.  
  1187.         jmp     osloop
  1188.  
  1189.  
  1190.         ; Fly :)
  1191.  
  1192. uglobal
  1193. align 4
  1194. ap_initialized  dd      0
  1195. endg
  1196.  
  1197. ap_init_high:
  1198.         mov     ax, os_stack
  1199.         mov     bx, app_data
  1200.         mov     cx, app_tls
  1201.         mov     ss, ax
  1202.         mov     ds, bx
  1203.         mov     es, bx
  1204.         mov     fs, cx
  1205.         mov     gs, bx
  1206.         xor     esp, esp
  1207.         mov     eax, sys_proc-OS_BASE+PROC.pdt_0
  1208.         mov     cr3, eax
  1209.         lock inc [ap_initialized]
  1210.         jmp     idle_loop
  1211.  
  1212.  
  1213. include 'unpacker.inc'
  1214.  
  1215. align 4
  1216. boot_log:
  1217.         pushad
  1218.  
  1219.         mov     ebx, 10*65536
  1220.         mov     bx, word [boot_y]
  1221.         add     [boot_y], dword 10
  1222.         mov     ecx, 0x80ffffff; ASCIIZ string with white color
  1223.         xor     edi, edi
  1224.         mov     edx, esi
  1225.         inc     edi
  1226.         call    dtext
  1227.  
  1228.         mov     [novesachecksum], 1000
  1229.         call    checkVga_N13
  1230.  
  1231.         popad
  1232.  
  1233.         ret
  1234.  
  1235. ; in: edx -> APPDATA for OS/IDLE slot
  1236. ; in: ebx = stack base
  1237. proc setup_os_slot
  1238.         xor     eax, eax
  1239.         mov     ecx, 256/4
  1240.         mov     edi, edx
  1241.         rep stosd
  1242.  
  1243.         mov     eax, tss+0x80
  1244.         call    get_pg_addr
  1245.         inc     eax
  1246.         mov     [edx+APPDATA.io_map], eax
  1247.         mov     eax, tss+0x1080
  1248.         call    get_pg_addr
  1249.         inc     eax
  1250.         mov     [edx+APPDATA.io_map+4], eax
  1251.  
  1252.         mov     dword [edx+APPDATA.pl0_stack], ebx
  1253.         lea     edi, [ebx+0x2000-512]
  1254.         mov     dword [edx+APPDATA.fpu_state], edi
  1255.         mov     dword [edx+APPDATA.saved_esp0], edi
  1256.         mov     dword [edx+APPDATA.saved_esp], edi
  1257.         mov     dword [edx+APPDATA.terminate_protection], 1 ; make unkillable
  1258.  
  1259.         mov     esi, fpu_data
  1260.         mov     ecx, 512/4
  1261.         cld
  1262.         rep movsd
  1263.  
  1264.         lea     eax, [edx+APP_OBJ_OFFSET]
  1265.         mov     dword [edx+APPDATA.fd_obj], eax
  1266.         mov     dword [edx+APPDATA.bk_obj], eax
  1267.  
  1268.         mov     dword [edx+APPDATA.cur_dir], sysdir_path
  1269.  
  1270.         mov     [edx + APPDATA.process], sys_proc
  1271.  
  1272.         lea     ebx, [edx+APPDATA.list]
  1273.         lea     ecx, [sys_proc+PROC.thr_list]
  1274.         list_add_tail ebx, ecx
  1275.  
  1276.         mov     eax, edx
  1277.         shr     eax, 3
  1278.         add     eax, CURRENT_TASK - (SLOT_BASE shr 3)
  1279.         mov     [eax+TASKDATA.wnd_number], dh
  1280.         mov     byte [eax+TASKDATA.pid], dh
  1281.  
  1282.         ret
  1283. endp
  1284.  
  1285. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1286. ;                                                                    ;
  1287. ;                    MAIN OS LOOP START                              ;
  1288. ;                                                                    ;
  1289. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1290. align 32
  1291. osloop:
  1292.         mov     edx, osloop_has_work?
  1293.         xor     ecx, ecx
  1294.         call    Wait_events
  1295.         xor     eax, eax
  1296.         xchg    eax, [osloop_nonperiodic_work]
  1297.         test    eax, eax
  1298.         jz      .no_periodic
  1299.  
  1300.         call    __sys_draw_pointer
  1301.         call    window_check_events
  1302.         call    mouse_check_events
  1303.         call    checkmisc
  1304.         call    checkVga_N13
  1305. ;--------------------------------------
  1306. .no_periodic:
  1307.         call    stack_handler
  1308.         call    check_fdd_motor_status
  1309.         call    check_ATAPI_device_event
  1310.         call    check_lights_state
  1311.         call    check_timers
  1312.  
  1313.         jmp     osloop
  1314. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1315. ;                                                                    ;
  1316. ;                      MAIN OS LOOP END                              ;
  1317. ;                                                                    ;
  1318. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1319. proc osloop_has_work?
  1320.         cmp     [osloop_nonperiodic_work], 0
  1321.         jnz     .yes
  1322.         call    stack_handler_has_work?
  1323.         jnz     .yes
  1324.         call    check_fdd_motor_status_has_work?
  1325.         jnz     .yes
  1326.         call    check_ATAPI_device_event_has_work?
  1327.         jnz     .yes
  1328.         call    check_lights_state_has_work?
  1329.         jnz     .yes
  1330.         call    check_timers_has_work?
  1331.         jnz     .yes
  1332. .no:
  1333.         xor     eax, eax
  1334.         ret
  1335. .yes:
  1336.         xor     eax, eax
  1337.         inc     eax
  1338.         ret
  1339. endp
  1340.  
  1341. proc wakeup_osloop
  1342.         mov     [osloop_nonperiodic_work], 1
  1343.         ret
  1344. endp
  1345.  
  1346. uglobal
  1347. align 4
  1348. osloop_nonperiodic_work dd      ?
  1349. endg
  1350.  
  1351. uglobal
  1352. align 64
  1353. idle_addr       rb      64
  1354. endg
  1355.  
  1356. idle_thread:
  1357.         sti
  1358.  
  1359. ; The following code can be executed by all CPUs in the system.
  1360. ; All other parts of the kernel do not expect multi-CPU.
  1361. ; Also, APs don't even have a stack here.
  1362. ; Beware. Don't do anything here. Anything at all.
  1363. idle_loop:
  1364.         cmp     [use_mwait_for_idle], 0
  1365.         jnz     idle_loop_mwait
  1366.  
  1367. idle_loop_hlt:
  1368.         hlt
  1369.         jmp     idle_loop_hlt
  1370.  
  1371. idle_loop_mwait:
  1372.         mov     eax, idle_addr
  1373.         xor     ecx, ecx
  1374.         xor     edx, edx
  1375.         monitor
  1376.         xor     ecx, ecx
  1377.         mov     eax, 20h        ; or 10h
  1378.         mwait
  1379.         jmp     idle_loop_mwait
  1380.  
  1381.  
  1382. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1383. ;                                                                      ;
  1384. ;                   INCLUDED SYSTEM FILES                              ;
  1385. ;                                                                      ;
  1386. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1387.  
  1388.  
  1389. include "kernel32.inc"
  1390.  
  1391.  
  1392. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1393. ;                                                                      ;
  1394. ;                       KERNEL FUNCTIONS                               ;
  1395. ;                                                                      ;
  1396. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1397.  
  1398. reserve_irqs_ports:
  1399.  
  1400.  
  1401. ; RESERVE PORTS
  1402.         mov     eax, RESERVED_PORTS
  1403.         mov     ecx, 1
  1404.  
  1405.         mov     [eax], dword 4
  1406.  
  1407.         mov     [eax+16], ecx
  1408.         mov     [eax+16+4], dword 0
  1409.         mov     [eax+16+8], dword 0x2D
  1410.  
  1411.         mov     [eax+32], ecx
  1412.         mov     [eax+32+4], dword 0x30
  1413.         mov     [eax+32+8], dword 0x4D
  1414.  
  1415.         mov     [eax+48], ecx
  1416.         mov     [eax+48+4], dword 0x50
  1417.         mov     [eax+48+8], dword 0xDF
  1418.  
  1419.         mov     [eax+64], ecx
  1420.         mov     [eax+64+4], dword 0xE5
  1421.         mov     [eax+64+8], dword 0xFF
  1422.  
  1423.         ret
  1424.  
  1425.  
  1426. iglobal
  1427.   process_number dd 0x2
  1428. endg
  1429.  
  1430. set_variables:
  1431.  
  1432.         mov     ecx, 0x16                    ; flush port 0x60
  1433. .fl60:
  1434.         in      al, 0x60
  1435.         loop    .fl60
  1436.         push    eax
  1437.  
  1438.         mov     ax, [BOOT_VARS+BOOT_Y_RES]
  1439.         shr     ax, 1
  1440.         shl     eax, 16
  1441.         mov     ax, [BOOT_VARS+BOOT_X_RES]
  1442.         shr     ax, 1
  1443.         mov     [MOUSE_X], eax
  1444.         call    wakeup_osloop
  1445.  
  1446.         xor     eax, eax
  1447.         mov     [BTN_ADDR], dword BUTTON_INFO ; address of button list
  1448.  
  1449.         mov     byte [KEY_COUNT], al              ; keyboard buffer
  1450.         mov     byte [BTN_COUNT], al              ; button buffer
  1451. ;        mov   [MOUSE_X],dword 100*65536+100    ; mouse x/y
  1452.  
  1453.         pop     eax
  1454.         ret
  1455.  
  1456. align 4
  1457. ;input  eax=43,bl-byte of output, ecx - number of port
  1458. sys_outport:
  1459.  
  1460.         mov     edi, ecx   ; separate flag for read / write
  1461.         and     ecx, 65535
  1462.  
  1463.         mov     eax, [RESERVED_PORTS]
  1464.         test    eax, eax
  1465.         jnz     .sopl8
  1466.         inc     eax
  1467.         mov     [esp+32], eax
  1468.         ret
  1469.  
  1470.   .sopl8:
  1471.         mov     edx, [TASK_BASE]
  1472.         mov     edx, [edx+0x4]
  1473.     ;and   ecx,65535
  1474.     ;cld - set on interrupt 0x40
  1475.   .sopl1:
  1476.  
  1477.         mov     esi, eax
  1478.         shl     esi, 4
  1479.         add     esi, RESERVED_PORTS
  1480.         cmp     edx, [esi+0]
  1481.         jne     .sopl2
  1482.         cmp     ecx, [esi+4]
  1483.         jb      .sopl2
  1484.         cmp     ecx, [esi+8]
  1485.         jg      .sopl2
  1486. .sopl3:
  1487.  
  1488.         test    edi, 0x80000000; read ?
  1489.         jnz     .sopl4
  1490.  
  1491.         mov     eax, ebx
  1492.         mov     dx, cx   ; write
  1493.         out     dx, al
  1494.         and     [esp+32], dword 0
  1495.         ret
  1496.  
  1497.         .sopl2:
  1498.  
  1499.         dec     eax
  1500.         jnz     .sopl1
  1501.         inc     eax
  1502.         mov     [esp+32], eax
  1503.         ret
  1504.  
  1505.  
  1506.   .sopl4:
  1507.  
  1508.         mov     dx, cx   ; read
  1509.         in      al, dx
  1510.         and     eax, 0xff
  1511.         and     [esp+32], dword 0
  1512.         mov     [esp+20], eax
  1513.         ret
  1514.  
  1515. display_number:
  1516. ;It is not optimization
  1517.         mov     eax, ebx
  1518.         mov     ebx, ecx
  1519.         mov     ecx, edx
  1520.         mov     edx, esi
  1521.         mov     esi, edi
  1522. ; eax = print type, al=0 -> ebx is number
  1523. ;                   al=1 -> ebx is pointer
  1524. ;                   ah=0 -> display decimal
  1525. ;                   ah=1 -> display hexadecimal
  1526. ;                   ah=2 -> display binary
  1527. ;                   eax bits 16-21 = number of digits to display (0-32)
  1528. ;                   eax bits 22-31 = reserved
  1529. ;
  1530. ; ebx = number or pointer
  1531. ; ecx = x shl 16 + y
  1532. ; edx = color
  1533.         xor     edi, edi
  1534. display_number_force:
  1535.         push    eax
  1536.         and     eax, 0x3fffffff
  1537.         cmp     eax, 0xffff     ; length > 0 ?
  1538.         pop     eax
  1539.         jge     cont_displ
  1540.         ret
  1541.    cont_displ:
  1542.         push    eax
  1543.         and     eax, 0x3fffffff
  1544.         cmp     eax, 61*0x10000  ; length <= 60 ?
  1545.         pop     eax
  1546.         jb      cont_displ2
  1547.         ret
  1548.    cont_displ2:
  1549.  
  1550.         pushad
  1551.  
  1552.         cmp     al, 1            ; ecx is a pointer ?
  1553.         jne     displnl1
  1554.         mov     ebp, ebx
  1555.         add     ebp, 4
  1556.         mov     ebp, [ebp+std_application_base_address]
  1557.         mov     ebx, [ebx+std_application_base_address]
  1558.  displnl1:
  1559.         sub     esp, 64
  1560.  
  1561.         test    ah, ah            ; DECIMAL
  1562.         jnz     no_display_desnum
  1563.         shr     eax, 16
  1564.         and     eax, 0xC03f
  1565. ;     and   eax,0x3f
  1566.         push    eax
  1567.         and     eax, 0x3f
  1568.         mov     edi, esp
  1569.         add     edi, 4+64-1
  1570.         mov     ecx, eax
  1571.         mov     eax, ebx
  1572.         mov     ebx, 10
  1573.  d_desnum:
  1574.         xor     edx, edx
  1575.         call    division_64_bits
  1576.         div     ebx
  1577.         add     dl, 48
  1578.         mov     [edi], dl
  1579.         dec     edi
  1580.         loop    d_desnum
  1581.         pop     eax
  1582.         call    normalize_number
  1583.         call    draw_num_text
  1584.         add     esp, 64
  1585.         popad
  1586.         ret
  1587.    no_display_desnum:
  1588.  
  1589.         cmp     ah, 0x01         ; HEXADECIMAL
  1590.         jne     no_display_hexnum
  1591.         shr     eax, 16
  1592.         and     eax, 0xC03f
  1593. ;     and   eax,0x3f
  1594.         push    eax
  1595.         and     eax, 0x3f
  1596.         mov     edi, esp
  1597.         add     edi, 4+64-1
  1598.         mov     ecx, eax
  1599.         mov     eax, ebx
  1600.         mov     ebx, 16
  1601.    d_hexnum:
  1602.         xor     edx, edx
  1603.         call    division_64_bits
  1604.         div     ebx
  1605.    hexletters = __fdo_hexdigits
  1606.         add     edx, hexletters
  1607.         mov     dl, [edx]
  1608.         mov     [edi], dl
  1609.         dec     edi
  1610.         loop    d_hexnum
  1611.         pop     eax
  1612.         call    normalize_number
  1613.         call    draw_num_text
  1614.         add     esp, 64
  1615.         popad
  1616.         ret
  1617.    no_display_hexnum:
  1618.  
  1619.         cmp     ah, 0x02         ; BINARY
  1620.         jne     no_display_binnum
  1621.         shr     eax, 16
  1622.         and     eax, 0xC03f
  1623. ;     and   eax,0x3f
  1624.         push    eax
  1625.         and     eax, 0x3f
  1626.         mov     edi, esp
  1627.         add     edi, 4+64-1
  1628.         mov     ecx, eax
  1629.         mov     eax, ebx
  1630.         mov     ebx, 2
  1631.    d_binnum:
  1632.         xor     edx, edx
  1633.         call    division_64_bits
  1634.         div     ebx
  1635.         add     dl, 48
  1636.         mov     [edi], dl
  1637.         dec     edi
  1638.         loop    d_binnum
  1639.         pop     eax
  1640.         call    normalize_number
  1641.         call    draw_num_text
  1642.         add     esp, 64
  1643.         popad
  1644.         ret
  1645.    no_display_binnum:
  1646.  
  1647.         add     esp, 64
  1648.         popad
  1649.         ret
  1650.  
  1651. normalize_number:
  1652.         test    ah, 0x80
  1653.         jz      .continue
  1654.         mov     ecx, 48
  1655.         and     eax, 0x3f
  1656. @@:
  1657.         inc     edi
  1658.         cmp     [edi], cl
  1659.         jne     .continue
  1660.         dec     eax
  1661.         cmp     eax, 1
  1662.         ja      @r
  1663.         mov     al, 1
  1664. .continue:
  1665.         and     eax, 0x3f
  1666.         ret
  1667.  
  1668. division_64_bits:
  1669.         test    [esp+1+4], byte 0x40
  1670.         jz      .continue
  1671.         push    eax
  1672.         mov     eax, ebp
  1673.         div     ebx
  1674.         mov     ebp, eax
  1675.         pop     eax
  1676. .continue:
  1677.         ret
  1678.  
  1679. draw_num_text:
  1680.         mov     esi, eax
  1681.         mov     edx, 64+4
  1682.         sub     edx, eax
  1683.         add     edx, esp
  1684.         mov     ebx, [esp+64+32-8+4]
  1685. ; add window start x & y
  1686.         mov     ecx, [TASK_BASE]
  1687.  
  1688.         mov     edi, [CURRENT_TASK]
  1689.         shl     edi, 8
  1690.  
  1691.         mov     eax, [ecx-twdw+WDATA.box.left]
  1692.         add     eax, [edi+SLOT_BASE+APPDATA.wnd_clientbox.left]
  1693.         shl     eax, 16
  1694.         add     eax, [ecx-twdw+WDATA.box.top]
  1695.         add     eax, [edi+SLOT_BASE+APPDATA.wnd_clientbox.top]
  1696.         add     ebx, eax
  1697.         mov     ecx, [esp+64+32-12+4]
  1698.         and     ecx, not 0x80000000     ; force counted string
  1699.         mov     eax, [esp+64+8]         ; background color (if given)
  1700.         mov     edi, [esp+64+4]
  1701.         jmp     dtext
  1702. ;-----------------------------------------------------------------------------
  1703. iglobal
  1704. midi_base dw 0
  1705. endg
  1706. ;-----------------------------------------------------------------------------
  1707. align 4
  1708. sys_setup:
  1709. ;  1 = roland mpu midi base , base io address
  1710. ;  2 = keyboard   1, base kaybap 2, shift keymap, 9 country 1eng 2fi 3ger 4rus
  1711. ;  3 = not used
  1712. ;  4 = not used
  1713. ;  5 = system language, 1eng 2fi 3ger 4rus
  1714. ;  6 = not used
  1715. ;  7 = not used
  1716. ;  8 = not used
  1717. ;  9 = not used
  1718. ; 10 = not used
  1719. ; 11 = enable lba read
  1720. ; 12 = enable pci access
  1721. ;-----------------------------------------------------------------------------
  1722.         and     [esp+32], dword 0
  1723. ; F.21.1 - set MPU MIDI base port
  1724.         dec     ebx
  1725.         jnz     @f
  1726.  
  1727.         cmp     ecx, 0x100
  1728.         jb      @f
  1729.  
  1730.         mov     esi, 65535
  1731.         cmp     esi, ecx
  1732.         jb      @f
  1733.  
  1734.         mov     [midi_base], cx
  1735.         mov     word [mididp], cx
  1736.         inc     cx
  1737.         mov     word [midisp], cx
  1738.         ret
  1739. ;--------------------------------------
  1740. @@:
  1741. ; F.21.2 - set keyboard layout
  1742.         dec     ebx
  1743.         jnz     @f
  1744.  
  1745.         mov     edi, [TASK_BASE]
  1746.         mov     eax, [edi+TASKDATA.mem_start]
  1747.         add     eax, edx
  1748. ; 1 = normal layout
  1749.         dec     ecx
  1750.         jnz     .shift
  1751.  
  1752.         mov     ebx, keymap
  1753.         mov     ecx, 128
  1754.         call    memmove
  1755.         ret
  1756. ;--------------------------------------
  1757. .shift:
  1758. ; 2 = layout at pressed Shift
  1759.         dec     ecx
  1760.         jnz     .alt
  1761.  
  1762.         mov     ebx, keymap_shift
  1763.         mov     ecx, 128
  1764.         call    memmove
  1765.         ret
  1766. ;--------------------------------------
  1767. .alt:
  1768. ; 3 = layout at pressed Alt
  1769.         dec     ecx
  1770.         jnz     .country
  1771.  
  1772.         mov     ebx, keymap_alt
  1773.         mov     ecx, 128
  1774.         call    memmove
  1775.         ret
  1776. ;--------------------------------------
  1777. .country:
  1778. ; country identifier
  1779.         sub     ecx, 6
  1780.         jnz     .error
  1781.  
  1782.         mov     word [keyboard], dx
  1783.         ret
  1784. ;--------------------------------------
  1785. @@:
  1786. ; F.21.5 - set system language
  1787.         sub     ebx, 3
  1788.         jnz     @f
  1789.  
  1790.         mov     [syslang], ecx
  1791.         ret
  1792. ;--------------------------------------
  1793. @@:
  1794. ; F.21.11 - enable/disable low-level access to HD
  1795.         and     ecx, 1
  1796.         sub     ebx, 6
  1797.         jnz     @f
  1798.  
  1799.         mov     [lba_read_enabled], ecx
  1800.         ret
  1801. ;--------------------------------------
  1802. @@:
  1803. ; F.21.12 - enable/disable low-level access to PCI
  1804.         dec     ebx
  1805.         jnz     .error
  1806.  
  1807.         mov     [pci_access_enabled], ecx
  1808.         ret
  1809. ;--------------------------------------
  1810. .error:
  1811.         or      [esp+32], dword -1
  1812.         ret
  1813. ;-----------------------------------------------------------------------------
  1814. align 4
  1815. sys_getsetup:
  1816. ;  1 = roland mpu midi base , base io address
  1817. ;  2 = keyboard   1, base kaybap 2, shift keymap, 9 country 1eng 2fi 3ger 4rus
  1818. ;  3 = not used
  1819. ;  4 = not used
  1820. ;  5 = system language, 1eng 2fi 3ger 4rus
  1821. ;  6 = not used
  1822. ;  7 = not used
  1823. ;  8 = not used
  1824. ;  9 = get hs timer tic
  1825. ; 10 = not used
  1826. ; 11 = get the state "lba read"
  1827. ; 12 = get the state "pci access"
  1828. ;-----------------------------------------------------------------------------
  1829. ; F.26.1 - get MPU MIDI base port
  1830.         dec     ebx
  1831.         jnz     @f
  1832.  
  1833.         movzx   eax, [midi_base]
  1834.         mov     [esp+32], eax
  1835.         ret
  1836. ;--------------------------------------
  1837. @@:
  1838. ; F.26.2 - get keyboard layout
  1839.         dec     ebx
  1840.         jnz     @f
  1841.  
  1842.         mov     edi, [TASK_BASE]
  1843.         mov     ebx, [edi+TASKDATA.mem_start]
  1844.         add     ebx, edx
  1845. ; 1 = normal layout
  1846.         dec     ecx
  1847.         jnz     .shift
  1848.  
  1849.         mov     eax, keymap
  1850.         mov     ecx, 128
  1851.         call    memmove
  1852.         ret
  1853. ;--------------------------------------
  1854. .shift:
  1855. ; 2 = layout with pressed Shift
  1856.         dec     ecx
  1857.         jnz     .alt
  1858.  
  1859.         mov     eax, keymap_shift
  1860.         mov     ecx, 128
  1861.         call    memmove
  1862.         ret
  1863. ;--------------------------------------
  1864. .alt:
  1865. ; 3 = layout with pressed Alt
  1866.         dec     ecx
  1867.         jne     .country
  1868.  
  1869.         mov     eax, keymap_alt
  1870.         mov     ecx, 128
  1871.         call    memmove
  1872.         ret
  1873. ;--------------------------------------
  1874. .country:
  1875. ; 9 = country identifier
  1876.         sub     ecx, 6
  1877.         jnz     .error
  1878.  
  1879.         movzx   eax, word [keyboard]
  1880.         mov     [esp+32], eax
  1881.         ret
  1882. ;--------------------------------------
  1883. @@:
  1884. ; F.26.5 - get system language
  1885.         sub     ebx, 3
  1886.         jnz     @f
  1887.  
  1888.         mov     eax, [syslang]
  1889.         mov     [esp+32], eax
  1890.         ret
  1891. ;--------------------------------------
  1892. @@:
  1893. ; F.26.9 - get the value of the time counter
  1894.         sub     ebx, 4
  1895.         jnz     @f
  1896.  
  1897.         mov     eax, [timer_ticks]
  1898.         mov     [esp+32], eax
  1899.         ret
  1900. ;--------------------------------------
  1901. @@:
  1902. ; F.26.11 - Find out whether low-level HD access is enabled
  1903.         sub     ebx, 2
  1904.         jnz     @f
  1905.  
  1906.         mov     eax, [lba_read_enabled]
  1907.         mov     [esp+32], eax
  1908.         ret
  1909. ;--------------------------------------
  1910. @@:
  1911. ; F.26.12 - Find out whether low-level PCI access is enabled
  1912.         dec     ebx
  1913.         jnz     .error
  1914.  
  1915.         mov     eax, [pci_access_enabled]
  1916.         mov     [esp+32], eax
  1917.         ret
  1918. ;--------------------------------------
  1919. .error:
  1920.         or      [esp+32], dword -1
  1921.         ret
  1922. ;-----------------------------------------------------------------------------
  1923. get_timer_ticks:
  1924.         mov     eax, [timer_ticks]
  1925.         ret
  1926. ;-----------------------------------------------------------------------------
  1927. iglobal
  1928. align 4
  1929. mousefn dd msscreen, mswin, msbutton, msset
  1930.         dd app_load_cursor
  1931.         dd app_set_cursor
  1932.         dd app_delete_cursor
  1933.         dd msz
  1934. endg
  1935. ;-----------------------------------------------------------------------------
  1936. readmousepos:
  1937.  
  1938. ; eax=0 screen relative
  1939. ; eax=1 window relative
  1940. ; eax=2 buttons pressed
  1941. ; eax=3 set mouse pos   ; reserved
  1942. ; eax=4 load cursor
  1943. ; eax=5 set cursor
  1944. ; eax=6 delete cursor   ; reserved
  1945. ; eax=7 get mouse_z
  1946.  
  1947.         cmp     ebx, 7
  1948.         ja      msset
  1949.         jmp     [mousefn+ebx*4]
  1950. msscreen:
  1951.         mov     eax, [MOUSE_X]
  1952.         shl     eax, 16
  1953.         mov     ax, [MOUSE_Y]
  1954.         mov     [esp+36-4], eax
  1955.         ret
  1956. mswin:
  1957.         mov     eax, [MOUSE_X]
  1958.         shl     eax, 16
  1959.         mov     ax, [MOUSE_Y]
  1960.         mov     esi, [TASK_BASE]
  1961.         mov     bx, word [esi-twdw+WDATA.box.left]
  1962.         shl     ebx, 16
  1963.         mov     bx, word [esi-twdw+WDATA.box.top]
  1964.         sub     eax, ebx
  1965.  
  1966.         mov     edi, [CURRENT_TASK]
  1967.         shl     edi, 8
  1968.         sub     ax, word[edi+SLOT_BASE+APPDATA.wnd_clientbox.top]
  1969.         rol     eax, 16
  1970.         sub     ax, word[edi+SLOT_BASE+APPDATA.wnd_clientbox.left]
  1971.         rol     eax, 16
  1972.         mov     [esp+36-4], eax
  1973.         ret
  1974. msbutton:
  1975.         movzx   eax, byte [BTN_DOWN]
  1976.         mov     [esp+36-4], eax
  1977.         ret
  1978. msz:
  1979.         mov     edi, [TASK_COUNT]
  1980.         movzx   edi, word [WIN_POS + edi*2]
  1981.         cmp     edi, [CURRENT_TASK]
  1982.         jne     @f
  1983.         mov     ax, [MOUSE_SCROLL_H]
  1984.         shl     eax, 16
  1985.         mov     ax, [MOUSE_SCROLL_V]
  1986.         mov     [esp+36-4], eax
  1987.         and     [MOUSE_SCROLL_H], word 0
  1988.         and     [MOUSE_SCROLL_V], word 0
  1989.         ret
  1990.        @@:
  1991.         and     [esp+36-4], dword 0
  1992. ;           ret
  1993. msset:
  1994.         ret
  1995.  
  1996. app_load_cursor:
  1997.         cmp     ecx, OS_BASE
  1998.         jae     msset
  1999.         stdcall load_cursor, ecx, edx
  2000.         mov     [esp+36-4], eax
  2001.         ret
  2002.  
  2003. app_set_cursor:
  2004.         stdcall set_cursor, ecx
  2005.         mov     [esp+36-4], eax
  2006.         ret
  2007.  
  2008. app_delete_cursor:
  2009.         stdcall delete_cursor, ecx
  2010.         mov     [esp+36-4], eax
  2011.         ret
  2012.  
  2013. is_input:
  2014.  
  2015.         push    edx
  2016.         mov     dx, word [midisp]
  2017.         in      al, dx
  2018.         and     al, 0x80
  2019.         pop     edx
  2020.         ret
  2021.  
  2022. is_output:
  2023.  
  2024.         push    edx
  2025.         mov     dx, word [midisp]
  2026.         in      al, dx
  2027.         and     al, 0x40
  2028.         pop     edx
  2029.         ret
  2030.  
  2031.  
  2032. get_mpu_in:
  2033.  
  2034.         push    edx
  2035.         mov     dx, word [mididp]
  2036.         in      al, dx
  2037.         pop     edx
  2038.         ret
  2039.  
  2040.  
  2041. put_mpu_out:
  2042.  
  2043.         push    edx
  2044.         mov     dx, word [mididp]
  2045.         out     dx, al
  2046.         pop     edx
  2047.         ret
  2048.  
  2049.  
  2050.  
  2051. align 4
  2052.  
  2053. sys_midi:
  2054.         cmp     [mididp], 0
  2055.         jnz     sm0
  2056.         mov     [esp+36], dword 1
  2057.         ret
  2058. sm0:
  2059.         and     [esp+36], dword 0
  2060.         dec     ebx
  2061.         jnz     smn1
  2062.  ;    call setuart
  2063. su1:
  2064.         call    is_output
  2065.         test    al, al
  2066.         jnz     su1
  2067.         mov     dx, word [midisp]
  2068.         mov     al, 0xff
  2069.         out     dx, al
  2070. su2:
  2071.         mov     dx, word [midisp]
  2072.         mov     al, 0xff
  2073.         out     dx, al
  2074.         call    is_input
  2075.         test    al, al
  2076.         jnz     su2
  2077.         call    get_mpu_in
  2078.         cmp     al, 0xfe
  2079.         jnz     su2
  2080. su3:
  2081.         call    is_output
  2082.         test    al, al
  2083.         jnz     su3
  2084.         mov     dx, word [midisp]
  2085.         mov     al, 0x3f
  2086.         out     dx, al
  2087.         ret
  2088. smn1:
  2089.         dec     ebx
  2090.         jnz     smn2
  2091. sm10:
  2092.         call    get_mpu_in
  2093.         call    is_output
  2094.         test    al, al
  2095.         jnz     sm10
  2096.         mov     al, bl
  2097.         call    put_mpu_out
  2098.         smn2:
  2099.         ret
  2100.  
  2101. detect_devices:
  2102. ;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  2103. ;include 'detect/commouse.inc'
  2104. ;include 'detect/ps2mouse.inc'
  2105. ;include 'detect/dev_fd.inc'
  2106. ;include 'detect/dev_hdcd.inc'
  2107. ;include 'detect/sear_par.inc'
  2108. ;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  2109.         ret
  2110.  
  2111. sys_end:
  2112. ;--------------------------------------
  2113.         cmp     [_display.select_cursor], 0
  2114.         je      @f
  2115. ; restore default cursor before killing
  2116.         pusha
  2117.         mov     ecx, [current_slot]
  2118.         call    restore_default_cursor_before_killing
  2119.         popa
  2120. @@:
  2121. ;--------------------------------------
  2122. ; kill all sockets this process owns
  2123.         pusha
  2124.         mov     edx, [TASK_BASE]
  2125.         mov     edx, [edx+TASKDATA.pid]
  2126.         call    SOCKET_process_end
  2127.         popa
  2128. ;--------------------------------------
  2129.         mov     ecx, [current_slot]
  2130.         mov     eax, [ecx+APPDATA.tls_base]
  2131.         test    eax, eax
  2132.         jz      @F
  2133.  
  2134.         stdcall user_free, eax
  2135. @@:
  2136.  
  2137.         mov     eax, [TASK_BASE]
  2138.         mov     [eax+TASKDATA.state], 3; terminate this program
  2139.         call    wakeup_osloop
  2140.  
  2141. .waitterm:            ; wait here for termination
  2142.         call    change_task
  2143.         jmp     .waitterm
  2144. ;------------------------------------------------------------------------------
  2145. align 4
  2146. restore_default_cursor_before_killing:
  2147.         pushfd
  2148.         cli
  2149.         mov     eax, [def_cursor]
  2150.         mov     [ecx+APPDATA.cursor], eax
  2151.  
  2152.         movzx   eax, word [MOUSE_Y]
  2153.         movzx   ebx, word [MOUSE_X]
  2154.         mov     eax, [d_width_calc_area + eax*4]
  2155.  
  2156.         add     eax, [_display.win_map]
  2157.         movzx   edx, byte [ebx+eax]
  2158.         shl     edx, 8
  2159.         mov     esi, [edx+SLOT_BASE+APPDATA.cursor]
  2160.  
  2161.         cmp     esi, [current_cursor]
  2162.         je      @f
  2163.  
  2164.         push    esi
  2165.         call    [_display.select_cursor]
  2166.         mov     [current_cursor], esi
  2167. @@:
  2168.         mov     [redrawmouse_unconditional], 1
  2169.         call    wakeup_osloop
  2170.         popfd
  2171.         ret
  2172. ;------------------------------------------------------------------------------
  2173. iglobal
  2174. align 4
  2175. sys_system_table:
  2176.         dd      sysfn_deactivate        ; 1 = deactivate window
  2177.         dd      sysfn_terminate         ; 2 = terminate thread
  2178.         dd      sysfn_activate          ; 3 = activate window
  2179.         dd      sysfn_getidletime       ; 4 = get idle time
  2180.         dd      sysfn_getcpuclock       ; 5 = get cpu clock
  2181.         dd      sysfn_saveramdisk       ; 6 = save ramdisk
  2182.         dd      sysfn_getactive         ; 7 = get active window
  2183.         dd      sysfn_sound_flag        ; 8 = get/set sound_flag
  2184.         dd      sysfn_shutdown          ; 9 = shutdown with parameter
  2185.         dd      sysfn_minimize          ; 10 = minimize window
  2186.         dd      sysfn_getdiskinfo       ; 11 = get disk subsystem info
  2187.         dd      sysfn_lastkey           ; 12 = get last pressed key
  2188.         dd      sysfn_getversion        ; 13 = get kernel version
  2189.         dd      sysfn_waitretrace       ; 14 = wait retrace
  2190.         dd      sysfn_centermouse       ; 15 = center mouse cursor
  2191.         dd      sysfn_getfreemem        ; 16 = get free memory size
  2192.         dd      sysfn_getallmem         ; 17 = get total memory size
  2193.         dd      sysfn_terminate2        ; 18 = terminate thread using PID
  2194.                                         ;                 instead of slot
  2195.         dd      sysfn_mouse_acceleration; 19 = set/get mouse acceleration
  2196.         dd      sysfn_meminfo           ; 20 = get extended memory info
  2197.         dd      sysfn_pid_to_slot       ; 21 = get slot number for pid
  2198.         dd      sysfn_min_rest_window   ; 22 = minimize and restore any window
  2199.         dd      sysfn_min_windows       ; 23 = minimize all windows
  2200.         dd      sysfn_set_screen_sizes  ; 24 = set screen sizes for Vesa
  2201. sysfn_num = ($ - sys_system_table)/4
  2202. endg
  2203. ;------------------------------------------------------------------------------
  2204. sys_system:
  2205.         dec     ebx
  2206.         cmp     ebx, sysfn_num
  2207.         jae     @f
  2208.         jmp     dword [sys_system_table + ebx*4]
  2209. @@:
  2210.         ret
  2211. ;------------------------------------------------------------------------------
  2212. sysfn_shutdown:          ; 18.9 = system shutdown
  2213.         cmp     ecx, 1
  2214.         jl      exit_for_anyone
  2215.         cmp     ecx, 4
  2216.         jg      exit_for_anyone
  2217.         mov     [BOOT_VARS+0x9030], cl
  2218.  
  2219.         mov     eax, [TASK_COUNT]
  2220.         mov     [SYS_SHUTDOWN], al
  2221.         mov     [shutdown_processes], eax
  2222.         call    wakeup_osloop
  2223.         and     dword [esp+32], 0
  2224.  exit_for_anyone:
  2225.         ret
  2226.   uglobal
  2227.    shutdown_processes:
  2228.                        dd 0x0
  2229.   endg
  2230. ;------------------------------------------------------------------------------
  2231. sysfn_terminate:        ; 18.2 = TERMINATE
  2232.         push    ecx
  2233.         cmp     ecx, 2
  2234.         jb      noprocessterminate
  2235.         mov     edx, [TASK_COUNT]
  2236.         cmp     ecx, edx
  2237.         ja      noprocessterminate
  2238.         mov     eax, [TASK_COUNT]
  2239.         shl     ecx, 5
  2240.         mov     edx, [ecx+CURRENT_TASK+TASKDATA.pid]
  2241.         add     ecx, CURRENT_TASK+TASKDATA.state
  2242.         cmp     byte [ecx], 9
  2243.         jz      noprocessterminate
  2244.         push    ecx edx
  2245.         lea     edx, [(ecx-(CURRENT_TASK and 1FFFFFFFh)-TASKDATA.state)*8+SLOT_BASE]
  2246.         call    request_terminate
  2247.         pop     edx ecx
  2248.         test    eax, eax
  2249.         jz      noprocessterminate
  2250. ;--------------------------------------
  2251. ; terminate all network sockets it used
  2252.         pusha
  2253.         mov     eax, edx
  2254.         call    SOCKET_process_end
  2255.         popa
  2256. ;--------------------------------------
  2257.         cmp     [_display.select_cursor], 0
  2258.         je      .restore_end
  2259. ; restore default cursor before killing
  2260.         pusha
  2261.         mov     ecx, [esp+32]
  2262.         shl     ecx, 8
  2263.         add     ecx, SLOT_BASE
  2264.         mov     eax, [def_cursor]
  2265.         cmp     [ecx+APPDATA.cursor], eax
  2266.         je      @f
  2267.         call    restore_default_cursor_before_killing
  2268. @@:
  2269.         popa
  2270. .restore_end:
  2271. ;--------------------------------------
  2272.      ;call MEM_Heap_Lock      ;guarantee that process isn't working with heap
  2273.         mov     [ecx], byte 3; clear possible i40's
  2274.         call    wakeup_osloop
  2275.      ;call MEM_Heap_UnLock
  2276.  
  2277.         cmp     edx, [application_table_owner]; clear app table stat
  2278.         jne     noatsc
  2279.         call    unlock_application_table
  2280. noatsc:
  2281. noprocessterminate:
  2282.         add     esp, 4
  2283.         ret
  2284. ;------------------------------------------------------------------------------
  2285. sysfn_terminate2:
  2286. ;lock application_table_status mutex
  2287. .table_status:
  2288.         call    lock_application_table
  2289.         mov     eax, ecx
  2290.         call    pid_to_slot
  2291.         test    eax, eax
  2292.         jz      .not_found
  2293.         mov     ecx, eax
  2294.         cli
  2295.         call    sysfn_terminate
  2296.         call    unlock_application_table
  2297.         sti
  2298.         and     dword [esp+32], 0
  2299.         ret
  2300. .not_found:
  2301.         call    unlock_application_table
  2302.         or      dword [esp+32], -1
  2303.         ret
  2304. ;------------------------------------------------------------------------------
  2305. sysfn_deactivate:         ; 18.1 = DEACTIVATE WINDOW
  2306.         cmp     ecx, 2
  2307.         jb      .nowindowdeactivate
  2308.         cmp     ecx, [TASK_COUNT]
  2309.         ja      .nowindowdeactivate
  2310.  
  2311.         movzx   esi, word [WIN_STACK + ecx*2]
  2312.         cmp     esi, 1
  2313.         je      .nowindowdeactivate ; already deactive
  2314.  
  2315.         mov     edi, ecx
  2316.         shl     edi, 5
  2317.         add     edi, window_data
  2318.         movzx   esi, word [WIN_STACK + ecx * 2]
  2319.         lea     esi, [WIN_POS + esi * 2]
  2320.         call    window._.window_deactivate
  2321.  
  2322.         call    syscall_display_settings._.calculate_whole_screen
  2323.         call    syscall_display_settings._.redraw_whole_screen
  2324. .nowindowdeactivate:
  2325.         ret
  2326. ;------------------------------------------------------------------------------
  2327. sysfn_activate:         ; 18.3 = ACTIVATE WINDOW
  2328.         cmp     ecx, 2
  2329.         jb      .nowindowactivate
  2330.         cmp     ecx, [TASK_COUNT]
  2331.         ja      .nowindowactivate
  2332. ;-------------------------------------
  2333. @@:
  2334. ; If the window is captured and moved by the user,
  2335. ; then you can't change the position in window stack!!!
  2336.         mov     al, [mouse.active_sys_window.action]
  2337.         and     al, WINDOW_MOVE_AND_RESIZE_FLAGS
  2338.         test    al, al
  2339.         jz      @f
  2340.         call    change_task
  2341.         jmp     @b
  2342. @@:
  2343. ;-------------------------------------
  2344.         mov     [window_minimize], 2; restore window if minimized
  2345.         call    wakeup_osloop
  2346.  
  2347.         movzx   esi, word [WIN_STACK + ecx*2]
  2348.         cmp     esi, [TASK_COUNT]
  2349.         je      .nowindowactivate; already active
  2350.  
  2351.         mov     edi, ecx
  2352.         shl     edi, 5
  2353.         add     edi, window_data
  2354.         movzx   esi, word [WIN_STACK + ecx * 2]
  2355.         lea     esi, [WIN_POS + esi * 2]
  2356.         call    waredraw
  2357. .nowindowactivate:
  2358.         ret
  2359. ;------------------------------------------------------------------------------
  2360. sysfn_getidletime:              ; 18.4 = GET IDLETIME
  2361.         mov     eax, [CURRENT_TASK+32+TASKDATA.cpu_usage]
  2362.         mov     [esp+32], eax
  2363.         ret
  2364. ;------------------------------------------------------------------------------
  2365. sysfn_getcpuclock:              ; 18.5 = GET TSC/SEC
  2366.         mov     eax, dword [cpu_freq]
  2367.         mov     [esp+32], eax
  2368.         ret
  2369. ;------------------------------------------------------------------------------
  2370. get_cpu_freq:
  2371.         mov     eax, dword [cpu_freq]
  2372.         mov     edx, dword [cpu_freq+4]
  2373.         ret
  2374. ;  SAVE ramdisk to /hd/1/menuet.img
  2375. ;!!!!!!!!!!!!!!!!!!!!!!!!
  2376.    include 'blkdev/rdsave.inc'
  2377. ;!!!!!!!!!!!!!!!!!!!!!!!!
  2378. ;------------------------------------------------------------------------------
  2379. align 4
  2380. sysfn_getactive:        ; 18.7 = get active window
  2381.         mov     eax, [TASK_COUNT]
  2382.         movzx   eax, word [WIN_POS + eax*2]
  2383.         mov     [esp+32], eax
  2384.         ret
  2385. ;------------------------------------------------------------------------------
  2386. sysfn_sound_flag:       ; 18.8 = get/set sound_flag
  2387. ;     cmp  ecx,1
  2388.         dec     ecx
  2389.         jnz     nogetsoundflag
  2390.         movzx   eax, byte [sound_flag]; get sound_flag
  2391.         mov     [esp+32], eax
  2392.         ret
  2393.  nogetsoundflag:
  2394. ;     cmp  ecx,2
  2395.         dec     ecx
  2396.         jnz     nosoundflag
  2397.         xor     byte [sound_flag], 1
  2398.  nosoundflag:
  2399.         ret
  2400. ;------------------------------------------------------------------------------
  2401. sysfn_minimize:         ; 18.10 = minimize window
  2402.         mov     [window_minimize], 1
  2403.         call    wakeup_osloop
  2404.         ret
  2405. ;------------------------------------------------------------------------------
  2406. align 4
  2407. sysfn_getdiskinfo:      ; 18.11 = get disk info table
  2408.         dec     ecx
  2409.         jnz     .exit
  2410. .small_table:
  2411.         mov     edi, edx
  2412.         mov     esi, DRIVE_DATA
  2413.         mov     ecx, DRIVE_DATA_SIZE ;10
  2414.         cld
  2415.         rep movsb
  2416. .exit:
  2417.         ret
  2418. ;------------------------------------------------------------------------------
  2419. sysfn_lastkey:          ; 18.12 = return 0 (backward compatibility)
  2420.         and     dword [esp+32], 0
  2421.         ret
  2422. ;------------------------------------------------------------------------------
  2423. sysfn_getversion:       ; 18.13 = get kernel ID and version
  2424.         mov     edi, ecx
  2425.         mov     esi, version_inf
  2426.         mov     ecx, version_end-version_inf
  2427.         rep movsb
  2428.         ret
  2429. ;------------------------------------------------------------------------------
  2430. sysfn_waitretrace:     ; 18.14 = sys wait retrace
  2431.      ;wait retrace functions
  2432.  sys_wait_retrace:
  2433.         mov     edx, 0x3da
  2434.  WaitRetrace_loop:
  2435.         in      al, dx
  2436.         test    al, 1000b
  2437.         jz      WaitRetrace_loop
  2438.         and     [esp+32], dword 0
  2439.         ret
  2440. ;------------------------------------------------------------------------------
  2441. align 4
  2442. sysfn_centermouse:      ; 18.15 = mouse centered
  2443. ; removed here by <Lrz>
  2444. ;     call  mouse_centered
  2445. ;* mouse centered - start code- Mario79
  2446. ;mouse_centered:
  2447. ;        push  eax
  2448.         mov     eax, [_display.width]
  2449.         shr     eax, 1
  2450.         mov     [MOUSE_X], ax
  2451.         mov     eax, [_display.height]
  2452.         shr     eax, 1
  2453.         mov     [MOUSE_Y], ax
  2454.         call    wakeup_osloop
  2455. ;        ret
  2456. ;* mouse centered - end code- Mario79
  2457.         xor     eax, eax
  2458.         and     [esp+32], eax
  2459. ;        pop   eax
  2460.         ret
  2461. ;------------------------------------------------------------------------------
  2462. align 4
  2463. sysfn_mouse_acceleration: ; 18.19 = set/get mouse features
  2464.         test    ecx, ecx; get mouse speed factor
  2465.         jnz     .set_mouse_acceleration
  2466.         xor     eax, eax
  2467.         mov     ax, [mouse_speed_factor]
  2468.         mov     [esp+32], eax
  2469.         ret
  2470.  .set_mouse_acceleration:
  2471. ;     cmp  ecx,1  ; set mouse speed factor
  2472.         dec     ecx
  2473.         jnz     .get_mouse_delay
  2474.         mov     [mouse_speed_factor], dx
  2475.         ret
  2476.  .get_mouse_delay:
  2477. ;     cmp  ecx,2  ; get mouse delay
  2478.         dec     ecx
  2479.         jnz     .set_mouse_delay
  2480.         mov     eax, [mouse_delay]
  2481.         mov     [esp+32], eax
  2482.         ret
  2483.  .set_mouse_delay:
  2484. ;     cmp  ecx,3  ; set mouse delay
  2485.         dec     ecx
  2486.         jnz     .set_pointer_position
  2487.         mov     [mouse_delay], edx
  2488.         ret
  2489.  .set_pointer_position:
  2490. ;     cmp  ecx,4  ; set mouse pointer position
  2491.         dec     ecx
  2492.         jnz     .set_mouse_button
  2493.         cmp     dx, word[_display.height]
  2494.         jae     .end
  2495.         rol     edx, 16
  2496.         cmp     dx, word[_display.width]
  2497.         jae     .end
  2498.         mov     [MOUSE_X], edx
  2499.         mov     [mouse_active], 1
  2500.         call    wakeup_osloop
  2501.         ret
  2502.  .set_mouse_button:
  2503. ;     cmp   ecx,5  ; set mouse button features
  2504.         dec     ecx
  2505.         jnz     .end
  2506.         mov     [BTN_DOWN], dl
  2507.         mov     [mouse_active], 1
  2508.         call    wakeup_osloop
  2509.  .end:
  2510.         ret
  2511. ;------------------------------------------------------------------------------
  2512. sysfn_getfreemem:
  2513.         mov     eax, [pg_data.pages_free]
  2514.         shl     eax, 2
  2515.         mov     [esp+32], eax
  2516.         ret
  2517. ;------------------------------------------------------------------------------
  2518. sysfn_getallmem:
  2519.         mov     eax, [MEM_AMOUNT]
  2520.         shr     eax, 10
  2521.         mov     [esp+32], eax
  2522.         ret
  2523. ;------------------------------------------------------------------------------
  2524. sysfn_pid_to_slot:
  2525.         mov     eax, ecx
  2526.         call    pid_to_slot
  2527.         mov     [esp+32], eax
  2528.         ret
  2529. ;------------------------------------------------------------------------------
  2530. sysfn_min_rest_window:
  2531.         pushad
  2532.         mov     eax, edx ; ebx - operating
  2533.         shr     ecx, 1
  2534.         jnc     @f
  2535.         call    pid_to_slot
  2536. @@:
  2537.         or      eax, eax ; eax - number of slot
  2538.         jz      .error
  2539.         cmp     eax, 255    ; varify maximal slot number
  2540.         ja      .error
  2541.         movzx   eax, word [WIN_STACK + eax*2]
  2542.         shr     ecx, 1
  2543.         jc      .restore
  2544.  ; .minimize:
  2545.         call    minimize_window
  2546.         jmp     .exit
  2547. .restore:
  2548.         call    restore_minimized_window
  2549. .exit:
  2550.         popad
  2551.         xor     eax, eax
  2552.         mov     [esp+32], eax
  2553.         ret
  2554. .error:
  2555.         popad
  2556.         xor     eax, eax
  2557.         dec     eax
  2558.         mov     [esp+32], eax
  2559.         ret
  2560. ;------------------------------------------------------------------------------
  2561. sysfn_min_windows:
  2562.         call    minimize_all_window
  2563.         mov     [esp+32], eax
  2564.         call    change_task
  2565.         ret
  2566. ;------------------------------------------------------------------------------
  2567. sysfn_set_screen_sizes:
  2568.         cmp     [SCR_MODE], word 0x13
  2569.         jbe     .exit
  2570.  
  2571.         cmp     [_display.select_cursor], select_cursor
  2572.         jne     .exit
  2573.  
  2574.         cmp     ecx, [display_width_standard]
  2575.         ja      .exit
  2576.  
  2577.         cmp     edx, [display_height_standard]
  2578.         ja      .exit
  2579.  
  2580.         pushfd
  2581.         cli
  2582.         mov     eax, ecx
  2583.         mov     ecx, [_display.lfb_pitch]
  2584.         mov     [_display.width], eax
  2585.         dec     eax
  2586.         mov     [_display.height], edx
  2587.         dec     edx
  2588. ; eax - new Screen_Max_X
  2589. ; edx - new Screen_Max_Y
  2590.         mov     [do_not_touch_winmap], 1
  2591.         call    set_screen
  2592.         mov     [do_not_touch_winmap], 0
  2593.         popfd
  2594.         call    change_task
  2595. .exit:
  2596.         ret
  2597. ;------------------------------------------------------------------------------
  2598. uglobal
  2599. screen_workarea RECT
  2600. display_width_standard dd 0
  2601. display_height_standard dd 0
  2602. do_not_touch_winmap db 0
  2603. window_minimize db 0
  2604. sound_flag      db 0
  2605.  
  2606. endg
  2607.  
  2608. UID_NONE=0
  2609. UID_MENUETOS=1   ;official
  2610. UID_KOLIBRI=2    ;russian
  2611.  
  2612. iglobal
  2613. version_inf:
  2614.         db 0,7,7,0  ; version 0.7.7.0
  2615.         db 0
  2616. .rev    dd __REV__
  2617. version_end:
  2618. endg
  2619. ;------------------------------------------------------------------------------
  2620. align 4
  2621. sys_cachetodiskette:
  2622.         cmp     ebx, 1
  2623.         jb      .no_floppy_save
  2624.         cmp     ebx, 2
  2625.         ja      .no_floppy_save
  2626.         call    save_image
  2627.         mov     [esp + 32], eax
  2628.         ret
  2629. .no_floppy_save:
  2630.         mov     [esp + 32], dword 1
  2631.         ret
  2632. ;------------------------------------------------------------------------------
  2633. uglobal
  2634. ;  bgrchanged  dd  0x0
  2635. align 4
  2636. bgrlockpid dd 0
  2637. bgrlock db 0
  2638. endg
  2639. ;------------------------------------------------------------------------------
  2640. align 4
  2641. sys_background:
  2642.         cmp     ebx, 1                     ; BACKGROUND SIZE
  2643.         jnz     nosb1
  2644.         test    ecx, ecx
  2645.         jz      sbgrr
  2646.  
  2647.         test    edx, edx
  2648.         jz      sbgrr
  2649. ;--------------------------------------
  2650. align 4
  2651. @@:
  2652. ;;Maxis use atomic bts for mutexes  4.4.2009
  2653.         bts     dword [bgrlock], 0
  2654.         jnc     @f
  2655.         call    change_task
  2656.         jmp     @b
  2657. ;--------------------------------------
  2658. align 4
  2659. @@:
  2660.         mov     [BgrDataWidth], ecx
  2661.         mov     [BgrDataHeight], edx
  2662. ;    mov   [bgrchanged],1
  2663.  
  2664.         pushad
  2665. ; return memory for old background
  2666.         mov     eax, [img_background]
  2667.         cmp     eax, static_background_data
  2668.         jz      @f
  2669.         stdcall kernel_free, eax
  2670. ;--------------------------------------
  2671. align 4
  2672. @@:
  2673. ; calculate RAW size
  2674.         xor     eax, eax
  2675.         inc     eax
  2676.         cmp     [BgrDataWidth], eax
  2677.         jae     @f
  2678.         mov     [BgrDataWidth], eax
  2679. ;--------------------------------------
  2680. align 4
  2681. @@:
  2682.         cmp     [BgrDataHeight], eax
  2683.         jae     @f
  2684.         mov     [BgrDataHeight], eax
  2685. ;--------------------------------------
  2686. align 4
  2687. @@:
  2688.         mov     eax, [BgrDataWidth]
  2689.         imul    eax, [BgrDataHeight]
  2690.         lea     eax, [eax*3]
  2691. ; it is reserved with aligned to the boundary of 4 KB pages,
  2692. ; otherwise there may be exceptions a page fault for vesa20_drawbackground_tiled
  2693. ; because the 32 bit read is used for  high performance: "mov eax,[esi]"
  2694.         shr     eax, 12
  2695.         inc     eax
  2696.         shl     eax, 12
  2697.         mov     [mem_BACKGROUND], eax
  2698. ; get memory for new background
  2699.         stdcall kernel_alloc, eax
  2700.         test    eax, eax
  2701.         jz      .memfailed
  2702.         mov     [img_background], eax
  2703.         jmp     .exit
  2704. ;--------------------------------------
  2705. align 4
  2706. .memfailed:
  2707. ; revert to static monotone data
  2708.         mov     [img_background], static_background_data
  2709.         xor     eax, eax
  2710.         inc     eax
  2711.         mov     [BgrDataWidth], eax
  2712.         mov     [BgrDataHeight], eax
  2713.         mov     [mem_BACKGROUND], 4
  2714. ;--------------------------------------
  2715. align 4
  2716. .exit:
  2717.         popad
  2718.         mov     [bgrlock], 0
  2719. ;--------------------------------------
  2720. align 4
  2721. sbgrr:
  2722.         ret
  2723. ;------------------------------------------------------------------------------
  2724. align 4
  2725. nosb1:
  2726.         cmp     ebx, 2                     ; SET PIXEL
  2727.         jnz     nosb2
  2728.  
  2729.         mov     eax, [img_background]
  2730.         test    ecx, ecx
  2731.         jz      @f
  2732.         cmp     eax, static_background_data
  2733.         jz      .ret
  2734. ;--------------------------------------
  2735. align 4
  2736. @@:
  2737.         mov     ebx, [mem_BACKGROUND]
  2738.         add     ebx, 4095
  2739.         and     ebx, -4096
  2740.         sub     ebx, 4
  2741.         cmp     ecx, ebx
  2742.         ja      .ret
  2743.  
  2744.         mov     ebx, [eax+ecx]
  2745.         and     ebx, 0xFF000000;255*256*256*256
  2746.         and     edx, 0x00FFFFFF;255*256*256+255*256+255
  2747.         add     edx, ebx
  2748.         mov     [eax+ecx], edx
  2749. ;--------------------------------------
  2750. align 4
  2751. .ret:
  2752.         ret
  2753. ;------------------------------------------------------------------------------
  2754. align 4
  2755. nosb2:
  2756.         cmp     ebx, 3                     ; DRAW BACKGROUND
  2757.         jnz     nosb3
  2758. ;--------------------------------------
  2759. align 4
  2760. draw_background_temp:
  2761.         mov     [background_defined], 1
  2762.         call    force_redraw_background
  2763. ;--------------------------------------
  2764. align 4
  2765. nosb31:
  2766.         ret
  2767. ;------------------------------------------------------------------------------
  2768. align 4
  2769. nosb3:
  2770.         cmp     ebx, 4                     ; TILED / STRETCHED
  2771.         jnz     nosb4
  2772.         cmp     ecx, [BgrDrawMode]
  2773.         je      nosb41
  2774.         mov     [BgrDrawMode], ecx
  2775. ;--------------------------------------
  2776. align 4
  2777. nosb41:
  2778.         ret
  2779. ;------------------------------------------------------------------------------
  2780. align 4
  2781. nosb4:
  2782.         cmp     ebx, 5                     ; BLOCK MOVE TO BGR
  2783.         jnz     nosb5
  2784.         cmp     [img_background], static_background_data
  2785.         jnz     @f
  2786.         test    edx, edx
  2787.         jnz     .fin
  2788.         cmp     esi, 4
  2789.         ja      .fin
  2790. ;--------------------------------------
  2791. align 4
  2792. @@:
  2793.   ; bughere
  2794.         mov     eax, ecx
  2795.         mov     ebx, edx
  2796.         add     ebx, [img_background];IMG_BACKGROUND
  2797.         mov     ecx, esi
  2798.         call    memmove
  2799. ;--------------------------------------
  2800. align 4
  2801. .fin:
  2802.         ret
  2803. ;------------------------------------------------------------------------------
  2804. align 4
  2805. nosb5:
  2806.         cmp     ebx, 6
  2807.         jnz     nosb6
  2808. ;--------------------------------------
  2809. align 4
  2810. ;;Maxis use atomic bts for mutex 4.4.2009
  2811. @@:
  2812.         bts     dword [bgrlock], 0
  2813.         jnc     @f
  2814.         call    change_task
  2815.         jmp     @b
  2816. ;--------------------------------------
  2817. align 4
  2818. @@:
  2819.         mov     eax, [CURRENT_TASK]
  2820.         mov     [bgrlockpid], eax
  2821.         cmp     [img_background], static_background_data
  2822.         jz      .nomem
  2823.         stdcall user_alloc, [mem_BACKGROUND]
  2824.         mov     [esp+32], eax
  2825.         test    eax, eax
  2826.         jz      .nomem
  2827.         mov     ebx, eax
  2828.         shr     ebx, 12
  2829.         or      dword [page_tabs+(ebx-1)*4], DONT_FREE_BLOCK
  2830.         mov     esi, [img_background]
  2831.         shr     esi, 12
  2832.         mov     ecx, [mem_BACKGROUND]
  2833.         add     ecx, 0xFFF
  2834.         shr     ecx, 12
  2835. ;--------------------------------------
  2836. align 4
  2837. .z:
  2838.         mov     eax, [page_tabs+ebx*4]
  2839.         test    al, 1
  2840.         jz      @f
  2841.         call    free_page
  2842. ;--------------------------------------
  2843. align 4
  2844. @@:
  2845.         mov     eax, [page_tabs+esi*4]
  2846.         or      al, PG_UWR
  2847.         mov     [page_tabs+ebx*4], eax
  2848.         mov     eax, ebx
  2849.         shl     eax, 12
  2850.         invlpg  [eax]
  2851.         inc     ebx
  2852.         inc     esi
  2853.         loop    .z
  2854.         ret
  2855. ;--------------------------------------
  2856. align 4
  2857. .nomem:
  2858.         and     [bgrlockpid], 0
  2859.         mov     [bgrlock], 0
  2860. ;------------------------------------------------------------------------------
  2861. align 4
  2862. nosb6:
  2863.         cmp     ebx, 7
  2864.         jnz     nosb7
  2865.         cmp     [bgrlock], 0
  2866.         jz      .err
  2867.         mov     eax, [CURRENT_TASK]
  2868.         cmp     [bgrlockpid], eax
  2869.         jnz     .err
  2870.         mov     eax, ecx
  2871.         mov     ebx, ecx
  2872.         shr     eax, 12
  2873.         mov     ecx, [page_tabs