WebSVN – Kolibri OS – Diff – /kernel/branches/kolibri-process/video/vesa20.inc


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;                                                              ;;
;; Copyright (C) KolibriOS team 2004-2012. All rights reserved. ;;
;; Distributed under terms of the GNU General Public License    ;;
;;                                                              ;;
;;  VESA20.INC                                                  ;;
;;                                                              ;;
;;  Vesa 2.0 functions for MenuetOS                             ;;
;;                                                              ;;
;;  Copyright 2002 Ville Turjanmaa                              ;;
;;  Alexey, kgaz@crosswindws.net                                ;;
;;  - Voodoo compatible graphics                                ;;
;;  Juan M. Caravaca                                            ;;
;;  - Graphics optimimizations eg. drawline                     ;;
;;                                                              ;;
;;  See file COPYING for details                                ;;
;;                                                              ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 
$Revision: 3606 $
 
 
; If you're planning to write your own video driver I suggest
; you replace the VESA12.INC file and see those instructions.
 
 
;-----------------------------------------------------------------------------
; getpixel
;
; in:
; eax = x coordinate
; ebx = y coordinate
;
; ret:
; ecx = 00 RR GG BB
;-----------------------------------------------------------------------------
align 4
getpixel:
        push    eax ebx edx edi
        call    dword [GETPIXEL]
        pop     edi edx ebx eax
        ret
;-----------------------------------------------------------------------------
align 4
Vesa20_getpixel24:
; eax = x
; ebx = y
;--------------------------------------
; check for hardware cursor
        cmp     [_display.select_cursor], select_cursor
        je      @f
        cmp     [_display.select_cursor], 0
        jne     .no_mouseunder
;--------------------------------------
align 4
@@:
; check mouse area for putpixel
        test    ecx, 0x04000000  ; don't load to mouseunder area
        jnz     .no_mouseunder
        call    [_display.check_m_pixel]
        test    ecx, ecx        ;0xff000000
        jnz     @f
;--------------------------------------
align 4
.no_mouseunder:
;--------------------------------------
;        imul    ebx, [BytesPerScanLine] ; ebx = y * y multiplier
        mov     ebx, [BPSLine_calc_area+ebx*4]
        lea     edi, [eax+eax*2]; edi = x*3
        add     edi, ebx      ; edi = x*3+(y*y multiplier)
        mov     ecx, [LFB_BASE+edi]
;--------------------------------------
align 4
@@:
        and     ecx, 0xffffff
        ret
;-----------------------------------------------------------------------------
align 4
Vesa20_getpixel32:
;--------------------------------------
; check for hardware cursor
        cmp     [_display.select_cursor], select_cursor
        je      @f
        cmp     [_display.select_cursor], 0
        jne     .no_mouseunder
;--------------------------------------
align 4
@@:
; check mouse area for putpixel
        test    ecx, 0x04000000  ; don't load to mouseunder area
        jnz     .no_mouseunder
        call    [_display.check_m_pixel]
        test    ecx, ecx        ;0xff000000
        jnz     @f
;--------------------------------------
align 4
.no_mouseunder:
;--------------------------------------
;        imul    ebx, [BytesPerScanLine] ; ebx = y * y multiplier
        mov     ebx, [BPSLine_calc_area+ebx*4]
        lea     edi, [ebx+eax*4]; edi = x*4+(y*y multiplier)
        mov     ecx, [LFB_BASE+edi]
;--------------------------------------
align 4
@@:
        and     ecx, 0xffffff
        ret
;-----------------------------------------------------------------------------
virtual at esp
 putimg:
   .real_sx        dd ?
   .real_sy        dd ?
   .image_sx       dd ?
   .image_sy       dd ?
   .image_cx       dd ?
   .image_cy       dd ?
   .pti            dd ?
   .abs_cx         dd ?
   .abs_cy         dd ?
   .line_increment dd ?
   .winmap_newline dd ?
   .screen_newline dd ?
   .real_sx_and_abs_cx dd ?
   .real_sy_and_abs_cy dd ?
   .stack_data = 4*14
   .edi         dd      ?
   .esi         dd      ?
   .ebp         dd      ?
   .esp         dd      ?
   .ebx         dd      ?
   .edx         dd      ?
   .ecx         dd      ?
   .eax         dd      ?
   .ret_addr    dd      ?
   .arg_0       dd      ?
end virtual
;-----------------------------------------------------------------------------
align 16
; ebx = pointer
; ecx = size [x|y]
; edx = coordinates [x|y]
; ebp = pointer to 'get' function
; esi = pointer to 'init' function
; edi = parameter for 'get' function
vesa20_putimage:
        pushad
        sub     esp, putimg.stack_data
; save pointer to image
        mov     [putimg.pti], ebx
; unpack the size
        mov     eax, ecx
        and     ecx, 0xFFFF
        shr     eax, 16
        mov     [putimg.image_sx], eax
        mov     [putimg.image_sy], ecx
; unpack the coordinates
        mov     eax, edx
        and     edx, 0xFFFF
        shr     eax, 16
        mov     [putimg.image_cx], eax
        mov     [putimg.image_cy], edx
; calculate absolute (i.e. screen) coordinates
        mov     eax, [TASK_BASE]
        mov     ebx, [eax-twdw + WDATA.box.left]
        add     ebx, [putimg.image_cx]
        mov     [putimg.abs_cx], ebx
        mov     ebx, [eax-twdw + WDATA.box.top]
        add     ebx, [putimg.image_cy]
        mov     [putimg.abs_cy], ebx
; real_sx = MIN(wnd_sx-image_cx, image_sx);
        mov     ebx, [eax-twdw + WDATA.box.width]; ebx = wnd_sx
; \begin{diamond}[20.08.2006]
; note that WDATA.box.width is one pixel less than real window x-size
        inc     ebx
; \end{diamond}[20.08.2006]
        sub     ebx, [putimg.image_cx]
        ja      @f
        add     esp, putimg.stack_data
        popad
        ret
;--------------------------------------
align 4
@@:
        cmp     ebx, [putimg.image_sx]
        jbe     .end_x
        mov     ebx, [putimg.image_sx]
;--------------------------------------
align 4
.end_x:
        mov     [putimg.real_sx], ebx
; init real_sy
        mov     ebx, [eax-twdw + WDATA.box.height]; ebx = wnd_sy
; \begin{diamond}[20.08.2006]
        inc     ebx
; \end{diamond}[20.08.2006]
        sub     ebx, [putimg.image_cy]
        ja      @f
        add     esp, putimg.stack_data
        popad
        ret
;--------------------------------------
align 4
@@:
        cmp     ebx, [putimg.image_sy]
        jbe     .end_y
        mov     ebx, [putimg.image_sy]
;--------------------------------------
align 4
.end_y:
        mov     [putimg.real_sy], ebx
; line increment
        mov     eax, [putimg.image_sx]
        mov     ecx, [putimg.real_sx]
        sub     eax, ecx
;;     imul    eax, [putimg.source_bpp]
;     lea     eax, [eax + eax * 2]
        call    esi
        add     eax, [putimg.arg_0]
        mov     [putimg.line_increment], eax
; winmap new line increment
        mov     eax, [_display.width]
 
        sub     eax, [putimg.real_sx]
        mov     [putimg.winmap_newline], eax
; screen new line increment
        mov     eax, [_display.pitch]
        mov     ebx, [_display.bpp]
        shr     ebx, 3
        imul    ecx, ebx
        sub     eax, ecx
        mov     [putimg.screen_newline], eax
; pointer to image
        mov     esi, [putimg.pti]
; pointer to screen
        mov     edx, [putimg.abs_cy]
;        imul    edx, [BytesPerScanLine]
        mov     edx, [BPSLine_calc_area+edx*4]
        mov     eax, [putimg.abs_cx]
;        movzx   ebx, byte [ScreenBPP]
;        shr     ebx, 3
        imul    eax, ebx
        add     edx, eax
; pointer to pixel map
        mov     eax, [putimg.abs_cy]
        mov     eax, [d_width_calc_area + eax*4]
 
        add     eax, [putimg.abs_cx]
        add     eax, [_WinMapAddress]
        xchg    eax, ebp
;--------------------------------------
        mov     ecx, [putimg.real_sx]
        add     ecx, [putimg.abs_cx]
        mov     [putimg.real_sx_and_abs_cx], ecx
        mov     ecx, [putimg.real_sy]
        add     ecx, [putimg.abs_cy]
        mov     [putimg.real_sy_and_abs_cy], ecx
;--------------------------------------
; get process number
        mov     ebx, [CURRENT_TASK]
        cmp     byte [_display.bpp], 32
        je      put_image_end_32
;--------------------------------------
put_image_end_24:
        mov     edi, [putimg.real_sy]
;--------------------------------------
; check for hardware cursor
        mov     ecx, [_display.select_cursor]
        cmp     ecx, select_cursor
        je      put_image_end_24_new
        cmp     ecx, 0
        je      put_image_end_24_old
;--------------------------------------
align 4
.new_line:
        mov     ecx, [putimg.real_sx]
;--------------------------------------
align 4
.new_x:
        push    [putimg.edi]
        mov     eax, [putimg.ebp+4]
        call    eax
        cmp     [ebp], bl
        jne     .skip
;--------------------------------------
; store to real LFB
        mov     [LFB_BASE+edx], ax
        shr     eax, 16
        mov     [LFB_BASE+edx+2], al
;--------------------------------------
align 4
.skip:
        add     edx, 3
        inc     ebp
        dec     ecx
        jnz     .new_x
 
        add     esi, [putimg.line_increment]
        add     edx, [putimg.screen_newline];[BytesPerScanLine]
        add     ebp, [putimg.winmap_newline];[Screen_Max_X]
 
        cmp     [putimg.ebp], putimage_get1bpp
        jz      .correct
        cmp     [putimg.ebp], putimage_get2bpp
        jz      .correct
        cmp     [putimg.ebp], putimage_get4bpp
        jnz     @f
;--------------------------------------
align 4
.correct:
        mov     eax, [putimg.edi]
        mov     byte [eax], 80h
;--------------------------------------
align 4
@@:
        dec     edi
        jnz     .new_line
;--------------------------------------
align 4
.finish:
        add     esp, putimg.stack_data
        popad
        ret
;------------------------------------------------------------------------------
align 4
put_image_end_24_old:
;--------------------------------------
align 4
.new_line:
        mov     ecx, [putimg.real_sx]
;--------------------------------------
align 4
.new_x:
        push    [putimg.edi]
        mov     eax, [putimg.ebp+4]
        call    eax
        cmp     [ebp], bl
        jne     .skip
;--------------------------------------
        push    ecx
 
        neg     ecx
        add     ecx, [putimg.real_sx_and_abs_cx + 4]
        shl     ecx, 16
        add     ecx, [putimg.real_sy_and_abs_cy + 4]
        sub     ecx, edi
 
; check mouse area for putpixel
        call    check_mouse_area_for_putpixel
        pop     ecx
; store to real LFB
        mov     [LFB_BASE+edx], ax
        shr     eax, 16
        mov     [LFB_BASE+edx+2], al
;--------------------------------------
align 4
.skip:
        add     edx, 3
        inc     ebp
        dec     ecx
        jnz     .new_x
 
        add     esi, [putimg.line_increment]
        add     edx, [putimg.screen_newline];[BytesPerScanLine]
        add     ebp, [putimg.winmap_newline];[Screen_Max_X]
 
        cmp     [putimg.ebp], putimage_get1bpp
        jz      .correct
        cmp     [putimg.ebp], putimage_get2bpp
        jz      .correct
        cmp     [putimg.ebp], putimage_get4bpp
        jnz     @f
;--------------------------------------
align 4
.correct:
        mov     eax, [putimg.edi]
        mov     byte [eax], 80h
