WebSVN – Kolibri OS – Diff – /programs/fs/kfar/trunk/viewer.inc


virtual at 0
viewer_data:
        .hPlugin        dd      ?
        .hFile          dd      ?
        .buf_start      dq      ?
        .cur_pos        dq      ?
        .filesize       dq      ?
        .buf_pos        dd      ?
        .buf_size       dd      ?
        .col            dq      ?
        .hWorkFile      dd      ?
        .encoding       db      ?
        .flags          db      ?       ; & 1: hex mode
                                        ; & 2: unwrap
                                        ; & 4: big-endian unicode
        .bEofReached    db      ?
                        rb      1
        .selected_start dq      ?
        .selected_len   dq      ?
        align 200h
        .filename       rb      1024
        .hostname       rb      1024
        .buf            rb      16384
        .size = $
end virtual
 
view_file:
        push    eax ecx
        mov     ecx, viewer_data.size
        mov     edx, viewer_vtable
        call    new_screen
        pop     ecx
        test    eax, eax
        pop     eax
        jnz     @f
        ret
@@:
        test    eax, eax
        jz      .frompanel
        and     dword [ebp+viewer_data.hPlugin], 0
        and     dword [ebp+viewer_data.hFile], 0
        mov     byte [ebp+viewer_data.hostname], 0
        lea     edi, [ebp+viewer_data.filename]
        push    edi
@@:
        lodsb
        stosb
        test    al, al
        jnz     @b
        jmp     .namecopied
.frompanel:
        mov     eax, dword [esi+panel1_hPlugin-panel1_dir]
        mov     [ebp+viewer_data.hPlugin], eax
        test    eax, eax
        jz      .nocopyhostname
        lea     edi, [ebp+viewer_data.hostname]
        push    esi
        mov     eax, dword [esi+panel1_parents-panel1_dir]
        mov     esi, dword [esi+panel1_parents_sz-panel1_dir]
        add     esi, eax
@@:
        dec     esi
        cmp     byte [esi-1], 0
        jz      @f
        cmp     byte [esi-1], '/'
        jnz     @b
@@:
        lodsb
        stosb
        test    al, al
        jnz     @b
        pop     esi
.nocopyhostname:
        mov     eax, dword [esi+panel1_hFile-panel1_dir]
        mov     [ebp+viewer_data.hFile], eax
        lea     edi, [ebp+viewer_data.filename]
        push    edi
@@:
        lodsb
        test    al, al
        jz      @f
        stosb
        jmp     @b
@@:
        lea     esi, [ecx+40]
        cmp     byte [edi-1], '/'
        jz      @f
        mov     al, '/'
        stosb
@@:
        lodsb
        stosb
        test    al, al
        jnz     @b
.namecopied:
        xor     eax, eax
        mov     [ebp+viewer_data.encoding], al ;encodings.cp866 = 0
        mov     [ebp+viewer_data.flags], al
        mov     dword [ebp+viewer_data.col], eax
        mov     dword [ebp+viewer_data.col+4], eax
        call    viewer_clear_selection
        pop     eax
 
        mov     ebx, attrinfo
        mov     [ebx+21], eax
        mov     [readinfo.name], eax
.attr_retry:
        mov     edx, [ebp+viewer_data.hPlugin]
        test    edx, edx
        jz      .attr_native
        push    ebp
        push    dword [ebx+16]
        push    eax
        push    [ebp+viewer_data.hFile]
        call    [edx+PluginInfo.getattr]
        pop     ebp
        jmp     .attr_common
.attr_native:
        push    70
        pop     eax
        int     40h
.attr_common:
        test    eax, eax
        jz      @f
        lea     ebx, [ebp+viewer_data.filename]
        push    ebx
        push    aCannotReadFile
        call    get_error_msg
        push    eax
        mov     eax, esp
        push    RetryOrCancelBtn
        push    2
        push    eax
        push    3
        call    SayErr
        add     esp, 3*4
        mov     ebx, attrinfo
        test    eax, eax
        jz      .attr_retry
        pop     eax
        jmp     delete_active_screen
@@:
        mov     eax, dword [attrinfo.attr+32]
        mov     dword [ebp+viewer_data.filesize], eax
        mov     eax, dword [attrinfo.attr+36]
        mov     dword [ebp+viewer_data.filesize+4], eax
        mov     ebx, readinfo
        xor     eax, eax
        mov     dword [ebx+readinfo.first-readinfo], eax
        mov     dword [ebx+readinfo.first+4-readinfo], eax
        mov     dword [ebp+viewer_data.buf_start], eax
        mov     dword [ebp+viewer_data.buf_start+4], eax
        mov     dword [ebp+viewer_data.cur_pos], eax
        mov     dword [ebp+viewer_data.cur_pos+4], eax
        mov     [ebx+readinfo.size-readinfo], 16384
        lea     eax, [ebp+viewer_data.buf]
        mov     [readinfo.data], eax
        mov     [ebp+viewer_data.buf_pos], eax
 
        mov     eax, [ebp+viewer_data.hPlugin]
        test    eax, eax
        jz      .retry
        push    ebx ebp
        push    O_READ
        push    dword [readinfo.name]
        push    [ebp+viewer_data.hFile]
        call    [eax+PluginInfo.open]
        pop     ebp ebx
        mov     [ebp+viewer_data.hWorkFile], eax
        test    eax, eax
        jnz     .retry
..openerr_in_screen:
        push    ContinueBtn
        push    1
        push    aCannotOpenFile_ptr
        push    1
        call    SayErr
        jmp     delete_active_screen
.retry:
        mov     eax, [ebp+viewer_data.hPlugin]
        test    eax, eax
        jz      .read_native
        push    ebp
        push    16384
        push    [ebx+readinfo.data-readinfo]
        push    [ebp+viewer_data.hWorkFile]
        call    [eax+PluginInfo.read]
        pop     ebp
        cmp     eax, -1
        jz      .readok         ; let's hope that plugin says error itself
        mov     [ebp+viewer_data.buf_size], eax
        mov     ebx, eax
        jmp     .readok
.read_native:
        push    70
        pop     eax
        int     40h
        mov     [ebp+viewer_data.buf_size], ebx
        test    eax, eax
        jz      .readok
        cmp     eax, 6
        jz      .readok
.readerr:
        lea     ebx, [ebp+viewer_data.filename]
        push    ebx
        push    aCannotReadFile
        call    get_error_msg
        push    eax
        mov     eax, esp
        push    RetryOrCancelBtn
        push    2
        push    eax
        push    3
        call    SayErr
        add     esp, 3*4
        mov     ebx, readinfo
        test    eax, eax
        jz      .attr_retry
        jmp     delete_active_screen
.readok:
        cmp     ebx, 2
        jb      .nounicode
        cmp     word [ebp+viewer_data.buf], 0xFEFF
        jz      @f
        cmp     word [ebp+viewer_data.buf], 0xFFFE
        jnz     .nounicode
        or      byte [ebp+viewer_data.flags], 4
@@:
        mov     [ebp+viewer_data.encoding], encodings.unicode
.nounicode:
viewer_OnRedraw:
        or      [cursor_x], -1
        or      [cursor_y], -1
        call    viewer_set_keybar
        call    viewer_draw_text
        ret
 
viewer_skip_unicode_marker:
        cmp     [ebp+viewer_data.encoding], encodings.unicode
        jnz     @f
        cmp     [bForHex], 0
        jnz     @f
        cmp     dword [ebp+viewer_data.buf_start], 0
        jnz     @f
        cmp     dword [ebp+viewer_data.buf_start+4], 0
        jnz     @f
        lea     eax, [ebp+viewer_data.buf]
        cmp     eax, [ebp+viewer_data.buf_pos]
        jnz     @f
        cmp     word [eax], 0xFFFE
        jz      .skip
        cmp     word [eax], 0xFEFF
        jnz     @f
.skip:
        add     [ebp+viewer_data.buf_pos], 2
@@:
        ret
 
viewer_load_next:
        mov     eax, dword [ebp+viewer_data.buf_start]
        add     eax, 8192
        mov     dword [ebp+viewer_data.buf_start], eax
        mov     edx, dword [ebp+viewer_data.buf_start+4]
        adc     edx, 0
        mov     dword [ebp+viewer_data.buf_start+4], edx
        add     eax, 16384-8192
        adc     edx, 0
        mov     dword [readinfo.first], eax
        mov     dword [readinfo.first+4], edx
        mov     dword [readinfo.size], 8192
        lea     edi, [ebp+viewer_data.buf]
        lea     esi, [edi+8192]
        mov     ecx, (16384-8192)/4
        rep     movsd
        mov     [readinfo.data], edi
        lea     eax, [ebp+viewer_data.filename]
        mov     [readinfo.name], eax
.readretry:
        mov     ebx, readinfo
        mov     eax, [ebp+viewer_data.hPlugin]
        test    eax, eax
        jz      .native
        push    ecx ebp
        push    8192
        push    [ebx+readinfo.data-readinfo]
        push    [ebp+viewer_data.hWorkFile]
        call    [eax+PluginInfo.read]
        pop     ebp ecx
        mov     ebx, eax
        cmp     eax, -1
        jnz     .readok
        xor     ebx, ebx
        jmp     .readok
.native:
        push    70
        pop     eax
        int     40h
        test    eax, eax
        jz      .readok
        cmp     eax, 6
        jz      .readok
.readerr:
        call    ask_retry_ignore
        jz      .readretry
.readok:
        sub     [ebp+viewer_data.buf_pos], 8192
        add     ebx, 16384-8192
        mov     [ebp+viewer_data.buf_size], ebx
        mov     eax, [ebp+viewer_data.buf_pos]
        cmp     ebx, 16384-8192
        ret
 
viewer_get_next_char:
        pusha
        call    viewer_skip_unicode_marker
        mov     eax, [ebp+viewer_data.buf_pos]
        lea     ecx, [ebp+viewer_data.buf]
        add     ecx, [ebp+viewer_data.buf_size]
        cmp     eax, ecx
        jb      .buffered
        mov     al, ' '
        sub     ecx, ebp
        cmp     ecx, viewer_data.buf + 16384
        jb      .err
        call    viewer_load_next
        jnz     .buffered
.err:
        stc
        popa
        ret
.buffered:
        cmp     [ebp+viewer_data.encoding], encodings.unicode
        jz      .unicode
        mov     al, [eax]
.done:
        mov     [esp+28], al
        inc     [ebp+viewer_data.buf_pos]
        clc
        popa
        ret
 
