WebSVN – Kolibri OS – Diff – /kernel/trunk/video/vesa20.inc


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;                                                              ;;
;; Copyright (C) KolibriOS team 2004-2008. All rights reserved. ;;
;; Distributed under terms of the GNU General Public License    ;;
;;                                                              ;;
;;  VESA20.INC                                                  ;;
;;                                                              ;;
;;  Vesa 2.0 functions for MenuetOS                             ;;
;;                                                              ;;
;;  Copyright 2002 Ville Turjanmaa                              ;;
;;  Alexey, kgaz@crosswindws.net                                ;;
;;  - Voodoo compatible graphics                                ;;
;;  Juan M. Caravaca                                            ;;
;;  - Graphics optimimizations eg. drawline                     ;;
;;                                                              ;;
;;  See file COPYING for details                                ;;
;;                                                              ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 
$Revision: 2438 $
 
 
; If you're planning to write your own video driver I suggest
; you replace the VESA12.INC file and see those instructions.
 
;Screen_Max_X             equ     0xfe00
;Screen_Max_Y            equ     0xfe04
;BytesPerScanLine        equ     0xfe08
;LFBAddress              equ     0xfe80
;ScreenBPP               equ     0xfbf1
 
 
 
;-----------------------------------------------------------------------------
; getpixel
;
; in:
; eax = x coordinate
; ebx = y coordinate
;
; ret:
; ecx = 00 RR GG BB
;-----------------------------------------------------------------------------
align 4
getpixel:
        push    eax ebx edx edi
        call    dword [GETPIXEL]
        pop     edi edx ebx eax
        ret
;-----------------------------------------------------------------------------
align 4
Vesa20_getpixel24:
; eax = x
; ebx = y
;--------------------------------------
; check mouse area for putpixel
        test    ecx, 0x04000000  ; don't load to mouseunder area
        jnz     .no_mouseunder
        call    [_display.check_m_pixel]
        test    ecx, ecx        ;0xff000000
        jnz     @f
.no_mouseunder:
;--------------------------------------
        imul    ebx, [BytesPerScanLine] ; ebx = y * y multiplier
        lea     edi, [eax+eax*2]; edi = x*3
        add     edi, ebx      ; edi = x*3+(y*y multiplier)
        mov     ecx, [LFB_BASE+edi]
;--------------------------------------
align 4
@@:
        and     ecx, 0xffffff
        ret
;-----------------------------------------------------------------------------
align 4
Vesa20_getpixel32:
;--------------------------------------
; check mouse area for putpixel
        test    ecx, 0x04000000  ; don't load to mouseunder area
        jnz     .no_mouseunder
        call    [_display.check_m_pixel]
        test    ecx, ecx        ;0xff000000
        jnz     @f
.no_mouseunder:
;--------------------------------------
        imul    ebx, [BytesPerScanLine] ; ebx = y * y multiplier
        lea     edi, [ebx+eax*4]; edi = x*4+(y*y multiplier)
        mov     ecx, [LFB_BASE+edi]
;--------------------------------------
align 4
@@:
        and     ecx, 0xffffff
        ret
;-----------------------------------------------------------------------------
virtual at esp
 putimg:
   .real_sx        dd ?
   .real_sy        dd ?
   .image_sx       dd ?
   .image_sy       dd ?
   .image_cx       dd ?
   .image_cy       dd ?
   .pti            dd ?
   .abs_cx         dd ?
   .abs_cy         dd ?
   .line_increment dd ?
   .winmap_newline dd ?
   .screen_newline dd ?
   .real_sx_and_abs_cx dd ?
   .real_sy_and_abs_cy dd ?
   .stack_data = 4*14
   .edi         dd      ?
   .esi         dd      ?
   .ebp         dd      ?
   .esp         dd      ?
   .ebx         dd      ?
   .edx         dd      ?
   .ecx         dd      ?
   .eax         dd      ?
   .ret_addr    dd      ?
   .arg_0       dd      ?
end virtual
;-----------------------------------------------------------------------------
align 16
; ebx = pointer
; ecx = size [x|y]
; edx = coordinates [x|y]
; ebp = pointer to 'get' function
; esi = pointer to 'init' function
; edi = parameter for 'get' function
vesa20_putimage:
        pushad
        sub     esp, putimg.stack_data
; save pointer to image
        mov     [putimg.pti], ebx
; unpack the size
        mov     eax, ecx
        and     ecx, 0xFFFF
        shr     eax, 16
        mov     [putimg.image_sx], eax
        mov     [putimg.image_sy], ecx
; unpack the coordinates
        mov     eax, edx
        and     edx, 0xFFFF
        shr     eax, 16
        mov     [putimg.image_cx], eax
        mov     [putimg.image_cy], edx
; calculate absolute (i.e. screen) coordinates
        mov     eax, [TASK_BASE]
        mov     ebx, [eax-twdw + WDATA.box.left]
        add     ebx, [putimg.image_cx]
        mov     [putimg.abs_cx], ebx
        mov     ebx, [eax-twdw + WDATA.box.top]
        add     ebx, [putimg.image_cy]
        mov     [putimg.abs_cy], ebx
; real_sx = MIN(wnd_sx-image_cx, image_sx);
        mov     ebx, [eax-twdw + WDATA.box.width]; ebx = wnd_sx
; \begin{diamond}[20.08.2006]
; note that WDATA.box.width is one pixel less than real window x-size
        inc     ebx
; \end{diamond}[20.08.2006]
        sub     ebx, [putimg.image_cx]
        ja      @f
        add     esp, putimg.stack_data
        popad
        ret
;--------------------------------------
align 4
@@:
        cmp     ebx, [putimg.image_sx]
        jbe     .end_x
        mov     ebx, [putimg.image_sx]
;--------------------------------------
align 4
.end_x:
        mov     [putimg.real_sx], ebx
; init real_sy
        mov     ebx, [eax-twdw + WDATA.box.height]; ebx = wnd_sy
; \begin{diamond}[20.08.2006]
        inc     ebx
; \end{diamond}[20.08.2006]
        sub     ebx, [putimg.image_cy]
        ja      @f
        add     esp, putimg.stack_data
        popad
        ret
;--------------------------------------
align 4
@@:
        cmp     ebx, [putimg.image_sy]
        jbe     .end_y
        mov     ebx, [putimg.image_sy]
;--------------------------------------
align 4
.end_y:
        mov     [putimg.real_sy], ebx
; line increment
        mov     eax, [putimg.image_sx]
        mov     ecx, [putimg.real_sx]
        sub     eax, ecx
;;     imul    eax, [putimg.source_bpp]
;     lea     eax, [eax + eax * 2]
        call    esi
        add     eax, [putimg.arg_0]
        mov     [putimg.line_increment], eax
; winmap new line increment
        mov     eax, [Screen_Max_X]
        inc     eax
        sub     eax, [putimg.real_sx]
        mov     [putimg.winmap_newline], eax
; screen new line increment
        mov     eax, [BytesPerScanLine]
        movzx   ebx, byte [ScreenBPP]
        shr     ebx, 3
        imul    ecx, ebx
        sub     eax, ecx
        mov     [putimg.screen_newline], eax
; pointer to image
        mov     esi, [putimg.pti]
; pointer to screen
        mov     edx, [putimg.abs_cy]
        imul    edx, [BytesPerScanLine]
        mov     eax, [putimg.abs_cx]
        movzx   ebx, byte [ScreenBPP]
        shr     ebx, 3
        imul    eax, ebx
        add     edx, eax
; pointer to pixel map
        mov     eax, [putimg.abs_cy]
        imul    eax, [Screen_Max_X]
        add     eax, [putimg.abs_cy]
        add     eax, [putimg.abs_cx]
        add     eax, [_WinMapAddress]
        xchg    eax, ebp
;--------------------------------------
        mov     ecx, [putimg.real_sx]
        add     ecx, [putimg.abs_cx]
        mov     [putimg.real_sx_and_abs_cx], ecx
        mov     ecx, [putimg.real_sy]
        add     ecx, [putimg.abs_cy]
        mov     [putimg.real_sy_and_abs_cy], ecx
;--------------------------------------
; get process number
        mov     ebx, [CURRENT_TASK]
        cmp     byte [ScreenBPP], 32
        je      put_image_end_32
;--------------------------------------
put_image_end_24:
        mov     edi, [putimg.real_sy]
        cmp     [_display.select_cursor], 0
        jne     put_image_end_24_new
;--------------------------------------
align 4
.new_line:
        mov     ecx, [putimg.real_sx]
;--------------------------------------
align 4
.new_x:
        push    [putimg.edi]
        mov     eax, [putimg.ebp+4]
        call    eax
        cmp     [ebp], bl
        jne     .skip
;--------------------------------------
        push    ecx
 
        neg     ecx
        add     ecx, [putimg.real_sx_and_abs_cx + 4]
        shl     ecx, 16
        add     ecx, [putimg.real_sy_and_abs_cy + 4]
        sub     ecx, edi
 
; check mouse area for putpixel
        call    check_mouse_area_for_putpixel
        pop     ecx
; store to real LFB
        mov     [LFB_BASE+edx], ax
        shr     eax, 16
        mov     [LFB_BASE+edx+2], al
;--------------------------------------
align 4
.skip:
        add     edx, 3
        inc     ebp
        dec     ecx
        jnz     .new_x
 
        add     esi, [putimg.line_increment]
        add     edx, [putimg.screen_newline];[BytesPerScanLine]
        add     ebp, [putimg.winmap_newline];[Screen_Max_X]
 
        cmp     [putimg.ebp], putimage_get1bpp
        jz      .correct
        cmp     [putimg.ebp], putimage_get2bpp
        jz      .correct
        cmp     [putimg.ebp], putimage_get4bpp
        jnz     @f
;--------------------------------------
align 4
.correct:
        mov     eax, [putimg.edi]
        mov     byte [eax], 80h
;--------------------------------------
align 4
@@:
        dec     edi
        jnz     .new_line
;--------------------------------------
align 4
.finish:
        add     esp, putimg.stack_data
        popad
        ret
;--------------------------------------
align 4
put_image_end_24_new:
;--------------------------------------
align 4
.new_line:
        mov     ecx, [putimg.real_sx]
;--------------------------------------
align 4
.new_x:
        push    [putimg.edi]
        mov     eax, [putimg.ebp+4]
        call    eax
        cmp     [ebp], bl
        jne     .skip
;--------------------------------------
        push    ecx
        mov     ecx, [putimg.real_sy_and_abs_cy + 4]
        sub     ecx, edi
;--------------------------------------
; check for Y
        cmp     cx, [Y_UNDER_subtraction_CUR_hot_y]
        jb      .no_mouse_area
 
        cmp     cx, [Y_UNDER_sub_CUR_hot_y_add_curh]
        jae     .no_mouse_area
 
        rol     ecx, 16
        add     ecx, [putimg.real_sx_and_abs_cx + 4]
        sub     ecx, [esp]