;--------------------------------------
align 4
@@:
        dec     edi
        jnz     .new_line
        jmp     put_image_end_24.finish
;------------------------------------------------------------------------------
align 4
put_image_end_24_new:
;--------------------------------------
align 4
.new_line:
        mov     ecx, [putimg.real_sx]
;--------------------------------------
align 4
.new_x:
        push    [putimg.edi]
        mov     eax, [putimg.ebp+4]
        call    eax
        cmp     [ebp], bl
        jne     .skip
;--------------------------------------
        push    ecx
;--------------------------------------
align 4
.sh:
        neg     ecx
        add     ecx, [putimg.real_sx_and_abs_cx + 4]
;--------------------------------------
; check for X
        cmp     cx, [X_UNDER_sub_CUR_hot_x_add_curh]
        jae     .no_mouse_area
 
        sub     cx, [X_UNDER_subtraction_CUR_hot_x]
        jb      .no_mouse_area
 
        shl     ecx, 16
 
        add     ecx, [putimg.real_sy_and_abs_cy + 4]
        sub     ecx, edi
;--------------------------------------
; check for Y
        cmp     cx, [Y_UNDER_sub_CUR_hot_y_add_curh]
        jae     .no_mouse_area
 
        sub     cx, [Y_UNDER_subtraction_CUR_hot_y]
        jb      .no_mouse_area
;--------------------------------------
; check mouse area for putpixel
        call    check_mouse_area_for_putpixel_new.1
        cmp     ecx, -1   ;SHIT HAPPENS?
        jne     .no_mouse_area
 
        mov     ecx, [esp]
        jmp     .sh
;--------------------------------------
align 4
.no_mouse_area:
        pop     ecx
; store to real LFB
        mov     [LFB_BASE+edx], ax
        shr     eax, 16
        mov     [LFB_BASE+edx+2], al
;--------------------------------------
align 4
.skip:
        add     edx, 3
        inc     ebp
        dec     ecx
        jnz     .new_x
 
        add     esi, [putimg.line_increment]
        add     edx, [putimg.screen_newline];[BytesPerScanLine]
        add     ebp, [putimg.winmap_newline];[Screen_Max_X]
 
        cmp     [putimg.ebp], putimage_get1bpp
        jz      .correct
        cmp     [putimg.ebp], putimage_get2bpp
        jz      .correct
        cmp     [putimg.ebp], putimage_get4bpp
        jnz     @f
;--------------------------------------
align 4
.correct:
        mov     eax, [putimg.edi]
        mov     byte [eax], 80h
;--------------------------------------
align 4
@@:
        dec     edi
        jnz     .new_line
        jmp     put_image_end_24.finish
;------------------------------------------------------------------------------
align 4
put_image_end_32:
        mov     edi, [putimg.real_sy]
;--------------------------------------
; check for hardware cursor
        mov     ecx, [_display.select_cursor]
        cmp     ecx, select_cursor
        je      put_image_end_32_new
        cmp     ecx, 0
        je      put_image_end_32_old
;--------------------------------------
align 4
.new_line:
        mov     ecx, [putimg.real_sx]
;--------------------------------------
align 4
.new_x:
        push    [putimg.edi]
        mov     eax, [putimg.ebp+4]
        call    eax
        cmp     [ebp], bl
        jne     .skip
;--------------------------------------
; store to real LFB
        mov     [LFB_BASE+edx], eax
;--------------------------------------
align 4
.skip:
        add     edx, 4
        inc     ebp
        dec     ecx
        jnz     .new_x
 
        add     esi, [putimg.line_increment]
        add     edx, [putimg.screen_newline];[BytesPerScanLine]
        add     ebp, [putimg.winmap_newline];[Screen_Max_X]
 
        cmp     [putimg.ebp], putimage_get1bpp
        jz      .correct
        cmp     [putimg.ebp], putimage_get2bpp
        jz      .correct
        cmp     [putimg.ebp], putimage_get4bpp
        jnz     @f
;--------------------------------------
align 4
.correct:
        mov     eax, [putimg.edi]
        mov     byte [eax], 80h
;--------------------------------------
align 4
@@:
        dec     edi
        jnz     .new_line
;--------------------------------------
align 4
.finish:
        add     esp, putimg.stack_data
        popad
        cmp     [SCR_MODE], 0x12
        jne     @f
        call    VGA__putimage
;--------------------------------------
align 4
@@:
        mov     [EGA_counter], 1
        ret
;------------------------------------------------------------------------------
align 4
put_image_end_32_old:
;--------------------------------------
align 4
.new_line:
        mov     ecx, [putimg.real_sx]
;--------------------------------------
align 4
.new_x:
        push    [putimg.edi]
        mov     eax, [putimg.ebp+4]
        call    eax
        cmp     [ebp], bl
        jne     .skip
;--------------------------------------
        push    ecx
 
        neg     ecx
        add     ecx, [putimg.real_sx_and_abs_cx + 4]
        shl     ecx, 16
        add     ecx, [putimg.real_sy_and_abs_cy + 4]
        sub     ecx, edi
 
; check mouse area for putpixel
        call    check_mouse_area_for_putpixel
        pop     ecx
; store to real LFB
        mov     [LFB_BASE+edx], eax
;--------------------------------------
align 4
.skip:
        add     edx, 4
        inc     ebp
        dec     ecx
        jnz     .new_x
 
        add     esi, [putimg.line_increment]
        add     edx, [putimg.screen_newline];[BytesPerScanLine]
        add     ebp, [putimg.winmap_newline];[Screen_Max_X]
 
        cmp     [putimg.ebp], putimage_get1bpp
        jz      .correct
        cmp     [putimg.ebp], putimage_get2bpp
        jz      .correct
        cmp     [putimg.ebp], putimage_get4bpp
        jnz     @f
;--------------------------------------
align 4
.correct:
        mov     eax, [putimg.edi]
        mov     byte [eax], 80h
;--------------------------------------
align 4
@@:
        dec     edi
        jnz     .new_line
        jmp     put_image_end_32.finish
;------------------------------------------------------------------------------
align 4
put_image_end_32_new:
;--------------------------------------
align 4
.new_line:
        mov     ecx, [putimg.real_sx]
;--------------------------------------
align 4
.new_x:
        push    [putimg.edi]
        mov     eax, [putimg.ebp+4]
        call    eax
        cmp     [ebp], bl
        jne     .skip
;--------------------------------------
        push    ecx
;--------------------------------------
align 4
.sh:
        neg     ecx
        add     ecx, [putimg.real_sx_and_abs_cx + 4]
;--------------------------------------
; check for X
        cmp     cx, [X_UNDER_sub_CUR_hot_x_add_curh]
        jae     .no_mouse_area
 
        sub     cx, [X_UNDER_subtraction_CUR_hot_x]
        jb      .no_mouse_area
 
        shl     ecx, 16
 
        add     ecx, [putimg.real_sy_and_abs_cy + 4]
        sub     ecx, edi
;--------------------------------------
; check for Y
        cmp     cx, [Y_UNDER_sub_CUR_hot_y_add_curh]
        jae     .no_mouse_area
 
        sub     cx, [Y_UNDER_subtraction_CUR_hot_y]
        jb      .no_mouse_area
;--------------------------------------
; check mouse area for putpixel
        call    check_mouse_area_for_putpixel_new.1
        cmp     ecx, -1   ;SHIT HAPPENS?
        jne     .no_mouse_area
 
        mov     ecx, [esp]
        jmp     .sh
;--------------------------------------
align 4
.no_mouse_area:
        pop     ecx
; store to real LFB
        mov     [LFB_BASE+edx], eax
;--------------------------------------
align 4
.skip:
        add     edx, 4
        inc     ebp
        dec     ecx
        jnz     .new_x
 
        add     esi, [putimg.line_increment]
        add     edx, [putimg.screen_newline];[BytesPerScanLine]
        add     ebp, [putimg.winmap_newline];[Screen_Max_X]
 
        cmp     [putimg.ebp], putimage_get1bpp
        jz      .correct
        cmp     [putimg.ebp], putimage_get2bpp
        jz      .correct
        cmp     [putimg.ebp], putimage_get4bpp
        jnz     @f
;--------------------------------------
align 4
.correct:
        mov     eax, [putimg.edi]
        mov     byte [eax], 80h
;--------------------------------------
align 4
@@:
        dec     edi
        jnz     .new_line
        jmp     put_image_end_32.finish
;------------------------------------------------------------------------------
align 4
__sys_putpixel:
 
; eax = x coordinate
; ebx = y coordinate
; ecx = ?? RR GG BB    ; 0x01000000 negation
                       ; 0x02000000 used for draw_rectangle without top line
                       ;            for example drawwindow_III and drawwindow_IV
; edi = 0x00000001 force
 
        pushad
        cmp     eax, [_display.width]
        jae     .exit
        cmp     ebx, [_display.height]
        jae     .exit
        test    edi, 1           ; force ?
        jnz     .forced
 
; not forced:
        mov     edx, [d_width_calc_area + ebx*4]
        add     edx, [_WinMapAddress]
        movzx   edx, byte [eax+edx]
        cmp     edx, [CURRENT_TASK]
        jne     .exit
;--------------------------------------
align 4
.forced:
; check if negation
        test    ecx, 0x01000000
        jz      .noneg
 
        call    getpixel
        not     ecx
 
        rol     ecx, 8
        mov     cl, [esp+32-8+3]
        ror     ecx, 8
        mov     [esp+32-8], ecx
;--------------------------------------
align 4
.noneg:
; OK to set pixel
        call    dword [PUTPIXEL]; call the real put_pixel function
;--------------------------------------
align 4
.exit:
        popad
        ret
;-----------------------------------------------------------------------------
align 4
Vesa20_putpixel24:
; eax = x
; ebx = y
        mov     ecx, eax
        shl     ecx, 16
        mov     cx, bx
 
;        imul    ebx, [BytesPerScanLine]  ; ebx = y * y multiplier
        mov     ebx, [BPSLine_calc_area+ebx*4]
        lea     edi, [eax+eax*2]; edi = x*3
        mov     eax, [esp+32-8+4]
;--------------------------------------
; check for hardware cursor
        cmp     [_display.select_cursor], 0
        jne     @f
; check mouse area for putpixel
        test    eax, 0x04000000
        jnz     @f
        call    check_mouse_area_for_putpixel
;--------------------------------------
align 4
@@:
; store to real LFB
        mov     [LFB_BASE+ebx+edi], ax
        shr     eax, 16
        mov     [LFB_BASE+ebx+edi+2], al
        ret
;-----------------------------------------------------------------------------
align 4
Vesa20_putpixel24_new:
; eax = x
; ebx = y
        mov     ecx, eax
        shl     ecx, 16
        mov     cx, bx
 
;        imul    ebx, [BytesPerScanLine]  ; ebx = y * y multiplier
        mov     ebx, [BPSLine_calc_area+ebx*4]
        lea     edi, [eax+eax*2]; edi = x*3
        mov     eax, [esp+32-8+4]
;--------------------------------------
; check for hardware cursor
        cmp     [_display.select_cursor], select_cursor
        jne     @f
; check mouse area for putpixel
        test    eax, 0x04000000
        jnz     @f
;--------------------------------------
; check for Y
        cmp     cx, [Y_UNDER_sub_CUR_hot_y_add_curh]
        jae     @f
 
        sub     cx, [Y_UNDER_subtraction_CUR_hot_y]
        jb      @f
 
        rol     ecx, 16
;--------------------------------------
; check for X
        cmp     cx, [X_UNDER_sub_CUR_hot_x_add_curh]
        jae     @f
 
        sub     cx, [X_UNDER_subtraction_CUR_hot_x]
        jb      @f
 
        ror     ecx, 16
 
        call    check_mouse_area_for_putpixel_new.1
