Subversion Repositories Kolibri OS

Rev

Rev 6074 | Go to most recent revision | Blame | Compare with Previous | Last modification | View Log | RSS feed

  1. /*OUTPUT_FORMAT("binary")*/
  2.  
  3. ENTRY(__start)
  4. SECTIONS
  5. {
  6.    .text 0x000000:
  7.    {
  8.         LONG(0x554e454D);
  9.         LONG(0x32305445);
  10.         LONG(1);
  11.         LONG(__start);
  12.         LONG(___iend);
  13.         LONG(___memsize);
  14.         LONG(___stacktop);
  15.         LONG(___cmdline);
  16.         LONG(___pgmname);     /*  full path    */
  17.         LONG(0);              /*FIXME tls data */
  18.  
  19.         *(.init)
  20.         *(.text)
  21.         *(SORT(.text$*))
  22.         *(.text.*)
  23.         *(.glue_7t)
  24.         *(.glue_7)
  25.         ___CTOR_LIST__ = .; __CTOR_LIST__ = . ;
  26.                         LONG (-1);*(.ctors); *(.ctor); *(SORT(.ctors.*));  LONG (0);
  27.         ___DTOR_LIST__ = .; __DTOR_LIST__ = . ;
  28.                         LONG (-1); *(.dtors); *(.dtor); *(SORT(.dtors.*));  LONG (0);
  29.         *(.fini)
  30.     /* ??? Why is .gcc_exc here?  */
  31.         *(.gcc_exc)
  32.         PROVIDE (etext = .);
  33.         *(.gcc_except_table)
  34.    }
  35.  
  36.    .rdata ALIGN(16) :
  37.    {
  38.         *(.rdata)
  39.         *(SORT(.rdata$*))
  40.         ___RUNTIME_PSEUDO_RELOC_LIST__ = .;
  41.         __RUNTIME_PSEUDO_RELOC_LIST__ = .;
  42.         *(.rdata_runtime_pseudo_reloc)
  43.         ___RUNTIME_PSEUDO_RELOC_LIST_END__ = .;
  44.         __RUNTIME_PSEUDO_RELOC_LIST_END__ = .;
  45.    }
  46.    .CRT ALIGN(16) :
  47.    {
  48.          ___crt_xc_start__ = . ;
  49.         *(SORT(.CRT$XC*))  /* C initialization */
  50.         ___crt_xc_end__ = . ;
  51.         ___crt_xi_start__ = . ;
  52.         *(SORT(.CRT$XI*))  /* C++ initialization */
  53.         ___crt_xi_end__ = . ;
  54.         ___crt_xl_start__ = . ;
  55.         *(SORT(.CRT$XL*))  /* TLS callbacks */
  56.     /* ___crt_xl_end__ is defined in the TLS Directory support code */
  57.         ___crt_xp_start__ = . ;
  58.         *(SORT(.CRT$XP*))  /* Pre-termination */
  59.         ___crt_xp_end__ = . ;
  60.         ___crt_xt_start__ = . ;
  61.         *(SORT(.CRT$XT*))  /* Termination */
  62.         ___crt_xt_end__ = . ;
  63.    }
  64.  
  65.    .data ALIGN(16) :
  66.    {
  67.         PROVIDE ( __data_start__ = .) ;
  68.         *(.data)
  69.         *(.data2)
  70.         *(SORT(.data$*))
  71.         *(.jcr)
  72.         __CRT_MT = .;
  73.         LONG(0);
  74.         PROVIDE ( __data_end__ = .) ;
  75.         *(.data_cygwin_nocopy)
  76.         ___iend = . ;
  77.    }
  78.  
  79. /*   .eh_frame BLOCK(16) :
  80.    {
  81.         PROVIDE (___EH_FRAME_BEGIN__ = .) ;
  82.         *(.eh_frame*)
  83.    }
  84. */
  85.  
  86.    bss ALIGN(16):
  87.    {
  88.         *(.bss)
  89.         *(COMMON)
  90.         . = ALIGN(16);
  91.         ___cmdline = .;
  92.         . = . + 256;
  93.         ___pgmname = .;
  94.         . = . + 1024 + 16;
  95.         ___stacktop = .;
  96.         ___memsize = . ;
  97.    }
  98.  
  99.   /DISCARD/ :
  100.   {
  101.     *(.debug$S)
  102.     *(.debug$T)
  103.     *(.debug$F)
  104.     *(.drectve)
  105.     *(.note.GNU-stack)
  106.     *(.comment)
  107.     *(.eh_frame)
  108.     *(.debug_abbrev)
  109.     *(.debug_info)
  110.     *(.debug_line)
  111.     *(.debug_frame)
  112.     *(.debug_loc)
  113.     *(.debug_pubnames)
  114.     *(.debug_aranges)
  115.     *(.debug_ranges)
  116.   }
  117.  
  118. }
  119.