.unicode:
        inc     [ebp+viewer_data.buf_pos]
        cmp     [bForHex], 0
        jnz     @f
        call    read_unicode_char
        jmp     .done
@@:
        mov     ax, [eax]
        mov     [esp+29], ah
        jmp     .done
 
viewer_get_prev_char:
        pusha
        lea     ecx, [ebp+viewer_data.buf]
        cmp     [ebp+viewer_data.buf_pos], ecx
        ja      .buffered
        mov     eax, dword [ebp+viewer_data.buf_start]
        mov     edx, dword [ebp+viewer_data.buf_start+4]
        test    eax, eax
        jnz     @f
        test    edx, edx
        jnz     @f
        stc
        jmp     .ret
@@:
        sub     eax, 8192
        sbb     edx, 0
        jnc     @f
        xor     eax, eax
        xor     edx, edx
@@:
        call    viewer_seek
        add     [ebp+viewer_data.buf_pos], 8192
.buffered:
        mov     eax, [ebp+viewer_data.buf_pos]
        dec     eax
        cmp     [ebp+viewer_data.encoding], encodings.unicode
        jz      .unicode
        mov     [ebp+viewer_data.buf_pos], eax
        mov     al, [eax]
        mov     [esp+28], al
.done:
        clc
.ret:
        popa
        ret
 
.unicode:
        dec     eax
        mov     [ebp+viewer_data.buf_pos], eax
        call    read_unicode_char
        jmp     .done
 
read_unicode_char:
        mov     ax, [eax]
uni2ansi_char:
        test    [ebp+viewer_data.flags], 4
        jz      @f
        xchg    al, ah
@@:
        cmp     ax, 0x80
        jb      .ret
        cmp     ax, 0x401
        jz      .yo1
        cmp     ax, 0x451
        jz      .yo2
        cmp     ax, 0x410
        jb      .unk
        cmp     ax, 0x440
        jb      .rus1
        cmp     ax, 0x450
        jb      .rus2
.unk:
        mov     al, ' '
.ret:
        ret
.yo1:
        mov     al, 'ð'
        ret
.yo2:
        mov     al, 'ñ'
        ret
.rus1:
; 0x410-0x43F -> 0x80-0xAF
        add     al, 0x70
        ret
.rus2:
; 0x440-0x44F -> 0xE0-0xEF
        add     al, 0xA0
        ret
 
viewer_clear_selection:
        and     dword [ebp+viewer_data.selected_start], 0
        and     dword [ebp+viewer_data.selected_start+4], 0
        and     dword [ebp+viewer_data.selected_len], 0
        and     dword [ebp+viewer_data.selected_len+4], 0
        ret
 
fld_uint64:
        fild    qword [eax]
        test    byte [eax+7], 80h
        jz      .ret
        fadd    [@f]
.ret:
        ret
@@      dq      18446744073709551616.0 ;0x10000000000000000
 
viewer_draw_text:
        call    viewer_seek_to_current
        xor     eax, eax
        xor     edx, edx
        call    get_console_ptr
        mov     ah, [view_status_color]
        mov     ecx, [cur_width]
        sub     ecx, 44
        cmp     ecx, 20
        jae     @f
        mov     cl, 20
@@:
        call    viewedit_draw_filename
        add     ecx, 11
        rep     stosw
        movzx   esi, [ebp+viewer_data.encoding]
        lea     esi, [encodings.names+esi*8]
        push    edi esi
        dec     edi
        dec     edi
        std
        add     esi, 8
@@:
        dec     esi
        cmp     byte [esi], ' '
        jz      @b
@@:
        lodsb
        stosw
        cmp     esi, [esp]
        jae     @b
        cld
        pop     esi edi
        mov     al, ' '
        mov     cl, 13
        rep     stosw
        std
        push    edi
        mov     edx, dword [ebp+viewer_data.filesize+4]
        mov     eax, dword [ebp+viewer_data.filesize]
        mov     cl, 10
@@:
        push    eax
        mov     eax, edx
        xor     edx, edx
        div     ecx
        xchg    eax, [esp]
        div     ecx
        xchg    eax, edx
        add     al, '0'
        mov     ah, [view_status_color]
        stosw
        xchg    eax, edx
        pop     edx
        test    eax, eax
        jnz     @b
        test    edx, edx
        jnz     @b
        mov     al, ' '
        mov     ah, [view_status_color]
        stosw
        cld
        pop     edi
        inc     edi
        inc     edi
        mov     al, ' '
        mov     cl, 5
        rep     stosw
if lang eq ru
        mov     al, ''
        stosw
        mov     al, '®'
        stosw
        mov     al, '«'
        stosw
else
        mov     al, 'C'
        stosw
        mov     al, 'o'
        stosw
        mov     al, 'l'
        stosw
end if
        mov     al, ' '
        stosw
        push    edi
        mov     eax, dword [ebp+viewer_data.col]
        mov     edx, dword [ebp+viewer_data.col+4]
        test    edx, edx
        jnz     .col_big
        cmp     eax, 100000
        jae     .col_big
        mov     cl, 10
        push    -'0'
@@:
        div     ecx
        push    edx
        xor     edx, edx
        test    eax, eax
        jnz     @b
@@:
        pop     eax
        add     eax, '0'
        jz      .col_done
        mov     ah, [view_status_color]
        stosw
        jmp     @b
.col_big:
        push    eax
        mov     al, '.'
        mov     ah, [view_status_color]
        stosw
        stosw
        stosw
        xor     eax, eax
        xchg    eax, edx
        mov     cl, 100
        div     ecx
        pop     eax
        div     ecx
        mov     cl, 10
        xor     eax, eax
        xchg    eax, edx
        div     ecx
        add     al, '0'
        mov     ah, [view_status_color]
        stosw
        mov     al, dl
        add     al, '0'
        stosw
.col_done:
        pop     ecx
        add     ecx, 10*2
        sub     ecx, edi
        shr     ecx, 1
        mov     al, ' '
        mov     ah, [view_status_color]
        rep     stosw
        finit
        fldcw   [fpu_cw]
        mov     [tmp], 100
        lea     eax, [ebp+viewer_data.filesize]
        cmp     dword [eax], 0
        jnz     @f
        cmp     dword [eax+4], 0
        jz      .size_zero
@@:
        call    fld_uint64
        lea     eax, [ebp+viewer_data.cur_pos]
        call    fld_uint64
        fdivrp
        fimul   [_100d]
        fistp   [tmp]
.size_zero:
        mov     byte [edi-2], '%'
        sub     edi, 4
        mov     eax, [tmp]
        mov     cl, 10
@@:
        xor     edx, edx
        div     ecx
        xchg    eax, edx
        add     al, '0'
        mov     [edi], al
        sub     edi, 2
        xchg    eax, edx
        test    eax, eax
        jnz     @b
        xor     eax, eax
        push    1
        pop     edx
        call    get_console_ptr
        test    [ebp+viewer_data.flags], 1
        jnz     .DrawHex
        push    2
        pop     edx
        xor     ecx, ecx
        mov     dword [scrpos], ecx
        mov     dword [scrpos+4], ecx
        mov     dword [viewer_right_side], ecx
        mov     dword [viewer_right_side+4], ecx
.1:
        call    viewer_get_next_char
        jc      .done
.2:
        cmp     al, 0xD
        jz      .newline
        cmp     al, 0xA
        jz      .newline
        cmp     ecx, [cur_width]
        jb      .no_newline
        test    [ebp+viewer_data.flags], 2
        jnz     .no_newline
.newline:
        push    eax
        mov     ecx, dword [scrpos]
        mov     eax, dword [scrpos+4]
        sub     ecx, dword [ebp+viewer_data.col]
        sbb     eax, dword [ebp+viewer_data.col+4]
        ja      .line_filled
        jb      .line_full
        cmp     ecx, [cur_width]
        ja      .line_filled
        jmp     @f
.line_full:
        xor     ecx, ecx
@@:
        test    ecx, ecx
        jnz     @f
        mov     eax, dword [scrpos]
        or      eax, dword [scrpos+4]
        jz      @f
        inc     ecx
@@:
        sub     ecx, [cur_width]
        neg     ecx
        mov     al, ' '
        mov     ah, [view_normal_color]
        rep     stosw
.line_filled:
        mov     eax, dword [scrpos]
        sub     eax, dword [viewer_right_side]
        mov     eax, dword [scrpos+4]
        sbb     eax, dword [viewer_right_side+4]
        jb      @f
        mov     eax, dword [scrpos]
        mov     dword [viewer_right_side], eax
        mov     eax, dword [scrpos+4]
        mov     dword [viewer_right_side+4], eax
@@:
        xor     ecx, ecx
        mov     dword [scrpos], ecx
        mov     dword [scrpos+4], ecx
        inc     edx
        pop     eax
        cmp     edx, [cur_height]
        jae     .done
.no_newline:
        cmp     al, 0xD
        jz      .3
        cmp     al, 0xA
        jz      .3
.4:
        test    al, al
        jns     @f
        movzx   esi, [ebp+viewer_data.encoding]
        cmp     esi, encodings.unicode
        jz      @f
        shl     esi, 7
        movzx   eax, al
        mov     al, [encodings.tables-80h+esi+eax]
@@:
        cmp     al, 9
        jz      .tab
        call    .write_char
        inc     ecx
        jns     .1
        push    edx
        mov     eax, ecx
        xor     edx, edx
        div     [viewer_tabsize]
        mov     ecx, edx
        pop     edx
        jmp     .1
.3:
        mov     bl, al
        call    viewer_get_next_char
        jc      .done
        xor     bl, al
        cmp     bl, 0xA xor 0xD
        jz      .1
        jmp     .2
.tab:
        push    edx
        push    ecx
        mov     eax, ecx
        mov     ecx, [viewer_tabsize]
        xor     edx, edx
        div     ecx
        pop     eax
        sub     ecx, edx
        pop     edx
        add     eax, ecx
        test    [ebp+viewer_data.flags], 2
        jnz     @f
        cmp     eax, [cur_width]
        jbe     @f
        sub     eax, [cur_width]
        sub     ecx, eax
        mov     eax, [cur_width]
@@:
        push    eax
        mov     al, ' '
@@:
        call    .write_char
        loop    @b
        pop     ecx
        jmp     .1
.done:
        setc    [ebp+viewer_data.bEofReached]