;--------------------------------------
align 4
@@:
; store to real LFB
        mov     [LFB_BASE+ebx+edi], ax
        shr     eax, 16
        mov     [LFB_BASE+ebx+edi+2], al
        ret
;-----------------------------------------------------------------------------
align 4
Vesa20_putpixel32:
; eax = x
; ebx = y
        mov     ecx, eax
        shl     ecx, 16
        mov     cx, bx
 
;        imul    ebx, [BytesPerScanLine]  ; ebx = y * y multiplier
        mov     ebx, [BPSLine_calc_area+ebx*4]
        lea     edi, [ebx+eax*4]; edi = x*4+(y*y multiplier)
        mov     eax, [esp+32-8+4]; eax = color
;--------------------------------------
; check for hardware cursor
        cmp     [_display.select_cursor], 0
        jne     @f
; check mouse area for putpixel
        test    eax, 0x04000000
        jnz     @f
        call    check_mouse_area_for_putpixel
;--------------------------------------
align 4
@@:
        and     eax, 0xffffff
; store to real LFB
        mov     [LFB_BASE+edi], eax
        ret
;-----------------------------------------------------------------------------
align 4
Vesa20_putpixel32_new:
; eax = x
; ebx = y
        mov     ecx, eax
        shl     ecx, 16
        mov     cx, bx
 
;        imul    ebx, [BytesPerScanLine]  ; ebx = y * y multiplier
        mov     ebx, [BPSLine_calc_area+ebx*4]
        lea     edi, [ebx+eax*4]; edi = x*4+(y*y multiplier)
        mov     eax, [esp+32-8+4]; eax = color
;--------------------------------------
; check for hardware cursor
        cmp     [_display.select_cursor], select_cursor
        jne     @f
; check mouse area for putpixel
        test    eax, 0x04000000
        jnz     @f
;--------------------------------------
; check for Y
        cmp     cx, [Y_UNDER_sub_CUR_hot_y_add_curh]
        jae     @f
 
        sub     cx, [Y_UNDER_subtraction_CUR_hot_y]
        jb      @f
 
        rol     ecx, 16
;--------------------------------------
; check for X
        cmp     cx, [X_UNDER_sub_CUR_hot_x_add_curh]
        jae     @f
 
        sub     cx, [X_UNDER_subtraction_CUR_hot_x]
        jb      @f
 
        ror     ecx, 16
 
        call    check_mouse_area_for_putpixel_new.1
;--------------------------------------
align 4
@@:
        and     eax, 0xffffff
; store to real LFB
        mov     [LFB_BASE+edi], eax
        ret
;-----------------------------------------------------------------------------
align 4
calculate_edi:
        mov     edi, [d_width_calc_area + ebx*4]
        add     edi, eax
        ret
;-----------------------------------------------------------------------------
; DRAWLINE
;-----------------------------------------------------------------------------
align 4
__sys_draw_line:
; draw a line
; eax = HIWORD = x1
;       LOWORD = x2
; ebx = HIWORD = y1
;       LOWORD = y2
; ecx = color
; edi = force ?
        pusha
 
dl_x1 equ esp+20
dl_y1 equ esp+16
dl_x2 equ esp+12
dl_y2 equ esp+8
dl_dx equ esp+4
dl_dy equ esp+0
 
        xor     edx, edx   ; clear edx
        xor     esi, esi   ; unpack arguments
        xor     ebp, ebp
        mov     si, ax     ; esi = x2
        mov     bp, bx     ; ebp = y2
        shr     eax, 16    ; eax = x1
        shr     ebx, 16    ; ebx = y1
        push    eax        ; save x1
        push    ebx        ; save y1
        push    esi        ; save x2
        push    ebp        ; save y2
; checking x-axis...
        sub     esi, eax   ; esi = x2-x1
        push    esi        ; save y2-y1
        jl      .x2lx1     ; is x2 less than x1 ?
        jg      .no_vline  ; x1 > x2 ?
        mov     edx, ebp   ; else (if x1=x2)
        call    vline
        push    edx ; necessary to rightly restore stack frame at .exit
        jmp     .exit
;--------------------------------------
align 4
.x2lx1:
        neg     esi         ; get esi absolute value
;--------------------------------------
align 4
.no_vline:
; checking y-axis...
        sub     ebp, ebx    ; ebp = y2-y1
        push    ebp         ; save y2-y1
        jl      .y2ly1      ; is y2 less than y1 ?
        jg      .no_hline   ; y1 > y2 ?
        mov     edx, [dl_x2]; else (if y1=y2)
        call    hline
        jmp     .exit
;--------------------------------------
align 4
.y2ly1:
        neg     ebp         ; get ebp absolute value
;--------------------------------------
align 4
.no_hline:
        cmp     ebp, esi
        jle     .x_rules    ; |y2-y1| < |x2-x1|  ?
        cmp     [dl_y2], ebx; make sure y1 is at the begining
        jge     .no_reverse1
        neg     dword [dl_dx]
        mov     edx, [dl_x2]
        mov     [dl_x2], eax
        mov     [dl_x1], edx
        mov     edx, [dl_y2]
        mov     [dl_y2], ebx
        mov     [dl_y1], edx
;--------------------------------------
align 4
.no_reverse1:
        mov     eax, [dl_dx]
        cdq                 ; extend eax sing to edx
        shl     eax, 16     ; using 16bit fix-point maths
        idiv    ebp         ; eax = ((x2-x1)*65536)/(y2-y1)
;--------------------------------------
; correction for the remainder of the division
        shl     edx, 1
        cmp     ebp, edx
        jb      @f
        inc     eax
;--------------------------------------
align 4
@@:
;--------------------------------------
        mov     edx, ebp    ; edx = counter (number of pixels to draw)
        mov     ebp, 1 *65536; <<16   ; ebp = dy = 1.0
        mov     esi, eax    ; esi = dx
        jmp     .y_rules
;--------------------------------------
align 4
.x_rules:
        cmp     [dl_x2], eax ; make sure x1 is at the begining
        jge     .no_reverse2
        neg     dword [dl_dy]
        mov     edx, [dl_x2]
        mov     [dl_x2], eax
        mov     [dl_x1], edx
        mov     edx, [dl_y2]
        mov     [dl_y2], ebx
        mov     [dl_y1], edx
;--------------------------------------
align 4
.no_reverse2:
        xor     edx, edx
        mov     eax, [dl_dy]
        cdq                 ; extend eax sing to edx
        shl     eax, 16     ; using 16bit fix-point maths
        idiv    esi         ; eax = ((y2-y1)*65536)/(x2-x1)
;--------------------------------------
; correction for the remainder of the division
        shl     edx, 1
        cmp     esi, edx
        jb      @f
        inc     eax
;--------------------------------------
align 4
@@:
;--------------------------------------
        mov     edx, esi    ; edx = counter (number of pixels to draw)
        mov     esi, 1 *65536;<< 16   ; esi = dx = 1.0
        mov     ebp, eax    ; ebp = dy
;--------------------------------------
align 4
.y_rules:
        mov     eax, [dl_x1]
        mov     ebx, [dl_y1]
        shl     eax, 16
        shl     ebx, 16
 
        and     ecx, 0xFBFFFFFF ;negate 0x04000000 save to mouseunder area
;-----------------------------------------------------------------------------
align 4
.draw:
        push    eax ebx
;--------------------------------------
; correction for the remainder of the division
        test    ah, 0x80
        jz      @f
        add     eax, 1 shl 16
;--------------------------------------
align 4
@@:
;--------------------------------------
        shr     eax, 16
;--------------------------------------
; correction for the remainder of the division
        test    bh, 0x80
        jz      @f
        add     ebx, 1 shl 16
;--------------------------------------
align 4
@@:
;--------------------------------------
        shr     ebx, 16
;        and     ecx, 0xFBFFFFFF  ;negate 0x04000000 save to mouseunder area
;        call    [putpixel]
        call    __sys_putpixel
        pop     ebx eax
        add     ebx, ebp     ; y = y+dy
        add     eax, esi     ; x = x+dx
        dec     edx
        jnz     .draw
; force last drawn pixel to be at (x2,y2)
        mov     eax, [dl_x2]
        mov     ebx, [dl_y2]
;        and     ecx, 0xFBFFFFFF ;negate 0x04000000 save to mouseunder area
;        call    [putpixel]
        call    __sys_putpixel
;--------------------------------------
align 4
.exit:
        add     esp, 6*4
        popa
;        call    [draw_pointer]
        ret
;------------------------------------------------------------------------------
align 4
hline:
; draw an horizontal line
; eax = x1
; edx = x2
; ebx = y
; ecx = color
; edi = force ?
        push    eax edx
        cmp     edx, eax   ; make sure x2 is above x1
        jge     @f
        xchg    eax, edx
;--------------------------------------
align 4
@@:
        and     ecx, 0xFBFFFFFF  ;negate 0x04000000 save to mouseunder area
;--------------------------------------
align 4
@@:
;        call    [putpixel]
        call    __sys_putpixel
        inc     eax
        cmp     eax, edx
        jle     @b
        pop     edx eax
        ret
;------------------------------------------------------------------------------
align 4
vline:
; draw a vertical line
; eax = x
; ebx = y1
; edx = y2
; ecx = color
; edi = force ?
        push    ebx edx
        cmp     edx, ebx   ; make sure y2 is above y1
        jge     @f
        xchg    ebx, edx
;--------------------------------------
align 4
@@:
        and     ecx, 0xFBFFFFFF ;negate 0x04000000 save to mouseunder area
;--------------------------------------
align 4
@@:
;        call    [putpixel]
        call    __sys_putpixel
        inc     ebx
        cmp     ebx, edx
        jle     @b
        pop     edx ebx
        ret
;------------------------------------------------------------------------------
align 4
virtual at esp
drbar:
     .bar_sx       dd ?
     .bar_sy       dd ?
     .bar_cx       dd ?
     .bar_cy       dd ?
     .abs_cx       dd ?
     .abs_cy       dd ?
     .real_sx      dd ?
     .real_sy      dd ?
     .color        dd ?
     .line_inc_scr dd ?
     .line_inc_map dd ?
     .real_sx_and_abs_cx dd ?
     .real_sy_and_abs_cy dd ?
     .stack_data = 4*13
end virtual
;--------------------------------------
align 4
; eax   cx
; ebx   cy
; ecx   xe
; edx   ye
; edi   color
vesa20_drawbar:
        pushad
        sub     esp, drbar.stack_data
        mov     [drbar.color], edi
        sub     edx, ebx
        jle     .exit       ;// mike.dld, 2005-01-29
        sub     ecx, eax
        jle     .exit       ;// mike.dld, 2005-01-29
        mov     [drbar.bar_sy], edx
        mov     [drbar.bar_sx], ecx
        mov     [drbar.bar_cx], eax
        mov     [drbar.bar_cy], ebx
        mov     edi, [TASK_BASE]
        add     eax, [edi-twdw + WDATA.box.left]; win_cx
        add     ebx, [edi-twdw + WDATA.box.top]; win_cy
        mov     [drbar.abs_cx], eax
        mov     [drbar.abs_cy], ebx
; real_sx = MIN(wnd_sx-bar_cx, bar_sx);
        mov     ebx, [edi-twdw + WDATA.box.width]; ebx = wnd_sx
; \begin{diamond}[20.08.2006]
; note that WDATA.box.width is one pixel less than real window x-size
        inc     ebx
; \end{diamond}[20.08.2006]
        sub     ebx, [drbar.bar_cx]
        ja      @f
;--------------------------------------
align 4
.exit:                       ;// mike.dld, 2005-01-29
        add     esp, drbar.stack_data
        popad
        xor     eax, eax
        inc     eax
        ret
;--------------------------------------
align 4
@@:
        cmp     ebx, [drbar.bar_sx]
        jbe     .end_x
        mov     ebx, [drbar.bar_sx]
;--------------------------------------
align 4
.end_x:
        mov     [drbar.real_sx], ebx
