Subversion Repositories Kolibri OS

Rev

Blame | Last modification | View Log | RSS feed

  1. /*
  2.  * Copyright © <2010>, Intel Corporation.
  3.  *
  4.  * This program is licensed under the terms and conditions of the
  5.  * Eclipse Public License (EPL), version 1.0.  The full text of the EPL is at
  6.  * http://www.opensource.org/licenses/eclipse-1.0.php.
  7.  * Authors: Zhao Yakui <yakui.zhao@intel.com>
  8.  *
  9.  */
  10. // Modual name: InterFrame_ivy.asm
  11. //
  12. // Make inter predition estimation for Inter frame on Ivy
  13. //
  14.  
  15. //
  16. //  Now, begin source code....
  17. //
  18.  
  19. #define SAVE_RET        add (1) RETURN_REG<1>:ud   ip:ud        32:ud
  20. #define RETURN          mov (1) ip:ud   RETURN_REG<0,1,0>:ud
  21.  
  22. /*
  23.  * __START
  24.  */
  25. __INTER_START:
  26. mov  (16) tmp_reg0.0<1>:UD      0x0:UD {align1};
  27. mov  (16) tmp_reg2.0<1>:UD      0x0:UD {align1};
  28. mov  (16) tmp_reg4.0<1>:UD      0x0:UD {align1} ;
  29. mov  (16) tmp_reg6.0<1>:UD      0x0:UD {align1} ;
  30.  
  31. shl  (2) read0_header.0<1>:D    orig_xy_ub<2,2,1>:UB 4:UW {align1};    /* (x, y) * 16 */
  32. add  (1) read0_header.0<1>:D    read0_header.0<0,1,0>:D -8:W {align1};     /* X offset */
  33. add  (1) read0_header.4<1>:D    read0_header.4<0,1,0>:D -1:W {align1};     /* Y offset */
  34. mov  (1) read0_header.8<1>:UD   BLOCK_32X1 {align1};
  35. mov  (1) read0_header.20<1>:UB  thread_id_ub {align1};                  /* dispatch id */
  36.  
  37. shl  (2) read1_header.0<1>:D    orig_xy_ub<2,2,1>:UB 4:UW {align1};    /* (x, y) * 16 */
  38. add  (1) read1_header.0<1>:D    read1_header.0<0,1,0>:D -4:W {align1};     /* X offset */
  39. mov  (1) read1_header.8<1>:UD   BLOCK_4X16 {align1};
  40. mov  (1) read1_header.20<1>:UB  thread_id_ub {align1};                  /* dispatch id */
  41.        
  42. shl  (2) vme_m0.8<1>:UW         orig_xy_ub<2,2,1>:UB 4:UW {align1};    /* (x, y) * 16 */
  43. mov  (1) vme_m0.20<1>:UB        thread_id_ub {align1};                  /* dispatch id */
  44.  
  45. mul  (1) obw_m0.8<1>:UD         w_in_mb_uw<0,1,0>:UW orig_y_ub<0,1,0>:UB {align1};
  46. add  (1) obw_m0.8<1>:UD         obw_m0.8<0,1,0>:UD orig_x_ub<0,1,0>:UB {align1};
  47. mul  (1) obw_m0.8<1>:UD         obw_m0.8<0,1,0>:UD INTER_VME_OUTPUT_IN_OWS:UD {align1};
  48. mov  (1) obw_m0.20<1>:UB        thread_id_ub {align1};                  /* dispatch id */
  49.        
  50. /*
  51.  * Media Read Message -- fetch Luma neighbor edge pixels
  52.  */
  53. /* ROW */
  54. mov  (8) msg_reg0.0<1>:UD       read0_header.0<8,8,1>:UD {align1};        
  55. send (8) msg_ind INEP_ROW<1>:UB null read(BIND_IDX_INEP, 0, 0, 4) mlen 1 rlen 1 {align1};
  56.  
  57. /* COL */
  58. mov  (8) msg_reg0.0<1>:UD       read1_header.0<8,8,1>:UD {align1};                
  59. send (8) msg_ind INEP_COL0<1>:UB null read(BIND_IDX_INEP, 0, 0, 4) mlen 1 rlen 2 {align1};
  60.        
  61. mov  (8) mb_mvp_ref.0<1>:ud     0:ud            {align1};
  62. mov  (8) mb_ref_win.0<1>:ud     0:ud            {align1};
  63. and.z.f0.0 (1)          null:uw mb_hwdep<0,1,0>:uw              0x04:uw   {align1};
  64. (f0.0) jmpi (1) __mb_hwdep_end;
  65. /* read back the data for MB A */
  66. /* the layout of MB result is: rx.0(Available). rx.4(MVa), rX.8(MVb), rX.16(Pred_L0 flag),
  67. *  rX.18 (Pred_L1 flag), rX.20(Forward reference ID), rX.22(Backwared reference ID)
  68. */
  69. mov  (8) mba_result.0<1>:ud     0x0:ud          {align1};
  70. mov  (8) mbb_result.0<1>:ud     0x0:ud          {align1};
  71. mov  (8) mbc_result.0<1>:ud     0x0:ud          {align1};
  72. mba_start:
  73. mov  (8) mb_msg0.0<1>:ud        0:ud            {align1};
  74. and.z.f0.0 (1)          null:uw input_mb_intra_ub<0,1,0>:ub     INTRA_PRED_AVAIL_FLAG_AE:uw   {align1};
  75. /* MB A doesn't exist. Zero MV. mba_flag is zero and ref ID = -1 */
  76. (f0.0)  mov  (2)        mba_result.20<1>:w      -1:w    {align1};
  77. (f0.0)  jmpi (1)        mbb_start;
  78. mov  (1) mba_result.0<1>:d      MB_AVAIL                {align1};      
  79. mov  (2) tmp_reg0.0<1>:UW       orig_xy_ub<2,2,1>:UB    {align1};
  80. add  (1) tmp_reg0.0<1>:w        tmp_reg0.0<0,1,0>:w     -1:w    {align1};
  81. mul  (1) mb_msg0.8<1>:UD       w_in_mb_uw<0,1,0>:UW tmp_reg0.2<0,1,0>:UW {align1};
  82. add  (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:UD   tmp_reg0.0<0,1,0>:uw {align1};
  83. mul  (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:UD INTER_VME_OUTPUT_IN_OWS:UD {align1};
  84. mov  (1) mb_msg0.20<1>:UB        thread_id_ub {align1};                  /* dispatch id */
  85. mov  (1) mb_msg_tmp.8<1>:ud     mb_msg0.8<0,1,0>:ud     {align1};
  86.  
  87. add  (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:UD      INTER_VME_OUTPUT_MV_IN_OWS:UD {align1};
  88. /* bind index 3, read 1 oword (16bytes), msg type: 0(OWord Block Read) */
  89. send (16)
  90.        mb_ind
  91.        mb_wb.0<1>:ud
  92.         NULL
  93.        data_port(
  94.                OBR_CACHE_TYPE,
  95.                OBR_MESSAGE_TYPE,
  96.                OBR_CONTROL_0,
  97.                OBR_BIND_IDX,
  98.                OBR_WRITE_COMMIT_CATEGORY,
  99.                OBR_HEADER_PRESENT
  100.        )
  101.        mlen 1
  102.        rlen 1
  103.        {align1};
  104.  
  105. /* TODO: RefID is required after multi-references are added */
  106. and.z.f0.0      (1)     null<1>:ud        mb_mode_wb.0<0,1,0>:ud     INTRAMBFLAG_MASK:ud {align1} ;
  107. (-f0.0)   mov (2)       mba_result.20<1>:w                      -1:w    {align1};
  108. (-f0.0)   jmpi  (1)     mbb_start;
  109.  
  110. mov   (1) mb_msg0.8<1>:UD       mb_msg_tmp.8<0,1,0>:ud  {align1};
  111. /* Read MV for MB A */
  112. /* bind index 3, read 8 oword (128bytes), msg type: 0(OWord Block Read) */
  113. send (16)
  114.        mb_ind
  115.        mb_mv0.0<1>:ud
  116.         NULL
  117.        data_port(
  118.                OBR_CACHE_TYPE,
  119.                OBR_MESSAGE_TYPE,
  120.                OBR_CONTROL_8,
  121.                OBR_BIND_IDX,
  122.                OBR_WRITE_COMMIT_CATEGORY,
  123.                OBR_HEADER_PRESENT
  124.        )
  125.        mlen 1
  126.        rlen 4
  127.        {align1};
  128. /* TODO: RefID is required after multi-references are added */
  129. /* MV */
  130. mov        (2)          mba_result.4<1>:ud              mb_mv1.8<2,2,1>:ud      {align1};
  131. mov        (1)          mba_result.16<1>:w              MB_PRED_FLAG            {align1};
  132.  
  133. mbb_start:
  134. mov  (8) mb_msg0.0<1>:ud        0:ud            {align1};
  135. and.z.f0.0 (1)          null:uw input_mb_intra_ub<0,1,0>:ub     INTRA_PRED_AVAIL_FLAG_B:uw   {align1};
  136. /* MB B doesn't exist. Zero MV. mba_flag is zero */
  137. /* If MB B doesn't exist, neither MB C nor D exists */
  138. (f0.0)  mov  (2)        mbb_result.20<1>:w      -1:w            {align1};
  139. (f0.0)  mov  (2)        mbc_result.20<1>:w      -1:w            {align1};
  140. (f0.0)  jmpi (1)        mb_mvp_start;
  141. mov  (1) mbb_result.0<1>:d      MB_AVAIL                {align1};      
  142. mov  (2) tmp_reg0.0<1>:UW       orig_xy_ub<2,2,1>:UB    {align1};
  143. add  (1) tmp_reg0.2<1>:w        tmp_reg0.2<0,1,0>:w     -1:w    {align1};
  144. mul  (1) mb_msg0.8<1>:UD       w_in_mb_uw<0,1,0>:UW tmp_reg0.2<0,1,0>:UW {align1};
  145. add  (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:UD   tmp_reg0.0<0,1,0>:uw {align1};
  146. mul  (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:UD INTER_VME_OUTPUT_IN_OWS:UD {align1};
  147. mov  (1) mb_msg0.20<1>:UB        thread_id_ub {align1};                  /* dispatch id */
  148. mov  (1) mb_msg_tmp.8<1>:ud     mb_msg0.8<0,1,0>:ud     {align1};
  149.  
  150. add  (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:UD      INTER_VME_OUTPUT_MV_IN_OWS:UD {align1};
  151.  
  152. /* bind index 3, read 4 oword (64bytes), msg type: 0(OWord Block Read) */
  153. send (16)
  154.        mb_ind
  155.        mb_wb.0<1>:ud
  156.         NULL
  157.        data_port(
  158.                OBR_CACHE_TYPE,
  159.                OBR_MESSAGE_TYPE,
  160.                OBR_CONTROL_0,
  161.                OBR_BIND_IDX,
  162.                OBR_WRITE_COMMIT_CATEGORY,
  163.                OBR_HEADER_PRESENT
  164.        )
  165.        mlen 1
  166.        rlen 1
  167.        {align1};
  168.  
  169. /* TODO: RefID is required after multi-references are added */
  170. and.z.f0.0      (1)     null<1>:ud        mb_mode_wb.0<0,1,0>:ud     INTRAMBFLAG_MASK:ud {align1} ;
  171. (-f0.0)   mov (2)       mbb_result.20<1>:w                      -1:w    {align1};
  172. (-f0.0)   jmpi  (1)     mbc_start;
  173.  
  174. mov   (1) mb_msg0.8<1>:UD       mb_msg_tmp.8<0,1,0>:ud  {align1};
  175. /* Read MV for MB B */
  176. /* bind index 3, read 8 oword (128bytes), msg type: 0(OWord Block Read) */
  177. send (16)
  178.        mb_ind
  179.        mb_mv0.0<1>:ud
  180.         NULL
  181.        data_port(
  182.                OBR_CACHE_TYPE,
  183.                OBR_MESSAGE_TYPE,
  184.                OBR_CONTROL_8,
  185.                OBR_BIND_IDX,
  186.                OBR_WRITE_COMMIT_CATEGORY,
  187.                OBR_HEADER_PRESENT
  188.        )
  189.        mlen 1
  190.        rlen 4
  191.        {align1};
  192. /* TODO: RefID is required after multi-references are added */
  193. mov        (2)          mbb_result.4<1>:ud              mb_mv2.16<2,2,1>:ud     {align1};
  194. mov        (1)          mbb_result.16<1>:w              MB_PRED_FLAG            {align1};
  195.  
  196. mbc_start:
  197. mov  (8) mb_msg0.0<1>:ud        0:ud            {align1};
  198. and.z.f0.0 (1)          null:uw input_mb_intra_ub<0,1,0>:ub     INTRA_PRED_AVAIL_FLAG_C:uw   {align1};
  199. /* MB C doesn't exist. Zero MV. mba_flag is zero */
  200. /* Based on h264 spec the MB D will be replaced if MB C doesn't exist */
  201. (f0.0)  jmpi (1)        mbd_start;
  202. mov  (1) mbc_result.0<1>:d      MB_AVAIL                {align1};      
  203. mov  (2) tmp_reg0.0<1>:UW       orig_xy_ub<2,2,1>:UB    {align1};
  204. add  (1) tmp_reg0.2<1>:w        tmp_reg0.2<0,1,0>:w     -1:w    {align1};
  205. add  (1) tmp_reg0.0<1>:w        tmp_reg0.0<0,1,0>:w     1:w     {align1};
  206. mul  (1) mb_msg0.8<1>:UD       w_in_mb_uw<0,1,0>:UW tmp_reg0.2<0,1,0>:UW {align1};
  207. add  (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:UD   tmp_reg0.0<0,1,0>:uw {align1};
  208. mul  (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:UD INTER_VME_OUTPUT_IN_OWS:UD {align1};
  209. mov  (1) mb_msg0.20<1>:UB        thread_id_ub {align1};                  /* dispatch id */
  210.  
  211. mov  (1) mb_msg_tmp.8<1>:ud     mb_msg0.8<0,1,0>:ud     {align1};
  212.  
  213. add  (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:UD      INTER_VME_OUTPUT_MV_IN_OWS:UD {align1};
  214. /* bind index 3, read 4 oword (64bytes), msg type: 0(OWord Block Read) */
  215. send (16)
  216.        mb_ind
  217.        mb_wb.0<1>:ud
  218.         NULL
  219.        data_port(
  220.                OBR_CACHE_TYPE,
  221.                OBR_MESSAGE_TYPE,
  222.                OBR_CONTROL_0,
  223.                OBR_BIND_IDX,
  224.                OBR_WRITE_COMMIT_CATEGORY,
  225.                OBR_HEADER_PRESENT
  226.        )
  227.        mlen 1
  228.        rlen 1
  229.        {align1};
  230.  
  231. /* TODO: RefID is required after multi-references are added */
  232. and.z.f0.0      (1)     null<1>:ud        mb_mode_wb.0<0,1,0>:ud     INTRAMBFLAG_MASK:ud {align1} ;
  233. (-f0.0)   mov (2)       mbc_result.20<1>:w                      -1:w    {align1};
  234. (-f0.0)   jmpi  (1)     mb_mvp_start;
  235. mov   (1) mb_msg0.8<1>:UD       mb_msg_tmp.8<0,1,0>:ud {align1};
  236. /* Read MV for MB C */
  237. /* bind index 3, read 8 oword (128bytes), msg type: 0(OWord Block Read) */
  238. send (16)
  239.        mb_ind
  240.        mb_mv0.0<1>:ud
  241.         NULL
  242.        data_port(
  243.                OBR_CACHE_TYPE,
  244.                OBR_MESSAGE_TYPE,
  245.                OBR_CONTROL_8,
  246.                OBR_BIND_IDX,
  247.                OBR_WRITE_COMMIT_CATEGORY,
  248.                OBR_HEADER_PRESENT
  249.        )
  250.        mlen 1
  251.        rlen 4
  252.        {align1};
  253. /* TODO: RefID is required after multi-references are added */
  254. /* Forward MV */
  255. mov        (2)          mbc_result.4<1>:ud              mb_mv2.16<2,2,1>:ud     {align1};
  256. mov        (1)          mbc_result.16<1>:w              MB_PRED_FLAG            {align1};
  257.  
  258. jmpi   (1)    mb_mvp_start;
  259. mbd_start:
  260. mov  (8) mb_msg0.0<1>:ud        0:ud            {align1};
  261. and.z.f0.0 (1)          null:uw input_mb_intra_ub<0,1,0>:ub     INTRA_PRED_AVAIL_FLAG_D:uw   {align1};
  262. (f0.0)  jmpi (1)        mb_mvp_start;
  263. mov  (1) mbc_result.0<1>:d      MB_AVAIL                {align1};      
  264. mov  (2) tmp_reg0.0<1>:UW       orig_xy_ub<2,2,1>:UB    {align1};
  265. add  (2) tmp_reg0.0<1>:w        tmp_reg0.0<2,2,1>:w     -1:w    {align1};
  266. mul  (1) mb_msg0.8<1>:UD       w_in_mb_uw<0,1,0>:UW tmp_reg0.2<0,1,0>:UW {align1};
  267. add  (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:UD   tmp_reg0.0<0,1,0>:uw {align1};
  268.  
  269. mul  (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:UD INTER_VME_OUTPUT_IN_OWS:UD {align1};
  270. mov  (1) mb_msg0.20<1>:UB        thread_id_ub {align1};                  /* dispatch id */
  271. mov  (1) mb_msg_tmp.8<1>:ud     mb_msg0.8<0,1,0>:ud     {align1};
  272.  
  273. add  (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:UD      INTER_VME_OUTPUT_MV_IN_OWS:UD {align1};
  274. /* bind index 3, read 4 oword (64bytes), msg type: 0(OWord Block Read) */
  275. send (16)
  276.        mb_ind
  277.        mb_wb.0<1>:ud
  278.         NULL
  279.        data_port(
  280.                OBR_CACHE_TYPE,
  281.                OBR_MESSAGE_TYPE,
  282.                OBR_CONTROL_0,
  283.                OBR_BIND_IDX,
  284.                OBR_WRITE_COMMIT_CATEGORY,
  285.                OBR_HEADER_PRESENT
  286.        )
  287.        mlen 1
  288.        rlen 1
  289.        {align1};
  290.  
  291. and.z.f0.0      (1)     null<1>:ud        mb_mode_wb.0<0,1,0>:ud     INTRAMBFLAG_MASK:ud {align1} ;
  292. (-f0.0)   mov (2)       mbc_result.20<1>:w                      -1:w    {align1};
  293. (-f0.0)   jmpi  (1)     mb_mvp_start;
  294.  
  295. mov   (1) mb_msg0.8<1>:UD       mb_msg_tmp.8<0,1,0>:ud  {align1};
  296. /* Read MV for MB D */
  297. /* bind index 3, read 8 oword (128bytes), msg type: 0(OWord Block Read) */
  298. send (16)
  299.        mb_ind
  300.        mb_mv0.0<1>:ub
  301.         NULL
  302.        data_port(
  303.                OBR_CACHE_TYPE,
  304.                OBR_MESSAGE_TYPE,
  305.                OBR_CONTROL_8,
  306.                OBR_BIND_IDX,
  307.                OBR_WRITE_COMMIT_CATEGORY,
  308.                OBR_HEADER_PRESENT
  309.        )
  310.        mlen 1
  311.        rlen 4
  312.        {align1};
  313.  
  314. /* TODO: RefID is required after multi-references are added */
  315.  
  316. /* Forward MV */
  317. mov        (2)          mbc_result.4<1>:ud              mb_mv3.24<2,2,1>:ud     {align1};
  318. mov        (1)          mbc_result.16<1>:w              MB_PRED_FLAG            {align1};
  319.        
  320. mb_mvp_start:
  321. /*TODO: Add the skip prediction */
  322. /* Check whether both MB B and C are invailable */
  323. add     (1)     tmp_reg0.0<1>:d         mbb_result.0<0,1,0>:d   mbc_result.0<0,1,0>:d   {align1};
  324. cmp.z.f0.0 (1)  null:d                  tmp_reg0.0<0,1,0>:d     0:d     {align1};
  325. (-f0.0) jmpi (1)        mb_median_start;
  326. cmp.nz.f0.0 (1) null:d  mba_result.0<0,1,0>:d           0:d             {align1};
  327. (f0.0)  mov     (1)     mbb_result.4<1>:ud              mba_result.4<0,1,0>:ud  {align1};      
  328. (f0.0)  mov     (1)     mbc_result.4<1>:ud              mba_result.4<0,1,0>:ud  {align1};      
  329. (f0.0)  mov     (1)     mbb_result.20<1>:uw             mba_result.20<0,1,0>:uw {align1};      
  330. (f0.0)  mov     (1)     mbc_result.20<1>:uw             mba_result.20<0,1,0>:uw {align1};      
  331. (f0.0)  mov     (1)     mb_mvp_ref.0<1>:ud              mba_result.4<0,1,0>:ud  {align1};
  332. (-f0.0) mov     (1)     mb_mvp_ref.0<1>:ud              0:ud                    {align1};
  333. jmpi    (1)     __mb_hwdep_end;
  334.        
  335. mb_median_start:
  336. /* check whether only one neighbour MB has the same ref ID with the current MB */
  337. mov (8) tmp_reg0.0<1>:ud                0:ud            {align1};
  338. cmp.z.f0.0      (1)     null:d  mba_result.20<1>:w      0:w     {align1};
  339. (f0.0)  add     (1)     tmp_reg0.0<1>:w         tmp_reg0.0<1>:w 1:w     {align1};
  340. (f0.0)  mov     (1)     tmp_reg0.4<1>:ud        mba_result.4<0,1,0>:ud  {align1};
  341. cmp.z.f0.0      (1)     null:d  mbb_result.20<1>:w      0:w     {align1};
  342. (f0.0)  add     (1)     tmp_reg0.0<1>:w         tmp_reg0.0<1>:w 1:w     {align1};
  343. (f0.0)  mov     (1)     tmp_reg0.4<1>:ud        mbb_result.4<0,1,0>:ud  {align1};
  344. cmp.z.f0.0      (1)     null:d  mbc_result.20<1>:w      0:w     {align1};
  345. (f0.0)  add     (1)     tmp_reg0.0<1>:w         tmp_reg0.0<1>:w 1:w     {align1};
  346. (f0.0)  mov     (1)     tmp_reg0.4<1>:ud        mbc_result.4<0,1,0>:ud  {align1};
  347. cmp.e.f0.0      (1)     null:d  tmp_reg0.0<1>:w  1:w    {align1};
  348. (f0.0)  mov     (1)     mb_mvp_ref.0<1>:ud      tmp_reg0.4<0,1,0>:ud    {align1};
  349. (f0.0)  jmpi (1)  __mb_hwdep_end;
  350.  
  351. mov     (1)     INPUT_ARG0.0<1>:w       mba_result.4<0,1,0>:w   {align1};
  352. mov     (1)     INPUT_ARG0.4<1>:w       mbb_result.4<0,1,0>:w   {align1};
  353. mov     (1)     INPUT_ARG0.8<1>:w       mbc_result.4<0,1,0>:w   {align1};
  354. SAVE_RET        {align1};
  355.  jmpi   (1)     word_imedian;
  356. mov     (1)     mb_mvp_ref.0<1>:w               RET_ARG<0,1,0>:w        {align1};
  357. mov     (1)     INPUT_ARG0.0<1>:w       mba_result.6<0,1,0>:w   {align1};
  358. mov     (1)     INPUT_ARG0.4<1>:w       mbb_result.6<0,1,0>:w   {align1};
  359. mov     (1)     INPUT_ARG0.8<1>:w       mbc_result.6<0,1,0>:w   {align1};
  360. SAVE_RET        {align1};
  361. jmpi    (1)     word_imedian;
  362. mov     (1)     mb_mvp_ref.2<1>:w               RET_ARG<0,1,0>:w        {align1};
  363.  
  364. __mb_hwdep_end:
  365. asr     (2)     mb_ref_win.0<1>:w       mb_mvp_ref.0<2,2,1>:w   2:w     {align1};
  366. add     (2)     mb_ref_win.8<1>:w       mb_ref_win.0<2,2,1>:w   3:w     {align1};
  367. and     (2)     mb_ref_win.16<1>:uw     mb_ref_win.8<2,2,1>:uw  0xFFFC:uw {align1};
  368.  
  369. /* m2 */        
  370. mov  (8) vme_msg_2<1>:UD        0x0:UD {align1};
  371.  
  372. /* m3 */
  373. mov  (1) INEP_ROW.0<1>:UD       0x0:UD {align1};
  374. and  (1) INEP_ROW.4<1>:UD       INEP_ROW.4<0,1,0>:UD            0xFF000000:UD {align1};
  375. mov  (8) vme_msg_3<1>:UD        INEP_ROW.0<8,8,1>:UD {align1};        
  376.  
  377. /* m4 */
  378. mov  (8) vme_msg_4<1>:UD        0x0 {align1};
  379. mov (16) vme_msg_4.0<1>:UB      INEP_COL0.3<32,8,4>:UB {align1};
  380. mov  (1) vme_msg_4.16<1>:UD     INTRA_PREDICTORE_MODE {align1};
  381.  
  382.  
  383. /* m1 */
  384. mov  (8) vme_m1.0<1>:ud         0x0:ud  {align1};
  385. and.z.f0.0 (1) null<1>:UW transform_8x8_ub<0,1,0>:UB 1:UW {align1};
  386. (f0.0) mov  (1) intra_part_mask_ub<1>:UB  LUMA_INTRA_8x8_DISABLE:uw {align1};
  387.  
  388. /* assign MB intra struct from the thread payload*/
  389. mov (1) mb_intra_struct_ub<1>:UB input_mb_intra_ub<0,1,0>:UB {align1};
  390.  
  391.  
  392. /* M0 */
  393. /* IME search */
  394. cmp.z.f0.0 (1)          null<1>:uw      quality_level_ub<0,1,0>:ub              LOW_QUALITY_LEVEL:uw   {align1};
  395. (f0.0) jmpi (1) __low_quality_search;
  396.  
  397. __high_quality_search:
  398. mov  (1) vme_m0.12<1>:UD   SEARCH_CTRL_SINGLE + INTER_PART_MASK + INTER_SAD_HAAR + SUB_PEL_MODE_QUARTER:UD {align1};  
  399. /* 16x16 Source, 1/4 pixel, harr */
  400. mov  (1) vme_m0.22<1>:UW        REF_REGION_SIZE {align1};         /* Reference Width&Height, 48x40 */
  401.  
  402. mov  (1) vme_m0.0<1>:W          -16:W                   {align1};
  403. mov  (1) vme_m0.2<1>:W          -12:W                   {align1};
  404.  
  405. and.z.f0.0 (1)          null:uw input_mb_intra_ub<0,1,0>:ub     INTRA_PRED_AVAIL_FLAG_AE:uw   {align1};
  406. (f0.0)  add     (1)     vme_m0.0<1>:w   vme_m0.0<0,1,0>:w       12:w    {align1};
  407. and.z.f0.0 (1)          null:uw input_mb_intra_ub<0,1,0>:ub     INTRA_PRED_AVAIL_FLAG_B:uw   {align1};
  408. (f0.0)  add     (1)     vme_m0.2<1>:w   vme_m0.2<0,1,0>:w       8:w     {align1};
  409.  
  410. jmpi __vme_msg;
  411.  
  412. __low_quality_search:
  413. mov  (1) vme_m0.12<1>:UD   SEARCH_CTRL_SINGLE + INTER_PART_MASK + INTER_SAD_HAAR + SUB_PEL_MODE_HALF:UD {align1};  
  414. /* 16x16 Source, 1/2 pixel, harr */
  415. mov  (1) vme_m0.22<1>:UW        MIN_REF_REGION_SIZE {align1};         /* Reference Width&Height, 32x32 */
  416.  
  417. mov  (1) vme_m0.0<1>:W          -8:W                    {align1};
  418. mov  (1) vme_m0.2<1>:W          -8:W                    {align1};
  419.  
  420. and.z.f0.0 (1)          null:uw input_mb_intra_ub<0,1,0>:ub     INTRA_PRED_AVAIL_FLAG_AE:uw   {align1};
  421. (f0.0)  add     (1)     vme_m0.0<1>:w   vme_m0.0<0,1,0>:w       4:w     {align1};
  422. and.z.f0.0 (1)          null:uw input_mb_intra_ub<0,1,0>:ub     INTRA_PRED_AVAIL_FLAG_B:uw   {align1};
  423. (f0.0)  add     (1)     vme_m0.2<1>:w   vme_m0.2<0,1,0>:w       4:w     {align1};
  424.  
  425. __vme_msg:
  426. mov  (1) vme_m0.4<1>:UD         vme_m0.0<0,1,0>:UD      {align1};
  427. add  (2) vme_m0.0<1>:w          vme_m0.0<2,2,1>:w       mb_ref_win.16<2,2,1>:w  {align1};
  428. add  (2) vme_m0.4<1>:w          vme_m0.4<2,2,1>:w       mb_ref_win.16<2,2,1>:w  {align1};
  429. mov  (8) vme_msg_0.0<1>:UD      vme_m0.0<8,8,1>:UD {align1};
  430.  
  431. /* m1 */
  432.  
  433. mov  (1) vme_m1.0<1>:UD         ADAPTIVE_SEARCH_ENABLE:ud {align1} ;
  434. /* MV num is passed by constant buffer. R4.28 */
  435. mov  (1) vme_m1.4<1>:UB         r4.28<0,1,0>:UB {align1};
  436. add  (1) vme_m1.4<1>:UD         vme_m1.4<0,1,0>:UD      FB_PRUNING_DISABLE:UD {align1};
  437. mov  (1) vme_m1.8<1>:UD         START_CENTER + SEARCH_PATH_LEN:UD {align1};
  438.  
  439. /* Set the MV cost center */
  440. mov  (1) vme_m1.16<1>:ud        mb_mvp_ref.0<0,1,0>:ud  {align1};
  441. mov  (1) vme_m1.20<1>:ud        mb_mvp_ref.0<0,1,0>:ud  {align1};
  442. mov  (8) vme_msg_1.0<1>:UD      vme_m1.0<8,8,1>:UD {align1};
  443.  
  444.  
  445. send (8)
  446.        vme_msg_ind
  447.        vme_wb
  448.        null
  449.        vme(
  450.                BIND_IDX_VME,
  451.                0,
  452.                0,
  453.                VME_MESSAGE_TYPE_MIXED
  454.        )
  455.        mlen vme_msg_length
  456.        rlen vme_inter_wb_length
  457.        {align1};
  458.  
  459. and.z.f0.0      (1)     null<1>:ud              vme_wb0.0<0,1,0>:ud     INTRAMBFLAG_MASK:ud {align1} ;
  460.  
  461. (-f0.0)jmpi     (1)     __INTRA_INFO ;
  462.  
  463. __INTER_INFO:
  464. /* Write MV pairs */   
  465. mov  (8) msg_reg0.0<1>:UD       obw_m0.0<8,8,1>:UD {align1};
  466.  
  467. mov  (8) msg_reg1.0<1>:UD       vme_wb1.0<8,8,1>:UD   {align1};
  468.  
  469. mov  (8) msg_reg2.0<1>:UD       vme_wb2.0<8,8,1>:UD   {align1};
  470.  
  471. mov  (8) msg_reg3.0<1>:UD       vme_wb3.0<8,8,1>:UD   {align1};
  472.  
  473. mov  (8) msg_reg4.0<1>:UD       vme_wb4.0<8,8,1>:UD   {align1};                
  474. /* bind index 3, write  8 oword (128 bytes), msg type: 8(OWord Block Write) */
  475. send (16)
  476.        msg_ind
  477.        obw_wb
  478.        null
  479.        data_port(
  480.                OBW_CACHE_TYPE,
  481.                OBW_MESSAGE_TYPE,
  482.                OBW_CONTROL_8,
  483.                OBW_BIND_IDX,
  484.                OBW_WRITE_COMMIT_CATEGORY,
  485.                OBW_HEADER_PRESENT
  486.        )
  487.        mlen 5
  488.        rlen obw_wb_length
  489.        {align1};
  490.  
  491. mov             (1)     tmp_uw1<1>:uw           0:uw {align1} ;
  492. mov             (1)     tmp_ud1<1>:ud           0:ud {align1} ;
  493. and             (1)     tmp_uw1<1>:uw           vme_wb0.2<0,1,0>:uw     MV32_BIT_MASK:uw {align1} ;
  494. shr             (1)     tmp_uw1<1>:uw           tmp_uw1<1>:uw           MV32_BIT_SHIFT:uw {align1} ;
  495. mul             (1)     tmp_ud1<1>:ud           tmp_uw1<0,1,0>:uw       96:uw {align1} ;
  496. add             (1)     tmp_ud1<1>:ud           tmp_ud1<0,1,0>:ud       32:uw {align1} ;
  497. shl       (1)     tmp_uw1<1>:uw           tmp_uw1<0,1,0>:uw       MFC_MV32_BIT_SHIFT:uw {align1} ;
  498. add       (1)     tmp_uw1<1>:uw           tmp_uw1<0,1,0>:uw       MVSIZE_UW_BASE:uw {align1} ;
  499. add             (1)     tmp_uw1<1>:uw           tmp_uw1<0,1,0>:uw       CBP_DC_YUV_UW:uw {align1} ;
  500.  
  501. mov             (1)     msg_reg1.0<1>:uw        vme_wb0.0<0,1,0>:uw     {align1} ;
  502. mov             (1)     msg_reg1.2<1>:uw        tmp_uw1<0,1,0>:uw       {align1} ;
  503. mov             (1)     msg_reg1.4<1>:UD        vme_wb0.28<0,1,0>:UD    {align1};
  504. mov             (1)     msg_reg1.8<1>:ud        tmp_ud1<0,1,0>:ud       {align1} ;
  505. mov             (1)     msg_reg1.12<1>:ud        vme_wb0.0<0,1,0>:ud     {align1} ;
  506. mov             (1)     msg_reg1.16<1>:ud        0x25:ud     {align1} ;
  507. jmpi            (1)     __OUTPUT_INFO;
  508.  
  509. __INTRA_INFO:
  510. mov             (1)     msg_reg1.0<1>:UD        vme_wb.0<0,1,0>:UD      {align1};
  511. mov             (1)     msg_reg1.4<1>:UD        vme_wb.16<0,1,0>:UD     {align1};
  512. mov             (1)     msg_reg1.8<1>:UD        vme_wb.20<0,1,0>:UD     {align1};
  513. mov             (1)     msg_reg1.12<1>:UD       vme_wb.24<0,1,0>:UD     {align1};
  514. mov             (1)     msg_reg1.16<1>:ud        0x35:ud     {align1} ;
  515.  
  516. __OUTPUT_INFO:
  517.  
  518. mov     (1)     msg_reg1.20<1>:ud       obw_m0.8<0,1,0>:ud      {align1};
  519. add     (1)     obw_m0.8<1>:UD       obw_m0.8<0,1,0>:UD      INTER_VME_OUTPUT_MV_IN_OWS:UD {align1};
  520. mov     (8)     msg_reg0.0<1>:ud        obw_m0.0<8,8,1>:ud      {align1};
  521.  
  522.  
  523. /* bind index 3, write 1 oword, msg type: 8(OWord Block Write) */
  524. send (16)
  525.        msg_ind
  526.        obw_wb
  527.        null
  528.        data_port(
  529.                OBW_CACHE_TYPE,
  530.                OBW_MESSAGE_TYPE,
  531.                OBW_CONTROL_2,
  532.                OBW_BIND_IDX,
  533.                OBW_WRITE_COMMIT_CATEGORY,
  534.                OBW_HEADER_PRESENT
  535.        )
  536.        mlen 2
  537.        rlen obw_wb_length
  538.        {align1};
  539.  
  540. /* Issue message fence so that the previous write message is committed */
  541. send (16)
  542.        mb_ind
  543.        mb_wb.0<1>:ud
  544.         NULL
  545.        data_port(
  546.                OBR_CACHE_TYPE,
  547.                OBR_MESSAGE_FENCE,
  548.                OBR_MF_COMMIT,
  549.                OBR_BIND_IDX,
  550.                OBR_WRITE_COMMIT_CATEGORY,
  551.                OBR_HEADER_PRESENT
  552.        )
  553.        mlen 1
  554.        rlen 1
  555.         {align1};
  556.  
  557. __EXIT:
  558. /*
  559. * kill thread
  560. */        
  561. mov  (8) ts_msg_reg0<1>:UD         r0<8,8,1>:UD {align1};
  562. send (16) ts_msg_ind acc0<1>UW null thread_spawner(0, 0, 1) mlen 1 rlen 0 {align1 EOT};
  563.  
  564.  
  565.         nop             ;
  566.         nop             ;
  567. /* Compare three word data to get the min value */
  568. word_imin:
  569.         cmp.le.f0.0 (1)         null:w          INPUT_ARG0.0<0,1,0>:w   INPUT_ARG0.4<0,1,0>:w {align1};
  570.         (f0.0) mov  (1)         TEMP_VAR0.0<1>:w INPUT_ARG0.0<0,1,0>:w                    {align1};
  571.         (-f0.0) mov (1)         TEMP_VAR0.0<1>:w INPUT_ARG0.4<0,1,0>:w                    {align1};
  572.         cmp.le.f0.0 (1)         null:w          TEMP_VAR0.0<0,1,0>:w    INPUT_ARG0.8<0,1,0>:w {align1};
  573.         (f0.0) mov  (1)         RET_ARG<1>:w TEMP_VAR0.0<0,1,0>:w                         {align1};
  574.         (-f0.0) mov (1)         RET_ARG<1>:w INPUT_ARG0.8<0,1,0>:w                        {align1};
  575.         RETURN          {align1};      
  576.        
  577. /* Compare three word data to get the max value */
  578. word_imax:
  579.         cmp.ge.f0.0 (1)         null:w          INPUT_ARG0.0<0,1,0>:w   INPUT_ARG0.4<0,1,0>:w {align1};
  580.         (f0.0) mov  (1)         TEMP_VAR0.0<1>:w INPUT_ARG0.0<0,1,0>:w                    {align1};
  581.         (-f0.0) mov (1)         TEMP_VAR0.0<1>:w INPUT_ARG0.4<0,1,0>:w                    {align1};
  582.         cmp.ge.f0.0 (1)         null:w          TEMP_VAR0.0<0,1,0>:w    INPUT_ARG0.8<0,1,0>:w {align1};
  583.         (f0.0) mov  (1)         RET_ARG<1>:w TEMP_VAR0.0<0,1,0>:w                         {align1};
  584.         (-f0.0) mov (1)         RET_ARG<1>:w INPUT_ARG0.8<0,1,0>:w                        {align1};
  585.         RETURN          {align1};      
  586.        
  587. word_imedian:
  588.         cmp.ge.f0.0 (1) null:w INPUT_ARG0.0<0,1,0>:w INPUT_ARG0.4<0,1,0>:w {align1};
  589.         (f0.0)  jmpi (1) cmp_a_ge_b;
  590.         cmp.ge.f0.0 (1) null:w INPUT_ARG0.0<0,1,0>:w INPUT_ARG0.8<0,1,0>:w {align1};
  591.         (f0.0) mov (1) RET_ARG<1>:w INPUT_ARG0.0<0,1,0>:w {align1};
  592.         (f0.0) jmpi (1) cmp_end;
  593.         cmp.ge.f0.0 (1) null:w INPUT_ARG0.4<0,1,0>:w INPUT_ARG0.8<0,1,0>:w {align1};
  594.         (f0.0) mov (1) RET_ARG<1>:w INPUT_ARG0.8<0,1,0>:w {align1};
  595.         (-f0.0) mov (1) RET_ARG<1>:w INPUT_ARG0.4<0,1,0>:w {align1};
  596.         jmpi (1) cmp_end;
  597. cmp_a_ge_b:
  598.         cmp.ge.f0.0 (1) null:w INPUT_ARG0.4<0,1,0>:w INPUT_ARG0.8<0,1,0>:w {align1};
  599.         (f0.0) mov (1) RET_ARG<1>:w INPUT_ARG0.4<0,1,0>:w {align1};
  600.         (f0.0) jmpi (1) cmp_end;
  601.         cmp.ge.f0.0 (1) null:w INPUT_ARG0.0<0,1,0>:w INPUT_ARG0.8<0,1,0>:w {align1};
  602.         (f0.0) mov (1) RET_ARG<1>:w INPUT_ARG0.8<0,1,0>:w {align1};
  603.         (-f0.0) mov (1) RET_ARG<1>:w INPUT_ARG0.0<0,1,0>:w {align1};
  604. cmp_end:
  605.         RETURN  {align1};
  606.  
  607.