;--------------------------------------
; check for X
        cmp     cx, [X_UNDER_subtraction_CUR_hot_x]
        jb      .no_mouse_area
 
        cmp     cx, [X_UNDER_sub_CUR_hot_x_add_curh]
        jae     .no_mouse_area
;--------------------------------------
; check mouse area for putpixel
        call    check_mouse_area_for_putpixel_new.1
;--------------------------------------
align 4
.no_mouse_area:
        pop     ecx
; store to real LFB
        mov     [LFB_BASE+edx], ax
        shr     eax, 16
        mov     [LFB_BASE+edx+2], al
;--------------------------------------
align 4
.skip:
        add     edx, 3
        inc     ebp
        dec     ecx
        jnz     .new_x
 
        add     esi, [putimg.line_increment]
        add     edx, [putimg.screen_newline];[BytesPerScanLine]
        add     ebp, [putimg.winmap_newline];[Screen_Max_X]
 
        cmp     [putimg.ebp], putimage_get1bpp
        jz      .correct
        cmp     [putimg.ebp], putimage_get2bpp
        jz      .correct
        cmp     [putimg.ebp], putimage_get4bpp
        jnz     @f
;--------------------------------------
align 4
.correct:
        mov     eax, [putimg.edi]
        mov     byte [eax], 80h
;--------------------------------------
align 4
@@:
        dec     edi
        jnz     .new_line
        jmp     put_image_end_24.finish
;------------------------------------------------------------------------------
align 4
put_image_end_32:
        mov     edi, [putimg.real_sy]
        cmp     [_display.select_cursor], 0
        jne     put_image_end_32_new
;--------------------------------------
align 4
.new_line:
        mov     ecx, [putimg.real_sx]
;--------------------------------------
align 4
.new_x:
        push    [putimg.edi]
        mov     eax, [putimg.ebp+4]
        call    eax
        cmp     [ebp], bl
        jne     .skip
;--------------------------------------
        push    ecx
 
        neg     ecx
        add     ecx, [putimg.real_sx_and_abs_cx + 4]
        shl     ecx, 16
        add     ecx, [putimg.real_sy_and_abs_cy + 4]
        sub     ecx, edi
 
; check mouse area for putpixel
        call    check_mouse_area_for_putpixel
        pop     ecx
; store to real LFB
        mov     [LFB_BASE+edx], eax
;--------------------------------------
align 4
.skip:
        add     edx, 4
        inc     ebp
        dec     ecx
        jnz     .new_x
 
        add     esi, [putimg.line_increment]
        add     edx, [putimg.screen_newline];[BytesPerScanLine]
        add     ebp, [putimg.winmap_newline];[Screen_Max_X]
 
        cmp     [putimg.ebp], putimage_get1bpp
        jz      .correct
        cmp     [putimg.ebp], putimage_get2bpp
        jz      .correct
        cmp     [putimg.ebp], putimage_get4bpp
        jnz     @f
;--------------------------------------
align 4
.correct:
        mov     eax, [putimg.edi]
        mov     byte [eax], 80h
;--------------------------------------
align 4
@@:
        dec     edi
        jnz     .new_line
;--------------------------------------
align 4
.finish:
        add     esp, putimg.stack_data
        popad
        cmp     [SCR_MODE], dword 0x12
        jne     @f
        call    VGA__putimage
;--------------------------------------
align 4
@@:
        mov     [EGA_counter], 1
        ret
;--------------------------------------
align 4
put_image_end_32_new:
;--------------------------------------
align 4
.new_line:
        mov     ecx, [putimg.real_sx]
;--------------------------------------
align 4
.new_x:
        push    [putimg.edi]
        mov     eax, [putimg.ebp+4]
        call    eax
        cmp     [ebp], bl
        jne     .skip
;--------------------------------------
        push    ecx
        mov     ecx, [putimg.real_sy_and_abs_cy + 4]
        sub     ecx, edi
;--------------------------------------
; check for Y
        cmp     cx, [Y_UNDER_subtraction_CUR_hot_y]
        jb      .no_mouse_area
 
        cmp     cx, [Y_UNDER_sub_CUR_hot_y_add_curh]
        jae     .no_mouse_area
 
        rol     ecx, 16
        add     ecx, [putimg.real_sx_and_abs_cx + 4]
        sub     ecx, [esp]
;--------------------------------------
; check for X
        cmp     cx, [X_UNDER_subtraction_CUR_hot_x]
        jb      .no_mouse_area
 
        cmp     cx, [X_UNDER_sub_CUR_hot_x_add_curh]
        jae     .no_mouse_area
;--------------------------------------
; check mouse area for putpixel
        call    check_mouse_area_for_putpixel_new.1
;--------------------------------------
align 4
.no_mouse_area:
        pop     ecx
; store to real LFB
        mov     [LFB_BASE+edx], eax
;--------------------------------------
align 4
.skip:
        add     edx, 4
        inc     ebp
        dec     ecx
        jnz     .new_x
 
        add     esi, [putimg.line_increment]
        add     edx, [putimg.screen_newline];[BytesPerScanLine]
        add     ebp, [putimg.winmap_newline];[Screen_Max_X]
 
        cmp     [putimg.ebp], putimage_get1bpp
        jz      .correct
        cmp     [putimg.ebp], putimage_get2bpp
        jz      .correct
        cmp     [putimg.ebp], putimage_get4bpp
        jnz     @f
;--------------------------------------
align 4
.correct:
        mov     eax, [putimg.edi]
        mov     byte [eax], 80h
;--------------------------------------
align 4
@@:
        dec     edi
        jnz     .new_line
        jmp     put_image_end_32.finish
;------------------------------------------------------------------------------
align 4
__sys_putpixel:
 
; eax = x coordinate
; ebx = y coordinate
; ecx = ?? RR GG BB    ; 0x01000000 negation
                       ; 0x02000000 used for draw_rectangle without top line
                       ;            for example drawwindow_III and drawwindow_IV
; edi = 0x00000001 force
 
;;;        mov  [novesachecksum], dword 0
        pushad
        cmp     [Screen_Max_X], eax
        jb      .exit
        cmp     [Screen_Max_Y], ebx
        jb      .exit
        test    edi, 1           ; force ?
        jnz     .forced
 
; not forced:
 
 
        mov     edx, [d_width_calc_area + ebx*4]
 
        add     edx, [_WinMapAddress]
        movzx   edx, byte [eax+edx]
        cmp     edx, [CURRENT_TASK]
 
        jne     .exit
;--------------------------------------
align 4
.forced:
; check if negation
        test    ecx, 0x01000000
        jz      .noneg
 
        call    getpixel
        not     ecx
 
        rol     ecx, 8
        mov     cl, [esp+32-8+3]
        ror     ecx, 8
        mov     [esp+32-8], ecx
;--------------------------------------
align 4
.noneg:
; OK to set pixel
        call    dword [PUTPIXEL]; call the real put_pixel function
;--------------------------------------
align 4
.exit:
        popad
        ret
;-----------------------------------------------------------------------------
align 4
Vesa20_putpixel24:
; eax = x
; ebx = y
        mov     ecx, eax
        shl     ecx, 16
        mov     cx, bx
 
        imul    ebx, [BytesPerScanLine]  ; ebx = y * y multiplier
        lea     edi, [eax+eax*2]; edi = x*3
        mov     eax, [esp+32-8+4]
;--------------------------------------
; check mouse area for putpixel
        test    eax, 0x04000000
        jnz     @f
        call    check_mouse_area_for_putpixel
;--------------------------------------
align 4
@@:
; store to real LFB
        mov     [LFB_BASE+ebx+edi], ax
        shr     eax, 16
        mov     [LFB_BASE+ebx+edi+2], al
        ret
;-----------------------------------------------------------------------------
align 4
Vesa20_putpixel24_new:
; eax = x
; ebx = y
        mov     ecx, eax
        shl     ecx, 16
        mov     cx, bx
 
        imul    ebx, [BytesPerScanLine]  ; ebx = y * y multiplier
        lea     edi, [eax+eax*2]; edi = x*3
        mov     eax, [esp+32-8+4]
;--------------------------------------
; check mouse area for putpixel
        test    eax, 0x04000000
        jnz     @f
;--------------------------------------
; check for Y
        cmp     cx, [Y_UNDER_subtraction_CUR_hot_y]
        jb      @f
 
        cmp     cx, [Y_UNDER_sub_CUR_hot_y_add_curh]
        jae     @f
 
        rol     ecx, 16
;--------------------------------------
; check for X
        cmp     cx, [X_UNDER_subtraction_CUR_hot_x]
        jb      @f
 
        cmp     cx, [X_UNDER_sub_CUR_hot_x_add_curh]
        jae     @f
 
        call    check_mouse_area_for_putpixel_new.1
;--------------------------------------
align 4
@@:
; store to real LFB
        mov     [LFB_BASE+ebx+edi], ax
        shr     eax, 16
        mov     [LFB_BASE+ebx+edi+2], al
        ret
;-----------------------------------------------------------------------------
align 4
Vesa20_putpixel32:
; eax = x
; ebx = y
        mov     ecx, eax
        shl     ecx, 16
        mov     cx, bx
 
        imul    ebx, [BytesPerScanLine]  ; ebx = y * y multiplier
        lea     edi, [ebx+eax*4]; edi = x*4+(y*y multiplier)
        mov     eax, [esp+32-8+4]; eax = color
;--------------------------------------
; check mouse area for putpixel
        test    eax, 0x04000000
        jnz     @f
        call    check_mouse_area_for_putpixel
;--------------------------------------
align 4
@@:
        and     eax, 0xffffff
; store to real LFB
        mov     [LFB_BASE+edi], eax
        ret
;-----------------------------------------------------------------------------
align 4
Vesa20_putpixel32_new:
; eax = x
; ebx = y
        mov     ecx, eax
        shl     ecx, 16
        mov     cx, bx
 
        imul    ebx, [BytesPerScanLine]  ; ebx = y * y multiplier
        lea     edi, [ebx+eax*4]; edi = x*4+(y*y multiplier)
        mov     eax, [esp+32-8+4]; eax = color
;--------------------------------------
; check mouse area for putpixel
        test    eax, 0x04000000
        jnz     @f
;--------------------------------------
; check for Y
        cmp     cx, [Y_UNDER_subtraction_CUR_hot_y]
        jb      @f
 
        cmp     cx, [Y_UNDER_sub_CUR_hot_y_add_curh]
        jae     @f
 
        rol     ecx, 16
;--------------------------------------
; check for X
        cmp     cx, [X_UNDER_subtraction_CUR_hot_x]
        jb      @f
 
        cmp     cx, [X_UNDER_sub_CUR_hot_x_add_curh]
        jae     @f
 
        call    check_mouse_area_for_putpixel_new.1
;--------------------------------------
align 4
@@:
        and     eax, 0xffffff
; store to real LFB
        mov     [LFB_BASE+edi], eax
        ret
;-----------------------------------------------------------------------------
align 4
calculate_edi:
        mov     edi, ebx
        imul    edi, [Screen_Max_X]
        add     edi, ebx
        add     edi, eax
        ret