; real_sy = MIN(wnd_sy-bar_cy, bar_sy);
        mov     ebx, [edi-twdw + WDATA.box.height]; ebx = wnd_sy
; \begin{diamond}[20.08.2006]
        inc     ebx
; \end{diamond}
        sub     ebx, [drbar.bar_cy]
        ja      @f
        add     esp, drbar.stack_data
        popad
        xor     eax, eax
        inc     eax
        ret
;--------------------------------------
align 4
@@:
        cmp     ebx, [drbar.bar_sy]
        jbe     .end_y
        mov     ebx, [drbar.bar_sy]
;--------------------------------------
align 4
.end_y:
        mov     [drbar.real_sy], ebx
; line_inc_map
        mov     eax, [_display.width]
        sub     eax, [drbar.real_sx]
 
        mov     [drbar.line_inc_map], eax
; line_inc_scr
        mov     eax, [drbar.real_sx]
        mov     ebx, [_display.bpp]
        shr     ebx, 3
        imul    eax, ebx
        neg     eax
        add     eax, [_display.pitch]
        mov     [drbar.line_inc_scr], eax
; pointer to screen
        mov     edx, [drbar.abs_cy]
;        imul    edx, [BytesPerScanLine]
        mov     edx, [BPSLine_calc_area+edx*4]
        mov     eax, [drbar.abs_cx]
        imul    eax, ebx
        add     edx, eax
; pointer to pixel map
        mov     eax, [drbar.abs_cy]
;        imul    eax, [Screen_Max_X]
;        add     eax, [drbar.abs_cy]
        mov     eax, [d_width_calc_area + eax*4]
 
        add     eax, [drbar.abs_cx]
        add     eax, [_WinMapAddress]
        xchg    eax, ebp
;--------------------------------------
        mov     ebx, [drbar.real_sx]
        add     ebx, [drbar.abs_cx]
        mov     [drbar.real_sx_and_abs_cx], ebx
        mov     ebx, [drbar.real_sy]
        add     ebx, [drbar.abs_cy]
        mov     [drbar.real_sy_and_abs_cy], ebx
 
        add     edx, LFB_BASE
;--------------------------------------
; get process number
        mov     ebx, [CURRENT_TASK]  ; bl - process num
        mov     esi, [drbar.real_sy]
        mov     eax, [drbar.color] ; BBGGRR00
        rol     eax, 8
        mov     bh, al  ; 0x80 drawing gradient bars
        ror     eax, 8
        cmp     byte [_display.bpp], 24
        jne     draw_bar_end_32
;--------------------------------------
align 4
draw_bar_end_24:
; eax - color high   RRGGBB
; bl - process num
; ecx - temp
; edx - pointer to screen
; esi - counter
; edi - counter
;--------------------------------------
; check for hardware cursor
        mov     ecx, [_display.select_cursor]
        cmp     ecx, select_cursor
        je      draw_bar_end_24_new
        cmp     ecx, 0
        je      draw_bar_end_24_old
;--------------------------------------
align 4
.new_y:
        mov     edi, [drbar.real_sx]
;--------------------------------------
align 4
.new_x:
        cmp     byte [ebp], bl
        jne     .skip
;--------------------------------------
; store to real LFB
        mov     [edx], ax
        shr     eax, 16
        mov     [edx + 2], al
;--------------------------------------
align 4
.skip:
; add pixel
        add     edx, 3
        inc     ebp
        dec     edi
        jnz     .new_x
; add line
        add     edx, [drbar.line_inc_scr]
        add     ebp, [drbar.line_inc_map]
; drawing gradient bars
        test    bh, 0x80
        jz      @f
        test    al, al
        jz      @f
        dec     al
;--------------------------------------
align 4
@@:
        dec     esi
        jnz     .new_y
;--------------------------------------
align 4
.end:
        add     esp, drbar.stack_data
        popad
        xor     eax, eax
        ret
;------------------------------------------------------------------------------
align 4
draw_bar_end_24_old:
;--------------------------------------
align 4
.new_y:
        mov     edi, [drbar.real_sx]
;--------------------------------------
align 4
.new_x:
        cmp     byte [ebp], bl
        jne     .skip
;--------------------------------------
        mov     ecx, [drbar.real_sx_and_abs_cx]
        sub     ecx, edi
        shl     ecx, 16
        add     ecx, [drbar.real_sy_and_abs_cy]
        sub     ecx, esi
; check mouse area for putpixel
        call    check_mouse_area_for_putpixel
; store to real LFB
        mov     [edx], ax
        shr     eax, 16
        mov     [edx + 2], al
        mov     eax, [drbar.color]
;--------------------------------------
align 4
.skip:
; add pixel
        add     edx, 3
        inc     ebp
        dec     edi
        jnz     .new_x
; add line
        add     edx, [drbar.line_inc_scr]
        add     ebp, [drbar.line_inc_map]
; drawing gradient bars
        test    bh, 0x80
        jz      @f
        test    al, al
        jz      @f
        dec     al
;--------------------------------------
align 4
@@:
        dec     esi
        jnz     .new_y
        jmp     draw_bar_end_24.end
;------------------------------------------------------------------------------
align 4
draw_bar_end_24_new:
;--------------------------------------
align 4
.new_y:
        mov     edi, [drbar.real_sx]
;--------------------------------------
align 4
.new_x:
        cmp     byte [ebp], bl
        jne     .skip
;--------------------------------------
        mov     ecx, [drbar.real_sy_and_abs_cy]
        sub     ecx, esi
;--------------------------------------
; check for Y
        cmp     cx, [Y_UNDER_sub_CUR_hot_y_add_curh]
        jae     .no_mouse_area
 
        sub     cx, [Y_UNDER_subtraction_CUR_hot_y]
        jb      .no_mouse_area
 
        rol     ecx, 16
        add     ecx, [drbar.real_sx_and_abs_cx]
        sub     ecx, edi
;--------------------------------------
; check for X
        cmp     cx, [X_UNDER_sub_CUR_hot_x_add_curh]
        jae     .no_mouse_area
 
        sub     cx, [X_UNDER_subtraction_CUR_hot_x]
        jb      .no_mouse_area
 
        ror     ecx, 16
;--------------------------------------
; check mouse area for putpixel
        push    eax
        call    check_mouse_area_for_putpixel_new.1
        mov     [edx], ax
        shr     eax, 16
        mov     [edx + 2], al
        pop     eax
        jmp     .skip
; store to real LFB
;--------------------------------------
align 4
.no_mouse_area:
        mov     [edx], ax
        ror     eax, 16
        mov     [edx + 2], al
        rol     eax, 16
;--------------------------------------
align 4
.skip:
; add pixel
        add     edx, 3
        inc     ebp
        dec     edi
        jnz     .new_x
; add line
        add     edx, [drbar.line_inc_scr]
        add     ebp, [drbar.line_inc_map]
; drawing gradient bars
        test    bh, 0x80
        jz      @f
        test    al, al
        jz      @f
        dec     al
;--------------------------------------
align 4
@@:
        dec     esi
        jnz     .new_y
        jmp     draw_bar_end_24.end
;------------------------------------------------------------------------------
align 4
draw_bar_end_32:
; eax - color high   RRGGBB
; bl - process num
; ecx - temp
; edx - pointer to screen
; esi - counter
; edi - counter
;--------------------------------------
; check for hardware cursor
        mov     ecx, [_display.select_cursor]
        cmp     ecx, select_cursor
        je      draw_bar_end_32_new
        cmp     ecx, 0
        je      draw_bar_end_32_old
;--------------------------------------
align 4
.new_y:
        mov     edi, [drbar.real_sx]
;--------------------------------------
align 4
.new_x:
        cmp     byte [ebp], bl
        jne     .skip
;--------------------------------------
; store to real LFB
        mov     [edx], eax
        mov     eax, [drbar.color]
;--------------------------------------
align 4
.skip:
; add pixel
        add     edx, 4
        inc     ebp
        dec     edi
        jnz     .new_x
; add line
        add     edx, [drbar.line_inc_scr]
        add     ebp, [drbar.line_inc_map]
; drawing gradient bars
        test    bh, 0x80
        jz      @f
        test    al, al
        jz      @f
        dec     al
;--------------------------------------
align 4
@@:
        dec     esi
        jnz     .new_y
;--------------------------------------
align 4
.end:
        add     esp, drbar.stack_data
        popad
        cmp     [SCR_MODE], 0x12
        jne     @f
        call    VGA_draw_bar
;--------------------------------------
align 4
@@:
        xor     eax, eax
        mov     [EGA_counter], 1
        ret
;------------------------------------------------------------------------------
align 4
draw_bar_end_32_old:
;--------------------------------------
align 4
.new_y:
        mov     edi, [drbar.real_sx]
;--------------------------------------
align 4
.new_x:
        cmp     byte [ebp], bl
        jne     .skip
;--------------------------------------
        mov     ecx, [drbar.real_sx_and_abs_cx]
        sub     ecx, edi
        shl     ecx, 16
        add     ecx, [drbar.real_sy_and_abs_cy]
        sub     ecx, esi
 
; check mouse area for putpixel
        call    check_mouse_area_for_putpixel
; store to real LFB
        mov     [edx], eax
        mov     eax, [drbar.color]
;--------------------------------------
align 4
.skip:
; add pixel
        add     edx, 4
        inc     ebp
        dec     edi
        jnz     .new_x
; add line
        add     edx, [drbar.line_inc_scr]
        add     ebp, [drbar.line_inc_map]
; drawing gradient bars
        test    bh, 0x80
        jz      @f
        test    al, al
        jz      @f
        dec     al
;--------------------------------------
align 4
@@:
        dec     esi
        jnz     .new_y
        jmp     draw_bar_end_32.end
;------------------------------------------------------------------------------
align 4
draw_bar_end_32_new:
;--------------------------------------
align 4
.new_y:
        mov     edi, [drbar.real_sx]
;--------------------------------------
align 4
.new_x:
        cmp     byte [ebp], bl
        jne     .skip
;--------------------------------------
        mov     ecx, [drbar.real_sy_and_abs_cy]
        sub     ecx, esi
;--------------------------------------
; check for Y
        cmp     cx, [Y_UNDER_sub_CUR_hot_y_add_curh]
        jae     .no_mouse_area
 
        sub     cx, [Y_UNDER_subtraction_CUR_hot_y]
        jb      .no_mouse_area
 
        rol     ecx, 16
        add     ecx, [drbar.real_sx_and_abs_cx]
        sub     ecx, edi
;--------------------------------------
; check for X
        cmp     cx, [X_UNDER_sub_CUR_hot_x_add_curh]
        jae     .no_mouse_area
 
        sub     cx, [X_UNDER_subtraction_CUR_hot_x]
        jb      .no_mouse_area
 
        ror     ecx, 16
;--------------------------------------
; check mouse area for putpixel
        push    eax
        call    check_mouse_area_for_putpixel_new.1
        mov     [edx], eax
        pop     eax
        jmp     .skip
; store to real LFB
;--------------------------------------
align 4
.no_mouse_area:
        mov     [edx], eax
;--------------------------------------
align 4
.skip:
; add pixel
        add     edx, 4
        inc     ebp
        dec     edi
        jnz     .new_x
; add line
        add     edx, [drbar.line_inc_scr]
        add     ebp, [drbar.line_inc_map]
; drawing gradient bars
        test    bh, 0x80
        jz      @f
        test    al, al
        jz      @f
        dec     al
;--------------------------------------
align 4
@@:
        dec     esi
        jnz     .new_y
        jmp     draw_bar_end_32.end
;------------------------------------------------------------------------------
align 4
vesa20_drawbackground_tiled:
        pushad
; External loop for all y from start to end
        mov     ebx, [draw_data+32+RECT.top]    ; y start