.done2:
        inc     edx
        cmp     edx, [cur_height]
        jnc     @f
        mov     eax, dword [ebp+viewer_data.cur_pos]
        or      eax, dword [ebp+viewer_data.cur_pos+4]
        jz      @f
        call    viewer_seek_to_current
        call    viewer_prev_newline
        jmp     viewer_draw_text
@@:
        push    edi
        xor     eax, eax
        mov     edx, [cur_height]
        dec     edx
        call    get_console_ptr
        mov     ecx, edi
        pop     edi
        sub     ecx, edi
        shr     ecx, 1
        mov     al, ' '
        mov     ah, [view_normal_color]
        rep     stosw
        cmp     [ebp+viewer_data.bEofReached], 0
        jz      @f
        xor     edx, edx
        mov     eax, [cur_width]
        sub     eax, 4
        call    get_console_ptr
        mov     ah, [view_status_color]
        mov     al, '1'
        stosw
        mov     al, '0'
        stosw
        stosw
@@:
        call    draw_image
        ret
.DrawHex:
        xor     esi, esi
        mov     [ebp+viewer_data.bEofReached], 0
.line:
        mov     al, ' '
        mov     ah, [view_normal_color]
        push    edi
        mov     ecx, [cur_width]
        rep     stosw
        mov     ebx, edi
        pop     edi
        mov     [bForHex], 1
        call    viewer_get_next_char
        mov     [bForHex], 0
        jc      .hexdone
        push    eax
        push    edi
        add     edi, 36*2
        mov     al, 0xB3
        mov     ah, [view_normal_color]
        call    .safechar
        pop     edi
        mov     eax, dword [ebp+viewer_data.cur_pos]
        mov     edx, dword [ebp+viewer_data.cur_pos+4]
        push    esi
        shl     esi, 4
        add     eax, esi
        adc     edx, 0
        pop     esi
        push    eax
        mov     al, dl
        shr     eax, 4
        and     al, 0xF
        call    .hex_digit
        mov     al, dl
        and     al, 0xF
        call    .hex_digit
        pop     eax
        push    8
        pop     ecx
        add     edi, 7*2
        std
@@:
        push    eax
        and     al, 0xF
        call    .hex_digit
        pop     eax
        shr     eax, 4
        loop    @b
        cld
        add     edi, 9*2
        mov     al, ':'
        mov     ah, [view_normal_color]
        stosw
        mov     al, ' '
        stosw
        xor     ecx, ecx
        pop     eax
        jmp     @f
.hexchar:
        mov     [bForHex], 1
        call    viewer_get_next_char
        mov     [bForHex], 0
        jc      .hexdone
@@:
        cmp     [ebp+viewer_data.encoding], encodings.unicode
        jz      .hexchar_unicode
        push    eax
        shr     al, 4
        call    .hex_digit
        pop     eax
        push    eax
        and     al, 0xF
        call    .hex_digit
        mov     al, ' '
        call    .safechar
        pop     eax
        push    edi
        add     edi, 48*2
        push    ecx
        shl     ecx, 2
        sub     edi, ecx
        pop     ecx
        cmp     ecx, 8
        jb      @f
        sub     edi, 4
@@:
        test    al, al
        jns     @f
        movzx   edx, [ebp+viewer_data.encoding]
        shl     edx, 7
        movzx   eax, al
        mov     al, [encodings.tables+eax+edx-80h]
        mov     ah, [view_normal_color]
@@:
        call    .safechar
        pop     edi
        inc     ecx
        cmp     ecx, 8
        jnz     @f
        mov     al, 0xB3
        call    .safechar
        mov     al, ' '
        call    .safechar
@@:
        cmp     ecx, 16
        jnz     .hexchar
        jmp     .hexchar_nextline
.hexchar_unicode:
        push    eax
        shr     eax, 12
        call    .hex_digit
        pop     eax
        push    eax
        shr     eax, 8
        and     al, 0xF
        call    .hex_digit
        pop     eax
        push    eax
        shr     al, 4
        call    .hex_digit
        pop     eax
        push    eax
        and     al, 0xF
        call    .hex_digit
        mov     al, ' '
        mov     ah, [view_normal_color]
        call    .safechar
        pop     eax
        push    edi
        add     edi, 38*2
        push    ecx
        shl     ecx, 3
        sub     edi, ecx
        pop     ecx
        cmp     ecx, 4
        jb      @f
        sub     edi, 4
@@:
        call    uni2ansi_char
        mov     ah, [view_normal_color]
        call    .safechar
        pop     edi
        inc     ecx
        cmp     ecx, 4
        jnz     @f
        mov     al, 0xB3
        call    .safechar
        mov     al, ' '
        call    .safechar
@@:
        cmp     ecx, 8
        jnz     .hexchar
.hexchar_nextline:
        mov     edi, ebx
        add     esi, 3
        mov     edx, esi
        cmp     esi, [cur_height]
        jae     .done2
        dec     esi
        dec     esi
        jmp     .line
.hexdone:
        mov     [ebp+viewer_data.bEofReached], 1
        mov     edi, ebx
        lea     edx, [esi+2]
        jmp     .done2
 
.hex_digit:
        push    eax
        cmp     al, 10
        sbb     al, 69h
        das
        mov     ah, [view_normal_color]
        call    .safechar
        pop     eax
        ret
.safechar:
        cmp     edi, ebx
        jae     @f
        stosw
@@:
        ret
.write_char:
        push    ecx eax
        mov     ecx, dword [scrpos]
        mov     eax, dword [scrpos+4]
        sub     ecx, dword [ebp+viewer_data.col]
        sbb     eax, dword [ebp+viewer_data.col+4]
        jb      .left
        ja      .skip
        test    ecx, ecx
        jnz     @f
        mov     eax, dword [scrpos]
        or      eax, dword [scrpos+4]
        jnz     .skip
@@:
        cmp     ecx, [cur_width]
        ja      .skip
        jb      .do
        mov     al, '>'
        mov     [edi-2], al
        mov     al, [view_arrows_color]
        mov     [edi-1], al
        jmp     .skip
.left:
        mov     eax, dword [scrpos]
        or      eax, dword [scrpos+4]
        jnz     .skip
        mov     al, '<'
        mov     ah, [view_arrows_color]
        stosw
        jmp     .skip
.do:
        mov     al, [esp]
        mov     ah, [view_normal_color]
        push    edx
        mov     ecx, [ebp+viewer_data.buf_pos]
        sub     ecx, ebp
        sub     ecx, viewer_data.buf + 1
        xor     edx, edx
        add     ecx, dword [ebp+viewer_data.buf_start]
        adc     edx, dword [ebp+viewer_data.buf_start+4]
        sub     ecx, dword [ebp+viewer_data.selected_start]
        sbb     edx, dword [ebp+viewer_data.selected_start+4]
        cmp     edx, dword [ebp+viewer_data.selected_len+4]
        ja      .color_ok
        jb      @f
        cmp     ecx, dword [ebp+viewer_data.selected_len]
        jae     .color_ok
@@:
        mov     ah, [view_selected_color]
.color_ok:
        pop     edx
        stosw
.skip:
        pop     eax ecx
        add     dword [scrpos], 1
        adc     dword [scrpos+4], 0
        ret
 
viewedit_draw_filename:
        lea     esi, [ebp+viewer_data.filename]
        xor     edx, edx
        cmp     [ebp+viewer_data.hPlugin], edx
        mov     dl, 3
        jz      .5
        mov     dl, 1
.5:
        lodsb
        cmp     al, '/'
        jnz     @f
        dec     edx
        jz      .6
@@:
        stosw
        loop    .5
.6:
        dec     ecx
        stosw
        push    esi
@@:
        inc     esi
        cmp     byte [esi-1], 0
        jnz     @b
        sub     esi, [esp]
        dec     esi
        cmp     ecx, esi
        jae     .7
        mov     al, '.'
        stosw
        stosw
        stosw
        sub     ecx, 3
        sub     esi, ecx
        add     [esp], esi
.7:
        pop     esi
@@:
        lodsb
        test    al, al
        jz      @f
        dec     ecx
        stosw
        jmp     @b
@@:
        mov     al, ' '
        ret
 
viewer_seek_to_current:
        mov     eax, dword [ebp+viewer_data.cur_pos]
        mov     edx, dword [ebp+viewer_data.cur_pos+4]
viewer_seek:
        push    eax edx
        sub     eax, dword [ebp+viewer_data.buf_start]
        sbb     edx, dword [ebp+viewer_data.buf_start+4]
        jb      .prev
        ja      .next
        cmp     eax, 16384
        jae     .next
        lea     eax, [ebp+viewer_data.buf+eax]
        mov     [ebp+viewer_data.buf_pos], eax
        pop     edx eax
        ret
.prev:
        inc     edx
        jnz     .read_full
        and     eax, not 511
        cmp     eax, -16384
        jbe     .read_full
        lea     edi, [ebp+viewer_data.buf+16384-4]
        lea     esi, [edi+eax]
        lea     ecx, [eax+16384]
        push    ecx
        shr     ecx, 2
        std
        rep     movsd
        cld
        pop     ecx
        add     dword [ebp+viewer_data.buf_start], eax
        adc     dword [ebp+viewer_data.buf_start+4], -1
        neg     eax
        cmp     dword [ebp+viewer_data.buf_size], ecx
        jb      .doread
        mov     dword [ebp+viewer_data.buf_size], ecx
        jmp     .doread
.read_full:
        pop     edx eax
        push    eax edx
        and     eax, not 511
        sub     eax, 8192-512
        sbb     edx, 0
        jnc     @f
        xor     eax, eax
        xor     edx, edx
@@:
        mov     dword [ebp+viewer_data.buf_start], eax
        mov     dword [ebp+viewer_data.buf_start+4], edx
        and     dword [ebp+viewer_data.buf_size], 0
        mov     eax, 16384
.doread:
        mov     ebx, readinfo
        push    dword [ebp+viewer_data.buf_start]
        pop     dword [ebx+4]
        push    dword [ebp+viewer_data.buf_start+4]
        pop     dword [ebx+8]
        mov     [ebx+12], eax
        lea     eax, [ebp+viewer_data.buf]
        mov     [ebx+16], eax
        lea     eax, [ebp+viewer_data.filename]
        mov     [ebx+21], eax
        call    .q
        cmp     ebx, [readinfo.size]
        jnz     @f
        add     ebx, [ebp+viewer_data.buf_size]
@@:
.ret:
        mov     [ebp+viewer_data.buf_size], ebx
        pop     edx eax
        sub     eax, dword [ebp+viewer_data.buf_start]
        lea     eax, [ebp+eax+viewer_data.buf]
        mov     [ebp+viewer_data.buf_pos], eax
        ret
