WebSVN – Kolibri OS – Diff – /programs/network/ftpc/ftpc.asm


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;                                                                 ;;
;; Copyright (C) KolibriOS team 2013-2021. All rights reserved.    ;;
;; Distributed under terms of the GNU General Public License       ;;
;;                                                                 ;;
;;  ftpc.asm - FTP client for KolibriOS                            ;;
;;                                                                 ;;
;;  Written by hidnplayr@kolibrios.org                             ;;
;;  Modified by nisargshah323@gmail.com (2016)                     ;;
;;                                                                 ;;
;;          GNU GENERAL PUBLIC LICENSE                             ;;
;;             Version 2, June 1991                                ;;
;;                                                                 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 
format binary as ""
 
TIMEOUT                 = 3     ; seconds
 
BUFFERSIZE              = 4096
 
STATUS_CONNECTING       = 0
STATUS_CONNECTED        = 1
STATUS_NEEDPASSWORD     = 2
STATUS_LOGGED_IN        = 3
 
OPERATION_NONE          = 0
OPERATION_LIST          = 1
OPERATION_RETR          = 2
OPERATION_STOR          = 3
OPERATION_RDIR          = 4
        
use32
; standard header
        db      'MENUET01'      ; signature
        dd      1               ; header version
        dd      start           ; entry point
        dd      i_end           ; initialized size
        dd      mem+0x1000      ; required memory
        dd      mem+0x1000      ; stack pointer
        dd      buf_cmd         ; parameters
        dd      path            ; path
 
include '../../macros.inc'
macro ijmp reg, addr, method
{   
    mov  reg, [addr]
    add  reg, [method]
    jmp  dword[reg]
}
macro icall reg, addr, method, [arg]
{  
    mov  reg, [addr]
    add  reg, [method]
    if ~ arg eq
      pushd arg
    end if
    call dword[reg]
}
 
purge mov,add,sub
 
include '../../proc32.inc'
include '../../network.inc'
include '../../KOSfuncs.inc'
 
include 'console.inc'
include 'gui.inc'
include 'login_gui.inc'
include 'usercommands.inc'
include 'servercommands.inc'
include 'parser.inc'
 
; TODO: Add Pasta support to FTPC
 
;;================================================================================================;;
start: ;//////////////////////////////////////////////////////////////////////////////////////////;;
;;------------------------------------------------------------------------------------------------;;
;? Program entry point - initialize heap, load libraries and settings                             ;;
;;------------------------------------------------------------------------------------------------;;
;>                                                                                                ;;
;;------------------------------------------------------------------------------------------------;;
;< none                                                                                           ;;
;;================================================================================================;;
; initialize heap for using dynamic blocks
        mcall   68, 11
        test    eax, eax
        je      exit2
        
; disable all events except network event
        mcall   40, EV_STACK
; load libraries
        stdcall dll.Load, @IMPORT
        test    eax, eax
        jnz     exit
; find path to main settings file (ftpc.ini)
        mov     edi, path               ; Calculate the length of zero-terminated string
        xor     al, al
        mov     ecx, 1024
        repne   scasb
        dec     edi
        mov     esi, str_ini            ; append it with '.ini', 0
        movsd
        movsb
; get settings from ini
        invoke  ini.get_str, path, str_active, str_ip, str_active_ip, 16, 0
        mov     esi, str_active_ip
  .ip_loop:
        lodsb
        test    al, al
        jz      .ip_ok
        cmp     al, ' '
        je      .ip_ok
        cmp     al, '.'
        jne     .ip_loop
        mov     byte[esi-1], ','
        jmp     .ip_loop
  .ip_ok:
        mov     byte[esi-1], 0
 
        invoke  ini.get_int, path, str_active, str_port_start, 64000
        mov     [acti_port_start], ax
 
        invoke  ini.get_int, path, str_active, str_port_stop, 65000
        mov     [acti_port_stop], ax
 
        invoke  ini.get_str, path, str_general, str_dir, buf_buffer1, BUFFERSIZE, 0
        mcall   30, 1, buf_buffer1                      ; set working directory
 
        ; initialize log file
        invoke  ini.get_str, path, str_general, str_logfile, log_file, 512, 0
        mov     [filestruct2.subfn], 2
        mov     [filestruct2.offset], 0
        mov     [filestruct2.size], 0
        mov     [filestruct2.ptr], 0
        mov     [filestruct2.name], log_file
        mcall   70, filestruct2
 