;--------------------------------------
align 4
dp2:
        mov     ebp, [draw_data+32+RECT.left]   ; x start
; 1) Calculate pointers in WinMapAddress (does pixel belong to OS thread?) [ebp]
;                       and LFB data (output for our function) [edi]
;        mov     eax, [BytesPerScanLine]
;        mul     ebx
        mov     eax, [BPSLine_calc_area+ebx*4]
        xchg    ebp, eax
        add     ebp, eax
        add     ebp, eax
        add     ebp, eax
        cmp     byte [_display.bpp], 24    ; 24 or 32 bpp ? - x size
        jz      @f
        add     ebp, eax
;--------------------------------------
align 4
@@:
        add     ebp, LFB_BASE
; ebp:=Y*BytesPerScanLine+X*BytesPerPixel+AddrLFB
        call    calculate_edi
        xchg    edi, ebp
        add     ebp, [_WinMapAddress]
; Now eax=x, ebx=y, edi->output, ebp=offset in WinMapAddress
; 2) Calculate offset in background memory block
        push    eax
        xor     edx, edx
        mov     eax, ebx
        div     dword [BgrDataHeight]   ; edx := y mod BgrDataHeight
        pop     eax
        push    eax
        mov     ecx, [BgrDataWidth]
        mov     esi, edx
        imul    esi, ecx                ; esi := (y mod BgrDataHeight) * BgrDataWidth
        xor     edx, edx
        div     ecx             ; edx := x mod BgrDataWidth
        sub     ecx, edx
        add     esi, edx        ; esi := (y mod BgrDataHeight)*BgrDataWidth + (x mod BgrDataWidth)
        pop     eax
        lea     esi, [esi*3]
        add     esi, [img_background]
        xor     edx, edx
        inc     edx
; 3) Loop through redraw rectangle and copy background data
; Registers meaning:
; eax = x, ebx = y (screen coordinates)
; ecx = deltax - number of pixels left in current tile block
; edx = 1
; esi -> bgr memory, edi -> output
; ebp = offset in WinMapAddress
;--------------------------------------
align 4
dp3:
        cmp     [ebp], dl
        jnz     nbgp
;--------------------------------------
        push    eax ecx
 
        mov     ecx, eax
        shl     ecx, 16
        add     ecx, ebx
 
        mov     eax, [esi]
 
; check for hardware cursor
        cmp     [_display.select_cursor], select_cursor
        je      @f
        cmp     [_display.select_cursor], 0
        jne     .no_mouseunder
;--------------------------------------
align 4
@@:
        and     eax, 0xffffff
; check mouse area for putpixel
        call    [_display.check_mouse]
;--------------------------------------
align 4
.no_mouseunder:
; store to real LFB
        mov     [edi], ax
        shr     eax, 16
        mov     [edi+2], al
 
        pop     ecx eax
;--------------------------------------
align 4
nbgp:
        add     esi, 3
        add     edi, 3
;--------------------------------------
align 4
@@:
        cmp     byte [_display.bpp], 25    ; 24 or 32 bpp?
        sbb     edi, -1         ; +1 for 32 bpp
; I do not use 'inc eax' because this is slightly slower then 'add eax,1'
        add     ebp, edx
        add     eax, edx
        cmp     eax, [draw_data+32+RECT.right]
        ja      dp4
        sub     ecx, edx
        jnz     dp3
; next tile block on x-axis
        mov     ecx, [BgrDataWidth]
        sub     esi, ecx
        sub     esi, ecx
        sub     esi, ecx
        jmp     dp3
;--------------------------------------
align 4
dp4:
; next scan line
        inc     ebx
        cmp     ebx, [draw_data+32+RECT.bottom]
        jbe     dp2
        popad
        mov     [EGA_counter], 1
        cmp     [SCR_MODE], 0x12
        jne     @f
        call    VGA_drawbackground
;--------------------------------------
align 4
@@:
        ret
;------------------------------------------------------------------------------
align 4
vesa20_drawbackground_stretch:
        pushad
; Helper variables
; calculate 2^32*(BgrDataWidth-1) mod (ScreenWidth-1)
        mov     eax, [BgrDataWidth]
        dec     eax
        xor     edx, edx
        div     dword [Screen_Max_X]
        push    eax     ; high
        xor     eax, eax
        div     dword [Screen_Max_X]
        push    eax     ; low
; the same for height
        mov     eax, [BgrDataHeight]
        dec     eax
        xor     edx, edx
        div     dword [Screen_Max_Y]
        push    eax     ; high
        xor     eax, eax
        div     dword [Screen_Max_Y]
        push    eax     ; low
; External loop for all y from start to end
        mov     ebx, [draw_data+32+RECT.top]    ; y start
        mov     ebp, [draw_data+32+RECT.left]   ; x start
; 1) Calculate pointers in WinMapAddress (does pixel belong to OS thread?) [ebp]
;                       and LFB data (output for our function) [edi]
;        mov     eax, [BytesPerScanLine]
;        mul     ebx
        mov     eax, [BPSLine_calc_area+ebx*4]
        xchg    ebp, eax
        add     ebp, eax
        add     ebp, eax
        add     ebp, eax
        cmp     byte [_display.bpp], 24    ; 24 or 32 bpp ? - x size
        jz      @f
        add     ebp, eax
;--------------------------------------
align 4
@@:
; ebp:=Y*BytesPerScanLine+X*BytesPerPixel+AddrLFB
        call    calculate_edi
        xchg    edi, ebp
; Now eax=x, ebx=y, edi->output, ebp=offset in WinMapAddress
        push    ebx
        push    eax
; 2) Calculate offset in background memory block
        mov     eax, ebx
        imul    ebx, dword [esp+12]
        mul     dword [esp+8]
        add     edx, ebx        ; edx:eax = y * 2^32*(BgrDataHeight-1)/(ScreenHeight-1)
        mov     esi, edx
        imul    esi, [BgrDataWidth]
        push    edx
        push    eax
        mov     eax, [esp+8]
        mul     dword [esp+28]
        push    eax
        mov     eax, [esp+12]
        mul     dword [esp+28]
        add     [esp], edx
        pop     edx             ; edx:eax = x * 2^32*(BgrDataWidth-1)/(ScreenWidth-1)
        add     esi, edx
        lea     esi, [esi*3]
        add     esi, [img_background]
        push    eax
        push    edx
        push    esi
; 3) Smooth horizontal
;--------------------------------------
align 4
bgr_resmooth0:
        mov     ecx, [esp+8]
        mov     edx, [esp+4]
        mov     esi, [esp]
        push    edi
        mov     edi, bgr_cur_line
        call    smooth_line
;--------------------------------------
align 4
bgr_resmooth1:
        mov     eax, [esp+16+4]
        inc     eax
        cmp     eax, [BgrDataHeight]
        jae     bgr.no2nd
        mov     ecx, [esp+8+4]
        mov     edx, [esp+4+4]
        mov     esi, [esp+4]
        add     esi, [BgrDataWidth]
        add     esi, [BgrDataWidth]
        add     esi, [BgrDataWidth]
        mov     edi, bgr_next_line
        call    smooth_line
;--------------------------------------
align 4
bgr.no2nd:
        pop     edi
;--------------------------------------
align 4
sdp3:
        xor     esi, esi
        mov     ecx, [esp+12]
; 4) Loop through redraw rectangle and copy background data
; Registers meaning:
; esi = offset in current line, edi -> output
; ebp = offset in WinMapAddress
; dword [esp] = offset in bgr data
; qword [esp+4] = x * 2^32 * (BgrDataWidth-1) / (ScreenWidth-1)
; qword [esp+12] = y * 2^32 * (BgrDataHeight-1) / (ScreenHeight-1)
; dword [esp+20] = x
; dword [esp+24] = y
; precalculated constants:
; qword [esp+28] = 2^32*(BgrDataHeight-1)/(ScreenHeight-1)
; qword [esp+36] = 2^32*(BgrDataWidth-1)/(ScreenWidth-1)
;--------------------------------------
align 4
sdp3a:
        mov     eax, [_WinMapAddress]
        cmp     [ebp+eax], byte 1
        jnz     snbgp
        mov     eax, [bgr_cur_line+esi]
        test    ecx, ecx
        jz      .novert
        mov     ebx, [bgr_next_line+esi]
        call    [overlapping_of_points_ptr]
;--------------------------------------
align 4
.novert:
        push    ecx
; check for hardware cursor
        cmp     [_display.select_cursor], select_cursor
        je      @f
        cmp     [_display.select_cursor], 0
        jne     .no_mouseunder
;--------------------------------------
align 4
@@:
        mov     ecx, [esp+20+4]        ;x
        shl     ecx, 16
        add     ecx, [esp+24+4]        ;y
; check mouse area for putpixel
        call    [_display.check_mouse]
;--------------------------------------
align 4
.no_mouseunder:
; store to real LFB
        mov     [LFB_BASE+edi], ax
        shr     eax, 16
        mov     [LFB_BASE+edi+2], al
        pop     ecx
;--------------------------------------
align 4
snbgp:
        cmp     byte [_display.bpp], 25
        sbb     edi, -4
        add     ebp, 1
        mov     eax, [esp+20]
        add     eax, 1
        mov     [esp+20], eax
        add     esi, 4
        cmp     eax, [draw_data+32+RECT.right]
        jbe     sdp3a
;--------------------------------------
align 4
sdp4:
; next y
        mov     ebx, [esp+24]
        add     ebx, 1
        mov     [esp+24], ebx
        cmp     ebx, [draw_data+32+RECT.bottom]
        ja      sdpdone
; advance edi, ebp to next scan line
        sub     eax, [draw_data+32+RECT.left]
        sub     ebp, eax
        add     ebp, [_display.width]
 
        sub     edi, eax
        sub     edi, eax
        sub     edi, eax
        cmp     byte [_display.bpp], 24
        jz      @f
        sub     edi, eax
;--------------------------------------
align 4
@@:
        add     edi, [_display.pitch]
; restore ecx,edx; advance esi to next background line
        mov     eax, [esp+28]
        mov     ebx, [esp+32]
        add     [esp+12], eax
        mov     eax, [esp+16]
        adc     [esp+16], ebx
        sub     eax, [esp+16]
        mov     ebx, eax
        lea     eax, [eax*3]
        imul    eax, [BgrDataWidth]
        sub     [esp], eax
        mov     eax, [draw_data+32+RECT.left]
        mov     [esp+20], eax
        test    ebx, ebx
        jz      sdp3
        cmp     ebx, -1
        jnz     bgr_resmooth0
        push    edi
        mov     esi, bgr_next_line
        mov     edi, bgr_cur_line
        mov     ecx, [_display.width]
 
        rep movsd
        jmp     bgr_resmooth1
;--------------------------------------
align 4
sdpdone:
        add     esp, 44
        popad
        mov     [EGA_counter], 1
        cmp     [SCR_MODE], 0x12
        jne     @f
        call    VGA_drawbackground
;--------------------------------------
align 4
@@:
        ret
 
uglobal
;--------------------------------------
align 4
bgr_cur_line    rd      1920    ; maximum width of screen
bgr_next_line   rd      1920
;--------------------------------------
endg
;--------------------------------------
align 4
smooth_line:
        mov     al, [esi+2]
        shl     eax, 16
        mov     ax, [esi]
        test    ecx, ecx
        jz      @f
        mov     ebx, [esi+2]
        shr     ebx, 8
        call    [overlapping_of_points_ptr]
;--------------------------------------
align 4
@@:
        stosd
        mov     eax, [esp+20+8]
        add     eax, 1
        mov     [esp+20+8], eax
        cmp     eax, [draw_data+32+RECT.right]
        ja      @f
        add     ecx, [esp+36+8]
        mov     eax, edx
        adc     edx, [esp+40+8]
        sub     eax, edx
        lea     eax, [eax*3]
        sub     esi, eax
        jmp     smooth_line