.next:
        or      eax, 511
        sub     eax, 16384-1
        sbb     edx, 0
        jnz     .read_full
        cmp     eax, 16384
        jae     .read_full
        cmp     [ebp+viewer_data.buf_size], 16384
        jb      .read_full
        lea     edi, [ebp+viewer_data.buf]
        lea     esi, [edi+eax]
        mov     ecx, 16384
        sub     ecx, eax
        shr     ecx, 2
        rep     movsd
        add     dword [ebp+viewer_data.buf_start], eax
        adc     dword [ebp+viewer_data.buf_start+4], 0
        mov     ebx, readinfo
        mov     [ebx+16], edi
        sub     edi, ebp
        sub     edi, viewer_data.buf
        mov     edx, dword [ebp+viewer_data.buf_start]
        add     edx, edi
        mov     [ebx+4], edx
        mov     edx, dword [ebp+viewer_data.buf_start+4]
        adc     edx, 0
        mov     [ebx+8], edx
        mov     [ebx+12], eax
        lea     eax, [ebp+viewer_data.filename]
        mov     [ebx+21], eax
        call    .q
        sub     ebx, [readinfo.size]
        add     ebx, 16384
        jmp     .ret
 
.q:
        mov     ebx, readinfo
        mov     eax, [ebp+viewer_data.hPlugin]
        test    eax, eax
        jz      .native
        push    ebp
        push    dword [ebx+12]
        push    dword [ebx+16]
        push    [ebp+viewer_data.hWorkFile]
        push    eax
        push    dword [ebx+8]
        push    dword [ebx+4]
        push    [ebp+viewer_data.hWorkFile]
        call    [eax+PluginInfo.setpos]
        pop     eax
        call    [eax+PluginInfo.read]
        pop     ebp
        mov     ebx, eax
        cmp     eax, -1
        jnz     @f
        xor     ebx, ebx
@@:
        ret
.native:
        push    70
        pop     eax
        int     40h
        test    eax, eax
        jz      .readok
        cmp     eax, 6
        jz      .readok
.readerr:
        call    ask_retry_ignore
        jz      .q
.readok:
        ret
 
ask_retry_ignore:
        push    esi
        lea     esi, [ebp+viewer_data.filename]
        push    esi
        push    aCannotReadFile
        call    get_error_msg
        push    eax
        mov     eax, esp
        push    RetryOrIgnoreBtn
        push    2
        push    eax
        push    3
        call    SayErr
        add     esp, 3*4
        pop     esi
        test    eax, eax
        ret
 
viewer_set_curpos:
        mov     eax, [ebp+viewer_data.buf_pos]
        sub     eax, ebp
        sub     eax, viewer_data.buf
        xor     edx, edx
        add     eax, dword [ebp+viewer_data.buf_start]
        adc     edx, dword [ebp+viewer_data.buf_start+4]
        mov     dword [ebp+viewer_data.cur_pos], eax
        mov     dword [ebp+viewer_data.cur_pos+4], edx
        ret
 
viewer_next_newline:
        test    [ebp+viewer_data.flags], 1
        jz      .nohex
        push    8
        pop     ecx
        cmp     [ebp+viewer_data.encoding], encodings.unicode
        jz      @f
        add     ecx, ecx
@@:
        call    viewer_get_next_char
        jc      @f
        loop    @b
        call    viewer_set_curpos
        clc
@@:     ret
.nohex:
        xor     ecx, ecx
@@:
        call    viewer_get_next_char
        jc      .ret
        cmp     al, 0xD
        jz      .1
        cmp     al, 0xA
        jz      .1
        cmp     al, 9
        jz      .tab
        inc     ecx
.next:
        test    [ebp+viewer_data.flags], 2
        jnz     @b
        cmp     ecx, [cur_width]
        jbe     @b
        call    viewer_get_prev_char
        jmp     .2
.tab:
        push    ecx
        mov     eax, ecx
        mov     ecx, [viewer_tabsize]
        xor     edx, edx
        div     ecx
        sub     ecx, edx
        add     [esp], ecx
        pop     ecx
        jmp     .next
.1:
        mov     cl, al
        call    viewer_get_next_char
        jc      .ret
        xor     cl, al
        cmp     cl, 0xD xor 0xA
        jz      .2
        dec     [ebp+viewer_data.buf_pos]
        cmp     [ebp+viewer_data.encoding], encodings.unicode
        jnz     .2
        dec     [ebp+viewer_data.buf_pos]
.2:
        clc
.ret:
        pushf
        call    viewer_set_curpos
        popf
        ret
 
viewer_prev_newline:
        test    [ebp+viewer_data.flags], 1
        jz      .nohex
        push    8
        pop     ecx
        cmp     [ebp+viewer_data.encoding], encodings.unicode
        jz      @f
        add     ecx, ecx
@@:
        call    viewer_get_prev_char
        jc      @f
        loop    @b
@@:     call    viewer_set_curpos
        ret
.nohex:
        mov     eax, 8192
        push    eax
        cdq
        div     [cur_width]
        pop     eax
        sub     eax, edx
        mov     edx, eax
        call    viewer_get_prev_char
        jc      .0
        dec     edx
        cmp     al, 0xD
        jz      .2
        cmp     al, 0xA
        jnz     .3
.2:
        mov     cl, al
        call    viewer_get_prev_char
        jc      .0
        dec     edx
        xor     cl, al
        cmp     cl, 0xD xor 0xA
        jnz     .3
@@:
        call    viewer_get_prev_char
        jc      .0
        dec     edx
        jz      .0
.3:
        cmp     al, 0xD
        jz      .1
        cmp     al, 0xA
        jnz     @b
.1:
        call    viewer_get_next_char
.0:
        push    dword [ebp+viewer_data.cur_pos+4]
        push    dword [ebp+viewer_data.cur_pos]
        call    viewer_set_curpos
@@:
        push    dword [ebp+viewer_data.cur_pos+4]
        push    dword [ebp+viewer_data.cur_pos]
        call    viewer_next_newline
        jc      .ret3
        mov     eax, dword [ebp+viewer_data.cur_pos]
        mov     edx, dword [ebp+viewer_data.cur_pos+4]
        sub     eax, [esp+8]
        sbb     edx, [esp+12]
        jae     .ret3
        pop     eax
        pop     eax
        jmp     @b
.ret3:
        pop     dword [ebp+viewer_data.cur_pos]
        pop     dword [ebp+viewer_data.cur_pos+4]
.ret:
        pop     eax
        pop     eax
        jmp     viewer_seek_to_current
 
viewer_set_keybar:
        mov     eax, keybar_viewer
if lang eq ru
        test    [ebp+viewer_data.flags], 1
        jnz     .hex
        mov     dword [eax+(4-1)*6], '®¤ '
        mov     word [eax+(4-1)*6+4], '  '
        jmp     @f
.hex:
        mov     dword [eax+(4-1)*6], '¥ªá'
        mov     word [eax+(4-1)*6+4], 'â '
@@:
        test    [ebp+viewer_data.flags], 2
        jnz     .unwrap
        mov     dword [eax+6], ' §¢'
        mov     word [eax+6+4], '¥à'
        jmp     @f
.unwrap:
        mov     dword [eax+6], '¢¥à'
        mov     word [eax+6+4], '­ '
@@:
else
        test    [ebp+viewer_data.flags], 1
        jnz     .hex
        mov     dword [eax+(4-1)*6], 'Hex '
;        mov     word [eax+(4-1)*6+4], '  '
        jmp     @f
.hex:
        mov     dword [eax+(4-1)*6], 'Text'
;        mov     word [eax+(4-1)*6+4], '  '
@@:
        test    [ebp+viewer_data.flags], 2
        jnz     .unwrap
        mov     dword [eax+6], 'Unwr'
        mov     word [eax+6+4], 'ap'
        jmp     @f
.unwrap:
        mov     dword [eax+6], 'Wrap'
        mov     word [eax+6+4], '  '
@@:
end if
        movzx   esi, [ebp+viewer_data.encoding]
        dec     esi
        jz      @f
        push    1
        pop     esi
@@:
        lea     esi, [encodings.names+esi*8]
        lea     edi, [eax+keybar_cp-keybar_viewer]
        movsd
        movsw
        jmp     draw_keybar
 
viewer_OnExit:
        mov     edx, [ebp+viewer_data.hPlugin]
        test    edx, edx
        jz      @f
        and     [ebp+viewer_data.hPlugin], 0
        push    edx ebp
        push    [ebp+viewer_data.hWorkFile]
        call    [edx+PluginInfo.close]
        pop     ebp edx
        mov     ebx, [ebp+viewer_data.hFile]
        call    close_handle_if_unused
@@:
        ret
 
viewer_IsHandleUsed:
editor_IsHandleUsed:
        cmp     edx, [ebp+viewer_data.hPlugin]
        jnz     @f
        cmp     ebx, [ebp+viewer_data.hFile]
@@:
        ret
 
viewer_OnKey:
        mov     esi, viewer_ctrlkeys
        jmp     process_ctrl_keys
.exit:
        call    viewer_OnExit
        jmp     delete_active_screen
.down:
        cmp     [ebp+viewer_data.bEofReached], 0
        jnz     .ret
        call    viewer_seek_to_current
        call    viewer_next_newline
        jc      .ret
        call    viewer_draw_text
        ret
.pgdn:
        cmp     [ebp+viewer_data.bEofReached], 0
        jnz     .ret
        call    viewer_seek_to_current
        mov     ebx, [cur_height]
        sub     ebx, 3
@@:
        call    viewer_next_newline
        jc      .ret
        dec     ebx
        jnz     @b
        call    viewer_draw_text
        ret
.up:
        call    viewer_seek_to_current
        call    viewer_prev_newline
        call    viewer_draw_text
        ret
.pgup:
        call    viewer_seek_to_current
        mov     ebx, [cur_height]
        sub     ebx, 3
@@:
        call    viewer_prev_newline
        dec     ebx
        jnz     @b
.done_redraw:
        call    viewer_draw_text
.ret:
        ret
.f8:
        movzx   esi, [ebp+viewer_data.encoding]
        dec     [ebp+viewer_data.encoding]
        jz      .done_redraw_keybar
        mov     [ebp+viewer_data.encoding], 1
        jmp     .done_redraw_keybar
.f2:
        xor     [ebp+viewer_data.flags], 2