; Usage: ftpc [-cli] [ftp://username:password@server:port/path]
 
        ; mov     dword[buf_cmd], '-cli' ;;;; to test CLI ;;;;;
 
        cmp     byte[buf_cmd], 0
        jne     @f
        mov     [interface_addr], gui
        jmp     .args_ok
  @@:   cmp     dword[buf_cmd], '-cli'
        jne     .error
        mov     [interface_addr], console
        jmp     .args_ok
 
  .args_ok:
 
        icall   eax, interface_addr, interface.init
        ; check for ftp://username:pass@server:port/path urls
        cmp     dword[buf_cmd], 'ftp:'
        je      parse_args
        cmp     dword[buf_cmd+5], 'ftp:'
        je      parse_args
        ijmp    eax, interface_addr, interface.server_addr
 
  .error:
        call    console.init
        invoke  con_write_asciiz, str_args_err
        invoke  con_getch2
        call    console.exit
        jmp     exit
 
;;================================================================================================;;
arg_handler: ;////////////////////////////////////////////////////////////////////////////////////;;
;;------------------------------------------------------------------------------------------------;;
;? Passes initial connection info from console/GUI to FTP core and the other way around           ;;
;;------------------------------------------------------------------------------------------------;;
;> esp+4 = pointer to the argument passed to the function                                         ;;
;;------------------------------------------------------------------------------------------------;;
;< none                                                                                           ;;
;;================================================================================================;;
 
  .get_username:
; request username
        ijmp    eax, interface_addr, interface.get_username
 
  .copy_user:
        mov     dword[buf_cmd], "USER"
        mov     byte[buf_cmd+4], " "
; copy user name to buf_cmd (for command line args)
        mov     edi, buf_cmd+5
        mov     esi, param_user
  @@:
        movsb
        cmp     byte [esi-1], 0
        jne     @b
        mov     word[edi-1], 0x0a0d
 
        lea     esi, [edi+1-buf_cmd]
        jmp     server_connect.send
 
  .get_pass:
        mov     dword[buf_cmd], "PASS"
        mov     byte[buf_cmd+4], " "
; copy password to buf_cmd (for command line args)
        mov     edi, buf_cmd+5
        mov     esi, param_password
  @@:
        movsb
        cmp     byte[esi-1], 0
        jne     @b
        mov     word[edi-1], 0x0a0d
 
        lea     esi, [edi+1-buf_cmd]
        jmp     server_connect.send
 
  .get_path:
; copy path from param_path to buf_cmd
        mov     dword[buf_cmd], "CWD "
        mov     edi, buf_cmd+4
        mov     esi, param_path
  @@:
        lodsb
        stosb
        cmp     al, 0x20
        ja      @b
        mov     word[edi-1], 0x0a0d
 
        lea     esi, [edi+1-buf_cmd]
        jmp     server_connect.send
 
  .connect:
        ; copy server address to buf_cmd
        mov     esi, param_server_addr
        mov     edi, buf_cmd
  @@:
        lodsb
        stosb
        cmp     al, 0x20
        ja      @r
        mov     byte[edi-1], 0 ; delete terminating '\n'
 
        cmp     [param_port], 0x20
        jbe     server_connect.default_port
        mov     esi, param_port
        jmp     server_connect.do_port
 
 
;;================================================================================================;;
server_connect: ;/////////////////////////////////////////////////////////////////////////////////;;
;;------------------------------------------------------------------------------------------------;;
;? Establishes a connection to the FTP server (common block for all interfaces)                   ;;
;? .do_port - Port is specified by the user and needs to be converted from ASCII                  ;;
;;------------------------------------------------------------------------------------------------;;
;> esi = pointer to port no.                                                                      ;;
;;------------------------------------------------------------------------------------------------;;
;< none                                                                                           ;;
;;================================================================================================;;
 
  .send:
; send username/password/path to the server
        mcall   send, [controlsocket], buf_cmd, , 0
        icall   eax, interface_addr, interface.print, str_newline
        icall   eax, interface_addr, interface.set_flags, 0x07 ; reset color
        
        jmp     wait_for_servercommand
 
; resolve port if specified
  .do_port:
        xor     eax, eax
        xor     ebx, ebx
  .portloop:
        lodsb
        cmp     al, 0x20
        jbe     .port_done
        sub     al, '0'
        jnb     @f
        mov     eax, str_err_host
        jmp     error
    @@: cmp     al, 9
        jna     @f
        mov     eax, str_err_host
        jmp     error
    @@: lea     ebx, [ebx*4 + ebx]
        shl     ebx, 1
        add     ebx, eax
        jmp     .portloop
 
  .port_done:
        xchg    bl, bh
        mov     [sockaddr1.port], bx
        jmp     .done
 
  .default_port:
        mov     [sockaddr1.port], 21 shl 8
 
  .done:
; Say to the user that we're resolving
        icall   eax, interface_addr, interface.set_flags, 0x07 ; reset color
        icall   eax, interface_addr, interface.print, str_resolve, buf_cmd
; resolve name
        push    esp     ; reserve stack place
        invoke  getaddrinfo, buf_cmd, 0, 0, esp
        pop     esi
; test for error
        test    eax, eax
        jz      @f
        mov     eax, str_err_resolve
        jmp     error
    @@:
; write results
        icall   eax, interface_addr, interface.print, str8 ; ' (',0
        mov     eax, [esi+addrinfo.ai_addr]     ; convert IP address to decimal notation
        mov     eax, [eax+sockaddr_in.sin_addr] ;
        mov     [sockaddr1.ip], eax             ;
        invoke  inet_ntoa, eax                  ;
        icall   ebx, interface_addr, interface.print, eax, str9 ; ,')',10,0
        invoke  freeaddrinfo, esi               ; free allocated memory
; open the socket
        mcall   socket, AF_INET4, SOCK_STREAM, 0
        cmp     eax, -1
        jne     @f
        mov     eax, str_err_socket
        jmp     error
    @@: mov     [controlsocket], eax
; connect to the server
        icall   eax, interface_addr, interface.print, str_connect
        mcall   connect, [controlsocket], sockaddr1, 18
        cmp     eax, -1
        jne     @f
        mov     eax, str_err_connect
        jmp     error
    @@: mov     [status], STATUS_CONNECTING
; Tell the user we're waiting for the server now.
        icall   eax, interface_addr, interface.print, str_waiting
 
; Reset 'offset' variable, it's used by the data receiver
        mov     [offset], 0
 
 
;;================================================================================================;;
wait_for_servercommand: ;/////////////////////////////////////////////////////////////////////////;;
;;------------------------------------------------------------------------------------------------;;
;? Checks if any data received from the server is present in buffer.                              ;;
;? If not, receives and processes it                                                              ;;
;;------------------------------------------------------------------------------------------------;;
;>                                                                                                ;;
;;------------------------------------------------------------------------------------------------;;
;< none                                                                                           ;;
;;================================================================================================;;
; Any commands still in our buffer?
        cmp     [offset], 0
        je      .receive                        ; nope, receive some more
        mov     esi, [offset]
        mov     edi, buf_cmd
        mov     ecx, [size]
        add     ecx, esi
        jmp     .byteloop
 
; receive socket data with timeout
  .receive:
        mcall   26, 9
        add     eax, TIMEOUT*100
        mov     [timeout], eax
  .again:
        mcall   recv, [controlsocket], buf_buffer1, BUFFERSIZE, MSG_DONTWAIT
 
 
 
 
        cmp     eax, 0
 
        jg      .got_data
        je      .closed
        cmp     ebx, EWOULDBLOCK
        jne     .sock_err
        mcall   26, 9
        mov     ebx, [timeout]
        sub     ebx, eax
        jle     .timeout
        mcall   23      ; Wait for event with timeout
        jmp     .again
 
  .sock_err:
        mov     eax, str_err_recv
        jmp     error
 
  .closed:
        mov     eax, str_err_closed
        jmp     error
 
  .timeout:
        mov     eax, str_err_timeout
        jmp     error
 
  .got_data:
        mov     [offset], 0
 
; extract commands, copy them to "buf_cmd" buffer
        lea     ecx, [eax + buf_buffer1]         ; ecx = end pointer
        mov     esi, buf_buffer1                 ; esi = current pointer
        mov     edi, buf_cmd
  .byteloop:
        cmp     esi, ecx
        jae     wait_for_servercommand
        lodsb
        cmp     al, 10                          ; excellent, we might have a command
        je      .got_command
        cmp     al, 13                          ; just ignore this byte
        je      .byteloop
        stosb
        jmp     .byteloop
  .got_command:                                 ; we have a newline check if its a command
        cmp     esi, ecx
        je      .no_more_data
        mov     [offset], esi
        sub     ecx, esi
        mov     [size], ecx
        jmp     .go_cmd
  .no_more_data:
        mov     [offset], 0
  .go_cmd:
        lea     ecx, [edi - buf_cmd]                  ; length of command
        xor     al, al
        stosb
 
        icall   eax, interface_addr, interface.set_flags, 0x03 ; change color
        icall   eax, interface_addr, interface.print, buf_cmd, str_newline
        icall   eax, interface_addr, interface.set_flags, 0x07 ; reset color
 
        jmp     server_parser                   ; parse command
 
 
 
;;================================================================================================;;
wait_for_usercommand: ;///////////////////////////////////////////////////////////////////////////;;
;;------------------------------------------------------------------------------------------------;;
;? Reads the FTP command entered by the user and compares it with valid FTP commands.             ;;
;? Jumps to appropriate handling routine in usercommands.inc                                      ;;
;;------------------------------------------------------------------------------------------------;;
;> status = socket connection status                                                              ;;
;> buf_cmd = command entered by the user                                                          ;;
;;------------------------------------------------------------------------------------------------;;
;< none                                                                                           ;;
;;================================================================================================;;
 
; Are there any files in the transfer queue?
 
        cmp     [queued], 0
        ja      transfer_queued                 ; Yes, transfer those first.
 
; change color to green for user input
        icall   eax, interface_addr, interface.set_flags, 0x0a
 
; If we are not yet connected, request username/password
 
        cmp     [status], STATUS_CONNECTED
        je      arg_handler.get_username
 
        cmp     [status], STATUS_NEEDPASSWORD
        je      arg_handler.get_pass
 
        ijmp    eax, interface_addr, interface.get_cmd
 
  .parse_cmd:
        cmp     dword[buf_cmd], "cwd "
        je      cmd_cwd
 
        cmp     dword[buf_cmd], "mkd "
        je      cmd_mkd
 
        cmp     dword[buf_cmd], "rmd "
        je      cmd_rmd
 
        cmp     dword[buf_cmd], "pwd" + 10 shl 24
        je      cmd_pwd
 
        cmp     dword[buf_cmd], "bye" + 10 shl 24
        je      cmd_bye
 
        cmp     dword[buf_cmd], "rdir"
        je      cmd_rdir
        
        cmp     byte[buf_cmd+4], " "
        jne     @f
 
        cmp     dword[buf_cmd], "lcwd"
        je      cmd_lcwd
 
        cmp     dword[buf_cmd], "retr"
        je      cmd_retr
 
        cmp     dword[buf_cmd], "stor"
        je      cmd_stor
 
        cmp     dword[buf_cmd], "dele"
        je      cmd_dele
 
  @@:
        cmp     byte[buf_cmd+4], 10
        jne     @f
 
        cmp     dword[buf_cmd], "list"
        je      cmd_list
 
        cmp     dword[buf_cmd], "help"
        je      cmd_help
 
        cmp     dword[buf_cmd], "cdup"
        je      cmd_cdup
 
        cmp     dword[buf_cmd], "abor"
        je      cmd_abor
 
  @@:
; Uh oh.. unknown command, tell the user and wait for new input
        icall   eax, interface_addr, interface.print, str_unknown
        jmp     wait_for_usercommand
 
 
; files for rdir operation are queued
transfer_queued:
 
        mov     esi, [ptr_queue]                ; always pointing to current part of ptr_fname_start
        mov     edi, buf_cmd+5                  ; always point to filename for retr command
  .build_filename:
        lodsb   
        stosb
        cmp     al, 10
        je      .get_file                       ; filename ends with character 10
        test    al, al
        jnz     .build_filename
 
        ; Error occured, we reached the end of the buffer before [queued] reached 0
        mov     [queued], 0
        mcall   68, 13, [ptr_fname]             ; free buffer
        test    eax, eax
        jz      error_heap
        jmp     wait_for_usercommand
 
  .get_file:
        mov     byte[edi], 0                    ; end filename with 0 byte
        mov     [ptr_queue], esi
        dec     [queued]
        jnz     cmd_retr
 
        mcall   68, 13, [ptr_fname]             ; free buffer
        test    eax, eax
        jz      error_heap
        jmp     cmd_retr
 
 
 
open_dataconnection:
 
        test    [mode], 1
        jnz     .active
 
        mcall   send, [controlsocket], str_PASV, str_PASV.length, 0
        ret
 
  .active:
        mcall   socket, AF_INET4, SOCK_STREAM, 0
        cmp     eax, -1
        jne     @f
        mov     eax, str_err_socket
        jmp     error
    @@: mov     [datasocket], eax
 
        mov     ax, [acti_port_start]
        xchg    al, ah
        mov     [sockaddr2.port], ax
 
        mcall   bind, [datasocket], sockaddr2, 18
        cmp     eax, -1
        jne     @f
        mov     eax, str_err_bind
        jmp     error
    @@:
 
        mcall   listen, [datasocket], 1
        cmp     eax, -1
        jne     @f
        mov     eax, str_err_listen
        jmp     error
    @@:
 
        mov     dword[buf_buffer1], 'PORT'
        mov     byte[buf_buffer1+4], ' '
        mov     edi, buf_buffer1+5
        mov     esi, str_active_ip
  .loop:
        lodsb
        test    al, al
        jz      .ip_ok
        stosb
        jmp     .loop
  .ip_ok:
        mov     al, ','
        stosb
        movzx   eax, byte[sockaddr2.port+0]
        call    dword_ascii
        mov     al, ','
        stosb
        movzx   eax, byte[sockaddr2.port+1]
        call    dword_ascii
        mov     ax, 0x0a0d
        stosw
        lea     esi, [edi - buf_buffer1]
        mcall   send, [controlsocket], buf_buffer1, , 0
 
        mcall   accept, [datasocket], sockaddr2, 18        ; time to accept the awaiting connection..
        cmp     eax, -1
        jne     @f
        mov     eax, str_err_accept
        jmp     error
    @@: push    eax
        mcall   close, [datasocket]
        pop     [datasocket]
 
        mcall   recv, [controlsocket], buf_buffer1, BUFFERSIZE, 0
 
        ret
 
; eax = input
; edi = ptr where to write
dword_ascii:
 
        push    edx ebx ecx
        mov     ebx, 10
        xor     ecx, ecx
 
       @@:
        xor     edx, edx
        div     ebx
        add     edx, '0'
        push    dx
        inc     ecx
        test    eax, eax
        jnz     @r
 
       @@:
        pop     ax
        stosb
        dec     ecx
        jnz     @r
 
        pop     ecx ebx edx
        ret
 
 
;;================================================================================================;;
write_to_file: ;//////////////////////////////////////////////////////////////////////////////////;;
;;------------------------------------------------------------------------------------------------;;
;? Writes input buffer to log file                                                                ;;
;;------------------------------------------------------------------------------------------------;;
;> eax = pointer to buffer                                                                        ;;
;> ecx = size of buffer                                                                           ;;
;;------------------------------------------------------------------------------------------------;;
;< eax = status of SF 70.3                                                                        ;;
;;================================================================================================;;
        cmp     [logfile_offset], -1 ; if offset == -1 => logging disabled
        jne     @f
        mov     eax, 0
        ret
      @@:
        mov     [filestruct2.subfn], 3
        m2m     [filestruct2.offset], [logfile_offset]
        mov     [filestruct2.size], ecx
        mov     [filestruct2.ptr], eax
        mov     [filestruct2.name], log_file
        mcall   70, filestruct2
        test    eax, eax
        jz      @f
        mov     [logfile_offset], -1 ; disable logging
        call    error_fs
        icall   ebx, interface_addr, interface.print, str_no_logging
        ret
      @@:
        mov     eax, [logfile_offset]
        add     eax, ecx
        mov     [logfile_offset], eax
        ret
 
;;================================================================================================;;
error: ;//////////////////////////////////////////////////////////////////////////////////////////;;
;;------------------------------------------------------------------------------------------------;;
;? Generic error routine. Prints the error string passed to it.                                   ;;
;;------------------------------------------------------------------------------------------------;;
;> eax = pointer to the error string                                                              ;;
;;------------------------------------------------------------------------------------------------;;
;< none                                                                                           ;;
;;================================================================================================;;
        push    eax
        icall   ebx, interface_addr, interface.set_flags, 0x0c ; print errors in red
        pop     eax
        icall   ebx, interface_addr, interface.print, eax
        jmp     wait_for_keypress
 
 
; Error handling block for filesystem errors
error_fs:
        
        cmp     eax, 12
        jne     @f
        mov     ebx, str_fs_err_12
  @@:
        cmp     eax, 11
        jne     @f
        mov     ebx, str_fs_err_11
  @@:
        cmp     eax, 10
        jne     @f
        mov     ebx, str_fs_err_10
  @@:
        cmp     eax, 9
        jne     @f
        mov     ebx, str_fs_err_9
  @@:
        cmp     eax, 8
        jne     @f
        mov     ebx, str_fs_err_8
  @@:
        cmp     eax, 7
        jne     @f
        mov     ebx, str_fs_err_7
  @@:
        cmp     eax, 6
        jne     @f
        mov     ebx, str_fs_err_6
  @@:
        cmp     eax, 5
        jne     @f
        mov     ebx, str_fs_err_5
  @@:
        cmp     eax, 3
        jne     @f
        mov     ebx, str_fs_err_3
  @@:
        cmp     eax, 2
        jne     @f
        mov     ebx, str_fs_err_2
  @@:
        mov     edi, fs_error_code
        call    dword_ascii    ; convert error code in eax to ascii
        icall   eax, interface_addr, interface.set_flags, 0x0c ; print errors in red
        icall   eax, interface_addr, interface.print, str_err_fs, fs_error_code, ebx
        mov     word[fs_error_code], '  '   ; clear error code for next time
        icall   eax, interface_addr, interface.set_flags, 0x0a
 
        ret
 
error_heap:
        icall   eax, interface_addr, interface.set_flags, 0x0c ; print errors in red
        icall   eax, interface_addr, interface.print, str_err_heap
        
wait_for_keypress:
        mcall   close, [controlsocket]
        icall   eax, interface_addr, interface.set_flags, 0x07 ; reset color to grey
        icall   eax, interface_addr, interface.print, str_push
        ijmp    eax, interface_addr, interface.error
 
exit:
        mcall   close, [controlsocket]
exit2:  
        mcall   -1
 
 
 
; data
str_title       db 'FTP client for KolibriOS',0
str_welcome     db 'FTP client for KolibriOS v0.16',10
                db 10,0
str_srv_addr    db 'Please enter ftp server address.',10,0
 
str_prompt      db '> ',0
str_resolve     db 'Resolving ',0
str_newline     db 10,0
str_err_resolve db 10,'Name resolution failed.',10,0
str_err_closed  db 10,'The connection was closed by the remote end',10,0
str_err_socket  db 10,'[75,0 socket]: Error creating a socket',10,0
str_err_bind    db 10,'[75,2 bind]: Error binding to socket',10,0
str_err_listen  db 10,'[75,3 listen]: Cannot accept incoming connections',10,0
str_err_accept  db 10,'[75,5 accept]: Error accepting a connection',10,0
str_err_recv    db 10,'[75,7 recv]: Error receiving data from server',10,0
str_err_heap    db 10,'Cannot allocate memory from heap.',10,0
str_err_timeout db 10,'Timeout - no response from server.',10,0
str_err_connect db 10,'[75,4 connect]: Cannot connect to the server.',10,0
str_err_host    db 10,'Invalid hostname.',10,0
str_err_params  db 10,'Invalid parameters',10,0
str_err_fs      db 10,'File system error: code ',0
fs_error_code   db '  ',0    ; file system error code
str_fs_err_2    db ' [Function is not supported for the given file system]',10,0
str_fs_err_3    db ' [Unknown file system]',10,0
str_fs_err_5    db ' [File/Folder not found]',10,0
str_fs_err_6    db ' [End of file, EOF]',10,0
str_fs_err_7    db ' [Pointer lies outside of application memory]',10,0
str_fs_err_8    db ' [Disk is full]',10,0
str_fs_err_9    db ' [File system error]',10,0
str_fs_err_10   db ' [Access denied]',10,0
str_fs_err_11   db ' [Device error]',10,0
str_fs_err_12   db ' [File system requires more memory]',10,0
str8            db ' (',0
str9            db ')',10,0
str_push        db 'Push any key to continue.',0
str_connect     db 'Connecting...',10,0
str_waiting     db 'Waiting for welcome message.',10,0
str_user        db "username: ",0
str_pass        db "password: ",0
str_port        db "port (default 21): ",0
str_path        db "path (optional): ",0
str_unknown     db "Unknown command or insufficient parameters - type help for more information.",10,0
str_lcwd        db "Local working directory is now: ",0
str_bytes_done  db '          ',0
str_downloaded  db 'Downloaded ',0
str_bytes       db ' bytes',13,0
str_args_err    db 'Invalid arguments. USAGE: ftpc [-cli] [ftp://username:password@server:port/path]',10,0
 
str_open        db "opening data socket",10,0
str_close       db 10,"closing data socket",10,0
str_dot         db '.',0
 
str_help        db "available commands:",10
                db 10
                db "bye             - close the connection",10
                db "cdup            - change to parent of current directory on the server",10
                db "cwd  - change working directoy on the server",10
                db "dele      - delete file from the server",10
                db "list            - list files and folders in current server directory",10
                db "lcwd      - change local working directory",10
                db "mkd  - make directory on the server",10
                db "pwd             - print server working directory",10
                db "retr      - retreive file from the server",10
                db "rmd  - remove directory from the server",10
                db "stor      - store file on the server",10
                db "rdir            - retreive all files from current server dir",10
                db 10,0
 
str_ini         db '.ini', 0
str_active      db 'active', 0
str_port_start  db 'port_start', 0
str_port_stop   db 'port_stop', 0
str_ip          db 'ip', 0
str_dir         db 'dir', 0
str_general     db 'general', 0
str_logfile     db 'logfile',0
str_no_logging  db 'Error writing to log file. Logging disabled',0
 
queued          dd 0
mode            db 0    ; passive = 0, active = 1
 
 
; FTP strings
 
str_PASV        db 'PASV',13,10
.length = $ - str_PASV
 
sockaddr1:
        dw AF_INET4
.port   dw ?
.ip     dd ?
        rb 10
 
sockaddr2:
        dw AF_INET4
.port   dw ?
.ip     dd ?
        rb 10
 
struc interface
{
    .init           dd 0
    .server_addr    dd 4
    .get_username   dd 8
    .get_cmd        dd 12
    .print          dd 16
    .set_flags      dd 20
    .list           dd 24
    .progress       dd 28
    .error          dd 32
}
interface interface
 
; import
align 4
@IMPORT:
 
library network, 'network.obj', libini, 'libini.obj'
 
import  network, \
        getaddrinfo,    'getaddrinfo', \
        freeaddrinfo,   'freeaddrinfo', \
        inet_ntoa,      'inet_ntoa'
 
import  libini, \
        ini.get_str,    'ini_get_str', \
        ini.get_int,    'ini_get_int'
 
param_user:     db 'anonymous',0
rb 60
 
param_server_addr db 'kolibrios.org'
rb 1024
 
align 4
i_end:
; uninitialised data
 
run_file_70 FileInfoBlock ; required for libimg
 
new_dir_buf rb 64
folder_data rb 32+32*304
 
remote_list_buf rb 1024
file_name   rb 4096 ; required for libimg
conv_tabl   rb 128
ed_buffer   rb 100
tedit_buffer rb 1024
el_focus    dd ?
;-----------------------
 
procinfo        process_information
 
interface_addr  rd 1
 
status          db ?
 
file_size       dd ?
 
controlsocket   dd ?
datasocket      dd ?
offset          dd ?
size            dd ?
operation       dd ?
timeout         dd ?
 
ptr_fname       dd ?
size_fname      dd ?
ptr_queue       dd ?
 
acti_port_start dw ?
acti_port_stop  dw ?
acti_port       dw ?
 
str_active_ip   rb 16
 
filestruct:
  .subfn        dd ?
  .offset       dd ?
                dd ?
  .size         dd ?
  .ptr          dd ?
  .name         rb 1024
 
filestruct2:
  .subfn        dd ?
  .offset       dd ?
                dd ?
  .size         dd ?
  .ptr          dd ?
                db ?
  .name         dd ?
 
folder_buf      rb 40
 
 
buf_buffer1     rb BUFFERSIZE+1
buf_buffer2     rb BUFFERSIZE+1
buf_cmd         rb 1024                 ; buffer for holding command string
log_file        rb 512 ; holds log file path
logfile_offset  rd 1 
 
path            rb 1024
 
initial_login   rb 1
 
param_password  rb 1024
 
param_path      rb 1024
param_port      rb 6
 
sc system_colors
rb 1024
 
mem:

Rev 8442	Rev 9164
1	;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;	1	;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2	;; ;;	2	;; ;;
3	;; Copyright (C) KolibriOS team 2013-2018. All rights reserved. ;;	3	;; Copyright (C) KolibriOS team 2013-2021. All rights reserved. ;;
4	;; Distributed under terms of the GNU General Public License ;;	4	;; Distributed under terms of the GNU General Public License ;;
5	;; ;;	5	;; ;;
6	;; ftpc.asm - FTP client for KolibriOS ;;	6	;; ftpc.asm - FTP client for KolibriOS ;;
7	;; ;;	7	;; ;;
8	;; Written by hidnplayr@kolibrios.org ;;	8	;; Written by hidnplayr@kolibrios.org ;;
9	;; Modified by nisargshah323@gmail.com (2016) ;;	9	;; Modified by nisargshah323@gmail.com (2016) ;;
10	;; ;;	10	;; ;;
11	;; GNU GENERAL PUBLIC LICENSE ;;	11	;; GNU GENERAL PUBLIC LICENSE ;;
12	;; Version 2, June 1991 ;;	12	;; Version 2, June 1991 ;;
13	;; ;;	13	;; ;;
14	;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;	14	;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
15		15
16	format binary as ""	16	format binary as ""
17		17
18	TIMEOUT = 3 ; seconds	18	TIMEOUT = 3 ; seconds
19		19
20	BUFFERSIZE = 4096	20	BUFFERSIZE = 4096
21		21
22	STATUS_CONNECTING = 0	22	STATUS_CONNECTING = 0
23	STATUS_CONNECTED = 1	23	STATUS_CONNECTED = 1
24	STATUS_NEEDPASSWORD = 2	24	STATUS_NEEDPASSWORD = 2
25	STATUS_LOGGED_IN = 3	25	STATUS_LOGGED_IN = 3
26		26
27	OPERATION_NONE = 0	27	OPERATION_NONE = 0
28	OPERATION_LIST = 1	28	OPERATION_LIST = 1
29	OPERATION_RETR = 2	29	OPERATION_RETR = 2
30	OPERATION_STOR = 3	30	OPERATION_STOR = 3
31	OPERATION_RDIR = 4	31	OPERATION_RDIR = 4
32		32
33	use32	33	use32
34	; standard header	34	; standard header
35	db 'MENUET01' ; signature	35	db 'MENUET01' ; signature
36	dd 1 ; header version	36	dd 1 ; header version
37	dd start ; entry point	37	dd start ; entry point
38	dd i_end ; initialized size	38	dd i_end ; initialized size
39	dd mem+0x1000 ; required memory	39	dd mem+0x1000 ; required memory
40	dd mem+0x1000 ; stack pointer	40	dd mem+0x1000 ; stack pointer
41	dd buf_cmd ; parameters	41	dd buf_cmd ; parameters
42	dd path ; path	42	dd path ; path
43		43
44	include '../../macros.inc'	44	include '../../macros.inc'
45	macro ijmp reg, addr, method	45	macro ijmp reg, addr, method
46	{	46	{
47	mov reg, [addr]	47	mov reg, [addr]
48	add reg, [method]	48	add reg, [method]
49	jmp dword[reg]	49	jmp dword[reg]
50	}	50	}
51	macro icall reg, addr, method, [arg]	51	macro icall reg, addr, method, [arg]
52	{	52	{
53	mov reg, [addr]	53	mov reg, [addr]
54	add reg, [method]	54	add reg, [method]
55	if ~ arg eq	55	if ~ arg eq
56	pushd arg	56	pushd arg
57	end if	57	end if
58	call dword[reg]	58	call dword[reg]
59	}	59	}
60		60
61	purge mov,add,sub	61	purge mov,add,sub
62		62
63	include '../../proc32.inc'	63	include '../../proc32.inc'
64	include '../../network.inc'	64	include '../../network.inc'
65	include '../../KOSfuncs.inc'	65	include '../../KOSfuncs.inc'
66		66
67	include 'console.inc'	67	include 'console.inc'
68	include 'gui.inc'	68	include 'gui.inc'
69	include 'login_gui.inc'	69	include 'login_gui.inc'
70	include 'usercommands.inc'	70	include 'usercommands.inc'
71	include 'servercommands.inc'	71	include 'servercommands.inc'
72	include 'parser.inc'	72	include 'parser.inc'
73		73
74	; TODO: Add Pasta support to FTPC	74	; TODO: Add Pasta support to FTPC
75		75
76	;;================================================================================================;;	76	;;================================================================================================;;
77	start: ;//////////////////////////////////////////////////////////////////////////////////////////;;	77	start: ;//////////////////////////////////////////////////////////////////////////////////////////;;
78	;;------------------------------------------------------------------------------------------------;;	78	;;------------------------------------------------------------------------------------------------;;
79	;? Program entry point - initialize heap, load libraries and settings ;;	79	;? Program entry point - initialize heap, load libraries and settings ;;
80	;;------------------------------------------------------------------------------------------------;;	80	;;------------------------------------------------------------------------------------------------;;
81	;> ;;	81	;> ;;
82	;;------------------------------------------------------------------------------------------------;;	82	;;------------------------------------------------------------------------------------------------;;
83	;< none ;;	83	;< none ;;
84	;;================================================================================================;;	84	;;================================================================================================;;
85	; initialize heap for using dynamic blocks	85	; initialize heap for using dynamic blocks
86	mcall 68, 11	86	mcall 68, 11
87	test eax, eax	87	test eax, eax
88	je exit2	88	je exit2
89		89
90	; disable all events except network event	90	; disable all events except network event
91	mcall 40, EV_STACK	91	mcall 40, EV_STACK
92	; load libraries	92	; load libraries
93	stdcall dll.Load, @IMPORT	93	stdcall dll.Load, @IMPORT
94	test eax, eax	94	test eax, eax
95	jnz exit	95	jnz exit
96	; find path to main settings file (ftpc.ini)	96	; find path to main settings file (ftpc.ini)
97	mov edi, path ; Calculate the length of zero-terminated string	97	mov edi, path ; Calculate the length of zero-terminated string
98	xor al, al	98	xor al, al
99	mov ecx, 1024	99	mov ecx, 1024
100	repne scasb	100	repne scasb
101	dec edi	101	dec edi
102	mov esi, str_ini ; append it with '.ini', 0	102	mov esi, str_ini ; append it with '.ini', 0
103	movsd	103	movsd
104	movsb	104	movsb
105	; get settings from ini	105	; get settings from ini
106	invoke ini.get_str, path, str_active, str_ip, str_active_ip, 16, 0	106	invoke ini.get_str, path, str_active, str_ip, str_active_ip, 16, 0
107	mov esi, str_active_ip	107	mov esi, str_active_ip
108	.ip_loop:	108	.ip_loop:
109	lodsb	109	lodsb
110	test al, al	110	test al, al
111	jz .ip_ok	111	jz .ip_ok
112	cmp al, ' '	112	cmp al, ' '
113	je .ip_ok	113	je .ip_ok
114	cmp al, '.'	114	cmp al, '.'
115	jne .ip_loop	115	jne .ip_loop
116	mov byte[esi-1], ','	116	mov byte[esi-1], ','
117	jmp .ip_loop	117	jmp .ip_loop
118	.ip_ok:	118	.ip_ok:
119	mov byte[esi-1], 0	119	mov byte[esi-1], 0
120		120
121	invoke ini.get_int, path, str_active, str_port_start, 64000	121	invoke ini.get_int, path, str_active, str_port_start, 64000
122	mov [acti_port_start], ax	122	mov [acti_port_start], ax
123		123
124	invoke ini.get_int, path, str_active, str_port_stop, 65000	124	invoke ini.get_int, path, str_active, str_port_stop, 65000
125	mov [acti_port_stop], ax	125	mov [acti_port_stop], ax
126		126
127	invoke ini.get_str, path, str_general, str_dir, buf_buffer1, BUFFERSIZE, 0	127	invoke ini.get_str, path, str_general, str_dir, buf_buffer1, BUFFERSIZE, 0
128	mcall 30, 1, buf_buffer1 ; set working directory	128	mcall 30, 1, buf_buffer1 ; set working directory
129		129
130	; initialize log file	130	; initialize log file
131	invoke ini.get_str, path, str_general, str_logfile, log_file, 512, 0	131	invoke ini.get_str, path, str_general, str_logfile, log_file, 512, 0
132	mov [filestruct2.subfn], 2	132	mov [filestruct2.subfn], 2
133	mov [filestruct2.offset], 0	133	mov [filestruct2.offset], 0
134	mov [filestruct2.size], 0	134	mov [filestruct2.size], 0
135	mov [filestruct2.ptr], 0	135	mov [filestruct2.ptr], 0
136	mov [filestruct2.name], log_file	136	mov [filestruct2.name], log_file
137	mcall 70, filestruct2	137	mcall 70, filestruct2
138		138
139	; Usage: ftpc [-cli] [ftp://username:password@server:port/path]	139	; Usage: ftpc [-cli] [ftp://username:password@server:port/path]
140		140
141	; mov dword[buf_cmd], '-cli' ;;;; to test CLI ;;;;;	141	; mov dword[buf_cmd], '-cli' ;;;; to test CLI ;;;;;
142		142
143	cmp byte[buf_cmd], 0	143	cmp byte[buf_cmd], 0
144	jne @f	144	jne @f
145	mov [interface_addr], gui	145	mov [interface_addr], gui
146	jmp .args_ok	146	jmp .args_ok
147	@@: cmp dword[buf_cmd], '-cli'	147	@@: cmp dword[buf_cmd], '-cli'
148	jne .error	148	jne .error
149	mov [interface_addr], console	149	mov [interface_addr], console
150	jmp .args_ok	150	jmp .args_ok
151		151
152	.args_ok:	152	.args_ok:
153		153
154	icall eax, interface_addr, interface.init	154	icall eax, interface_addr, interface.init
155	; check for ftp://username:pass@server:port/path urls	155	; check for ftp://username:pass@server:port/path urls
156	cmp dword[buf_cmd], 'ftp:'	156	cmp dword[buf_cmd], 'ftp:'
157	je parse_args	157	je parse_args
158	cmp dword[buf_cmd+5], 'ftp:'	158	cmp dword[buf_cmd+5], 'ftp:'
159	je parse_args	159	je parse_args
160	ijmp eax, interface_addr, interface.server_addr	160	ijmp eax, interface_addr, interface.server_addr
161		161
162	.error:	162	.error:
163	call console.init	163	call console.init
164	invoke con_write_asciiz, str_args_err	164	invoke con_write_asciiz, str_args_err
165	invoke con_getch2	165	invoke con_getch2
166	call console.exit	166	call console.exit
167	jmp exit	167	jmp exit
168		168
169	;;================================================================================================;;	169	;;================================================================================================;;
170	arg_handler: ;////////////////////////////////////////////////////////////////////////////////////;;	170	arg_handler: ;////////////////////////////////////////////////////////////////////////////////////;;
171	;;------------------------------------------------------------------------------------------------;;	171	;;------------------------------------------------------------------------------------------------;;
172	;? Passes initial connection info from console/GUI to FTP core and the other way around ;;	172	;? Passes initial connection info from console/GUI to FTP core and the other way around ;;
173	;;------------------------------------------------------------------------------------------------;;	173	;;------------------------------------------------------------------------------------------------;;
174	;> esp+4 = pointer to the argument passed to the function ;;	174	;> esp+4 = pointer to the argument passed to the function ;;
175	;;------------------------------------------------------------------------------------------------;;	175	;;------------------------------------------------------------------------------------------------;;
176	;< none ;;	176	;< none ;;
177	;;================================================================================================;;	177	;;================================================================================================;;
178		178
179	.get_username:	179	.get_username:
180	; request username	180	; request username
181	ijmp eax, interface_addr, interface.get_username	181	ijmp eax, interface_addr, interface.get_username
182		182
183	.copy_user:	183	.copy_user:
184	mov dword[buf_cmd], "USER"	184	mov dword[buf_cmd], "USER"
185	mov byte[buf_cmd+4], " "	185	mov byte[buf_cmd+4], " "
186	; copy user name to buf_cmd (for command line args)	186	; copy user name to buf_cmd (for command line args)
187	mov edi, buf_cmd+5	187	mov edi, buf_cmd+5
188	mov esi, param_user	188	mov esi, param_user
189	@@:	189	@@:
190	movsb	190	movsb
191	cmp byte [esi-1], 0	191	cmp byte [esi-1], 0
192	jne @b	192	jne @b
193	mov word[edi-1], 0x0a0d	193	mov word[edi-1], 0x0a0d
194		194
195	lea esi, [edi+1-buf_cmd]	195	lea esi, [edi+1-buf_cmd]
196	jmp server_connect.send	196	jmp server_connect.send
197		197
198	.get_pass:	198	.get_pass:
199	mov dword[buf_cmd], "PASS"	199	mov dword[buf_cmd], "PASS"
200	mov byte[buf_cmd+4], " "	200	mov byte[buf_cmd+4], " "
201	; copy password to buf_cmd (for command line args)	201	; copy password to buf_cmd (for command line args)
202	mov edi, buf_cmd+5	202	mov edi, buf_cmd+5
203	mov esi, param_password	203	mov esi, param_password
204	@@:	204	@@:
205	movsb	205	movsb
206	cmp byte[esi-1], 0	206	cmp byte[esi-1], 0
207	jne @b	207	jne @b
208	mov word[edi-1], 0x0a0d	208	mov word[edi-1], 0x0a0d
209		209
210	lea esi, [edi+1-buf_cmd]	210	lea esi, [edi+1-buf_cmd]
211	jmp server_connect.send	211	jmp server_connect.send
212		212
213	.get_path:	213	.get_path:
214	; copy path from param_path to buf_cmd	214	; copy path from param_path to buf_cmd
215	mov dword[buf_cmd], "CWD "	215	mov dword[buf_cmd], "CWD "
216	mov edi, buf_cmd+4	216	mov edi, buf_cmd+4
217	mov esi, param_path	217	mov esi, param_path
218	@@:	218	@@:
219	lodsb	219	lodsb
220	stosb	220	stosb
221	cmp al, 0x20	221	cmp al, 0x20
222	ja @b	222	ja @b
223	mov word[edi-1], 0x0a0d	223	mov word[edi-1], 0x0a0d
224		224
225	lea esi, [edi+1-buf_cmd]	225	lea esi, [edi+1-buf_cmd]
226	jmp server_connect.send	226	jmp server_connect.send
227		227
228	.connect:	228	.connect:
229	; copy server address to buf_cmd	229	; copy server address to buf_cmd
230	mov esi, param_server_addr	230	mov esi, param_server_addr
231	mov edi, buf_cmd	231	mov edi, buf_cmd
232	@@:	232	@@:
233	lodsb	233	lodsb
234	stosb	234	stosb
235	cmp al, 0x20	235	cmp al, 0x20
236	ja @r	236	ja @r
237	mov byte[edi-1], 0 ; delete terminating '\n'	237	mov byte[edi-1], 0 ; delete terminating '\n'
238		238
239	cmp [param_port], 0x20	239	cmp [param_port], 0x20
240	jbe server_connect.default_port	240	jbe server_connect.default_port
241	mov esi, param_port	241	mov esi, param_port
242	jmp server_connect.do_port	242	jmp server_connect.do_port
243		243
244		244
245	;;================================================================================================;;	245	;;================================================================================================;;
246	server_connect: ;/////////////////////////////////////////////////////////////////////////////////;;	246	server_connect: ;/////////////////////////////////////////////////////////////////////////////////;;
247	;;------------------------------------------------------------------------------------------------;;	247	;;------------------------------------------------------------------------------------------------;;
248	;? Establishes a connection to the FTP server (common block for all interfaces) ;;	248	;? Establishes a connection to the FTP server (common block for all interfaces) ;;
249	;? .do_port - Port is specified by the user and needs to be converted from ASCII ;;	249	;? .do_port - Port is specified by the user and needs to be converted from ASCII ;;
250	;;------------------------------------------------------------------------------------------------;;	250	;;------------------------------------------------------------------------------------------------;;
251	;> esi = pointer to port no. ;;	251	;> esi = pointer to port no. ;;
252	;;------------------------------------------------------------------------------------------------;;	252	;;------------------------------------------------------------------------------------------------;;
253	;< none ;;	253	;< none ;;
254	;;================================================================================================;;	254	;;================================================================================================;;
255		255
256	.send:	256	.send:
257	; send username/password/path to the server	257	; send username/password/path to the server
258	mcall send, [controlsocket], buf_cmd, , 0	258	mcall send, [controlsocket], buf_cmd, , 0
259	icall eax, interface_addr, interface.print, str_newline	259	icall eax, interface_addr, interface.print, str_newline
260	icall eax, interface_addr, interface.set_flags, 0x07 ; reset color	260	icall eax, interface_addr, interface.set_flags, 0x07 ; reset color
261		261
262	jmp wait_for_servercommand	262	jmp wait_for_servercommand
263		263
264	; resolve port if specified	264	; resolve port if specified
265	.do_port:	265	.do_port:
266	xor eax, eax	266	xor eax, eax
267	xor ebx, ebx	267	xor ebx, ebx
268	.portloop:	268	.portloop:
269	lodsb	269	lodsb
270	cmp al, 0x20	270	cmp al, 0x20
271	jbe .port_done	271	jbe .port_done
272	sub al, '0'	272	sub al, '0'
273	jnb @f	273	jnb @f
274	mov eax, str_err_host	274	mov eax, str_err_host
275	jmp error	275	jmp error
276	@@: cmp al, 9	276	@@: cmp al, 9
277	jna @f	277	jna @f
278	mov eax, str_err_host	278	mov eax, str_err_host
279	jmp error	279	jmp error
280	@@: lea ebx, [ebx*4 + ebx]	280	@@: lea ebx, [ebx*4 + ebx]
281	shl ebx, 1	281	shl ebx, 1
282	add ebx, eax	282	add ebx, eax
283	jmp .portloop	283	jmp .portloop
284		284
285	.port_done:	285	.port_done:
286	xchg bl, bh	286	xchg bl, bh
287	mov [sockaddr1.port], bx	287	mov [sockaddr1.port], bx
288	jmp .done	288	jmp .done
289		289
290	.default_port:	290	.default_port:
291	mov [sockaddr1.port], 21 shl 8	291	mov [sockaddr1.port], 21 shl 8
292		292
293	.done:	293	.done:
294	; Say to the user that we're resolving	294	; Say to the user that we're resolving
295	icall eax, interface_addr, interface.set_flags, 0x07 ; reset color	295	icall eax, interface_addr, interface.set_flags, 0x07 ; reset color
296	icall eax, interface_addr, interface.print, str_resolve, buf_cmd	296	icall eax, interface_addr, interface.print, str_resolve, buf_cmd
297	; resolve name	297	; resolve name
298	push esp ; reserve stack place	298	push esp ; reserve stack place
299	invoke getaddrinfo, buf_cmd, 0, 0, esp	299	invoke getaddrinfo, buf_cmd, 0, 0, esp
300	pop esi	300	pop esi
301	; test for error	301	; test for error
302	test eax, eax	302	test eax, eax
303	jz @f	303	jz @f
304	mov eax, str_err_resolve	304	mov eax, str_err_resolve
305	jmp error	305	jmp error
306	@@:	306	@@:
307	; write results	307	; write results
308	icall eax, interface_addr, interface.print, str8 ; ' (',0	308	icall eax, interface_addr, interface.print, str8 ; ' (',0
309	mov eax, [esi+addrinfo.ai_addr] ; convert IP address to decimal notation	309	mov eax, [esi+addrinfo.ai_addr] ; convert IP address to decimal notation
310	mov eax, [eax+sockaddr_in.sin_addr] ;	310	mov eax, [eax+sockaddr_in.sin_addr] ;
311	mov [sockaddr1.ip], eax ;	311	mov [sockaddr1.ip], eax ;
312	invoke inet_ntoa, eax ;	312	invoke inet_ntoa, eax ;
313	icall ebx, interface_addr, interface.print, eax, str9 ; ,')',10,0	313	icall ebx, interface_addr, interface.print, eax, str9 ; ,')',10,0
314	invoke freeaddrinfo, esi ; free allocated memory	314	invoke freeaddrinfo, esi ; free allocated memory
315	; open the socket	315	; open the socket
316	mcall socket, AF_INET4, SOCK_STREAM, 0	316	mcall socket, AF_INET4, SOCK_STREAM, 0
317	cmp eax, -1	317	cmp eax, -1
318	jne @f	318	jne @f
319	mov eax, str_err_socket	319	mov eax, str_err_socket
320	jmp error	320	jmp error
321	@@: mov [controlsocket], eax	321	@@: mov [controlsocket], eax
322	; connect to the server	322	; connect to the server
323	icall eax, interface_addr, interface.print, str_connect	323	icall eax, interface_addr, interface.print, str_connect
324	mcall connect, [controlsocket], sockaddr1, 18	324	mcall connect, [controlsocket], sockaddr1, 18
325	cmp eax, -1	325	cmp eax, -1
326	jne @f	326	jne @f
327	mov eax, str_err_connect	327	mov eax, str_err_connect
328	jmp error	328	jmp error
329	@@: mov [status], STATUS_CONNECTING	329	@@: mov [status], STATUS_CONNECTING
330	; Tell the user we're waiting for the server now.	330	; Tell the user we're waiting for the server now.
331	icall eax, interface_addr, interface.print, str_waiting	331	icall eax, interface_addr, interface.print, str_waiting
332		332
333	; Reset 'offset' variable, it's used by the data receiver	333	; Reset 'offset' variable, it's used by the data receiver
334	mov [offset], 0	334	mov [offset], 0
335		335
336		336
337	;;================================================================================================;;	337	;;================================================================================================;;
338	wait_for_servercommand: ;/////////////////////////////////////////////////////////////////////////;;	338	wait_for_servercommand: ;/////////////////////////////////////////////////////////////////////////;;
339	;;------------------------------------------------------------------------------------------------;;	339	;;------------------------------------------------------------------------------------------------;;
340	;? Checks if any data received from the server is present in buffer. ;;	340	;? Checks if any data received from the server is present in buffer. ;;
341	;? If not, receives and processes it ;;	341	;? If not, receives and processes it ;;
342	;;------------------------------------------------------------------------------------------------;;	342	;;------------------------------------------------------------------------------------------------;;
343	;> ;;	343	;> ;;
344	;;------------------------------------------------------------------------------------------------;;	344	;;------------------------------------------------------------------------------------------------;;
345	;< none ;;	345	;< none ;;
346	;;================================================================================================;;	346	;;================================================================================================;;
347	; Any commands still in our buffer?	347	; Any commands still in our buffer?
348	cmp [offset], 0	348	cmp [offset], 0
349	je .receive ; nope, receive some more	349	je .receive ; nope, receive some more
350	mov esi, [offset]	350	mov esi, [offset]
351	mov edi, buf_cmd	351	mov edi, buf_cmd
352	mov ecx, [size]	352	mov ecx, [size]
353	add ecx, esi	353	add ecx, esi
354	jmp .byteloop	354	jmp .byteloop
355		355
356	; receive socket data	356	; receive socket data with timeout
357	.receive:	357	.receive:
358	mcall 26, 9	358	mcall 26, 9
359	add eax, TIMEOUT*100	359	add eax, TIMEOUT*100
360	mov [timeout], eax	360	mov [timeout], eax
361	.receive_loop:	361	.again:
362	mcall 23, 50 ; Wait for event with timeout	362	mcall recv, [controlsocket], buf_buffer1, BUFFERSIZE, MSG_DONTWAIT
363	mcall 26, 9	-
364	cmp eax, [timeout]	-
365	jl @f	-
366	mov eax, str_err_timeout	-
367	jmp error	363	cmp eax, 0
368	@@: mcall recv, [controlsocket], buf_buffer1, BUFFERSIZE, MSG_DONTWAIT	-
369	test eax, eax	364	jg .got_data
370	jnz .got_data	365	je .closed
371	cmp ebx, EWOULDBLOCK	366	cmp ebx, EWOULDBLOCK
-		367	jne .sock_err
-		368	mcall 26, 9
-		369	mov ebx, [timeout]
-		370	sub ebx, eax
-		371	jle .timeout
-		372	mcall 23 ; Wait for event with timeout
372	je @f	373	jmp .again
-		374
-		375	.sock_err:
373	mov eax, str_err_recv	376	mov eax, str_err_recv
374	jmp error	377	jmp error
-		378
-		379	.closed:
-		380	mov eax, str_err_closed
375	@@: jmp .receive_loop	381	jmp error
-		382
-		383	.timeout:
-		384	mov eax, str_err_timeout
-		385	jmp error
376		386
377	.got_data:	387	.got_data:
378	mov [offset], 0	388	mov [offset], 0
379		389
380	; extract commands, copy them to "buf_cmd" buffer	390	; extract commands, copy them to "buf_cmd" buffer
381	lea ecx, [eax + buf_buffer1] ; ecx = end pointer	391	lea ecx, [eax + buf_buffer1] ; ecx = end pointer
382	mov esi, buf_buffer1 ; esi = current pointer	392	mov esi, buf_buffer1 ; esi = current pointer
383	mov edi, buf_cmd	393	mov edi, buf_cmd
384	.byteloop:	394	.byteloop:
385	cmp esi, ecx	395	cmp esi, ecx
386	jae wait_for_servercommand	396	jae wait_for_servercommand
387	lodsb	397	lodsb
388	cmp al, 10 ; excellent, we might have a command	398	cmp al, 10 ; excellent, we might have a command
389	je .got_command	399	je .got_command
390	cmp al, 13 ; just ignore this byte	400	cmp al, 13 ; just ignore this byte
391	je .byteloop	401	je .byteloop
392	stosb	402	stosb
393	jmp .byteloop	403	jmp .byteloop
394	.got_command: ; we have a newline check if its a command	404	.got_command: ; we have a newline check if its a command
395	cmp esi, ecx	405	cmp esi, ecx
396	je .no_more_data	406	je .no_more_data
397	mov [offset], esi	407	mov [offset], esi
398	sub ecx, esi	408	sub ecx, esi
399	mov [size], ecx	409	mov [size], ecx
400	jmp .go_cmd	410	jmp .go_cmd
401	.no_more_data:	411	.no_more_data:
402	mov [offset], 0	412	mov [offset], 0
403	.go_cmd:	413	.go_cmd:
404	lea ecx, [edi - buf_cmd] ; length of command	414	lea ecx, [edi - buf_cmd] ; length of command
405	xor al, al	415	xor al, al
406	stosb	416	stosb
407		417
408	icall eax, interface_addr, interface.set_flags, 0x03 ; change color	418	icall eax, interface_addr, interface.set_flags, 0x03 ; change color
409	icall eax, interface_addr, interface.print, buf_cmd, str_newline	419	icall eax, interface_addr, interface.print, buf_cmd, str_newline
410	icall eax, interface_addr, interface.set_flags, 0x07 ; reset color	420	icall eax, interface_addr, interface.set_flags, 0x07 ; reset color
411		421
412	jmp server_parser ; parse command	422	jmp server_parser ; parse command
413		423
414		424
415		425
416	;;================================================================================================;;	426	;;================================================================================================;;
417	wait_for_usercommand: ;///////////////////////////////////////////////////////////////////////////;;	427	wait_for_usercommand: ;///////////////////////////////////////////////////////////////////////////;;
418	;;------------------------------------------------------------------------------------------------;;	428	;;------------------------------------------------------------------------------------------------;;
419	;? Reads the FTP command entered by the user and compares it with valid FTP commands. ;;	429	;? Reads the FTP command entered by the user and compares it with valid FTP commands. ;;
420	;? Jumps to appropriate handling routine in usercommands.inc ;;	430	;? Jumps to appropriate handling routine in usercommands.inc ;;
421	;;------------------------------------------------------------------------------------------------;;	431	;;------------------------------------------------------------------------------------------------;;
422	;> status = socket connection status ;;	432	;> status = socket connection status ;;
423	;> buf_cmd = command entered by the user ;;	433	;> buf_cmd = command entered by the user ;;
424	;;------------------------------------------------------------------------------------------------;;	434	;;------------------------------------------------------------------------------------------------;;
425	;< none ;;	435	;< none ;;
426	;;================================================================================================;;	436	;;================================================================================================;;
427		437
428	; Are there any files in the transfer queue?	438	; Are there any files in the transfer queue?
429		439
430	cmp [queued], 0	440	cmp [queued], 0
431	ja transfer_queued ; Yes, transfer those first.	441	ja transfer_queued ; Yes, transfer those first.
432		442
433	; change color to green for user input	443	; change color to green for user input
434	icall eax, interface_addr, interface.set_flags, 0x0a	444	icall eax, interface_addr, interface.set_flags, 0x0a
435		445
436	; If we are not yet connected, request username/password	446	; If we are not yet connected, request username/password
437		447
438	cmp [status], STATUS_CONNECTED	448	cmp [status], STATUS_CONNECTED
439	je arg_handler.get_username	449	je arg_handler.get_username
440		450
441	cmp [status], STATUS_NEEDPASSWORD	451	cmp [status], STATUS_NEEDPASSWORD
442	je arg_handler.get_pass	452	je arg_handler.get_pass
443		453
444	ijmp eax, interface_addr, interface.get_cmd	454	ijmp eax, interface_addr, interface.get_cmd
445		455
446	.parse_cmd:	456	.parse_cmd:
447	cmp dword[buf_cmd], "cwd "	457	cmp dword[buf_cmd], "cwd "
448	je cmd_cwd	458	je cmd_cwd
449		459
450	cmp dword[buf_cmd], "mkd "	460	cmp dword[buf_cmd], "mkd "
451	je cmd_mkd	461	je cmd_mkd
452		462
453	cmp dword[buf_cmd], "rmd "	463	cmp dword[buf_cmd], "rmd "
454	je cmd_rmd	464	je cmd_rmd
455		465
456	cmp dword[buf_cmd], "pwd" + 10 shl 24	466	cmp dword[buf_cmd], "pwd" + 10 shl 24
457	je cmd_pwd	467	je cmd_pwd
458		468
459	cmp dword[buf_cmd], "bye" + 10 shl 24	469	cmp dword[buf_cmd], "bye" + 10 shl 24
460	je cmd_bye	470	je cmd_bye
461		471
462	cmp dword[buf_cmd], "rdir"	472	cmp dword[buf_cmd], "rdir"
463	je cmd_rdir	473	je cmd_rdir
464		474
465	cmp byte[buf_cmd+4], " "	475	cmp byte[buf_cmd+4], " "
466	jne @f	476	jne @f
467		477
468	cmp dword[buf_cmd], "lcwd"	478	cmp dword[buf_cmd], "lcwd"
469	je cmd_lcwd	479	je cmd_lcwd
470		480
471	cmp dword[buf_cmd], "retr"	481	cmp dword[buf_cmd], "retr"
472	je cmd_retr	482	je cmd_retr
473		483
474	cmp dword[buf_cmd], "stor"	484	cmp dword[buf_cmd], "stor"
475	je cmd_stor	485	je cmd_stor
476		486
477	cmp dword[buf_cmd], "dele"	487	cmp dword[buf_cmd], "dele"
478	je cmd_dele	488	je cmd_dele
479		489
480	@@:	490	@@:
481	cmp byte[buf_cmd+4], 10	491	cmp byte[buf_cmd+4], 10
482	jne @f	492	jne @f
483		493
484	cmp dword[buf_cmd], "list"	494	cmp dword[buf_cmd], "list"
485	je cmd_list	495	je cmd_list

Subversion Repositories Kolibri OS

(root)/programs/network/ftpc/ftpc.asm @ 3967 – Rev 8442 → 9164