;-----------------------------------------------------------------------------
; DRAWLINE
;-----------------------------------------------------------------------------
align 4
__sys_draw_line:
; draw a line
; eax = HIWORD = x1
;       LOWORD = x2
; ebx = HIWORD = y1
;       LOWORD = y2
; ecx = color
; edi = force ?
        pusha
 
dl_x1 equ esp+20
dl_y1 equ esp+16
dl_x2 equ esp+12
dl_y2 equ esp+8
dl_dx equ esp+4
dl_dy equ esp+0
 
        xor     edx, edx   ; clear edx
        xor     esi, esi   ; unpack arguments
        xor     ebp, ebp
        mov     si, ax     ; esi = x2
        mov     bp, bx     ; ebp = y2
        shr     eax, 16    ; eax = x1
        shr     ebx, 16    ; ebx = y1
        push    eax        ; save x1
        push    ebx        ; save y1
        push    esi        ; save x2
        push    ebp        ; save y2
; checking x-axis...
        sub     esi, eax   ; esi = x2-x1
        push    esi        ; save y2-y1
        jl      .x2lx1     ; is x2 less than x1 ?
        jg      .no_vline  ; x1 > x2 ?
        mov     edx, ebp   ; else (if x1=x2)
        call    vline
        push    edx ; necessary to rightly restore stack frame at .exit
        jmp     .exit
;--------------------------------------
align 4
.x2lx1:
        neg     esi         ; get esi absolute value
;--------------------------------------
align 4
.no_vline:
; checking y-axis...
        sub     ebp, ebx    ; ebp = y2-y1
        push    ebp         ; save y2-y1
        jl      .y2ly1      ; is y2 less than y1 ?
        jg      .no_hline   ; y1 > y2 ?
        mov     edx, [dl_x2]; else (if y1=y2)
        call    hline
        jmp     .exit
;--------------------------------------
align 4
.y2ly1:
        neg     ebp         ; get ebp absolute value
;--------------------------------------
align 4
.no_hline:
        cmp     ebp, esi
        jle     .x_rules    ; |y2-y1| < |x2-x1|  ?
        cmp     [dl_y2], ebx; make sure y1 is at the begining
        jge     .no_reverse1
        neg     dword [dl_dx]
        mov     edx, [dl_x2]
        mov     [dl_x2], eax
        mov     [dl_x1], edx
        mov     edx, [dl_y2]
        mov     [dl_y2], ebx
        mov     [dl_y1], edx
;--------------------------------------
align 4
.no_reverse1:
        mov     eax, [dl_dx]
        cdq                 ; extend eax sing to edx
        shl     eax, 16     ; using 16bit fix-point maths
        idiv    ebp         ; eax = ((x2-x1)*65536)/(y2-y1)
;--------------------------------------
; correction for the remainder of the division
        shl     edx, 1
        cmp     ebp, edx
        jb      @f
        inc     eax
;--------------------------------------
align 4
@@:
;--------------------------------------
        mov     edx, ebp    ; edx = counter (number of pixels to draw)
        mov     ebp, 1 *65536; <<16   ; ebp = dy = 1.0
        mov     esi, eax    ; esi = dx
        jmp     .y_rules
;--------------------------------------
align 4
.x_rules:
        cmp     [dl_x2], eax ; make sure x1 is at the begining
        jge     .no_reverse2
        neg     dword [dl_dy]
        mov     edx, [dl_x2]
        mov     [dl_x2], eax
        mov     [dl_x1], edx
        mov     edx, [dl_y2]
        mov     [dl_y2], ebx
        mov     [dl_y1], edx
;--------------------------------------
align 4
.no_reverse2:
        xor     edx, edx
        mov     eax, [dl_dy]
        cdq                 ; extend eax sing to edx
        shl     eax, 16     ; using 16bit fix-point maths
        idiv    esi         ; eax = ((y2-y1)*65536)/(x2-x1)
;--------------------------------------
; correction for the remainder of the division
        shl     edx, 1
        cmp     esi, edx
        jb      @f
        inc     eax
;--------------------------------------
align 4
@@:
;--------------------------------------
        mov     edx, esi    ; edx = counter (number of pixels to draw)
        mov     esi, 1 *65536;<< 16   ; esi = dx = 1.0
        mov     ebp, eax    ; ebp = dy
;--------------------------------------
align 4
.y_rules:
        mov     eax, [dl_x1]
        mov     ebx, [dl_y1]
        shl     eax, 16
        shl     ebx, 16
;-----------------------------------------------------------------------------
align 4
.draw:
        push    eax ebx
;--------------------------------------
; correction for the remainder of the division
        test    ah, 0x80
        jz      @f
        add     eax, 1 shl 16
;--------------------------------------
align 4
@@:
;--------------------------------------
        shr     eax, 16
;--------------------------------------
; correction for the remainder of the division
        test    bh, 0x80
        jz      @f
        add     ebx, 1 shl 16
;--------------------------------------
align 4
@@:
;--------------------------------------
        shr     ebx, 16
        and     ecx, 0xFBFFFFFF  ;negate 0x04000000 save to mouseunder area
        call    [putpixel]
        pop     ebx eax
        add     ebx, ebp     ; y = y+dy
        add     eax, esi     ; x = x+dx
        dec     edx
        jnz     .draw
; force last drawn pixel to be at (x2,y2)
        mov     eax, [dl_x2]
        mov     ebx, [dl_y2]
        and     ecx, 0xFBFFFFFF ;negate 0x04000000 save to mouseunder area
        call    [putpixel]
;--------------------------------------
align 4
.exit:
        add     esp, 6*4
        popa
;        call    [draw_pointer]
        ret
;------------------------------------------------------------------------------
align 4
hline:
; draw an horizontal line
; eax = x1
; edx = x2
; ebx = y
; ecx = color
; edi = force ?
        push    eax edx
        cmp     edx, eax   ; make sure x2 is above x1
        jge     @f
        xchg    eax, edx
;--------------------------------------
align 4
@@:
        and     ecx, 0xFBFFFFFF  ;negate 0x04000000 save to mouseunder area
        call    [putpixel]
        inc     eax
        cmp     eax, edx
        jle     @b
        pop     edx eax
        ret
;------------------------------------------------------------------------------
align 4
vline:
; draw a vertical line
; eax = x
; ebx = y1
; edx = y2
; ecx = color
; edi = force ?
        push    ebx edx
        cmp     edx, ebx   ; make sure y2 is above y1
        jge     @f
        xchg    ebx, edx
;--------------------------------------
align 4
@@:
        and     ecx, 0xFBFFFFFF ;negate 0x04000000 save to mouseunder area
        call    [putpixel]
        inc     ebx
        cmp     ebx, edx
        jle     @b
        pop     edx ebx
        ret
;------------------------------------------------------------------------------
align 4
virtual at esp
drbar:
     .bar_sx       dd ?
     .bar_sy       dd ?
     .bar_cx       dd ?
     .bar_cy       dd ?
     .abs_cx       dd ?
     .abs_cy       dd ?
     .real_sx      dd ?
     .real_sy      dd ?
     .color        dd ?
     .line_inc_scr dd ?
     .line_inc_map dd ?
     .real_sx_and_abs_cx dd ?
     .real_sy_and_abs_cy dd ?
     .stack_data = 4*13
end virtual
;--------------------------------------
align 4
; eax   cx
; ebx   cy
; ecx   xe
; edx   ye
; edi   color
vesa20_drawbar:
        pushad
        sub     esp, drbar.stack_data
        mov     [drbar.color], edi
        sub     edx, ebx
        jle     .exit       ;// mike.dld, 2005-01-29
        sub     ecx, eax
        jle     .exit       ;// mike.dld, 2005-01-29
        mov     [drbar.bar_sy], edx
        mov     [drbar.bar_sx], ecx
        mov     [drbar.bar_cx], eax
        mov     [drbar.bar_cy], ebx
        mov     edi, [TASK_BASE]
        add     eax, [edi-twdw + WDATA.box.left]; win_cx
        add     ebx, [edi-twdw + WDATA.box.top]; win_cy
        mov     [drbar.abs_cx], eax
        mov     [drbar.abs_cy], ebx
; real_sx = MIN(wnd_sx-bar_cx, bar_sx);
        mov     ebx, [edi-twdw + WDATA.box.width]; ebx = wnd_sx
; \begin{diamond}[20.08.2006]
; note that WDATA.box.width is one pixel less than real window x-size
        inc     ebx
; \end{diamond}[20.08.2006]
        sub     ebx, [drbar.bar_cx]
        ja      @f
;--------------------------------------
align 4
.exit:                       ;// mike.dld, 2005-01-29
        add     esp, drbar.stack_data
        popad
        xor     eax, eax
        inc     eax
        ret
;--------------------------------------
align 4
@@:
        cmp     ebx, [drbar.bar_sx]
        jbe     .end_x
        mov     ebx, [drbar.bar_sx]
;--------------------------------------
align 4
.end_x:
        mov     [drbar.real_sx], ebx
; real_sy = MIN(wnd_sy-bar_cy, bar_sy);
        mov     ebx, [edi-twdw + WDATA.box.height]; ebx = wnd_sy
; \begin{diamond}[20.08.2006]
        inc     ebx
; \end{diamond}
        sub     ebx, [drbar.bar_cy]
        ja      @f
        add     esp, drbar.stack_data
        popad
        xor     eax, eax
        inc     eax
        ret
;--------------------------------------
align 4
@@:
        cmp     ebx, [drbar.bar_sy]
        jbe     .end_y
        mov     ebx, [drbar.bar_sy]
;--------------------------------------
align 4
.end_y:
        mov     [drbar.real_sy], ebx
; line_inc_map
        mov     eax, [Screen_Max_X]
        sub     eax, [drbar.real_sx]
        inc     eax
        mov     [drbar.line_inc_map], eax
; line_inc_scr
        mov     eax, [drbar.real_sx]
        movzx   ebx, byte [ScreenBPP]
        shr     ebx, 3
        imul    eax, ebx
        neg     eax
        add     eax, [BytesPerScanLine]
        mov     [drbar.line_inc_scr], eax
; pointer to screen
        mov     edx, [drbar.abs_cy]
        imul    edx, [BytesPerScanLine]
        mov     eax, [drbar.abs_cx]
;     movzx   ebx, byte [ScreenBPP]
;     shr     ebx, 3
        imul    eax, ebx
        add     edx, eax
; pointer to pixel map
        mov     eax, [drbar.abs_cy]
        imul    eax, [Screen_Max_X]
        add     eax, [drbar.abs_cy]
        add     eax, [drbar.abs_cx]
        add     eax, [_WinMapAddress]
        xchg    eax, ebp
;--------------------------------------
        mov     ebx, [drbar.real_sx]
        add     ebx, [drbar.abs_cx]
        mov     [drbar.real_sx_and_abs_cx], ebx
        mov     ebx, [drbar.real_sy]
        add     ebx, [drbar.abs_cy]
        mov     [drbar.real_sy_and_abs_cy], ebx
 
        add     edx, LFB_BASE