;--------------------------------------
align 4
@@:
        mov     eax, [draw_data+32+RECT.left]
        mov     [esp+20+8], eax
        ret
;------------------------------------------------------------------------------
align 16
overlapping_of_points:
if 0
; this version of procedure works, but is slower than next version
        push    ecx edx
        mov     edx, eax
        push    esi
        shr     ecx, 24
        mov     esi, ecx
        mov     ecx, ebx
        movzx   ebx, dl
        movzx   eax, cl
        sub     eax, ebx
        movzx   ebx, dh
        imul    eax, esi
        add     dl, ah
        movzx   eax, ch
        sub     eax, ebx
        imul    eax, esi
        add     dh, ah
        ror     ecx, 16
        ror     edx, 16
        movzx   eax, cl
        movzx   ebx, dl
        sub     eax, ebx
        imul    eax, esi
        pop     esi
        add     dl, ah
        mov     eax, edx
        pop     edx
        ror     eax, 16
        pop     ecx
        ret
else
        push    ecx edx
        mov     edx, eax
        push    esi
        shr     ecx, 26
        mov     esi, ecx
        mov     ecx, ebx
        shl     esi, 9
        movzx   ebx, dl
        movzx   eax, cl
        sub     eax, ebx
        movzx   ebx, dh
        add     dl, [BgrAuxTable+(eax+0x100)+esi]
        movzx   eax, ch
        sub     eax, ebx
        add     dh, [BgrAuxTable+(eax+0x100)+esi]
        ror     ecx, 16
        ror     edx, 16
        movzx   eax, cl
        movzx   ebx, dl
        sub     eax, ebx
        add     dl, [BgrAuxTable+(eax+0x100)+esi]
        pop     esi
        mov     eax, edx
        pop     edx
        ror     eax, 16
        pop     ecx
        ret
end if
 
iglobal
;--------------------------------------
align 4
overlapping_of_points_ptr       dd      overlapping_of_points
;--------------------------------------
endg
;------------------------------------------------------------------------------
align 4
init_background:
        mov     edi, BgrAuxTable
        xor     edx, edx
;--------------------------------------
align 4
.loop2:
        mov     eax, edx
        shl     eax, 8
        neg     eax
        mov     ecx, 0x200
;--------------------------------------
align 4
.loop1:
        mov     byte [edi], ah
        inc     edi
        add     eax, edx
        loop    .loop1
        add     dl, 4
        jnz     .loop2
        test    byte [cpu_caps+(CAPS_MMX/8)], 1 shl (CAPS_MMX mod 8)
        jz      @f
        mov     [overlapping_of_points_ptr], overlapping_of_points_mmx
;--------------------------------------
align 4
@@:
        ret
;------------------------------------------------------------------------------
align 16
overlapping_of_points_mmx:
        movd    mm0, eax
        movd    mm4, eax
        movd    mm1, ebx
        pxor    mm2, mm2
        punpcklbw mm0, mm2
        punpcklbw mm1, mm2
        psubw   mm1, mm0
        movd    mm3, ecx
        psrld   mm3, 24
        packuswb mm3, mm3
        packuswb mm3, mm3
        pmullw  mm1, mm3
        psrlw   mm1, 8
        packuswb mm1, mm2
        paddb   mm4, mm1
        movd    eax, mm4
        ret
;------------------------------------------------------------------------------