.done_redraw_keybar:
        call    viewer_set_keybar
        jmp     .done_redraw
.f4:
        xor     [ebp+viewer_data.flags], 1
        pushf
        call    viewer_set_keybar
        popf
        jnz     .tohex
        push    1
        pop     eax
        cmp     [ebp+viewer_data.encoding], encodings.unicode
        jnz     @f
        add     eax, eax
@@:
        add     dword [ebp+viewer_data.cur_pos], eax
        adc     dword [ebp+viewer_data.cur_pos+4], 0
        call    viewer_seek_to_current
        call    viewer_prev_newline
        jmp     .done_redraw
.tohex:
        and     byte [ebp+viewer_data.cur_pos], 0xF0
        jmp     .done_redraw
.home:
        xor     eax, eax
        mov     dword [ebp+viewer_data.cur_pos], eax
        mov     dword [ebp+viewer_data.cur_pos+4], eax
        mov     dword [ebp+viewer_data.col], eax
        mov     dword [ebp+viewer_data.col+4], eax
        jmp     .done_redraw
.end:
        mov     eax, dword [ebp+viewer_data.filesize]
        mov     edx, dword [ebp+viewer_data.filesize+4]
        and     al, 0xF0
        mov     dword [ebp+viewer_data.cur_pos], eax
        mov     dword [ebp+viewer_data.cur_pos+4], edx
        and     dword [ebp+viewer_data.col], 0
        and     dword [ebp+viewer_data.col+4], 0
        jmp     .done_redraw
.right:
        add     dword [ebp+viewer_data.col], 1
        adc     dword [ebp+viewer_data.col+4], 0
        jnc     .done_redraw
        sub     dword [ebp+viewer_data.col], 1
        sbb     dword [ebp+viewer_data.col+4], 0
        ret
.left:
        sub     dword [ebp+viewer_data.col], 1
        sbb     dword [ebp+viewer_data.col+4], 0
        jnc     .done_redraw
        add     dword [ebp+viewer_data.col], 1
        adc     dword [ebp+viewer_data.col+4], 0
        ret
.ctrl_left:
        test    [ebp+viewer_data.flags], 1
        jnz     .ctrl_left_hex
        sub     dword [ebp+viewer_data.col], 20
        sbb     dword [ebp+viewer_data.col+4], 0
        jnc     .done_redraw
.ctrl_shift_left:
        and     dword [ebp+viewer_data.col], 0
        and     dword [ebp+viewer_data.col+4], 0
        jmp     .done_redraw
.ctrl_left_hex:
        call    viewer_seek_to_current
        call    viewer_get_prev_char
        jc      @f
        call    viewer_set_curpos
        jmp     .done_redraw
.ctrl_right:
        test    [ebp+viewer_data.flags], 1
        jnz     .ctrl_right_hex
        add     dword [ebp+viewer_data.col], 20
        adc     dword [ebp+viewer_data.col+4], 0
        jnc     .done_redraw
        sub     dword [ebp+viewer_data.col], 20
        sbb     dword [ebp+viewer_data.col+4], 0
@@:     ret
.ctrl_right_hex:
        call    viewer_seek_to_current
        call    viewer_get_next_char
        call    viewer_set_curpos
        jmp     .done_redraw
.ctrl_shift_right:
        test    [ebp+viewer_data.flags], 1
        jnz     @b
        mov     eax, dword [viewer_right_side]
        mov     edx, dword [viewer_right_side+4]
        sub     eax, [cur_width]
        sbb     edx, 0
        jnc     @f
        xor     eax, eax
        xor     edx, edx
@@:
        mov     dword [ebp+viewer_data.col], eax
        mov     dword [ebp+viewer_data.col+4], edx
        jmp     .done_redraw
.shift_f8:
        mov     ecx, encodings.menu.1
        mov     al, [ebp+viewer_data.encoding]
@@:
        cmp     byte [ecx-1], al
        jz      @f
        mov     ecx, [ecx]
        jmp     @b
@@:
        push    1
        push    aTables
        push    ecx
        call    menu
        cmp     eax, -1
        jz      .ret
        mov     al, [eax-1]
        mov     [ebp+viewer_data.encoding], al
        cmp     al, encodings.unicode
        jnz     .done_redraw_keybar
        add     dword [ebp+viewer_data.cur_pos], 1
        adc     dword [ebp+viewer_data.cur_pos+4], 0
        and     dword [ebp+viewer_data.cur_pos], not 1
        jmp     .done_redraw_keybar
.f7:
        call    viewer_clear_selection
        call    find_in_file_dlg
        jz      .shift_f7
.ret2:
        ret
.shift_f7:
; search string SearchString in file starting from current position
        cmp     byte [SearchString], 0
        jz      .ret2
        mov     eax, dword [ebp+viewer_data.selected_start]
        mov     edx, dword [ebp+viewer_data.selected_start+4]
        inc     eax
        jnz     @f
        inc     edx
@@:
        cmp     dword [ebp+viewer_data.selected_len], 0
        jnz     @f
        cmp     dword [ebp+viewer_data.selected_len+4], 0
        jnz     @f
        mov     eax, dword [ebp+viewer_data.cur_pos]
        mov     edx, dword [ebp+viewer_data.cur_pos+4]
@@:
        call    viewer_clear_selection
        call    viewer_seek
        call    viewer_skip_unicode_marker
        mov     esi, tolower_table
        test    [find_in_file_dlgdata.flags_case], 10h
        jz      @f
        mov     esi, identical_table
@@:
        mov     ebx, SearchString
 	test	[find_in_file_dlgdata.flags_whole], 10h
	setnz	al
	push	eax
        push    dword [ebp+viewer_data.encoding]
        call    search_string_pre
        mov     esi, [ebp+viewer_data.buf_pos]
        lea     ebx, [ebp+viewer_data.buf]
        add     ebx, [ebp+viewer_data.buf_size]
        mov     edi, edx
        cmp     esi, ebx
        jb      @f
        sub     ebx, ebp
        cmp     ebx, viewer_data.buf + 16384
        jnz     .f7.notfound
        pusha
        call    viewer_load_next
        popa
        jz      .f7.notfound
        mov     esi, [ebp+viewer_data.buf_pos]
        lea     ebx, [ebp+viewer_data.buf]
        add     ebx, [ebp+viewer_data.buf_size]
@@:
        test    [find_in_file_dlgdata.flags_whole], 10h
        jz      .search_loop
        cmp     dword [ebp+viewer_data.buf_start], 0
        jnz     @f
        cmp     dword [ebp+viewer_data.buf_start+4], 0
        jnz     @f
        lea     eax, [ebp+viewer_data.buf]
        cmp     [ebp+viewer_data.buf_pos], eax
        jz      .f7.startspace
@@:
        xor     eax, eax
        call    viewer_get_prev_char
        inc     esi
        cmp     [isspace_table+eax], 0
        jz      .search_loop
.f7.startspace:
        add     edi, 256
.search_loop:
; edx -> FSM, ecx = last state, edi = current state,
; esi = buf_pos, ebx = end of buffer
; get current symbol
        movzx   eax, byte [esi]
; calculate next state
        movzx   edi, byte [edi+eax]
; done?
        cmp     edi, ecx
        jz      .f7.found
.search_loop_next:
; no; proceed to next symbol
        shl     edi, 8
        add     esi, 1
        add     edi, edx
        cmp     esi, ebx
        jb      .search_loop
        sub     ebx, ebp
        cmp     ebx, viewer_data.buf + 16384
        jnz     .f7.notfound
        mov     [ebp+viewer_data.buf_pos], esi
        pusha
        call    viewer_load_next
        popa
        jz      .f7.notfoundt
        mov     esi, [ebp+viewer_data.buf_pos]
        lea     ebx, [ebp+viewer_data.buf]
        add     ebx, [ebp+viewer_data.buf_size]
        jmp     .search_loop
.f7.notfoundt:
; last chance - if we are looking for a whole word, EOF is ok for last symbol
        test    [find_in_file_dlgdata.flags_whole], 10h
        jz      .f7.notfound
        movzx   edi, byte [edi+' ']
        inc     esi
        cmp     edi, ecx
        jz      .f7.found
.f7.notfound:
        call    search_failed
        jmp     .done_redraw
.f7.found:
        push    ecx
        mov     ecx, edx
        call    pgfree
        mov     [ebp+viewer_data.buf_pos], esi
        call    viewer_set_curpos
        pop     ecx
        mov     dword [ebp+viewer_data.selected_len], ecx
        and     dword [ebp+viewer_data.selected_len+4], 0
        dec     ecx
        sub     eax, ecx
        sbb     edx, 0
        mov     dword [ebp+viewer_data.selected_start], eax
        mov     dword [ebp+viewer_data.selected_start+4], edx
        inc     eax
        jnz     @f
        inc     edx
@@:
        test    [find_in_file_dlgdata.flags_whole], 10h
        jz      @f
        sub     dword [ebp+viewer_data.selected_len], 2
        sbb     dword [ebp+viewer_data.selected_len+4], 0
        mov     dword [ebp+viewer_data.selected_start], eax
        mov     dword [ebp+viewer_data.selected_start+4], edx
        inc     eax
        jnz     @f
        inc     edx
@@:
        mov     dword [ebp+viewer_data.cur_pos], eax
        mov     dword [ebp+viewer_data.cur_pos+4], edx
        call    viewer_seek
        call    viewer_prev_newline
        jmp     .done_redraw
 
search_failed:
	mov	ecx, edx
	call	pgfree
	mov	eax, SearchString-1
	push	dword [eax-3]
	push	eax
	mov	byte [eax], '"'
@@:
	inc	eax
	cmp	byte [eax], 0
	jnz	@b
	mov	word [eax], '"'
	xchg	eax, [esp]
	push	eax
	push	aStringNotFound
	mov	eax, esp
	push	ContinueBtn
	push	1
	push	eax
	push	2
	push	aSearch
	call	SayErrTitle
	pop	eax
	pop	eax
	pop	ecx
	mov	byte [ecx], 0
	pop	dword [eax-3]
	ret
 
viewer_getname:
if lang eq ru
        mov     eax, 'à®á'
        stosd
        mov     eax, '¬®âà'
        stosd
        mov     eax, '    '
        stosd
        stosb
else
        mov     eax, 'View'
        stosd
        mov     eax, '    '
        stosd
        stosd
        stosb
end if
        jmp     viewedit_getname
editor_getname:
if lang eq ru
        mov     eax, '¥¤ '
        stosd
        mov     eax, 'ªâ®à'
        stosd
        mov     eax, '    '
        stosd
        stosb