;--------------------------------------
; get process number
        mov     ebx, [CURRENT_TASK]
        cmp     byte [ScreenBPP], 24
        jne     draw_bar_end_32
;--------------------------------------
align 4
draw_bar_end_24:
        mov     eax, [drbar.color] ;; BBGGRR00
        mov     bh, al             ;; bh  = BB
        shr     eax, 8             ;; eax = RRGG
; eax - color high   RRGG
; bl - process num
; bh - color low    BB
; ecx - temp
; edx - pointer to screen
; esi - counter
; edi - counter
        mov     esi, [drbar.real_sy]
        cmp     [_display.select_cursor], 0
        jne     draw_bar_end_24_new
;--------------------------------------
align 4
.new_y:
        mov     edi, [drbar.real_sx]
;--------------------------------------
align 4
.new_x:
        cmp     byte [ebp], bl
        jne     .skip
;--------------------------------------
        push    eax
 
        mov     ecx, [drbar.real_sx_and_abs_cx + 4]
        sub     ecx, edi
        shl     ecx, 16
        add     ecx, [drbar.real_sy_and_abs_cy + 4]
        sub     ecx, esi
 
        shl     eax, 8
        mov     al, bh
; check mouse area for putpixel
        call    check_mouse_area_for_putpixel
; store to real LFB
        mov     [edx], ax
        shr     eax, 16
        mov     [edx + 2], al
        pop     eax
;--------------------------------------
align 4
.skip:
; add pixel
        add     edx, 3
        inc     ebp
        dec     edi
        jnz     .new_x
; add line
        add     edx, [drbar.line_inc_scr]
        add     ebp, [drbar.line_inc_map]
;  drawing gradient bars
        test    eax, 0x00800000
        jz      @f
        test    bh, bh
        jz      @f
        dec     bh
;--------------------------------------
align 4
@@:
; 
        dec     esi
        jnz     .new_y
;--------------------------------------
align 4
.end:
        add     esp, drbar.stack_data
        popad
        xor     eax, eax
        ret
;--------------------------------------
align 4
draw_bar_end_24_new:
;--------------------------------------
align 4
.new_y:
        mov     edi, [drbar.real_sx]
;--------------------------------------
align 4
.new_x:
        cmp     byte [ebp], bl
        jne     .skip
;--------------------------------------
        mov     ecx, [drbar.real_sy_and_abs_cy]
        sub     ecx, esi
;--------------------------------------
; check for Y
        cmp     cx, [Y_UNDER_subtraction_CUR_hot_y]
        jb      .no_mouse_area
 
        cmp     cx, [Y_UNDER_sub_CUR_hot_y_add_curh]
        jae     .no_mouse_area
 
        rol     ecx, 16
        add     ecx, [drbar.real_sx_and_abs_cx]
        sub     ecx, edi
;--------------------------------------
; check for X
        cmp     cx, [X_UNDER_subtraction_CUR_hot_x]
        jb      .no_mouse_area
 
        cmp     cx, [X_UNDER_sub_CUR_hot_x_add_curh]
        jae     .no_mouse_area
;--------------------------------------
; check mouse area for putpixel
        push    eax
 
        shl     eax, 8
        mov     al, bh
 
        call    check_mouse_area_for_putpixel_new.1
; store to real LFB
        mov     [edx], ax
        shr     eax, 16
        mov     [edx + 2], al
        pop     eax
        jmp     .skip
; store to real LFB
;--------------------------------------
align 4
.no_mouse_area:
        mov     [edx], bh
        mov     [edx + 1], ax
;--------------------------------------
align 4
.skip:
; add pixel
        add     edx, 3
        inc     ebp
        dec     edi
        jnz     .new_x
; add line
        add     edx, [drbar.line_inc_scr]
        add     ebp, [drbar.line_inc_map]
;  drawing gradient bars
        test    eax, 0x00800000
        jz      @f
        test    bh, bh
        jz      @f
        dec     bh
;--------------------------------------
align 4
@@:
; 
        dec     esi
        jnz     .new_y
        jmp     draw_bar_end_24.end
;--------------------------------------
align 4
draw_bar_end_32:
        mov     eax, [drbar.color] ;; BBGGRR00
        mov     esi, [drbar.real_sy]
        cmp     [_display.select_cursor], 0
        jne     draw_bar_end_32_new
;--------------------------------------
align 4
.new_y:
        mov     edi, [drbar.real_sx]
;--------------------------------------
align 4
.new_x:
        cmp     byte [ebp], bl
        jne     .skip
;--------------------------------------
        push    eax
 
        mov     ecx, [drbar.real_sx_and_abs_cx + 4]
        sub     ecx, edi
        shl     ecx, 16
        add     ecx, [drbar.real_sy_and_abs_cy + 4]
        sub     ecx, esi
 
; check mouse area for putpixel
        call    check_mouse_area_for_putpixel
; store to real LFB
        mov     [edx], eax
        pop     eax
;--------------------------------------
align 4
.skip:
; add pixel
        add     edx, 4
        inc     ebp
        dec     edi
        jnz     .new_x
; add line
        add     edx, [drbar.line_inc_scr]
        add     ebp, [drbar.line_inc_map]
;  drawing gradient bars
        test    eax, 0x80000000
        jz      @f
        test    al, al
        jz      @f
        dec     al
;--------------------------------------
align 4
@@:
; 
        dec     esi
        jnz     .new_y
;--------------------------------------
align 4
.end:
        add     esp, drbar.stack_data
        popad
        cmp     [SCR_MODE], dword 0x12
        jne     @f
        call    VGA_draw_bar
;--------------------------------------
align 4
@@:
        xor     eax, eax
        mov     [EGA_counter], 1
        ret
;--------------------------------------
align 4
draw_bar_end_32_new:
;--------------------------------------
align 4
.new_y:
        mov     edi, [drbar.real_sx]
;--------------------------------------
align 4
.new_x:
        cmp     byte [ebp], bl
        jne     .skip
;--------------------------------------
        mov     ecx, [drbar.real_sy_and_abs_cy]
        sub     ecx, esi
;--------------------------------------
; check for Y
        cmp     cx, [Y_UNDER_subtraction_CUR_hot_y]
        jb      .no_mouse_area
 
        cmp     cx, [Y_UNDER_sub_CUR_hot_y_add_curh]
        jae     .no_mouse_area
 
        rol     ecx, 16
        add     ecx, [drbar.real_sx_and_abs_cx]
        sub     ecx, edi
;--------------------------------------
; check for X
        cmp     cx, [X_UNDER_subtraction_CUR_hot_x]
        jb      .no_mouse_area
 
        cmp     cx, [X_UNDER_sub_CUR_hot_x_add_curh]
        jae     .no_mouse_area
;--------------------------------------
; check mouse area for putpixel
        push    eax
        call    check_mouse_area_for_putpixel_new.1
        mov     [edx], eax
        pop     eax
        jmp     .skip
; store to real LFB
;--------------------------------------
align 4
.no_mouse_area:
        mov     [edx], eax
;--------------------------------------
align 4
.skip:
; add pixel
        add     edx, 4
        inc     ebp
        dec     edi
        jnz     .new_x
; add line
        add     edx, [drbar.line_inc_scr]
        add     ebp, [drbar.line_inc_map]
;  drawing gradient bars
        test    eax, 0x80000000
        jz      @f
        test    al, al
        jz      @f
        dec     al
;--------------------------------------
align 4
@@:
; 
        dec     esi
        jnz     .new_y
        jmp     draw_bar_end_32.end
;------------------------------------------------------------------------------
align 4
vesa20_drawbackground_tiled:
        pushad
; External loop for all y from start to end
        mov     ebx, [draw_data+32+RECT.top]    ; y start
;--------------------------------------
align 4
dp2:
        mov     ebp, [draw_data+32+RECT.left]   ; x start
; 1) Calculate pointers in WinMapAddress (does pixel belong to OS thread?) [ebp]
;                       and LFB data (output for our function) [edi]
        mov     eax, [BytesPerScanLine]
        mul     ebx
        xchg    ebp, eax
        add     ebp, eax
        add     ebp, eax
        add     ebp, eax
        cmp     [ScreenBPP], byte 24    ; 24 or 32 bpp ? - x size
        jz      @f
        add     ebp, eax
;--------------------------------------
align 4
@@:
        add     ebp, LFB_BASE
; ebp:=Y*BytesPerScanLine+X*BytesPerPixel+AddrLFB
        call    calculate_edi
        xchg    edi, ebp
        add     ebp, [_WinMapAddress]
; Now eax=x, ebx=y, edi->output, ebp=offset in WinMapAddress
; 2) Calculate offset in background memory block
        push    eax
        xor     edx, edx
        mov     eax, ebx
        div     dword [BgrDataHeight]   ; edx := y mod BgrDataHeight
        pop     eax
        push    eax
        mov     ecx, [BgrDataWidth]
        mov     esi, edx
        imul    esi, ecx                ; esi := (y mod BgrDataHeight) * BgrDataWidth
        xor     edx, edx
        div     ecx             ; edx := x mod BgrDataWidth
        sub     ecx, edx
        add     esi, edx        ; esi := (y mod BgrDataHeight)*BgrDataWidth + (x mod BgrDataWidth)
        pop     eax
        lea     esi, [esi*3]
        add     esi, [img_background]
        xor     edx, edx
        inc     edx
; 3) Loop through redraw rectangle and copy background data
; Registers meaning:
; eax = x, ebx = y (screen coordinates)
; ecx = deltax - number of pixels left in current tile block
; edx = 1
; esi -> bgr memory, edi -> output
; ebp = offset in WinMapAddress
;--------------------------------------
align 4
dp3:
        cmp     [ebp], dl
        jnz     nbgp
;--------------------------------------
        push    eax ecx
 
        mov     ecx, eax
        shl     ecx, 16
        add     ecx, ebx
 
        mov     eax, [esi]
        and     eax, 0xffffff
; check mouse area for putpixel
        call    [_display.check_mouse]
; store to real LFB
        mov     [edi], ax
        shr     eax, 16
        mov     [edi+2], al
 
        pop     ecx eax
;--------------------------------------
align 4
nbgp:
        add     esi, 3
        add     edi, 3
;--------------------------------------
align 4
@@:
        cmp     [ScreenBPP], byte 25    ; 24 or 32 bpp?
        sbb     edi, -1         ; +1 for 32 bpp
; I do not use 'inc eax' because this is slightly slower then 'add eax,1'
        add     ebp, edx
        add     eax, edx
        cmp     eax, [draw_data+32+RECT.right]
        ja      dp4
        sub     ecx, edx
        jnz     dp3
; next tile block on x-axis
        mov     ecx, [BgrDataWidth]
        sub     esi, ecx
        sub     esi, ecx
        sub     esi, ecx
        jmp     dp3