Rev 4587	Rev 4923
1	;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;	1	;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2	;; ;;	2	;; ;;
3	;; Copyright (C) KolibriOS team 2004-2012. All rights reserved. ;;	3	;; Copyright (C) KolibriOS team 2004-2012. All rights reserved. ;;
4	;; Distributed under terms of the GNU General Public License ;;	4	;; Distributed under terms of the GNU General Public License ;;
5	;; ;;	5	;; ;;
6	;; VESA20.INC ;;	6	;; VESA20.INC ;;
7	;; ;;	7	;; ;;
8	;; Vesa 2.0 functions for MenuetOS ;;	8	;; Vesa 2.0 functions for MenuetOS ;;
9	;; ;;	9	;; ;;
10	;; Copyright 2002 Ville Turjanmaa ;;	10	;; Copyright 2002 Ville Turjanmaa ;;
11	;; Alexey, kgaz@crosswindws.net ;;	11	;; Alexey, kgaz@crosswindws.net ;;
12	;; - Voodoo compatible graphics ;;	12	;; - Voodoo compatible graphics ;;
13	;; Juan M. Caravaca ;;	13	;; Juan M. Caravaca ;;
14	;; - Graphics optimimizations eg. drawline ;;	14	;; - Graphics optimimizations eg. drawline ;;
15	;; ;;	15	;; ;;
16	;; See file COPYING for details ;;	16	;; See file COPYING for details ;;
17	;; ;;	17	;; ;;
18	;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;	18	;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
19		19
20	$Revision: 3606 $	20	$Revision: 3606 $
21		21
22		22
23	; If you're planning to write your own video driver I suggest	23	; If you're planning to write your own video driver I suggest
24	; you replace the VESA12.INC file and see those instructions.	24	; you replace the VESA12.INC file and see those instructions.
25		25
26		26
27	;-----------------------------------------------------------------------------	27	;-----------------------------------------------------------------------------
28	; getpixel	28	; getpixel
29	;	29	;
30	; in:	30	; in:
31	; eax = x coordinate	31	; eax = x coordinate
32	; ebx = y coordinate	32	; ebx = y coordinate
33	;	33	;
34	; ret:	34	; ret:
35	; ecx = 00 RR GG BB	35	; ecx = 00 RR GG BB
36	;-----------------------------------------------------------------------------	36	;-----------------------------------------------------------------------------
37	align 4	37	align 4
38	getpixel:	38	getpixel:
39	push eax ebx edx edi	39	push eax ebx edx edi
40	call dword [GETPIXEL]	40	call dword [GETPIXEL]
41	pop edi edx ebx eax	41	pop edi edx ebx eax
42	ret	42	ret
43	;-----------------------------------------------------------------------------	43	;-----------------------------------------------------------------------------
44	align 4	44	align 4
45	Vesa20_getpixel24:	45	Vesa20_getpixel24:
46	; eax = x	46	; eax = x
47	; ebx = y	47	; ebx = y
48	;--------------------------------------	48	;--------------------------------------
49	; check for hardware cursor	49	; check for hardware cursor
50	cmp [_display.select_cursor], select_cursor	50	cmp [_display.select_cursor], select_cursor
51	je @f	51	je @f
52	cmp [_display.select_cursor], 0	52	cmp [_display.select_cursor], 0
53	jne .no_mouseunder	53	jne .no_mouseunder
54	;--------------------------------------	54	;--------------------------------------
55	align 4	55	align 4
56	@@:	56	@@:
57	; check mouse area for putpixel	57	; check mouse area for putpixel
58	test ecx, 0x04000000 ; don't load to mouseunder area	58	test ecx, 0x04000000 ; don't load to mouseunder area
59	jnz .no_mouseunder	59	jnz .no_mouseunder
60	call [_display.check_m_pixel]	60	call [_display.check_m_pixel]
61	test ecx, ecx ;0xff000000	61	test ecx, ecx ;0xff000000
62	jnz @f	62	jnz @f
63	;--------------------------------------	63	;--------------------------------------
64	align 4	64	align 4
65	.no_mouseunder:	65	.no_mouseunder:
66	;--------------------------------------	66	;--------------------------------------
67	; imul ebx, [BytesPerScanLine] ; ebx = y * y multiplier	67	; imul ebx, [BytesPerScanLine] ; ebx = y * y multiplier
68	mov ebx, [BPSLine_calc_area+ebx*4]	68	mov ebx, [BPSLine_calc_area+ebx*4]
69	lea edi, [eax+eax2]; edi = x3	69	lea edi, [eax+eax2]; edi = x3
70	add edi, ebx ; edi = x3+(yy multiplier)	70	add edi, ebx ; edi = x3+(yy multiplier)
71	mov ecx, [LFB_BASE+edi]	71	mov ecx, [LFB_BASE+edi]
72	;--------------------------------------	72	;--------------------------------------
73	align 4	73	align 4
74	@@:	74	@@:
75	and ecx, 0xffffff	75	and ecx, 0xffffff
76	ret	76	ret
77	;-----------------------------------------------------------------------------	77	;-----------------------------------------------------------------------------
78	align 4	78	align 4
79	Vesa20_getpixel32:	79	Vesa20_getpixel32:
80	;--------------------------------------	80	;--------------------------------------
81	; check for hardware cursor	81	; check for hardware cursor
82	cmp [_display.select_cursor], select_cursor	82	cmp [_display.select_cursor], select_cursor
83	je @f	83	je @f
84	cmp [_display.select_cursor], 0	84	cmp [_display.select_cursor], 0
85	jne .no_mouseunder	85	jne .no_mouseunder
86	;--------------------------------------	86	;--------------------------------------
87	align 4	87	align 4
88	@@:	88	@@:
89	; check mouse area for putpixel	89	; check mouse area for putpixel
90	test ecx, 0x04000000 ; don't load to mouseunder area	90	test ecx, 0x04000000 ; don't load to mouseunder area
91	jnz .no_mouseunder	91	jnz .no_mouseunder
92	call [_display.check_m_pixel]	92	call [_display.check_m_pixel]
93	test ecx, ecx ;0xff000000	93	test ecx, ecx ;0xff000000
94	jnz @f	94	jnz @f
95	;--------------------------------------	95	;--------------------------------------
96	align 4	96	align 4
97	.no_mouseunder:	97	.no_mouseunder:
98	;--------------------------------------	98	;--------------------------------------
99	; imul ebx, [BytesPerScanLine] ; ebx = y * y multiplier	99	; imul ebx, [BytesPerScanLine] ; ebx = y * y multiplier
100	mov ebx, [BPSLine_calc_area+ebx*4]	100	mov ebx, [BPSLine_calc_area+ebx*4]
101	lea edi, [ebx+eax4]; edi = x4+(y*y multiplier)	101	lea edi, [ebx+eax4]; edi = x4+(y*y multiplier)
102	mov ecx, [LFB_BASE+edi]	102	mov ecx, [LFB_BASE+edi]
103	;--------------------------------------	103	;--------------------------------------
104	align 4	104	align 4
105	@@:	105	@@:
106	and ecx, 0xffffff	106	and ecx, 0xffffff
107	ret	107	ret
108	;-----------------------------------------------------------------------------	108	;-----------------------------------------------------------------------------
109	virtual at esp	109	virtual at esp
110	putimg:	110	putimg:
111	.real_sx dd ?	111	.real_sx dd ?
112	.real_sy dd ?	112	.real_sy dd ?
113	.image_sx dd ?	113	.image_sx dd ?
114	.image_sy dd ?	114	.image_sy dd ?
115	.image_cx dd ?	115	.image_cx dd ?
116	.image_cy dd ?	116	.image_cy dd ?
117	.pti dd ?	117	.pti dd ?
118	.abs_cx dd ?	118	.abs_cx dd ?
119	.abs_cy dd ?	119	.abs_cy dd ?
120	.line_increment dd ?	120	.line_increment dd ?
121	.winmap_newline dd ?	121	.winmap_newline dd ?
122	.screen_newline dd ?	122	.screen_newline dd ?
123	.real_sx_and_abs_cx dd ?	123	.real_sx_and_abs_cx dd ?
124	.real_sy_and_abs_cy dd ?	124	.real_sy_and_abs_cy dd ?
125	.stack_data = 4*14	125	.stack_data = 4*14
126	.edi dd ?	126	.edi dd ?
127	.esi dd ?	127	.esi dd ?
128	.ebp dd ?	128	.ebp dd ?
129	.esp dd ?	129	.esp dd ?
130	.ebx dd ?	130	.ebx dd ?
131	.edx dd ?	131	.edx dd ?
132	.ecx dd ?	132	.ecx dd ?
133	.eax dd ?	133	.eax dd ?
134	.ret_addr dd ?	134	.ret_addr dd ?
135	.arg_0 dd ?	135	.arg_0 dd ?
136	end virtual	136	end virtual
137	;-----------------------------------------------------------------------------	137	;-----------------------------------------------------------------------------
138	align 16	138	align 16
139	; ebx = pointer	139	; ebx = pointer
140	; ecx = size [x\|y]	140	; ecx = size [x\|y]
141	; edx = coordinates [x\|y]	141	; edx = coordinates [x\|y]
142	; ebp = pointer to 'get' function	142	; ebp = pointer to 'get' function
143	; esi = pointer to 'init' function	143	; esi = pointer to 'init' function
144	; edi = parameter for 'get' function	144	; edi = parameter for 'get' function
145	vesa20_putimage:	145	vesa20_putimage:
146	pushad	146	pushad
147	sub esp, putimg.stack_data	147	sub esp, putimg.stack_data
148	; save pointer to image	148	; save pointer to image
149	mov [putimg.pti], ebx	149	mov [putimg.pti], ebx
150	; unpack the size	150	; unpack the size
151	mov eax, ecx	151	mov eax, ecx
152	and ecx, 0xFFFF	152	and ecx, 0xFFFF
153	shr eax, 16	153	shr eax, 16
154	mov [putimg.image_sx], eax	154	mov [putimg.image_sx], eax
155	mov [putimg.image_sy], ecx	155	mov [putimg.image_sy], ecx
156	; unpack the coordinates	156	; unpack the coordinates
157	mov eax, edx	157	mov eax, edx
158	and edx, 0xFFFF	158	and edx, 0xFFFF
159	shr eax, 16	159	shr eax, 16
160	mov [putimg.image_cx], eax	160	mov [putimg.image_cx], eax
161	mov [putimg.image_cy], edx	161	mov [putimg.image_cy], edx
162	; calculate absolute (i.e. screen) coordinates	162	; calculate absolute (i.e. screen) coordinates
163	mov eax, [TASK_BASE]	163	mov eax, [TASK_BASE]
164	mov ebx, [eax-twdw + WDATA.box.left]	164	mov ebx, [eax-twdw + WDATA.box.left]
165	add ebx, [putimg.image_cx]	165	add ebx, [putimg.image_cx]
166	mov [putimg.abs_cx], ebx	166	mov [putimg.abs_cx], ebx
167	mov ebx, [eax-twdw + WDATA.box.top]	167	mov ebx, [eax-twdw + WDATA.box.top]
168	add ebx, [putimg.image_cy]	168	add ebx, [putimg.image_cy]
169	mov [putimg.abs_cy], ebx	169	mov [putimg.abs_cy], ebx
170	; real_sx = MIN(wnd_sx-image_cx, image_sx);	170	; real_sx = MIN(wnd_sx-image_cx, image_sx);
171	mov ebx, [eax-twdw + WDATA.box.width]; ebx = wnd_sx	171	mov ebx, [eax-twdw + WDATA.box.width]; ebx = wnd_sx
172	; \begin{diamond}[20.08.2006]	172	; \begin{diamond}[20.08.2006]
173	; note that WDATA.box.width is one pixel less than real window x-size	173	; note that WDATA.box.width is one pixel less than real window x-size
174	inc ebx	174	inc ebx
175	; \end{diamond}[20.08.2006]	175	; \end{diamond}[20.08.2006]
176	sub ebx, [putimg.image_cx]	176	sub ebx, [putimg.image_cx]
177	ja @f	177	ja @f
178	add esp, putimg.stack_data	178	add esp, putimg.stack_data
179	popad	179	popad
180	ret	180	ret
181	;--------------------------------------	181	;--------------------------------------
182	align 4	182	align 4
183	@@:	183	@@:
184	cmp ebx, [putimg.image_sx]	184	cmp ebx, [putimg.image_sx]
185	jbe .end_x	185	jbe .end_x
186	mov ebx, [putimg.image_sx]	186	mov ebx, [putimg.image_sx]
187	;--------------------------------------	187	;--------------------------------------
188	align 4	188	align 4
189	.end_x:	189	.end_x:
190	mov [putimg.real_sx], ebx	190	mov [putimg.real_sx], ebx
191	; init real_sy	191	; init real_sy
192	mov ebx, [eax-twdw + WDATA.box.height]; ebx = wnd_sy	192	mov ebx, [eax-twdw + WDATA.box.height]; ebx = wnd_sy
193	; \begin{diamond}[20.08.2006]	193	; \begin{diamond}[20.08.2006]
194	inc ebx	194	inc ebx
195	; \end{diamond}[20.08.2006]	195	; \end{diamond}[20.08.2006]
196	sub ebx, [putimg.image_cy]	196	sub ebx, [putimg.image_cy]
197	ja @f	197	ja @f
198	add esp, putimg.stack_data	198	add esp, putimg.stack_data
199	popad	199	popad
200	ret	200	ret
201	;--------------------------------------	201	;--------------------------------------
202	align 4	202	align 4
203	@@:	203	@@:
204	cmp ebx, [putimg.image_sy]	204	cmp ebx, [putimg.image_sy]
205	jbe .end_y	205	jbe .end_y
206	mov ebx, [putimg.image_sy]	206	mov ebx, [putimg.image_sy]
207	;--------------------------------------	207	;--------------------------------------
208	align 4	208	align 4
209	.end_y:	209	.end_y:
210	mov [putimg.real_sy], ebx	210	mov [putimg.real_sy], ebx
211	; line increment	211	; line increment
212	mov eax, [putimg.image_sx]	212	mov eax, [putimg.image_sx]
213	mov ecx, [putimg.real_sx]	213	mov ecx, [putimg.real_sx]
214	sub eax, ecx	214	sub eax, ecx
215	;; imul eax, [putimg.source_bpp]	215	;; imul eax, [putimg.source_bpp]
216	; lea eax, [eax + eax * 2]	216	; lea eax, [eax + eax * 2]
217	call esi	217	call esi
218	add eax, [putimg.arg_0]	218	add eax, [putimg.arg_0]
219	mov [putimg.line_increment], eax	219	mov [putimg.line_increment], eax
220	; winmap new line increment	220	; winmap new line increment
221	mov eax, [Screen_Max_X]	221	mov eax, [_display.width]
222	inc eax	-
223	sub eax, [putimg.real_sx]	222	sub eax, [putimg.real_sx]
224	mov [putimg.winmap_newline], eax	223	mov [putimg.winmap_newline], eax
225	; screen new line increment	224	; screen new line increment
226	mov eax, [_display.pitch]	225	mov eax, [_display.pitch]
227	mov ebx, [_display.bpp]	226	mov ebx, [_display.bpp]
228	shr ebx, 3	227	shr ebx, 3
229	imul ecx, ebx	228	imul ecx, ebx
230	sub eax, ecx	229	sub eax, ecx
231	mov [putimg.screen_newline], eax	230	mov [putimg.screen_newline], eax
232	; pointer to image	231	; pointer to image
233	mov esi, [putimg.pti]	232	mov esi, [putimg.pti]
234	; pointer to screen	233	; pointer to screen
235	mov edx, [putimg.abs_cy]	234	mov edx, [putimg.abs_cy]
236	; imul edx, [BytesPerScanLine]	235	; imul edx, [BytesPerScanLine]
237	mov edx, [BPSLine_calc_area+edx*4]	236	mov edx, [BPSLine_calc_area+edx*4]
238	mov eax, [putimg.abs_cx]	237	mov eax, [putimg.abs_cx]
239	; movzx ebx, byte [ScreenBPP]	238	; movzx ebx, byte [ScreenBPP]
240	; shr ebx, 3	239	; shr ebx, 3
241	imul eax, ebx	240	imul eax, ebx
242	add edx, eax	241	add edx, eax
243	; pointer to pixel map	242	; pointer to pixel map
244	mov eax, [putimg.abs_cy]	243	mov eax, [putimg.abs_cy]
245	mov eax, [d_width_calc_area + eax*4]	244	mov eax, [d_width_calc_area + eax*4]
246		245
247	add eax, [putimg.abs_cx]	246	add eax, [putimg.abs_cx]
248	add eax, [_WinMapAddress]	247	add eax, [_WinMapAddress]
249	xchg eax, ebp	248	xchg eax, ebp
250	;--------------------------------------	249	;--------------------------------------
251	mov ecx, [putimg.real_sx]	250	mov ecx, [putimg.real_sx]
252	add ecx, [putimg.abs_cx]	251	add ecx, [putimg.abs_cx]
253	mov [putimg.real_sx_and_abs_cx], ecx	252	mov [putimg.real_sx_and_abs_cx], ecx
254	mov ecx, [putimg.real_sy]	253	mov ecx, [putimg.real_sy]
255	add ecx, [putimg.abs_cy]	254	add ecx, [putimg.abs_cy]
256	mov [putimg.real_sy_and_abs_cy], ecx	255	mov [putimg.real_sy_and_abs_cy], ecx
257	;--------------------------------------	256	;--------------------------------------
258	; get process number	257	; get process number
259	mov ebx, [CURRENT_TASK]	258	mov ebx, [CURRENT_TASK]
260	cmp byte [_display.bpp], 32	259	cmp byte [_display.bpp], 32
261	je put_image_end_32	260	je put_image_end_32
262	;--------------------------------------	261	;--------------------------------------
263	put_image_end_24:	262	put_image_end_24:
264	mov edi, [putimg.real_sy]	263	mov edi, [putimg.real_sy]
265	;--------------------------------------	264	;--------------------------------------
266	; check for hardware cursor	265	; check for hardware cursor
267	mov ecx, [_display.select_cursor]	266	mov ecx, [_display.select_cursor]
268	cmp ecx, select_cursor	267	cmp ecx, select_cursor
269	je put_image_end_24_new	268	je put_image_end_24_new
270	cmp ecx, 0	269	cmp ecx, 0
271	je put_image_end_24_old	270	je put_image_end_24_old
272	;--------------------------------------	271	;--------------------------------------
273	align 4	272	align 4
274	.new_line:	273	.new_line:
275	mov ecx, [putimg.real_sx]	274	mov ecx, [putimg.real_sx]
276	;--------------------------------------	275	;--------------------------------------
277	align 4	276	align 4
278	.new_x:	277	.new_x:
279	push [putimg.edi]	278	push [putimg.edi]
280	mov eax, [putimg.ebp+4]	279	mov eax, [putimg.ebp+4]
281	call eax	280	call eax
282	cmp [ebp], bl	281	cmp [ebp], bl
283	jne .skip	282	jne .skip
284	;--------------------------------------	283	;--------------------------------------
285	; store to real LFB	284	; store to real LFB
286	mov [LFB_BASE+edx], ax	285	mov [LFB_BASE+edx], ax
287	shr eax, 16	286	shr eax, 16
288	mov [LFB_BASE+edx+2], al	287	mov [LFB_BASE+edx+2], al
289	;--------------------------------------	288	;--------------------------------------
290	align 4	289	align 4
291	.skip:	290	.skip:
292	add edx, 3	291	add edx, 3
293	inc ebp	292	inc ebp
294	dec ecx	293	dec ecx
295	jnz .new_x	294	jnz .new_x
296		295
297	add esi, [putimg.line_increment]	296	add esi, [putimg.line_increment]
298	add edx, [putimg.screen_newline];[BytesPerScanLine]	297	add edx, [putimg.screen_newline];[BytesPerScanLine]
299	add ebp, [putimg.winmap_newline];[Screen_Max_X]	298	add ebp, [putimg.winmap_newline];[Screen_Max_X]
300		299
301	cmp [putimg.ebp], putimage_get1bpp	300	cmp [putimg.ebp], putimage_get1bpp
302	jz .correct	301	jz .correct
303	cmp [putimg.ebp], putimage_get2bpp	302	cmp [putimg.ebp], putimage_get2bpp
304	jz .correct	303	jz .correct
305	cmp [putimg.ebp], putimage_get4bpp	304	cmp [putimg.ebp], putimage_get4bpp
306	jnz @f	305	jnz @f
307	;--------------------------------------	306	;--------------------------------------
308	align 4	307	align 4
309	.correct:	308	.correct:
310	mov eax, [putimg.edi]	309	mov eax, [putimg.edi]
311	mov byte [eax], 80h	310	mov byte [eax], 80h
312	;--------------------------------------	311	;--------------------------------------
313	align 4	312	align 4
314	@@:	313	@@:
315	dec edi	314	dec edi
316	jnz .new_line	315	jnz .new_line
317	;--------------------------------------	316	;--------------------------------------
318	align 4	317	align 4
319	.finish:	318	.finish:
320	add esp, putimg.stack_data	319	add esp, putimg.stack_data
321	popad	320	popad
322	ret	321	ret
323	;------------------------------------------------------------------------------	322	;------------------------------------------------------------------------------
324	align 4	323	align 4
325	put_image_end_24_old:	324	put_image_end_24_old:
326	;--------------------------------------	325	;--------------------------------------
327	align 4	326	align 4
328	.new_line:	327	.new_line:
329	mov ecx, [putimg.real_sx]	328	mov ecx, [putimg.real_sx]
330	;--------------------------------------	329	;--------------------------------------
331	align 4	330	align 4
332	.new_x:	331	.new_x:
333	push [putimg.edi]	332	push [putimg.edi]
334	mov eax, [putimg.ebp+4]	333	mov eax, [putimg.ebp+4]
335	call eax	334	call eax
336	cmp [ebp], bl	335	cmp [ebp], bl
337	jne .skip	336	jne .skip
338	;--------------------------------------	337	;--------------------------------------
339	push ecx	338	push ecx
340		339
341	neg ecx	340	neg ecx
342	add ecx, [putimg.real_sx_and_abs_cx + 4]	341	add ecx, [putimg.real_sx_and_abs_cx + 4]
343	shl ecx, 16	342	shl ecx, 16
344	add ecx, [putimg.real_sy_and_abs_cy + 4]	343	add ecx, [putimg.real_sy_and_abs_cy + 4]
345	sub ecx, edi	344	sub ecx, edi
346		345
347	; check mouse area for putpixel	346	; check mouse area for putpixel
348	call check_mouse_area_for_putpixel	347	call check_mouse_area_for_putpixel
349	pop ecx	348	pop ecx
350	; store to real LFB	349	; store to real LFB
351	mov [LFB_BASE+edx], ax	350	mov [LFB_BASE+edx], ax
352	shr eax, 16	351	shr eax, 16
353	mov [LFB_BASE+edx+2], al	352	mov [LFB_BASE+edx+2], al
354	;--------------------------------------	353	;--------------------------------------
355	align 4	354	align 4
356	.skip:	355	.skip:
357	add edx, 3	356	add edx, 3
358	inc ebp	357	inc ebp
359	dec ecx	358	dec ecx
360	jnz .new_x	359	jnz .new_x
361		360
362	add esi, [putimg.line_increment]	361	add esi, [putimg.line_increment]
363	add edx, [putimg.screen_newline];[BytesPerScanLine]	362	add edx, [putimg.screen_newline];[BytesPerScanLine]
364	add ebp, [putimg.winmap_newline];[Screen_Max_X]	363	add ebp, [putimg.winmap_newline];[Screen_Max_X]
365		364
366	cmp [putimg.ebp], putimage_get1bpp	365	cmp [putimg.ebp], putimage_get1bpp
367	jz .correct	366	jz .correct
368	cmp [putimg.ebp], putimage_get2bpp	367	cmp [putimg.ebp], putimage_get2bpp
369	jz .correct	368	jz .correct
370	cmp [putimg.ebp], putimage_get4bpp	369	cmp [putimg.ebp], putimage_get4bpp
371	jnz @f	370	jnz @f
372	;--------------------------------------	371	;--------------------------------------
373	align 4	372	align 4
374	.correct:	373	.correct:
375	mov eax, [putimg.edi]	374	mov eax, [putimg.edi]
376	mov byte [eax], 80h	375	mov byte [eax], 80h
377	;--------------------------------------	376	;--------------------------------------
378	align 4	377	align 4
379	@@:	378	@@:
380	dec edi	379	dec edi
381	jnz .new_line	380	jnz .new_line
382	jmp put_image_end_24.finish	381	jmp put_image_end_24.finish
383	;------------------------------------------------------------------------------	382	;------------------------------------------------------------------------------
384	align 4	383	align 4
385	put_image_end_24_new:	384	put_image_end_24_new:
386	;--------------------------------------	385	;--------------------------------------
387	align 4	386	align 4
388	.new_line:	387	.new_line:
389	mov ecx, [putimg.real_sx]	388	mov ecx, [putimg.real_sx]
390	;--------------------------------------	389	;--------------------------------------
391	align 4	390	align 4
392	.new_x:	391	.new_x:
393	push [putimg.edi]	392	push [putimg.edi]
394	mov eax, [putimg.ebp+4]	393	mov eax, [putimg.ebp+4]
395	call eax	394	call eax
396	cmp [ebp], bl	395	cmp [ebp], bl
397	jne .skip	396	jne .skip
398	;--------------------------------------	397	;--------------------------------------
399	push ecx	398	push ecx
400	;--------------------------------------	399	;--------------------------------------
401	align 4	400	align 4
402	.sh:	401	.sh:
403	neg ecx	402	neg ecx
404	add ecx, [putimg.real_sx_and_abs_cx + 4]	403	add ecx, [putimg.real_sx_and_abs_cx + 4]
405	;--------------------------------------	404	;--------------------------------------
406	; check for X	405	; check for X
407	cmp cx, [X_UNDER_sub_CUR_hot_x_add_curh]	406	cmp cx, [X_UNDER_sub_CUR_hot_x_add_curh]
408	jae .no_mouse_area	407	jae .no_mouse_area
409		408
410	sub cx, [X_UNDER_subtraction_CUR_hot_x]	409	sub cx, [X_UNDER_subtraction_CUR_hot_x]
411	jb .no_mouse_area	410	jb .no_mouse_area
412		411
413	shl ecx, 16	412	shl ecx, 16
414		413
415	add ecx, [putimg.real_sy_and_abs_cy + 4]	414	add ecx, [putimg.real_sy_and_abs_cy + 4]
416	sub ecx, edi	415	sub ecx, edi
417	;--------------------------------------	416	;--------------------------------------
418	; check for Y	417	; check for Y
419	cmp cx, [Y_UNDER_sub_CUR_hot_y_add_curh]	418	cmp cx, [Y_UNDER_sub_CUR_hot_y_add_curh]
420	jae .no_mouse_area	419	jae .no_mouse_area
421		420
422	sub cx, [Y_UNDER_subtraction_CUR_hot_y]	421	sub cx, [Y_UNDER_subtraction_CUR_hot_y]
423	jb .no_mouse_area	422	jb .no_mouse_area
424	;--------------------------------------	423	;--------------------------------------
425	; check mouse area for putpixel	424	; check mouse area for putpixel
426	call check_mouse_area_for_putpixel_new.1	425	call check_mouse_area_for_putpixel_new.1
427	cmp ecx, -1 ;SHIT HAPPENS?	426	cmp ecx, -1 ;SHIT HAPPENS?
428	jne .no_mouse_area	427	jne .no_mouse_area
429		428
430	mov ecx, [esp]	429	mov ecx, [esp]
431	jmp .sh	430	jmp .sh
432	;--------------------------------------	431	;--------------------------------------
433	align 4	432	align 4
434	.no_mouse_area:	433	.no_mouse_area:
435	pop ecx	434	pop ecx
436	; store to real LFB	435	; store to real LFB
437	mov [LFB_BASE+edx], ax	436	mov [LFB_BASE+edx], ax
438	shr eax, 16	437	shr eax, 16
439	mov [LFB_BASE+edx+2], al	438	mov [LFB_BASE+edx+2], al
440	;--------------------------------------	439	;--------------------------------------
441	align 4	440	align 4
442	.skip:	441	.skip:
443	add edx, 3	442	add edx, 3
444	inc ebp	443	inc ebp
445	dec ecx	444	dec ecx
446	jnz .new_x	445	jnz .new_x
447		446
448	add esi, [putimg.line_increment]	447	add esi, [putimg.line_increment]
449	add edx, [putimg.screen_newline];[BytesPerScanLine]	448	add edx, [putimg.screen_newline];[BytesPerScanLine]
450	add ebp, [putimg.winmap_newline];[Screen_Max_X]	449	add ebp, [putimg.winmap_newline];[Screen_Max_X]
451		450
452	cmp [putimg.ebp], putimage_get1bpp	451	cmp [putimg.ebp], putimage_get1bpp
453	jz .correct	452	jz .correct
454	cmp [putimg.ebp], putimage_get2bpp	453	cmp [putimg.ebp], putimage_get2bpp
455	jz .correct	454	jz .correct
456	cmp [putimg.ebp], putimage_get4bpp	455	cmp [putimg.ebp], putimage_get4bpp
457	jnz @f	456	jnz @f
458	;--------------------------------------	457	;--------------------------------------
459	align 4	458	align 4
460	.correct:	459	.correct:
461	mov eax, [putimg.edi]	460	mov eax, [putimg.edi]
462	mov byte [eax], 80h	461	mov byte [eax], 80h
463	;--------------------------------------	462	;--------------------------------------
464	align 4	463	align 4
465	@@:	464	@@:
466	dec edi	465	dec edi
467	jnz .new_line	466	jnz .new_line
468	jmp put_image_end_24.finish	467	jmp put_image_end_24.finish
469	;------------------------------------------------------------------------------	468	;------------------------------------------------------------------------------
470	align 4	469	align 4
471	put_image_end_32:	470	put_image_end_32:
472	mov edi, [putimg.real_sy]	471	mov edi, [putimg.real_sy]
473	;--------------------------------------	472	;--------------------------------------
474	; check for hardware cursor	473	; check for hardware cursor
475	mov ecx, [_display.select_cursor]	474	mov ecx, [_display.select_cursor]
476	cmp ecx, select_cursor	475	cmp ecx, select_cursor
477	je put_image_end_32_new	476	je put_image_end_32_new
478	cmp ecx, 0	477	cmp ecx, 0
479	je put_image_end_32_old	478	je put_image_end_32_old
480	;--------------------------------------	479	;--------------------------------------
481	align 4	480	align 4
482	.new_line:	481	.new_line:
483	mov ecx, [putimg.real_sx]	482	mov ecx, [putimg.real_sx]
484	;--------------------------------------	483	;--------------------------------------
485	align 4	484	align 4
486	.new_x:	485	.new_x:
487	push [putimg.edi]	486	push [putimg.edi]
488	mov eax, [putimg.ebp+4]	487	mov eax, [putimg.ebp+4]
489	call eax	488	call eax
490	cmp [ebp], bl	489	cmp [ebp], bl
491	jne .skip	490	jne .skip
492	;--------------------------------------	491	;--------------------------------------
493	; store to real LFB	492	; store to real LFB
494	mov [LFB_BASE+edx], eax	493	mov [LFB_BASE+edx], eax
495	;--------------------------------------	494	;--------------------------------------
496	align 4	495	align 4
497	.skip:	496	.skip:
498	add edx, 4	497	add edx, 4
499	inc ebp	498	inc ebp
500	dec ecx	499	dec ecx

Subversion Repositories Kolibri OS

(root)/kernel/branches/kolibri-process/video/vesa20.inc – Rev 4587 → 4923