Subversion Repositories Kolibri OS

        push    0               ; for fat_get_name: read ASCII name

;----------------------------------------------------------------

;

;  fs_FloppyReadFolder - LFN variant for reading floppy folders

;

;  esi  points to filename

;  ebx  pointer to 32-bit number = first wanted block, 0+

;  ecx  number of blocks to read, 0+

;  edx  mem location to return data

;

;  ret ebx = size or 0xffffffff folder not found

;      eax = 0 ok read or other = errormsg

;

;--------------------------------------------------------------

fs_FloppyReadFolder:

        call    read_flp_fat

        mov     ebx, [ebx]

        push    edi

        cmp     byte [esi], 0

        jz      .root

        call    fd_find_lfn

        jnc     .found

        pop     edi

        or      ebx, -1

        mov     eax, ERROR_FILE_NOT_FOUND

        ret

.found:

        test    byte [edi+11], 0x10     ; do not allow read files

        jnz     .found_dir

        pop     edi

        or      ebx, -1

        mov     eax, ERROR_ACCESS_DENIED

        ret

.found_dir:

        movzx   eax, word [edi+26]

        add     eax, 31

        push    0

        jmp     .doit

.root:

        mov     eax, 19

        push    14

.doit:

        push    ecx ebp

        sub     esp, 262*2      ; reserve space for LFN

        mov     ebp, esp

        push    1               ; for fat_get_name: read UNICODE names

; init header

        push    eax ecx

        mov     edi, edx

        mov     ecx, 32/4

        xor     eax, eax

        rep     stosd

        pop     ecx eax

        mov     byte [edx], 1   ; version

        mov     esi, edi        ; esi points to BDFE

.main_loop:

        pusha

        call    read_chs_sector

        popa

        cmp     [FDC_Status], 0

        jnz     .error

        mov     edi, 0xD000

        push    eax

.l1:

        call    fat_get_name

        jc      .l2

        cmp     byte [edi+11], 0xF

        jnz     .do_bdfe

        add     edi, 0x20

        cmp     edi, 0xD200

        jb      .do_bdfe

        pop     eax

        inc     eax

        dec     byte [esp+262*2+12]

        jz      .done

        jns     @f

; read next sector from FAT

        mov     eax, [(eax-31-1)*2+0x282000]

        and     eax, 0xFFF

        cmp     eax, 0xFF8

        jae     .done

        add     eax, 31

        mov     byte [esp+262*2+12], 0

@@:

        pusha

        call    read_chs_sector

        popa

        cmp     [FDC_Status], 0

        jnz     .error

        mov     edi, 0xD000

        push    eax

.do_bdfe:

        inc     dword [edx+8]   ; new file found

        dec     ebx

        jns     .l2

        dec     ecx

        js      .l2

        inc     dword [edx+4]   ; new file block copied

        call    fat_entry_to_bdfe

.l2:

        add     edi, 0x20

        cmp     edi, 0xD200

        jb      .l1

        pop     eax

        inc     eax

        dec     byte [esp+262*2+12]

        jz      .done

        jns     @f

; read next sector from FAT

        mov     eax, [(eax-31-1)*2+0x282000]

        and     eax, 0xFFF

        cmp     eax, 0xFF8

        jae     .done

        add     eax, 31

        mov     byte [esp+262*2+12], 0

@@:

        jmp     .main_loop

.error:

        add     esp, 262*2+4

        pop     ebp ecx edi edi

        or      ebx, -1

        mov     eax, ERROR_FILE_NOT_FOUND

        ret

.done:

        add     esp, 262*2+4

        pop     ebp

        mov     ebx, [edx+8]

        xor     eax, eax

        dec     ecx

        js      @f

        mov     al, ERROR_END_OF_FILE

@@:

        pop     ecx edi edi

        ret