else
        mov     eax, 'Edit'
        stosd
        mov     eax, '    '
        stosd
        stosd
        stosb
end if
viewedit_getname:
        sub     ecx, 13
        cmp     [ebp+viewer_data.hPlugin], 0
        jz      .native
        lea     esi, [ebp+viewer_data.hostname]
        push    ecx edi
        shr     ecx, 1
@@:
        lodsb
        test    al, al
        jz      @f
        stosb
        loop    @b
@@:
        sub     edi, [esp]
        sub     [esp+4], edi
        add     [esp], edi
        pop     edi ecx
        lea     esi, [ebp+viewer_data.filename]
        jmp     .main
.native:
        lea     esi, [ebp+viewer_data.filename]
        push    3
        pop     edx
@@:
        lodsb
        stosb
        dec     ecx
        test    al, al
        jz      .ret
        cmp     al, '/'
        jnz     @b
        dec     edx
        jnz     @b
.main:
        push    esi
@@:
        lodsb
        test    al, al
        jnz     @b
        sub     esi, [esp]
        dec     esi
        cmp     esi, ecx
        jbe     @f
        mov     al, '.'
        stosb
        stosb
        stosb
        sub     ecx, 3
        sub     esi, ecx
        add     [esp], esi
@@:
        pop     esi
@@:
        lodsb
        stosb
        test    al, al
        jnz     @b
.ret:
        ret
>

