Subversion Repositories Kolibri OS

Rev

Blame | Last modification | View Log | RSS feed

  1. /*
  2.  * Copyright © <2010>, Intel Corporation.
  3.  *
  4.  * Permission is hereby granted, free of charge, to any person obtaining a
  5.  * copy of this software and associated documentation files (the
  6.  * "Software"), to deal in the Software without restriction, including
  7.  * without limitation the rights to use, copy, modify, merge, publish,
  8.  * distribute, sub license, and/or sell copies of the Software, and to
  9.  * permit persons to whom the Software is furnished to do so, subject to
  10.  * the following conditions:
  11.  *
  12.  * The above copyright notice and this permission notice (including the
  13.  * next paragraph) shall be included in all copies or substantial portions
  14.  * of the Software.
  15.  *
  16.  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
  17.  * OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
  18.  * MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.
  19.  * IN NO EVENT SHALL PRECISION INSIGHT AND/OR ITS SUPPLIERS BE LIABLE FOR
  20.  * ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
  21.  * TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE
  22.  * SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  23.  *
  24.  */
  25. // Modual name: Inter_frame_haswell.asm
  26. //
  27. // Make inter predition estimation for Inter-frame on Haswell
  28. //
  29.  
  30. //
  31. //  Now, begin source code....
  32. //
  33.  
  34. #define SAVE_RET        add (1) RETURN_REG<1>:ud   ip:ud        32:ud
  35. #define RETURN          mov (1) ip:ud   RETURN_REG<0,1,0>:ud
  36.  
  37. /*
  38.  * __START
  39.  */
  40. __INTER_START:
  41. mov  (16) tmp_reg0.0<1>:UD      0x0:UD {align1};
  42. mov  (16) tmp_reg2.0<1>:UD      0x0:UD {align1};
  43. mov  (16) tmp_reg4.0<1>:UD      0x0:UD {align1} ;
  44. mov  (16) tmp_reg6.0<1>:UD      0x0:UD {align1} ;
  45.  
  46. shl  (2) read0_header.0<1>:D    orig_xy_ub<2,2,1>:UB 4:UW {align1};    /* (x, y) * 16 */
  47. add  (1) read0_header.0<1>:D    read0_header.0<0,1,0>:D -8:W {align1};     /* X offset */
  48. add  (1) read0_header.4<1>:D    read0_header.4<0,1,0>:D -1:W {align1};     /* Y offset */
  49. mov  (1) read0_header.8<1>:UD   BLOCK_32X1 {align1};
  50. mov  (1) read0_header.20<1>:UB  thread_id_ub {align1};                  /* dispatch id */
  51.  
  52. shl  (2) read1_header.0<1>:D    orig_xy_ub<2,2,1>:UB 4:UW {align1};    /* (x, y) * 16 */
  53. add  (1) read1_header.0<1>:D    read1_header.0<0,1,0>:D -4:W {align1};     /* X offset */
  54. mov  (1) read1_header.8<1>:UD   BLOCK_4X16 {align1};
  55. mov  (1) read1_header.20<1>:UB  thread_id_ub {align1};                  /* dispatch id */
  56.        
  57. shl  (2) vme_m0.8<1>:UW         orig_xy_ub<2,2,1>:UB 4:UW {align1};    /* (x, y) * 16 */
  58. mov  (1) vme_m0.20<1>:UB        thread_id_ub {align1};                  /* dispatch id */
  59.  
  60. mul  (1) obw_m0.8<1>:UD         w_in_mb_uw<0,1,0>:UW orig_y_ub<0,1,0>:UB {align1};
  61. add  (1) obw_m0.8<1>:UD         obw_m0.8<0,1,0>:UD orig_x_ub<0,1,0>:UB {align1};
  62. mul  (1) obw_m0.8<1>:UD         obw_m0.8<0,1,0>:UD 24:UD {align1};
  63. mov  (1) obw_m0.20<1>:UB        thread_id_ub {align1};                  /* dispatch id */
  64.        
  65. /*
  66.  * Media Read Message -- fetch Luma neighbor edge pixels
  67.  */
  68. /* ROW */
  69. mov  (8) msg_reg0.0<1>:UD       read0_header.0<8,8,1>:UD {align1};        
  70. send (8) msg_ind INEP_ROW<1>:UB null read(BIND_IDX_INEP, 0, 0, 4) mlen 1 rlen 1 {align1};
  71.  
  72. /* COL */
  73. mov  (8) msg_reg0.0<1>:UD       read1_header.0<8,8,1>:UD {align1};                
  74. send (8) msg_ind INEP_COL0<1>:UB null read(BIND_IDX_INEP, 0, 0, 4) mlen 1 rlen 2 {align1};
  75.        
  76. /*
  77.  * Media Read Message -- fetch Chroma neighbor edge pixels
  78.  */
  79. /* ROW */
  80. shl  (2) read0_header.0<1>:D    orig_xy_ub<2,2,1>:UB 3:UW {align1};    /* x * 16 , y * 8 */
  81. mul  (1) read0_header.0<1>:D    read0_header.0<0,1,0>:D  2:W {align1};
  82. add  (1) read0_header.0<1>:D    read0_header.0<0,1,0>:D -8:W {align1};     /* X offset */
  83. add  (1) read0_header.4<1>:D    read0_header.4<0,1,0>:D -1:W {align1};     /* Y offset */
  84. mov  (8) msg_reg0.0<1>:UD       read0_header.0<8,8,1>:UD {align1};        
  85. send (8) msg_ind CHROMA_ROW<1>:UB null read(BIND_IDX_CBCR, 0, 0, 4) mlen 1 rlen 1 {align1};
  86.  
  87. /* COL */
  88. shl  (2) read1_header.0<1>:D    orig_xy_ub<2,2,1>:UB 3:UW {align1};    /* x * 16, y * 8 */
  89. mul  (1) read1_header.0<1>:D    read1_header.0<0,1,0>:D  2:W {align1};
  90. add  (1) read1_header.0<1>:D    read1_header.0<0,1,0>:D -4:W {align1};     /* X offset */
  91. mov  (1) read1_header.8<1>:UD   BLOCK_8X4 {align1};
  92. mov  (8) msg_reg0.0<1>:UD       read1_header.0<8,8,1>:UD {align1};                
  93. send (8) msg_ind CHROMA_COL<1>:UB null read(BIND_IDX_CBCR, 0, 0, 4) mlen 1 rlen 1 {align1};
  94.  
  95. mov  (8) mb_mvp_ref.0<1>:ud     0:ud            {align1};
  96. mov  (8) mb_ref_win.0<1>:ud     0:ud            {align1};
  97. and.z.f0.0 (1)          null:uw mb_hwdep<0,1,0>:uw              0x04:uw   {align1};
  98. (f0.0) jmpi (1) __mb_hwdep_end;
  99. /* read back the data for MB A */
  100. /* the layout of MB result is: rx.0(Available). rx.4(MVa), rX.8(MVb), rX.16(Pred_L0 flag),
  101. *  rX.18 (Pred_L1 flag), rX.20(Forward reference ID), rX.22(Backwared reference ID)
  102. */
  103. mov  (8) mba_result.0<1>:ud     0x0:ud          {align1};
  104. mov  (8) mbb_result.0<1>:ud     0x0:ud          {align1};
  105. mov  (8) mbc_result.0<1>:ud     0x0:ud          {align1};
  106. mba_start:
  107. mov  (8) mb_msg0.0<1>:ud        0:ud            {align1};
  108. and.z.f0.0 (1)          null:uw input_mb_intra_ub<0,1,0>:ub     INTRA_PRED_AVAIL_FLAG_AE:uw   {align1};
  109. /* MB A doesn't exist. Zero MV. mba_flag is zero and ref ID = -1 */
  110. (f0.0)  mov  (2)        mba_result.20<1>:w      -1:w    {align1};
  111. (f0.0)  jmpi (1)        mbb_start;
  112. mov  (1) mba_result.0<1>:d      MB_AVAIL                {align1};      
  113. mov  (2) tmp_reg0.0<1>:UW       orig_xy_ub<2,2,1>:UB    {align1};
  114. add  (1) tmp_reg0.0<1>:w        tmp_reg0.0<0,1,0>:w     -1:w    {align1};
  115. mul  (1) mb_msg0.8<1>:UD       w_in_mb_uw<0,1,0>:UW tmp_reg0.2<0,1,0>:UW {align1};
  116. add  (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:UD   tmp_reg0.0<0,1,0>:uw {align1};
  117. mul  (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:UD 24:UD {align1};
  118. mov  (1) mb_msg0.20<1>:UB        thread_id_ub {align1};                  /* dispatch id */
  119.  
  120. /* bind index 3, read 4 oword (64bytes), msg type: 0(OWord Block Read) */
  121. send (16)
  122.        mb_ind
  123.        mb_wb.0<1>:ud
  124.         NULL
  125.        data_port(
  126.                OBR_CACHE_TYPE,
  127.                OBR_MESSAGE_TYPE,
  128.                OBR_CONTROL_4,
  129.                OBR_BIND_IDX,
  130.                OBR_WRITE_COMMIT_CATEGORY,
  131.                OBR_HEADER_PRESENT
  132.        )
  133.        mlen 1
  134.        rlen 2
  135.        {align1};
  136.  
  137. /* TODO: RefID is required after multi-references are added */
  138. cmp.l.f0.0 (1)          null:w  mb_intra_wb.16<0,1,0>:uw        mb_inter_wb.8<0,1,0>:uw {align1};
  139. (f0.0)   mov (2)        mba_result.20<1>:w                      -1:w    {align1};
  140. (f0.0)   jmpi   (1)     mbb_start;
  141.  
  142. add   (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:ud     3:ud {align1};
  143. /* Read MV for MB A */
  144. /* bind index 3, read 8 oword (128bytes), msg type: 0(OWord Block Read) */
  145. send (16)
  146.        mb_ind
  147.        mb_mv0.0<1>:ud
  148.         NULL
  149.        data_port(
  150.                OBR_CACHE_TYPE,
  151.                OBR_MESSAGE_TYPE,
  152.                OBR_CONTROL_8,
  153.                OBR_BIND_IDX,
  154.                OBR_WRITE_COMMIT_CATEGORY,
  155.                OBR_HEADER_PRESENT
  156.        )
  157.        mlen 1
  158.        rlen 4
  159.        {align1};
  160. /* TODO: RefID is required after multi-references are added */
  161. /* MV */
  162. mov        (2)          mba_result.4<1>:ud              mb_mv1.8<2,2,1>:ud      {align1};
  163. mov        (1)          mba_result.16<1>:w              MB_PRED_FLAG            {align1};
  164.  
  165. mbb_start:
  166. mov  (8) mb_msg0.0<1>:ud        0:ud            {align1};
  167. and.z.f0.0 (1)          null:uw input_mb_intra_ub<0,1,0>:ub     INTRA_PRED_AVAIL_FLAG_B:uw   {align1};
  168. /* MB B doesn't exist. Zero MV. mba_flag is zero */
  169. /* If MB B doesn't exist, neither MB C nor D exists */
  170. (f0.0)  mov  (2)        mbb_result.20<1>:w      -1:w            {align1};
  171. (f0.0)  mov  (2)        mbc_result.20<1>:w      -1:w            {align1};
  172. (f0.0)  jmpi (1)        mb_mvp_start;
  173. mov  (1) mbb_result.0<1>:d      MB_AVAIL                {align1};      
  174. mov  (2) tmp_reg0.0<1>:UW       orig_xy_ub<2,2,1>:UB    {align1};
  175. add  (1) tmp_reg0.2<1>:w        tmp_reg0.2<0,1,0>:w     -1:w    {align1};
  176. mul  (1) mb_msg0.8<1>:UD       w_in_mb_uw<0,1,0>:UW tmp_reg0.2<0,1,0>:UW {align1};
  177. add  (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:UD   tmp_reg0.0<0,1,0>:uw {align1};
  178. mul  (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:UD 24:UD {align1};
  179. mov  (1) mb_msg0.20<1>:UB        thread_id_ub {align1};                  /* dispatch id */
  180.  
  181. /* bind index 3, read 4 oword (64bytes), msg type: 0(OWord Block Read) */
  182. send (16)
  183.        mb_ind
  184.        mb_wb.0<1>:ud
  185.         NULL
  186.        data_port(
  187.                OBR_CACHE_TYPE,
  188.                OBR_MESSAGE_TYPE,
  189.                OBR_CONTROL_4,
  190.                OBR_BIND_IDX,
  191.                OBR_WRITE_COMMIT_CATEGORY,
  192.                OBR_HEADER_PRESENT
  193.        )
  194.        mlen 1
  195.        rlen 2
  196.        {align1};
  197.  
  198. /* TODO: RefID is required after multi-references are added */
  199. cmp.l.f0.0 (1)          null:w  mb_intra_wb.16<0,1,0>:uw        mb_inter_wb.8<0,1,0>:uw {align1};
  200. (f0.0)   mov (2)        mbb_result.20<1>:w                      -1:w    {align1};
  201. (f0.0)   jmpi   (1)     mbc_start;
  202. add   (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:ud     3:ud {align1};
  203. /* Read MV for MB B */
  204. /* bind index 3, read 8 oword (128bytes), msg type: 0(OWord Block Read) */
  205. send (16)
  206.        mb_ind
  207.        mb_mv0.0<1>:ud
  208.         NULL
  209.        data_port(
  210.                OBR_CACHE_TYPE,
  211.                OBR_MESSAGE_TYPE,
  212.                OBR_CONTROL_8,
  213.                OBR_BIND_IDX,
  214.                OBR_WRITE_COMMIT_CATEGORY,
  215.                OBR_HEADER_PRESENT
  216.        )
  217.        mlen 1
  218.        rlen 4
  219.        {align1};
  220. /* TODO: RefID is required after multi-references are added */
  221. mov        (2)          mbb_result.4<1>:ud              mb_mv2.16<2,2,1>:ud     {align1};
  222. mov        (1)          mbb_result.16<1>:w              MB_PRED_FLAG            {align1};
  223.  
  224. mbc_start:
  225. mov  (8) mb_msg0.0<1>:ud        0:ud            {align1};
  226. and.z.f0.0 (1)          null:uw input_mb_intra_ub<0,1,0>:ub     INTRA_PRED_AVAIL_FLAG_C:uw   {align1};
  227. /* MB C doesn't exist. Zero MV. mba_flag is zero */
  228. /* Based on h264 spec the MB D will be replaced if MB C doesn't exist */
  229. (f0.0)  jmpi (1)        mbd_start;
  230. mov  (1) mbc_result.0<1>:d      MB_AVAIL                {align1};      
  231. mov  (2) tmp_reg0.0<1>:UW       orig_xy_ub<2,2,1>:UB    {align1};
  232. add  (1) tmp_reg0.2<1>:w        tmp_reg0.2<0,1,0>:w     -1:w    {align1};
  233. add  (1) tmp_reg0.0<1>:w        tmp_reg0.0<0,1,0>:w     1:w     {align1};
  234. mul  (1) mb_msg0.8<1>:UD       w_in_mb_uw<0,1,0>:UW tmp_reg0.2<0,1,0>:UW {align1};
  235. add  (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:UD   tmp_reg0.0<0,1,0>:uw {align1};
  236. mul  (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:UD 24:UD {align1};
  237. mov  (1) mb_msg0.20<1>:UB        thread_id_ub {align1};                  /* dispatch id */
  238.  
  239. /* bind index 3, read 4 oword (64bytes), msg type: 0(OWord Block Read) */
  240. send (16)
  241.        mb_ind
  242.        mb_wb.0<1>:ud
  243.         NULL
  244.        data_port(
  245.                OBR_CACHE_TYPE,
  246.                OBR_MESSAGE_TYPE,
  247.                OBR_CONTROL_4,
  248.                OBR_BIND_IDX,
  249.                OBR_WRITE_COMMIT_CATEGORY,
  250.                OBR_HEADER_PRESENT
  251.        )
  252.        mlen 1
  253.        rlen 2
  254.        {align1};
  255.  
  256. /* TODO: RefID is required after multi-references are added */
  257. cmp.l.f0.0 (1)          null:w  mb_intra_wb.16<0,1,0>:uw        mb_inter_wb.8<0,1,0>:uw {align1};
  258. (f0.0)   mov (2)        mbc_result.20<1>:w                      -1:w    {align1};
  259. (f0.0)   jmpi   (1)     mb_mvp_start;
  260. add   (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:ud     3:ud {align1};
  261. /* Read MV for MB C */
  262. /* bind index 3, read 8 oword (128bytes), msg type: 0(OWord Block Read) */
  263. send (16)
  264.        mb_ind
  265.        mb_mv0.0<1>:ud
  266.         NULL
  267.        data_port(
  268.                OBR_CACHE_TYPE,
  269.                OBR_MESSAGE_TYPE,
  270.                OBR_CONTROL_8,
  271.                OBR_BIND_IDX,
  272.                OBR_WRITE_COMMIT_CATEGORY,
  273.                OBR_HEADER_PRESENT
  274.        )
  275.        mlen 1
  276.        rlen 4
  277.        {align1};
  278. /* TODO: RefID is required after multi-references are added */
  279. /* Forward MV */
  280. mov        (2)          mbc_result.4<1>:ud              mb_mv2.16<2,2,1>:ud     {align1};
  281. mov        (1)          mbc_result.16<1>:w              MB_PRED_FLAG            {align1};
  282.  
  283. jmpi   (1)    mb_mvp_start;
  284. mbd_start:
  285. mov  (8) mb_msg0.0<1>:ud        0:ud            {align1};
  286. and.z.f0.0 (1)          null:uw input_mb_intra_ub<0,1,0>:ub     INTRA_PRED_AVAIL_FLAG_D:uw   {align1};
  287. (f0.0)  jmpi (1)        mb_mvp_start;
  288. mov  (1) mbc_result.0<1>:d      MB_AVAIL                {align1};      
  289. mov  (2) tmp_reg0.0<1>:UW       orig_xy_ub<2,2,1>:UB    {align1};
  290. add  (2) tmp_reg0.0<1>:w        tmp_reg0.0<2,2,1>:w     -1:w    {align1};
  291. mul  (1) mb_msg0.8<1>:UD       w_in_mb_uw<0,1,0>:UW tmp_reg0.2<0,1,0>:UW {align1};
  292. add  (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:UD   tmp_reg0.0<0,1,0>:uw {align1};
  293. mul  (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:UD 24:UD {align1};
  294. mov  (1) mb_msg0.20<1>:UB        thread_id_ub {align1};                  /* dispatch id */
  295.  
  296. /* bind index 3, read 4 oword (64bytes), msg type: 0(OWord Block Read) */
  297. send (16)
  298.        mb_ind
  299.        mb_wb.0<1>:ud
  300.         NULL
  301.        data_port(
  302.                OBR_CACHE_TYPE,
  303.                OBR_MESSAGE_TYPE,
  304.                OBR_CONTROL_4,
  305.                OBR_BIND_IDX,
  306.                OBR_WRITE_COMMIT_CATEGORY,
  307.                OBR_HEADER_PRESENT
  308.        )
  309.        mlen 1
  310.        rlen 2
  311.        {align1};
  312.  
  313. cmp.l.f0.0 (1)          null:w  mb_intra_wb.16<0,1,0>:uw        mb_inter_wb.8<0,1,0>:uw {align1};
  314. (f0.0)   mov (2)        mbc_result.20<1>:w                      -1:w    {align1};
  315. (f0.0)   jmpi   (1)     mb_mvp_start;
  316.  
  317. add   (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:ud     3:ud {align1};
  318. /* Read MV for MB D */
  319. /* bind index 3, read 8 oword (128bytes), msg type: 0(OWord Block Read) */
  320. send (16)
  321.        mb_ind
  322.        mb_mv0.0<1>:ub
  323.         NULL
  324.        data_port(
  325.                OBR_CACHE_TYPE,
  326.                OBR_MESSAGE_TYPE,
  327.                OBR_CONTROL_8,
  328.                OBR_BIND_IDX,
  329.                OBR_WRITE_COMMIT_CATEGORY,
  330.                OBR_HEADER_PRESENT
  331.        )
  332.        mlen 1
  333.        rlen 4
  334.        {align1};
  335.  
  336. /* TODO: RefID is required after multi-references are added */
  337.  
  338. /* Forward MV */
  339. mov        (2)          mbc_result.4<1>:ud              mb_mv3.24<2,2,1>:ud     {align1};
  340. mov        (1)          mbc_result.16<1>:w              MB_PRED_FLAG            {align1};
  341.        
  342. mb_mvp_start:
  343. /*TODO: Add the skip prediction */
  344. /* Check whether both MB B and C are inavailable */
  345. add     (1)     tmp_reg0.0<1>:d         mbb_result.0<0,1,0>:d   mbc_result.0<0,1,0>:d   {align1};
  346. cmp.z.f0.0 (1)  null:d                  tmp_reg0.0<0,1,0>:d     0:d     {align1};
  347. (-f0.0) jmpi (1)        mb_median_start;
  348. cmp.nz.f0.0 (1) null:d  mba_result.0<0,1,0>:d           0:d             {align1};
  349. (f0.0)  mov     (1)     mbb_result.4<1>:ud              mba_result.4<0,1,0>:ud  {align1};      
  350. (f0.0)  mov     (1)     mbc_result.4<1>:ud              mba_result.4<0,1,0>:ud  {align1};      
  351. (f0.0)  mov     (1)     mbb_result.20<1>:uw             mba_result.20<0,1,0>:uw {align1};      
  352. (f0.0)  mov     (1)     mbc_result.20<1>:uw             mba_result.20<0,1,0>:uw {align1};      
  353. (f0.0)  mov     (1)     mb_mvp_ref.0<1>:ud              mba_result.4<0,1,0>:ud  {align1};
  354. (-f0.0) mov     (1)     mb_mvp_ref.0<1>:ud              0:ud                    {align1};
  355. jmpi    (1)     __mb_hwdep_end;
  356.        
  357. mb_median_start:
  358. /* check whether only one neighbour MB has the same ref ID with the current MB */
  359. mov (8) tmp_reg0.0<1>:ud                0:ud            {align1};
  360. cmp.z.f0.0      (1)     null:d  mba_result.20<1>:w      0:w     {align1};
  361. (f0.0)  add     (1)     tmp_reg0.0<1>:w         tmp_reg0.0<1>:w 1:w     {align1};
  362. (f0.0)  mov     (1)     tmp_reg0.4<1>:ud        mba_result.4<0,1,0>:ud  {align1};
  363. cmp.z.f0.0      (1)     null:d  mbb_result.20<1>:w      0:w     {align1};
  364. (f0.0)  add     (1)     tmp_reg0.0<1>:w         tmp_reg0.0<1>:w 1:w     {align1};
  365. (f0.0)  mov     (1)     tmp_reg0.4<1>:ud        mbb_result.4<0,1,0>:ud  {align1};
  366. cmp.z.f0.0      (1)     null:d  mbc_result.20<1>:w      0:w     {align1};
  367. (f0.0)  add     (1)     tmp_reg0.0<1>:w         tmp_reg0.0<1>:w 1:w     {align1};
  368. (f0.0)  mov     (1)     tmp_reg0.4<1>:ud        mbc_result.4<0,1,0>:ud  {align1};
  369. cmp.e.f0.0      (1)     null:d  tmp_reg0.0<1>:w  1:w    {align1};
  370. (f0.0)  mov     (1)     mb_mvp_ref.0<1>:ud      tmp_reg0.4<0,1,0>:ud    {align1};
  371. (f0.0)  jmpi (1)  __mb_hwdep_end;
  372.  
  373. mov     (1)     INPUT_ARG0.0<1>:w       mba_result.4<0,1,0>:w   {align1};
  374. mov     (1)     INPUT_ARG0.4<1>:w       mbb_result.4<0,1,0>:w   {align1};
  375. mov     (1)     INPUT_ARG0.8<1>:w       mbc_result.4<0,1,0>:w   {align1};
  376. SAVE_RET        {align1};
  377.  jmpi   (1)     word_imedian;
  378. mov     (1)     mb_mvp_ref.0<1>:w               RET_ARG<0,1,0>:w        {align1};
  379. mov     (1)     INPUT_ARG0.0<1>:w       mba_result.6<0,1,0>:w   {align1};
  380. mov     (1)     INPUT_ARG0.4<1>:w       mbb_result.6<0,1,0>:w   {align1};
  381. mov     (1)     INPUT_ARG0.8<1>:w       mbc_result.6<0,1,0>:w   {align1};
  382. SAVE_RET        {align1};
  383. jmpi    (1)     word_imedian;
  384. mov     (1)     mb_mvp_ref.2<1>:w               RET_ARG<0,1,0>:w        {align1};
  385.  
  386. __mb_hwdep_end:
  387. asr     (2)     mb_ref_win.0<1>:w       mb_mvp_ref.0<2,2,1>:w   2:w     {align1};
  388. add     (2)     mb_ref_win.8<1>:w       mb_ref_win.0<2,2,1>:w   3:w     {align1};
  389. and     (2)     mb_ref_win.16<1>:uw     mb_ref_win.8<2,2,1>:uw  0xFFFC:uw {align1};
  390.        
  391. /* m2, get the MV/Mb cost passed from constant buffer when
  392. spawning thread by MEDIA_OBJECT */      
  393. mov (8) vme_m2<1>:UD            r1.0<8,8,1>:UD {align1};
  394.  
  395. mov (8) vme_msg_2<1>:UD         vme_m2.0<8,8,1>:UD {align1};
  396.  
  397. /* m3 */
  398. mov (8) vme_msg_3<1>:UD         0x0:UD {align1};               
  399.  
  400. /* m4 */
  401. mov  (1) INEP_ROW.0<1>:UD       0x0:UD {align1};
  402. and  (1) INEP_ROW.4<1>:UD       INEP_ROW.4<0,1,0>:UD            0xFF000000:UD {align1};
  403. mov  (8) vme_msg_4<1>:UD         INEP_ROW.0<8,8,1>:UD {align1};
  404.  
  405. /* m5 */        
  406. mov  (8) vme_msg_5<1>:UD         0x0:UD {align1};
  407. mov (16) vme_msg_5.0<1>:UB       INEP_COL0.3<32,8,4>:UB {align1};
  408. mov  (1) vme_msg_5.16<1>:UD      INTRA_PREDICTORE_MODE {align1};
  409.  
  410. /* the penalty for Intra mode */
  411. mov  (1) vme_msg_5.28<1>:UD     0x010101:UD {align1};
  412. mov  (1) vme_msg_5.20<1>:UW      CHROMA_ROW.6<0,1,0>:UW {align1};
  413.  
  414.  
  415. /* m6 */
  416. mov  (4) vme_msg_6.16<1>:UD      CHROMA_ROW.8<4,4,1>:UD {align1};
  417. mov  (8) vme_msg_6.0<1>:UW       CHROMA_COL.2<16,8,2>:UW {align1};
  418.  
  419. /*
  420. * SIC VME message
  421. */
  422. /* m0 */        
  423. mov  (8) vme_msg_0.0<1>:UD      vme_m0.0<8,8,1>:UD {align1};
  424. mov  (1) tmp_reg0.0<1>:UW       LUMA_INTRA_MODE:UW {align1};
  425. /* Use the Luma mode */
  426. mov  (1) vme_msg_4.5<1>:UB      tmp_reg0.0<0,1,0>:UB {align1};
  427.  
  428. /* m1 */
  429. mov  (1) intra_flag<1>:UW       0x0:UW {align1}                     ;
  430. and.z.f0.0 (1) null<1>:UW transform_8x8_ub<0,1,0>:UB 1:UW {align1};
  431. (f0.0) mov  (1) intra_part_mask_ub<1>:UB  LUMA_INTRA_8x8_DISABLE {align1};
  432.  
  433. /* assign MB intra struct from the thread payload*/
  434. mov (1) mb_intra_struct_ub<1>:UB input_mb_intra_ub<0,1,0>:UB {align1};
  435.  
  436. /* Disable DC HAAR component when calculating HARR SATD block */
  437. mov  (1) tmp_reg0.0<1>:UW       DC_HARR_DISABLE:UW              {align1};
  438. mov  (1) vme_m1.30<1>:UB        tmp_reg0.0<0,1,0>:UB  {align1};
  439.  
  440. mov  (1) vme_m0.12<1>:UD        INTRA_SAD_HAAR:UD {align1};    /* 16x16 Source, Intra_harr */
  441. /* m0 */        
  442. mov  (8) vme_msg_0.0<1>:UD      vme_m0.0<8,8,1>:UD {align1};
  443. mov  (8) vme_msg_1<1>:UD        vme_m1.0<8,8,1>:UD {align1};
  444.  
  445. /* after verification it will be passed by using payload */
  446. send (8)
  447.        vme_msg_ind
  448.        vme_wb<1>:UD
  449.        null
  450.        cre(
  451.                BIND_IDX_VME,
  452.                VME_SIC_MESSAGE_TYPE
  453.        )
  454.        mlen sic_vme_msg_length
  455.        rlen vme_wb_length
  456.        {align1};
  457. /*
  458. * Oword Block Write message
  459. */
  460. mov  (8) msg_reg0.0<1>:UD       obw_m0<8,8,1>:UD {align1};
  461.        
  462. mov  (1) msg_reg1.0<1>:UD       vme_wb.0<0,1,0>:UD      {align1};
  463. mov  (1) msg_reg1.4<1>:UD       vme_wb.16<0,1,0>:UD     {align1};
  464. mov  (1) msg_reg1.8<1>:UD       vme_wb.20<0,1,0>:UD     {align1};
  465. mov  (1) msg_reg1.12<1>:UD      vme_wb.24<0,1,0>:UD     {align1};
  466.  
  467. /* Distortion, Intra (17-16), */
  468. mov  (1) msg_reg1.16<1>:UW      vme_wb.12<0,1,0>:UW     {align1};
  469.  
  470. mov  (1) msg_reg1.20<1>:UD      vme_wb.8<0,1,0>:UD     {align1};
  471. /* VME clock counts */
  472. mov  (1) msg_reg1.24<1>:UD      vme_wb.28<0,1,0>:UD     {align1};
  473.  
  474. mov  (1) msg_reg1.28<1>:UD      obw_m0.8<0,1,0>:UD     {align1};
  475.  
  476. /* bind index 3, write 2 oword (32bytes), msg type: 8(OWord Block Write) */
  477. send (16)
  478.        msg_ind
  479.        obw_wb
  480.        null
  481.        data_port(
  482.                OBW_CACHE_TYPE,
  483.                OBW_MESSAGE_TYPE,
  484.                OBW_CONTROL_2,
  485.                OBW_BIND_IDX,
  486.                OBW_WRITE_COMMIT_CATEGORY,
  487.                OBW_HEADER_PRESENT
  488.        )
  489.        mlen 2
  490.        rlen obw_wb_length
  491.        {align1};
  492.  
  493. /* IME search */
  494. cmp.z.f0.0 (1)          null<1>:uw      quality_level_ub<0,1,0>:ub              LOW_QUALITY_LEVEL:uw   {align1};
  495. (f0.0) jmpi (1) __low_quality_search;
  496.  
  497. __high_quality_search:
  498. /* M3/M4 search path */
  499. mov  (1) vme_msg_3.0<1>:UD      0x01010101:UD {align1};
  500. mov  (1) vme_msg_3.4<1>:UD      0x10010101:UD {align1};
  501. mov  (1) vme_msg_3.8<1>:UD      0x0F0F0F0F:UD {align1};
  502. mov  (1) vme_msg_3.12<1>:UD     0x100F0F0F:UD {align1};
  503. mov  (1) vme_msg_3.16<1>:UD     0x01010101:UD {align1};
  504. mov  (1) vme_msg_3.20<1>:UD     0x10010101:UD {align1};
  505. mov  (1) vme_msg_3.24<1>:UD     0x0F0F0F0F:UD {align1};
  506. mov  (1) vme_msg_3.28<1>:UD     0x100F0F0F:UD {align1};
  507. mov  (1) vme_msg_4.0<1>:UD      0x01010101:UD {align1};
  508. mov  (1) vme_msg_4.4<1>:UD      0x10010101:UD {align1};
  509. mov  (1) vme_msg_4.8<1>:UD      0x0F0F0F0F:UD {align1};
  510. mov  (1) vme_msg_4.12<1>:UD     0x000F0F0F:UD {align1};
  511. mov  (4) vme_msg_4.16<1>:UD     0x0:UD {align1};
  512.  
  513. mov  (1) vme_m0.12<1>:UD        SEARCH_CTRL_SINGLE + INTER_PART_MASK + INTER_SAD_HAAR:UD {align1};    /* 16x16 Source, harr */
  514. mov  (1) vme_m0.22<1>:UW        REF_REGION_SIZE {align1};         /* Reference Width&Height, 48x40 */
  515. mov  (1) vme_m0.0<1>:W          -16:W                   {align1};
  516. mov  (1) vme_m0.2<1>:W          -12:W                   {align1};
  517.  
  518. and.z.f0.0 (1)          null:uw input_mb_intra_ub<0,1,0>:ub     INTRA_PRED_AVAIL_FLAG_AE:uw   {align1};
  519. (f0.0)  add     (1)     vme_m0.0<1>:w   vme_m0.0<0,1,0>:w       12:w    {align1};
  520. and.z.f0.0 (1)          null:uw input_mb_intra_ub<0,1,0>:ub     INTRA_PRED_AVAIL_FLAG_B:uw   {align1};
  521. (f0.0)  add     (1)     vme_m0.2<1>:w   vme_m0.2<0,1,0>:w       8:w     {align1};
  522.  
  523. jmpi (1) __vme_msg;
  524.  
  525. __low_quality_search:
  526. /* M3/M4 search path */
  527. mov  (1) vme_msg_3.0<1>:UD      0x10010101:UD {align1};
  528. mov  (1) vme_msg_3.4<1>:UD      0x100F0F0F:UD {align1};
  529. mov  (1) vme_msg_3.8<1>:UD      0x10010101:UD {align1};
  530. mov  (1) vme_msg_3.12<1>:UD     0x000F0F0F:UD {align1};
  531. mov  (4) vme_msg_3.16<1>:UD     0x0:UD {align1};
  532. mov  (8) vme_msg_4.16<1>:UD     0x0:UD {align1};
  533.  
  534. mov  (1) vme_m0.12<1>:UD        SEARCH_CTRL_SINGLE + INTER_PART_MASK + INTER_SAD_HAAR:UD {align1};    /* 16x16 Source, harr */
  535. mov  (1) vme_m0.22<1>:UW        MIN_REF_REGION_SIZE {align1};         /* Reference Width&Height, 32x32 */
  536. mov  (1) vme_m0.0<1>:W          -8:W                    {align1};
  537. mov  (1) vme_m0.2<1>:W          -8:W                    {align1};
  538.  
  539. and.z.f0.0 (1)          null:uw input_mb_intra_ub<0,1,0>:ub     INTRA_PRED_AVAIL_FLAG_AE:uw   {align1};
  540. (f0.0)  add     (1)     vme_m0.0<1>:w   vme_m0.0<0,1,0>:w       4:w     {align1};
  541. and.z.f0.0 (1)          null:uw input_mb_intra_ub<0,1,0>:ub     INTRA_PRED_AVAIL_FLAG_B:uw   {align1};
  542. (f0.0)  add     (1)     vme_m0.2<1>:w   vme_m0.2<0,1,0>:w       4:w     {align1};
  543.  
  544. __vme_msg:
  545. mov  (1) vme_m0.4<1>:UD         vme_m0.0<0,1,0>:UD      {align1};
  546. add  (2) vme_m0.0<1>:w          vme_m0.0<2,2,1>:w       mb_ref_win.16<2,2,1>:w  {align1};
  547. add  (2) vme_m0.4<1>:w          vme_m0.4<2,2,1>:w       mb_ref_win.16<2,2,1>:w  {align1};
  548. mov  (8) vme_msg_0.0<1>:UD      vme_m0.0<8,8,1>:UD {align1};
  549.  
  550. mov  (1) vme_m1.0<1>:UD         ADAPTIVE_SEARCH_ENABLE:ud {align1} ;
  551. /* the Max MV number is passed by constant buffer */
  552. mov  (1) vme_m1.4<1>:UB         r4.28<0,1,0>:UB {align1};          
  553. mov  (1) vme_m1.8<1>:UD         START_CENTER + SEARCH_PATH_LEN:UD {align1};
  554. /* Set the MV cost center */
  555. mov  (1) vme_m1.16<1>:ud        mb_mvp_ref.0<0,1,0>:ud  {align1};
  556. mov  (1) vme_m1.20<1>:ud        mb_mvp_ref.0<0,1,0>:ud  {align1};
  557. mov  (8) vme_msg_1.0<1>:UD      vme_m1.0<8,8,1>:UD {align1};
  558.  
  559. mov (8) vme_msg_2<1>:UD         vme_m2.0<8,8,1>:UD {align1};
  560.  
  561. send (8)
  562.        vme_msg_ind
  563.        vme_wb<1>:UD
  564.        null
  565.        vme(
  566.                BIND_IDX_VME,
  567.                0,
  568.                0,
  569.                VME_IME_MESSAGE_TYPE
  570.        )
  571.        mlen ime_vme_msg_length
  572.        rlen vme_wb_length {align1};
  573.  
  574. /* Set Macroblock-shape/mode for FBR */
  575.  
  576. mov  (1) vme_m2.20<1>:UD        0x0:UD {align1};
  577. mov  (1) vme_m2.21<1>:UB        vme_wb.25<0,1,0>:UB     {align1};
  578. mov  (1) vme_m2.22<1>:UB        vme_wb.26<0,1,0>:UB     {align1};
  579.  
  580. and  (1) tmp_reg0.0<1>:UW       vme_wb.0<0,1,0>:UW      0x03:UW {align1};
  581. mov  (1) vme_m2.20<1>:UB        tmp_reg0.0<0,1,0>:UB    {align1};
  582.  
  583. /* Send FBR message into CRE */
  584.  
  585. mov  (8) vme_msg_3.0<1>:UD       vme_wb1.0<8,8,1>:UD {align1};
  586. mov  (8) vme_msg_4.0<1>:ud       vme_wb2.0<8,8,1>:ud {align1};
  587. mov  (8) vme_msg_5.0<1>:ud       vme_wb3.0<8,8,1>:ud {align1};
  588. mov  (8) vme_msg_6.0<1>:ud       vme_wb4.0<8,8,1>:ud {align1};                
  589.  
  590. mov  (1) vme_m0.12<1>:UD        INTER_SAD_HAAR + SUB_PEL_MODE_QUARTER + FBR_BME_DISABLE:UD {align1};    /* 16x16 Source, 1/4 pixel, harr, BME disable */
  591. mov  (8) vme_msg_0.0<1>:UD      vme_m0.0<8,8,1>:UD  {align1};
  592. mov  (8) vme_msg_1.0<1>:UD      vme_m1.0<8,8,1>:UD  {align1};
  593.  
  594. mov  (8) vme_msg_2.0<1>:UD              vme_m2.0<8,8,1>:UD      {align1};
  595.  
  596. /* after verification it will be passed by using payload */
  597. send (8)
  598.        vme_msg_ind
  599.        vme_wb<1>:UD
  600.        null
  601.        cre(
  602.                BIND_IDX_VME,
  603.                VME_FBR_MESSAGE_TYPE
  604.        )
  605.        mlen fbr_vme_msg_length
  606.        rlen vme_wb_length
  607.        {align1};
  608.  
  609. add  (1) obw_m0.8<1>:UD         obw_m0.8<0,1,0>:UD 0x02:UD {align1};
  610. mov  (8) msg_reg0.0<1>:UD       obw_m0<8,8,1>:UD {align1};
  611. /* write FME info */
  612. mov  (1) msg_reg1.0<1>:UD       vme_wb.0<0,1,0>:UD      {align1};
  613.  
  614. mov  (1) msg_reg1.4<1>:UD       vme_wb.24<0,1,0>:UD     {align1};
  615. /* Inter distortion of FME */
  616. mov  (1) msg_reg1.8<1>:UD       vme_wb.8<0,1,0>:UD     {align1};
  617.  
  618. mov  (1) msg_reg1.12<1>:UD      vme_m2.20<0,1,0>:UD {align1};
  619.  
  620. /* bind index 3, write  oword (16bytes), msg type: 8(OWord Block Write) */
  621. send (16)
  622.        msg_ind
  623.        obw_wb
  624.        null
  625.        data_port(
  626.                OBW_CACHE_TYPE,
  627.                OBW_MESSAGE_TYPE,
  628.                OBW_CONTROL_0,
  629.                OBW_BIND_IDX,
  630.                OBW_WRITE_COMMIT_CATEGORY,
  631.                OBW_HEADER_PRESENT
  632.        )
  633.        mlen 2
  634.        rlen obw_wb_length
  635.        {align1};
  636.  
  637. /* Write FME/BME MV */
  638. add  (1) obw_m0.8<1>:UD         obw_m0.8<0,1,0>:UD 0x01:UD {align1};
  639. mov  (8) msg_reg0.0<1>:UD       obw_m0.0<8,8,1>:UD {align1};
  640.  
  641.  
  642. mov  (8) msg_reg1.0<1>:UD       vme_wb1.0<8,8,1>:UD {align1};
  643. mov  (8) msg_reg2.0<1>:ud       vme_wb2.0<8,8,1>:ud {align1};
  644. mov  (8) msg_reg3.0<1>:ud       vme_wb3.0<8,8,1>:ud {align1};
  645. mov  (8) msg_reg4.0<1>:ud       vme_wb4.0<8,8,1>:ud {align1};                
  646. /* bind index 3, write  8 oword (128 bytes), msg type: 8(OWord Block Write) */
  647. send (16)
  648.        msg_ind
  649.        obw_wb
  650.        null
  651.        data_port(
  652.                OBW_CACHE_TYPE,
  653.                OBW_MESSAGE_TYPE,
  654.                OBW_CONTROL_8,
  655.                OBW_BIND_IDX,
  656.                OBW_WRITE_COMMIT_CATEGORY,
  657.                OBW_HEADER_PRESENT
  658.        )
  659.        mlen 5
  660.        rlen obw_wb_length
  661.        {align1};
  662.  
  663. /* Write FME/BME RefID */
  664. add  (1) obw_m0.8<1>:UD         obw_m0.8<0,1,0>:UD 0x08:UD {align1};
  665. mov  (8) msg_reg0.0<1>:UD       obw_m0<8,8,1>:UD {align1};
  666.  
  667. mov  (8) msg_reg1.0<1>:UD       vme_wb6.0<8,8,1>:UD {align1};
  668.  
  669. /* bind index 3, write 2 oword (32bytes), msg type: 8(OWord Block Write) */
  670. send (16)
  671.        msg_ind
  672.        obw_wb
  673.        null
  674.        data_port(
  675.                OBW_CACHE_TYPE,
  676.                OBW_MESSAGE_TYPE,
  677.                OBW_CONTROL_2,
  678.                OBW_BIND_IDX,
  679.                OBW_WRITE_COMMIT_CATEGORY,
  680.                OBW_HEADER_PRESENT
  681.        )
  682.        mlen 2
  683.        rlen obw_wb_length
  684.        {align1};
  685.  
  686. /* Issue message fence so that the previous write message is committed */
  687. send (16)
  688.        mb_ind
  689.        mb_wb.0<1>:ud
  690.         NULL
  691.        data_port(
  692.                OBR_CACHE_TYPE,
  693.                OBR_MESSAGE_FENCE,
  694.                OBR_MF_COMMIT,
  695.                OBR_BIND_IDX,
  696.                OBR_WRITE_COMMIT_CATEGORY,
  697.                OBR_HEADER_PRESENT
  698.        )
  699.        mlen 1
  700.        rlen 1
  701.        {align1};
  702.  
  703. __EXIT:
  704. /*
  705. * kill thread
  706. */        
  707. mov  (8) ts_msg_reg0<1>:UD         r0<8,8,1>:UD {align1};
  708. send (16) ts_msg_ind acc0<1>UW null thread_spawner(0, 0, 1) mlen 1 rlen 0 {align1 EOT};
  709.  
  710.         nop             ;
  711.         nop             ;
  712. /* Compare three word data to get the min value */
  713. word_imin:
  714.         cmp.le.f0.0 (1)         null:w          INPUT_ARG0.0<0,1,0>:w   INPUT_ARG0.4<0,1,0>:w {align1};
  715.         (f0.0) mov  (1)         TEMP_VAR0.0<1>:w INPUT_ARG0.0<0,1,0>:w                    {align1};
  716.         (-f0.0) mov (1)         TEMP_VAR0.0<1>:w INPUT_ARG0.4<0,1,0>:w                    {align1};
  717.         cmp.le.f0.0 (1)         null:w          TEMP_VAR0.0<0,1,0>:w    INPUT_ARG0.8<0,1,0>:w {align1};
  718.         (f0.0) mov  (1)         RET_ARG<1>:w TEMP_VAR0.0<0,1,0>:w                         {align1};
  719.         (-f0.0) mov (1)         RET_ARG<1>:w INPUT_ARG0.8<0,1,0>:w                        {align1};
  720.         RETURN          {align1};      
  721.        
  722. /* Compare three word data to get the max value */
  723. word_imax:
  724.         cmp.ge.f0.0 (1)         null:w          INPUT_ARG0.0<0,1,0>:w   INPUT_ARG0.4<0,1,0>:w {align1};
  725.         (f0.0) mov  (1)         TEMP_VAR0.0<1>:w INPUT_ARG0.0<0,1,0>:w                    {align1};
  726.         (-f0.0) mov (1)         TEMP_VAR0.0<1>:w INPUT_ARG0.4<0,1,0>:w                    {align1};
  727.         cmp.ge.f0.0 (1)         null:w          TEMP_VAR0.0<0,1,0>:w    INPUT_ARG0.8<0,1,0>:w {align1};
  728.         (f0.0) mov  (1)         RET_ARG<1>:w TEMP_VAR0.0<0,1,0>:w                         {align1};
  729.         (-f0.0) mov (1)         RET_ARG<1>:w INPUT_ARG0.8<0,1,0>:w                        {align1};
  730.         RETURN          {align1};      
  731.        
  732. word_imedian:
  733.         cmp.ge.f0.0 (1) null:w INPUT_ARG0.0<0,1,0>:w INPUT_ARG0.4<0,1,0>:w {align1};
  734.         (f0.0)  jmpi (1) cmp_a_ge_b;
  735.         cmp.ge.f0.0 (1) null:w INPUT_ARG0.0<0,1,0>:w INPUT_ARG0.8<0,1,0>:w {align1};
  736.         (f0.0) mov (1) RET_ARG<1>:w INPUT_ARG0.0<0,1,0>:w {align1};
  737.         (f0.0) jmpi (1) cmp_end;
  738.         cmp.ge.f0.0 (1) null:w INPUT_ARG0.4<0,1,0>:w INPUT_ARG0.8<0,1,0>:w {align1};
  739.         (f0.0) mov (1) RET_ARG<1>:w INPUT_ARG0.8<0,1,0>:w {align1};
  740.         (-f0.0) mov (1) RET_ARG<1>:w INPUT_ARG0.4<0,1,0>:w {align1};
  741.         jmpi (1) cmp_end;
  742. cmp_a_ge_b:
  743.         cmp.ge.f0.0 (1) null:w INPUT_ARG0.4<0,1,0>:w INPUT_ARG0.8<0,1,0>:w {align1};
  744.         (f0.0) mov (1) RET_ARG<1>:w INPUT_ARG0.4<0,1,0>:w {align1};
  745.         (f0.0) jmpi (1) cmp_end;
  746.         cmp.ge.f0.0 (1) null:w INPUT_ARG0.0<0,1,0>:w INPUT_ARG0.8<0,1,0>:w {align1};
  747.         (f0.0) mov (1) RET_ARG<1>:w INPUT_ARG0.8<0,1,0>:w {align1};
  748.         (-f0.0) mov (1) RET_ARG<1>:w INPUT_ARG0.0<0,1,0>:w {align1};
  749. cmp_end:
  750.         RETURN  {align1};
  751.