Subversion Repositories Kolibri OS

Rev

Rev 3194 | Rev 3490 | Go to most recent revision | Blame | Compare with Previous | Last modification | View Log | Download | RSS feed

  1. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  2. ;;
  3. ;; Copyright (C) KolibriOS team 2004-2013. All rights reserved.
  4. ;; PROGRAMMING:
  5. ;; Ivan Poddubny
  6. ;; Marat Zakiyanov (Mario79)
  7. ;; VaStaNi
  8. ;; Trans
  9. ;; Mihail Semenyako (mike.dld)
  10. ;; Sergey Kuzmin (Wildwest)
  11. ;; Andrey Halyavin (halyavin)
  12. ;; Mihail Lisovin (Mihasik)
  13. ;; Andrey Ignatiev (andrew_programmer)
  14. ;; NoName
  15. ;; Evgeny Grechnikov (Diamond)
  16. ;; Iliya Mihailov (Ghost)
  17. ;; Sergey Semyonov (Serge)
  18. ;; Johnny_B
  19. ;; SPraid (simba)
  20. ;; Hidnplayr
  21. ;; Alexey Teplov (<Lrz>)
  22. ;; Artem Jerdev (art_zh)
  23. ;;
  24. ;; Data in this file was originally part of MenuetOS project which is
  25. ;; distributed under the terms of GNU GPL. It is modified and redistributed as
  26. ;; part of KolibriOS project under the terms of GNU GPL.
  27. ;;
  28. ;; Copyright (C) MenuetOS 2000-2004 Ville Mikael Turjanmaa
  29. ;; PROGRAMMING:
  30. ;;
  31. ;; Ville Mikael Turjanmaa, villemt@itu.jyu.fi
  32. ;; - main os coding/design
  33. ;; Jan-Michael Brummer, BUZZ2@gmx.de
  34. ;; Felix Kaiser, info@felix-kaiser.de
  35. ;; Paolo Minazzi, paolo.minazzi@inwind.it
  36. ;; quickcode@mail.ru
  37. ;; Alexey, kgaz@crosswinds.net
  38. ;; Juan M. Caravaca, bitrider@wanadoo.es
  39. ;; kristol@nic.fi
  40. ;; Mike Hibbett, mikeh@oceanfree.net
  41. ;; Lasse Kuusijarvi, kuusijar@lut.fi
  42. ;; Jarek Pelczar, jarekp3@wp.pl
  43. ;;
  44. ;; KolibriOS is distributed in the hope that it will be useful, but WITHOUT ANY
  45. ;; WARRANTY. No author or distributor accepts responsibility to anyone for the
  46. ;; consequences of using it or for whether it serves any particular purpose or
  47. ;; works at all, unless he says so in writing. Refer to the GNU General Public
  48. ;; License (the "GPL") for full details.
  49. ;
  50. ;; Everyone is granted permission to copy, modify and redistribute KolibriOS,
  51. ;; but only under the conditions described in the GPL. A copy of this license
  52. ;; is supposed to have been given to you along with KolibriOS so you can know
  53. ;; your rights and responsibilities. It should be in a file named COPYING.
  54. ;; Among other things, the copyright notice and this notice must be preserved
  55. ;; on all copies.
  56. ;;
  57. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  58.  
  59. include 'macros.inc'
  60.  
  61. $Revision: 3487 $
  62.  
  63.  
  64. USE_COM_IRQ     equ 1      ; make irq 3 and irq 4 available for PCI devices
  65.  
  66. include "proc32.inc"
  67. include "kglobals.inc"
  68.  
  69. include "const.inc"
  70. max_processes   equ   255
  71. tss_step        equ   (128+8192) ; tss & i/o - 65535 ports, * 256=557056*4
  72.  
  73.  
  74. os_stack       equ  (os_data_l-gdts)    ; GDTs
  75. os_code       equ  (os_code_l-gdts)
  76. graph_data     equ  (3+graph_data_l-gdts)
  77. tss0          equ  (tss0_l-gdts)
  78. app_code       equ  (3+app_code_l-gdts)
  79. app_data       equ  (3+app_data_l-gdts)
  80. app_tls       equ  (3+tls_data_l-gdts)
  81. pci_code_sel   equ  (pci_code_32-gdts)
  82. pci_data_sel   equ  (pci_data_32-gdts)
  83.  
  84.  
  85. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  86. ;;
  87. ;;   Included files:
  88. ;;
  89. ;;   Kernel16.inc
  90. ;;    - Bootcode.inc  Hardware setup
  91. ;;
  92. ;;   Kernel32.inc
  93. ;;    - Sys32.inc     Process management
  94. ;;    - Shutdown.inc  Shutdown and restart
  95. ;;    - Fat32.inc     Read / write hd
  96. ;;    - Vesa12.inc    Vesa 1.2 driver
  97. ;;    - Vesa20.inc    Vesa 2.0 driver
  98. ;;    - Vga.inc       VGA driver
  99. ;;    - Stack.inc     Network interface
  100. ;;    - Mouse.inc     Mouse pointer
  101. ;;    - Scincode.inc  Window skinning
  102. ;;    - Pci32.inc     PCI functions
  103. ;;
  104. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  105.  
  106.  
  107. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  108. ;;                                                                      ;;
  109. ;;                  16 BIT ENTRY FROM BOOTSECTOR                        ;;
  110. ;;                                                                      ;;
  111. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  112.  
  113. use16
  114.                   org   0x0
  115.                   jmp   start_of_code
  116.  
  117. version db    'Kolibri-A   version 0.1.0.0      ',13,10,13,10,0
  118.  
  119. diff16 "bootcode start: ",0,$
  120. include "boot/bootcode.inc"    ; 16 bit system boot code
  121.  
  122. diff16 "biosdisk start: ",0,$
  123. include "detect/biosdisk.inc"
  124.  
  125. diff16 "end of code16 : ",0,$
  126.  
  127. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  128. ;;                                                                      ;;
  129. ;;                  SWITCH TO 32 BIT PROTECTED MODE                     ;;
  130. ;;                                                                      ;;
  131. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  132.  
  133. switch_32:
  134. ; CR0 Flags - Protected mode and Paging
  135.  
  136.         mov ecx, CR0_PE
  137.  
  138. ; Enabling 32 bit protected mode
  139.  
  140.         sidt    [cs:old_ints_h]
  141.  
  142.         cli                             ; disable all irqs
  143.         cld
  144.         mov     al,255                  ; mask all irqs
  145.         out     0xa1,al
  146.         out     0x21,al
  147.    l.5: in      al, 0x64                ; Enable A20
  148.         test    al, 2
  149.         jnz     l.5
  150.         mov     al, 0xD1
  151.         out     0x64, al
  152.    l.6: in      al, 0x64
  153.         test    al, 2
  154.         jnz     l.6
  155.         mov     al, 0xDF
  156.         out     0x60, al
  157.    l.7: in      al, 0x64
  158.         test    al, 2
  159.         jnz     l.7
  160.         mov     al, 0xFF
  161.         out     0x64, al
  162.  
  163.         lgdt    [cs:tmp_gdt]            ; Load GDT
  164.         mov     eax, cr0                ; protected mode
  165.         or      eax, ecx
  166.         and     eax, 10011111b *65536*256 + 0xffffff ; caching enabled
  167.         mov     cr0, eax
  168.         jmp     pword os_code:B32       ; jmp to enable 32 bit mode
  169.  
  170. align 8
  171. tmp_gdt:
  172.  
  173.         dw     23
  174.         dd     tmp_gdt+0x10000
  175.         dw     0
  176.  
  177.         dw     0xffff
  178.         dw     0x0000
  179.         db     0x00
  180.         dw     11011111b *256 +10011010b
  181.         db     0x00
  182.  
  183.         dw     0xffff
  184.         dw     0x0000
  185.         db     0x00
  186.         dw     11011111b *256 +10010010b
  187.         db     0x00
  188.  
  189. diff10 "32bit enter sz :",switch_32,$
  190. diff16 "data16   start :",0,$
  191.  
  192. include "data16.inc"
  193.  
  194.  
  195. use32
  196. org $+0x10000
  197.  
  198. align 4
  199. B32:
  200. diff16 "32-bit code start ",0,$
  201.            mov   ax,os_stack       ; Selector for os
  202.            mov   ds,ax
  203.            mov   es,ax
  204.            mov   fs,ax
  205.            mov   gs,ax
  206.            mov   ss,ax
  207.            mov   esp,0x4ec00       ; Set stack
  208.  
  209. ;-------------------------------------------------------------------------------
  210.            call preinit_mem     ; (init.inc)
  211.  
  212.            call test_cpu        ; (init.inc - to be moved to bus/CPU.inc)
  213.            bts [cpu_caps-OS_BASE], CAPS_TSC     ;force use rdtsc
  214.  
  215.            call init_BIOS32     ; (init.inc - to be removed later)
  216.  
  217. ; PCIe extended config space access
  218.  
  219.         display '** Platform chosen (const.inc): '
  220. if PLATFORM>PLATFORM_RS780
  221.         call fusion_pcie_init   ; (bus/HT.inc)
  222.         display 'RS880/Fusion '
  223. else
  224.         call rs7xx_pcie_init    ; (bus/HT.inc)
  225.         display 'RS780 '
  226. end if
  227.         display 10,13
  228.  
  229.  
  230. ; MEMORY MODEL
  231.            call init_mem        ; (init.inc)
  232.  
  233. ; ENABLE PAGING
  234.  
  235.            mov eax, sys_pgdir-OS_BASE
  236.            mov cr3, eax
  237.  
  238.            mov eax,cr0
  239.            or eax,CR0_PG+CR0_WP
  240.            mov cr0,eax
  241.  
  242.            lgdt [gdts]
  243.            jmp pword os_code:high_code
  244.  
  245. diff16 "32-bit init size ",B32,$
  246.  
  247. align 4
  248. bios32_entry    dd ?
  249. tmp_page_tabs   dd ?
  250.  
  251.  
  252. __DEBUG__ fix 1
  253. __DEBUG_LEVEL__ fix 1
  254. include 'init.inc'
  255.  
  256. org OS_BASE+$
  257.  
  258. align 4
  259. high_code:
  260.            mov ax, os_stack
  261.            mov bx, app_data
  262.            mov cx, app_tls
  263.            mov ss, ax
  264.            add esp, OS_BASE
  265.  
  266.            mov ds, bx
  267.            mov es, bx
  268.            mov fs, cx
  269.            mov gs, bx
  270.  
  271.            bt [cpu_caps], CAPS_PGE
  272.            jnc @F
  273.  
  274.            or dword [sys_pgdir+(OS_BASE shr 20)], PG_GLOBAL
  275.  
  276.            mov ebx, cr4
  277.            or ebx, CR4_PGE
  278.            mov cr4, ebx
  279. @@:
  280.            xor eax, eax
  281.            mov dword [sys_pgdir], eax
  282.            mov dword [sys_pgdir+4], eax
  283.  
  284.            mov eax, cr3
  285.            mov cr3, eax           ; flush TLB
  286.  
  287. ; SAVE REAL MODE VARIABLES
  288.         xor     eax, eax
  289.         mov     [IDEContrRegsBaseAddr], ax
  290. ; -----------------------------------------
  291.         inc     eax
  292. ;        mov     al, [BOOT_VAR+0x901F]           ; DMA access
  293.         mov     [allow_dma_access], al
  294.         mov     eax, 32                         ; << bpp
  295.         mov     [ScreenBPP],al
  296.         mov     [_display.bpp], eax
  297.  
  298.         mov     [_display.vrefresh], 60
  299.         mov     [_display.disable_mouse],  __sys_disable_mouse
  300.  
  301.         mov     eax, 1024                       ; << X max
  302.         mov     [_display.width], eax
  303.         dec     eax
  304.         mov     [Screen_Max_X],eax
  305.         mov     [screen_workarea.right],eax
  306.         mov     eax,768                         ; << Y max
  307.         mov     [_display.height], eax
  308.         dec     eax
  309.         mov     [Screen_Max_Y],eax
  310.         mov     [screen_workarea.bottom],eax
  311.         mov     eax, 0x7055                     ; << screen mode
  312.         mov     [SCR_MODE],eax
  313.  
  314.         mov     eax, 4096                       ; << may be different!
  315.         mov     [BytesPerScanLine],ax
  316.         mov     [_display.pitch], eax
  317.  
  318.         mov     eax, [_display.width]
  319.         mul     [_display.height]
  320.         mov     [_WinMapSize], eax
  321.  
  322.         mov     esi, BOOT_VAR+0x9080
  323.         movzx   ecx, byte [esi-1]
  324.         mov     [NumBiosDisks], ecx
  325.         mov     edi, BiosDisksData
  326.         rep     movsd
  327.  
  328.  
  329. ; GRAPHICS ADDRESSES
  330.  
  331.         and     byte [BOOT_VAR+0x901e],0x0
  332.         mov     eax, [BOOT_VAR+0x9018]
  333.         mov     [LFBAddress],eax
  334.  
  335.         mov     [PUTPIXEL],dword __sys_putpixel
  336.         mov     [GETPIXEL],dword get_pixel
  337.  
  338. ; -------- Fast System Call init ----------
  339. .SEnP:
  340. ; AMD SYSCALL/SYSRET
  341.            mov ecx, MSR_AMD_EFER
  342.            rdmsr
  343.            or eax, 1   ; bit_0 - System Call Extension (SCE)
  344.            wrmsr
  345.  
  346.         ; Bits of EDX :
  347.         ; Bit 31..16 During the SYSRET instruction, this field is copied into the CS register
  348.         ;  and the contents of this field, plus 8, are copied into the SS register.
  349.         ; Bit 15..0 During the SYSCALL instruction, this field is copied into the CS register
  350.         ;  and the contents of this field, plus 8, are copied into the SS register.
  351.  
  352.            mov edx, 0x1B000B    ; RING3 task stack will be used for fast syscalls!
  353.  
  354.            mov eax, syscall_entry
  355.            mov ecx, MSR_AMD_STAR
  356.            wrmsr
  357. .noSYSCALL:
  358. ; -----------------------------------------
  359.         stdcall alloc_page
  360.         stdcall map_page, tss-0xF80, eax, PG_SW         ; lower 0xF80 bytes might be used for something
  361.         stdcall alloc_page
  362.         inc     eax
  363.         mov     [SLOT_BASE+256+APPDATA.io_map], eax
  364.         stdcall map_page, tss+0x80, eax, PG_SW
  365.         stdcall alloc_page
  366.         inc     eax
  367.         mov     dword [SLOT_BASE+256+APPDATA.io_map+4], eax
  368.         stdcall map_page, tss+0x1080, eax, PG_SW
  369.  
  370. ; LOAD IDT
  371.  
  372.            call         build_interrupt_table ;lidt is executed
  373.  
  374.            call         init_kernel_heap
  375.            stdcall      kernel_alloc, RING0_STACK_SIZE+512
  376.            mov  [os_stack_seg], eax
  377.  
  378.            lea  esp, [eax+RING0_STACK_SIZE]
  379.  
  380.            mov  [tss._ss0], os_stack
  381.            mov  [tss._esp0], esp
  382.            mov  [tss._esp], esp
  383.            mov  [tss._cs],os_code
  384.            mov  [tss._ss],os_stack
  385.            mov  [tss._ds],app_data
  386.            mov  [tss._es],app_data
  387.            mov  [tss._fs],app_data
  388.            mov  [tss._gs],app_data
  389.            mov  [tss._io],128
  390. ;Add IO access table - bit array of permitted ports
  391.            mov  edi, tss._io_map_0
  392.            xor  eax, eax
  393.            mov  ecx, 2047
  394.            rep  stosd                ; access to 65504 ports granted
  395.            not  eax                  ; the last 32 ports blocked
  396.            stosd
  397.  
  398.            mov  ax,tss0
  399.            ltr  ax
  400.  
  401.            mov  [LFBSize], 0x800000
  402.            call init_LFB
  403.            call init_fpu
  404.            call init_malloc
  405. ;-
  406.            stdcall alloc_kernel_space, 0x51000
  407.            mov  [default_io_map], eax
  408.  
  409.            add  eax, 0x2000
  410.            mov  [ipc_tmp], eax
  411.            mov  ebx, 0x1000
  412.  
  413.            add  eax, 0x40000
  414.            mov  [proc_mem_map], eax
  415.  
  416.            add  eax, 0x8000
  417.            mov  [proc_mem_pdir], eax
  418.  
  419.            add  eax, ebx
  420.            mov  [proc_mem_tab], eax
  421.  
  422.            add  eax, ebx
  423.            mov  [tmp_task_pdir], eax
  424.  
  425.            add  eax, ebx
  426.            mov  [tmp_task_ptab], eax
  427.  
  428.            add  eax, ebx
  429.            mov  [ipc_pdir], eax
  430.  
  431.            add  eax, ebx
  432.            mov  [ipc_ptab], eax
  433.  
  434.            stdcall kernel_alloc, (unpack.LZMA_BASE_SIZE+(unpack.LZMA_LIT_SIZE shl \
  435.                                  (unpack.lc+unpack.lp)))*4
  436.  
  437.            mov  [unpack.p], eax     ; unpacker.inc
  438.  
  439.            call init_events
  440.            mov  eax, srv.fd-SRV_FD_OFFSET
  441.            mov  [srv.fd], eax
  442.            mov  [srv.bk], eax
  443.  
  444.            mov  edi, irq_tab
  445.            xor  eax, eax
  446.            mov  ecx, 16
  447.            rep  stosd
  448.  
  449. ;Set base of graphic segment to linear address of LFB
  450.         mov     eax,[LFBAddress]          ; set for gs
  451.         mov     [graph_data_l+2],ax
  452.         shr     eax,16
  453.         mov     [graph_data_l+4],al
  454.         mov     [graph_data_l+7],ah
  455.  
  456. ;       or      [KERNEL_ALLOC_FLAG], dword PG_NOCACHE   ;<<<<<<<<<<<<<<<<
  457.         stdcall kernel_alloc, [_WinMapSize]
  458.         mov     [_WinMapAddress], eax
  459. ;       xor     [KERNEL_ALLOC_FLAG], dword PG_NOCACHE   ;<<<<<<<<<<<<<<<<
  460.  
  461.         xor  eax,eax
  462.         inc  eax
  463.         mov [CURRENT_TASK],eax          ;dword 1
  464.         mov [TASK_COUNT],eax            ;dword 1
  465.         mov [TASK_BASE],dword TASK_DATA
  466.         mov [current_slot], SLOT_BASE+256
  467.  
  468. ; set background
  469.  
  470.         mov   [BgrDrawMode],eax
  471.         mov   [BgrDataWidth],eax
  472.         mov   [BgrDataHeight],eax
  473.         mov   [mem_BACKGROUND], 4
  474.         mov   [img_background], static_background_data
  475.  
  476.         mov     [SLOT_BASE + 256 + APPDATA.dir_table], sys_pgdir - OS_BASE
  477.  
  478.         stdcall kernel_alloc, 0x10000/8
  479.         mov     edi, eax
  480.         mov     [network_free_ports], eax
  481.         or      eax, -1
  482.         mov     ecx, 0x10000/32
  483.         rep     stosd
  484.  
  485. ; REDIRECT ALL IRQ'S TO INT'S 0x20-0x2f
  486.  
  487.         call  rerouteirqs
  488.  
  489. ; Initialize system V86 machine
  490.         call    init_sys_v86
  491.  
  492. ; TIMER SET TO 1/100 S
  493.  
  494.         mov   al,0x34              ; set to 100Hz
  495.         out   0x43,al
  496.         mov   al,0x9b              ; lsb    1193180 / 1193
  497.         out   0x40,al
  498.         mov   al,0x2e              ; msb
  499.         out   0x40,al
  500.  
  501. ; Enable timer IRQ (IRQ0) and hard drives IRQs (IRQ14, IRQ15)
  502. ; they are used: when partitions are scanned, hd_read relies on timer
  503. ; Also enable IRQ2, because in some configurations
  504. ; IRQs from slave controller are not delivered until IRQ2 on master is enabled
  505.         mov     al, 0xFA
  506.         out     0x21, al
  507.         mov     al, 0x3F
  508.         out     0xA1, al
  509.  
  510. ; Enable interrupts in IDE controller
  511.         mov     al, 0
  512.         mov     dx, 0x3F6
  513.         out     dx, al
  514.         mov     dl, 0x76
  515.         out     dx, al
  516.  
  517. ;!!!!!!!!!!!!!!!!!!!!!!!!!!
  518. include 'detect/disks.inc'
  519. ;!!!!!!!!!!!!!!!!!!!!!!!!!!
  520.  
  521.   call Parser_params
  522.  
  523. ; READ RAMDISK IMAGE FROM HD
  524.  
  525. ;!!!!!!!!!!!!!!!!!!!!!!!
  526. ;include 'boot/rdload.inc'
  527. ;!!!!!!!!!!!!!!!!!!!!!!!
  528. ;    mov    [dma_hdd],1
  529. ; CALCULATE FAT CHAIN FOR RAMDISK
  530.  
  531.         call  calculatefatchain
  532.  
  533. ; LOAD VMODE DRIVER
  534.  
  535. ;!!!!!!!!!!!!!!!!!!!!!!!
  536. include 'vmodeld.inc'
  537. ;!!!!!!!!!!!!!!!!!!!!!!!
  538.  
  539.  
  540. ; LOAD FONTS I and II
  541.  
  542.         stdcall read_file, char, FONT_I, 0, 2304
  543.         stdcall read_file, char2, FONT_II, 0, 2560
  544.  
  545. ;        mov   esi,boot_fonts
  546. ;        call  boot_log
  547.  
  548. ; PRINT AMOUNT OF MEMORY
  549. ;        mov     esi, boot_memdetect
  550. ;        call    boot_log
  551.  
  552.         movzx   ecx, word [boot_y]
  553.         or      ecx, (10+29*6) shl 16 ; "Determining amount of memory"
  554.         sub     ecx, 10
  555.         mov     edx, 0xFFFFFF
  556.         mov     ebx, [MEM_AMOUNT]
  557.         shr     ebx, 20
  558.         xor     edi,edi
  559.         mov     eax, 0x00040000
  560.                 inc             edi
  561.         call    display_number_force
  562.  
  563. ; BUILD SCHEDULER
  564.  
  565.         call   build_scheduler ; sys32.inc
  566.  
  567. ;        mov    esi,boot_devices
  568. ;        call   boot_log
  569.  
  570.         mov  [pci_access_enabled],1
  571.  
  572.  
  573. ; SET PRELIMINARY WINDOW STACK AND POSITIONS
  574.  
  575.         mov   esi,boot_windefs
  576.         call  boot_log
  577.         call  set_window_defaults
  578.  
  579. ; SET BACKGROUND DEFAULTS
  580.  
  581. ;        mov   esi,boot_bgr
  582. ;        call  boot_log
  583.         call  init_background   ;
  584.         call  calculatebackground
  585.  
  586. ; SET UP OS TASK
  587.  
  588. ;        mov  esi,boot_setostask
  589. ;        call boot_log
  590.  
  591.         xor  eax, eax
  592.         mov  dword [SLOT_BASE+APPDATA.fpu_state], fpu_data
  593.         mov  dword [SLOT_BASE+APPDATA.exc_handler], eax
  594.         mov  dword [SLOT_BASE+APPDATA.except_mask], eax
  595.  
  596.         ; name for OS/IDLE process
  597.  
  598.         mov dword [SLOT_BASE+256+APPDATA.app_name],   dword 'OS/I'
  599.         mov dword [SLOT_BASE+256+APPDATA.app_name+4], dword 'DLE '
  600.         mov edi, [os_stack_seg]
  601.         mov dword [SLOT_BASE+256+APPDATA.pl0_stack], edi
  602.         add edi, 0x2000-512
  603.         mov dword [SLOT_BASE+256+APPDATA.fpu_state], edi
  604.         mov dword [SLOT_BASE+256+APPDATA.saved_esp0], edi ; just for case
  605.         ; [SLOT_BASE+256+APPDATA.io_map] was set earlier
  606.  
  607.         mov esi, fpu_data
  608.         mov ecx, 512/4
  609.         cld
  610.         rep movsd
  611.  
  612.         mov dword [SLOT_BASE+256+APPDATA.exc_handler], eax
  613.         mov dword [SLOT_BASE+256+APPDATA.except_mask], eax
  614.  
  615.         mov ebx, SLOT_BASE+256+APP_OBJ_OFFSET
  616.         mov  dword [SLOT_BASE+256+APPDATA.fd_obj], ebx
  617.         mov  dword [SLOT_BASE+256+APPDATA.bk_obj], ebx
  618.  
  619.         mov  dword [SLOT_BASE+256+APPDATA.cur_dir], sysdir_path
  620.         mov dword [SLOT_BASE+256+APPDATA.tls_base], eax
  621.  
  622.         ; task list
  623.         mov  dword [TASK_DATA+TASKDATA.mem_start],eax   ; process base address
  624.         inc  eax
  625.         mov  dword [CURRENT_TASK],eax
  626.         mov  dword [TASK_COUNT],eax
  627.         mov  [current_slot], SLOT_BASE+256
  628.         mov  [TASK_BASE],dword TASK_DATA
  629.         mov  byte[TASK_DATA+TASKDATA.wnd_number],al     ; on screen number
  630.         mov  dword [TASK_DATA+TASKDATA.pid], eax        ; process id number
  631.  
  632.         call init_display
  633.         mov eax, [def_cursor]
  634.         mov [SLOT_BASE+APPDATA.cursor],eax
  635.         mov [SLOT_BASE+APPDATA.cursor+256],eax
  636.  
  637.  
  638.   ; READ TSC / SECOND == Fusion only!
  639.  
  640.         cli
  641.         mov     edx, PCIe_CONFIG_SPACE + 0xE0
  642.         mov     eax, 0x013080F0         ; BIOS timer reg.
  643.         mov     [edx], eax
  644.         add     dl, 4
  645.         mov     edi, edx
  646.         mov     eax, [edi]              ; old microseconds
  647.         inc     eax                     ; next precise microsecond
  648.         mov     esi, eax
  649.  @@:
  650.         mov     eax, [edi]
  651.         cmp     eax, esi
  652.         jne     @b
  653.  
  654.         rdtsc
  655.         mov     ebp, eax                ; clockmark
  656.         add     esi, 20                 ; wait 20us
  657.  @@:
  658.         mov     eax, [edi]
  659.         cmp     eax, esi
  660.         jne     @b
  661.  
  662.         rdtsc
  663.         sub     eax, ebp
  664.         mov     ebx, 50000
  665.         mul     ebx                   ; clks per second
  666.         sti
  667.  
  668.         mov   [CPU_FREQ],eax          ; save tsc / sec
  669.         mov   ebx, 1000000
  670.         div   ebx
  671.         mov [stall_mcs], eax
  672. ; PRINT CPU FREQUENCY
  673.         mov     esi, boot_cpufreq
  674.         call    boot_log
  675.  
  676.         mov     ebx, eax
  677.         movzx   ecx, word [boot_y]
  678.         add     ecx, (10+17*6) shl 16 - 10 ; 'CPU frequency is '
  679.         mov     edx, 0xFFFFFF
  680.         xor     edi,edi
  681.         mov     eax, 0x00040000
  682.                 inc             edi
  683.         call    display_number_force
  684.  
  685. ; SET VARIABLES
  686.  
  687.         call  set_variables
  688.  
  689. ; SET MOUSE
  690.  
  691.         stdcall load_driver, szPS2MDriver
  692.  
  693.         cli
  694.  
  695. ; STACK AND FDC
  696.  
  697.         call  stack_init
  698. ;       call  fdc_init
  699.  
  700.  
  701. ; LOAD DEFAULT SKIN
  702.  
  703.         call    load_default_skin
  704.  
  705. ;protect io permission map
  706.  
  707.            mov esi, [default_io_map]
  708.            stdcall map_page,esi,[SLOT_BASE+256+APPDATA.io_map], PG_MAP
  709.            add esi, 0x1000
  710.            stdcall map_page,esi,[SLOT_BASE+256+APPDATA.io_map+4], PG_MAP
  711.  
  712.            stdcall map_page,tss._io_map_0,\
  713.                    [SLOT_BASE+256+APPDATA.io_map], PG_MAP
  714.            stdcall map_page,tss._io_map_1,\
  715.                    [SLOT_BASE+256+APPDATA.io_map+4], PG_MAP
  716.  
  717.  
  718.         call init_userDMA       ; <<<<<<<<< ============== core/memory.inc =================
  719. ;        mov     esi, boot_uDMA_ok
  720. ;        call    boot_log
  721.  
  722. ; LOAD FIRST APPLICATION
  723.         cli
  724.  
  725.         cmp   byte [BOOT_VAR+0x9030],1
  726.         jne   no_load_vrr_m
  727.  
  728.         mov     ebp, vrr_m
  729.         call    fs_execute_from_sysdir
  730.  
  731. ;        cmp   eax,2                  ; if vrr_m app found (PID=2)
  732.         sub   eax,2
  733.         jz    first_app_found
  734.  
  735. no_load_vrr_m:
  736.  
  737.         mov     ebp, firstapp
  738.         call    fs_execute_from_sysdir
  739.  
  740. ;        cmp   eax,2                  ; continue if a process has been loaded
  741.         sub   eax,2
  742.         jz    first_app_found
  743.  
  744. ;        mov     esi, boot_failed
  745. ;        call    boot_log
  746.  
  747.         mov   eax, 0xDEADBEEF        ; otherwise halt
  748.         hlt
  749.  
  750. first_app_found:
  751.  
  752.         cli
  753.  
  754.         ;mov   [TASK_COUNT],dword 2
  755.         push  1
  756.         pop   dword [CURRENT_TASK]      ; set OS task fisrt
  757.  
  758. ; SET KEYBOARD PARAMETERS
  759.         mov   al, 0xf6         ; reset keyboard, scan enabled
  760.         call  kb_write
  761.  
  762.         ; wait until 8042 is ready
  763.         xor ecx,ecx
  764.       @@:
  765.         in     al,64h
  766.         and    al,00000010b
  767.         loopnz @b
  768.  
  769.  
  770.         mov   al, 0xF3       ; set repeat rate & delay
  771.         call  kb_write
  772. ;        call  kb_read
  773.         mov   al, 0 ; 30 250 ;00100010b ; 24 500  ;00100100b  ; 20 500
  774.         call  kb_write
  775. ;        call  kb_read
  776.      ;// mike.dld [
  777.         call  set_lights
  778.      ;// mike.dld ]
  779.  
  780.  
  781.  
  782. ; START MULTITASKING
  783.  
  784.         stdcall attach_int_handler, 1, irq1, 0
  785.  
  786.         cmp     [IDEContrRegsBaseAddr], 0
  787.         setnz   [dma_hdd]
  788.         mov [timer_ticks_enable],1              ; for cd driver
  789.  
  790.         sti
  791.         call change_task
  792.  
  793.         jmp osloop                              ; Fly :)
  794.  
  795. diff16 "init code end  ",0,$
  796.  
  797. unpacker_inc:
  798. include 'unpacker.inc'
  799. diff16 "unpacker code  ",unpacker_inc,$
  800.  
  801. include 'fdo.inc'
  802.  
  803. align 4
  804. boot_log:
  805.          pushad
  806.  
  807.         mov   ebx,10*65536
  808.         mov   bx,word [boot_y]
  809.         add   [boot_y],dword 10
  810.         mov   ecx,0x80ffffff   ; ASCIIZ string with white color
  811.                 xor       edi,edi
  812.         mov   edx,esi
  813.                 inc       edi
  814.         call  dtext
  815.  
  816.         popad
  817.  
  818.         ret
  819.  
  820. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  821. ;                                                                    ;
  822. ;                    MAIN OS LOOP START                              ;
  823. ;                                                                    ;
  824. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  825. align 32
  826. osloop:
  827.         call   [draw_pointer]
  828.         call    window_check_events
  829.         call    mouse_check_events
  830.         call   checkmisc
  831.         call   stack_handler
  832.         call   checkidle
  833.         jmp    osloop
  834. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  835. ;                                                                    ;
  836. ;                      MAIN OS LOOP END                              ;
  837. ;                                                                    ;
  838. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  839. align 4
  840. checkidle:
  841.         pushad
  842.         call    change_task
  843.         jmp     idle_loop_entry
  844.   idle_loop:
  845.         cmp     eax,[idlemem]     ; eax == [timer_ticks]
  846.         jne     idle_exit
  847.         rdtsc   ;call _rdtsc
  848.         mov     ecx,eax
  849.         hlt
  850.         rdtsc   ;call _rdtsc
  851.         sub     eax,ecx
  852.         add     [idleuse],eax
  853.   idle_loop_entry:
  854.         mov     eax,[timer_ticks] ; eax =  [timer_ticks]
  855.         cmp     [check_idle_semaphore],0
  856.         je      idle_loop
  857.         dec     [check_idle_semaphore]
  858.   idle_exit:
  859.         mov     [idlemem],eax     ; eax == [timer_ticks]
  860.         popad
  861.         ret
  862.  
  863. uglobal
  864.   idlemem               dd   0x0
  865.   idleuse               dd   0x0
  866.   idleusesec            dd   0x0
  867.   check_idle_semaphore  dd   0x0
  868. endg
  869.  
  870.  
  871.  
  872. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  873. ;                                                                      ;
  874. ;                   INCLUDED SYSTEM FILES                              ;
  875. ;                                                                      ;
  876. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  877.  
  878.  
  879. include "kernel32.inc"
  880.  
  881.  
  882. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  883. ;                                                                      ;
  884. ;                       KERNEL FUNCTIONS                               ;
  885. ;                                                                      ;
  886. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  887.  
  888. reserve_irqs_ports:
  889.         ; removed
  890.         ret
  891.  
  892. setirqreadports:
  893.         ; removed
  894.         ret
  895.  
  896. iglobal
  897.   process_number dd 0x1
  898. endg
  899.  
  900. set_variables:
  901.  
  902.         mov   ecx,0x100                       ; flush port 0x60
  903. .fl60:  in    al,0x60
  904.         loop  .fl60
  905.         push  eax
  906.  
  907.         mov   ax,[BOOT_VAR+0x900c]
  908.         shr   ax,1
  909.         shl   eax,16
  910.         mov   ax,[BOOT_VAR+0x900A]
  911.         shr   ax,1
  912.         mov   [MOUSE_X],eax
  913.  
  914.         xor   eax,eax
  915.         mov   [BTN_ADDR],dword BUTTON_INFO    ; address of button list
  916.  
  917.         mov   byte [MOUSE_BUFF_COUNT],al                 ; mouse buffer
  918.         mov   byte [KEY_COUNT],al                 ; keyboard buffer
  919.         mov   byte [BTN_COUNT],al                 ; button buffer
  920. ;        mov   [MOUSE_X],dword 100*65536+100    ; mouse x/y
  921.  
  922.      ;!! IP 04.02.2005:
  923.         mov   byte [DONT_SWITCH],al ; change task if possible
  924.         pop   eax
  925.         ret
  926.  
  927. align 4
  928. ;input  eax=43,bl-byte of output, ecx - number of port
  929. sys_outport:
  930.      and   [esp+32],dword 1     ; for backward compatibility: operation failed
  931.     ret
  932.  
  933. display_number:
  934. ;It is not optimization
  935.         mov     eax, ebx
  936.         mov     ebx, ecx
  937.         mov     ecx, edx
  938.         mov     edx, esi
  939.         mov     esi, edi
  940. ; eax = print type, al=0 -> ebx is number
  941. ;                   al=1 -> ebx is pointer
  942. ;                   ah=0 -> display decimal
  943. ;                   ah=1 -> display hexadecimal
  944. ;                   ah=2 -> display binary
  945. ;                   eax bits 16-21 = number of digits to display (0-32)
  946. ;                   eax bits 22-31 = reserved
  947. ;
  948. ; ebx = number or pointer
  949. ; ecx = x shl 16 + y
  950. ; edx = color
  951.     xor     edi, edi
  952. display_number_force:
  953.     push  eax
  954.     and   eax,0x3fffffff
  955.     cmp   eax,0xffff            ; length > 0 ?
  956.     pop   eax
  957.     jge   cont_displ
  958.     ret
  959.    cont_displ:
  960.      push  eax
  961.      and   eax,0x3fffffff
  962.      cmp   eax,61*0x10000        ; length <= 60 ?
  963.      pop   eax
  964.      jb    cont_displ2
  965.      ret
  966.    cont_displ2:
  967.  
  968.      pushad
  969.  
  970.      cmp   al,1                  ; ecx is a pointer ?
  971.      jne   displnl1
  972.      mov   ebp,ebx
  973.      add   ebp,4
  974.      mov   ebp,[ebp+std_application_base_address]
  975.      mov   ebx,[ebx+std_application_base_address]
  976.  displnl1:
  977.      sub   esp,64
  978.  
  979.     test   ah,ah                  ; DECIMAL
  980.     jnz   no_display_desnum
  981.     shr   eax,16
  982.     and   eax,0xC03f
  983. ;     and   eax,0x3f
  984.     push  eax
  985.     and   eax,0x3f
  986.     mov   edi,esp
  987.     add   edi,4+64-1
  988.     mov   ecx,eax
  989.     mov   eax,ebx
  990.     mov   ebx,10
  991.  d_desnum:
  992.      xor   edx,edx
  993.      call  division_64_bits
  994.      div   ebx
  995.      add   dl,48
  996.      mov   [edi],dl
  997.      dec   edi
  998.      loop  d_desnum
  999.      pop   eax
  1000.      call  normalize_number
  1001.      call  draw_num_text
  1002.      add   esp,64
  1003.      popad
  1004.      ret
  1005.    no_display_desnum:
  1006.  
  1007.      cmp   ah,0x01               ; HEXADECIMAL
  1008.      jne   no_display_hexnum
  1009.      shr   eax,16
  1010.      and   eax,0xC03f
  1011. ;     and   eax,0x3f
  1012.      push  eax
  1013.      and   eax,0x3f
  1014.      mov   edi,esp
  1015.      add   edi,4+64-1
  1016.      mov   ecx,eax
  1017.      mov   eax,ebx
  1018.      mov   ebx,16
  1019.    d_hexnum:
  1020.      xor   edx,edx
  1021.      call  division_64_bits
  1022.      div   ebx
  1023.    hexletters = __fdo_hexdigits
  1024.      add   edx,hexletters
  1025.      mov   dl,[edx]
  1026.      mov   [edi],dl
  1027.      dec   edi
  1028.      loop  d_hexnum
  1029.      pop   eax
  1030.      call  normalize_number
  1031.      call  draw_num_text
  1032.      add   esp,64
  1033.      popad
  1034.      ret
  1035.    no_display_hexnum:
  1036.  
  1037.      cmp   ah,0x02               ; BINARY
  1038.      jne   no_display_binnum
  1039.      shr   eax,16
  1040.      and   eax,0xC03f
  1041. ;     and   eax,0x3f
  1042.      push  eax
  1043.      and   eax,0x3f
  1044.      mov   edi,esp
  1045.      add   edi,4+64-1
  1046.      mov   ecx,eax
  1047.      mov   eax,ebx
  1048.      mov   ebx,2
  1049.    d_binnum:
  1050.      xor   edx,edx
  1051.      call  division_64_bits
  1052.      div   ebx
  1053.      add   dl,48
  1054.      mov   [edi],dl
  1055.      dec   edi
  1056.      loop  d_binnum
  1057.      pop   eax
  1058.      call  normalize_number
  1059.      call  draw_num_text
  1060.      add   esp,64
  1061.      popad
  1062.      ret
  1063.    no_display_binnum:
  1064.  
  1065.      add   esp,64
  1066.      popad
  1067.      ret
  1068.  
  1069. normalize_number:
  1070.      test  ah,0x80
  1071.      jz   .continue
  1072.      mov  ecx,48
  1073.      and   eax,0x3f
  1074. @@:
  1075.      inc   edi
  1076.      cmp   [edi],cl
  1077.      jne   .continue
  1078.      dec   eax
  1079.      cmp   eax,1
  1080.      ja    @r
  1081.      mov   al,1
  1082. .continue:
  1083.      and   eax,0x3f
  1084.      ret
  1085.  
  1086. division_64_bits:
  1087.      test  [esp+1+4],byte 0x40
  1088.      jz   .continue
  1089.      push  eax
  1090.      mov   eax,ebp
  1091.      div   ebx
  1092.      mov   ebp,eax
  1093.      pop   eax
  1094. .continue:
  1095.      ret
  1096.  
  1097. draw_num_text:
  1098.      mov   esi,eax
  1099.      mov   edx,64+4
  1100.      sub   edx,eax
  1101.      add   edx,esp
  1102.      mov   ebx,[esp+64+32-8+4]
  1103. ; add window start x & y
  1104.      mov   ecx,[TASK_BASE]
  1105.  
  1106.      mov   edi,[CURRENT_TASK]
  1107.      shl   edi,8
  1108.  
  1109.      mov   eax,[ecx-twdw+WDATA.box.left]
  1110.      add   eax,[edi+SLOT_BASE+APPDATA.wnd_clientbox.left]
  1111.      shl   eax,16
  1112.      add   eax,[ecx-twdw+WDATA.box.top]
  1113.      add   eax,[edi+SLOT_BASE+APPDATA.wnd_clientbox.top]
  1114.      add   ebx,eax
  1115.      mov   ecx,[esp+64+32-12+4]
  1116.         and     ecx, not 0x80000000     ; force counted string
  1117.         mov     eax, [esp+64+8]         ; background color (if given)
  1118.         mov     edi, [esp+64+4]
  1119.      jmp   dtext
  1120.  
  1121. align 4
  1122.  
  1123. sys_setup:
  1124.  
  1125. ; 1=roland mpu midi base , base io address
  1126. ; 2=keyboard   1, base kaybap 2, shift keymap, 9 country 1eng 2fi 3ger 4rus
  1127. ; 3=cd base    1, pri.master 2, pri slave 3 sec master, 4 sec slave
  1128. ; 5=system language, 1eng 2fi 3ger 4rus
  1129. ; 7=hd base    1, pri.master 2, pri slave 3 sec master, 4 sec slave
  1130. ; 8=fat32 partition in hd
  1131. ; 9
  1132. ; 10 = sound dma channel
  1133. ; 11 = enable lba read
  1134. ; 12 = enable pci access
  1135.  
  1136.  
  1137.         and  [esp+32],dword 0
  1138.         dec     ebx                             ; MIDI
  1139.         jnz  nsyse1
  1140.         cmp  ecx,0x100
  1141.  
  1142.         jb   nsyse1
  1143.         mov     esi,65535
  1144.         cmp     esi,ecx
  1145.  
  1146.         jb   nsyse1
  1147.         mov  [midi_base],cx     ;bx
  1148.         mov  word [mididp],cx   ;bx
  1149.         inc  cx                 ;bx
  1150.         mov  word [midisp],cx   ;bx
  1151.         ret
  1152.  
  1153. iglobal
  1154. midi_base dw 0
  1155. endg
  1156.  
  1157.    nsyse1:
  1158.         dec     ebx                              ; KEYBOARD
  1159.         jnz  nsyse2
  1160.         mov  edi,[TASK_BASE]
  1161.         mov  eax,[edi+TASKDATA.mem_start]
  1162.         add  eax,edx
  1163.  
  1164.         dec     ecx
  1165.         jnz  kbnobase
  1166.         mov  ebx,keymap
  1167.         mov  ecx,128
  1168.         call memmove
  1169.         ret
  1170.    kbnobase:
  1171.         dec  ecx
  1172.         jnz  kbnoshift
  1173.  
  1174.         mov  ebx,keymap_shift
  1175.         mov  ecx,128
  1176.         call memmove
  1177.         ret
  1178.    kbnoshift:
  1179.         dec  ecx
  1180.         jnz  kbnoalt
  1181.         mov  ebx,keymap_alt
  1182.         mov  ecx,128
  1183.         call memmove
  1184.         ret
  1185.    kbnoalt:
  1186.         sub  ecx,6
  1187.         jnz  kbnocountry
  1188.         mov  word [keyboard],dx
  1189.         ret
  1190.    kbnocountry:
  1191.         mov  [esp+32],dword 1
  1192.         ret
  1193.    nsyse2:
  1194.         dec  ebx                            ; CD
  1195.         jnz  nsyse4
  1196.  
  1197.         test ecx,ecx
  1198.         jz   nosesl
  1199.  
  1200.         cmp  ecx, 4
  1201.         ja   nosesl
  1202.         mov  [cd_base],cl
  1203.  
  1204.         dec     ecx
  1205.         jnz  noprma
  1206.         mov  [cdbase],0x1f0
  1207.         mov  [cdid],0xa0
  1208.    noprma:
  1209.  
  1210.         dec     ecx
  1211.         jnz  noprsl
  1212.         mov  [cdbase],0x1f0
  1213.         mov  [cdid],0xb0
  1214.    noprsl:
  1215.         dec     ecx
  1216.         jnz  nosema
  1217.         mov  [cdbase],0x170
  1218.         mov  [cdid],0xa0
  1219.    nosema:
  1220.         dec     ecx
  1221.         jnz  nosesl
  1222.         mov  [cdbase],0x170
  1223.         mov  [cdid],0xb0
  1224.    nosesl:
  1225.         ret
  1226.  
  1227. iglobal
  1228. cd_base db 0
  1229.  
  1230. endg
  1231.    nsyse4:
  1232.  
  1233.         sub  ebx,2               ; SYSTEM LANGUAGE
  1234.         jnz  nsyse5
  1235.         mov  [syslang],ecx
  1236.         ret
  1237.    nsyse5:
  1238.  
  1239.         sub  ebx,2              ; HD BASE
  1240.         jnz  nsyse7
  1241.  
  1242.         test ecx,ecx
  1243.         jz   nosethd
  1244.  
  1245.         cmp  ecx,4
  1246.         ja   nosethd
  1247.         mov  [hd_base],cl
  1248.  
  1249.         cmp  ecx,1
  1250.         jnz  noprmahd
  1251.         mov  [hdbase],0x1f0
  1252.         and  dword [hdid],0x0
  1253.         mov  dword [hdpos],ecx
  1254. ;     call set_FAT32_variables
  1255.    noprmahd:
  1256.  
  1257.         cmp  ecx,2
  1258.         jnz  noprslhd
  1259.         mov  [hdbase],0x1f0
  1260.         mov  [hdid],0x10
  1261.         mov  dword [hdpos],ecx
  1262. ;     call set_FAT32_variables
  1263.    noprslhd:
  1264.  
  1265.         cmp  ecx,3
  1266.         jnz  nosemahd
  1267.         mov  [hdbase],0x170
  1268.         and  dword [hdid],0x0
  1269.         mov  dword [hdpos],ecx
  1270. ;     call set_FAT32_variables
  1271.    nosemahd:
  1272.  
  1273.         cmp  ecx,4
  1274.         jnz  noseslhd
  1275.         mov  [hdbase],0x170
  1276.         mov  [hdid],0x10
  1277.         mov  dword [hdpos],ecx
  1278. ;     call set_FAT32_variables
  1279.    noseslhd:
  1280.         call  reserve_hd1
  1281.         call  reserve_hd_channel
  1282.         call  free_hd_channel
  1283.         and   dword [hd1_status],0        ; free
  1284.    nosethd:
  1285.         ret
  1286.  
  1287. iglobal
  1288. hd_base db 0
  1289. endg
  1290.  
  1291. nsyse7:
  1292.  
  1293. ;     cmp  eax,8                      ; HD PARTITION
  1294.         dec  ebx
  1295.         jnz  nsyse8
  1296.         mov  [fat32part],ecx
  1297. ;     call set_FAT32_variables
  1298.         call  reserve_hd1
  1299.         call  reserve_hd_channel
  1300.         call  free_hd_channel
  1301. ;       pusha
  1302.         call  choice_necessity_partition_1
  1303. ;       popa
  1304.         and dword [hd1_status],0        ; free
  1305.         ret
  1306.  
  1307. nsyse8:
  1308. ;     cmp  eax,11                     ; ENABLE LBA READ
  1309.         and  ecx,1
  1310.         sub  ebx,3
  1311.         jnz  no_set_lba_read
  1312.         mov  [lba_read_enabled],ecx
  1313.         ret
  1314.  
  1315. no_set_lba_read:
  1316. ;     cmp  eax,12                     ; ENABLE PCI ACCESS
  1317.         dec  ebx
  1318.         jnz  no_set_pci_access
  1319.         mov  [pci_access_enabled],ecx
  1320.         ret
  1321. no_set_pci_access:
  1322.  
  1323. ;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  1324. include 'vmodeint.inc'
  1325. ;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  1326.  
  1327. sys_setup_err:
  1328.         or  [esp+32],dword -1
  1329.         ret
  1330.  
  1331. align 4
  1332.  
  1333. sys_getsetup:
  1334.  
  1335. ; 1=roland mpu midi base , base io address
  1336. ; 2=keyboard   1, base kaybap 2, shift keymap, 9 country 1eng 2fi 3ger 4rus
  1337. ; 3=cd base    1, pri.master 2, pri slave 3 sec master, 4 sec slave
  1338. ; 5=system language, 1eng 2fi 3ger 4rus
  1339. ; 7=hd base    1, pri.master 2, pri slave 3 sec master, 4 sec slave
  1340. ; 8=fat32 partition in hd
  1341. ; 9=get hs timer tic
  1342.  
  1343. ;     cmp  eax,1
  1344.         dec     ebx
  1345.         jnz  ngsyse1
  1346.         movzx eax,[midi_base]
  1347.         mov  [esp+32],eax
  1348.         ret
  1349. ngsyse1:
  1350. ;     cmp  eax,2
  1351.         dec     ebx
  1352.         jnz  ngsyse2
  1353.  
  1354.         mov  edi,[TASK_BASE]
  1355.         mov  ebx,[edi+TASKDATA.mem_start]
  1356.         add  ebx,edx
  1357.  
  1358. ;     cmp  ebx,1
  1359.         dec     ecx
  1360.         jnz  kbnobaseret
  1361.         mov  eax,keymap
  1362.         mov  ecx,128
  1363.         call memmove
  1364.         ret
  1365. kbnobaseret:
  1366. ;     cmp  ebx,2
  1367.         dec     ecx
  1368.         jnz  kbnoshiftret
  1369.  
  1370.         mov  eax,keymap_shift
  1371.         mov  ecx,128
  1372.         call memmove
  1373.         ret
  1374. kbnoshiftret:
  1375. ;     cmp  ebx,3
  1376.         dec     ecx
  1377.         jne  kbnoaltret
  1378.  
  1379.         mov  eax,keymap_alt
  1380.         mov  ecx,128
  1381.         call memmove
  1382.         ret
  1383. kbnoaltret:
  1384. ;     cmp  ebx,9
  1385.         sub     ecx,6
  1386.         jnz  ngsyse2
  1387.         movzx eax,word [keyboard]
  1388.         mov  [esp+32],eax
  1389.         ret
  1390.  
  1391.  
  1392. ngsyse2:
  1393. ;         cmp  eax,3
  1394.         dec     ebx
  1395.         jnz  ngsyse3
  1396.         movzx eax,[cd_base]
  1397.         mov  [esp+32],eax
  1398.         ret
  1399. ngsyse3:
  1400. ;         cmp  eax,5
  1401.         sub     ebx,2
  1402.         jnz  ngsyse5
  1403.         mov  eax,[syslang]
  1404.         mov  [esp+32],eax
  1405.         ret
  1406. ngsyse5:
  1407. ;     cmp  eax,7
  1408.         sub     ebx,2
  1409.         jnz  ngsyse7
  1410.         movzx eax,[hd_base]
  1411.         mov  [esp+32],eax
  1412.         ret
  1413. ngsyse7:
  1414. ;     cmp  eax,8
  1415.         dec     ebx
  1416.         jnz  ngsyse8
  1417.         mov eax,[fat32part]
  1418.         mov  [esp+32],eax
  1419.         ret
  1420. ngsyse8:
  1421. ;     cmp  eax,9
  1422.         dec     ebx
  1423.         jnz  ngsyse9
  1424.         mov  eax,[timer_ticks] ;[0xfdf0]
  1425.         mov  [esp+32],eax
  1426.         ret
  1427. ngsyse9:
  1428. ;     cmp  eax,11
  1429.         sub     ebx,2
  1430.         jnz  ngsyse11
  1431.         mov eax,[lba_read_enabled]
  1432.         mov  [esp+32],eax
  1433.         ret
  1434. ngsyse11:
  1435. ;     cmp  eax,12
  1436.         dec     ebx
  1437.         jnz  ngsyse12
  1438.         mov eax,[pci_access_enabled]
  1439.         mov  [esp+32],eax
  1440.         ret
  1441. ngsyse12:
  1442.         mov  [esp+32],dword 1
  1443.         ret
  1444.  
  1445.  
  1446. get_timer_ticks:
  1447.         mov eax,[timer_ticks]
  1448.         ret
  1449.  
  1450. iglobal
  1451. align 4
  1452. mousefn dd msscreen, mswin, msbutton, msset
  1453.         dd app_load_cursor
  1454.         dd app_set_cursor
  1455.         dd app_delete_cursor
  1456.         dd msz
  1457. endg
  1458.  
  1459. readmousepos:
  1460.  
  1461. ; eax=0 screen relative
  1462. ; eax=1 window relative
  1463. ; eax=2 buttons pressed
  1464. ; eax=3 set mouse pos   ; reserved
  1465. ; eax=4 load cursor
  1466. ; eax=5 set cursor
  1467. ; eax=6 delete cursor   ; reserved
  1468. ; eax=7 get mouse_z
  1469.  
  1470.            cmp ebx, 7
  1471.            ja msset
  1472.            jmp [mousefn+ebx*4]
  1473. msscreen:
  1474.            mov  eax,[MOUSE_X]
  1475.            shl  eax,16
  1476.            mov  ax,[MOUSE_Y]
  1477.            mov  [esp+36-4],eax
  1478.            ret
  1479. mswin:
  1480.            mov  eax,[MOUSE_X]
  1481.            shl  eax,16
  1482.            mov  ax,[MOUSE_Y]
  1483.            mov  esi,[TASK_BASE]
  1484.            mov  bx, word [esi-twdw+WDATA.box.left]
  1485.            shl  ebx,16
  1486.            mov  bx, word [esi-twdw+WDATA.box.top]
  1487.            sub  eax,ebx
  1488.  
  1489.            mov  edi,[CURRENT_TASK]
  1490.            shl  edi,8
  1491.            sub  ax,word[edi+SLOT_BASE+APPDATA.wnd_clientbox.top]
  1492.            rol  eax,16
  1493.            sub  ax,word[edi+SLOT_BASE+APPDATA.wnd_clientbox.left]
  1494.            rol  eax,16
  1495.            mov  [esp+36-4],eax
  1496.            ret
  1497. msbutton:
  1498.            movzx eax,byte [BTN_DOWN]
  1499.            mov  [esp+36-4],eax
  1500.            ret
  1501. msz:
  1502.            mov   edi, [TASK_COUNT]
  1503.            movzx edi, word [WIN_POS + edi*2]
  1504.            cmp   edi, [CURRENT_TASK]
  1505.            jne   @f
  1506.            mov   ax,[MOUSE_SCROLL_H]
  1507.            shl   eax,16
  1508.            mov   ax,[MOUSE_SCROLL_V]
  1509.            mov   [esp+36-4],eax
  1510.            and   [MOUSE_SCROLL_H],word 0
  1511.            and   [MOUSE_SCROLL_V],word 0
  1512.            ret
  1513.        @@:
  1514.            and  [esp+36-4],dword 0
  1515. ;           ret
  1516. msset:
  1517.            ret
  1518.  
  1519. app_load_cursor:
  1520.            cmp ecx, OS_BASE
  1521.            jae msset
  1522.            stdcall load_cursor, ecx, edx
  1523.            mov [esp+36-4], eax
  1524.            ret
  1525.  
  1526. app_set_cursor:
  1527.            stdcall set_cursor, ecx
  1528.            mov [esp+36-4], eax
  1529.            ret
  1530.  
  1531. app_delete_cursor:
  1532.            stdcall delete_cursor, ecx
  1533.            mov [esp+36-4], eax
  1534.            ret
  1535.  
  1536. is_input:
  1537.  
  1538.    push edx
  1539.    mov  dx,word [midisp]
  1540.    in   al,dx
  1541.    and  al,0x80
  1542.    pop  edx
  1543.    ret
  1544.  
  1545. is_output:
  1546.  
  1547.    push edx
  1548.    mov  dx,word [midisp]
  1549.    in   al,dx
  1550.    and  al,0x40
  1551.    pop  edx
  1552.    ret
  1553.  
  1554.  
  1555. get_mpu_in:
  1556.  
  1557.    push edx
  1558.    mov  dx,word [mididp]
  1559.    in   al,dx
  1560.    pop  edx
  1561.    ret
  1562.  
  1563.  
  1564. put_mpu_out:
  1565.  
  1566.    push edx
  1567.    mov  dx,word [mididp]
  1568.    out  dx,al
  1569.    pop  edx
  1570.    ret
  1571.  
  1572.  
  1573.  
  1574. align 4
  1575.  
  1576. sys_midi:
  1577.         cmp  [mididp],0
  1578.         jnz  sm0
  1579.         mov  [esp+36],dword 1
  1580.         ret
  1581. sm0:
  1582.         and  [esp+36],dword 0
  1583.         dec  ebx
  1584.         jnz  smn1
  1585.  ;    call setuart
  1586. su1:
  1587.         call is_output
  1588.         test al,al
  1589.         jnz  su1
  1590.         mov  dx,word [midisp]
  1591.         mov  al,0xff
  1592.         out  dx,al
  1593. su2:
  1594.         mov  dx,word [midisp]
  1595.         mov  al,0xff
  1596.         out  dx,al
  1597.         call is_input
  1598.         test al,al
  1599.         jnz  su2
  1600.         call get_mpu_in
  1601.         cmp  al,0xfe
  1602.         jnz  su2
  1603. su3:
  1604.         call is_output
  1605.         test  al,al
  1606.         jnz  su3
  1607.         mov  dx,word [midisp]
  1608.         mov  al,0x3f
  1609.         out  dx,al
  1610.         ret
  1611. smn1:
  1612.         dec  ebx
  1613.         jnz  smn2
  1614. sm10:
  1615.         call get_mpu_in
  1616.         call is_output
  1617.         test al,al
  1618.         jnz  sm10
  1619.         mov  al,bl
  1620.         call put_mpu_out
  1621.         smn2:
  1622.         ret
  1623.  
  1624. detect_devices:
  1625. ;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  1626. ;include 'detect/commouse.inc'
  1627. ;include 'detect/ps2mouse.inc'
  1628. ;include 'detect/dev_fd.inc'
  1629. ;include 'detect/dev_hdcd.inc'
  1630. ;include 'detect/sear_par.inc'
  1631. ;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  1632.     ret
  1633.  
  1634. sys_end:
  1635.  
  1636.      mov ecx, [current_slot]
  1637.      mov eax, [ecx+APPDATA.tls_base]
  1638.      test eax, eax
  1639.      jz @F
  1640.  
  1641.      stdcall user_free, eax
  1642. @@:
  1643.  
  1644.      mov   eax,[TASK_BASE]
  1645.      mov   [eax+TASKDATA.state], 3  ; terminate this program
  1646.  
  1647.     waitterm:            ; wait here for termination
  1648.      mov   ebx,100
  1649.      call  delay_hs
  1650.      jmp   waitterm
  1651.  
  1652. iglobal
  1653. align 4
  1654. sys_system_table:
  1655.         dd      exit_for_anyone         ; 1 = obsolete
  1656.         dd      sysfn_terminate         ; 2 = terminate thread
  1657.         dd      sysfn_activate          ; 3 = activate window
  1658.         dd      sysfn_getidletime       ; 4 = get idle time
  1659.         dd      sysfn_getcpuclock       ; 5 = get cpu clock
  1660.         dd      sysfn_saveramdisk       ; 6 = save ramdisk
  1661.         dd      sysfn_getactive         ; 7 = get active window
  1662.         dd      sysfn_sound_flag        ; 8 = get/set sound_flag
  1663.         dd      sysfn_shutdown          ; 9 = shutdown with parameter
  1664.         dd      sysfn_minimize          ; 10 = minimize window
  1665.         dd      sysfn_getdiskinfo       ; 11 = get disk subsystem info
  1666.         dd      sysfn_lastkey           ; 12 = get last pressed key
  1667.         dd      sysfn_getversion        ; 13 = get kernel version
  1668.         dd      sysfn_waitretrace       ; 14 = wait retrace
  1669.         dd      sysfn_centermouse       ; 15 = center mouse cursor
  1670.         dd      sysfn_getfreemem        ; 16 = get free memory size
  1671.         dd      sysfn_getallmem         ; 17 = get total memory size
  1672.         dd      sysfn_terminate2        ; 18 = terminate thread using PID
  1673.                                         ;                 instead of slot
  1674.         dd      sysfn_mouse_acceleration; 19 = set/get mouse acceleration
  1675.         dd      sysfn_meminfo           ; 20 = get extended memory info
  1676.         dd      sysfn_pid_to_slot       ; 21 = get slot number for pid
  1677.         dd      sysfn_min_rest_window   ; 22 = minimize and restore any window
  1678. sysfn_num = ($ - sys_system_table)/4
  1679. endg
  1680.  
  1681. sys_system:
  1682.         dec     ebx
  1683.         cmp     ebx, sysfn_num
  1684.         jae     @f
  1685.         jmp     dword [sys_system_table + ebx*4]
  1686. @@:
  1687.         ret
  1688.  
  1689.  
  1690. sysfn_shutdown:          ; 18.9 = system shutdown
  1691.      cmp  ecx,1
  1692.      jl   exit_for_anyone
  1693.      cmp  ecx,4
  1694.      jg   exit_for_anyone
  1695.      mov  [BOOT_VAR+0x9030],cl
  1696.  
  1697.      mov  eax,[TASK_COUNT]
  1698.      mov  [SYS_SHUTDOWN],al
  1699.      mov  [shutdown_processes],eax
  1700.      and  dword [esp+32], 0
  1701.  exit_for_anyone:
  1702.      ret
  1703.   uglobal
  1704.    shutdown_processes: dd 0x0
  1705.   endg
  1706.  
  1707. sysfn_terminate:        ; 18.2 = TERMINATE
  1708.      cmp  ecx,2
  1709.      jb   noprocessterminate
  1710.      mov  edx,[TASK_COUNT]
  1711.      cmp  ecx,edx
  1712.      ja   noprocessterminate
  1713.      mov  eax,[TASK_COUNT]
  1714.      shl  ecx,5
  1715.      mov  edx,[ecx+CURRENT_TASK+TASKDATA.pid]
  1716.      add  ecx,CURRENT_TASK+TASKDATA.state
  1717.      cmp  byte [ecx], 9
  1718.      jz   noprocessterminate
  1719.  
  1720.      ;call MEM_Heap_Lock      ;guarantee that process isn't working with heap
  1721.      mov  [ecx],byte 3       ; clear possible i40's
  1722.      ;call MEM_Heap_UnLock
  1723.  
  1724.      cmp  edx,[application_table_status]    ; clear app table stat
  1725.      jne  noatsc
  1726.  
  1727.      and  [application_table_status],0
  1728.    noatsc:
  1729.    noprocessterminate:
  1730.      ret
  1731.  
  1732. sysfn_terminate2:
  1733. ;lock application_table_status mutex
  1734. .table_status:
  1735.     cli
  1736.     cmp    [application_table_status],0
  1737.     je     .stf
  1738.     sti
  1739.     call   change_task
  1740.     jmp    .table_status
  1741. .stf:
  1742.     call   set_application_table_status
  1743.     mov    eax,ecx
  1744.     call   pid_to_slot
  1745.     test   eax,eax
  1746.     jz     .not_found
  1747.     mov    ecx,eax
  1748.     cli
  1749.     call   sysfn_terminate
  1750.     and    [application_table_status],0
  1751.     sti
  1752.     and    dword [esp+32],0
  1753.     ret
  1754. .not_found:
  1755.     mov    [application_table_status],0
  1756.     or     dword [esp+32],-1
  1757.     ret
  1758.  
  1759. sysfn_activate:         ; 18.3 = ACTIVATE WINDOW
  1760.      cmp  ecx,2
  1761.      jb   .nowindowactivate
  1762.      cmp  ecx,[TASK_COUNT]
  1763.      ja   .nowindowactivate
  1764.  
  1765.      mov   [window_minimize], 2   ; restore window if minimized
  1766.  
  1767.      movzx esi, word [WIN_STACK + ecx*2]
  1768.      cmp   esi, [TASK_COUNT]
  1769.      je    .nowindowactivate ; already active
  1770.  
  1771.      mov   edi, ecx
  1772.      shl   edi, 5
  1773.      add   edi, window_data
  1774.      movzx esi, word [WIN_STACK + ecx * 2]
  1775.      lea   esi, [WIN_POS + esi * 2]
  1776.      call  waredraw
  1777. .nowindowactivate:
  1778.      ret
  1779.  
  1780. sysfn_getidletime:              ; 18.4 = GET IDLETIME
  1781.      mov  eax,[idleusesec]
  1782.      mov  [esp+32], eax
  1783.      ret
  1784.  
  1785. sysfn_getcpuclock:              ; 18.5 = GET TSC/SEC
  1786.      mov  eax,[CPU_FREQ]
  1787.      mov  [esp+32], eax
  1788.      ret
  1789.  
  1790. ;  SAVE ramdisk to /hd/1/menuet.img
  1791. ;!!!!!!!!!!!!!!!!!!!!!!!!
  1792.    include 'blkdev/rdsave.inc'
  1793. ;!!!!!!!!!!!!!!!!!!!!!!!!
  1794. align 4
  1795. sysfn_getactive:        ; 18.7 = get active window
  1796.      mov  eax, [TASK_COUNT]
  1797.    movzx  eax, word [WIN_POS + eax*2]
  1798.      mov  [esp+32],eax
  1799.      ret
  1800.  
  1801. sysfn_sound_flag:       ; 18.8 = get/set sound_flag
  1802. ;     cmp  ecx,1
  1803.      dec  ecx
  1804.      jnz  nogetsoundflag
  1805.      movzx  eax,byte [sound_flag] ; get sound_flag
  1806.      mov  [esp+32],eax
  1807.      ret
  1808.  nogetsoundflag:
  1809. ;     cmp  ecx,2
  1810.      dec  ecx
  1811.      jnz  nosoundflag
  1812.      xor  byte [sound_flag], 1
  1813.  nosoundflag:
  1814.      ret
  1815.  
  1816. sysfn_minimize:         ; 18.10 = minimize window
  1817.      mov   [window_minimize],1
  1818.      ret
  1819. align 4
  1820. sysfn_getdiskinfo:      ; 18.11 = get disk info table
  1821. ;     cmp  ecx,1
  1822.      dec  ecx
  1823.      jnz  full_table
  1824.   small_table:
  1825.      call for_all_tables
  1826.      mov ecx,10
  1827.      cld
  1828.      rep movsb
  1829.      ret
  1830.    for_all_tables:
  1831.      mov edi,edx
  1832.      mov esi,DRIVE_DATA
  1833.      ret
  1834.   full_table:
  1835. ;     cmp  ecx,2
  1836.      dec  ecx
  1837.      jnz  exit_for_anyone
  1838.      call for_all_tables
  1839.      mov ecx,16384
  1840.      cld
  1841.      rep movsd
  1842.      ret
  1843.  
  1844. sysfn_lastkey:          ; 18.12 = return 0 (backward compatibility)
  1845.         and     dword [esp+32], 0
  1846.         ret
  1847.  
  1848. sysfn_getversion:       ; 18.13 = get kernel ID and version
  1849.      mov edi,ecx
  1850.      mov esi,version_inf
  1851.      mov ecx,version_end-version_inf
  1852.      rep movsb
  1853.      ret
  1854.  
  1855. sysfn_waitretrace:     ; 18.14 = sys wait retrace
  1856.      ;wait retrace functions
  1857.  sys_wait_retrace:
  1858.      mov edx,0x3da
  1859.  WaitRetrace_loop:
  1860.      in al,dx
  1861.      test al,1000b
  1862.      jz WaitRetrace_loop
  1863.      and [esp+32],dword 0
  1864.      ret
  1865.  
  1866. align 4
  1867. sysfn_centermouse:      ; 18.15 = mouse centered
  1868. ; removed here by <Lrz>
  1869. ;     call  mouse_centered
  1870. ;* mouse centered - start code- Mario79
  1871. ;mouse_centered:
  1872. ;        push  eax
  1873.         mov   eax,[Screen_Max_X]
  1874.         shr   eax,1
  1875.         mov   [MOUSE_X],ax
  1876.         mov   eax,[Screen_Max_Y]
  1877.         shr   eax,1
  1878.         mov   [MOUSE_Y],ax
  1879. ;        ret
  1880. ;* mouse centered - end code- Mario79
  1881.         xor   eax,eax
  1882.         and   [esp+32],eax
  1883. ;        pop   eax
  1884.  
  1885.      ret
  1886. align 4
  1887. sysfn_mouse_acceleration: ; 18.19 = set/get mouse features
  1888.      test ecx,ecx  ; get mouse speed factor
  1889.      jnz  .set_mouse_acceleration
  1890.      xor  eax,eax
  1891.      mov  ax,[mouse_speed_factor]
  1892.      mov  [esp+32],eax
  1893.      ret
  1894.  .set_mouse_acceleration:
  1895. ;     cmp  ecx,1  ; set mouse speed factor
  1896.      dec  ecx
  1897.      jnz  .get_mouse_delay
  1898.      mov  [mouse_speed_factor],dx
  1899.      ret
  1900.  .get_mouse_delay:
  1901. ;     cmp  ecx,2  ; get mouse delay
  1902.      dec  ecx
  1903.      jnz  .set_mouse_delay
  1904.      mov  eax,[mouse_delay]
  1905.      mov  [esp+32],eax
  1906.      ret
  1907.  .set_mouse_delay:
  1908. ;     cmp  ecx,3  ; set mouse delay
  1909.      dec  ecx
  1910.      jnz  .set_pointer_position
  1911.      mov  [mouse_delay],edx
  1912.      ret
  1913.  .set_pointer_position:
  1914. ;     cmp  ecx,4  ; set mouse pointer position
  1915.      dec   ecx
  1916.      jnz  .set_mouse_button
  1917.      cmp   dx, word[Screen_Max_Y]
  1918.      ja    .end
  1919.  
  1920.      rol   edx,16
  1921.      cmp   dx, word[Screen_Max_X]
  1922.      ja    .end
  1923.      mov   [MOUSE_X], edx
  1924.      ret
  1925.  .set_mouse_button:
  1926. ;     cmp   ecx,5  ; set mouse button features
  1927.      dec   ecx
  1928.      jnz  .end
  1929.      mov   [BTN_DOWN],dl
  1930.      mov   [mouse_active],1
  1931.  .end:
  1932.      ret
  1933.  
  1934. sysfn_getfreemem:
  1935.      mov eax, [pg_data.pages_free]
  1936.      shl eax, 2
  1937.      mov [esp+32],eax
  1938.      ret
  1939.  
  1940. sysfn_getallmem:
  1941.      mov  eax,[MEM_AMOUNT]
  1942.      shr eax, 10
  1943.      mov  [esp+32],eax
  1944.      ret
  1945.  
  1946. ; // Alver, 2007-22-08 // {
  1947. sysfn_pid_to_slot:
  1948.      mov   eax, ecx
  1949.      call  pid_to_slot
  1950.      mov   [esp+32], eax
  1951.      ret
  1952.  
  1953. sysfn_min_rest_window:
  1954.      pushad
  1955.      mov   eax, edx      ; ebx - operating
  1956.      shr   ecx, 1
  1957.      jnc    @f
  1958.      call  pid_to_slot
  1959. @@:
  1960.      or    eax, eax      ; eax - number of slot
  1961.      jz    .error
  1962.      cmp   eax, 255         ; varify maximal slot number
  1963.      ja    .error
  1964.      movzx eax, word [WIN_STACK + eax*2]
  1965.      shr   ecx, 1
  1966.      jc    .restore
  1967.  ; .minimize:
  1968.      call  minimize_window
  1969.      jmp   .exit
  1970. .restore:
  1971.      call  restore_minimized_window
  1972. .exit:
  1973.      popad
  1974.      xor   eax, eax
  1975.      mov   [esp+32], eax
  1976.      ret
  1977. .error:
  1978.      popad
  1979.      xor   eax, eax
  1980.      dec   eax
  1981.      mov   [esp+32], eax
  1982.      ret
  1983. ; } \\ Alver, 2007-22-08 \\
  1984.  
  1985. uglobal
  1986. ;// mike.dld, 2006-29-01 [
  1987. screen_workarea RECT
  1988. ;// mike.dld, 2006-29-01 ]
  1989. window_minimize db 0
  1990. sound_flag      db 0
  1991. endg
  1992.  
  1993. iglobal
  1994. version_inf:
  1995.   db 0,7,7,0  ; version 0.7.7.0
  1996.   db 0          ;reserved
  1997.   dd __REV__
  1998. version_end:
  1999. endg
  2000.  
  2001. sys_cachetodiskette:            ; << removed
  2002.         mov     [esp + 32], ebx
  2003.         ret
  2004.  
  2005. uglobal
  2006. ;  bgrchanged  dd  0x0
  2007. align 4
  2008. bgrlockpid dd 0
  2009. bgrlock db 0
  2010. endg
  2011.  
  2012. ;===============================  SysFn 15  ================================
  2013. sys_background:
  2014.  
  2015.     cmp   ebx,1                            ; BACKGROUND SIZE
  2016.     jnz   nosb1
  2017.     test  ecx,ecx
  2018. ;    cmp   ecx,0
  2019.     jz    sbgrr
  2020.     test  edx,edx
  2021. ;    cmp   edx,0
  2022.     jz    sbgrr
  2023. @@:
  2024. ;;Maxis use atomic bts for mutexes  4.4.2009
  2025.         bts     dword [bgrlock], 0
  2026.         jnc     @f
  2027.         call    change_task
  2028.         jmp     @b
  2029. @@:
  2030.     mov   [BgrDataWidth],ecx
  2031.     mov   [BgrDataHeight],edx
  2032. ;    mov   [bgrchanged],1
  2033.  
  2034.     pushad
  2035. ; return memory for old background
  2036.         mov     eax, [img_background]
  2037.         cmp     eax, static_background_data
  2038.         jz      @f
  2039.         stdcall kernel_free, eax
  2040. @@:
  2041. ; calculate RAW size
  2042.     xor  eax,eax
  2043.     inc  eax
  2044.     cmp  [BgrDataWidth],eax
  2045.     jae   @f
  2046.     mov [BgrDataWidth],eax
  2047. @@:
  2048.     cmp  [BgrDataHeight],eax
  2049.     jae   @f
  2050.     mov [BgrDataHeight],eax
  2051. @@:
  2052.     mov  eax,[BgrDataWidth]
  2053.     imul eax,[BgrDataHeight]
  2054.     lea  eax,[eax*3]
  2055.     mov  [mem_BACKGROUND],eax
  2056. ; get memory for new background
  2057.     stdcall kernel_alloc, eax
  2058.     test eax, eax
  2059.     jz .memfailed
  2060.     mov [img_background], eax
  2061.     jmp .exit
  2062. .memfailed:
  2063. ; revert to static monotone data
  2064.         mov     [img_background], static_background_data
  2065.         xor     eax, eax
  2066.         inc     eax
  2067.         mov     [BgrDataWidth], eax
  2068.         mov     [BgrDataHeight], eax
  2069.         mov     [mem_BACKGROUND], 4
  2070. .exit:
  2071.     popad
  2072.         mov     [bgrlock], 0
  2073.  
  2074.   sbgrr:
  2075.     ret
  2076.  
  2077. nosb1:
  2078.  
  2079.     cmp   ebx,2                            ; SET PIXEL
  2080.     jnz   nosb2
  2081.  
  2082.     mov   eax, [img_background]
  2083.     test  ecx, ecx
  2084.     jz    @f
  2085.     cmp   eax, static_background_data
  2086.  
  2087.     jz    .ret
  2088. @@:
  2089.     mov ebx, [mem_BACKGROUND]
  2090.     add ebx, 4095
  2091.     and ebx, -4096
  2092.     sub ebx, 4
  2093.     cmp   ecx, ebx
  2094.     ja   .ret
  2095.  
  2096.     mov   ebx,[eax+ecx]
  2097.     and   ebx,0xFF000000 ;255*256*256*256
  2098.     and   edx,0x00FFFFFF ;255*256*256+255*256+255
  2099.     add   edx,ebx
  2100.     mov   [eax+ecx],edx
  2101. .ret:
  2102.     ret
  2103. nosb2:
  2104.  
  2105.     cmp   ebx,3                            ; DRAW BACKGROUND
  2106.     jnz   nosb3
  2107. draw_background_temp:
  2108. ;    cmp   [bgrchanged],1 ;0
  2109. ;    je    nosb31
  2110. ;draw_background_temp:
  2111. ;    mov   [bgrchanged],1 ;0
  2112.     mov    [background_defined], 1
  2113.     mov    byte[BACKGROUND_CHANGED], 1
  2114.     call  force_redraw_background
  2115.    nosb31:
  2116.     ret
  2117.   nosb3:
  2118.  
  2119.     cmp   ebx,4                            ; TILED / STRETCHED
  2120.     jnz   nosb4
  2121.     cmp   ecx,[BgrDrawMode]
  2122.     je    nosb41
  2123.     mov   [BgrDrawMode],ecx
  2124. ;    mov   [bgrchanged],1
  2125.    nosb41:
  2126.     ret
  2127.   nosb4:
  2128.  
  2129.     cmp   ebx,5                            ; BLOCK MOVE TO BGR
  2130.     jnz   nosb5
  2131.     cmp   [img_background], static_background_data
  2132.     jnz   @f
  2133.     test  edx, edx
  2134.     jnz   .fin
  2135.     cmp   esi, 4
  2136.     ja    .fin
  2137.   @@:
  2138.   ; bughere
  2139.     mov   eax, ecx
  2140.     mov   ebx, edx
  2141.     add   ebx, [img_background]   ;IMG_BACKGROUND
  2142.     mov   ecx, esi
  2143.     call  memmove
  2144.   .fin:
  2145.     ret
  2146.   nosb5:
  2147.  
  2148.         cmp     ebx, 6
  2149.         jnz     nosb6
  2150. ;;Maxis use atomic bts for mutex 4.4.2009
  2151. @@:
  2152.         bts     dword [bgrlock], 0
  2153.         jnc     @f
  2154.         call    change_task
  2155.         jmp     @b
  2156. @@:
  2157.         mov     eax, [CURRENT_TASK]
  2158.         mov     [bgrlockpid], eax
  2159.         cmp     [img_background], static_background_data
  2160.         jz      .nomem
  2161.         stdcall user_alloc, [mem_BACKGROUND]
  2162.         mov     [esp+32], eax
  2163.         test    eax, eax
  2164.         jz      .nomem
  2165.         mov     ebx, eax
  2166.         shr     ebx, 12
  2167.         or      dword [page_tabs+(ebx-1)*4], DONT_FREE_BLOCK
  2168.         mov     esi, [img_background]
  2169.         shr     esi, 12
  2170.         mov     ecx, [mem_BACKGROUND]
  2171.         add     ecx, 0xFFF
  2172.         shr     ecx, 12
  2173. .z:
  2174.         mov     eax, [page_tabs+ebx*4]
  2175.         test    al, 1
  2176.         jz      @f
  2177.         call    free_page
  2178. @@:
  2179.         mov     eax, [page_tabs+esi*4]
  2180.         or      al, PG_UW
  2181.         mov     [page_tabs+ebx*4], eax
  2182.         mov     eax, ebx
  2183.         shl     eax, 12
  2184.         invlpg  [eax]
  2185.         inc     ebx
  2186.         inc     esi
  2187.         loop    .z
  2188.         ret
  2189. .nomem:
  2190.         and     [bgrlockpid], 0
  2191.         mov     [bgrlock], 0
  2192. nosb6:
  2193.         cmp     ebx, 7
  2194.         jnz     nosb7
  2195.         cmp     [bgrlock], 0
  2196.         jz      .err
  2197.         mov     eax, [CURRENT_TASK]
  2198.         cmp     [bgrlockpid], eax
  2199.         jnz     .err
  2200.         mov     eax, ecx
  2201.         mov     ebx, ecx
  2202.         shr     eax, 12
  2203.         mov     ecx, [page_tabs+(eax-1)*4]
  2204.         test    cl, USED_BLOCK+DONT_FREE_BLOCK
  2205.         jz      .err
  2206.         jnp     .err
  2207.         push    eax
  2208.         shr     ecx, 12
  2209.         dec     ecx
  2210. @@:
  2211.         and     dword [page_tabs+eax*4], 0
  2212.         mov     edx, eax
  2213.         shl     edx, 12
  2214.         push eax
  2215.         invlpg  [edx]
  2216.         pop eax
  2217.         inc     eax
  2218.         loop    @b
  2219.         pop     eax
  2220.         and     dword [page_tabs+(eax-1)*4], not DONT_FREE_BLOCK
  2221.         stdcall user_free, ebx
  2222.         mov     [esp+32], eax
  2223.         and     [bgrlockpid], 0
  2224.         mov     [bgrlock], 0
  2225.         ret
  2226. .err:
  2227.         and     dword [esp+32], 0
  2228.         ret
  2229.  
  2230. nosb7:
  2231.     ret
  2232.  
  2233. ;===============================  SysFn 39  ================================
  2234. align 4
  2235.  
  2236. sys_getbackground:
  2237.     dec   ebx
  2238.     jnz   nogb1
  2239.     mov   eax,[BgrDataWidth]
  2240.     shl   eax,16
  2241.     mov   ax,[BgrDataHeight]
  2242.     mov   [esp+32],eax
  2243.     ret
  2244.  
  2245. nogb1:
  2246. ;    cmp   eax,2                                  ; PIXEL
  2247.     dec   ebx
  2248.     jnz   nogb2
  2249.  
  2250.         mov     eax, [img_background]
  2251.         test    ecx, ecx
  2252.         jz      @f
  2253.         cmp     eax, static_background_data
  2254.         jz      .ret
  2255. @@:
  2256.     mov ebx, [mem_BACKGROUND]
  2257.     add ebx, 4095
  2258.     and ebx, -4096
  2259.     sub ebx, 4
  2260.     cmp ecx, ebx
  2261.     ja  .ret
  2262.  
  2263.     mov   eax,[ecx+eax]
  2264.  
  2265.     and   eax, 0xFFFFFF
  2266.     mov   [esp+32],eax
  2267. .ret:
  2268.     ret
  2269.   nogb2:
  2270.  
  2271. ;    cmp   eax,4                                  ; TILED / STRETCHED
  2272.     dec   ebx
  2273.     dec   ebx
  2274.     jnz   nogb4
  2275.     mov   eax,[BgrDrawMode]
  2276.   nogb4:
  2277.     mov   [esp+32],eax
  2278.     ret
  2279.  
  2280. ;===========================================
  2281.  
  2282. force_redraw_background:
  2283.     and   [draw_data+32 + RECT.left], 0
  2284.     and   [draw_data+32 + RECT.top], 0
  2285.     push  eax ebx
  2286.     mov   eax,[Screen_Max_X]
  2287.     mov   ebx,[Screen_Max_Y]
  2288.     mov   [draw_data+32 + RECT.right],eax
  2289.     mov   [draw_data+32 + RECT.bottom],ebx
  2290.     pop   ebx eax
  2291.     inc   byte[REDRAW_BACKGROUND]
  2292.     ret
  2293. ;===========================================
  2294.  
  2295.  
  2296. align 4
  2297.  
  2298. sys_getkey:
  2299.         mov     [esp + 32],dword 1
  2300.         ; test main buffer
  2301.         mov     ebx, [CURRENT_TASK]                          ; TOP OF WINDOW STACK
  2302.         movzx   ecx, word [WIN_STACK + ebx * 2]
  2303.         mov     edx, [TASK_COUNT]
  2304.         cmp     ecx, edx
  2305.         jne     .finish
  2306.         cmp     [KEY_COUNT], byte 0
  2307.         je      .finish
  2308.         movzx   eax, byte [KEY_BUFF]
  2309.         shl     eax, 8
  2310.         push    eax
  2311.         dec     byte [KEY_COUNT]
  2312.         and     byte [KEY_COUNT], 127
  2313.         movzx   ecx, byte [KEY_COUNT]
  2314.         add     ecx, 2
  2315.         mov     eax, KEY_BUFF + 1
  2316.         mov     ebx, KEY_BUFF
  2317.         call    memmove
  2318.         pop     eax
  2319. .ret_eax:
  2320.         mov     [esp + 32], eax
  2321.         ret
  2322. .finish:
  2323. ; test hotkeys buffer
  2324.         mov     ecx, hotkey_buffer
  2325. @@:
  2326.         cmp     [ecx], ebx
  2327.         jz      .found
  2328.         add     ecx, 8
  2329.         cmp     ecx, hotkey_buffer + 120 * 8
  2330.         jb      @b
  2331.         ret
  2332. .found:
  2333.         mov     ax, [ecx + 6]
  2334.         shl     eax, 16
  2335.         mov     ah, [ecx + 4]
  2336.         mov     al, 2
  2337.         and     dword [ecx + 4], 0
  2338.         and     dword [ecx], 0
  2339.         jmp     .ret_eax
  2340.  
  2341. align 4
  2342.  
  2343. sys_getbutton:
  2344.  
  2345.         mov     ebx, [CURRENT_TASK]                         ; TOP OF WINDOW STACK
  2346.         mov     [esp + 32], dword 1
  2347.         movzx   ecx, word [WIN_STACK + ebx * 2]
  2348.         mov     edx, [TASK_COUNT] ; less than 256 processes
  2349.         cmp     ecx, edx
  2350.         jne     .exit
  2351.         movzx   eax, byte [BTN_COUNT]
  2352.         test    eax, eax
  2353.         jz      .exit
  2354.         mov     eax, [BTN_BUFF]
  2355.         and     al, 0xFE                                    ; delete left button bit
  2356.         mov     [BTN_COUNT], byte 0
  2357.         mov     [esp + 32], eax
  2358. .exit:
  2359.         ret
  2360.  
  2361.  
  2362. align 4
  2363.  
  2364. sys_cpuusage:
  2365.  
  2366. ;  RETURN:
  2367. ;
  2368. ;  +00 dword     process cpu usage
  2369. ;  +04  word     position in windowing stack
  2370. ;  +06  word     windowing stack value at current position (cpu nro)
  2371. ;  +10 12 bytes  name
  2372. ;  +22 dword     start in mem
  2373. ;  +26 dword     used mem
  2374. ;  +30 dword     PID , process idenfification number
  2375. ;
  2376.  
  2377.     cmp  ecx,-1         ; who am I ?
  2378.     jne  .no_who_am_i
  2379.     mov  ecx,[CURRENT_TASK]
  2380.   .no_who_am_i:
  2381.         cmp     ecx, max_processes
  2382.         ja      .nofillbuf
  2383.  
  2384. ; +4: word: position of the window of thread in the window stack
  2385.         mov     ax, [WIN_STACK + ecx * 2]
  2386.         mov     [ebx+4], ax
  2387. ; +6: word: number of the thread slot, which window has in the window stack
  2388. ;           position ecx (has no relation to the specific thread)
  2389.         mov     ax, [WIN_POS + ecx * 2]
  2390.         mov     [ebx+6], ax
  2391.  
  2392.         shl     ecx, 5
  2393.  
  2394. ; +0: dword: memory usage
  2395.         mov     eax, [ecx+CURRENT_TASK+TASKDATA.cpu_usage]
  2396.         mov     [ebx], eax
  2397. ; +10: 11 bytes: name of the process
  2398.         push    ecx
  2399.         lea     eax, [ecx*8+SLOT_BASE+APPDATA.app_name]
  2400.         add     ebx, 10
  2401.         mov     ecx, 11
  2402.         call    memmove
  2403.         pop     ecx
  2404.  
  2405. ; +22: address of the process in memory
  2406. ; +26: size of used memory - 1
  2407.         push    edi
  2408.         lea     edi, [ebx+12]
  2409.         xor     eax, eax
  2410.         mov     edx, 0x100000*16
  2411.         cmp     ecx, 1 shl 5
  2412.         je      .os_mem
  2413.         mov     edx, [SLOT_BASE+ecx*8+APPDATA.mem_size]
  2414.         mov     eax, std_application_base_address
  2415. .os_mem:
  2416.         stosd
  2417.         lea     eax, [edx-1]
  2418.         stosd
  2419.  
  2420. ; +30: PID/TID
  2421.         mov     eax, [ecx+CURRENT_TASK+TASKDATA.pid]
  2422.         stosd
  2423.  
  2424.     ; window position and size
  2425.         push    esi
  2426.         lea     esi, [ecx + window_data + WDATA.box]
  2427.         movsd
  2428.         movsd
  2429.         movsd
  2430.         movsd
  2431.  
  2432.     ; Process state (+50)
  2433.         mov     eax, dword [ecx+CURRENT_TASK+TASKDATA.state]
  2434.         stosd
  2435.  
  2436.     ; Window client area box
  2437.         lea     esi, [ecx*8 + SLOT_BASE + APPDATA.wnd_clientbox]
  2438.         movsd
  2439.         movsd
  2440.         movsd
  2441.         movsd
  2442.  
  2443.     ; Window state
  2444.         mov     al, [ecx+window_data+WDATA.fl_wstate]
  2445.         stosb
  2446.  
  2447.     ; Event mask (+71)
  2448.         mov     EAX, dword [ECX+CURRENT_TASK+TASKDATA.event_mask]
  2449.         stosd
  2450.  
  2451.         pop     esi
  2452.         pop     edi
  2453.  
  2454. .nofillbuf:
  2455.     ; return number of processes
  2456.  
  2457.     mov    eax,[TASK_COUNT]
  2458.     mov    [esp+32],eax
  2459.     ret
  2460.  
  2461. align 4
  2462. sys_clock:
  2463.         cli
  2464.   ; Mikhail Lisovin  xx Jan 2005
  2465.   @@:   mov   al, 10
  2466.         out   0x70, al
  2467.         in    al, 0x71
  2468.         test  al, al
  2469.         jns   @f
  2470.         mov   esi, 1
  2471.         call  delay_ms
  2472.         jmp   @b
  2473.   @@:
  2474.   ; end Lisovin's fix
  2475.  
  2476.         xor   al,al           ; seconds
  2477.         out   0x70,al
  2478.         in    al,0x71
  2479.         movzx ecx,al
  2480.         mov   al,02           ; minutes
  2481.         shl   ecx,16
  2482.         out   0x70,al
  2483.         in    al,0x71
  2484.         movzx edx,al
  2485.         mov   al,04           ; hours
  2486.         shl   edx,8
  2487.         out   0x70,al
  2488.         in    al,0x71
  2489.         add   ecx,edx
  2490.         movzx edx,al
  2491.         add   ecx,edx
  2492.         sti
  2493.         mov     [esp + 32], ecx
  2494.         ret
  2495.  
  2496.  
  2497. align 4
  2498.  
  2499. sys_date:
  2500.  
  2501.         cli
  2502.   @@:   mov   al, 10
  2503.         out   0x70, al
  2504.         in    al, 0x71
  2505.         test  al, al
  2506.         jns   @f
  2507.         mov   esi, 1
  2508.         call  delay_ms
  2509.         jmp   @b
  2510.   @@:
  2511.  
  2512.         mov     ch,0
  2513.         mov     al,7            ; date
  2514.         out     0x70,al
  2515.         in      al,0x71
  2516.         mov     cl,al
  2517.         mov     al,8            ; month
  2518.         shl     ecx,16
  2519.         out     0x70,al
  2520.         in      al,0x71
  2521.         mov     ch,al
  2522.         mov     al,9            ; year
  2523.         out     0x70,al
  2524.         in      al,0x71
  2525.         mov     cl,al
  2526.         sti
  2527.         mov     [esp+32], ecx
  2528.         ret
  2529.  
  2530.  
  2531. ; redraw status
  2532.  
  2533. sys_redrawstat:
  2534.         cmp     ebx, 1
  2535.         jne     no_widgets_away
  2536.         ; buttons away
  2537.         mov     ecx,[CURRENT_TASK]
  2538.   sys_newba2:
  2539.         mov     edi,[BTN_ADDR]
  2540.         cmp     [edi], dword 0  ; empty button list ?
  2541.         je      end_of_buttons_away
  2542.         movzx   ebx, word [edi]
  2543.         inc     ebx
  2544.         mov     eax,edi
  2545.   sys_newba:
  2546.         dec     ebx
  2547.         jz      end_of_buttons_away
  2548.  
  2549.         add     eax, 0x10
  2550.         cmp     cx, [eax]
  2551.         jnz     sys_newba
  2552.  
  2553.         push    eax ebx ecx
  2554.         mov     ecx,ebx
  2555.         inc     ecx
  2556.         shl     ecx, 4
  2557.         mov     ebx, eax
  2558.         add     eax, 0x10
  2559.         call    memmove
  2560.         dec     dword [edi]
  2561.         pop     ecx ebx eax
  2562.  
  2563.         jmp     sys_newba2
  2564.  
  2565.   end_of_buttons_away:
  2566.  
  2567.         ret
  2568.  
  2569.   no_widgets_away:
  2570.  
  2571.         cmp     ebx, 2
  2572.         jnz     srl1
  2573.  
  2574.         mov     edx, [TASK_BASE]      ; return whole screen draw area for this app
  2575.         add     edx, draw_data - CURRENT_TASK
  2576.         mov     [edx + RECT.left], 0
  2577.         mov     [edx + RECT.top], 0
  2578.         mov     eax, [Screen_Max_X]
  2579.  
  2580.         mov     [edx + RECT.right], eax
  2581.         mov     eax, [Screen_Max_Y]
  2582.         mov     [edx + RECT.bottom], eax
  2583.  
  2584.   srl1:
  2585.         ret
  2586.  
  2587. ;ok - 100% work
  2588. ;nt - not tested
  2589. ;---------------------------------------------------------------------------------------------
  2590. ;eax
  2591. ;0 - task switch counter. Ret switch counter in eax. Block. ok.
  2592. ;1 - change task. Ret nothing. Block. ok.
  2593. ;2 - performance control
  2594. ; ebx
  2595. ; 0 - enable or disable (inversion) PCE flag on CR4 for rdmpc in user mode.
  2596. ; returned new cr4 in eax. Ret cr4 in eax. Block. ok.
  2597. ; 1 - is cache enabled. Ret cr0 in eax if enabled else zero in eax. Block. ok.
  2598. ; 2 - enable cache. Ret 1 in eax. Ret nothing. Block. ok.
  2599. ; 3 - disable cache. Ret 0 in eax. Ret nothing. Block. ok.
  2600. ;eax
  2601. ;3 - rdmsr. Counter in edx. (edx:eax) [esi:edi, edx] => [edx:esi, ecx]. Ret in ebx:eax. Block. ok.
  2602. ;4 - wrmsr. Counter in edx. (edx:eax) [esi:edi, edx] => [edx:esi, ecx]. Ret in ebx:eax. Block. ok.
  2603. ;---------------------------------------------------------------------------------------------
  2604. iglobal
  2605. align 4
  2606. sheduler:
  2607.         dd      sys_sheduler.00
  2608.         dd      change_task
  2609.         dd      sys_sheduler.02
  2610.         dd      sys_sheduler.03
  2611.         dd      sys_sheduler.04
  2612. endg
  2613. sys_sheduler:
  2614. ;rewritten by <Lrz>  29.12.2009
  2615.         jmp     dword [sheduler+ebx*4]
  2616. ;.shed_counter:
  2617. .00:
  2618.         mov eax,[context_counter]
  2619.         mov [esp+32],eax
  2620.         ret
  2621.  
  2622. .02:
  2623. ;.perf_control:
  2624.         inc     ebx                     ;before ebx=2, ebx=3
  2625.         cmp     ebx,ecx                 ;if ecx=3, ebx=3
  2626.         jz      cache_disable
  2627.  
  2628.         dec     ebx                     ;ebx=2
  2629.         cmp     ebx,ecx                 ;
  2630.         jz      cache_enable            ;if ecx=2 and ebx=2
  2631.  
  2632.         dec     ebx                     ;ebx=1
  2633.         cmp     ebx,ecx
  2634.         jz      is_cache_enabled        ;if ecx=1 and ebx=1
  2635.  
  2636.         dec     ebx
  2637.         test    ebx,ecx                 ;ebx=0 and ecx=0
  2638.         jz      modify_pce              ;if ecx=0
  2639.  
  2640.         ret
  2641.  
  2642. .03:
  2643. ;.rdmsr_instr:
  2644. ;now counter in ecx
  2645. ;(edx:eax) esi:edi => edx:esi
  2646.         mov     eax,esi
  2647.         mov     ecx,edx
  2648.         rdmsr
  2649.         mov     [esp+32],eax
  2650.         mov     [esp+20],edx            ;ret in ebx?
  2651.         ret
  2652.  
  2653. .04:
  2654. ;.wrmsr_instr:
  2655. ;now counter in ecx
  2656. ;(edx:eax) esi:edi => edx:esi
  2657.         ; Fast Call MSR can't be destroy
  2658.         ; Но MSR_AMD_EFER можно изменять, т.к. в этом регистре лиш
  2659.         ; включаются/выключаются расширенные возможности
  2660.         cmp     edx,MSR_SYSENTER_CS
  2661.         je      @f
  2662.         cmp     edx,MSR_SYSENTER_ESP
  2663.         je      @f
  2664.         cmp     edx,MSR_SYSENTER_EIP
  2665.         je      @f
  2666.         cmp     edx,MSR_AMD_STAR
  2667.         je      @f
  2668.  
  2669.         mov     eax,esi
  2670.         mov     ecx,edx
  2671.         wrmsr
  2672.         ; mov   [esp + 32], eax
  2673.         ; mov   [esp + 20], edx ;ret in ebx?
  2674. @@:
  2675.         ret
  2676.  
  2677. cache_disable:
  2678.        mov eax,cr0
  2679.        or  eax,01100000000000000000000000000000b
  2680.        mov cr0,eax
  2681.        wbinvd ;set MESI
  2682. ret
  2683.  
  2684. cache_enable:
  2685.        mov eax,cr0
  2686.        and eax,10011111111111111111111111111111b
  2687.        mov cr0,eax
  2688. ret
  2689.  
  2690. is_cache_enabled:
  2691.        mov eax,cr0
  2692.        mov ebx,eax
  2693.        and eax,01100000000000000000000000000000b
  2694.        jz cache_disabled
  2695.        mov [esp+32],ebx
  2696. cache_disabled:
  2697.        mov dword [esp+32],eax ;0
  2698. ret
  2699.  
  2700. modify_pce:
  2701.        mov eax,cr4
  2702. ;       mov ebx,0
  2703. ;       or  bx,100000000b ;pce
  2704. ;       xor eax,ebx ;invert pce
  2705.        bts eax,8 ;pce=cr4[8]
  2706.        mov cr4,eax
  2707.        mov [esp+32],eax
  2708. ret
  2709. ;---------------------------------------------------------------------------------------------
  2710.  
  2711.  
  2712. iglobal
  2713.   cpustring db 'CPU',0
  2714. endg
  2715.  
  2716. uglobal
  2717. background_defined    db    0    ; diamond, 11.04.2006
  2718. endg
  2719.  
  2720. align 4
  2721. ; check misc
  2722.  
  2723. checkmisc:
  2724.  
  2725.     cmp   [ctrl_alt_del], 1
  2726.     jne   nocpustart
  2727.  
  2728.         mov     ebp, cpustring
  2729.         call    fs_execute_from_sysdir
  2730.  
  2731.     mov   [ctrl_alt_del], 0
  2732.  
  2733. nocpustart:
  2734.     cmp   [mouse_active], 1
  2735.     jne   mouse_not_active
  2736.     mov   [mouse_active], 0
  2737.     xor   edi, edi
  2738.     mov   ecx,  [TASK_COUNT]
  2739. set_mouse_event:
  2740.     add   edi, 256
  2741.     or    [edi+SLOT_BASE+APPDATA.event_mask], dword 100000b
  2742.     loop  set_mouse_event
  2743.  
  2744. mouse_not_active:
  2745.     cmp   byte[BACKGROUND_CHANGED], 0
  2746.     jz    no_set_bgr_event
  2747.     xor   edi, edi
  2748.     mov   ecx, [TASK_COUNT]
  2749. set_bgr_event:
  2750.     add   edi, 256
  2751.     or    [edi+SLOT_BASE+APPDATA.event_mask], 16
  2752.     loop  set_bgr_event
  2753.     mov   byte[BACKGROUND_CHANGED], 0
  2754. no_set_bgr_event:
  2755.     cmp   byte[REDRAW_BACKGROUND], 0               ; background update ?
  2756.     jz    nobackgr
  2757.     cmp    [background_defined], 0
  2758.     jz    nobackgr
  2759. @@:
  2760.     call  drawbackground
  2761.     xor   eax, eax
  2762.     xchg  al, [REDRAW_BACKGROUND]
  2763.     test  al, al                                   ; got new update request?
  2764.     jnz   @b
  2765.     mov   [draw_data+32 + RECT.left], eax
  2766.     mov   [draw_data+32 + RECT.top], eax
  2767.     mov   [draw_data+32 + RECT.right], eax
  2768.     mov   [draw_data+32 + RECT.bottom], eax
  2769.     mov   [MOUSE_BACKGROUND],byte 0
  2770.  
  2771. nobackgr:
  2772.  
  2773.     ; system shutdown request
  2774.  
  2775.     cmp  [SYS_SHUTDOWN],byte 0
  2776.     je   noshutdown
  2777.  
  2778.     mov  edx,[shutdown_processes]
  2779.  
  2780.     cmp  [SYS_SHUTDOWN],dl
  2781.     jne  no_mark_system_shutdown
  2782.  
  2783.     lea   ecx,[edx-1]
  2784.     mov   edx,OS_BASE+0x3040
  2785.     jecxz @f
  2786. markz:
  2787.     mov   [edx+TASKDATA.state],byte 3
  2788.     add   edx,0x20
  2789.     loop  markz
  2790. @@:
  2791.  
  2792.   no_mark_system_shutdown:
  2793.  
  2794.     call [_display.disable_mouse]
  2795.  
  2796.     dec  byte [SYS_SHUTDOWN]
  2797.     je   system_shutdown
  2798.  
  2799. noshutdown:
  2800.     mov   eax,[TASK_COUNT]                  ; termination
  2801.     mov   ebx,TASK_DATA+TASKDATA.state
  2802.     mov   esi,1
  2803.  
  2804. newct:
  2805.     mov   cl,[ebx]
  2806.     cmp   cl,byte 3
  2807.     jz    terminate
  2808.     cmp   cl,byte 4
  2809.     jz    terminate
  2810.  
  2811.     add   ebx,0x20
  2812.     inc   esi
  2813.     dec   eax
  2814.     jnz   newct
  2815.     ret
  2816.  
  2817. ; redraw screen
  2818. ; eax , if process window_data base is eax, do not set flag/limits
  2819.  
  2820. redrawscreen:
  2821.          pushad
  2822.          push  eax
  2823.  
  2824.          xor   ecx,ecx                  ; redraw flags for apps
  2825.        newdw2:
  2826.  
  2827.          inc   ecx
  2828.          push  ecx
  2829.  
  2830.          mov   eax,ecx
  2831.          shl   eax,5
  2832.          add   eax,window_data
  2833.  
  2834.          cmp   eax,[esp+4]
  2835.          je    not_this_task
  2836.                                    ; check if window in redraw area
  2837.          mov   edi,eax
  2838.  
  2839.          cmp   ecx,1               ; limit for background
  2840.          jz    bgli
  2841.  
  2842.          mov   eax, [edi + WDATA.box.left]
  2843.          mov   ebx, [edi + WDATA.box.top]
  2844.          mov   ecx, [edi + WDATA.box.width]
  2845.          mov   edx, [edi + WDATA.box.height]
  2846.          add   ecx,eax
  2847.          add   edx,ebx
  2848.  
  2849.          mov   ecx,[draw_limits.bottom]   ; ecx = area y end     ebx = window y start
  2850.          cmp   ecx,ebx
  2851.          jb    ricino
  2852.  
  2853.          mov   ecx,[draw_limits.right]   ; ecx = area x end     eax = window x start
  2854.          cmp   ecx,eax
  2855.          jb    ricino
  2856.  
  2857.          mov   eax, [edi + WDATA.box.left]
  2858.          mov   ebx, [edi + WDATA.box.top]
  2859.          mov   ecx, [edi + WDATA.box.width]
  2860.          mov   edx, [edi + WDATA.box.height]
  2861.          add   ecx, eax
  2862.          add   edx, ebx
  2863.  
  2864.          mov   eax,[draw_limits.top]    ; eax = area y start     edx = window y end
  2865.          cmp   edx,eax
  2866.          jb    ricino
  2867.  
  2868.          mov   eax,[draw_limits.left]    ; eax = area x start     ecx = window x end
  2869.          cmp   ecx,eax
  2870.          jb    ricino
  2871.  
  2872.         bgli:
  2873.  
  2874.          cmp   dword[esp], 1
  2875.          jnz   .az
  2876.          cmp   byte[REDRAW_BACKGROUND], 0
  2877.          jz    .az
  2878.          mov   dl, 0
  2879.          lea   eax,[edi+draw_data-window_data]
  2880.          mov   ebx,[draw_limits.left]
  2881.          cmp   ebx,[eax+RECT.left]
  2882.          jae   @f
  2883.          mov   [eax+RECT.left],ebx
  2884.          mov   dl, 1
  2885.         @@:
  2886.          mov   ebx,[draw_limits.top]
  2887.          cmp   ebx,[eax+RECT.top]
  2888.          jae   @f
  2889.          mov   [eax+RECT.top],ebx
  2890.          mov   dl, 1
  2891.         @@:
  2892.          mov   ebx,[draw_limits.right]
  2893.          cmp   ebx,[eax+RECT.right]
  2894.          jbe   @f
  2895.          mov   [eax+RECT.right],ebx
  2896.          mov   dl, 1
  2897.         @@:
  2898.          mov   ebx,[draw_limits.bottom]
  2899.          cmp   ebx,[eax+RECT.bottom]
  2900.          jbe   @f
  2901.          mov   [eax+RECT.bottom],ebx
  2902.          mov   dl, 1
  2903.         @@:
  2904.          add   byte[REDRAW_BACKGROUND], dl
  2905.          jmp   newdw8
  2906.         .az:
  2907.  
  2908.          mov   eax,edi
  2909.          add   eax,draw_data-window_data
  2910.  
  2911.          mov   ebx,[draw_limits.left]          ; set limits
  2912.          mov   [eax + RECT.left], ebx
  2913.          mov   ebx,[draw_limits.top]
  2914.          mov   [eax + RECT.top], ebx
  2915.          mov   ebx,[draw_limits.right]
  2916.          mov   [eax + RECT.right], ebx
  2917.          mov   ebx,[draw_limits.bottom]