Subversion Repositories Kolibri OS

Rev

Rev 4265 | Rev 4288 | Go to most recent revision | Blame | Compare with Previous | Last modification | View Log | Download | RSS feed

  1. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  2. ;;
  3. ;; Copyright (C) KolibriOS team 2004-2013. All rights reserved.
  4. ;; PROGRAMMING:
  5. ;; Ivan Poddubny
  6. ;; Marat Zakiyanov (Mario79)
  7. ;; VaStaNi
  8. ;; Trans
  9. ;; Mihail Semenyako (mike.dld)
  10. ;; Sergey Kuzmin (Wildwest)
  11. ;; Andrey Halyavin (halyavin)
  12. ;; Mihail Lisovin (Mihasik)
  13. ;; Andrey Ignatiev (andrew_programmer)
  14. ;; NoName
  15. ;; Evgeny Grechnikov (Diamond)
  16. ;; Iliya Mihailov (Ghost)
  17. ;; Sergey Semyonov (Serge)
  18. ;; Johnny_B
  19. ;; SPraid (simba)
  20. ;; Hidnplayr
  21. ;; Alexey Teplov (<Lrz>)
  22. ;; Rus
  23. ;; Nable
  24. ;; shurf
  25. ;; Alver
  26. ;; Maxis
  27. ;; Galkov
  28. ;; CleverMouse
  29. ;; tsdima
  30. ;; turbanoff
  31. ;; Asper
  32. ;; art_zh
  33. ;;
  34. ;; Data in this file was originally part of MenuetOS project which is
  35. ;; distributed under the terms of GNU GPL. It is modified and redistributed as
  36. ;; part of KolibriOS project under the terms of GNU GPL.
  37. ;;
  38. ;; Copyright (C) MenuetOS 2000-2004 Ville Mikael Turjanmaa
  39. ;; PROGRAMMING:
  40. ;;
  41. ;; Ville Mikael Turjanmaa, villemt@itu.jyu.fi
  42. ;; - main os coding/design
  43. ;; Jan-Michael Brummer, BUZZ2@gmx.de
  44. ;; Felix Kaiser, info@felix-kaiser.de
  45. ;; Paolo Minazzi, paolo.minazzi@inwind.it
  46. ;; quickcode@mail.ru
  47. ;; Alexey, kgaz@crosswinds.net
  48. ;; Juan M. Caravaca, bitrider@wanadoo.es
  49. ;; kristol@nic.fi
  50. ;; Mike Hibbett, mikeh@oceanfree.net
  51. ;; Lasse Kuusijarvi, kuusijar@lut.fi
  52. ;; Jarek Pelczar, jarekp3@wp.pl
  53. ;;
  54. ;; KolibriOS is distributed in the hope that it will be useful, but WITHOUT ANY
  55. ;; WARRANTY. No author or distributor accepts responsibility to anyone for the
  56. ;; consequences of using it or for whether it serves any particular purpose or
  57. ;; works at all, unless he says so in writing. Refer to the GNU General Public
  58. ;; License (the "GPL") for full details.
  59. ;
  60. ;; Everyone is granted permission to copy, modify and redistribute KolibriOS,
  61. ;; but only under the conditions described in the GPL. A copy of this license
  62. ;; is supposed to have been given to you along with KolibriOS so you can know
  63. ;; your rights and responsibilities. It should be in a file named COPYING.
  64. ;; Among other things, the copyright notice and this notice must be preserved
  65. ;; on all copies.
  66. ;;
  67. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  68.  
  69. format binary as "mnt"
  70.  
  71. include 'macros.inc'
  72. include 'struct.inc'
  73.  
  74. $Revision: 4287 $
  75.  
  76.  
  77. USE_COM_IRQ     equ 1      ; make irq 3 and irq 4 available for PCI devices
  78. VESA_1_2_VIDEO equ 0      ; enable vesa 1.2 bank switch functions
  79.  
  80. ; Enabling the next line will enable serial output console
  81. ;debug_com_base  equ 0x3f8  ; 0x3f8 is com1, 0x2f8 is com2, 0x3e8 is com3, 0x2e8 is com4, no irq's are used
  82.  
  83. include "proc32.inc"
  84. include "kglobals.inc"
  85. include "lang.inc"
  86. include "encoding.inc"
  87.  
  88. include "const.inc"
  89.  
  90. iglobal
  91. ; The following variable, if equal to 1, duplicates debug output to the screen.
  92. debug_direct_print db 0
  93. ; Start the first app (LAUNCHER) after kernel is loaded? (1=yes, 2 or 0=no)
  94. launcher_start db 1
  95. endg
  96.  
  97. max_processes   equ   255
  98. tss_step         equ   (128+8192) ; tss & i/o - 65535 ports, * 256=557056*4
  99.  
  100. os_stack       equ  (os_data_l-gdts)    ; GDTs
  101. os_code       equ  (os_code_l-gdts)
  102. graph_data     equ  (3+graph_data_l-gdts)
  103. tss0           equ  (tss0_l-gdts)
  104. app_code       equ  (3+app_code_l-gdts)
  105. app_data       equ  (3+app_data_l-gdts)
  106. app_tls       equ  (3+tls_data_l-gdts)
  107. pci_code_sel   equ  (pci_code_32-gdts)
  108. pci_data_sel   equ  (pci_data_32-gdts)
  109.  
  110.  
  111. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  112. ;;
  113. ;;   Included files:
  114. ;;
  115. ;;   Kernel16.inc
  116. ;;    - Booteng.inc   English text for bootup
  117. ;;    - Bootcode.inc  Hardware setup
  118. ;;    - Pci16.inc     PCI functions
  119. ;;
  120. ;;   Kernel32.inc
  121. ;;    - Sys32.inc     Process management
  122. ;;    - Shutdown.inc  Shutdown and restart
  123. ;;    - Fat32.inc     Read / write hd
  124. ;;    - Vesa12.inc    Vesa 1.2 driver
  125. ;;    - Vesa20.inc    Vesa 2.0 driver
  126. ;;    - Vga.inc       VGA driver
  127. ;;    - Stack.inc     Network interface
  128. ;;    - Mouse.inc     Mouse pointer
  129. ;;    - Scincode.inc  Window skinning
  130. ;;    - Pci32.inc     PCI functions
  131. ;;
  132. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  133.  
  134.  
  135. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  136. ;;                                                                      ;;
  137. ;;                  16 BIT ENTRY FROM BOOTSECTOR                        ;;
  138. ;;                                                                      ;;
  139. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  140.  
  141. use16
  142.                   org   0x0
  143.         jmp     start_of_code
  144.  
  145. if lang eq sp
  146. include "kernelsp.inc"  ; spanish kernel messages
  147. else if lang eq et
  148. version db    'Kolibri OS  versioon 0.7.7.0+    ',13,10,13,10,0
  149. else
  150. version db    'Kolibri OS  version 0.7.7.0+     ',13,10,13,10,0
  151. end if
  152.  
  153. include "boot/bootstr.inc"     ; language-independent boot messages
  154. include "boot/preboot.inc"
  155.  
  156. if lang eq ge
  157. include "boot/bootge.inc"     ; german system boot messages
  158. else if lang eq sp
  159. include "boot/bootsp.inc"     ; spanish system boot messages
  160. else if lang eq ru
  161. include "boot/bootru.inc"      ; russian system boot messages
  162. include "boot/ru.inc"          ; Russian font
  163. else if lang eq et
  164. include "boot/bootet.inc"      ; estonian system boot messages
  165. include "boot/et.inc"          ; Estonian font
  166. else
  167. include "boot/booten.inc"      ; english system boot messages
  168. end if
  169.  
  170. include "boot/bootcode.inc"    ; 16 bit system boot code
  171. include "bus/pci/pci16.inc"
  172. include "detect/biosdisk.inc"
  173.  
  174. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  175. ;;                                                                      ;;
  176. ;;                  SWITCH TO 32 BIT PROTECTED MODE                     ;;
  177. ;;                                                                      ;;
  178. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  179.  
  180.  
  181. ; CR0 Flags - Protected mode and Paging
  182.  
  183.         mov     ecx, CR0_PE
  184.  
  185. ; Enabling 32 bit protected mode
  186.  
  187.         sidt    [cs:old_ints_h]
  188.  
  189.         cli                             ; disable all irqs
  190.         cld
  191.         mov     al, 255                 ; mask all irqs
  192.         out     0xa1, al
  193.         out     0x21, al
  194.    l.5:
  195.         in      al, 0x64                ; Enable A20
  196.         test    al, 2
  197.         jnz     l.5
  198.         mov     al, 0xD1
  199.         out     0x64, al
  200.    l.6:
  201.         in      al, 0x64
  202.         test    al, 2
  203.         jnz     l.6
  204.         mov     al, 0xDF
  205.         out     0x60, al
  206.    l.7:
  207.         in      al, 0x64
  208.         test    al, 2
  209.         jnz     l.7
  210.         mov     al, 0xFF
  211.         out     0x64, al
  212.  
  213.         lgdt    [cs:tmp_gdt]            ; Load GDT
  214.         mov     eax, cr0                ; protected mode
  215.         or      eax, ecx
  216.         and     eax, 10011111b *65536*256 + 0xffffff ; caching enabled
  217.         mov     cr0, eax
  218.         jmp     pword os_code:B32       ; jmp to enable 32 bit mode
  219.  
  220. align 8
  221. tmp_gdt:
  222.  
  223.         dw     23
  224.         dd     tmp_gdt+0x10000
  225.         dw     0
  226.  
  227.         dw     0xffff
  228.         dw     0x0000
  229.         db     0x00
  230.         dw     11011111b *256 +10011010b
  231.         db     0x00
  232.  
  233.         dw     0xffff
  234.         dw     0x0000
  235.         db     0x00
  236.         dw     11011111b *256 +10010010b
  237.         db     0x00
  238.  
  239. include "data16.inc"
  240.  
  241. if ~ lang eq sp
  242. diff16 "end of bootcode",0,$+0x10000
  243. end if
  244.  
  245. use32
  246. org $+0x10000
  247.  
  248. align 4
  249. B32:
  250.         mov     ax, os_stack       ; Selector for os
  251.         mov     ds, ax
  252.         mov     es, ax
  253.         mov     fs, ax
  254.         mov     gs, ax
  255.         mov     ss, ax
  256.         mov     esp, 0x006CC00       ; Set stack
  257.  
  258. ; CLEAR 0x280000 - HEAP_BASE
  259.  
  260.         xor     eax, eax
  261.         mov     edi, CLEAN_ZONE
  262.         mov     ecx, (HEAP_BASE-OS_BASE-CLEAN_ZONE) / 4
  263.         cld
  264.         rep stosd
  265.  
  266. ; CLEAR KERNEL UNDEFINED GLOBALS
  267.         mov     edi, endofcode-OS_BASE
  268.         mov     ecx, 0x90000
  269.         sub     ecx, edi
  270.         shr     ecx, 2
  271.         rep stosd
  272.  
  273. ; SAVE & CLEAR 0-0xffff
  274.  
  275.         mov     edi, 0x1000
  276.         mov     ecx, 0x8000 / 4
  277.         rep stosd
  278.         mov     edi, 0xa000
  279.         mov     ecx, 0x6000 / 4
  280.         rep stosd
  281.  
  282.         call    test_cpu
  283.         bts     [cpu_caps-OS_BASE], CAPS_TSC    ;force use rdtsc
  284.  
  285.         call    check_acpi
  286.         call    init_BIOS32
  287. ; MEMORY MODEL
  288.         call    mem_test
  289.         call    init_mem
  290.         call    init_page_map
  291.  
  292. ; ENABLE PAGING
  293.  
  294.         mov     eax, sys_pgdir-OS_BASE
  295.         mov     cr3, eax
  296.  
  297.         mov     eax, cr0
  298.         or      eax, CR0_PG+CR0_WP
  299.         mov     cr0, eax
  300.  
  301.         lgdt    [gdts]
  302.         jmp     pword os_code:high_code
  303.  
  304. align 4
  305. bios32_entry    dd ?
  306. tmp_page_tabs   dd ?
  307.  
  308. use16
  309. org $-0x10000
  310. include "boot/shutdown.inc" ; shutdown or restart
  311. org $+0x10000
  312. use32
  313.  
  314. __DEBUG__ fix 1
  315. __DEBUG_LEVEL__ fix 1
  316. include 'init.inc'
  317.  
  318. org OS_BASE+$
  319.  
  320. include 'fdo.inc'
  321.  
  322. align 4
  323. high_code:
  324.         mov     ax, os_stack
  325.         mov     bx, app_data
  326.         mov     cx, app_tls
  327.         mov     ss, ax
  328.         add     esp, OS_BASE
  329.  
  330.         mov     ds, bx
  331.         mov     es, bx
  332.         mov     fs, cx
  333.         mov     gs, bx
  334.  
  335.         bt      [cpu_caps], CAPS_PGE
  336.         jnc     @F
  337.  
  338.         or      dword [sys_pgdir+(OS_BASE shr 20)], PG_GLOBAL
  339.  
  340.         mov     ebx, cr4
  341.         or      ebx, CR4_PGE
  342.         mov     cr4, ebx
  343. @@:
  344.         xor     eax, eax
  345.         mov     dword [sys_pgdir], eax
  346.         mov     dword [sys_pgdir+4], eax
  347.  
  348.         mov     eax, cr3
  349.         mov     cr3, eax          ; flush TLB
  350.  
  351.         mov     ecx, pg_data.mutex
  352.         call    mutex_init
  353.  
  354.         mov     ecx, disk_list_mutex
  355.         call    mutex_init
  356.  
  357.         mov     ecx, keyboard_list_mutex
  358.         call    mutex_init
  359.  
  360.         mov     ecx, unpack_mutex
  361.         call    mutex_init
  362.  
  363.         mov     ecx, application_table_mutex
  364.         call    mutex_init
  365.  
  366.         mov     ecx, ide_mutex
  367.         call    mutex_init
  368.         mov     ecx, ide_channel1_mutex
  369.         call    mutex_init
  370.         mov     ecx, ide_channel2_mutex
  371.         call    mutex_init
  372. ;-----------------------------------------------------------------------------
  373. ; SAVE REAL MODE VARIABLES
  374. ;-----------------------------------------------------------------------------
  375. save_variables_IDE_controller:
  376.         xor     eax, eax
  377.         mov     ax, [BOOT_VARS + BOOT_IDE_INTERR_16]
  378.         mov     [IDE_Interrupt], ax
  379. ;--------------------------------------
  380.         mov     ax, [BOOT_VARS + BOOT_IDE_PI_16]
  381.         mov     [IDEContrProgrammingInterface], ax
  382. ;--------------------------------------
  383.         mov     ax, [BOOT_VARS + BOOT_IDE_BASE_ADDR]
  384.         mov     [IDEContrRegsBaseAddr], ax
  385. ;--------------------------------------
  386.         mov     ax, [BOOT_VARS + BOOT_IDE_BAR0_16]
  387.         cmp     ax, 0
  388.         je      @f
  389.         cmp     ax, 1
  390.         jne     .no_PATA_BAR0
  391. @@:
  392.         mov     ax, 0x1F0
  393.         jmp     @f
  394. .no_PATA_BAR0:
  395.         and     ax, 0xFFFC
  396. @@:
  397.         mov     [StandardATABases], ax
  398.         mov     [hd_address_table], eax
  399.         mov     [hd_address_table+8], eax
  400.         mov     [IDE_BAR0_val], ax
  401. ;--------------------------------------
  402.         mov     ax, [BOOT_VARS + BOOT_IDE_BAR1_16]
  403.         cmp     ax, 0
  404.         je      @f
  405.         cmp     ax, 1
  406.         jne     .no_PATA_BAR1
  407. @@:
  408.         mov     ax, 0x3F4
  409.         jmp     @f
  410. .no_PATA_BAR1:
  411.         and     ax, 0xFFFC
  412. @@:
  413.         mov     [IDE_BAR1_val], ax
  414. ;--------------------------------------
  415.         mov     ax, [BOOT_VARS + BOOT_IDE_BAR2_16]
  416.         cmp     ax, 0
  417.         je      @f
  418.         cmp     ax, 1
  419.         jne     .no_PATA_BAR2
  420. @@:
  421.         mov     ax, 0x170
  422.         jmp     @f
  423. .no_PATA_BAR2:
  424.         and     ax, 0xFFFC
  425. @@:
  426.         mov     [StandardATABases+2], ax
  427.         mov     [hd_address_table+16], eax
  428.         mov     [hd_address_table+24], eax
  429.         mov     [IDE_BAR2_val], ax
  430. ;--------------------------------------
  431.         mov     ax, [BOOT_VARS + BOOT_IDE_BAR3_16]
  432.         cmp     ax, 0
  433.         je      @f
  434.         cmp     ax, 1
  435.         jne     .no_PATA_BAR3
  436. @@:
  437.         mov     ax, 0x374
  438.         jmp     @f
  439. .no_PATA_BAR3:
  440.         and     ax, 0xFFFC
  441. @@:
  442.         mov     [IDE_BAR3_val], ax
  443.  
  444. ; --------------- APM ---------------------
  445.  
  446. ; init selectors
  447.         mov     ebx, [BOOT_VARS+BOOT_APM_ENTRY]        ; offset of APM entry point
  448.         movzx   eax, word [BOOT_VARS+BOOT_APM_CODE_32] ; real-mode segment base address of
  449.                                                                                 ; protected-mode 32-bit code segment
  450.         movzx   ecx, word [BOOT_VARS+BOOT_APM_CODE_16]; real-mode segment base address of
  451.                                                                                 ; protected-mode 16-bit code segment
  452.         movzx   edx, word [BOOT_VARS+BOOT_APM_DATA_16]; real-mode segment base address of
  453.                                                                                 ; protected-mode 16-bit data segment
  454.  
  455.         shl     eax, 4
  456.         mov     [dword apm_code_32 + 2], ax
  457.         shr     eax, 16
  458.         mov     [dword apm_code_32 + 4], al
  459.  
  460.         shl     ecx, 4
  461.         mov     [dword apm_code_16 + 2], cx
  462.         shr     ecx, 16
  463.         mov     [dword apm_code_16 + 4], cl
  464.  
  465.         shl     edx, 4
  466.         mov     [dword apm_data_16 + 2], dx
  467.         shr     edx, 16
  468.         mov     [dword apm_data_16 + 4], dl
  469.  
  470.         mov     dword[apm_entry], ebx
  471.         mov     word [apm_entry + 4], apm_code_32 - gdts
  472.  
  473.         mov     eax, [BOOT_VARS + BOOT_APM_VERSION] ; version & flags
  474.         mov     [apm_vf], eax
  475. ; -----------------------------------------
  476.         mov     al, [BOOT_VARS+BOOT_DMA]            ; DMA access
  477.         mov     [allow_dma_access], al
  478.         movzx   eax, byte [BOOT_VARS+BOOT_BPP]      ; bpp
  479.         mov     [_display.bpp], eax
  480.         mov     [_display.vrefresh], 60
  481.         mov     al, [BOOT_VARS+BOOT_DEBUG_PRINT]    ; If nonzero, duplicates debug output to the screen
  482.         mov     [debug_direct_print], al
  483.         mov     al, [BOOT_VARS+BOOT_LAUNCHER_START] ; Start the first app (LAUNCHER) after kernel is loaded?
  484.         mov     [launcher_start], al
  485.         movzx   eax, word [BOOT_VARS+BOOT_X_RES]; X max
  486.         mov     [_display.width], eax
  487.         mov     [display_width_standard], eax
  488.         dec     eax
  489.         mov     [Screen_Max_X], eax
  490.         mov     [screen_workarea.right], eax
  491.         movzx   eax, word [BOOT_VARS+BOOT_Y_RES]; Y max
  492.         mov     [_display.height], eax
  493.         mov     [display_height_standard], eax
  494.         dec     eax
  495.         mov     [Screen_Max_Y], eax
  496.         mov     [screen_workarea.bottom], eax
  497.         movzx   eax, word [BOOT_VARS+BOOT_VESA_MODE] ; screen mode
  498.         mov     dword [SCR_MODE], eax
  499. ;        mov     eax, [BOOT_VAR+0x9014]             ; Vesa 1.2 bnk sw add
  500. ;        mov     [BANK_SWITCH], eax
  501.         mov     eax, 640 *4                         ; Bytes PerScanLine
  502.         cmp     [SCR_MODE], word 0x13               ; 320x200
  503.         je      @f
  504.         cmp     [SCR_MODE], word 0x12               ; VGA 640x480
  505.         je      @f
  506.         movzx   eax, word[BOOT_VARS+BOOT_PITCH]      ; for other modes
  507. @@:
  508.         mov     [_display.pitch], eax
  509.         mov     eax, [_display.width]
  510.         mul     [_display.height]
  511.         mov     [_WinMapSize], eax
  512.  
  513.         call    calculate_fast_getting_offset_for_WinMapAddress
  514. ; for Qemu or non standart video cards
  515. ; Unfortunately [BytesPerScanLine] does not always
  516. ;                             equal to [_display.width] * [ScreenBPP] / 8
  517.         call    calculate_fast_getting_offset_for_LFB
  518.  
  519.         mov     esi, BOOT_VARS+0x9080
  520.         movzx   ecx, byte [esi-1]
  521.         mov     [NumBiosDisks], ecx
  522.         mov     edi, BiosDisksData
  523.         rep movsd
  524.  
  525. ; GRAPHICS ADDRESSES
  526.  
  527.         mov     eax, [BOOT_VARS+BOOT_LFB]
  528.         mov     [LFBAddress], eax
  529.  
  530.         cmp     [SCR_MODE], word 0100000000000000b
  531.         jge     setvesa20
  532.         cmp     [SCR_MODE], word 0x13  ; EGA 320*200 256 colors
  533.         je      v20ga32
  534.         jmp     v20ga24
  535.  
  536. setvesa20:
  537.         mov     [PUTPIXEL], dword Vesa20_putpixel24 ; Vesa 2.0
  538.         mov     [GETPIXEL], dword Vesa20_getpixel24
  539.         cmp     byte [_display.bpp], 24
  540.         jz      v20ga24
  541. v20ga32:
  542.         mov     [PUTPIXEL], dword Vesa20_putpixel32
  543.         mov     [GETPIXEL], dword Vesa20_getpixel32
  544.         jmp     no_mode_0x12
  545. v20ga24:
  546.         cmp     [SCR_MODE], word 0x12               ; 16 C VGA 640x480
  547.         jne     no_mode_0x12
  548.         mov     [PUTPIXEL], dword VGA_putpixel
  549.         mov     [GETPIXEL], dword Vesa20_getpixel32
  550. no_mode_0x12:
  551.  
  552.         mov     [MOUSE_PICTURE], dword mousepointer
  553.         mov     [_display.check_mouse], check_mouse_area_for_putpixel
  554.         mov     [_display.check_m_pixel], check_mouse_area_for_getpixel
  555.  
  556. ; -------- Fast System Call init ----------
  557. ; Intel SYSENTER/SYSEXIT (AMD CPU support it too)
  558.         bt      [cpu_caps], CAPS_SEP
  559.         jnc     .SEnP  ; SysEnter not Present
  560.         xor     edx, edx
  561.         mov     ecx, MSR_SYSENTER_CS
  562.         mov     eax, os_code
  563.         wrmsr
  564.         mov     ecx, MSR_SYSENTER_ESP
  565. ;           mov eax, sysenter_stack ; Check it
  566.         xor     eax, eax
  567.         wrmsr
  568.         mov     ecx, MSR_SYSENTER_EIP
  569.         mov     eax, sysenter_entry
  570.         wrmsr
  571. .SEnP:
  572. ; AMD SYSCALL/SYSRET
  573.         cmp     byte[cpu_vendor], 'A'
  574.         jne     .noSYSCALL
  575.         mov     eax, 0x80000001
  576.         cpuid
  577.         test    edx, 0x800  ; bit_11 - SYSCALL/SYSRET support
  578.         jz      .noSYSCALL
  579.         mov     ecx, MSR_AMD_EFER
  580.         rdmsr
  581.         or      eax, 1 ; bit_0 - System Call Extension (SCE)
  582.         wrmsr
  583.  
  584.         ; !!!! It`s dirty hack, fix it !!!
  585.         ; Bits of EDX :
  586.         ; Bit 31–16 During the SYSRET instruction, this field is copied into the CS register
  587.         ;  and the contents of this field, plus 8, are copied into the SS register.
  588.         ; Bit 15–0 During the SYSCALL instruction, this field is copied into the CS register
  589.         ;  and the contents of this field, plus 8, are copied into the SS register.
  590.  
  591.         ; mov   edx, (os_code + 16) * 65536 + os_code
  592.         mov     edx, 0x1B0008
  593.  
  594.         mov     eax, syscall_entry
  595.         mov     ecx, MSR_AMD_STAR
  596.         wrmsr
  597. .noSYSCALL:
  598. ; -----------------------------------------
  599.         stdcall alloc_page
  600.         stdcall map_page, tss-0xF80, eax, PG_SW
  601.         stdcall alloc_page
  602.         stdcall map_page, tss+0x80, eax, PG_SW
  603.         stdcall alloc_page
  604.         stdcall map_page, tss+0x1080, eax, PG_SW
  605.  
  606. ; LOAD IDT
  607.  
  608.         call    build_interrupt_table ;lidt is executed
  609.           ;lidt [idtreg]
  610.  
  611.         call    init_kernel_heap
  612.         stdcall kernel_alloc, (RING0_STACK_SIZE+512) * 2
  613.         mov     [os_stack_seg], eax
  614.  
  615.         lea     esp, [eax+RING0_STACK_SIZE]
  616.  
  617.         mov     [tss._ss0], os_stack
  618.         mov     [tss._esp0], esp
  619.         mov     [tss._esp], esp
  620.         mov     [tss._cs], os_code
  621.         mov     [tss._ss], os_stack
  622.         mov     [tss._ds], app_data
  623.         mov     [tss._es], app_data
  624.         mov     [tss._fs], app_data
  625.         mov     [tss._gs], app_data
  626.         mov     [tss._io], 128
  627. ;Add IO access table - bit array of permitted ports
  628.         mov     edi, tss._io_map_0
  629.         xor     eax, eax
  630.         not     eax
  631.         mov     ecx, 8192/4
  632.         rep stosd                    ; access to 4096*8=65536 ports
  633.  
  634.         mov     ax, tss0
  635.         ltr     ax
  636.  
  637.         mov     [LFBSize], 0xC00000
  638.         call    init_LFB
  639.         call    init_fpu
  640.         call    init_malloc
  641.  
  642.         stdcall alloc_kernel_space, 0x51000
  643.         mov     [default_io_map], eax
  644.  
  645.         add     eax, 0x2000
  646.         mov     [ipc_tmp], eax
  647.         mov     ebx, 0x1000
  648.  
  649.         add     eax, 0x40000
  650.         mov     [proc_mem_map], eax
  651.  
  652.         add     eax, 0x8000
  653.         mov     [proc_mem_pdir], eax
  654.  
  655.         add     eax, ebx
  656.         mov     [proc_mem_tab], eax
  657.  
  658.         add     eax, ebx
  659.         mov     [tmp_task_pdir], eax
  660.  
  661.         add     eax, ebx
  662.         mov     [tmp_task_ptab], eax
  663.  
  664.         add     eax, ebx
  665.         mov     [ipc_pdir], eax
  666.  
  667.         add     eax, ebx
  668.         mov     [ipc_ptab], eax
  669.  
  670.         stdcall kernel_alloc, (unpack.LZMA_BASE_SIZE+(unpack.LZMA_LIT_SIZE shl \
  671.                 (unpack.lc+unpack.lp)))*4
  672.  
  673.         mov     [unpack.p], eax
  674.  
  675.         call    init_events
  676.         mov     eax, srv.fd-SRV.fd
  677.         mov     [srv.fd], eax
  678.         mov     [srv.bk], eax
  679.  
  680. ;Set base of graphic segment to linear address of LFB
  681.         mov     eax, [LFBAddress]         ; set for gs
  682.         mov     [graph_data_l+2], ax
  683.         shr     eax, 16
  684.         mov     [graph_data_l+4], al
  685.         mov     [graph_data_l+7], ah
  686.  
  687.         stdcall kernel_alloc, [_WinMapSize]
  688.         mov     [_WinMapAddress], eax
  689.  
  690.         xor     eax, eax
  691.         inc     eax
  692.  
  693. ; set background
  694.  
  695.         mov     [BgrDrawMode], eax
  696.         mov     [BgrDataWidth], eax
  697.         mov     [BgrDataHeight], eax
  698.         mov     [mem_BACKGROUND], 4
  699.         mov     [img_background], static_background_data
  700.  
  701. ; set clipboard
  702.  
  703.         xor     eax, eax
  704.         mov     [clipboard_slots], eax
  705.         mov     [clipboard_write_lock], eax
  706.         stdcall kernel_alloc, 4096
  707.         test    eax, eax
  708.         jnz     @f
  709.  
  710.         dec     eax
  711. @@:
  712.         mov     [clipboard_main_list], eax
  713.  
  714. ; SET UP OS TASK
  715.  
  716.         mov     esi, boot_setostask
  717.         call    boot_log
  718.  
  719.         mov     edx, SLOT_BASE+256
  720.         mov     ebx, [os_stack_seg]
  721.         add     ebx, 0x2000
  722.         call    setup_os_slot
  723.         mov     dword [edx], 'IDLE'
  724.         sub     [edx+APPDATA.saved_esp], 4
  725.         mov     eax, [edx+APPDATA.saved_esp]
  726.         mov     dword [eax], idle_thread
  727.         mov     ecx, IDLE_PRIORITY
  728.         call    scheduler_add_thread
  729.  
  730.         mov     edx, SLOT_BASE+256*2
  731.         mov     ebx, [os_stack_seg]
  732.         call    setup_os_slot
  733.         mov     dword [edx], 'OS'
  734.         xor     ecx, ecx
  735.         call    scheduler_add_thread
  736.  
  737.         mov     dword [CURRENT_TASK], 2
  738.         mov     dword [TASK_COUNT], 2
  739.         mov     dword [current_slot], SLOT_BASE + 256*2
  740.         mov     dword [TASK_BASE], CURRENT_TASK + 32*2
  741.  
  742.  
  743. ; REDIRECT ALL IRQ'S TO INT'S 0x20-0x2f
  744.         mov     esi, boot_initirq
  745.         call    boot_log
  746.         call    init_irqs
  747.  
  748.         mov     esi, boot_picinit
  749.         call    boot_log
  750.         call    PIC_init
  751.  
  752.         mov     esi, boot_v86machine
  753.         call    boot_log
  754. ; Initialize system V86 machine
  755.         call    init_sys_v86
  756.  
  757.         mov     esi, boot_inittimer
  758.         call    boot_log
  759. ; Initialize system timer (IRQ0)
  760.         call    PIT_init
  761.  
  762. ; Register ramdisk file system
  763.         mov     esi, boot_initramdisk
  764.         call    boot_log
  765.         call    ramdisk_init
  766.  
  767.         mov     esi, boot_initapic
  768.         call    boot_log
  769. ; Try to Initialize APIC
  770.         call    APIC_init
  771.  
  772.         mov     esi, boot_enableirq
  773.         call    boot_log
  774. ; Enable timer IRQ (IRQ0) and co-processor IRQ (IRQ13)
  775. ; they are used: when partitions are scanned, hd_read relies on timer
  776.         call    unmask_timer
  777.         stdcall enable_irq, 2               ; @#$%! PIC
  778.         stdcall enable_irq, 13              ; co-processor
  779.  
  780.         cmp     [IDEContrProgrammingInterface], 0
  781.         je      @f
  782.  
  783.         mov     esi, boot_disabling_ide
  784.         call    boot_log
  785. ;--------------------------------------
  786. ; Disable IDE interrupts, because the search
  787. ; for IDE partitions is in the PIO mode.
  788. ;--------------------------------------
  789. .disable_IDE_interrupt:
  790. ; Disable interrupts in IDE controller for PIO
  791.         mov     al, 2
  792.         mov     dx, [IDE_BAR1_val] ;0x3F4
  793.         add     dx, 2 ;0x3F6
  794.         out     dx, al
  795.         mov     dx, [IDE_BAR3_val] ;0x374
  796.         add     dx, 2 ;0x376
  797.         out     dx, al
  798. @@:
  799. ;-----------------------------------------------------------------------------
  800. ;!!!!!!!!!!!!!!!!!!!!!!!!!!
  801. ;        mov     esi, boot_detectdisks
  802. ;        call    boot_log
  803. ;include 'detect/disks.inc'
  804.         mov     esi, boot_detectfloppy
  805.         call    boot_log
  806. include 'detect/dev_fd.inc'
  807.         mov     esi, boot_detecthdcd
  808.         call    boot_log
  809. include 'detect/dev_hdcd.inc'
  810.         mov     esi, boot_getcache
  811.         call    boot_log
  812. include 'detect/getcache.inc'
  813.         mov     esi, boot_detectpart
  814.         call    boot_log
  815. include 'detect/sear_par.inc'
  816. ;!!!!!!!!!!!!!!!!!!!!!!!!!!
  817.  
  818.         mov     esi, boot_init_sys
  819.         call    boot_log
  820.         call    Parser_params
  821.  
  822. if ~ defined extended_primary_loader
  823. ; ramdisk image should be loaded by extended primary loader if it exists
  824. ; READ RAMDISK IMAGE FROM HD
  825.  
  826. ;!!!!!!!!!!!!!!!!!!!!!!!
  827. include 'boot/rdload.inc'
  828. ;!!!!!!!!!!!!!!!!!!!!!!!
  829. end if
  830. ;    mov    [dma_hdd],1
  831.  
  832. if 0
  833.         mov     ax, [OS_BASE+0x10000+bx_from_load]
  834.         cmp     ax, 'r1'; if using not ram disk, then load librares and parameters {SPraid.simba}
  835.         je      no_lib_load
  836.  
  837.         mov     esi, boot_loadlibs
  838.         call    boot_log
  839. ; LOADING LIBRARES
  840.         stdcall dll.Load, @IMPORT           ; loading librares for kernel (.obj files)
  841.         call    load_file_parse_table       ; prepare file parse table
  842.         call    set_kernel_conf             ; configure devices and gui
  843. no_lib_load:
  844. end if
  845.  
  846. ; Display APIC status
  847.         mov     esi, boot_APIC_found
  848.         cmp     [irq_mode], IRQ_APIC
  849.         je      @f
  850.         mov     esi, boot_APIC_nfound
  851. @@:
  852.         call    boot_log
  853.  
  854. ; PRINT AMOUNT OF MEMORY
  855.         mov     esi, boot_memdetect
  856.         call    boot_log
  857.  
  858.         movzx   ecx, word [boot_y]
  859.         if lang eq ru
  860.         or      ecx, (10+30*6) shl 16
  861.         else if lang eq sp
  862.         or      ecx, (10+33*6) shl 16
  863.         else
  864.         or      ecx, (10+29*6) shl 16
  865.         end if
  866.         sub     ecx, 10
  867.         mov     edx, 0xFFFFFF
  868.         mov     ebx, [MEM_AMOUNT]
  869.         shr     ebx, 20
  870.         xor     edi, edi
  871.         mov     eax, 0x00040000
  872.         inc     edi
  873.         call    display_number_force
  874.  
  875. ; BUILD SCHEDULER
  876.  
  877. ;        call    build_scheduler; sys32.inc
  878.  
  879. ;        mov     esi, boot_devices
  880. ;        call    boot_log
  881.  
  882.         mov     [pci_access_enabled], 1
  883.         call    pci_enum
  884.  
  885.         stdcall load_driver, szVidintel
  886.  
  887.         call    usb_init
  888.  
  889. ; SET PRELIMINARY WINDOW STACK AND POSITIONS
  890.  
  891.         mov     esi, boot_windefs
  892.         call    boot_log
  893.         call    set_window_defaults
  894.  
  895. ; SET BACKGROUND DEFAULTS
  896.  
  897.         mov     esi, boot_bgr
  898.         call    boot_log
  899.         call    init_background
  900.         call    calculatebackground
  901.  
  902. ; RESERVE SYSTEM IRQ'S JA PORT'S
  903.  
  904.         mov     esi, boot_resirqports
  905.         call    boot_log
  906.         call    reserve_irqs_ports
  907.  
  908.         call    init_display
  909.         mov     eax, [def_cursor]
  910.         mov     [SLOT_BASE+APPDATA.cursor+256], eax
  911.         mov     [SLOT_BASE+APPDATA.cursor+256*2], eax
  912.  
  913. ; PRINT CPU FREQUENCY
  914.  
  915.         mov     esi, boot_cpufreq
  916.         call    boot_log
  917.  
  918.         cli                         ;FIXME check IF
  919.         rdtsc
  920.         mov     ecx, eax
  921.         mov     esi, 250            ; wait 1/4 a second
  922.         call    delay_ms
  923.         rdtsc
  924.  
  925.         sub     eax, ecx
  926.         xor     edx, edx
  927.         shld    edx, eax, 2
  928.         shl     eax, 2
  929.         mov     dword [cpu_freq], eax
  930.         mov     dword [cpu_freq+4], edx
  931.         mov     ebx, 1000000
  932.         div     ebx
  933.         mov     ebx, eax
  934.  
  935.         movzx   ecx, word [boot_y]
  936.         if lang eq ru
  937.         add     ecx, (10+19*6) shl 16 - 10
  938.         else if lang eq sp
  939.         add     ecx, (10+25*6) shl 16 - 10
  940.         else
  941.         add     ecx, (10+17*6) shl 16 - 10
  942.         end if
  943.  
  944.         mov     edx, 0xFFFFFF
  945.         xor     edi, edi
  946.         mov     eax, 0x00040000
  947.         inc     edi
  948.         call    display_number_force
  949.  
  950. ; SET VARIABLES
  951.  
  952.         call    set_variables
  953.  
  954. ; STACK AND FDC
  955.  
  956.         call    stack_init
  957.         call    fdc_init
  958.  
  959. ; PALETTE FOR 320x200 and 640x480 16 col
  960.  
  961.         cmp     [SCR_MODE], word 0x12
  962.         jne     no_pal_vga
  963.         mov     esi, boot_pal_vga
  964.         call    boot_log
  965.         call    paletteVGA
  966.       no_pal_vga:
  967.  
  968.         cmp     [SCR_MODE], word 0x13
  969.         jne     no_pal_ega
  970.         mov     esi, boot_pal_ega
  971.         call    boot_log
  972.         call    palette320x200
  973.       no_pal_ega:
  974.  
  975. ; LOAD DEFAULT SKIN
  976.  
  977.         call    load_default_skin
  978.  
  979. ;protect io permission map
  980.  
  981.         mov     esi, [default_io_map]
  982.         stdcall map_page, esi, [SLOT_BASE+256+APPDATA.io_map], PG_MAP
  983.         add     esi, 0x1000
  984.         stdcall map_page, esi, [SLOT_BASE+256+APPDATA.io_map+4], PG_MAP
  985.  
  986.         stdcall map_page, tss._io_map_0, \
  987.                 [SLOT_BASE+256+APPDATA.io_map], PG_MAP
  988.         stdcall map_page, tss._io_map_1, \
  989.                 [SLOT_BASE+256+APPDATA.io_map+4], PG_MAP
  990.  
  991. ; LOAD FIRST APPLICATION
  992.         cmp     byte [launcher_start], 1        ; Check if starting LAUNCHER is selected on blue screen (1 = yes)
  993.         jnz     first_app_found
  994.  
  995.         cli
  996.         mov     ebp, firstapp
  997.         call    fs_execute_from_sysdir
  998.         test    eax, eax
  999.         jns     first_app_found
  1000.  
  1001.         mov     esi, boot_failed
  1002.         call    boot_log
  1003.  
  1004.         mov     eax, 0xDEADBEEF      ; otherwise halt
  1005.         hlt
  1006.  
  1007. first_app_found:
  1008.  
  1009.         cli
  1010.  
  1011. ; SET KEYBOARD PARAMETERS
  1012.         mov     al, 0xf6       ; reset keyboard, scan enabled
  1013.         call    kb_write
  1014.         test    ah, ah
  1015.         jnz     .no_keyboard
  1016.  
  1017.         ; wait until 8042 is ready
  1018.         xor     ecx, ecx
  1019.       @@:
  1020.         in      al, 64h
  1021.         and     al, 00000010b
  1022.         loopnz  @b
  1023.  
  1024. iglobal
  1025. align 4
  1026. ps2_keyboard_functions:
  1027.         dd      .end - $
  1028.         dd      0       ; no close
  1029.         dd      ps2_set_lights
  1030. .end:
  1031. endg
  1032.         stdcall register_keyboard, ps2_keyboard_functions, 0
  1033.        ; mov   al, 0xED       ; Keyboard LEDs - only for testing!
  1034.        ; call  kb_write
  1035.        ; call  kb_read
  1036.        ; mov   al, 111b
  1037.        ; call  kb_write
  1038.        ; call  kb_read
  1039.  
  1040.         mov     al, 0xF3     ; set repeat rate & delay
  1041.         call    kb_write
  1042. ;        call  kb_read
  1043.         mov     al, 0; 30 250 ;00100010b ; 24 500  ;00100100b  ; 20 500
  1044.         call    kb_write
  1045. ;        call  kb_read
  1046.      ;// mike.dld [
  1047.         call    set_lights
  1048.      ;// mike.dld ]
  1049.         stdcall attach_int_handler, 1, irq1, 0
  1050.         DEBUGF  1, "K : IRQ1 error code %x\n", eax
  1051. .no_keyboard:
  1052.  
  1053. ; SET MOUSE
  1054.  
  1055.         stdcall load_driver, szPS2MDriver
  1056. ;        stdcall load_driver, szCOM_MDriver
  1057.  
  1058.         mov     esi, boot_setmouse
  1059.         call    boot_log
  1060.         call    setmouse
  1061.  
  1062. ; Setup serial output console (if enabled)
  1063.  
  1064. if defined debug_com_base
  1065.  
  1066.         ; enable Divisor latch
  1067.  
  1068.         mov     dx, debug_com_base+3
  1069.         mov     al, 1 shl 7
  1070.         out     dx, al
  1071.  
  1072.         ; Set speed to 115200 baud (max speed)
  1073.  
  1074.         mov     dx, debug_com_base
  1075.         mov     al, 0x01
  1076.         out     dx, al
  1077.  
  1078.         mov     dx, debug_com_base+1
  1079.         mov     al, 0x00
  1080.         out     dx, al
  1081.  
  1082.         ; No parity, 8bits words, one stop bit, dlab bit back to 0
  1083.  
  1084.         mov     dx, debug_com_base+3
  1085.         mov     al, 3
  1086.         out     dx, al
  1087.  
  1088.         ; disable interrupts
  1089.  
  1090.         mov     dx, debug_com_base+1
  1091.         mov     al, 0
  1092.         out     dx, al
  1093.  
  1094.         ; clear +  enable fifo (64 bits)
  1095.  
  1096.         mov     dx, debug_com_base+2
  1097.         mov     al, 0x7 + 1 shl 5
  1098.         out     dx, al
  1099.  
  1100.  
  1101. end if
  1102.         mov     eax, [version_inf.rev]
  1103.         DEBUGF  1, "K : kernel SVN r%d\n", eax
  1104.  
  1105.         mov     eax, [cpu_count]
  1106.         test    eax, eax
  1107.         jnz     @F
  1108.         mov     al, 1                             ; at least one CPU
  1109. @@:
  1110.         DEBUGF  1, "K : %d CPU detected\n", eax
  1111.  
  1112. include "detect/vortex86.inc"                     ; Vortex86 SoC detection code
  1113.  
  1114.         DEBUGF  1, "K : BAR0 %x \n", [IDE_BAR0_val]:4
  1115.         DEBUGF  1, "K : BAR1 %x \n", [IDE_BAR1_val]:4
  1116.         DEBUGF  1, "K : BAR2 %x \n", [IDE_BAR2_val]:4
  1117.         DEBUGF  1, "K : BAR3 %x \n", [IDE_BAR3_val]:4
  1118.         DEBUGF  1, "K : BAR4 %x \n", [IDEContrRegsBaseAddr]:4
  1119.         DEBUGF  1, "K : IDEContrProgrammingInterface %x \n", [IDEContrProgrammingInterface]:4
  1120.         DEBUGF  1, "K : IDE_Interrupt %x \n", [IDE_Interrupt]:4
  1121.  
  1122. ; START MULTITASKING
  1123.  
  1124. ; A 'All set - press ESC to start' messages if need
  1125. if preboot_blogesc
  1126.         mov     esi, boot_tasking
  1127.         call    boot_log
  1128. .bll1:
  1129.         in      al, 0x60        ; wait for ESC key press
  1130.         cmp     al, 129
  1131.         jne     .bll1
  1132. end if
  1133.  
  1134.         push    eax edx
  1135.         mov     dx, [IDEContrRegsBaseAddr]
  1136.         xor     eax, eax
  1137.         add     dx, 2
  1138.         in      al, dx
  1139.         DEBUGF  1, "K : Primary Bus Master IDE Status Register %x\n", eax
  1140.  
  1141.         add     dx, 8
  1142.         in      al, dx
  1143.         DEBUGF  1, "K : Secondary Bus Master IDE Status Register %x\n", eax
  1144.         pop     edx eax
  1145.  
  1146.         cmp     [IDEContrRegsBaseAddr], 0
  1147.         setnz   [dma_hdd]
  1148.  
  1149.         cmp     [IDEContrProgrammingInterface], 0
  1150.         je      set_interrupts_for_IDE_controllers.continue
  1151.  
  1152.         mov     ax, [IDE_Interrupt]
  1153.         cmp     al, 0xff
  1154.         jne     @f
  1155.  
  1156.         mov     [dma_hdd], 0
  1157.         jmp     set_interrupts_for_IDE_controllers.end_set_interrupts
  1158. @@:
  1159. ;-----------------------------------------------------------------------------
  1160. ; set interrupts for IDE Controller
  1161. ;-----------------------------------------------------------------------------
  1162.         mov     esi, boot_set_int_IDE
  1163.         call    boot_log
  1164. set_interrupts_for_IDE_controllers:
  1165.         mov     ax, [IDEContrProgrammingInterface]
  1166.         cmp     ax, 0x0180
  1167.         je      .pata_ide
  1168.  
  1169.         cmp     ax, 0x018a
  1170.         jne     .sata_ide
  1171. ;--------------------------------------
  1172. .pata_ide:
  1173.         cmp     [IDEContrRegsBaseAddr], 0
  1174.         je      .end_set_interrupts
  1175.  
  1176.         stdcall attach_int_handler, 14, IDE_irq_14_handler, 0
  1177.         DEBUGF  1, "K : Set IDE IRQ14 return code %x\n", eax
  1178.         stdcall attach_int_handler, 15, IDE_irq_15_handler, 0
  1179.         DEBUGF  1, "K : Set IDE IRQ15 return code %x\n", eax
  1180.         jmp     .enable_IDE_interrupt
  1181. ;--------------------------------------
  1182. .sata_ide:
  1183.         cmp     ax, 0x0185
  1184.         je      .sata_ide_1
  1185.  
  1186.         cmp     ax, 0x018f
  1187.         jne     .end_set_interrupts
  1188. ;--------------------------------------
  1189. .sata_ide_1:
  1190.         cmp     [IDEContrRegsBaseAddr], 0
  1191.         je      .end_set_interrupts
  1192.  
  1193.         mov     ax, [IDE_Interrupt]
  1194.         movzx   eax, al
  1195.         stdcall attach_int_handler, eax, IDE_common_irq_handler, 0
  1196.         DEBUGF  1, "K : Set IDE IRQ%d return code %x\n", [IDE_Interrupt]:1, eax
  1197. ;--------------------------------------
  1198. .enable_IDE_interrupt:
  1199.         mov     esi, boot_enabling_ide
  1200.         call    boot_log
  1201. ; Enable interrupts in IDE controller for DMA
  1202.         mov     al, 0
  1203.         mov     dx, [IDE_BAR1_val] ;0x3F4
  1204.         add     dx, 2 ;0x3F6
  1205.         out     dx, al
  1206.         mov     dx, [IDE_BAR3_val] ;0x374
  1207.         add     dx, 2 ;0x376
  1208.         out     dx, al
  1209. ;--------------------------------------
  1210. .end_set_interrupts:
  1211. ;-----------------------------------------------------------------------------
  1212.         cmp     [dma_hdd], 0
  1213.         je      .print_pio
  1214. .print_dma:
  1215.         DEBUGF  1, "K : IDE DMA mode\n"
  1216.         jmp     .continue
  1217.  
  1218. .print_pio:
  1219.         DEBUGF  1, "K : IDE PIO mode\n"
  1220. .continue:
  1221.  
  1222.         mov     [timer_ticks_enable], 1         ; for cd driver
  1223.  
  1224.         sti
  1225. ;        call    change_task
  1226.  
  1227.         jmp     osloop
  1228.  
  1229.  
  1230.         ; Fly :)
  1231.  
  1232. include 'unpacker.inc'
  1233.  
  1234. align 4
  1235. boot_log:
  1236.         pushad
  1237.  
  1238.         mov     ebx, 10*65536
  1239.         mov     bx, word [boot_y]
  1240.         add     [boot_y], dword 10
  1241.         mov     ecx, 0x80ffffff; ASCIIZ string with white color
  1242.         xor     edi, edi
  1243.         mov     edx, esi
  1244.         inc     edi
  1245.         call    dtext
  1246.  
  1247.         mov     [novesachecksum], 1000
  1248.         call    checkVga_N13
  1249.  
  1250.         popad
  1251.  
  1252.         ret
  1253.  
  1254. ; in: edx -> APPDATA for OS/IDLE slot
  1255. ; in: ebx = stack base
  1256. proc setup_os_slot
  1257.         xor     eax, eax
  1258.         mov     ecx, 256/4
  1259.         mov     edi, edx
  1260.         rep stosd
  1261.  
  1262.         mov     eax, tss+0x80
  1263.         call    get_pg_addr
  1264.         inc     eax
  1265.         mov     [edx+APPDATA.io_map], eax
  1266.         mov     eax, tss+0x1080
  1267.         call    get_pg_addr
  1268.         inc     eax
  1269.         mov     [edx+APPDATA.io_map+4], eax
  1270.  
  1271.         mov     dword [edx+APPDATA.pl0_stack], ebx
  1272.         lea     edi, [ebx+0x2000-512]
  1273.         mov     dword [edx+APPDATA.fpu_state], edi
  1274.         mov     dword [edx+APPDATA.saved_esp0], edi
  1275.         mov     dword [edx+APPDATA.saved_esp], edi
  1276.         mov     dword [edx+APPDATA.terminate_protection], 1 ; make unkillable
  1277.  
  1278.         mov     esi, fpu_data
  1279.         mov     ecx, 512/4
  1280.         cld
  1281.         rep movsd
  1282.  
  1283.         lea     eax, [edx+APP_OBJ_OFFSET]
  1284.         mov     dword [edx+APPDATA.fd_obj], eax
  1285.         mov     dword [edx+APPDATA.bk_obj], eax
  1286.  
  1287.         mov     dword [edx+APPDATA.cur_dir], sysdir_path
  1288.  
  1289.         mov     [edx + APPDATA.dir_table], sys_pgdir - OS_BASE
  1290.  
  1291.         mov     eax, edx
  1292.         shr     eax, 3
  1293.         add     eax, CURRENT_TASK - (SLOT_BASE shr 3)
  1294.         mov     [eax+TASKDATA.wnd_number], dh
  1295.         mov     byte [eax+TASKDATA.pid], dh
  1296.  
  1297.         ret
  1298. endp
  1299.  
  1300. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1301. ;                                                                    ;
  1302. ;                    MAIN OS LOOP START                              ;
  1303. ;                                                                    ;
  1304. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1305. align 32
  1306. osloop:
  1307.         mov     edx, osloop_has_work?
  1308.         xor     ecx, ecx
  1309.         call    Wait_events
  1310.         xor     eax, eax
  1311.         xchg    eax, [osloop_nonperiodic_work]
  1312.         test    eax, eax
  1313.         jz      .no_periodic
  1314. ;        call    [draw_pointer]
  1315.         call    __sys_draw_pointer
  1316.         call    window_check_events
  1317.         call    mouse_check_events
  1318.         call    checkmisc
  1319.         call    checkVga_N13
  1320. .no_periodic:
  1321.         call    stack_handler
  1322.         call    check_fdd_motor_status
  1323.         call    check_ATAPI_device_event
  1324.         call    check_lights_state
  1325.         call    check_timers
  1326.         jmp     osloop
  1327. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1328. ;                                                                    ;
  1329. ;                      MAIN OS LOOP END                              ;
  1330. ;                                                                    ;
  1331. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1332. proc osloop_has_work?
  1333.         cmp     [osloop_nonperiodic_work], 0
  1334.         jnz     .yes
  1335.         call    stack_handler_has_work?
  1336.         jnz     .yes
  1337.         call    check_fdd_motor_status_has_work?
  1338.         jnz     .yes
  1339.         call    check_ATAPI_device_event_has_work?
  1340.         jnz     .yes
  1341.         call    check_lights_state_has_work?
  1342.         jnz     .yes
  1343.         call    check_timers_has_work?
  1344.         jnz     .yes
  1345. .no:
  1346.         xor     eax, eax
  1347.         ret
  1348. .yes:
  1349.         xor     eax, eax
  1350.         inc     eax
  1351.         ret
  1352. endp
  1353.  
  1354. proc wakeup_osloop
  1355.         mov     [osloop_nonperiodic_work], 1
  1356.         ret
  1357. endp
  1358.  
  1359. uglobal
  1360. align 4
  1361. osloop_nonperiodic_work dd      ?
  1362. endg
  1363.  
  1364. align 4
  1365. idle_thread:
  1366.         sti
  1367. idle_loop:
  1368.         hlt
  1369.         jmp     idle_loop
  1370.  
  1371.  
  1372.  
  1373. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1374. ;                                                                      ;
  1375. ;                   INCLUDED SYSTEM FILES                              ;
  1376. ;                                                                      ;
  1377. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1378.  
  1379.  
  1380. include "kernel32.inc"
  1381.  
  1382.  
  1383. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1384. ;                                                                      ;
  1385. ;                       KERNEL FUNCTIONS                               ;
  1386. ;                                                                      ;
  1387. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1388.  
  1389. reserve_irqs_ports:
  1390.  
  1391.  
  1392. ; RESERVE PORTS
  1393.         mov     eax, RESERVED_PORTS
  1394.         mov     ecx, 1
  1395.  
  1396.         mov     [eax], dword 4
  1397.  
  1398.         mov     [eax+16], ecx
  1399.         mov     [eax+16+4], dword 0
  1400.         mov     [eax+16+8], dword 0x2D
  1401.  
  1402.         mov     [eax+32], ecx
  1403.         mov     [eax+32+4], dword 0x30
  1404.         mov     [eax+32+8], dword 0x4D
  1405.  
  1406.         mov     [eax+48], ecx
  1407.         mov     [eax+48+4], dword 0x50
  1408.         mov     [eax+48+8], dword 0xDF
  1409.  
  1410.         mov     [eax+64], ecx
  1411.         mov     [eax+64+4], dword 0xE5
  1412.         mov     [eax+64+8], dword 0xFF
  1413.  
  1414.         ret
  1415.  
  1416.  
  1417. iglobal
  1418.   process_number dd 0x2
  1419. endg
  1420.  
  1421. set_variables:
  1422.  
  1423.         mov     ecx, 0x16                    ; flush port 0x60
  1424. .fl60:
  1425.         in      al, 0x60
  1426.         loop    .fl60
  1427.         push    eax
  1428.  
  1429.         mov     ax, [BOOT_VARS+BOOT_Y_RES]
  1430.         shr     ax, 1
  1431.         shl     eax, 16
  1432.         mov     ax, [BOOT_VARS+BOOT_X_RES]
  1433.         shr     ax, 1
  1434.         mov     [MOUSE_X], eax
  1435.         call    wakeup_osloop
  1436.  
  1437.         xor     eax, eax
  1438.         mov     [BTN_ADDR], dword BUTTON_INFO ; address of button list
  1439.  
  1440.         mov     byte [KEY_COUNT], al              ; keyboard buffer
  1441.         mov     byte [BTN_COUNT], al              ; button buffer
  1442. ;        mov   [MOUSE_X],dword 100*65536+100    ; mouse x/y
  1443.  
  1444.         pop     eax
  1445.         ret
  1446.  
  1447. align 4
  1448. ;input  eax=43,bl-byte of output, ecx - number of port
  1449. sys_outport:
  1450.  
  1451.         mov     edi, ecx   ; separate flag for read / write
  1452.         and     ecx, 65535
  1453.  
  1454.         mov     eax, [RESERVED_PORTS]
  1455.         test    eax, eax
  1456.         jnz     .sopl8
  1457.         inc     eax
  1458.         mov     [esp+32], eax
  1459.         ret
  1460.  
  1461.   .sopl8:
  1462.         mov     edx, [TASK_BASE]
  1463.         mov     edx, [edx+0x4]
  1464.     ;and   ecx,65535
  1465.     ;cld - set on interrupt 0x40
  1466.   .sopl1:
  1467.  
  1468.         mov     esi, eax
  1469.         shl     esi, 4
  1470.         add     esi, RESERVED_PORTS
  1471.         cmp     edx, [esi+0]
  1472.         jne     .sopl2
  1473.         cmp     ecx, [esi+4]
  1474.         jb      .sopl2
  1475.         cmp     ecx, [esi+8]
  1476.         jg      .sopl2
  1477. .sopl3:
  1478.  
  1479.         test    edi, 0x80000000; read ?
  1480.         jnz     .sopl4
  1481.  
  1482.         mov     eax, ebx
  1483.         mov     dx, cx   ; write
  1484.         out     dx, al
  1485.         and     [esp+32], dword 0
  1486.         ret
  1487.  
  1488.         .sopl2:
  1489.  
  1490.         dec     eax
  1491.         jnz     .sopl1
  1492.         inc     eax
  1493.         mov     [esp+32], eax
  1494.         ret
  1495.  
  1496.  
  1497.   .sopl4:
  1498.  
  1499.         mov     dx, cx   ; read
  1500.         in      al, dx
  1501.         and     eax, 0xff
  1502.         and     [esp+32], dword 0
  1503.         mov     [esp+20], eax
  1504.         ret
  1505.  
  1506. display_number:
  1507. ;It is not optimization
  1508.         mov     eax, ebx
  1509.         mov     ebx, ecx
  1510.         mov     ecx, edx
  1511.         mov     edx, esi
  1512.         mov     esi, edi
  1513. ; eax = print type, al=0 -> ebx is number
  1514. ;                   al=1 -> ebx is pointer
  1515. ;                   ah=0 -> display decimal
  1516. ;                   ah=1 -> display hexadecimal
  1517. ;                   ah=2 -> display binary
  1518. ;                   eax bits 16-21 = number of digits to display (0-32)
  1519. ;                   eax bits 22-31 = reserved
  1520. ;
  1521. ; ebx = number or pointer
  1522. ; ecx = x shl 16 + y
  1523. ; edx = color
  1524.         xor     edi, edi
  1525. display_number_force:
  1526.         push    eax
  1527.         and     eax, 0x3fffffff
  1528.         cmp     eax, 0xffff     ; length > 0 ?
  1529.         pop     eax
  1530.         jge     cont_displ
  1531.         ret
  1532.    cont_displ:
  1533.         push    eax
  1534.         and     eax, 0x3fffffff
  1535.         cmp     eax, 61*0x10000  ; length <= 60 ?
  1536.         pop     eax
  1537.         jb      cont_displ2
  1538.         ret
  1539.    cont_displ2:
  1540.  
  1541.         pushad
  1542.  
  1543.         cmp     al, 1            ; ecx is a pointer ?
  1544.         jne     displnl1
  1545.         mov     ebp, ebx
  1546.         add     ebp, 4
  1547.         mov     ebp, [ebp+std_application_base_address]
  1548.         mov     ebx, [ebx+std_application_base_address]
  1549.  displnl1:
  1550.         sub     esp, 64
  1551.  
  1552.         test    ah, ah            ; DECIMAL
  1553.         jnz     no_display_desnum
  1554.         shr     eax, 16
  1555.         and     eax, 0xC03f
  1556. ;     and   eax,0x3f
  1557.         push    eax
  1558.         and     eax, 0x3f
  1559.         mov     edi, esp
  1560.         add     edi, 4+64-1
  1561.         mov     ecx, eax
  1562.         mov     eax, ebx
  1563.         mov     ebx, 10
  1564.  d_desnum:
  1565.         xor     edx, edx
  1566.         call    division_64_bits
  1567.         div     ebx
  1568.         add     dl, 48
  1569.         mov     [edi], dl
  1570.         dec     edi
  1571.         loop    d_desnum
  1572.         pop     eax
  1573.         call    normalize_number
  1574.         call    draw_num_text
  1575.         add     esp, 64
  1576.         popad
  1577.         ret
  1578.    no_display_desnum:
  1579.  
  1580.         cmp     ah, 0x01         ; HEXADECIMAL
  1581.         jne     no_display_hexnum
  1582.         shr     eax, 16
  1583.         and     eax, 0xC03f
  1584. ;     and   eax,0x3f
  1585.         push    eax
  1586.         and     eax, 0x3f
  1587.         mov     edi, esp
  1588.         add     edi, 4+64-1
  1589.         mov     ecx, eax
  1590.         mov     eax, ebx
  1591.         mov     ebx, 16
  1592.    d_hexnum:
  1593.         xor     edx, edx
  1594.         call    division_64_bits
  1595.         div     ebx
  1596.    hexletters = __fdo_hexdigits
  1597.         add     edx, hexletters
  1598.         mov     dl, [edx]
  1599.         mov     [edi], dl
  1600.         dec     edi
  1601.         loop    d_hexnum
  1602.         pop     eax
  1603.         call    normalize_number
  1604.         call    draw_num_text
  1605.         add     esp, 64
  1606.         popad
  1607.         ret
  1608.    no_display_hexnum:
  1609.  
  1610.         cmp     ah, 0x02         ; BINARY
  1611.         jne     no_display_binnum
  1612.         shr     eax, 16
  1613.         and     eax, 0xC03f
  1614. ;     and   eax,0x3f
  1615.         push    eax
  1616.         and     eax, 0x3f
  1617.         mov     edi, esp
  1618.         add     edi, 4+64-1
  1619.         mov     ecx, eax
  1620.         mov     eax, ebx
  1621.         mov     ebx, 2
  1622.    d_binnum:
  1623.         xor     edx, edx
  1624.         call    division_64_bits
  1625.         div     ebx
  1626.         add     dl, 48
  1627.         mov     [edi], dl
  1628.         dec     edi
  1629.         loop    d_binnum
  1630.         pop     eax
  1631.         call    normalize_number
  1632.         call    draw_num_text
  1633.         add     esp, 64
  1634.         popad
  1635.         ret
  1636.    no_display_binnum:
  1637.  
  1638.         add     esp, 64
  1639.         popad
  1640.         ret
  1641.  
  1642. normalize_number:
  1643.         test    ah, 0x80
  1644.         jz      .continue
  1645.         mov     ecx, 48
  1646.         and     eax, 0x3f
  1647. @@:
  1648.         inc     edi
  1649.         cmp     [edi], cl
  1650.         jne     .continue
  1651.         dec     eax
  1652.         cmp     eax, 1
  1653.         ja      @r
  1654.         mov     al, 1
  1655. .continue:
  1656.         and     eax, 0x3f
  1657.         ret
  1658.  
  1659. division_64_bits:
  1660.         test    [esp+1+4], byte 0x40
  1661.         jz      .continue
  1662.         push    eax
  1663.         mov     eax, ebp
  1664.         div     ebx
  1665.         mov     ebp, eax
  1666.         pop     eax
  1667. .continue:
  1668.         ret
  1669.  
  1670. draw_num_text:
  1671.         mov     esi, eax
  1672.         mov     edx, 64+4
  1673.         sub     edx, eax
  1674.         add     edx, esp
  1675.         mov     ebx, [esp+64+32-8+4]
  1676. ; add window start x & y
  1677.         mov     ecx, [TASK_BASE]
  1678.  
  1679.         mov     edi, [CURRENT_TASK]
  1680.         shl     edi, 8
  1681.  
  1682.         mov     eax, [ecx-twdw+WDATA.box.left]
  1683.         add     eax, [edi+SLOT_BASE+APPDATA.wnd_clientbox.left]
  1684.         shl     eax, 16
  1685.         add     eax, [ecx-twdw+WDATA.box.top]
  1686.         add     eax, [edi+SLOT_BASE+APPDATA.wnd_clientbox.top]
  1687.         add     ebx, eax
  1688.         mov     ecx, [esp+64+32-12+4]
  1689.         and     ecx, not 0x80000000     ; force counted string
  1690.         mov     eax, [esp+64+8]         ; background color (if given)
  1691.         mov     edi, [esp+64+4]
  1692.         jmp     dtext
  1693.  
  1694. align 4
  1695.  
  1696. sys_setup:
  1697.  
  1698. ; 1=roland mpu midi base , base io address
  1699. ; 2=keyboard   1, base kaybap 2, shift keymap, 9 country 1eng 2fi 3ger 4rus
  1700. ; 3=cd base    1, pri.master 2, pri slave 3 sec master, 4 sec slave
  1701. ; 5=system language, 1eng 2fi 3ger 4rus
  1702. ; 7=hd base    1, pri.master 2, pri slave 3 sec master, 4 sec slave
  1703. ; 8=fat32 partition in hd
  1704. ; 9
  1705. ; 10 = sound dma channel
  1706. ; 11 = enable lba read
  1707. ; 12 = enable pci access
  1708.  
  1709.  
  1710.         and     [esp+32], dword 0
  1711.         dec     ebx                             ; MIDI
  1712.         jnz     nsyse1
  1713.         cmp     ecx, 0x100
  1714.  
  1715.         jb      nsyse1
  1716.         mov     esi, 65535
  1717.         cmp     esi, ecx
  1718.  
  1719.         jb      nsyse1
  1720.         mov     [midi_base], cx ;bx
  1721.         mov     word [mididp], cx;bx
  1722.         inc     cx              ;bx
  1723.         mov     word [midisp], cx;bx
  1724.         ret
  1725.  
  1726. iglobal
  1727. midi_base dw 0
  1728. endg
  1729.  
  1730.    nsyse1:
  1731.         dec     ebx                              ; KEYBOARD
  1732.         jnz     nsyse2
  1733.         mov     edi, [TASK_BASE]
  1734.         mov     eax, [edi+TASKDATA.mem_start]
  1735.         add     eax, edx
  1736.  
  1737.         dec     ecx
  1738.         jnz     kbnobase
  1739.         mov     ebx, keymap
  1740.         mov     ecx, 128
  1741.         call    memmove
  1742.         ret
  1743.    kbnobase:
  1744.         dec     ecx
  1745.         jnz     kbnoshift
  1746.  
  1747.         mov     ebx, keymap_shift
  1748.         mov     ecx, 128
  1749.         call    memmove
  1750.         ret
  1751.    kbnoshift:
  1752.         dec     ecx
  1753.         jnz     kbnoalt
  1754.         mov     ebx, keymap_alt
  1755.         mov     ecx, 128
  1756.         call    memmove
  1757.         ret
  1758.    kbnoalt:
  1759.         sub     ecx, 6
  1760.         jnz     kbnocountry
  1761.         mov     word [keyboard], dx
  1762.         ret
  1763.    kbnocountry:
  1764.         mov     [esp+32], dword 1
  1765.         ret
  1766.    nsyse2:
  1767.         dec     ebx                         ; CD
  1768.         jnz     nsyse4
  1769.  
  1770.         test    ecx, ecx
  1771.         jz      nosesl
  1772.  
  1773.         cmp     ecx, 4
  1774.         ja      nosesl
  1775.         mov     [cd_base], cl
  1776.  
  1777.         dec     ecx
  1778.         jnz     noprma
  1779.         mov     eax, [hd_address_table]
  1780.         mov     [cdbase], eax   ;0x1f0
  1781.         mov     [cdid], 0xa0
  1782. noprma:
  1783.  
  1784.         dec     ecx
  1785.         jnz     noprsl
  1786.         mov     eax, [hd_address_table]
  1787.         mov     [cdbase], eax   ;0x1f0
  1788.         mov     [cdid], 0xb0
  1789. noprsl:
  1790.         dec     ecx
  1791.         jnz     nosema
  1792.         mov     eax, [hd_address_table+16]
  1793.         mov     [cdbase], eax   ;0x170
  1794.         mov     [cdid], 0xa0
  1795. nosema:
  1796.         dec     ecx
  1797.         jnz     nosesl
  1798.         mov     eax, [hd_address_table+16]
  1799.         mov     [cdbase], eax   ;0x170
  1800.         mov     [cdid], 0xb0
  1801. nosesl:
  1802.         ret
  1803.  
  1804. iglobal
  1805. cd_base db 0
  1806.  
  1807. endg
  1808.    nsyse4:
  1809.  
  1810.         sub     ebx, 2           ; SYSTEM LANGUAGE
  1811.         jnz     nsyse5
  1812.         mov     [syslang], ecx
  1813.         ret
  1814.    nsyse5:
  1815.  
  1816.         sub     ebx, 2          ; HD BASE - obsolete
  1817.         jnz     nsyse7
  1818.  
  1819.    nosethd:
  1820.         ret
  1821.  
  1822. nsyse7:
  1823.  
  1824. ;     cmp  eax,8                      ; HD PARTITION - obsolete
  1825.         dec     ebx
  1826.         jnz     nsyse8
  1827.         ret
  1828.  
  1829. nsyse8:
  1830. ;     cmp  eax,11                     ; ENABLE LBA READ
  1831.         and     ecx, 1
  1832.         sub     ebx, 3
  1833.         jnz     no_set_lba_read
  1834.         mov     [lba_read_enabled], ecx
  1835.         ret
  1836.  
  1837. no_set_lba_read:
  1838. ;     cmp  eax,12                     ; ENABLE PCI ACCESS
  1839.         dec     ebx
  1840.         jnz     sys_setup_err
  1841.         mov     [pci_access_enabled], ecx
  1842.         ret
  1843.  
  1844. sys_setup_err:
  1845.         or      [esp+32], dword -1
  1846.         ret
  1847.  
  1848. align 4
  1849.  
  1850. sys_getsetup:
  1851.  
  1852. ; 1=roland mpu midi base , base io address
  1853. ; 2=keyboard   1, base kaybap 2, shift keymap, 9 country 1eng 2fi 3ger 4rus
  1854. ; 3=cd base    1, pri.master 2, pri slave 3 sec master, 4 sec slave
  1855. ; 5=system language, 1eng 2fi 3ger 4rus
  1856. ; 7=hd base    1, pri.master 2, pri slave 3 sec master, 4 sec slave
  1857. ; 8=fat32 partition in hd
  1858. ; 9=get hs timer tic
  1859.  
  1860. ;     cmp  eax,1
  1861.         dec     ebx
  1862.         jnz     ngsyse1
  1863.         movzx   eax, [midi_base]
  1864.         mov     [esp+32], eax
  1865.         ret
  1866. ngsyse1:
  1867. ;     cmp  eax,2
  1868.         dec     ebx
  1869.         jnz     ngsyse2
  1870.  
  1871.         mov     edi, [TASK_BASE]
  1872.         mov     ebx, [edi+TASKDATA.mem_start]
  1873.         add     ebx, edx
  1874.  
  1875. ;     cmp  ebx,1
  1876.         dec     ecx
  1877.         jnz     kbnobaseret
  1878.         mov     eax, keymap
  1879.         mov     ecx, 128
  1880.         call    memmove
  1881.         ret
  1882. kbnobaseret:
  1883. ;     cmp  ebx,2
  1884.         dec     ecx
  1885.         jnz     kbnoshiftret
  1886.  
  1887.         mov     eax, keymap_shift
  1888.         mov     ecx, 128
  1889.         call    memmove
  1890.         ret
  1891. kbnoshiftret:
  1892. ;     cmp  ebx,3
  1893.         dec     ecx
  1894.         jne     kbnoaltret
  1895.  
  1896.         mov     eax, keymap_alt
  1897.         mov     ecx, 128
  1898.         call    memmove
  1899.         ret
  1900. kbnoaltret:
  1901. ;     cmp  ebx,9
  1902.         sub     ecx, 6
  1903.         jnz     ngsyse2
  1904.         movzx   eax, word [keyboard]
  1905.         mov     [esp+32], eax
  1906.         ret
  1907.  
  1908.  
  1909. ngsyse2:
  1910. ;         cmp  eax,3
  1911.         dec     ebx
  1912.         jnz     ngsyse3
  1913.         movzx   eax, [cd_base]
  1914.         mov     [esp+32], eax
  1915.         ret
  1916. ngsyse3:
  1917. ;         cmp  eax,5
  1918.         sub     ebx, 2
  1919.         jnz     ngsyse5
  1920.         mov     eax, [syslang]
  1921.         mov     [esp+32], eax
  1922.         ret
  1923. ngsyse5:
  1924. ;     cmp  eax,7
  1925.         sub     ebx, 2
  1926.         jnz     ngsyse7
  1927.         xor     eax, eax
  1928.         mov     [esp+32], eax
  1929.         ret
  1930. ngsyse7:
  1931. ;     cmp  eax,8
  1932.         dec     ebx
  1933.         jnz     ngsyse8
  1934.         mov     eax, [fat32part]
  1935.         mov     [esp+32], eax
  1936.         ret
  1937. ngsyse8:
  1938. ;     cmp  eax,9
  1939.         dec     ebx
  1940.         jnz     ngsyse9
  1941.         mov     eax, [timer_ticks];[0xfdf0]
  1942.         mov     [esp+32], eax
  1943.         ret
  1944. ngsyse9:
  1945. ;     cmp  eax,11
  1946.         sub     ebx, 2
  1947.         jnz     ngsyse11
  1948.         mov     eax, [lba_read_enabled]
  1949.         mov     [esp+32], eax
  1950.         ret
  1951. ngsyse11:
  1952. ;     cmp  eax,12
  1953.         dec     ebx
  1954.         jnz     ngsyse12
  1955.         mov     eax, [pci_access_enabled]
  1956.         mov     [esp+32], eax
  1957.         ret
  1958. ngsyse12:
  1959.         mov     [esp+32], dword 1
  1960.         ret
  1961.  
  1962.  
  1963. get_timer_ticks:
  1964.         mov     eax, [timer_ticks]
  1965.         ret
  1966.  
  1967. iglobal
  1968. align 4
  1969. mousefn dd msscreen, mswin, msbutton, msset
  1970.         dd app_load_cursor
  1971.         dd app_set_cursor
  1972.         dd app_delete_cursor
  1973.         dd msz
  1974. endg
  1975.  
  1976. readmousepos:
  1977.  
  1978. ; eax=0 screen relative
  1979. ; eax=1 window relative
  1980. ; eax=2 buttons pressed
  1981. ; eax=3 set mouse pos   ; reserved
  1982. ; eax=4 load cursor
  1983. ; eax=5 set cursor
  1984. ; eax=6 delete cursor   ; reserved
  1985. ; eax=7 get mouse_z
  1986.  
  1987.         cmp     ebx, 7
  1988.         ja      msset
  1989.         jmp     [mousefn+ebx*4]
  1990. msscreen:
  1991.         mov     eax, [MOUSE_X]
  1992.         shl     eax, 16
  1993.         mov     ax, [MOUSE_Y]
  1994.         mov     [esp+36-4], eax
  1995.         ret
  1996. mswin:
  1997.         mov     eax, [MOUSE_X]
  1998.         shl     eax, 16
  1999.         mov     ax, [MOUSE_Y]
  2000.         mov     esi, [TASK_BASE]
  2001.         mov     bx, word [esi-twdw+WDATA.box.left]
  2002.         shl     ebx, 16
  2003.         mov     bx, word [esi-twdw+WDATA.box.top]
  2004.         sub     eax, ebx
  2005.  
  2006.         mov     edi, [CURRENT_TASK]
  2007.         shl     edi, 8
  2008.         sub     ax, word[edi+SLOT_BASE+APPDATA.wnd_clientbox.top]
  2009.         rol     eax, 16
  2010.         sub     ax, word[edi+SLOT_BASE+APPDATA.wnd_clientbox.left]
  2011.         rol     eax, 16
  2012.         mov     [esp+36-4], eax
  2013.         ret
  2014. msbutton:
  2015.         movzx   eax, byte [BTN_DOWN]
  2016.         mov     [esp+36-4], eax
  2017.         ret
  2018. msz:
  2019.         mov     edi, [TASK_COUNT]
  2020.         movzx   edi, word [WIN_POS + edi*2]
  2021.         cmp     edi, [CURRENT_TASK]
  2022.         jne     @f
  2023.         mov     ax, [MOUSE_SCROLL_H]
  2024.         shl     eax, 16
  2025.         mov     ax, [MOUSE_SCROLL_V]
  2026.         mov     [esp+36-4], eax
  2027.         and     [MOUSE_SCROLL_H], word 0
  2028.         and     [MOUSE_SCROLL_V], word 0
  2029.         ret
  2030.        @@:
  2031.         and     [esp+36-4], dword 0
  2032. ;           ret
  2033. msset:
  2034.         ret
  2035.  
  2036. app_load_cursor:
  2037.         cmp     ecx, OS_BASE
  2038.         jae     msset
  2039.         stdcall load_cursor, ecx, edx
  2040.         mov     [esp+36-4], eax
  2041.         ret
  2042.  
  2043. app_set_cursor:
  2044.         stdcall set_cursor, ecx
  2045.         mov     [esp+36-4], eax
  2046.         ret
  2047.  
  2048. app_delete_cursor:
  2049.         stdcall delete_cursor, ecx
  2050.         mov     [esp+36-4], eax
  2051.         ret
  2052.  
  2053. is_input:
  2054.  
  2055.         push    edx
  2056.         mov     dx, word [midisp]
  2057.         in      al, dx
  2058.         and     al, 0x80
  2059.         pop     edx
  2060.         ret
  2061.  
  2062. is_output:
  2063.  
  2064.         push    edx
  2065.         mov     dx, word [midisp]
  2066.         in      al, dx
  2067.         and     al, 0x40
  2068.         pop     edx
  2069.         ret
  2070.  
  2071.  
  2072. get_mpu_in:
  2073.  
  2074.         push    edx
  2075.         mov     dx, word [mididp]
  2076.         in      al, dx
  2077.         pop     edx
  2078.         ret
  2079.  
  2080.  
  2081. put_mpu_out:
  2082.  
  2083.         push    edx
  2084.         mov     dx, word [mididp]
  2085.         out     dx, al
  2086.         pop     edx
  2087.         ret
  2088.  
  2089.  
  2090.  
  2091. align 4
  2092.  
  2093. sys_midi:
  2094.         cmp     [mididp], 0
  2095.         jnz     sm0
  2096.         mov     [esp+36], dword 1
  2097.         ret
  2098. sm0:
  2099.         and     [esp+36], dword 0
  2100.         dec     ebx
  2101.         jnz     smn1
  2102.  ;    call setuart
  2103. su1:
  2104.         call    is_output
  2105.         test    al, al
  2106.         jnz     su1
  2107.         mov     dx, word [midisp]
  2108.         mov     al, 0xff
  2109.         out     dx, al
  2110. su2:
  2111.         mov     dx, word [midisp]
  2112.         mov     al, 0xff
  2113.         out     dx, al
  2114.         call    is_input
  2115.         test    al, al
  2116.         jnz     su2
  2117.         call    get_mpu_in
  2118.         cmp     al, 0xfe
  2119.         jnz     su2
  2120. su3:
  2121.         call    is_output
  2122.         test    al, al
  2123.         jnz     su3
  2124.         mov     dx, word [midisp]
  2125.         mov     al, 0x3f
  2126.         out     dx, al
  2127.         ret
  2128. smn1:
  2129.         dec     ebx
  2130.         jnz     smn2
  2131. sm10:
  2132.         call    get_mpu_in
  2133.         call    is_output
  2134.         test    al, al
  2135.         jnz     sm10
  2136.         mov     al, bl
  2137.         call    put_mpu_out
  2138.         smn2:
  2139.         ret
  2140.  
  2141. detect_devices:
  2142. ;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  2143. ;include 'detect/commouse.inc'
  2144. ;include 'detect/ps2mouse.inc'
  2145. ;include 'detect/dev_fd.inc'
  2146. ;include 'detect/dev_hdcd.inc'
  2147. ;include 'detect/sear_par.inc'
  2148. ;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  2149.         ret
  2150.  
  2151. sys_end:
  2152. ;--------------------------------------
  2153.         cmp     [_display.select_cursor], 0
  2154.         je      @f
  2155. ; restore default cursor before killing
  2156.         pusha
  2157.         mov     ecx, [current_slot]
  2158.         call    restore_default_cursor_before_killing
  2159.         popa
  2160. @@:
  2161. ;--------------------------------------
  2162. ; kill all sockets this process owns
  2163.         pusha
  2164.         mov     edx, [TASK_BASE]
  2165.         mov     edx, [edx+TASKDATA.pid]
  2166.         call    SOCKET_process_end
  2167.         popa
  2168. ;--------------------------------------
  2169.         mov     ecx, [current_slot]
  2170.         mov     eax, [ecx+APPDATA.tls_base]
  2171.         test    eax, eax
  2172.         jz      @F
  2173.  
  2174.         stdcall user_free, eax
  2175. @@:
  2176.  
  2177.         mov     eax, [TASK_BASE]
  2178.         mov     [eax+TASKDATA.state], 3; terminate this program
  2179.         call    wakeup_osloop
  2180.  
  2181. .waitterm:            ; wait here for termination
  2182.         call    change_task
  2183.         jmp     .waitterm
  2184. ;------------------------------------------------------------------------------
  2185. align 4
  2186. restore_default_cursor_before_killing:
  2187.         pushfd
  2188.         cli
  2189.         mov     eax, [def_cursor]
  2190.         mov     [ecx+APPDATA.cursor], eax
  2191.  
  2192.         movzx   eax, word [MOUSE_Y]
  2193.         movzx   ebx, word [MOUSE_X]
  2194. ;        mov     ecx, [Screen_Max_X]
  2195. ;        inc     ecx
  2196. ;        mul     ecx
  2197.         mov     eax, [d_width_calc_area + eax*4]
  2198.  
  2199.         add     eax, [_WinMapAddress]
  2200.         movzx   edx, byte [ebx+eax]
  2201.         shl     edx, 8
  2202.         mov     esi, [edx+SLOT_BASE+APPDATA.cursor]
  2203.  
  2204.         cmp     esi, [current_cursor]
  2205.         je      @f
  2206.  
  2207.         push    esi
  2208.         call    [_display.select_cursor]
  2209.         mov     [current_cursor], esi
  2210. @@:
  2211.         mov     [redrawmouse_unconditional], 1
  2212.         call    wakeup_osloop
  2213.         popfd
  2214.         ret
  2215. ;------------------------------------------------------------------------------
  2216. iglobal
  2217. align 4
  2218. sys_system_table:
  2219.         dd      sysfn_deactivate        ; 1 = deactivate window
  2220.         dd      sysfn_terminate         ; 2 = terminate thread
  2221.         dd      sysfn_activate          ; 3 = activate window
  2222.         dd      sysfn_getidletime       ; 4 = get idle time
  2223.         dd      sysfn_getcpuclock       ; 5 = get cpu clock
  2224.         dd      sysfn_saveramdisk       ; 6 = save ramdisk
  2225.         dd      sysfn_getactive         ; 7 = get active window
  2226.         dd      sysfn_sound_flag        ; 8 = get/set sound_flag
  2227.         dd      sysfn_shutdown          ; 9 = shutdown with parameter
  2228.         dd      sysfn_minimize          ; 10 = minimize window
  2229.         dd      sysfn_getdiskinfo       ; 11 = get disk subsystem info
  2230.         dd      sysfn_lastkey           ; 12 = get last pressed key
  2231.         dd      sysfn_getversion        ; 13 = get kernel version
  2232.         dd      sysfn_waitretrace       ; 14 = wait retrace
  2233.         dd      sysfn_centermouse       ; 15 = center mouse cursor
  2234.         dd      sysfn_getfreemem        ; 16 = get free memory size
  2235.         dd      sysfn_getallmem         ; 17 = get total memory size
  2236.         dd      sysfn_terminate2        ; 18 = terminate thread using PID
  2237.                                         ;                 instead of slot
  2238.         dd      sysfn_mouse_acceleration; 19 = set/get mouse acceleration
  2239.         dd      sysfn_meminfo           ; 20 = get extended memory info
  2240.         dd      sysfn_pid_to_slot       ; 21 = get slot number for pid
  2241.         dd      sysfn_min_rest_window   ; 22 = minimize and restore any window
  2242.         dd      sysfn_min_windows       ; 23 = minimize all windows
  2243.         dd      sysfn_set_screen_sizes  ; 24 = set screen sizes for Vesa
  2244. sysfn_num = ($ - sys_system_table)/4
  2245. endg
  2246. ;------------------------------------------------------------------------------
  2247. sys_system:
  2248.         dec     ebx
  2249.         cmp     ebx, sysfn_num
  2250.         jae     @f
  2251.         jmp     dword [sys_system_table + ebx*4]
  2252. @@:
  2253.         ret
  2254. ;------------------------------------------------------------------------------
  2255. sysfn_shutdown:          ; 18.9 = system shutdown
  2256.         cmp     ecx, 1
  2257.         jl      exit_for_anyone
  2258.         cmp     ecx, 4
  2259.         jg      exit_for_anyone
  2260.         mov     [BOOT_VARS+0x9030], cl
  2261.  
  2262.         mov     eax, [TASK_COUNT]
  2263.         mov     [SYS_SHUTDOWN], al
  2264.         mov     [shutdown_processes], eax
  2265.         call    wakeup_osloop
  2266.         and     dword [esp+32], 0
  2267.  exit_for_anyone:
  2268.         ret
  2269.   uglobal
  2270.    shutdown_processes:
  2271.                        dd 0x0
  2272.   endg
  2273. ;------------------------------------------------------------------------------
  2274. sysfn_terminate:        ; 18.2 = TERMINATE
  2275.         push    ecx
  2276.         cmp     ecx, 2
  2277.         jb      noprocessterminate
  2278.         mov     edx, [TASK_COUNT]
  2279.         cmp     ecx, edx
  2280.         ja      noprocessterminate
  2281.         mov     eax, [TASK_COUNT]
  2282.         shl     ecx, 5
  2283.         mov     edx, [ecx+CURRENT_TASK+TASKDATA.pid]
  2284.         add     ecx, CURRENT_TASK+TASKDATA.state
  2285.         cmp     byte [ecx], 9
  2286.         jz      noprocessterminate
  2287.         push    ecx edx
  2288.         lea     edx, [(ecx-(CURRENT_TASK and 1FFFFFFFh)-TASKDATA.state)*8+SLOT_BASE]
  2289.         call    request_terminate
  2290.         pop     edx ecx
  2291.         test    eax, eax
  2292.         jz      noprocessterminate
  2293. ;--------------------------------------
  2294. ; terminate all network sockets it used
  2295.         pusha
  2296.         mov     eax, edx
  2297.         call    SOCKET_process_end
  2298.         popa
  2299. ;--------------------------------------
  2300.         cmp     [_display.select_cursor], 0
  2301.         je      .restore_end
  2302. ; restore default cursor before killing
  2303.         pusha
  2304.         mov     ecx, [esp+32]
  2305.         shl     ecx, 8
  2306.         add     ecx, SLOT_BASE
  2307.         mov     eax, [def_cursor]
  2308.         cmp     [ecx+APPDATA.cursor], eax
  2309.         je      @f
  2310.         call    restore_default_cursor_before_killing
  2311. @@:
  2312.         popa
  2313. .restore_end:
  2314. ;--------------------------------------
  2315.      ;call MEM_Heap_Lock      ;guarantee that process isn't working with heap
  2316.         mov     [ecx], byte 3; clear possible i40's
  2317.         call    wakeup_osloop
  2318.      ;call MEM_Heap_UnLock
  2319.  
  2320.         cmp     edx, [application_table_owner]; clear app table stat
  2321.         jne     noatsc
  2322.         call    unlock_application_table
  2323. noatsc:
  2324. noprocessterminate:
  2325.         add     esp, 4
  2326.         ret
  2327. ;------------------------------------------------------------------------------
  2328. sysfn_terminate2:
  2329. ;lock application_table_status mutex
  2330. .table_status:
  2331.         call    lock_application_table
  2332.         mov     eax, ecx
  2333.         call    pid_to_slot
  2334.         test    eax, eax
  2335.         jz      .not_found
  2336.         mov     ecx, eax
  2337.         cli
  2338.         call    sysfn_terminate
  2339.         call    unlock_application_table
  2340.         sti
  2341.         and     dword [esp+32], 0
  2342.         ret
  2343. .not_found:
  2344.         call    unlock_application_table
  2345.         or      dword [esp+32], -1
  2346.         ret
  2347. ;------------------------------------------------------------------------------
  2348. sysfn_deactivate:         ; 18.1 = DEACTIVATE WINDOW
  2349.         cmp     ecx, 2
  2350.         jb      .nowindowdeactivate
  2351.         cmp     ecx, [TASK_COUNT]
  2352.         ja      .nowindowdeactivate
  2353.  
  2354.         movzx   esi, word [WIN_STACK + ecx*2]
  2355.         cmp     esi, 1
  2356.         je      .nowindowdeactivate ; already deactive
  2357.  
  2358.         mov     edi, ecx
  2359.         shl     edi, 5
  2360.         add     edi, window_data
  2361.         movzx   esi, word [WIN_STACK + ecx * 2]
  2362.         lea     esi, [WIN_POS + esi * 2]
  2363.         call    window._.window_deactivate
  2364.  
  2365.         call    syscall_display_settings._.calculate_whole_screen
  2366.         call    syscall_display_settings._.redraw_whole_screen
  2367. .nowindowdeactivate:
  2368.         ret
  2369. ;------------------------------------------------------------------------------
  2370. sysfn_activate:         ; 18.3 = ACTIVATE WINDOW
  2371.         cmp     ecx, 2
  2372.         jb      .nowindowactivate
  2373.         cmp     ecx, [TASK_COUNT]
  2374.         ja      .nowindowactivate
  2375. ;-------------------------------------
  2376. @@:
  2377. ; If the window is captured and moved by the user,
  2378. ; then you can't change the position in window stack!!!
  2379.         mov     al, [mouse.active_sys_window.action]
  2380.         and     al, WINDOW_MOVE_AND_RESIZE_FLAGS
  2381.         test    al, al
  2382.         jz      @f
  2383.         call    change_task
  2384.         jmp     @b
  2385. @@:
  2386. ;-------------------------------------
  2387.         mov     [window_minimize], 2; restore window if minimized
  2388.         call    wakeup_osloop
  2389.  
  2390.         movzx   esi, word [WIN_STACK + ecx*2]
  2391.         cmp     esi, [TASK_COUNT]
  2392.         je      .nowindowactivate; already active
  2393.  
  2394.         mov     edi, ecx
  2395.         shl     edi, 5
  2396.         add     edi, window_data
  2397.         movzx   esi, word [WIN_STACK + ecx * 2]
  2398.         lea     esi, [WIN_POS + esi * 2]
  2399.         call    waredraw
  2400. .nowindowactivate:
  2401.         ret
  2402. ;------------------------------------------------------------------------------
  2403. sysfn_getidletime:              ; 18.4 = GET IDLETIME
  2404.         mov     eax, [CURRENT_TASK+32+TASKDATA.cpu_usage]
  2405.         mov     [esp+32], eax
  2406.         ret
  2407. ;------------------------------------------------------------------------------
  2408. sysfn_getcpuclock:              ; 18.5 = GET TSC/SEC
  2409.         mov     eax, dword [cpu_freq]
  2410.         mov     [esp+32], eax
  2411.         ret
  2412. ;------------------------------------------------------------------------------
  2413. get_cpu_freq:
  2414.         mov     eax, dword [cpu_freq]
  2415.         mov     edx, dword [cpu_freq+4]
  2416.         ret
  2417. ;  SAVE ramdisk to /hd/1/menuet.img
  2418. ;!!!!!!!!!!!!!!!!!!!!!!!!
  2419.    include 'blkdev/rdsave.inc'
  2420. ;!!!!!!!!!!!!!!!!!!!!!!!!
  2421. ;------------------------------------------------------------------------------
  2422. align 4
  2423. sysfn_getactive:        ; 18.7 = get active window
  2424.         mov     eax, [TASK_COUNT]
  2425.         movzx   eax, word [WIN_POS + eax*2]
  2426.         mov     [esp+32], eax
  2427.         ret
  2428. ;------------------------------------------------------------------------------
  2429. sysfn_sound_flag:       ; 18.8 = get/set sound_flag
  2430. ;     cmp  ecx,1
  2431.         dec     ecx
  2432.         jnz     nogetsoundflag
  2433.         movzx   eax, byte [sound_flag]; get sound_flag
  2434.         mov     [esp+32], eax
  2435.         ret
  2436.  nogetsoundflag:
  2437. ;     cmp  ecx,2
  2438.         dec     ecx
  2439.         jnz     nosoundflag
  2440.         xor     byte [sound_flag], 1
  2441.  nosoundflag:
  2442.         ret
  2443. ;------------------------------------------------------------------------------
  2444. sysfn_minimize:         ; 18.10 = minimize window
  2445.         mov     [window_minimize], 1
  2446.         call    wakeup_osloop
  2447.         ret
  2448. ;------------------------------------------------------------------------------
  2449. align 4
  2450. sysfn_getdiskinfo:      ; 18.11 = get disk info table
  2451. ;     cmp  ecx,1
  2452.         dec     ecx
  2453.         jnz     full_table
  2454.   small_table:
  2455.         call    for_all_tables
  2456.         mov     ecx, 10
  2457.         cld
  2458.         rep movsb
  2459.         ret
  2460.    for_all_tables:
  2461.         mov     edi, edx
  2462.         mov     esi, DRIVE_DATA
  2463.         ret
  2464.   full_table:
  2465. ;     cmp  ecx,2
  2466.         dec     ecx
  2467.         jnz     exit_for_anyone
  2468.         call    for_all_tables
  2469.         mov     ecx, DRIVE_DATA_SIZE/4
  2470.         cld
  2471.         rep movsd
  2472.         ret
  2473. ;------------------------------------------------------------------------------
  2474. sysfn_lastkey:          ; 18.12 = return 0 (backward compatibility)
  2475.         and     dword [esp+32], 0
  2476.         ret
  2477. ;------------------------------------------------------------------------------
  2478. sysfn_getversion:       ; 18.13 = get kernel ID and version
  2479.         mov     edi, ecx
  2480.         mov     esi, version_inf
  2481.         mov     ecx, version_end-version_inf
  2482.         rep movsb
  2483.         ret
  2484. ;------------------------------------------------------------------------------
  2485. sysfn_waitretrace:     ; 18.14 = sys wait retrace
  2486.      ;wait retrace functions
  2487.  sys_wait_retrace:
  2488.         mov     edx, 0x3da
  2489.  WaitRetrace_loop:
  2490.         in      al, dx
  2491.         test    al, 1000b
  2492.         jz      WaitRetrace_loop
  2493.         and     [esp+32], dword 0
  2494.         ret
  2495. ;------------------------------------------------------------------------------
  2496. align 4
  2497. sysfn_centermouse:      ; 18.15 = mouse centered
  2498. ; removed here by <Lrz>
  2499. ;     call  mouse_centered
  2500. ;* mouse centered - start code- Mario79
  2501. ;mouse_centered:
  2502. ;        push  eax
  2503.         mov     eax, [Screen_Max_X]
  2504.         shr     eax, 1
  2505.         mov     [MOUSE_X], ax
  2506.         mov     eax, [Screen_Max_Y]
  2507.         shr     eax, 1
  2508.         mov     [MOUSE_Y], ax
  2509.         call    wakeup_osloop
  2510. ;        ret
  2511. ;* mouse centered - end code- Mario79
  2512.         xor     eax, eax
  2513.         and     [esp+32], eax
  2514. ;        pop   eax
  2515.         ret
  2516. ;------------------------------------------------------------------------------
  2517. align 4
  2518. sysfn_mouse_acceleration: ; 18.19 = set/get mouse features
  2519.         test    ecx, ecx; get mouse speed factor
  2520.         jnz     .set_mouse_acceleration
  2521.         xor     eax, eax
  2522.         mov     ax, [mouse_speed_factor]
  2523.         mov     [esp+32], eax
  2524.         ret
  2525.  .set_mouse_acceleration:
  2526. ;     cmp  ecx,1  ; set mouse speed factor
  2527.         dec     ecx
  2528.         jnz     .get_mouse_delay
  2529.         mov     [mouse_speed_factor], dx
  2530.         ret
  2531.  .get_mouse_delay:
  2532. ;     cmp  ecx,2  ; get mouse delay
  2533.         dec     ecx
  2534.         jnz     .set_mouse_delay
  2535.         mov     eax, [mouse_delay]
  2536.         mov     [esp+32], eax
  2537.         ret
  2538.  .set_mouse_delay:
  2539. ;     cmp  ecx,3  ; set mouse delay
  2540.         dec     ecx
  2541.         jnz     .set_pointer_position
  2542.         mov     [mouse_delay], edx
  2543.         ret
  2544.  .set_pointer_position:
  2545. ;     cmp  ecx,4  ; set mouse pointer position
  2546.         dec     ecx
  2547.         jnz     .set_mouse_button
  2548.         cmp     dx, word[Screen_Max_Y]
  2549.         ja      .end
  2550.         rol     edx, 16
  2551.         cmp     dx, word[Screen_Max_X]
  2552.         ja      .end
  2553.         mov     [MOUSE_X], edx
  2554.         call    wakeup_osloop
  2555.         ret
  2556.  .set_mouse_button:
  2557. ;     cmp   ecx,5  ; set mouse button features
  2558.         dec     ecx
  2559.         jnz     .end
  2560.         mov     [BTN_DOWN], dl
  2561.         mov     [mouse_active], 1
  2562.         call    wakeup_osloop
  2563.  .end:
  2564.         ret
  2565. ;------------------------------------------------------------------------------
  2566. sysfn_getfreemem:
  2567.         mov     eax, [pg_data.pages_free]
  2568.         shl     eax, 2
  2569.         mov     [esp+32], eax
  2570.         ret
  2571. ;------------------------------------------------------------------------------
  2572. sysfn_getallmem:
  2573.         mov     eax, [MEM_AMOUNT]
  2574.         shr     eax, 10
  2575.         mov     [esp+32], eax
  2576.         ret
  2577. ;------------------------------------------------------------------------------
  2578. sysfn_pid_to_slot:
  2579.         mov     eax, ecx
  2580.         call    pid_to_slot
  2581.         mov     [esp+32], eax
  2582.         ret
  2583. ;------------------------------------------------------------------------------
  2584. sysfn_min_rest_window:
  2585.         pushad
  2586.         mov     eax, edx ; ebx - operating
  2587.         shr     ecx, 1
  2588.         jnc     @f
  2589.         call    pid_to_slot
  2590. @@:
  2591.         or      eax, eax ; eax - number of slot
  2592.         jz      .error
  2593.         cmp     eax, 255    ; varify maximal slot number
  2594.         ja      .error
  2595.         movzx   eax, word [WIN_STACK + eax*2]
  2596.         shr     ecx, 1
  2597.         jc      .restore
  2598.  ; .minimize:
  2599.         call    minimize_window
  2600.         jmp     .exit
  2601. .restore:
  2602.         call    restore_minimized_window
  2603. .exit:
  2604.         popad
  2605.         xor     eax, eax
  2606.         mov     [esp+32], eax
  2607.         ret
  2608. .error:
  2609.         popad
  2610.         xor     eax, eax
  2611.         dec     eax
  2612.         mov     [esp+32], eax
  2613.         ret
  2614. ;------------------------------------------------------------------------------
  2615. sysfn_min_windows:
  2616.         call    minimize_all_window
  2617.         mov     [esp+32], eax
  2618.         call    change_task
  2619.         ret
  2620. ;------------------------------------------------------------------------------
  2621. sysfn_set_screen_sizes:
  2622.         cmp     [SCR_MODE], word 0x13
  2623.         jbe     .exit
  2624.  
  2625.         cmp     [_display.select_cursor], select_cursor
  2626.         jne     .exit
  2627.  
  2628.         cmp     ecx, [display_width_standard]
  2629.         ja      .exit
  2630.  
  2631.         cmp     edx, [display_height_standard]
  2632.         ja      .exit
  2633.  
  2634.         pushfd
  2635.         cli
  2636.         mov     eax, ecx
  2637.         mov     ecx, [_display.pitch]
  2638.         mov     [_display.width], eax
  2639.         dec     eax
  2640.         mov     [_display.height], edx
  2641.         dec     edx
  2642. ; eax - new Screen_Max_X
  2643. ; edx - new Screen_Max_Y
  2644.         mov     [do_not_touch_winmap], 1
  2645.         call    set_screen
  2646.         mov     [do_not_touch_winmap], 0
  2647.         popfd
  2648.         call    change_task
  2649. .exit:
  2650.         ret
  2651. ;------------------------------------------------------------------------------
  2652. uglobal
  2653. screen_workarea RECT
  2654. display_width_standard dd 0
  2655. display_height_standard dd 0
  2656. do_not_touch_winmap db 0
  2657. window_minimize db 0
  2658. sound_flag      db 0
  2659.  
  2660. endg
  2661.  
  2662. UID_NONE=0
  2663. UID_MENUETOS=1   ;official
  2664. UID_KOLIBRI=2    ;russian
  2665.  
  2666. iglobal
  2667. version_inf:
  2668.         db 0,7,7,0  ; version 0.7.7.0
  2669.         db 0
  2670. .rev    dd __REV__
  2671. version_end:
  2672. endg
  2673. ;------------------------------------------------------------------------------
  2674. align 4
  2675. sys_cachetodiskette:
  2676.         cmp     ebx, 1
  2677.         jb      .no_floppy_save
  2678.         cmp     ebx, 2
  2679.         ja      .no_floppy_save
  2680.         call    save_image
  2681.         mov     [esp + 32], eax
  2682.         ret
  2683. .no_floppy_save:
  2684.         mov     [esp + 32], dword 1
  2685.         ret
  2686. ;------------------------------------------------------------------------------
  2687. uglobal
  2688. ;  bgrchanged  dd  0x0
  2689. align 4
  2690. bgrlockpid dd 0
  2691. bgrlock db 0
  2692. endg
  2693. ;------------------------------------------------------------------------------
  2694. align 4
  2695. sys_background:
  2696.         cmp     ebx, 1                     ; BACKGROUND SIZE
  2697.         jnz     nosb1
  2698.         test    ecx, ecx
  2699.         jz      sbgrr
  2700.  
  2701.         test    edx, edx
  2702.         jz      sbgrr
  2703. ;--------------------------------------
  2704. align 4
  2705. @@:
  2706. ;;Maxis use atomic bts for mutexes  4.4.2009
  2707.         bts     dword [bgrlock], 0
  2708.         jnc     @f
  2709.         call    change_task
  2710.         jmp     @b
  2711. ;--------------------------------------
  2712. align 4
  2713. @@:
  2714.         mov     [BgrDataWidth], ecx
  2715.         mov     [BgrDataHeight], edx
  2716. ;    mov   [bgrchanged],1
  2717.  
  2718.         pushad
  2719. ; return memory for old background
  2720.         mov     eax, [img_background]
  2721.         cmp     eax, static_background_data
  2722.         jz      @f
  2723.         stdcall kernel_free, eax
  2724. ;--------------------------------------
  2725. align 4
  2726. @@:
  2727. ; calculate RAW size
  2728.         xor     eax, eax
  2729.         inc     eax
  2730.         cmp     [BgrDataWidth], eax
  2731.         jae     @f
  2732.         mov     [BgrDataWidth], eax
  2733. ;--------------------------------------
  2734. align 4
  2735. @@:
  2736.         cmp     [BgrDataHeight], eax
  2737.         jae     @f
  2738.         mov     [BgrDataHeight], eax
  2739. ;--------------------------------------
  2740. align 4
  2741. @@:
  2742.         mov     eax, [BgrDataWidth]
  2743.         imul    eax, [BgrDataHeight]
  2744.         lea     eax, [eax*3]
  2745. ; it is reserved with aligned to the boundary of 4 KB pages,
  2746. ; otherwise there may be exceptions a page fault for vesa20_drawbackground_tiled
  2747. ; because the 32 bit read is used for  high performance: "mov eax,[esi]"
  2748.         shr     eax, 12
  2749.         inc     eax
  2750.         shl     eax, 12
  2751.         mov     [mem_BACKGROUND], eax
  2752. ; get memory for new background
  2753.         stdcall kernel_alloc, eax
  2754.         test    eax, eax
  2755.         jz      .memfailed
  2756.         mov     [img_background], eax
  2757.         jmp     .exit
  2758. ;--------------------------------------
  2759. align 4
  2760. .memfailed:
  2761. ; revert to static monotone data
  2762.         mov     [img_background], static_background_data
  2763.         xor     eax, eax
  2764.         inc     eax
  2765.         mov     [BgrDataWidth], eax
  2766.         mov     [BgrDataHeight], eax
  2767.         mov     [mem_BACKGROUND], 4
  2768. ;--------------------------------------
  2769. align 4
  2770. .exit:
  2771.         popad
  2772.         mov     [bgrlock], 0
  2773. ;--------------------------------------
  2774. align 4
  2775. sbgrr:
  2776.         ret
  2777. ;------------------------------------------------------------------------------
  2778. align 4
  2779. nosb1:
  2780.         cmp     ebx, 2                     ; SET PIXEL
  2781.         jnz     nosb2
  2782.  
  2783.         mov     eax, [img_background]
  2784.         test    ecx, ecx
  2785.         jz      @f
  2786.         cmp     eax, static_background_data
  2787.         jz      .ret
  2788. ;--------------------------------------
  2789. align 4
  2790. @@:
  2791.         mov     ebx, [mem_BACKGROUND]
  2792.         add     ebx, 4095
  2793.         and     ebx, -4096
  2794.         sub     ebx, 4
  2795.         cmp     ecx, ebx
  2796.         ja      .ret
  2797.  
  2798.         mov     ebx, [eax+ecx]
  2799.         and     ebx, 0xFF000000;255*256*256*256
  2800.         and     edx, 0x00FFFFFF;255*256*256+255*256+255
  2801.         add     edx, ebx
  2802.         mov     [eax+ecx], edx
  2803. ;--------------------------------------
  2804. align 4
  2805. .ret:
  2806.         ret
  2807. ;------------------------------------------------------------------------------
  2808. align 4
  2809. nosb2:
  2810.         cmp     ebx, 3                     ; DRAW BACKGROUND
  2811.         jnz     nosb3
  2812. ;--------------------------------------
  2813. align 4
  2814. draw_background_temp:
  2815.         mov     [background_defined], 1
  2816.         call    force_redraw_background
  2817. ;--------------------------------------
  2818. align 4
  2819. nosb31:
  2820.         ret
  2821. ;------------------------------------------------------------------------------
  2822. align 4
  2823. nosb3:
  2824.         cmp     ebx, 4                     ; TILED / STRETCHED
  2825.         jnz     nosb4
  2826.         cmp     ecx, [BgrDrawMode]
  2827.         je      nosb41
  2828.         mov     [BgrDrawMode], ecx
  2829. ;--------------------------------------
  2830. align 4
  2831. nosb41:
  2832.         ret
  2833. ;------------------------------------------------------------------------------
  2834. align 4
  2835. nosb4:
  2836.         cmp     ebx, 5                     ; BLOCK MOVE TO BGR
  2837.         jnz     nosb5
  2838.         cmp     [img_background], static_background_data
  2839.         jnz     @f
  2840.         test    edx, edx
  2841.         jnz     .fin
  2842.         cmp     esi, 4
  2843.         ja      .fin
  2844. ;--------------------------------------
  2845. align 4
  2846. @@:
  2847.   ; bughere
  2848.         mov     eax, ecx
  2849.         mov     ebx, edx
  2850.         add     ebx, [img_background];IMG_BACKGROUND
  2851.         mov     ecx, esi
  2852.         call    memmove
  2853. ;--------------------------------------
  2854. align 4
  2855. .fin:
  2856.         ret
  2857. ;------------------------------------------------------------------------------
  2858. align 4
  2859. nosb5:
  2860.         cmp     ebx, 6
  2861.         jnz     nosb6
  2862. ;--------------------------------------
  2863. align 4
  2864. ;;Maxis use atomic bts for mutex 4.4.2009
  2865. @@:
  2866.         bts     dword [bgrlock], 0
  2867.         jnc     @f
  2868.         call    change_task
  2869.         jmp     @b
  2870. ;--------------------------------------
  2871. align 4
  2872. @@:
  2873.         mov     eax, [CURRENT_TASK]
  2874.         mov     [bgrlockpid], eax
  2875.         cmp     [img_background], static_background_data
  2876.         jz      .nomem
  2877.         stdcall user_alloc, [mem_BACKGROUND]
  2878.         mov     [esp+32], eax
  2879.         test    eax, eax
  2880.         jz      .nomem
  2881.         mov     ebx, eax
  2882.         shr     ebx, 12
  2883.         or      dword [page_tabs+(ebx-1)*4], DONT_FREE_BLOCK
  2884.         mov     esi, [img_background]
  2885.         shr     esi, 12
  2886.         mov     ecx, [mem_BACKGROUND]
  2887.         add     ecx,