;--------------------------------------
align 4
dp4:
; next scan line
        inc     ebx
        cmp     ebx, [draw_data+32+RECT.bottom]
        jbe     dp2
        popad
        mov     [EGA_counter], 1
        cmp     [SCR_MODE], dword 0x12
        jne     @f
        call    VGA_drawbackground
;--------------------------------------
align 4
@@:
        ret
;------------------------------------------------------------------------------
align 4
vesa20_drawbackground_stretch:
        pushad
; Helper variables
; calculate 2^32*(BgrDataWidth-1) mod (ScreenWidth-1)
        mov     eax, [BgrDataWidth]
        dec     eax
        xor     edx, edx
        div     dword [Screen_Max_X]
        push    eax     ; high
        xor     eax, eax
        div     dword [Screen_Max_X]
        push    eax     ; low
; the same for height
        mov     eax, [BgrDataHeight]
        dec     eax
        xor     edx, edx
        div     dword [Screen_Max_Y]
        push    eax     ; high
        xor     eax, eax
        div     dword [Screen_Max_Y]
        push    eax     ; low
; External loop for all y from start to end
        mov     ebx, [draw_data+32+RECT.top]    ; y start
        mov     ebp, [draw_data+32+RECT.left]   ; x start
; 1) Calculate pointers in WinMapAddress (does pixel belong to OS thread?) [ebp]
;                       and LFB data (output for our function) [edi]
        mov     eax, [BytesPerScanLine]
        mul     ebx
        xchg    ebp, eax
        add     ebp, eax
        add     ebp, eax
        add     ebp, eax
        cmp     [ScreenBPP], byte 24    ; 24 or 32 bpp ? - x size
        jz      @f
        add     ebp, eax
;--------------------------------------
align 4
@@:
; ebp:=Y*BytesPerScanLine+X*BytesPerPixel+AddrLFB
        call    calculate_edi
        xchg    edi, ebp
; Now eax=x, ebx=y, edi->output, ebp=offset in WinMapAddress
        push    ebx
        push    eax
; 2) Calculate offset in background memory block
        mov     eax, ebx
        imul    ebx, dword [esp+12]
        mul     dword [esp+8]
        add     edx, ebx        ; edx:eax = y * 2^32*(BgrDataHeight-1)/(ScreenHeight-1)
        mov     esi, edx
        imul    esi, [BgrDataWidth]
        push    edx
        push    eax
        mov     eax, [esp+8]
        mul     dword [esp+28]
        push    eax
        mov     eax, [esp+12]
        mul     dword [esp+28]
        add     [esp], edx
        pop     edx             ; edx:eax = x * 2^32*(BgrDataWidth-1)/(ScreenWidth-1)
        add     esi, edx
        lea     esi, [esi*3]
        add     esi, [img_background]
        push    eax
        push    edx
        push    esi
; 3) Smooth horizontal
;--------------------------------------
align 4
bgr_resmooth0:
        mov     ecx, [esp+8]
        mov     edx, [esp+4]
        mov     esi, [esp]
        push    edi
        mov     edi, bgr_cur_line
        call    smooth_line
;--------------------------------------
align 4
bgr_resmooth1:
        mov     eax, [esp+16+4]
        inc     eax
        cmp     eax, [BgrDataHeight]
        jae     bgr.no2nd
        mov     ecx, [esp+8+4]
        mov     edx, [esp+4+4]
        mov     esi, [esp+4]
        add     esi, [BgrDataWidth]
        add     esi, [BgrDataWidth]
        add     esi, [BgrDataWidth]
        mov     edi, bgr_next_line
        call    smooth_line
;--------------------------------------
align 4
bgr.no2nd:
        pop     edi
;--------------------------------------
align 4
sdp3:
        xor     esi, esi
        mov     ecx, [esp+12]
; 4) Loop through redraw rectangle and copy background data
; Registers meaning:
; esi = offset in current line, edi -> output
; ebp = offset in WinMapAddress
; dword [esp] = offset in bgr data
; qword [esp+4] = x * 2^32 * (BgrDataWidth-1) / (ScreenWidth-1)
; qword [esp+12] = y * 2^32 * (BgrDataHeight-1) / (ScreenHeight-1)
; dword [esp+20] = x
; dword [esp+24] = y
; precalculated constants:
; qword [esp+28] = 2^32*(BgrDataHeight-1)/(ScreenHeight-1)
; qword [esp+36] = 2^32*(BgrDataWidth-1)/(ScreenWidth-1)
;--------------------------------------
align 4
sdp3a:
        mov     eax, [_WinMapAddress]
        cmp     [ebp+eax], byte 1
        jnz     snbgp
        mov     eax, [bgr_cur_line+esi]
        test    ecx, ecx
        jz      .novert
        mov     ebx, [bgr_next_line+esi]
        call    [overlapping_of_points_ptr]
;--------------------------------------
align 4
.novert:
        push    ecx
        mov     ecx, [esp+20+4]        ;x
        shl     ecx, 16
        add     ecx, [esp+24+4]        ;y
; check mouse area for putpixel
        call    [_display.check_mouse]
; store to real LFB
        mov     [LFB_BASE+edi], ax
        shr     eax, 16
        mov     [LFB_BASE+edi+2], al
        pop     ecx
;--------------------------------------
align 4
snbgp:
        cmp     [ScreenBPP], byte 25
        sbb     edi, -4
        add     ebp, 1
        mov     eax, [esp+20]
        add     eax, 1
        mov     [esp+20], eax
        add     esi, 4
        cmp     eax, [draw_data+32+RECT.right]
        jbe     sdp3a
;--------------------------------------
align 4
sdp4:
; next y
        mov     ebx, [esp+24]
        add     ebx, 1
        mov     [esp+24], ebx
        cmp     ebx, [draw_data+32+RECT.bottom]
        ja      sdpdone
; advance edi, ebp to next scan line
        sub     eax, [draw_data+32+RECT.left]
        sub     ebp, eax
        add     ebp, [Screen_Max_X]
        add     ebp, 1
        sub     edi, eax
        sub     edi, eax
        sub     edi, eax
        cmp     [ScreenBPP], byte 24
        jz      @f
        sub     edi, eax
;--------------------------------------
align 4
@@:
        add     edi, [BytesPerScanLine]
; restore ecx,edx; advance esi to next background line
        mov     eax, [esp+28]
        mov     ebx, [esp+32]
        add     [esp+12], eax
        mov     eax, [esp+16]
        adc     [esp+16], ebx
        sub     eax, [esp+16]
        mov     ebx, eax
        lea     eax, [eax*3]
        imul    eax, [BgrDataWidth]
        sub     [esp], eax
        mov     eax, [draw_data+32+RECT.left]
        mov     [esp+20], eax
        test    ebx, ebx
        jz      sdp3
        cmp     ebx, -1
        jnz     bgr_resmooth0
        push    edi
        mov     esi, bgr_next_line
        mov     edi, bgr_cur_line
        mov     ecx, [Screen_Max_X]
        inc     ecx
        rep movsd
        jmp     bgr_resmooth1
;--------------------------------------
align 4
sdpdone:
        add     esp, 44
        popad
        mov     [EGA_counter], 1
        cmp     [SCR_MODE], dword 0x12
        jne     @f
        call    VGA_drawbackground
;--------------------------------------
align 4
@@:
        ret
 
uglobal
;--------------------------------------
align 4
bgr_cur_line    rd      1920    ; maximum width of screen
bgr_next_line   rd      1920
;--------------------------------------
endg
;--------------------------------------
align 4
smooth_line:
        mov     al, [esi+2]
        shl     eax, 16
        mov     ax, [esi]
        test    ecx, ecx
        jz      @f
        mov     ebx, [esi+2]
        shr     ebx, 8
        call    [overlapping_of_points_ptr]
;--------------------------------------
align 4
@@:
        stosd
        mov     eax, [esp+20+8]
        add     eax, 1
        mov     [esp+20+8], eax
        cmp     eax, [draw_data+32+RECT.right]
        ja      @f
        add     ecx, [esp+36+8]
        mov     eax, edx
        adc     edx, [esp+40+8]
        sub     eax, edx
        lea     eax, [eax*3]
        sub     esi, eax
        jmp     smooth_line
;--------------------------------------
align 4
@@:
        mov     eax, [draw_data+32+RECT.left]
        mov     [esp+20+8], eax
        ret
;------------------------------------------------------------------------------
align 16
overlapping_of_points:
if 0
; this version of procedure works, but is slower than next version
        push    ecx edx
        mov     edx, eax
        push    esi
        shr     ecx, 24
        mov     esi, ecx
        mov     ecx, ebx
        movzx   ebx, dl
        movzx   eax, cl
        sub     eax, ebx
        movzx   ebx, dh
        imul    eax, esi
        add     dl, ah
        movzx   eax, ch
        sub     eax, ebx
        imul    eax, esi
        add     dh, ah
        ror     ecx, 16
        ror     edx, 16
        movzx   eax, cl
        movzx   ebx, dl
        sub     eax, ebx
        imul    eax, esi
        pop     esi
        add     dl, ah
        mov     eax, edx
        pop     edx
        ror     eax, 16
        pop     ecx
        ret
else
        push    ecx edx
        mov     edx, eax
        push    esi
        shr     ecx, 26
        mov     esi, ecx
        mov     ecx, ebx
        shl     esi, 9
        movzx   ebx, dl
        movzx   eax, cl
        sub     eax, ebx
        movzx   ebx, dh
        add     dl, [BgrAuxTable+(eax+0x100)+esi]
        movzx   eax, ch
        sub     eax, ebx
        add     dh, [BgrAuxTable+(eax+0x100)+esi]
        ror     ecx, 16
        ror     edx, 16
        movzx   eax, cl
        movzx   ebx, dl
        sub     eax, ebx
        add     dl, [BgrAuxTable+(eax+0x100)+esi]
        pop     esi
        mov     eax, edx
        pop     edx
        ror     eax, 16
        pop     ecx
        ret
end if
 
iglobal
;--------------------------------------
align 4
overlapping_of_points_ptr       dd      overlapping_of_points
;--------------------------------------
endg
;------------------------------------------------------------------------------
align 4
init_background:
        mov     edi, BgrAuxTable
        xor     edx, edx
;--------------------------------------
align 4
.loop2:
        mov     eax, edx
        shl     eax, 8
        neg     eax
        mov     ecx, 0x200
;--------------------------------------
align 4
.loop1:
        mov     byte [edi], ah
        inc     edi
        add     eax, edx
        loop    .loop1
        add     dl, 4
        jnz     .loop2
        test    byte [cpu_caps+(CAPS_MMX/8)], 1 shl (CAPS_MMX mod 8)
        jz      @f
        mov     [overlapping_of_points_ptr], overlapping_of_points_mmx
;--------------------------------------
align 4
@@:
        ret