Rev 997	Rev 1122
1	virtual at 0	1	virtual at 0
2	viewer_data:	2	viewer_data:
3	.hPlugin dd ?	3	.hPlugin dd ?
4	.hFile dd ?	4	.hFile dd ?
5	.buf_start dq ?	5	.buf_start dq ?
6	.cur_pos dq ?	6	.cur_pos dq ?
7	.filesize dq ?	7	.filesize dq ?
8	.buf_pos dd ?	8	.buf_pos dd ?
9	.buf_size dd ?	9	.buf_size dd ?
10	.col dq ?	10	.col dq ?
11	.hWorkFile dd ?	11	.hWorkFile dd ?
12	.encoding db ?	12	.encoding db ?
13	.flags db ? ; & 1: hex mode	13	.flags db ? ; & 1: hex mode
14	; & 2: unwrap	14	; & 2: unwrap
15	; & 4: big-endian unicode	15	; & 4: big-endian unicode
16	.bEofReached db ?	16	.bEofReached db ?
17	rb 1	17	rb 1
18	.selected_start dq ?	18	.selected_start dq ?
19	.selected_len dq ?	19	.selected_len dq ?
20	align 200h	20	align 200h
21	.filename rb 1024	21	.filename rb 1024
22	.hostname rb 1024	22	.hostname rb 1024
23	.buf rb 16384	23	.buf rb 16384
24	.size = $	24	.size = $
25	end virtual	25	end virtual
26		26
27	view_file:	27	view_file:
28	push eax ecx	28	push eax ecx
29	mov ecx, viewer_data.size	29	mov ecx, viewer_data.size
30	mov edx, viewer_vtable	30	mov edx, viewer_vtable
31	call new_screen	31	call new_screen
32	pop ecx	32	pop ecx
33	test eax, eax	33	test eax, eax
34	pop eax	34	pop eax
35	jnz @f	35	jnz @f
36	ret	36	ret
37	@@:	37	@@:
38	test eax, eax	38	test eax, eax
39	jz .frompanel	39	jz .frompanel
40	and dword [ebp+viewer_data.hPlugin], 0	40	and dword [ebp+viewer_data.hPlugin], 0
41	and dword [ebp+viewer_data.hFile], 0	41	and dword [ebp+viewer_data.hFile], 0
42	mov byte [ebp+viewer_data.hostname], 0	42	mov byte [ebp+viewer_data.hostname], 0
43	lea edi, [ebp+viewer_data.filename]	43	lea edi, [ebp+viewer_data.filename]
44	push edi	44	push edi
45	@@:	45	@@:
46	lodsb	46	lodsb
47	stosb	47	stosb
48	test al, al	48	test al, al
49	jnz @b	49	jnz @b
50	jmp .namecopied	50	jmp .namecopied
51	.frompanel:	51	.frompanel:
52	mov eax, dword [esi+panel1_hPlugin-panel1_dir]	52	mov eax, dword [esi+panel1_hPlugin-panel1_dir]
53	mov [ebp+viewer_data.hPlugin], eax	53	mov [ebp+viewer_data.hPlugin], eax
54	test eax, eax	54	test eax, eax
55	jz .nocopyhostname	55	jz .nocopyhostname
56	lea edi, [ebp+viewer_data.hostname]	56	lea edi, [ebp+viewer_data.hostname]
57	push esi	57	push esi
58	mov eax, dword [esi+panel1_parents-panel1_dir]	58	mov eax, dword [esi+panel1_parents-panel1_dir]
59	mov esi, dword [esi+panel1_parents_sz-panel1_dir]	59	mov esi, dword [esi+panel1_parents_sz-panel1_dir]
60	add esi, eax	60	add esi, eax
61	@@:	61	@@:
62	dec esi	62	dec esi
63	cmp byte [esi-1], 0	63	cmp byte [esi-1], 0
64	jz @f	64	jz @f
65	cmp byte [esi-1], '/'	65	cmp byte [esi-1], '/'
66	jnz @b	66	jnz @b
67	@@:	67	@@:
68	lodsb	68	lodsb
69	stosb	69	stosb
70	test al, al	70	test al, al
71	jnz @b	71	jnz @b
72	pop esi	72	pop esi
73	.nocopyhostname:	73	.nocopyhostname:
74	mov eax, dword [esi+panel1_hFile-panel1_dir]	74	mov eax, dword [esi+panel1_hFile-panel1_dir]
75	mov [ebp+viewer_data.hFile], eax	75	mov [ebp+viewer_data.hFile], eax
76	lea edi, [ebp+viewer_data.filename]	76	lea edi, [ebp+viewer_data.filename]
77	push edi	77	push edi
78	@@:	78	@@:
79	lodsb	79	lodsb
80	test al, al	80	test al, al
81	jz @f	81	jz @f
82	stosb	82	stosb
83	jmp @b	83	jmp @b
84	@@:	84	@@:
85	lea esi, [ecx+40]	85	lea esi, [ecx+40]
86	cmp byte [edi-1], '/'	86	cmp byte [edi-1], '/'
87	jz @f	87	jz @f
88	mov al, '/'	88	mov al, '/'
89	stosb	89	stosb
90	@@:	90	@@:
91	lodsb	91	lodsb
92	stosb	92	stosb
93	test al, al	93	test al, al
94	jnz @b	94	jnz @b
95	.namecopied:	95	.namecopied:
96	xor eax, eax	96	xor eax, eax
97	mov [ebp+viewer_data.encoding], al ;encodings.cp866 = 0	97	mov [ebp+viewer_data.encoding], al ;encodings.cp866 = 0
98	mov [ebp+viewer_data.flags], al	98	mov [ebp+viewer_data.flags], al
99	mov dword [ebp+viewer_data.col], eax	99	mov dword [ebp+viewer_data.col], eax
100	mov dword [ebp+viewer_data.col+4], eax	100	mov dword [ebp+viewer_data.col+4], eax
101	call viewer_clear_selection	101	call viewer_clear_selection
102	pop eax	102	pop eax
103	push eax	-
104	mov ebx, attrinfo	103	mov ebx, attrinfo
105	mov [ebx+21], eax	104	mov [ebx+21], eax
-		105	mov [readinfo.name], eax
106	.attr_retry:	106	.attr_retry:
107	mov edx, [ebp+viewer_data.hPlugin]	107	mov edx, [ebp+viewer_data.hPlugin]
108	test edx, edx	108	test edx, edx
109	jz .attr_native	109	jz .attr_native
110	push ebp	110	push ebp
111	push dword [ebx+16]	111	push dword [ebx+16]
112	push eax	112	push eax
113	push [ebp+viewer_data.hFile]	113	push [ebp+viewer_data.hFile]
114	call [edx+PluginInfo.getattr]	114	call [edx+PluginInfo.getattr]
115	pop ebp	115	pop ebp
116	jmp .attr_common	116	jmp .attr_common
117	.attr_native:	117	.attr_native:
118	push 70	118	push 70
119	pop eax	119	pop eax
120	int 40h	120	int 40h
121	.attr_common:	121	.attr_common:
122	test eax, eax	122	test eax, eax
123	jz @f	123	jz @f
124	lea ebx, [ebp+viewer_data.filename]	124	lea ebx, [ebp+viewer_data.filename]
125	push ebx	125	push ebx
126	push aCannotReadFile	126	push aCannotReadFile
127	call get_error_msg	127	call get_error_msg
128	push eax	128	push eax
129	mov eax, esp	129	mov eax, esp
130	push RetryOrCancelBtn	130	push RetryOrCancelBtn
131	push 2	131	push 2
132	push eax	132	push eax
133	push 3	133	push 3
134	call SayErr	134	call SayErr
135	add esp, 3*4	135	add esp, 3*4
136	mov ebx, attrinfo	136	mov ebx, attrinfo
137	test eax, eax	137	test eax, eax
138	jz .attr_retry	138	jz .attr_retry
139	pop eax	139	pop eax
140	jmp delete_active_screen	140	jmp delete_active_screen
141	@@:	141	@@:
142	mov eax, dword [attrinfo.attr+32]	142	mov eax, dword [attrinfo.attr+32]
143	mov dword [ebp+viewer_data.filesize], eax	143	mov dword [ebp+viewer_data.filesize], eax
144	mov eax, dword [attrinfo.attr+36]	144	mov eax, dword [attrinfo.attr+36]
145	mov dword [ebp+viewer_data.filesize+4], eax	145	mov dword [ebp+viewer_data.filesize+4], eax
146	mov ebx, readinfo	146	mov ebx, readinfo
147	xor eax, eax	147	xor eax, eax
148	mov dword [ebx+readinfo.first-readinfo], eax	148	mov dword [ebx+readinfo.first-readinfo], eax
149	mov dword [ebx+readinfo.first+4-readinfo], eax	149	mov dword [ebx+readinfo.first+4-readinfo], eax
150	mov dword [ebp+viewer_data.buf_start], eax	150	mov dword [ebp+viewer_data.buf_start], eax
151	mov dword [ebp+viewer_data.buf_start+4], eax	151	mov dword [ebp+viewer_data.buf_start+4], eax
152	mov dword [ebp+viewer_data.cur_pos], eax	152	mov dword [ebp+viewer_data.cur_pos], eax
153	mov dword [ebp+viewer_data.cur_pos+4], eax	153	mov dword [ebp+viewer_data.cur_pos+4], eax
154	mov [ebx+readinfo.size-readinfo], 16384	154	mov [ebx+readinfo.size-readinfo], 16384
155	lea eax, [ebp+viewer_data.buf]	155	lea eax, [ebp+viewer_data.buf]
156	mov [readinfo.data], eax	156	mov [readinfo.data], eax
157	mov [ebp+viewer_data.buf_pos], eax	157	mov [ebp+viewer_data.buf_pos], eax
158	pop dword [readinfo.name]	-
159	mov eax, [ebp+viewer_data.hPlugin]	158	mov eax, [ebp+viewer_data.hPlugin]
160	test eax, eax	159	test eax, eax
161	jz .retry	160	jz .retry
162	push ebx ebp	161	push ebx ebp
163	push O_READ	162	push O_READ
164	push dword [readinfo.name]	163	push dword [readinfo.name]
165	push [ebp+viewer_data.hFile]	164	push [ebp+viewer_data.hFile]
166	call [eax+PluginInfo.open]	165	call [eax+PluginInfo.open]
167	pop ebp ebx	166	pop ebp ebx
168	mov [ebp+viewer_data.hWorkFile], eax	167	mov [ebp+viewer_data.hWorkFile], eax
169	test eax, eax	168	test eax, eax
170	jnz .retry	169	jnz .retry
171	..openerr_in_screen:	170	..openerr_in_screen:
172	push ContinueBtn	171	push ContinueBtn
173	push 1	172	push 1
174	push aCannotOpenFile_ptr	173	push aCannotOpenFile_ptr
175	push 1	174	push 1
176	call SayErr	175	call SayErr
177	jmp delete_active_screen	176	jmp delete_active_screen
178	.retry:	177	.retry:
179	mov eax, [ebp+viewer_data.hPlugin]	178	mov eax, [ebp+viewer_data.hPlugin]
180	test eax, eax	179	test eax, eax
181	jz .read_native	180	jz .read_native
182	push ebp	181	push ebp
183	push 16384	182	push 16384
184	push [ebx+readinfo.data-readinfo]	183	push [ebx+readinfo.data-readinfo]
185	push [ebp+viewer_data.hWorkFile]	184	push [ebp+viewer_data.hWorkFile]
186	call [eax+PluginInfo.read]	185	call [eax+PluginInfo.read]
187	pop ebp	186	pop ebp
188	cmp eax, -1	187	cmp eax, -1
189	jz .readok ; let's hope that plugin says error itself	188	jz .readok ; let's hope that plugin says error itself
190	mov [ebp+viewer_data.buf_size], eax	189	mov [ebp+viewer_data.buf_size], eax
191	mov ebx, eax	190	mov ebx, eax
192	jmp .readok	191	jmp .readok
193	.read_native:	192	.read_native:
194	push 70	193	push 70
195	pop eax	194	pop eax
196	int 40h	195	int 40h
197	mov [ebp+viewer_data.buf_size], ebx	196	mov [ebp+viewer_data.buf_size], ebx
198	test eax, eax	197	test eax, eax
199	jz .readok	198	jz .readok
200	cmp eax, 6	199	cmp eax, 6
201	jz .readok	200	jz .readok
202	.readerr:	201	.readerr:
203	lea ebx, [ebp+viewer_data.filename]	202	lea ebx, [ebp+viewer_data.filename]
204	push ebx	203	push ebx
205	push aCannotReadFile	204	push aCannotReadFile
206	call get_error_msg	205	call get_error_msg
207	push eax	206	push eax
208	mov eax, esp	207	mov eax, esp
209	push RetryOrCancelBtn	208	push RetryOrCancelBtn
210	push 2	209	push 2
211	push eax	210	push eax
212	push 3	211	push 3
213	call SayErr	212	call SayErr
214	add esp, 3*4	213	add esp, 3*4
215	mov ebx, readinfo	214	mov ebx, readinfo
216	test eax, eax	215	test eax, eax
217	jz .attr_retry	216	jz .attr_retry
218	jmp delete_active_screen	217	jmp delete_active_screen
219	.readok:	218	.readok:
220	cmp ebx, 2	219	cmp ebx, 2
221	jb .nounicode	220	jb .nounicode
222	cmp word [ebp+viewer_data.buf], 0xFEFF	221	cmp word [ebp+viewer_data.buf], 0xFEFF
223	jz @f	222	jz @f
224	cmp word [ebp+viewer_data.buf], 0xFFFE	223	cmp word [ebp+viewer_data.buf], 0xFFFE
225	jnz .nounicode	224	jnz .nounicode
226	or byte [ebp+viewer_data.flags], 4	225	or byte [ebp+viewer_data.flags], 4
227	@@:	226	@@:
228	mov [ebp+viewer_data.encoding], encodings.unicode	227	mov [ebp+viewer_data.encoding], encodings.unicode
229	.nounicode:	228	.nounicode:
230	viewer_OnRedraw:	229	viewer_OnRedraw:
231	or [cursor_x], -1	230	or [cursor_x], -1
232	or [cursor_y], -1	231	or [cursor_y], -1
233	call viewer_set_keybar	232	call viewer_set_keybar
234	call viewer_draw_text	233	call viewer_draw_text
235	ret	234	ret
236		235
237	viewer_skip_unicode_marker:	236	viewer_skip_unicode_marker:
238	cmp [ebp+viewer_data.encoding], encodings.unicode	237	cmp [ebp+viewer_data.encoding], encodings.unicode
239	jnz @f	238	jnz @f
240	cmp [bForHex], 0	239	cmp [bForHex], 0
241	jnz @f	240	jnz @f
242	cmp dword [ebp+viewer_data.buf_start], 0	241	cmp dword [ebp+viewer_data.buf_start], 0
243	jnz @f	242	jnz @f
244	cmp dword [ebp+viewer_data.buf_start+4], 0	243	cmp dword [ebp+viewer_data.buf_start+4], 0
245	jnz @f	244	jnz @f
246	lea eax, [ebp+viewer_data.buf]	245	lea eax, [ebp+viewer_data.buf]
247	cmp eax, [ebp+viewer_data.buf_pos]	246	cmp eax, [ebp+viewer_data.buf_pos]
248	jnz @f	247	jnz @f
249	cmp word [eax], 0xFFFE	248	cmp word [eax], 0xFFFE
250	jz .skip	249	jz .skip
251	cmp word [eax], 0xFEFF	250	cmp word [eax], 0xFEFF
252	jnz @f	251	jnz @f
253	.skip:	252	.skip:
254	add [ebp+viewer_data.buf_pos], 2	253	add [ebp+viewer_data.buf_pos], 2
255	@@:	254	@@:
256	ret	255	ret
257		256
258	viewer_load_next:	257	viewer_load_next:
259	mov eax, dword [ebp+viewer_data.buf_start]	258	mov eax, dword [ebp+viewer_data.buf_start]
260	add eax, 8192	259	add eax, 8192
261	mov dword [ebp+viewer_data.buf_start], eax	260	mov dword [ebp+viewer_data.buf_start], eax
262	mov edx, dword [ebp+viewer_data.buf_start+4]	261	mov edx, dword [ebp+viewer_data.buf_start+4]
263	adc edx, 0	262	adc edx, 0
264	mov dword [ebp+viewer_data.buf_start+4], edx	263	mov dword [ebp+viewer_data.buf_start+4], edx
265	add eax, 16384-8192	264	add eax, 16384-8192
266	adc edx, 0	265	adc edx, 0
267	mov dword [readinfo.first], eax	266	mov dword [readinfo.first], eax
268	mov dword [readinfo.first+4], edx	267	mov dword [readinfo.first+4], edx
269	mov dword [readinfo.size], 8192	268	mov dword [readinfo.size], 8192
270	lea edi, [ebp+viewer_data.buf]	269	lea edi, [ebp+viewer_data.buf]
271	lea esi, [edi+8192]	270	lea esi, [edi+8192]
272	mov ecx, (16384-8192)/4	271	mov ecx, (16384-8192)/4
273	rep movsd	272	rep movsd
274	mov [readinfo.data], edi	273	mov [readinfo.data], edi
275	lea eax, [ebp+viewer_data.filename]	274	lea eax, [ebp+viewer_data.filename]
276	mov [readinfo.name], eax	275	mov [readinfo.name], eax
277	.readretry:	276	.readretry:
278	mov ebx, readinfo	277	mov ebx, readinfo
279	mov eax, [ebp+viewer_data.hPlugin]	278	mov eax, [ebp+viewer_data.hPlugin]
280	test eax, eax	279	test eax, eax
281	jz .native	280	jz .native
282	push ecx ebp	281	push ecx ebp
283	push 8192	282	push 8192
284	push [ebx+readinfo.data-readinfo]	283	push [ebx+readinfo.data-readinfo]
285	push [ebp+viewer_data.hWorkFile]	284	push [ebp+viewer_data.hWorkFile]
286	call [eax+PluginInfo.read]	285	call [eax+PluginInfo.read]
287	pop ebp ecx	286	pop ebp ecx
288	mov ebx, eax	287	mov ebx, eax
289	cmp eax, -1	288	cmp eax, -1
290	jnz .readok	289	jnz .readok
291	xor ebx, ebx	290	xor ebx, ebx
292	jmp .readok	291	jmp .readok
293	.native:	292	.native:
294	push 70	293	push 70
295	pop eax	294	pop eax
296	int 40h	295	int 40h
297	test eax, eax	296	test eax, eax
298	jz .readok	297	jz .readok
299	cmp eax, 6	298	cmp eax, 6
300	jz .readok	299	jz .readok
301	.readerr:	300	.readerr:
302	call ask_retry_ignore	301	call ask_retry_ignore
303	jz .readretry	302	jz .readretry
304	.readok:	303	.readok:
305	sub [ebp+viewer_data.buf_pos], 8192	304	sub [ebp+viewer_data.buf_pos], 8192
306	add ebx, 16384-8192	305	add ebx, 16384-8192
307	mov [ebp+viewer_data.buf_size], ebx	306	mov [ebp+viewer_data.buf_size], ebx
308	mov eax, [ebp+viewer_data.buf_pos]	307	mov eax, [ebp+viewer_data.buf_pos]
309	cmp ebx, 16384-8192	308	cmp ebx, 16384-8192
310	ret	309	ret
311		310
312	viewer_get_next_char:	311	viewer_get_next_char:
313	pusha	312	pusha
314	call viewer_skip_unicode_marker	313	call viewer_skip_unicode_marker
315	mov eax, [ebp+viewer_data.buf_pos]	314	mov eax, [ebp+viewer_data.buf_pos]
316	lea ecx, [ebp+viewer_data.buf]	315	lea ecx, [ebp+viewer_data.buf]
317	add ecx, [ebp+viewer_data.buf_size]	316	add ecx, [ebp+viewer_data.buf_size]
318	cmp eax, ecx	317	cmp eax, ecx
319	jb .buffered	318	jb .buffered
320	mov al, ' '	319	mov al, ' '
321	sub ecx, ebp	320	sub ecx, ebp
322	cmp ecx, viewer_data.buf + 16384	321	cmp ecx, viewer_data.buf + 16384
323	jb .err	322	jb .err
324	call viewer_load_next	323	call viewer_load_next
325	jnz .buffered	324	jnz .buffered
326	.err:	325	.err:
327	stc	326	stc
328	popa	327	popa
329	ret	328	ret
330	.buffered:	329	.buffered:
331	cmp [ebp+viewer_data.encoding], encodings.unicode	330	cmp [ebp+viewer_data.encoding], encodings.unicode
332	jz .unicode	331	jz .unicode
333	mov al, [eax]	332	mov al, [eax]
334	.done:	333	.done:
335	mov [esp+28], al	334	mov [esp+28], al
336	inc [ebp+viewer_data.buf_pos]	335	inc [ebp+viewer_data.buf_pos]
337	clc	336	clc
338	popa	337	popa
339	ret	338	ret
340		339
341	.unicode:	340	.unicode:
342	inc [ebp+viewer_data.buf_pos]	341	inc [ebp+viewer_data.buf_pos]
343	cmp [bForHex], 0	342	cmp [bForHex], 0
344	jnz @f	343	jnz @f
345	call read_unicode_char	344	call read_unicode_char
346	jmp .done	345	jmp .done
347	@@:	346	@@:
348	mov ax, [eax]	347	mov ax, [eax]
349	mov [esp+29], ah	348	mov [esp+29], ah
350	jmp .done	349	jmp .done
351		350
352	viewer_get_prev_char:	351	viewer_get_prev_char:
353	pusha	352	pusha
354	lea ecx, [ebp+viewer_data.buf]	353	lea ecx, [ebp+viewer_data.buf]
355	cmp [ebp+viewer_data.buf_pos], ecx	354	cmp [ebp+viewer_data.buf_pos], ecx
356	ja .buffered	355	ja .buffered
357	mov eax, dword [ebp+viewer_data.buf_start]	356	mov eax, dword [ebp+viewer_data.buf_start]
358	mov edx, dword [ebp+viewer_data.buf_start+4]	357	mov edx, dword [ebp+viewer_data.buf_start+4]
359	test eax, eax	358	test eax, eax
360	jnz @f	359	jnz @f
361	test edx, edx	360	test edx, edx
362	jnz @f	361	jnz @f
363	stc	362	stc
364	jmp .ret	363	jmp .ret
365	@@:	364	@@:
366	sub eax, 8192	365	sub eax, 8192
367	sbb edx, 0	366	sbb edx, 0
368	jnc @f	367	jnc @f
369	xor eax, eax	368	xor eax, eax
370	xor edx, edx	369	xor edx, edx
371	@@:	370	@@:
372	call viewer_seek	371	call viewer_seek
373	add [ebp+viewer_data.buf_pos], 8192	372	add [ebp+viewer_data.buf_pos], 8192
374	.buffered:	373	.buffered:
375	mov eax, [ebp+viewer_data.buf_pos]	374	mov eax, [ebp+viewer_data.buf_pos]
376	dec eax	375	dec eax
377	cmp [ebp+viewer_data.encoding], encodings.unicode	376	cmp [ebp+viewer_data.encoding], encodings.unicode
378	jz .unicode	377	jz .unicode
379	mov [ebp+viewer_data.buf_pos], eax	378	mov [ebp+viewer_data.buf_pos], eax
380	mov al, [eax]	379	mov al, [eax]
381	mov [esp+28], al	380	mov [esp+28], al
382	.done:	381	.done:
383	clc	382	clc
384	.ret:	383	.ret:
385	popa	384	popa
386	ret	385	ret
387		386
388	.unicode:	387	.unicode:
389	dec eax	388	dec eax
390	mov [ebp+viewer_data.buf_pos], eax	389	mov [ebp+viewer_data.buf_pos], eax
391	call read_unicode_char	390	call read_unicode_char
392	jmp .done	391	jmp .done
393		392
394	read_unicode_char:	393	read_unicode_char:
395	mov ax, [eax]	394	mov ax, [eax]
396	uni2ansi_char:	395	uni2ansi_char:
397	test [ebp+viewer_data.flags], 4	396	test [ebp+viewer_data.flags], 4
398	jz @f	397	jz @f
399	xchg al, ah	398	xchg al, ah
400	@@:	399	@@:
401	cmp ax, 0x80	400	cmp ax, 0x80
402	jb .ret	401	jb .ret
403	cmp ax, 0x401	402	cmp ax, 0x401
404	jz .yo1	403	jz .yo1
405	cmp ax, 0x451	404	cmp ax, 0x451
406	jz .yo2	405	jz .yo2
407	cmp ax, 0x410	406	cmp ax, 0x410
408	jb .unk	407	jb .unk
409	cmp ax, 0x440	408	cmp ax, 0x440
410	jb .rus1	409	jb .rus1
411	cmp ax, 0x450	410	cmp ax, 0x450
412	jb .rus2	411	jb .rus2
413	.unk:	412	.unk:
414	mov al, ' '	413	mov al, ' '
415	.ret:	414	.ret:
416	ret	415	ret
417	.yo1:	416	.yo1:
418	mov al, 'ð'	417	mov al, 'ð'
419	ret	418	ret
420	.yo2:	419	.yo2:
421	mov al, 'ñ'	420	mov al, 'ñ'
422	ret	421	ret
423	.rus1:	422	.rus1:
424	; 0x410-0x43F -> 0x80-0xAF	423	; 0x410-0x43F -> 0x80-0xAF
425	add al, 0x70	424	add al, 0x70
426	ret	425	ret
427	.rus2:	426	.rus2:
428	; 0x440-0x44F -> 0xE0-0xEF	427	; 0x440-0x44F -> 0xE0-0xEF
429	add al, 0xA0	428	add al, 0xA0
430	ret	429	ret
431		430
432	viewer_clear_selection:	431	viewer_clear_selection:
433	and dword [ebp+viewer_data.selected_start], 0	432	and dword [ebp+viewer_data.selected_start], 0
434	and dword [ebp+viewer_data.selected_start+4], 0	433	and dword [ebp+viewer_data.selected_start+4], 0
435	and dword [ebp+viewer_data.selected_len], 0	434	and dword [ebp+viewer_data.selected_len], 0
436	and dword [ebp+viewer_data.selected_len+4], 0	435	and dword [ebp+viewer_data.selected_len+4], 0
437	ret	436	ret
438		437
439	fld_uint64:	438	fld_uint64:
440	fild qword [eax]	439	fild qword [eax]
441	test byte [eax+7], 80h	440	test byte [eax+7], 80h
442	jz .ret	441	jz .ret
443	fadd [@f]	442	fadd [@f]
444	.ret:	443	.ret:
445	ret	444	ret
446	@@ dq 18446744073709551616.0 ;0x10000000000000000	445	@@ dq 18446744073709551616.0 ;0x10000000000000000
447		446
448	viewer_draw_text:	447	viewer_draw_text:
449	call viewer_seek_to_current	448	call viewer_seek_to_current
450	xor eax, eax	449	xor eax, eax
451	xor edx, edx	450	xor edx, edx
452	call get_console_ptr	451	call get_console_ptr
453	mov ah, [view_status_color]	452	mov ah, [view_status_color]
454	mov ecx, [cur_width]	453	mov ecx, [cur_width]
455	sub ecx, 44	454	sub ecx, 44
456	cmp ecx, 20	455	cmp ecx, 20
457	jae @f	456	jae @f
458	mov cl, 20	457	mov cl, 20
459	@@:	458	@@:
460	call viewedit_draw_filename	459	call viewedit_draw_filename
461	add ecx, 11	460	add ecx, 11
462	rep stosw	461	rep stosw
463	movzx esi, [ebp+viewer_data.encoding]	462	movzx esi, [ebp+viewer_data.encoding]
464	lea esi, [encodings.names+esi*8]	463	lea esi, [encodings.names+esi*8]
465	push edi esi	464	push edi esi
466	dec edi	465	dec edi
467	dec edi	466	dec edi
468	std	467	std
469	add esi, 8	468	add esi, 8
470	@@:	469	@@:
471	dec esi	470	dec esi
472	cmp byte [esi], ' '	471	cmp byte [esi], ' '
473	jz @b	472	jz @b
474	@@:	473	@@:
475	lodsb	474	lodsb
476	stosw	475	stosw
477	cmp esi, [esp]	476	cmp esi, [esp]
478	jae @b	477	jae @b
479	cld	478	cld
480	pop esi edi	479	pop esi edi
481	mov al, ' '	480	mov al, ' '
482	mov cl, 13	481	mov cl, 13
483	rep stosw	482	rep stosw
484	std	483	std
485	push edi	484	push edi
486	mov edx, dword [ebp+viewer_data.filesize+4]	485	mov edx, dword [ebp+viewer_data.filesize+4]
487	mov eax, dword [ebp+viewer_data.filesize]	486	mov eax, dword [ebp+viewer_data.filesize]
488	mov cl, 10	487	mov cl, 10
489	@@:	488	@@:
490	push eax	489	push eax
491	mov eax, edx	490	mov eax, edx
492	xor edx, edx	491	xor edx, edx
493	div ecx	492	div ecx
494	xchg eax, [esp]	493	xchg eax, [esp]
495	div ecx	494	div ecx
496	xchg eax, edx	495	xchg eax, edx
497	add al, '0'	496	add al, '0'
498	mov ah, [view_status_color]	497	mov ah, [view_status_color]
499	stosw	498	stosw

Subversion Repositories Kolibri OS

(root)/programs/fs/kfar/trunk/viewer.inc – Rev 997 → 1122