;------------------------------------------------------------------------------
align 16
overlapping_of_points_mmx:
        movd    mm0, eax
        movd    mm4, eax
        movd    mm1, ebx
        pxor    mm2, mm2
        punpcklbw mm0, mm2
        punpcklbw mm1, mm2
        psubw   mm1, mm0
        movd    mm3, ecx
        psrld   mm3, 24
        packuswb mm3, mm3
        packuswb mm3, mm3
        pmullw  mm1, mm3
        psrlw   mm1, 8
        packuswb mm1, mm2
        paddb   mm4, mm1
        movd    eax, mm4
        ret
;------------------------------------------------------------------------------

Rev 2436	Rev 2438
1	;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;	1	;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2	;; ;;	2	;; ;;
3	;; Copyright (C) KolibriOS team 2004-2008. All rights reserved. ;;	3	;; Copyright (C) KolibriOS team 2004-2008. All rights reserved. ;;
4	;; Distributed under terms of the GNU General Public License ;;	4	;; Distributed under terms of the GNU General Public License ;;
5	;; ;;	5	;; ;;
6	;; VESA20.INC ;;	6	;; VESA20.INC ;;
7	;; ;;	7	;; ;;
8	;; Vesa 2.0 functions for MenuetOS ;;	8	;; Vesa 2.0 functions for MenuetOS ;;
9	;; ;;	9	;; ;;
10	;; Copyright 2002 Ville Turjanmaa ;;	10	;; Copyright 2002 Ville Turjanmaa ;;
11	;; Alexey, kgaz@crosswindws.net ;;	11	;; Alexey, kgaz@crosswindws.net ;;
12	;; - Voodoo compatible graphics ;;	12	;; - Voodoo compatible graphics ;;
13	;; Juan M. Caravaca ;;	13	;; Juan M. Caravaca ;;
14	;; - Graphics optimimizations eg. drawline ;;	14	;; - Graphics optimimizations eg. drawline ;;
15	;; ;;	15	;; ;;
16	;; See file COPYING for details ;;	16	;; See file COPYING for details ;;
17	;; ;;	17	;; ;;
18	;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;	18	;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
19		19
20	$Revision: 2436 $	20	$Revision: 2438 $
21		21
22		22
23	; If you're planning to write your own video driver I suggest	23	; If you're planning to write your own video driver I suggest
24	; you replace the VESA12.INC file and see those instructions.	24	; you replace the VESA12.INC file and see those instructions.
25		25
26	;Screen_Max_X equ 0xfe00	26	;Screen_Max_X equ 0xfe00
27	;Screen_Max_Y equ 0xfe04	27	;Screen_Max_Y equ 0xfe04
28	;BytesPerScanLine equ 0xfe08	28	;BytesPerScanLine equ 0xfe08
29	;LFBAddress equ 0xfe80	29	;LFBAddress equ 0xfe80
30	;ScreenBPP equ 0xfbf1	30	;ScreenBPP equ 0xfbf1
31		31
32		32
33		33
34	;-----------------------------------------------------------------------------	34	;-----------------------------------------------------------------------------
35	; getpixel	35	; getpixel
36	;	36	;
37	; in:	37	; in:
38	; eax = x coordinate	38	; eax = x coordinate
39	; ebx = y coordinate	39	; ebx = y coordinate
40	;	40	;
41	; ret:	41	; ret:
42	; ecx = 00 RR GG BB	42	; ecx = 00 RR GG BB
43	;-----------------------------------------------------------------------------	43	;-----------------------------------------------------------------------------
44	align 4	44	align 4
45	getpixel:	45	getpixel:
46	push eax ebx edx edi	46	push eax ebx edx edi
47	call dword [GETPIXEL]	47	call dword [GETPIXEL]
48	pop edi edx ebx eax	48	pop edi edx ebx eax
49	ret	49	ret
50	;-----------------------------------------------------------------------------	50	;-----------------------------------------------------------------------------
51	align 4	51	align 4
52	Vesa20_getpixel24:	52	Vesa20_getpixel24:
53	; eax = x	53	; eax = x
54	; ebx = y	54	; ebx = y
55	;--------------------------------------	55	;--------------------------------------
56	; check mouse area for putpixel	56	; check mouse area for putpixel
57	test ecx, 0x04000000 ; don't load to mouseunder area	57	test ecx, 0x04000000 ; don't load to mouseunder area
58	jnz .no_mouseunder	58	jnz .no_mouseunder
59	call [_display.check_m_pixel]	59	call [_display.check_m_pixel]
60	test ecx, ecx ;0xff000000	60	test ecx, ecx ;0xff000000
61	jnz @f	61	jnz @f
62	.no_mouseunder:	62	.no_mouseunder:
63	;--------------------------------------	63	;--------------------------------------
64	imul ebx, [BytesPerScanLine] ; ebx = y * y multiplier	64	imul ebx, [BytesPerScanLine] ; ebx = y * y multiplier
65	lea edi, [eax+eax2]; edi = x3	65	lea edi, [eax+eax2]; edi = x3
66	add edi, ebx ; edi = x3+(yy multiplier)	66	add edi, ebx ; edi = x3+(yy multiplier)
67	mov ecx, [LFB_BASE+edi]	67	mov ecx, [LFB_BASE+edi]
68	;--------------------------------------	68	;--------------------------------------
69	align 4	69	align 4
70	@@:	70	@@:
71	and ecx, 0xffffff	71	and ecx, 0xffffff
72	ret	72	ret
73	;-----------------------------------------------------------------------------	73	;-----------------------------------------------------------------------------
74	align 4	74	align 4
75	Vesa20_getpixel32:	75	Vesa20_getpixel32:
76	;--------------------------------------	76	;--------------------------------------
77	; check mouse area for putpixel	77	; check mouse area for putpixel
78	test ecx, 0x04000000 ; don't load to mouseunder area	78	test ecx, 0x04000000 ; don't load to mouseunder area
79	jnz .no_mouseunder	79	jnz .no_mouseunder
80	call [_display.check_m_pixel]	80	call [_display.check_m_pixel]
81	test ecx, ecx ;0xff000000	81	test ecx, ecx ;0xff000000
82	jnz @f	82	jnz @f
83	.no_mouseunder:	83	.no_mouseunder:
84	;--------------------------------------	84	;--------------------------------------
85	imul ebx, [BytesPerScanLine] ; ebx = y * y multiplier	85	imul ebx, [BytesPerScanLine] ; ebx = y * y multiplier
86	lea edi, [ebx+eax4]; edi = x4+(y*y multiplier)	86	lea edi, [ebx+eax4]; edi = x4+(y*y multiplier)
87	mov ecx, [LFB_BASE+edi]	87	mov ecx, [LFB_BASE+edi]
88	;--------------------------------------	88	;--------------------------------------
89	align 4	89	align 4
90	@@:	90	@@:
91	and ecx, 0xffffff	91	and ecx, 0xffffff
92	ret	92	ret
93	;-----------------------------------------------------------------------------	93	;-----------------------------------------------------------------------------
94	virtual at esp	94	virtual at esp
95	putimg:	95	putimg:
96	.real_sx dd ?	96	.real_sx dd ?
97	.real_sy dd ?	97	.real_sy dd ?
98	.image_sx dd ?	98	.image_sx dd ?
99	.image_sy dd ?	99	.image_sy dd ?
100	.image_cx dd ?	100	.image_cx dd ?
101	.image_cy dd ?	101	.image_cy dd ?
102	.pti dd ?	102	.pti dd ?
103	.abs_cx dd ?	103	.abs_cx dd ?
104	.abs_cy dd ?	104	.abs_cy dd ?
105	.line_increment dd ?	105	.line_increment dd ?
106	.winmap_newline dd ?	106	.winmap_newline dd ?
107	.screen_newline dd ?	107	.screen_newline dd ?
108	.real_sx_and_abs_cx dd ?	108	.real_sx_and_abs_cx dd ?
109	.real_sy_and_abs_cy dd ?	109	.real_sy_and_abs_cy dd ?
110	.stack_data = 4*14	110	.stack_data = 4*14
111	.edi dd ?	111	.edi dd ?
112	.esi dd ?	112	.esi dd ?
113	.ebp dd ?	113	.ebp dd ?
114	.esp dd ?	114	.esp dd ?
115	.ebx dd ?	115	.ebx dd ?
116	.edx dd ?	116	.edx dd ?
117	.ecx dd ?	117	.ecx dd ?
118	.eax dd ?	118	.eax dd ?
119	.ret_addr dd ?	119	.ret_addr dd ?
120	.arg_0 dd ?	120	.arg_0 dd ?
121	end virtual	121	end virtual
122	;-----------------------------------------------------------------------------	122	;-----------------------------------------------------------------------------
123	align 16	123	align 16
124	; ebx = pointer	124	; ebx = pointer
125	; ecx = size [x\|y]	125	; ecx = size [x\|y]
126	; edx = coordinates [x\|y]	126	; edx = coordinates [x\|y]
127	; ebp = pointer to 'get' function	127	; ebp = pointer to 'get' function
128	; esi = pointer to 'init' function	128	; esi = pointer to 'init' function
129	; edi = parameter for 'get' function	129	; edi = parameter for 'get' function
130	vesa20_putimage:	130	vesa20_putimage:
131	pushad	131	pushad
132	sub esp, putimg.stack_data	132	sub esp, putimg.stack_data
133	; save pointer to image	133	; save pointer to image
134	mov [putimg.pti], ebx	134	mov [putimg.pti], ebx
135	; unpack the size	135	; unpack the size
136	mov eax, ecx	136	mov eax, ecx
137	and ecx, 0xFFFF	137	and ecx, 0xFFFF
138	shr eax, 16	138	shr eax, 16
139	mov [putimg.image_sx], eax	139	mov [putimg.image_sx], eax
140	mov [putimg.image_sy], ecx	140	mov [putimg.image_sy], ecx
141	; unpack the coordinates	141	; unpack the coordinates
142	mov eax, edx	142	mov eax, edx
143	and edx, 0xFFFF	143	and edx, 0xFFFF
144	shr eax, 16	144	shr eax, 16
145	mov [putimg.image_cx], eax	145	mov [putimg.image_cx], eax
146	mov [putimg.image_cy], edx	146	mov [putimg.image_cy], edx
147	; calculate absolute (i.e. screen) coordinates	147	; calculate absolute (i.e. screen) coordinates
148	mov eax, [TASK_BASE]	148	mov eax, [TASK_BASE]
149	mov ebx, [eax-twdw + WDATA.box.left]	149	mov ebx, [eax-twdw + WDATA.box.left]
150	add ebx, [putimg.image_cx]	150	add ebx, [putimg.image_cx]
151	mov [putimg.abs_cx], ebx	151	mov [putimg.abs_cx], ebx
152	mov ebx, [eax-twdw + WDATA.box.top]	152	mov ebx, [eax-twdw + WDATA.box.top]
153	add ebx, [putimg.image_cy]	153	add ebx, [putimg.image_cy]
154	mov [putimg.abs_cy], ebx	154	mov [putimg.abs_cy], ebx
155	; real_sx = MIN(wnd_sx-image_cx, image_sx);	155	; real_sx = MIN(wnd_sx-image_cx, image_sx);
156	mov ebx, [eax-twdw + WDATA.box.width]; ebx = wnd_sx	156	mov ebx, [eax-twdw + WDATA.box.width]; ebx = wnd_sx
157	; \begin{diamond}[20.08.2006]	157	; \begin{diamond}[20.08.2006]
158	; note that WDATA.box.width is one pixel less than real window x-size	158	; note that WDATA.box.width is one pixel less than real window x-size
159	inc ebx	159	inc ebx
160	; \end{diamond}[20.08.2006]	160	; \end{diamond}[20.08.2006]
161	sub ebx, [putimg.image_cx]	161	sub ebx, [putimg.image_cx]
162	ja @f	162	ja @f
163	add esp, putimg.stack_data	163	add esp, putimg.stack_data
164	popad	164	popad
165	ret	165	ret
166	;--------------------------------------	166	;--------------------------------------
167	align 4	167	align 4
168	@@:	168	@@:
169	cmp ebx, [putimg.image_sx]	169	cmp ebx, [putimg.image_sx]
170	jbe .end_x	170	jbe .end_x
171	mov ebx, [putimg.image_sx]	171	mov ebx, [putimg.image_sx]
172	;--------------------------------------	172	;--------------------------------------
173	align 4	173	align 4
174	.end_x:	174	.end_x:
175	mov [putimg.real_sx], ebx	175	mov [putimg.real_sx], ebx
176	; init real_sy	176	; init real_sy
177	mov ebx, [eax-twdw + WDATA.box.height]; ebx = wnd_sy	177	mov ebx, [eax-twdw + WDATA.box.height]; ebx = wnd_sy
178	; \begin{diamond}[20.08.2006]	178	; \begin{diamond}[20.08.2006]
179	inc ebx	179	inc ebx
180	; \end{diamond}[20.08.2006]	180	; \end{diamond}[20.08.2006]
181	sub ebx, [putimg.image_cy]	181	sub ebx, [putimg.image_cy]
182	ja @f	182	ja @f
183	add esp, putimg.stack_data	183	add esp, putimg.stack_data
184	popad	184	popad
185	ret	185	ret
186	;--------------------------------------	186	;--------------------------------------
187	align 4	187	align 4
188	@@:	188	@@:
189	cmp ebx, [putimg.image_sy]	189	cmp ebx, [putimg.image_sy]
190	jbe .end_y	190	jbe .end_y
191	mov ebx, [putimg.image_sy]	191	mov ebx, [putimg.image_sy]
192	;--------------------------------------	192	;--------------------------------------
193	align 4	193	align 4
194	.end_y:	194	.end_y:
195	mov [putimg.real_sy], ebx	195	mov [putimg.real_sy], ebx
196	; line increment	196	; line increment
197	mov eax, [putimg.image_sx]	197	mov eax, [putimg.image_sx]
198	mov ecx, [putimg.real_sx]	198	mov ecx, [putimg.real_sx]
199	sub eax, ecx	199	sub eax, ecx
200	;; imul eax, [putimg.source_bpp]	200	;; imul eax, [putimg.source_bpp]
201	; lea eax, [eax + eax * 2]	201	; lea eax, [eax + eax * 2]
202	call esi	202	call esi
203	add eax, [putimg.arg_0]	203	add eax, [putimg.arg_0]
204	mov [putimg.line_increment], eax	204	mov [putimg.line_increment], eax
205	; winmap new line increment	205	; winmap new line increment
206	mov eax, [Screen_Max_X]	206	mov eax, [Screen_Max_X]
207	inc eax	207	inc eax
208	sub eax, [putimg.real_sx]	208	sub eax, [putimg.real_sx]
209	mov [putimg.winmap_newline], eax	209	mov [putimg.winmap_newline], eax
210	; screen new line increment	210	; screen new line increment
211	mov eax, [BytesPerScanLine]	211	mov eax, [BytesPerScanLine]
212	movzx ebx, byte [ScreenBPP]	212	movzx ebx, byte [ScreenBPP]
213	shr ebx, 3	213	shr ebx, 3
214	imul ecx, ebx	214	imul ecx, ebx
215	sub eax, ecx	215	sub eax, ecx
216	mov [putimg.screen_newline], eax	216	mov [putimg.screen_newline], eax
217	; pointer to image	217	; pointer to image
218	mov esi, [putimg.pti]	218	mov esi, [putimg.pti]
219	; pointer to screen	219	; pointer to screen
220	mov edx, [putimg.abs_cy]	220	mov edx, [putimg.abs_cy]
221	imul edx, [BytesPerScanLine]	221	imul edx, [BytesPerScanLine]
222	mov eax, [putimg.abs_cx]	222	mov eax, [putimg.abs_cx]
223	movzx ebx, byte [ScreenBPP]	223	movzx ebx, byte [ScreenBPP]
224	shr ebx, 3	224	shr ebx, 3
225	imul eax, ebx	225	imul eax, ebx
226	add edx, eax	226	add edx, eax
227	; pointer to pixel map	227	; pointer to pixel map
228	mov eax, [putimg.abs_cy]	228	mov eax, [putimg.abs_cy]
229	imul eax, [Screen_Max_X]	229	imul eax, [Screen_Max_X]
230	add eax, [putimg.abs_cy]	230	add eax, [putimg.abs_cy]
231	add eax, [putimg.abs_cx]	231	add eax, [putimg.abs_cx]
232	add eax, [_WinMapAddress]	232	add eax, [_WinMapAddress]
233	xchg eax, ebp	233	xchg eax, ebp
234	;--------------------------------------	234	;--------------------------------------
235	mov ecx, [putimg.real_sx]	235	mov ecx, [putimg.real_sx]
236	add ecx, [putimg.abs_cx]	236	add ecx, [putimg.abs_cx]
237	mov [putimg.real_sx_and_abs_cx], ecx	237	mov [putimg.real_sx_and_abs_cx], ecx
238	mov ecx, [putimg.real_sy]	238	mov ecx, [putimg.real_sy]
239	add ecx, [putimg.abs_cy]	239	add ecx, [putimg.abs_cy]
240	mov [putimg.real_sy_and_abs_cy], ecx	240	mov [putimg.real_sy_and_abs_cy], ecx
241	;--------------------------------------	241	;--------------------------------------
242	; get process number	242	; get process number
243	mov ebx, [CURRENT_TASK]	243	mov ebx, [CURRENT_TASK]
244	cmp byte [ScreenBPP], 32	244	cmp byte [ScreenBPP], 32
245	je put_image_end_32	245	je put_image_end_32
246	;--------------------------------------	246	;--------------------------------------
247	put_image_end_24:	247	put_image_end_24:
248	mov edi, [putimg.real_sy]	248	mov edi, [putimg.real_sy]
249	cmp [_display.select_cursor], 0	249	cmp [_display.select_cursor], 0
250	jne put_image_end_24_new	250	jne put_image_end_24_new
251	;--------------------------------------	251	;--------------------------------------
252	align 4	252	align 4
253	.new_line:	253	.new_line:
254	mov ecx, [putimg.real_sx]	254	mov ecx, [putimg.real_sx]
255	;--------------------------------------	255	;--------------------------------------
256	align 4	256	align 4
257	.new_x:	257	.new_x:
258	push [putimg.edi]	258	push [putimg.edi]
259	mov eax, [putimg.ebp+4]	259	mov eax, [putimg.ebp+4]
260	call eax	260	call eax
261	cmp [ebp], bl	261	cmp [ebp], bl
262	jne .skip	262	jne .skip
263	;--------------------------------------	263	;--------------------------------------
264	push ecx	264	push ecx
265		265
266	neg ecx	266	neg ecx
267	add ecx, [putimg.real_sx_and_abs_cx + 4]	267	add ecx, [putimg.real_sx_and_abs_cx + 4]
268	shl ecx, 16	268	shl ecx, 16
269	add ecx, [putimg.real_sy_and_abs_cy + 4]	269	add ecx, [putimg.real_sy_and_abs_cy + 4]
270	sub ecx, edi	270	sub ecx, edi
271		271
272	; check mouse area for putpixel	272	; check mouse area for putpixel
273	call check_mouse_area_for_putpixel	273	call check_mouse_area_for_putpixel
274	pop ecx	274	pop ecx
275	; store to real LFB	275	; store to real LFB
276	mov [LFB_BASE+edx], ax	276	mov [LFB_BASE+edx], ax
277	shr eax, 16	277	shr eax, 16
278	mov [LFB_BASE+edx+2], al	278	mov [LFB_BASE+edx+2], al
279	;--------------------------------------	279	;--------------------------------------
280	align 4	280	align 4
281	.skip:	281	.skip:
282	add edx, 3	282	add edx, 3
283	inc ebp	283	inc ebp
284	dec ecx	284	dec ecx
285	jnz .new_x	285	jnz .new_x
286		286
287	add esi, [putimg.line_increment]	287	add esi, [putimg.line_increment]
288	add edx, [putimg.screen_newline];[BytesPerScanLine]	288	add edx, [putimg.screen_newline];[BytesPerScanLine]
289	add ebp, [putimg.winmap_newline];[Screen_Max_X]	289	add ebp, [putimg.winmap_newline];[Screen_Max_X]
290		290
291	cmp [putimg.ebp], putimage_get1bpp	291	cmp [putimg.ebp], putimage_get1bpp
292	jz .correct	292	jz .correct
293	cmp [putimg.ebp], putimage_get2bpp	293	cmp [putimg.ebp], putimage_get2bpp
294	jz .correct	294	jz .correct
295	cmp [putimg.ebp], putimage_get4bpp	295	cmp [putimg.ebp], putimage_get4bpp
296	jnz @f	296	jnz @f
297	;--------------------------------------	297	;--------------------------------------
298	align 4	298	align 4
299	.correct:	299	.correct:
300	mov eax, [putimg.edi]	300	mov eax, [putimg.edi]
301	mov byte [eax], 80h	301	mov byte [eax], 80h
302	;--------------------------------------	302	;--------------------------------------
303	align 4	303	align 4
304	@@:	304	@@:
305	dec edi	305	dec edi
306	jnz .new_line	306	jnz .new_line
307	;--------------------------------------	307	;--------------------------------------
308	align 4	308	align 4
309	.finish:	309	.finish:
310	add esp, putimg.stack_data	310	add esp, putimg.stack_data
311	popad	311	popad
312	ret	312	ret
313	;--------------------------------------	313	;--------------------------------------
314	align 4	314	align 4
315	put_image_end_24_new:	315	put_image_end_24_new:
316	;--------------------------------------	316	;--------------------------------------
317	align 4	317	align 4
318	.new_line:	318	.new_line:
319	mov ecx, [putimg.real_sx]	319	mov ecx, [putimg.real_sx]
320	;--------------------------------------	320	;--------------------------------------
321	align 4	321	align 4
322	.new_x:	322	.new_x:
323	push [putimg.edi]	323	push [putimg.edi]
324	mov eax, [putimg.ebp+4]	324	mov eax, [putimg.ebp+4]
325	call eax	325	call eax
326	cmp [ebp], bl	326	cmp [ebp], bl
327	jne .skip	327	jne .skip
328	;--------------------------------------	328	;--------------------------------------
329	push ecx	329	push ecx
330	mov ecx, [putimg.real_sy_and_abs_cy + 4]	330	mov ecx, [putimg.real_sy_and_abs_cy + 4]
331	sub ecx, edi	331	sub ecx, edi
332	;--------------------------------------	332	;--------------------------------------
333	; check for Y	333	; check for Y
334	cmp cx, [Y_UNDER_subtraction_CUR_hot_y]	334	cmp cx, [Y_UNDER_subtraction_CUR_hot_y]
335	jb .no_mouse_area	335	jb .no_mouse_area
336		336
337	cmp cx, [Y_UNDER_sub_CUR_hot_y_add_curh]	337	cmp cx, [Y_UNDER_sub_CUR_hot_y_add_curh]
338	jae .no_mouse_area	338	jae .no_mouse_area
339		339
340	rol ecx, 16	340	rol ecx, 16
341	add ecx, [putimg.real_sx_and_abs_cx + 4]	341	add ecx, [putimg.real_sx_and_abs_cx + 4]
342	sub ecx, [esp]	342	sub ecx, [esp]
343	;--------------------------------------	343	;--------------------------------------
344	; check for X	344	; check for X
345	cmp cx, [X_UNDER_subtraction_CUR_hot_x]	345	cmp cx, [X_UNDER_subtraction_CUR_hot_x]
346	jb .no_mouse_area	346	jb .no_mouse_area
347		347
348	cmp cx, [X_UNDER_sub_CUR_hot_x_add_curh]	348	cmp cx, [X_UNDER_sub_CUR_hot_x_add_curh]
349	jae .no_mouse_area	349	jae .no_mouse_area
350	;--------------------------------------	350	;--------------------------------------
351	; check mouse area for putpixel	351	; check mouse area for putpixel
352	call check_mouse_area_for_putpixel_new.1	352	call check_mouse_area_for_putpixel_new.1
353	;--------------------------------------	353	;--------------------------------------
354	align 4	354	align 4
355	.no_mouse_area:	355	.no_mouse_area:
356	pop ecx	356	pop ecx
357	; store to real LFB	357	; store to real LFB
358	mov [LFB_BASE+edx], ax	358	mov [LFB_BASE+edx], ax
359	shr eax, 16	359	shr eax, 16
360	mov [LFB_BASE+edx+2], al	360	mov [LFB_BASE+edx+2], al
361	;--------------------------------------	361	;--------------------------------------
362	align 4	362	align 4
363	.skip:	363	.skip:
364	add edx, 3	364	add edx, 3
365	inc ebp	365	inc ebp
366	dec ecx	366	dec ecx
367	jnz .new_x	367	jnz .new_x
368		368
369	add esi, [putimg.line_increment]	369	add esi, [putimg.line_increment]
370	add edx, [putimg.screen_newline];[BytesPerScanLine]	370	add edx, [putimg.screen_newline];[BytesPerScanLine]
371	add ebp, [putimg.winmap_newline];[Screen_Max_X]	371	add ebp, [putimg.winmap_newline];[Screen_Max_X]
372		372
373	cmp [putimg.ebp], putimage_get1bpp	373	cmp [putimg.ebp], putimage_get1bpp
374	jz .correct	374	jz .correct
375	cmp [putimg.ebp], putimage_get2bpp	375	cmp [putimg.ebp], putimage_get2bpp
376	jz .correct	376	jz .correct
377	cmp [putimg.ebp], putimage_get4bpp	377	cmp [putimg.ebp], putimage_get4bpp
378	jnz @f	378	jnz @f
379	;--------------------------------------	379	;--------------------------------------
380	align 4	380	align 4
381	.correct:	381	.correct:
382	mov eax, [putimg.edi]	382	mov eax, [putimg.edi]
383	mov byte [eax], 80h	383	mov byte [eax], 80h
384	;--------------------------------------	384	;--------------------------------------
385	align 4	385	align 4
386	@@:	386	@@:
387	dec edi	387	dec edi
388	jnz .new_line	388	jnz .new_line
389	jmp put_image_end_24.finish	389	jmp put_image_end_24.finish
390	;------------------------------------------------------------------------------	390	;------------------------------------------------------------------------------
391	align 4	391	align 4
392	put_image_end_32:	392	put_image_end_32:
393	mov edi, [putimg.real_sy]	393	mov edi, [putimg.real_sy]
394	cmp [_display.select_cursor], 0	394	cmp [_display.select_cursor], 0
395	jne put_image_end_32_new	395	jne put_image_end_32_new
396	;--------------------------------------	396	;--------------------------------------
397	align 4	397	align 4
398	.new_line:	398	.new_line:
399	mov ecx, [putimg.real_sx]	399	mov ecx, [putimg.real_sx]
400	;--------------------------------------	400	;--------------------------------------
401	align 4	401	align 4
402	.new_x:	402	.new_x:
403	push [putimg.edi]	403	push [putimg.edi]
404	mov eax, [putimg.ebp+4]	404	mov eax, [putimg.ebp+4]
405	call eax	405	call eax
406	cmp [ebp], bl	406	cmp [ebp], bl
407	jne .skip	407	jne .skip
408	;--------------------------------------	408	;--------------------------------------
409	push ecx	409	push ecx
410		410
411	neg ecx	411	neg ecx
412	add ecx, [putimg.real_sx_and_abs_cx + 4]	412	add ecx, [putimg.real_sx_and_abs_cx + 4]
413	shl ecx, 16	413	shl ecx, 16
414	add ecx, [putimg.real_sy_and_abs_cy + 4]	414	add ecx, [putimg.real_sy_and_abs_cy + 4]
415	sub ecx, edi	415	sub ecx, edi
416		416
417	; check mouse area for putpixel	417	; check mouse area for putpixel
418	call check_mouse_area_for_putpixel	418	call check_mouse_area_for_putpixel
419	pop ecx	419	pop ecx
420	; store to real LFB	420	; store to real LFB
421	mov [LFB_BASE+edx], eax	421	mov [LFB_BASE+edx], eax
422	;--------------------------------------	422	;--------------------------------------
423	align 4	423	align 4
424	.skip:	424	.skip:
425	add edx, 4	425	add edx, 4
426	inc ebp	426	inc ebp
427	dec ecx	427	dec ecx
428	jnz .new_x	428	jnz .new_x
429		429
430	add esi, [putimg.line_increment]	430	add esi, [putimg.line_increment]
431	add edx, [putimg.screen_newline];[BytesPerScanLine]	431	add edx, [putimg.screen_newline];[BytesPerScanLine]
432	add ebp, [putimg.winmap_newline];[Screen_Max_X]	432	add ebp, [putimg.winmap_newline];[Screen_Max_X]
433		433
434	cmp [putimg.ebp], putimage_get1bpp	434	cmp [putimg.ebp], putimage_get1bpp
435	jz .correct	435	jz .correct
436	cmp [putimg.ebp], putimage_get2bpp	436	cmp [putimg.ebp], putimage_get2bpp
437	jz .correct	437	jz .correct
438	cmp [putimg.ebp], putimage_get4bpp	438	cmp [putimg.ebp], putimage_get4bpp
439	jnz @f	439	jnz @f
440	;--------------------------------------	440	;--------------------------------------
441	align 4	441	align 4
442	.correct:	442	.correct:
443	mov eax, [putimg.edi]	443	mov eax, [putimg.edi]
444	mov byte [eax], 80h	444	mov byte [eax], 80h
445	;--------------------------------------	445	;--------------------------------------
446	align 4	446	align 4
447	@@:	447	@@:
448	dec edi	448	dec edi
449	jnz .new_line	449	jnz .new_line
450	;--------------------------------------	450	;--------------------------------------
451	align 4	451	align 4
452	.finish:	452	.finish:
453	add esp, putimg.stack_data	453	add esp, putimg.stack_data
454	popad	454	popad
455	cmp [SCR_MODE], dword 0x12	455	cmp [SCR_MODE], dword 0x12
456	jne @f	456	jne @f
457	call VGA__putimage	457	call VGA__putimage
458	;--------------------------------------	458	;--------------------------------------
459	align 4	459	align 4
460	@@:	460	@@:
461	mov [EGA_counter], 1	461	mov [EGA_counter], 1
462	ret	462	ret
463	;--------------------------------------	463	;--------------------------------------
464	align 4	464	align 4
465	put_image_end_32_new:	465	put_image_end_32_new:
466	;--------------------------------------	466	;--------------------------------------
467	align 4	467	align 4
468	.new_line:	468	.new_line:
469	mov ecx, [putimg.real_sx]	469	mov ecx, [putimg.real_sx]
470	;--------------------------------------	470	;--------------------------------------
471	align 4	471	align 4
472	.new_x:	472	.new_x:
473	push [putimg.edi]	473	push [putimg.edi]
474	mov eax, [putimg.ebp+4]	474	mov eax, [putimg.ebp+4]
475	call eax	475	call eax
476	cmp [ebp], bl	476	cmp [ebp], bl
477	jne .skip	477	jne .skip
478	;--------------------------------------	478	;--------------------------------------
479	push ecx	479	push ecx
480	mov ecx, [putimg.real_sy_and_abs_cy + 4]	480	mov ecx, [putimg.real_sy_and_abs_cy + 4]
481	sub ecx, edi	481	sub ecx, edi
482	;--------------------------------------	482	;--------------------------------------
483	; check for Y	483	; check for Y
484	cmp cx, [Y_UNDER_subtraction_CUR_hot_y]	484	cmp cx, [Y_UNDER_subtraction_CUR_hot_y]
485	jb .no_mouse_area	485	jb .no_mouse_area
486		486
487	cmp cx, [Y_UNDER_sub_CUR_hot_y_add_curh]	487	cmp cx, [Y_UNDER_sub_CUR_hot_y_add_curh]
488	jae .no_mouse_area	488	jae .no_mouse_area
489		489
490	rol ecx, 16	490	rol ecx, 16
491	add ecx, [putimg.real_sx_and_abs_cx + 4]	491	add ecx, [putimg.real_sx_and_abs_cx + 4]
492	sub ecx, [esp]	492	sub ecx, [esp]
493	;--------------------------------------	493	;--------------------------------------
494	; check for X	494	; check for X
495	cmp cx, [X_UNDER_subtraction_CUR_hot_x]	495	cmp cx, [X_UNDER_subtraction_CUR_hot_x]
496	jb .no_mouse_area	496	jb .no_mouse_area
497		497
498	cmp cx, [X_UNDER_sub_CUR_hot_x_add_curh]	498	cmp cx, [X_UNDER_sub_CUR_hot_x_add_curh]
499	jae .no_mouse_area	499	jae .no_mouse_area
500	;--------------------------------------	500	;--------------------------------------

Subversion Repositories Kolibri OS

(root)/kernel/trunk/video/vesa20.inc – Rev 2436 → 2438