WebSVN – Kolibri OS – Diff – /kernel/branches/Kolibri-acpi/network/socket.inc


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;                                                                 ;;
;; Copyright (C) KolibriOS team 2004-2014. All rights reserved.    ;;
;; Distributed under terms of the GNU General Public License       ;;
;;                                                                 ;;
;;  Part of the TCP/IP network stack for KolibriOS                 ;;
;;                                                                 ;;
;;   Written by hidnplayr@kolibrios.org,                           ;;
;;     and Clevermouse.                                            ;;
;;                                                                 ;;
;;       Based on code by mike.dld                                 ;;
;;                                                                 ;;
;;         GNU GENERAL PUBLIC LICENSE                              ;;
;;          Version 2, June 1991                                   ;;
;;                                                                 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 
$Revision: 5201 $
 
struct  SOCKET
 
        NextPtr                 dd ? ; pointer to next socket in list
        PrevPtr                 dd ? ; pointer to previous socket in list
        Number                  dd ? ; socket number
 
        mutex                   MUTEX
 
        PID                     dd ? ; process ID
        TID                     dd ? ; thread ID
        Domain                  dd ? ; INET/LOCAL/..
        Type                    dd ? ; RAW/STREAM/DGRAM
        Protocol                dd ? ; ICMP/IPv4/ARP/TCP/UDP
        errorcode               dd ?
        device                  dd ? ; driver pointer, socket pointer if it's an LOCAL socket
 
        options                 dd ?
        state                   dd ?
        backlog                 dw ? ; how many incoming connections that can be queued
 
        snd_proc                dd ?
        rcv_proc                dd ?
        connect_proc            dd ?
 
ends
 
struct  IP_SOCKET               SOCKET
 
        LocalIP                 rd 4 ; network byte order
        RemoteIP                rd 4 ; network byte order
 
ends
 
struct  TCP_SOCKET              IP_SOCKET
 
        LocalPort               dw ? ; network byte order
        RemotePort              dw ? ; network byte order
 
        t_state                 dd ? ; TCB state
        t_rxtshift              db ?
                                rb 3 ; align
        t_rxtcur                dd ?
        t_dupacks               dd ?
        t_maxseg                dd ?
        t_force                 dd ?
        t_flags                 dd ?
 
;---------------
; RFC783 page 21
 
; send sequence
        SND_UNA                 dd ? ; sequence number of unack'ed sent Packets
        SND_NXT                 dd ? ; next send sequence number to use
        SND_UP                  dd ? ; urgent pointer
        SND_WL1                 dd ? ; window minus one
        SND_WL2                 dd ? ;
        ISS                     dd ? ; initial send sequence number
        SND_WND                 dd ? ; send window
 
; receive sequence
        RCV_WND                 dd ? ; receive window
        RCV_NXT                 dd ? ; next receive sequence number to use
        RCV_UP                  dd ? ; urgent pointer
        IRS                     dd ? ; initial receive sequence number
 
;---------------------
; Additional variables
 
; receive variables
        RCV_ADV                 dd ?
 
; retransmit variables
        SND_MAX                 dd ?
 
; congestion control
        SND_CWND                dd ?    ; congestion window
        SND_SSTHRESH            dd ?    ; slow start threshold
 
;----------------------
; Transmit timing stuff
        t_idle                  dd ?
        t_rtt                   dd ?
        t_rtseq                 dd ?
        t_srtt                  dd ?
        t_rttvar                dd ?
        t_rttmin                dd ?
        max_sndwnd              dd ?
 
;-----------------
; Out-of-band data
        t_oobflags              dd ?
        t_iobc                  dd ?
        t_softerror             dd ?
 
 
;---------
; RFC 1323                              ; the order of next 4 elements may not change
 
        SND_SCALE               db ?
        RCV_SCALE               db ?
        requested_s_scale       db ?
        request_r_scale         db ?
 
        ts_recent               dd ?    ; a copy of the most-recent valid timestamp from the other end
        ts_recent_age           dd ?
        last_ack_sent           dd ?
 
 
;-------
; Timers
        timer_flags             dd ?
        timer_retransmission    dd ? ; rexmt
        timer_persist           dd ?
        timer_keepalive         dd ? ; keepalive/syn timeout
        timer_timed_wait        dd ? ; also used as 2msl timer
        timer_connect           dd ?
 
; extra
 
        ts_ecr                  dd ? ; timestamp echo reply
        ts_val                  dd ?
 
        seg_next                dd ? ; re-assembly queue
 
ends
 
struct  UDP_SOCKET              IP_SOCKET
 
        LocalPort               dw ? ; network byte order
        RemotePort              dw ? ; network byte order
 
ends
 
 
struct  ICMP_SOCKET             IP_SOCKET
 
        Identifier              dw ?
 
ends
 
 
struct  RING_BUFFER
 
        mutex                   MUTEX
        start_ptr               dd ? ; Pointer to start of buffer
        end_ptr                 dd ? ; pointer to end of buffer
        read_ptr                dd ? ; Read pointer
        write_ptr               dd ? ; Write pointer
        size                    dd ? ; Number of bytes buffered
 
ends
 
struct  STREAM_SOCKET           TCP_SOCKET
 
        rcv                     RING_BUFFER
        snd                     RING_BUFFER
 
ends
 
struct  socket_queue_entry
 
        data_ptr                dd ?
        buf_ptr                 dd ?
        data_size               dd ?
 
ends
 
 
SOCKETBUFFSIZE          = 4096     ; in bytes
 
SOCKET_QUEUE_SIZE       = 10       ; maximum number of incoming packets queued for 1 socket
; the incoming packet queue for sockets is placed in the socket struct itself, at this location from start
SOCKET_QUEUE_LOCATION   = (SOCKETBUFFSIZE - SOCKET_QUEUE_SIZE*sizeof.socket_queue_entry - sizeof.queue)
 
uglobal
align 4
 
        net_sockets     rd 4
        last_socket_num dd ?
        last_UDP_port   dw ? ; These values give the number of the last used ephemeral port
        last_TCP_port   dw ? ;
        socket_mutex    MUTEX
 
endg
 
 
;-----------------------------------------------------------------
;
; SOCKET_init
;
;-----------------------------------------------------------------
macro   SOCKET_init {
 
        xor     eax, eax
        mov     edi, net_sockets
        mov     ecx, 5
        rep stosd
 
       @@:
        pseudo_random eax
        cmp     ax, EPHEMERAL_PORT_MIN
        jb      @r
        cmp     ax, EPHEMERAL_PORT_MAX
        ja      @r
        xchg    al, ah
        mov     [last_UDP_port], ax
 
       @@:
        pseudo_random eax
        cmp     ax, EPHEMERAL_PORT_MIN
        jb      @r
        cmp     ax, EPHEMERAL_PORT_MAX
        ja      @r
        xchg    al, ah
        mov     [last_TCP_port], ax
 
        mov     ecx, socket_mutex
        call    mutex_init
 
}
 
;-----------------------------------------------------------------
;
; Socket API (function 74)
;
;-----------------------------------------------------------------
align 4
sys_socket:
 
        mov     dword[esp+20], 0        ; Set error code to 0
 
        cmp     ebx, 255
        jz      SOCKET_debug
 
        cmp     ebx, .number
        ja      .error
        jmp     dword [.table + 4*ebx]
 
  .table:
        dd      SOCKET_open     ; 0
        dd      SOCKET_close    ; 1
        dd      SOCKET_bind     ; 2
        dd      SOCKET_listen   ; 3
        dd      SOCKET_connect  ; 4
        dd      SOCKET_accept   ; 5
        dd      SOCKET_send     ; 6
        dd      SOCKET_receive  ; 7
        dd      SOCKET_set_opt  ; 8
        dd      SOCKET_get_opt  ; 9
        dd      SOCKET_pair     ; 10
  .number = ($ - .table) / 4 - 1
 
  .error:
        mov     dword[esp+32], -1
        mov     dword[esp+20], EINVAL
 
        ret
 
;-----------------------------------------------------------------
;
; SOCKET_open
;
;  IN:  domain in ecx
;       type in edx
;       protocol in esi
;  OUT: eax is socket num, -1 on error
;
;-----------------------------------------------------------------
align 4
SOCKET_open:
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_open: domain=%u type=%u protocol=%x ", ecx, edx, esi
 
        push    ecx edx esi
        call    SOCKET_alloc
        pop     esi edx ecx
        test    eax, eax
        jz      .nobuffs
 
        mov     [esp+32], edi                   ; return socketnumber
        DEBUGF  DEBUG_NETWORK_VERBOSE, "socknum=%u\n", edi
 
        test    edx, SO_NONBLOCK
        jz      @f
        or      [eax + SOCKET.options], SO_NONBLOCK
        and     edx, not SO_NONBLOCK
  @@:
 
        mov     [eax + SOCKET.Domain], ecx
        mov     [eax + SOCKET.Type], edx
        mov     [eax + SOCKET.Protocol], esi
        mov     [eax + SOCKET.connect_proc], connect_notsupp
 
        cmp     ecx, AF_INET4
        jne     .no_inet4
 
        cmp     edx, SOCK_DGRAM
        je      .udp
 
        cmp     edx, SOCK_STREAM
        je      .tcp
 
        cmp     edx, SOCK_RAW
        je      .raw
 
  .no_inet4:
        cmp     ecx, AF_PPP
        jne     .no_ppp
 
        cmp     esi, PPP_PROTO_ETHERNET
        je      .pppoe
 
  .no_ppp:
  .unsupported:
        push    eax
        call    SOCKET_free
        pop     eax
        mov     dword[esp+20], EOPNOTSUPP
        mov     dword[esp+32], -1
        ret
 
  .nobuffs:
        mov     dword[esp+20], ENOBUFS
        mov     dword[esp+32], -1
        ret
 
  .raw:
        test    esi, esi       ; IP_PROTO_IP
        jz      .raw_ip
 
        cmp     esi, IP_PROTO_ICMP
        je      .raw_icmp
 
        jmp     .unsupported
 
align 4
  .udp:
        mov     [eax + SOCKET.Protocol], IP_PROTO_UDP
        mov     [eax + SOCKET.snd_proc], SOCKET_send_udp
        mov     [eax + SOCKET.rcv_proc], SOCKET_receive_dgram
        mov     [eax + SOCKET.connect_proc], UDP_connect
        ret
 
align 4
  .tcp:
        mov     [eax + SOCKET.Protocol], IP_PROTO_TCP
        mov     [eax + SOCKET.snd_proc], SOCKET_send_tcp
        mov     [eax + SOCKET.rcv_proc], SOCKET_receive_stream
        mov     [eax + SOCKET.connect_proc], TCP_connect
 
        TCP_init_socket eax
        ret
 
 
align 4
  .raw_ip:
        mov     [eax + SOCKET.snd_proc], SOCKET_send_ip
        mov     [eax + SOCKET.rcv_proc], SOCKET_receive_dgram
        mov     [eax + SOCKET.connect_proc], IPv4_connect
        ret
 
 
align 4
  .raw_icmp:
        mov     [eax + SOCKET.snd_proc], SOCKET_send_icmp
        mov     [eax + SOCKET.rcv_proc], SOCKET_receive_dgram
        mov     [eax + SOCKET.connect_proc], IPv4_connect
        ret
 
align 4
  .pppoe:
        push    eax
        init_queue (eax + SOCKET_QUEUE_LOCATION)        ; Set up data receiving queue
        pop     eax
 
        mov     [eax + SOCKET.snd_proc], SOCKET_send_pppoe
        mov     [eax + SOCKET.rcv_proc], SOCKET_receive_dgram
        ret
 
 
;-----------------------------------------------------------------
;
; SOCKET_bind
;
;  IN:  socket number in ecx
;       pointer to sockaddr struct in edx
;       length of that struct in esi
;  OUT: 0 on success
;
;-----------------------------------------------------------------
align 4
SOCKET_bind:
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_bind: socknum=%u sockaddr=%x length=%u\n", ecx, edx, esi
 
        call    SOCKET_num_to_ptr
        jz      .invalid
 
        cmp     esi, 2
        jb      .invalid
 
        cmp     [eax + UDP_SOCKET.LocalPort], 0         ; Socket can only be bound once
        jnz     .invalid
 
        cmp     word [edx], AF_INET4
        je      .af_inet4
 
        cmp     word [edx], AF_LOCAL
        je      .af_local
 
  .notsupp:
        mov     dword[esp+20], EOPNOTSUPP
        mov     dword[esp+32], -1
        ret
 
  .invalid:
        mov     dword[esp+20], EINVAL
        mov     dword[esp+32], -1
        ret
 
  .af_local:
        ; TODO: write code here
        mov     dword[esp+32], 0
        ret
 
  .af_inet4:
        cmp     esi, 6
        jb      .invalid
 
        cmp     [eax + SOCKET.Protocol], IP_PROTO_UDP
        je      .udp
 
        cmp     [eax + SOCKET.Protocol], IP_PROTO_TCP
        je      .tcp
 
        jmp     .notsupp
 
  .tcp:
  .udp:
 
        pushd   [edx + 4]                       ; First, fill in the IP
        popd    [eax + IP_SOCKET.LocalIP]
 
        mov     bx, [edx + 2]                   ; Did caller specify a local port?
        test    bx, bx
        jnz     .just_check
        call    SOCKET_find_port                ; Nope, find an ephemeral one
        jmp     .done
 
  .just_check:
        call    SOCKET_check_port               ; Yes, check if it's still available
        jz      .addrinuse                      ; ZF is set by socket_check_port on error
 
  .done:
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_bind: local ip=%u.%u.%u.%u\n",\
        [eax + IP_SOCKET.LocalIP + 0]:1,[eax + IP_SOCKET.LocalIP + 1]:1,\
        [eax + IP_SOCKET.LocalIP + 2]:1,[eax + IP_SOCKET.LocalIP + 3]:1
 
        mov     dword[esp+32], 0
        ret
 
  .addrinuse:
        mov     dword[esp+32], -1
        mov     dword[esp+20], EADDRINUSE
        ret
 
 
 
 
;-----------------------------------------------------------------
;
; SOCKET_connect
;
;  IN:  socket number in ecx
;       pointer to sockaddr struct in edx
;       length of that struct in esi
;  OUT: 0 on success
;
;-----------------------------------------------------------------
align 4
SOCKET_connect:
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_connect: socknum=%u sockaddr=%x length=%u\n", ecx, edx, esi
 
        call    SOCKET_num_to_ptr
        jz      .invalid
 
        cmp     esi, 8
        jb      .invalid
 
        cmp     [eax + SOCKET.state], SS_ISCONNECTING
        je      .already
 
        test    [eax + SOCKET.options], SO_ACCEPTCON
        jnz     .notsupp
 
        call    [eax + SOCKET.connect_proc]
 
        mov     dword[esp+20], ebx
        mov     dword[esp+32], eax
        ret
 
 
  .notsupp:
        mov     dword[esp+20], EOPNOTSUPP
        mov     dword[esp+32], -1
        ret
 
  .invalid:
        mov     dword[esp+20], EINVAL
        mov     dword[esp+32], -1
        ret
 
  .already:
        mov     dword[esp+20], EALREADY
        mov     dword[esp+32], -1
        ret
 
 
connect_notsupp:
        xor     eax, eax
        dec     eax
        mov     ebx, EOPNOTSUPP
        ret
 
 
;-----------------------------------------------------------------
;
; SOCKET_listen
;
;  IN:  socket number in ecx
;       backlog in edx
;  OUT: eax is socket num, -1 on error
;
;-----------------------------------------------------------------
align 4
SOCKET_listen:
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_listen: socknum=%u backlog=%u\n", ecx, edx
 
        call    SOCKET_num_to_ptr
        jz      .invalid
 
        cmp     [eax + SOCKET.Domain], AF_INET4
        jne     .notsupp
 
        cmp     [eax + SOCKET.Protocol], IP_PROTO_TCP
        jne     .invalid
 
        cmp     [eax + TCP_SOCKET.LocalPort], 0
        je      .already
 
        cmp     [eax + IP_SOCKET.LocalIP], 0
        jne     @f
        push    [IP_LIST + 4]           ;;; fixme!!!!
        pop     [eax + IP_SOCKET.LocalIP]
       @@:
 
        cmp     edx, MAX_backlog
        jbe     @f
        mov     edx, MAX_backlog
       @@:
 
        mov     [eax + SOCKET.backlog], dx
        or      [eax + SOCKET.options], SO_ACCEPTCON
        mov     [eax + TCP_SOCKET.t_state], TCPS_LISTEN
        mov     [eax + TCP_SOCKET.timer_keepalive], 0           ; disable keepalive timer
 
        push    eax
        init_queue (eax + SOCKET_QUEUE_LOCATION)                ; Set up sockets queue
        pop     eax
 
        mov     dword[esp+32], 0
        ret
 
  .notsupp:
        mov     dword[esp+20], EOPNOTSUPP
        mov     dword[esp+32], -1
        ret
 
  .invalid:
        mov     dword[esp+20], EINVAL
        mov     dword[esp+32], -1
        ret
 
  .already:
        mov     dword[esp+20], EALREADY
        mov     dword[esp+32], -1
        ret
 
 
;-----------------------------------------------------------------
;
; SOCKET_accept
;
;  IN:  socket number in ecx
;       addr in edx
;       addrlen in esi
;  OUT: eax is socket num, -1 on error
;
;-----------------------------------------------------------------
align 4
SOCKET_accept:
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_accept: socknum=%u sockaddr=%x length=%u\n", ecx, edx, esi
 
        call    SOCKET_num_to_ptr
        jz      .invalid
 
        test    [eax + SOCKET.options], SO_ACCEPTCON
        jz      .invalid
 
        cmp     [eax + SOCKET.Domain], AF_INET4
        jne     .notsupp
 
        cmp     [eax + SOCKET.Protocol], IP_PROTO_TCP
        jne     .invalid
 
  .loop:
        get_from_queue (eax + SOCKET_QUEUE_LOCATION), MAX_backlog, 4, .block
 
; Ok, we got a socket ptr
        mov     eax, [esi]
 
; Change thread ID to that of the current thread
        mov     ebx, [TASK_BASE]
        mov     ebx, [ebx + TASKDATA.pid]
        mov     [eax + SOCKET.TID], ebx
 
; Convert it to a socket number
        call    SOCKET_ptr_to_num
        jz      .invalid        ; FIXME ?
 
; and return it to caller
        mov     [esp+32], eax
        ret
 
  .block:
        test    [eax + SOCKET.options], SO_NONBLOCK
        jnz     .wouldblock
 
        call    SOCKET_block
        jmp     .loop
 
  .wouldblock:
        mov     dword[esp+20], EWOULDBLOCK
        mov     dword[esp+32], -1
        ret
 
  .invalid:
        mov     dword[esp+20], EINVAL
        mov     dword[esp+32], -1
        ret
 
  .notsupp:
        mov     dword[esp+20], EOPNOTSUPP
        mov     dword[esp+32], -1
        ret
 
;-----------------------------------------------------------------
;
; SOCKET_close
;
;  IN:  socket number in ecx
;  OUT: eax is socket num, -1 on error
;
;-----------------------------------------------------------------
align 4
SOCKET_close:
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_close: socknum=%u\n", ecx
 
        call    SOCKET_num_to_ptr
        jz      .invalid
 
        mov     dword[esp+32], 0                                ; The socket exists, so we will succeed in closing it.
 
        or      [eax + SOCKET.options], SO_NONBLOCK             ; Mark the socket as non blocking, we dont want it to block any longer!
 
        test    [eax + SOCKET.state], SS_BLOCKED                ; Is the socket still in blocked state?
        jz      @f
        call    SOCKET_notify                                   ; Unblock it.
  @@:
 
        cmp     [eax + SOCKET.Domain], AF_INET4
        jne     .free
 
        cmp     [eax + SOCKET.Protocol], IP_PROTO_TCP
        je      .tcp
 
  .free:
        call    SOCKET_free
        ret
 
  .tcp:
 
        call    TCP_usrclosed
 
        test    eax, eax
        jz      @f
        call    TCP_output                                      ; If connection is not closed yet, send the FIN
  @@:
 
        ret
 
 
  .invalid:
        mov     dword[esp+20], EINVAL
        mov     dword[esp+32], -1
        ret
 
 
;-----------------------------------------------------------------
;
; SOCKET_receive
;
;  IN:  socket number in ecx
;       addr to buffer in edx
;       length of buffer in esi
;       flags in edi
;  OUT: eax is number of bytes copied, -1 on error
;
;-----------------------------------------------------------------
align 4
SOCKET_receive:
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_receive: socknum=%u bufaddr=%x buflength=%u flags=%x\n", ecx, edx, esi, edi
 
        call    SOCKET_num_to_ptr
        jz      .invalid
 
  .loop:
        push    edi
        call    [eax + SOCKET.rcv_proc]
        pop     edi
 
        test    [eax + SOCKET.state], SS_CANTRCVMORE
        jnz     .return
 
        cmp     ebx, EWOULDBLOCK
        jne     .return
 
        test    edi, MSG_DONTWAIT
        jnz     .return_err
 
;        test    [eax + SOCKET.options], SO_NONBLOCK
;        jnz     .return_err
 
        call    SOCKET_block
        jmp     .loop
 
 
  .invalid:
        push    EINVAL
        pop     ebx
  .return_err:
        mov     ecx, -1
  .return:
        mov     [esp+20], ebx
        mov     [esp+32], ecx
        ret
 
 
 
 
 
align 4
SOCKET_receive_dgram:
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_receive: DGRAM\n"
 
        mov     ebx, esi                                        ; bufferlength
 
        get_from_queue (eax + SOCKET_QUEUE_LOCATION), SOCKET_QUEUE_SIZE, sizeof.socket_queue_entry, .wouldblock ; sets esi only on success.
        mov     ecx, [esi + socket_queue_entry.data_size]
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_receive: %u bytes data\n", ecx
 
        cmp     ecx, ebx                                        ; If data segment does not fit in applications buffer, abort
        ja      .too_small
 
        push    eax ecx
        push    [esi + socket_queue_entry.buf_ptr]              ; save the buffer addr so we can clear it later
        mov     esi, [esi + socket_queue_entry.data_ptr]
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_receive: Source buffer=%x real addr=%x\n", [esp], esi
 
; copy the data from kernel buffer to application buffer
        mov     edi, edx                                        ; bufferaddr
        shr     ecx, 1
        jnc     .nb
        movsb
  .nb:
        shr     ecx, 1
        jnc     .nw
        movsw
  .nw:
        test    ecx, ecx
        jz      .nd
        rep movsd
  .nd:
 
        call    NET_packet_free
        pop     ecx eax                                         ; return number of bytes copied to application
        xor     ebx, ebx
        ret
 
  .too_small:
        mov     ecx, -1
        push    EMSGSIZE
        pop     ebx
        ret
 
  .wouldblock:
        push    EWOULDBLOCK
        pop     ebx
        ret
 
 
 
align 4
SOCKET_receive_local:
 
        ; does this socket have a PID yet?
        cmp     [eax + SOCKET.PID], 0
        jne     @f
 
        ; Change PID to that of current process
        mov     ebx, [TASK_BASE]
        mov     ebx, [ebx + TASKDATA.pid]
        mov     [eax + SOCKET.PID], ebx
        mov     [eax + SOCKET.TID], ebx                         ; currently TID = PID in kolibrios :(
      @@:
 
        mov     [eax + SOCKET.rcv_proc], SOCKET_receive_stream
 
; ... continue to SOCKET_receive_stream
 
align 4
SOCKET_receive_stream:
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_receive: STREAM\n"
 
        cmp     [eax + STREAM_SOCKET.rcv + RING_BUFFER.size], 0
        je      .wouldblock
 
        test    edi, MSG_PEEK
        jnz     .peek
 
        mov     ecx, esi
        mov     edi, edx
        xor     edx, edx
 
        push    eax
        add     eax, STREAM_SOCKET.rcv
        call    SOCKET_ring_read                                ; copy data from kernel buffer to application buffer
        call    SOCKET_ring_free                                ; free read memory
        pop     eax
 
        xor     ebx, ebx                                        ; errorcode = 0 (no error)
        ret
 
  .wouldblock:
        push    EWOULDBLOCK
        pop     ebx
        xor     ecx, ecx
        ret
 
  .peek:
        mov     ecx, [eax + STREAM_SOCKET.rcv + RING_BUFFER.size]
        xor     ebx, ebx
        ret
 
 
;-----------------------------------------------------------------
;
; SOCKET_send
;
;
;  IN:  socket number in ecx
;       pointer to data in edx
;       datalength in esi
;       flags in edi
;  OUT: -1 on error
;
;-----------------------------------------------------------------
align 4
SOCKET_send:
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_send: socknum=%u data ptr=%x length=%u flags=%x\n", ecx, edx, esi, edi
 
        call    SOCKET_num_to_ptr
        jz      .invalid
 
        mov     ecx, esi
        mov     esi, edx
 
        jmp     [eax + SOCKET.snd_proc]
 
  .invalid:
        mov     dword[esp+20], EINVAL
        mov     dword[esp+32], -1
        ret
 
 
align 4
SOCKET_send_udp:
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_send: UDP\n"
 
        mov     [esp+32], ecx
        call    UDP_output
        cmp     eax, -1
        je      .error
        ret
 
  .error:
        mov     dword[esp+32], -1
        mov     dword[esp+20], EMSGSIZE ; FIXME: UDP_output should return error codes!
        ret
 
 
align 4
SOCKET_send_tcp:
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_send: TCP\n"
 
        push    eax
        add     eax, STREAM_SOCKET.snd
        call    SOCKET_ring_write
        pop     eax
 
        mov     [esp+32], ecx
        mov     [eax + SOCKET.errorcode], 0
        push    eax
        call    TCP_output              ; FIXME: this doesnt look pretty, does it?
        pop     eax
        mov     eax, [eax + SOCKET.errorcode]
        mov     [esp+20], eax
        ret
 
 
align 4
SOCKET_send_ip:
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_send: IPv4\n"
 
        mov     [esp+32], ecx
        call    IPv4_output_raw         ; FIXME: IPv4_output_raw should return error codes!
        cmp     eax, -1
        je      .error
        ret
 
  .error:
        mov     dword[esp+32], -1
        mov     dword[esp+20], EMSGSIZE
        ret
 
 
align 4
SOCKET_send_icmp:
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_send: ICMP\n"
 
        mov     [esp+32], ecx
        call    ICMP_output_raw         ; FIXME: errorcodes
        cmp     eax, -1
        je      .error
        ret
 
  .error:
        mov     dword[esp+32], -1
        mov     dword[esp+20], EMSGSIZE
        ret
 
 
align 4
SOCKET_send_pppoe:
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_send: PPPoE\n"
 
        mov     [esp+32], ecx
        mov     ebx, [eax + SOCKET.device]
 
        call    PPPoE_discovery_output  ; FIXME: errorcodes
        cmp     eax, -1
        je      .error
        ret
 
  .error:
        mov     dword[esp+32], -1
        mov     dword[esp+20], EMSGSIZE
        ret
 
 
 
align 4
SOCKET_send_local:
 
        ; does this socket have a PID yet?
        cmp     [eax + SOCKET.PID], 0
        jne     @f
 
        ; Change PID to that of current process
        mov     ebx, [TASK_BASE]
        mov     ebx, [ebx + TASKDATA.pid]
        mov     [eax + SOCKET.PID], ebx
        mov     [eax + SOCKET.TID], ebx         ; currently TID = PID in kolibrios :(
      @@:
        mov     [eax + SOCKET.snd_proc], SOCKET_send_local_
 
align 4
SOCKET_send_local_:
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_send: LOCAL\n"
 
        ; get the other side's socket and check if it still exists
        mov     eax, [eax + SOCKET.device]
        call    SOCKET_check
        jz      .invalid
 
        ; allright, shove in the data!
        push    eax
        add     eax, STREAM_SOCKET.rcv
        call    SOCKET_ring_write
        pop     eax
 
        ; return the number of written bytes (or errorcode) to application
        mov     [esp+32], ecx
 
        ; and notify the other end
        call    SOCKET_notify
 
        ret
 
  .invalid:
        mov     dword[esp+32], -1
        mov     dword[esp+20], EINVAL
        ret
 
 
;-----------------------------------------------------------------
;
; SOCKET_get_options
;
;  IN:  ecx = socket number
;       edx = pointer to the options:
;               dd      level, optname, optval, optlen
;  OUT: -1 on error
;
; At moment, uses only pseudo-optname -2 for get last_ack_number for TCP.
; TODO: find best way to notify that send()'ed data were acknowledged
; Also pseudo-optname -3 is valid and returns socket state, one of TCPS_*.
;
;-----------------------------------------------------------------
align 4
SOCKET_get_opt:
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_get_opt\n"
 
        call    SOCKET_num_to_ptr
        jz      .invalid
 
        cmp     dword [edx], IP_PROTO_TCP
        jne     .invalid
        cmp     dword [edx+4], -2
        je      @f
        cmp     dword [edx+4], -3
        jne     .invalid
@@:
;        mov     eax, [edx+12]
;        test    eax, eax
;        jz      .fail
;        cmp     dword [eax], 4
;        mov     dword [eax], 4
;        jb      .fail
;        stdcall net_socket_num_to_addr, ecx
;        test    eax, eax
;        jz      .fail
;        ; todo: check that eax is really TCP socket
;        mov     ecx, [eax + TCP_SOCKET.last_ack_number]
;        cmp     dword [edx+4], -2
;        jz      @f
;        mov     ecx, [eax + TCP_SOCKET.state]
@@:
        mov     eax, [edx+8]
        test    eax, eax
        jz      @f
        mov     [eax], ecx
@@:
        mov     dword [esp+32], 0
        ret
 
  .invalid:
        mov     dword[esp+32], -1
        mov     dword[esp+20], EINVAL
        ret
 
 
 
;-----------------------------------------------------------------
;
; SOCKET_set_options
;
;  IN:  ecx = socket number
;       edx = pointer to the options:
;               dd      level, optname, optlen, optval
;  OUT: -1 on error
;
;-----------------------------------------------------------------
align 4
SOCKET_set_opt:
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_set_opt\n"
 
        call    SOCKET_num_to_ptr
        jz      .invalid
 
        cmp     dword [edx], SOL_SOCKET
        jne     .invalid
 
        cmp     dword [edx+4], SO_BINDTODEVICE
        je      .bind
 
  .invalid:
        mov     dword[esp+32], -1
        mov     dword[esp+20], EINVAL
        ret
 
  .bind:
        cmp     dword[edx+8], 0
        je      .unbind
 
        movzx   edx, byte[edx + 9]
        cmp     edx, NET_DEVICES_MAX
        ja      .invalid
 
        mov     edx, [NET_DRV_LIST + 4*edx]
        test    edx, edx
        jz      .already
        mov     [eax + SOCKET.device], edx
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_set_opt: Bound socket %x to device %x\n",eax, edx
 
        mov     dword[esp+32], 0        ; success!
        ret
 
  .unbind:
        mov     [eax + SOCKET.device], 0
 
        mov     dword[esp+32], 0        ; success!
        ret
 
  .already:
        mov     dword[esp+20], EALREADY
        mov     dword[esp+32], -1
        ret
 
 
 
 
;-----------------------------------------------------------------
;
; SOCKET_pair
;
; Allocates a pair of linked LOCAL domain sockets
;
; IN: /
; OUT: eax is socket1 num, -1 on error
;      ebx is socket2 num
;
;-----------------------------------------------------------------
align 4
SOCKET_pair:
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_pair\n"
 
        call    SOCKET_alloc
        test    eax, eax
        jz      .nomem1
        mov     [esp+32], edi   ; application's eax
 
        mov     [eax + SOCKET.Domain], AF_LOCAL
        mov     [eax + SOCKET.Type], SOCK_STREAM
        mov     [eax + SOCKET.Protocol], 0              ;;; CHECKME
        mov     [eax + SOCKET.snd_proc], SOCKET_send_local
        mov     [eax + SOCKET.rcv_proc], SOCKET_receive_local
        mov     [eax + SOCKET.PID], 0
        mov     ebx, eax
 
        call    SOCKET_alloc
        test    eax, eax
        jz      .nomem2
        mov     [esp+20], edi   ; application's ebx
 
        mov     [eax + SOCKET.Domain], AF_LOCAL
        mov     [eax + SOCKET.Type], SOCK_STREAM
        mov     [eax + SOCKET.Protocol], 0              ;;; CHECKME
        mov     [eax + SOCKET.snd_proc], SOCKET_send_local
        mov     [eax + SOCKET.rcv_proc], SOCKET_receive_local
        mov     [eax + SOCKET.PID], 0
 
        ; Link the two sockets to eachother
        mov     [eax + SOCKET.device], ebx
        mov     [ebx + SOCKET.device], eax
 
        lea     eax, [eax + STREAM_SOCKET.rcv]
        call    SOCKET_ring_create
        test    eax, eax
        jz      .nomem1
 
        lea     eax, [ebx + STREAM_SOCKET.rcv]
        call    SOCKET_ring_create
        test    eax, eax
        jz      .nomem2
 
        ret
 
  .nomem2:
        mov     eax, ebx
        call    SOCKET_free
  .nomem1:
        mov     dword[esp+32], -1
        mov     dword[esp+28], ENOMEM
        ret
 
 
 
;-----------------------------------------------------------------
;
; SOCKET_debug
;
;  Copies socket variables to application buffer
;
;  IN:  ecx = socket number
;       edx = pointer to buffer
;
;  OUT: -1 on error
;-----------------------------------------------------------------
align 4
SOCKET_debug:
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_debug\n"
 
        mov     edi, edx
 
        test    ecx, ecx
        jz      .returnall
 
        call    SOCKET_num_to_ptr
        jz      .invalid
 
        mov     esi, eax
        mov     ecx, SOCKETBUFFSIZE/4
        rep movsd
 
        mov     dword[esp+32], 0
        ret
 
  .returnall:
        mov     ebx, net_sockets
  .next_socket:
        mov     ebx, [ebx + SOCKET.NextPtr]
        test    ebx, ebx
        jz      .done
        mov     eax, [ebx + SOCKET.Number]
        stosd
        jmp     .next_socket
  .done:
        xor     eax, eax
        stosd
        mov     dword[esp+32], eax
        ret
 
  .invalid:
        mov     dword[esp+32], -1
        mov     dword[esp+28], EINVAL
        ret
 
 
;-----------------------------------------------------------------
;
; SOCKET_find_port
;
; Fills in the local port number for TCP and UDP sockets
; This procedure always works because the number of sockets is
; limited to a smaller number then the number of possible ports
;
;  IN:  eax = socket pointer
;  OUT: /
;
;-----------------------------------------------------------------
align 4
SOCKET_find_port:
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_find_port\n"
 
        push    ebx esi ecx
 
        cmp     [eax + SOCKET.Protocol], IP_PROTO_UDP
        je      .udp
 
        cmp     [eax + SOCKET.Protocol], IP_PROTO_TCP
        je      .tcp
 
        pop     ecx esi ebx
        ret
 
  .udp:
        mov     bx, [last_UDP_port]
        call    .findit
        mov     [last_UDP_port], bx
 
        pop     ecx esi ebx
        ret
 
  .tcp:
        mov     bx, [last_TCP_port]
        call    .findit
        mov     [last_TCP_port], bx
 
        pop     ecx esi ebx
        ret
 
 
  .restart:
        mov     bx, MIN_EPHEMERAL_PORT_N
  .findit:
        cmp     bx, MAX_EPHEMERAL_PORT_N
        je      .restart
 
        add     bh, 1
        adc     bl, 0
 
        call    SOCKET_check_port
        jz      .findit
        ret
 
 
 
;-----------------------------------------------------------------
;
; SOCKET_check_port (to be used with AF_INET only!)
;
; Checks if a local port number is unused
; If the proposed port number is unused, it is filled in in the socket structure
;
;  IN:  eax = socket ptr (to find out if its a TCP/UDP socket)
;        bx = proposed socket number (network byte order)
;
;  OUT:  ZF = set on error
;
;-----------------------------------------------------------------
align 4
SOCKET_check_port:
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_check_port: "
 
        pusha
        mov     ecx, socket_mutex
        call    mutex_lock
        popa
 
        mov     ecx, [eax + SOCKET.Protocol]
        mov     edx, [eax + IP_SOCKET.LocalIP]
        mov     esi, net_sockets
 
  .next_socket:
        mov     esi, [esi + SOCKET.NextPtr]
        or      esi, esi
        jz      .port_ok
 
        cmp     [esi + SOCKET.Protocol], ecx
        jne     .next_socket
 
        cmp     [esi + IP_SOCKET.LocalIP], edx
        jne     .next_socket
 
        cmp     [esi + UDP_SOCKET.LocalPort], bx
        jne     .next_socket
 
        pusha
        mov     ecx, socket_mutex
        call    mutex_unlock
        popa
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "local port %x already in use\n", bx  ; FIXME: find a way to print big endian values with debugf
        ret
 
  .port_ok:
        pusha
        mov     ecx, socket_mutex
        call    mutex_unlock
        popa
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "local port %x is free\n", bx         ; FIXME: find a way to print big endian values with debugf
        mov     [eax + UDP_SOCKET.LocalPort], bx
        or      bx, bx                                  ; clear the zero-flag
        ret
 
 
 
;-----------------------------------------------------------------
;
; SOCKET_input
;
; Updates a (stateless) socket with received data
;
; Note: the mutex should already be set !
;
;  IN:  eax = socket ptr
;       ecx = data size
;       esi = ptr to data
;       [esp] = ptr to buf
;       [esp + 4] = buf size
;
;  OUT: /
;
;-----------------------------------------------------------------
align 4
SOCKET_input:
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_input: socket=%x, data=%x size=%u\n", eax, esi, ecx
 
        mov     [esp+4], ecx
        push    esi
        mov     esi, esp
 
        add_to_queue (eax + SOCKET_QUEUE_LOCATION), SOCKET_QUEUE_SIZE, sizeof.socket_queue_entry, SOCKET_input.full
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_input: success\n"
        add     esp, sizeof.socket_queue_entry
 
        pusha
        lea     ecx, [eax + SOCKET.mutex]
        call    mutex_unlock
        popa
 
        jmp     SOCKET_notify
 
  .full:
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_input: socket %x is full!\n", eax
 
        pusha
        lea     ecx, [eax + SOCKET.mutex]
        call    mutex_unlock
        popa
 
        call    NET_packet_free
        add     esp, 8
 
        ret
 
 
;--------------------------
;
; IN: eax = ptr to ring struct (just a buffer of the right size)
; OUT: eax = unchanged / 0 on error
;
align 4
SOCKET_ring_create:
 
        push    esi
        mov     esi, eax
 
        push    edx
        stdcall create_ring_buffer, SOCKET_MAXDATA, PG_SW
        pop     edx
        test    eax, eax
        jz      .fail
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_ring_created: %x\n", eax
 
        pusha
        lea     ecx, [esi + RING_BUFFER.mutex]
        call    mutex_init
        popa
 
        mov     [esi + RING_BUFFER.start_ptr], eax
        mov     [esi + RING_BUFFER.write_ptr], eax
        mov     [esi + RING_BUFFER.read_ptr], eax
        mov     [esi + RING_BUFFER.size], 0
        add     eax, SOCKET_MAXDATA
        mov     [esi + RING_BUFFER.end_ptr], eax
        mov     eax, esi
        pop     esi
 
  .fail:
        ret
 
;-----------------------------------------------------------------
;
; SOCKET_ring_write
;
; Adds data to a stream socket, and updates write pointer and size
;
;  IN:  eax = ptr to ring struct
;       ecx = data size
;       esi = ptr to data
;
;  OUT: ecx = number of bytes stored
;
;-----------------------------------------------------------------
align 4
SOCKET_ring_write:
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_ring_write: ringbuff=%x ptr=%x size=%u\n", eax, esi, ecx
 
; lock mutex
        pusha
        lea     ecx, [eax + RING_BUFFER.mutex]
        call    mutex_lock                                      ; TODO: check what registers this function actually destroys
        popa
 
; calculate available size
        mov     edi, SOCKET_MAXDATA
        sub     edi, [eax + RING_BUFFER.size]                   ; available buffer size in edi
        cmp     ecx, edi
        jbe     .copy
        mov     ecx, edi
  .copy:
        mov     edi, [eax + RING_BUFFER.write_ptr]
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_ring_write: %u bytes from %x to %x\n", ecx, esi, edi
 
; update write ptr
        push    edi
        add     edi, ecx
        cmp     edi, [eax + RING_BUFFER.end_ptr]
        jb      @f
        sub     edi, SOCKET_MAXDATA                             ; WRAP
  @@:
 
        mov     [eax + RING_BUFFER.write_ptr], edi
        pop     edi
 
; update size
        add     [eax + RING_BUFFER.size], ecx
 
; copy the data
        push    ecx
        shr     ecx, 1
        jnc     .nb
        movsb
  .nb:
        shr     ecx, 1
        jnc     .nw
        movsw
  .nw:
        test    ecx, ecx
        jz      .nd
        rep movsd
  .nd:
        pop     ecx
 
; unlock mutex
        pusha
        lea     ecx, [eax + RING_BUFFER.mutex]
        call    mutex_unlock                                    ; TODO: check what registers this function actually destroys
        popa
 
        ret
 
;-----------------------------------------------------------------
;
; SOCKET_ring_read
;
;  IN:  eax = ring struct ptr
;       ecx = bytes to read
;       edx = offset
;       edi = ptr to buffer start
;
;  OUT: eax = unchanged
;       ecx = number of bytes read (0 on error)
;       edx = destroyed
;       esi = destroyed
;       edi = ptr to buffer end
;
;-----------------------------------------------------------------
align 4
SOCKET_ring_read:
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_ring_read: ringbuff=%x ptr=%x size=%u offset=%x\n", eax, edi, ecx, edx
 
        pusha
        lea     ecx, [eax + RING_BUFFER.mutex]
        call    mutex_lock                                      ; TODO: check what registers this function actually destroys
        popa
 
        mov     esi, [eax + RING_BUFFER.read_ptr]
        add     esi, edx                                        ; esi = start_ptr + offset
 
        neg     edx
        add     edx, [eax + RING_BUFFER.size]                   ; edx = snd.size - offset
        jle     .no_data_at_all
 
        pusha
        lea     ecx, [eax + RING_BUFFER.mutex]
        call    mutex_unlock                                    ; TODO: check what registers this function actually destroys
        popa
 
        cmp     ecx, edx
        ja      .less_data
 
  .copy:
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_ring_read: %u bytes from %x to %x\n", ecx, esi, edi
        push    ecx
        shr     ecx, 1
        jnc     .nb
        movsb
  .nb:
        shr     ecx, 1
        jnc     .nw
        movsw
  .nw:
        test    ecx, ecx
        jz      .nd
        rep movsd
  .nd:
        pop     ecx
        ret
 
  .no_data_at_all:
        pusha
        lea     ecx, [eax + RING_BUFFER.mutex]
        call    mutex_unlock                                    ; TODO: check what registers this function actually destroys
        popa
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_ring_read: no data at all!\n"
        xor     ecx, ecx
        ret
 
  .less_data:
        mov     ecx, edx
        jmp     .copy
 
 
;-----------------------------------------------------------------
;
; SOCKET_ring_free
;
; Free's some bytes from the ringbuffer
;
;  IN:  eax = ptr to ring struct
;       ecx = data size
;
;  OUT: ecx = number of bytes free-ed
;
;-----------------------------------------------------------------
align 4
SOCKET_ring_free:
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_ring_free: %u bytes from ring %x\n", ecx, eax
 
        push    eax ecx
        lea     ecx, [eax + RING_BUFFER.mutex]
        call    mutex_lock                                      ; TODO: check what registers this function actually destroys
        pop     ecx eax
 
        sub     [eax + RING_BUFFER.size], ecx
        jb      .error
        add     [eax + RING_BUFFER.read_ptr], ecx
 
        mov     edx, [eax + RING_BUFFER.end_ptr]
        cmp     [eax + RING_BUFFER.read_ptr], edx
        jb      @f
        sub     [eax + RING_BUFFER.read_ptr], SOCKET_MAXDATA
       @@:
 
        push    eax ecx
        lea     ecx, [eax + RING_BUFFER.mutex]                  ; TODO: check what registers this function actually destroys
        call    mutex_unlock
        pop     ecx eax
 
        ret
 
  .error:       ; we could free all available bytes, but that would be stupid, i guess..
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_ring_free: buffer=%x error!\n", eax
        add     [eax + RING_BUFFER.size], ecx
 
        push    eax
        lea     ecx, [eax + RING_BUFFER.mutex]
        call    mutex_unlock                                    ; TODO: check what registers this function actually destroys
        pop     eax
 
        xor     ecx, ecx
        ret
 
 
;-----------------------------------------------------------------
;
; SOCKET_block
;
; Suspends the thread attached to a socket
;
;  IN:  eax = socket ptr
;  OUT: eax = unchanged
;
;-----------------------------------------------------------------
align 4
SOCKET_block:
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_block: %x\n", eax
 
 
        push    eax
 
        pushf
        cli
 
        ; Set the 'socket is blocked' flag
        or      [eax + SOCKET.state], SS_BLOCKED
 
        ; Suspend the thread
        push    edx
        mov     edx, [TASK_BASE]
        mov     [edx + TASKDATA.state], 1               ; Suspended
 
        ; Remember the thread ID so we can wake it up again
        mov     edx, [edx + TASKDATA.pid]
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_block: suspending thread: %u\n", edx
        mov     [eax + SOCKET.TID], edx
        pop     edx
        popf
 
        call    change_task
        pop     eax
 
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_block: continuing\n"
 
        ret
 
 
;-----------------------------------------------------------------
;
; SOCKET_notify
;
; notify's the owner of a socket that something happened
;
;  IN:  eax = socket ptr
;  OUT: eax = unchanged
;
;-----------------------------------------------------------------
align 4
SOCKET_notify:
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_notify: %x\n", eax
 
        call    SOCKET_check
        jz      .error
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
; Find the associated thread's TASK_DATA
 
 
 
 
        push    ebx ecx esi
        mov     ebx, [eax + SOCKET.TID]
        test    ebx, ebx
        jz      .error2
        xor     ecx, ecx
        inc     ecx
        mov     esi, TASK_DATA
  .next:
        cmp     [esi + TASKDATA.pid], ebx
        je      .found
        inc     ecx
        add     esi, 0x20
        cmp     ecx, [TASK_COUNT]
        jbe     .next
 
  .error2:
; PID not found, TODO: close socket!
        DEBUGF  DEBUG_NETWORK_ERROR, "SOCKET_notify: error finding thread 0x%x !\n", ebx
        pop     esi ecx ebx
        ret
 
  .error:
        DEBUGF  DEBUG_NETWORK_ERROR, "SOCKET_notify: invalid socket ptr: 0x%x !\n", eax
        ret
 
  .found:
        test    [eax + SOCKET.state], SS_BLOCKED
        jnz     .un_block
 
; socket and thread exists and socket is of non blocking type.
; We'll try to flag an event to the thread.
        shl     ecx, 8
 
        or      [ecx + SLOT_BASE + APPDATA.event_mask], EVENT_NETWORK
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_notify: poking thread %u!\n", eax
        pop     esi ecx ebx
        ret
 
 
  .un_block:
; socket and thread exists and socket is of blocking type
; We'll try to unblock it.
        and     [eax + SOCKET.state], not SS_BLOCKED    ; Clear the 'socket is blocked' flag
        mov     [esi + TASKDATA.state], 0               ; Run the thread
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_notify: Unblocked socket!\n"
        pop     esi ecx ebx
        ret
 
 
;--------------------------------------------------------------------
;
; SOCKET_alloc
;
; Allocate memory for socket data and put new socket into the list
; Newly created socket is initialized with calling PID and number and
; put into beginning of list (which is a fastest way).
;
; IN:  /
; OUT: eax = 0 on error, socket ptr otherwise
;      edi = socket number
 
;
;--------------------------------------------------------------------
align 4
SOCKET_alloc:
 
        push    ebx
 
        stdcall kernel_alloc, SOCKETBUFFSIZE
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_alloc: ptr=%x\n", eax
        or      eax, eax
        jz      .exit
 
; zero-initialize allocated memory
        push    eax
        mov     edi, eax
        mov     ecx, SOCKETBUFFSIZE / 4
        xor     eax, eax
        rep stosd
        pop     eax
 
; set send-and receive procedures to return -1
        mov     [eax + SOCKET.snd_proc], .not_yet
        mov     [eax + SOCKET.rcv_proc], .not_yet
 
        pusha
        mov     ecx, socket_mutex
        call    mutex_lock
        popa
 
; find first free socket number and use it
        mov     edi, [last_socket_num]
  .next_socket_number:
        inc     edi
        jz      .next_socket_number     ; avoid socket nr 0
        cmp     edi, -1
        je      .next_socket_number     ; avoid socket nr -1
        mov     ebx, net_sockets
  .next_socket:
        mov     ebx, [ebx + SOCKET.NextPtr]
        test    ebx, ebx
        jz      .last_socket
 
        cmp     [ebx + SOCKET.Number], edi
        jne     .next_socket
        jmp     .next_socket_number
 
  .last_socket:
        mov     [last_socket_num], edi
        mov     [eax + SOCKET.Number], edi
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_alloc: number=%u\n", edi
 
; Fill in PID
        mov     ebx, [TASK_BASE]
        mov     ebx, [ebx + TASKDATA.pid]
        mov     [eax + SOCKET.PID], ebx
        mov     [eax + SOCKET.TID], ebx         ; currently TID = PID in kolibrios :(
 
; init mutex
        pusha
        lea     ecx, [eax + SOCKET.mutex]
        call    mutex_init
        popa
 
; add socket to the list by re-arranging some pointers
        mov     ebx, [net_sockets + SOCKET.NextPtr]
 
        mov     [eax + SOCKET.PrevPtr], net_sockets
        mov     [eax + SOCKET.NextPtr], ebx
 
        test    ebx, ebx
        jz      @f
 
        pusha
        lea     ecx, [ebx + SOCKET.mutex]
        call    mutex_lock
        popa
 
        mov     [ebx + SOCKET.PrevPtr], eax
 
        pusha
        lea     ecx, [ebx + SOCKET.mutex]
        call    mutex_unlock
        popa
       @@:
 
        mov     [net_sockets + SOCKET.NextPtr], eax
 
 
        pusha
        mov     ecx, socket_mutex
        call    mutex_unlock
        popa
 
  .exit:
        pop     ebx
 
        ret
 
  .not_yet:
        mov     dword[esp+20], ENOTCONN
        mov     dword[esp+32], -1
        ret
 
 
;----------------------------------------------------
;
; SOCKET_free
;
; Free socket data memory and remove socket from the list
; Caller should lock and unlock socket_mutex
;
; IN:  eax = socket ptr
; OUT: /
;
;----------------------------------------------------
align 4
SOCKET_free:
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_free: %x\n", eax
 
        call    SOCKET_check
        jz      .error
 
        push    ebx
 
        pusha
        lea     ecx, [eax + SOCKET.mutex]
        call    mutex_lock
        popa
 
        cmp     [eax + SOCKET.Domain], AF_INET4
        jnz     .no_tcp
 
        cmp     [eax + SOCKET.Protocol], IP_PROTO_TCP
        jnz     .no_tcp
 
        mov     ebx, eax
        cmp     [ebx + STREAM_SOCKET.rcv.start_ptr], 0
        je      @f
        stdcall kernel_free, [ebx + STREAM_SOCKET.rcv.start_ptr]
  @@:
        cmp     [ebx + STREAM_SOCKET.snd.start_ptr], 0
        je      @f
        stdcall kernel_free, [ebx + STREAM_SOCKET.snd.start_ptr]
  @@:
        mov     eax, ebx
  .no_tcp:
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_free: freeing socket %x\n", eax
        push    eax                             ; this will be passed to kernel_free
        mov     ebx, [eax + SOCKET.NextPtr]
        mov     eax, [eax + SOCKET.PrevPtr]
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_free: linking socket %x to socket %x\n", eax, ebx
 
        test    eax, eax
        jz      @f
        mov     [eax + SOCKET.NextPtr], ebx
       @@:
 
        test    ebx, ebx
        jz      @f
        mov     [ebx + SOCKET.PrevPtr], eax
       @@:
 
        call    kernel_free
        pop     ebx
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_free: success!\n"
 
  .error:
        ret
 
;------------------------------------
;
; SOCKET_fork
;
; Create a child socket
;
; IN:  socket nr in ebx
; OUT: child socket nr in eax
;
;-----------------------------------
align 4
SOCKET_fork:
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_fork: %x\n", ebx
 
; Exit if backlog queue is full
        mov     eax, [ebx + SOCKET_QUEUE_LOCATION + queue.size]
        cmp     ax, [ebx + SOCKET.backlog]
        jae     .fail
 
; Allocate new socket
        push    ebx
        call    SOCKET_alloc
        pop     ebx
        test    eax, eax
        jz      .fail
 
        push    eax
        mov     esi, esp
        add_to_queue (ebx + SOCKET_QUEUE_LOCATION), MAX_backlog, 4, .fail2
        pop     eax
 
; Copy structure from current socket to new
; We start at PID to preserve the socket num, 2 pointers and mutex
; TID will be filled in later
        lea     esi, [ebx + SOCKET.PID]
        lea     edi, [eax + SOCKET.PID]
        mov     ecx, (SOCKET_QUEUE_LOCATION - SOCKET.PID + 3)/4
        rep movsd
 
        and     [eax + SOCKET.options], not SO_ACCEPTCON
 
; Notify owner of parent socket
        push    eax
        mov     eax, ebx
        call    SOCKET_notify
        pop     eax
 
        ret
 
  .fail2:
        add     esp, 4+4+4
  .fail:
        DEBUGF  DEBUG_NETWORK_ERROR, "SOCKET_fork: failed\n"
        xor     eax, eax
        ret
 
 
;---------------------------------------------------
;
; SOCKET_num_to_ptr
;
; Get socket structure address by its number
;
; IN:  ecx = socket number
; OUT: eax = 0 on error, socket ptr otherwise
;       ZF = set on error
;
;---------------------------------------------------
align 4
SOCKET_num_to_ptr:
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_num_to_ptr: num=%u ", ecx
 
        pusha
        mov     ecx, socket_mutex
        call    mutex_lock
        popa
 
        mov     eax, net_sockets
 
  .next_socket:
        mov     eax, [eax + SOCKET.NextPtr]
        or      eax, eax
        jz      .error
        cmp     [eax + SOCKET.Number], ecx
        jne     .next_socket
 
        test    eax, eax
 
        pusha
        mov     ecx, socket_mutex
        call    mutex_unlock
        popa
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "ptr=%x\n", eax
        ret
 
  .error:
        pusha
        mov     ecx, socket_mutex
        call    mutex_unlock
        popa
 
        DEBUGF  DEBUG_NETWORK_ERROR, "SOCKET_num_to_ptr: socket %u not found!\n", eax
        DEBUGF  DEBUG_NETWORK_ERROR, "SOCKET_num_to_ptr: caller = 0x%x\n", [esp]
        ret
 
 
;---------------------------------------------------
;
; SOCKET_ptr_to_num
;
; Get socket number by its address
;
; IN:  eax = socket ptr
; OUT: eax = 0 on error, socket num otherwise
;       ZF = set on error
;
;---------------------------------------------------
align 4
SOCKET_ptr_to_num:
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_ptr_to_num: ptr=%x ", eax
 
        call    SOCKET_check
        jz      .error
 
        mov     eax, [eax + SOCKET.Number]
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "num=%u\n", eax
        ret
 
  .error:
        DEBUGF  DEBUG_NETWORK_ERROR, "SOCKET_ptr_to_num: not found\n", eax
        ret
 
 
;---------------------------------------------------
;
; SOCKET_check
;
; checks if the given value is really a socket ptr
;
; IN:  eax = socket ptr
; OUT: eax = 0 on error, unchanged otherwise
;       ZF = set on error
;
;---------------------------------------------------
align 4
SOCKET_check:
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_check: %x\n", eax
 
        push    ebx
        mov     ebx, net_sockets
 
  .next_socket:
        mov     ebx, [ebx + SOCKET.NextPtr]
        or      ebx, ebx
        jz      .done
        cmp     ebx, eax
        jnz     .next_socket
 
  .done:
        mov     eax, ebx
        test    eax, eax
        pop     ebx
 
        ret
 
 
 
;---------------------------------------------------
;
; SOCKET_check_owner
;
; checks if the caller application owns the socket
;
; IN:  eax = socket ptr
; OUT:  ZF = true/false
;
;---------------------------------------------------
align 4
SOCKET_check_owner:
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_check_owner: %x\n", eax
 
        push    ebx
        mov     ebx, [TASK_BASE]
        mov     ebx, [ebx + TASKDATA.pid]
        cmp     [eax + SOCKET.PID], ebx
        pop     ebx
 
        ret
 
 
 
 
;------------------------------------------------------
;
; SOCKET_process_end
;
; Kernel calls this function when a certain process ends
; This function will check if the process had any open sockets
; And update them accordingly (clean up)
;
; IN:  edx = pid
; OUT: /
;
;------------------------------------------------------
align 4
SOCKET_process_end:
 
        ret     ; FIXME
 
        cmp     [net_sockets + SOCKET.NextPtr], 0       ; Are there any active sockets at all?
        je      .quickret                               ; nope, exit immediately
 
; TODO: run the following code in another thread, to avoid deadlock
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_process_end: %x\n", edx
 
        pusha
        mov     ecx, socket_mutex
        call    mutex_lock
        popa
 
        push    ebx
        mov     ebx, net_sockets
 
  .next_socket:
        mov     ebx, [ebx + SOCKET.NextPtr]
  .next_socket_test:
        test    ebx, ebx
        jz      .done
 
        cmp     [ebx + SOCKET.PID], edx
        jne     .next_socket
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_process_end: killing socket %x\n", ebx
 
        mov     [ebx + SOCKET.PID], 0
        mov     eax, ebx
        mov     ebx, [ebx + SOCKET.NextPtr]
 
        pusha
        cmp     [eax + SOCKET.Domain], AF_INET4
        jne     .free
 
        cmp     [eax + SOCKET.Protocol], IP_PROTO_TCP
        jne     .free
 
        call    TCP_disconnect
        jmp     .closed
 
  .free:
        call    SOCKET_free
 
  .closed:
        popa
        jmp     .next_socket_test
 
  .done:
        pop     ebx
 
        pusha
        mov     ecx, socket_mutex
        call    mutex_unlock
        popa
 
  .quickret:
        ret
 
 
 
 
;-----------------------------------------------------------------
;
; SOCKET_is_connecting
;
;  IN:  eax = socket ptr
;  OUT: /
;
;-----------------------------------------------------------------
 
align 4
SOCKET_is_connecting:
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_is_connecting: %x\n", eax
 
        and     [eax + SOCKET.state], not (SS_ISCONNECTED + SS_ISDISCONNECTING + SS_ISCONFIRMING)
        or      [eax + SOCKET.state], SS_ISCONNECTING
 
        ret
 
 
 
;-----------------------------------------------------------------
;
; SOCKET_is_connected
;
;  IN:  eax = socket ptr
;  OUT: /
;
;-----------------------------------------------------------------
 
align 4
SOCKET_is_connected:
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_is_connected: %x\n", eax
 
        and     [eax + SOCKET.state], not (SS_ISCONNECTING + SS_ISDISCONNECTING + SS_ISCONFIRMING)
        or      [eax + SOCKET.state], SS_ISCONNECTED
 
        jmp     SOCKET_notify
 
 
 
 
;-----------------------------------------------------------------
;
; SOCKET_is_disconnecting
;
;  IN:  eax = socket ptr
;  OUT: /
;
;-----------------------------------------------------------------
 
align 4
SOCKET_is_disconnecting:
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_is_disconnecting: %x\n", eax
 
        and     [eax + SOCKET.state], not (SS_ISCONNECTING)
        or      [eax + SOCKET.state], SS_ISDISCONNECTING + SS_CANTRCVMORE + SS_CANTSENDMORE
 
        jmp     SOCKET_notify
 
 
 
;-----------------------------------------------------------------
;
; SOCKET_is_disconnected
;
;  IN:  eax = socket ptr
;  OUT: /
;
;-----------------------------------------------------------------
 
align 4
SOCKET_is_disconnected:
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_is_disconnected: %x\n", eax
 
        and     [eax + SOCKET.state], not (SS_ISCONNECTING + SS_ISCONNECTED + SS_ISDISCONNECTING)
        or      [eax + SOCKET.state], SS_CANTRCVMORE + SS_CANTSENDMORE
 
 
        jmp     SOCKET_notify
 
 
 
;-----------------------------------------------------------------
;
; SOCKET_cant_recv_more
;
;  IN:  eax = socket ptr
;  OUT: /
;
;-----------------------------------------------------------------
 
align 4
SOCKET_cant_recv_more:
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_cant_recv_more: %x\n", eax
 
        or      [eax + SOCKET.state], SS_CANTRCVMORE
 
        call    SOCKET_notify
 
        ret
 
 
 
;-----------------------------------------------------------------
;
; SOCKET_cant_send_more
;
;  IN:  eax = socket ptr
;  OUT: /
;
;-----------------------------------------------------------------
 
align 4
SOCKET_cant_send_more:
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "SOCKET_cant_send_more: %x\n", eax
 
        or      [eax + SOCKET.state], SS_CANTSENDMORE
        mov     [eax + SOCKET.snd_proc], .notconn
 
        call    SOCKET_notify
 
        ret
 
  .notconn:
        mov     dword[esp+20], ENOTCONN
        mov     dword[esp+32], -1
        ret

Rev 4423	Rev 5201
1	;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;	1	;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2	;; ;;	2	;; ;;
3	;; Copyright (C) KolibriOS team 2004-2013. All rights reserved. ;;	3	;; Copyright (C) KolibriOS team 2004-2014. All rights reserved. ;;
4	;; Distributed under terms of the GNU General Public License ;;	4	;; Distributed under terms of the GNU General Public License ;;
5	;; ;;	5	;; ;;
6	;; Part of the TCP/IP network stack for KolibriOS ;;	6	;; Part of the TCP/IP network stack for KolibriOS ;;
7	;; ;;	7	;; ;;
8	;; Written by hidnplayr@kolibrios.org, ;;	8	;; Written by hidnplayr@kolibrios.org, ;;
9	;; and Clevermouse. ;;	9	;; and Clevermouse. ;;
10	;; ;;	10	;; ;;
11	;; Based on code by mike.dld ;;	11	;; Based on code by mike.dld ;;
12	;; ;;	12	;; ;;
13	;; GNU GENERAL PUBLIC LICENSE ;;	13	;; GNU GENERAL PUBLIC LICENSE ;;
14	;; Version 2, June 1991 ;;	14	;; Version 2, June 1991 ;;
15	;; ;;	15	;; ;;
16	;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;	16	;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
17		17
18	$Revision: 4423 $	18	$Revision: 5201 $
19		19
20	struct SOCKET	20	struct SOCKET
21		21
22	NextPtr dd ? ; pointer to next socket in list	22	NextPtr dd ? ; pointer to next socket in list
23	PrevPtr dd ? ; pointer to previous socket in list	23	PrevPtr dd ? ; pointer to previous socket in list
24	Number dd ? ; socket number	24	Number dd ? ; socket number
25		25
26	mutex MUTEX	26	mutex MUTEX
27		27
28	PID dd ? ; process ID	28	PID dd ? ; process ID
29	TID dd ? ; thread ID	29	TID dd ? ; thread ID
30	Domain dd ? ; INET/LOCAL/..	30	Domain dd ? ; INET/LOCAL/..
31	Type dd ? ; RAW/STREAM/DGRAM	31	Type dd ? ; RAW/STREAM/DGRAM
32	Protocol dd ? ; ICMP/IPv4/ARP/TCP/UDP	32	Protocol dd ? ; ICMP/IPv4/ARP/TCP/UDP
33	errorcode dd ?	33	errorcode dd ?
34	device dd ? ; driver pointer, socket pointer if it's an LOCAL socket	34	device dd ? ; driver pointer, socket pointer if it's an LOCAL socket
35		35
36	options dd ?	36	options dd ?
37	state dd ?	37	state dd ?
38	backlog dw ? ; how many incoming connections that can be queued	38	backlog dw ? ; how many incoming connections that can be queued
39		39
40	snd_proc dd ?	40	snd_proc dd ?
41	rcv_proc dd ?	41	rcv_proc dd ?
42	connect_proc dd ?	42	connect_proc dd ?
43		43
44	ends	44	ends
45		45
46	struct IP_SOCKET SOCKET	46	struct IP_SOCKET SOCKET
47		47
48	LocalIP rd 4 ; network byte order	48	LocalIP rd 4 ; network byte order
49	RemoteIP rd 4 ; network byte order	49	RemoteIP rd 4 ; network byte order
50		50
51	ends	51	ends
52		52
53	struct TCP_SOCKET IP_SOCKET	53	struct TCP_SOCKET IP_SOCKET
54		54
55	LocalPort dw ? ; network byte order	55	LocalPort dw ? ; network byte order
56	RemotePort dw ? ; network byte order	56	RemotePort dw ? ; network byte order
57		57
58	t_state dd ? ; TCB state	58	t_state dd ? ; TCB state
59	t_rxtshift db ?	59	t_rxtshift db ?
60	rb 3 ; align	60	rb 3 ; align
61	t_rxtcur dd ?	61	t_rxtcur dd ?
62	t_dupacks dd ?	62	t_dupacks dd ?
63	t_maxseg dd ?	63	t_maxseg dd ?
64	t_force dd ?	64	t_force dd ?
65	t_flags dd ?	65	t_flags dd ?
66		66
67	;---------------	67	;---------------
68	; RFC783 page 21	68	; RFC783 page 21
69		69
70	; send sequence	70	; send sequence
71	SND_UNA dd ? ; sequence number of unack'ed sent Packets	71	SND_UNA dd ? ; sequence number of unack'ed sent Packets
72	SND_NXT dd ? ; next send sequence number to use	72	SND_NXT dd ? ; next send sequence number to use
73	SND_UP dd ? ; urgent pointer	73	SND_UP dd ? ; urgent pointer
74	SND_WL1 dd ? ; window minus one	74	SND_WL1 dd ? ; window minus one
75	SND_WL2 dd ? ;	75	SND_WL2 dd ? ;
76	ISS dd ? ; initial send sequence number	76	ISS dd ? ; initial send sequence number
77	SND_WND dd ? ; send window	77	SND_WND dd ? ; send window
78		78
79	; receive sequence	79	; receive sequence
80	RCV_WND dd ? ; receive window	80	RCV_WND dd ? ; receive window
81	RCV_NXT dd ? ; next receive sequence number to use	81	RCV_NXT dd ? ; next receive sequence number to use
82	RCV_UP dd ? ; urgent pointer	82	RCV_UP dd ? ; urgent pointer
83	IRS dd ? ; initial receive sequence number	83	IRS dd ? ; initial receive sequence number
84		84
85	;---------------------	85	;---------------------
86	; Additional variables	86	; Additional variables
87		87
88	; receive variables	88	; receive variables
89	RCV_ADV dd ?	89	RCV_ADV dd ?
90		90
91	; retransmit variables	91	; retransmit variables
92	SND_MAX dd ?	92	SND_MAX dd ?
93		93
94	; congestion control	94	; congestion control
95	SND_CWND dd ? ; congestion window	95	SND_CWND dd ? ; congestion window
96	SND_SSTHRESH dd ? ; slow start threshold	96	SND_SSTHRESH dd ? ; slow start threshold
97		97
98	;----------------------	98	;----------------------
99	; Transmit timing stuff	99	; Transmit timing stuff
100	t_idle dd ?	100	t_idle dd ?
101	t_rtt dd ?	101	t_rtt dd ?
102	t_rtseq dd ?	102	t_rtseq dd ?
103	t_srtt dd ?	103	t_srtt dd ?
104	t_rttvar dd ?	104	t_rttvar dd ?
105	t_rttmin dd ?	105	t_rttmin dd ?
106	max_sndwnd dd ?	106	max_sndwnd dd ?
107		107
108	;-----------------	108	;-----------------
109	; Out-of-band data	109	; Out-of-band data
110	t_oobflags dd ?	110	t_oobflags dd ?
111	t_iobc dd ?	111	t_iobc dd ?
112	t_softerror dd ?	112	t_softerror dd ?
113		113
114		114
115	;---------	115	;---------
116	; RFC 1323 ; the order of next 4 elements may not change	116	; RFC 1323 ; the order of next 4 elements may not change
117		117
118	SND_SCALE db ?	118	SND_SCALE db ?
119	RCV_SCALE db ?	119	RCV_SCALE db ?
120	requested_s_scale db ?	120	requested_s_scale db ?
121	request_r_scale db ?	121	request_r_scale db ?
122		122
123	ts_recent dd ? ; a copy of the most-recent valid timestamp from the other end	123	ts_recent dd ? ; a copy of the most-recent valid timestamp from the other end
124	ts_recent_age dd ?	124	ts_recent_age dd ?
125	last_ack_sent dd ?	125	last_ack_sent dd ?
126		126
127		127
128	;-------	128	;-------
129	; Timers	129	; Timers
130	timer_flags dd ?	130	timer_flags dd ?
131	timer_retransmission dd ? ; rexmt	131	timer_retransmission dd ? ; rexmt
132	timer_persist dd ?	132	timer_persist dd ?
133	timer_keepalive dd ? ; keepalive/syn timeout	133	timer_keepalive dd ? ; keepalive/syn timeout
134	timer_timed_wait dd ? ; also used as 2msl timer	134	timer_timed_wait dd ? ; also used as 2msl timer
135	timer_connect dd ?	135	timer_connect dd ?
136		136
137	; extra	137	; extra
138		138
139	ts_ecr dd ? ; timestamp echo reply	139	ts_ecr dd ? ; timestamp echo reply
140	ts_val dd ?	140	ts_val dd ?
141		141
142	seg_next dd ? ; re-assembly queue	142	seg_next dd ? ; re-assembly queue
143		143
144	ends	144	ends
145		145
146	struct UDP_SOCKET IP_SOCKET	146	struct UDP_SOCKET IP_SOCKET
147		147
148	LocalPort dw ? ; network byte order	148	LocalPort dw ? ; network byte order
149	RemotePort dw ? ; network byte order	149	RemotePort dw ? ; network byte order
150		150
151	ends	151	ends
152		152
153		153
154	struct ICMP_SOCKET IP_SOCKET	154	struct ICMP_SOCKET IP_SOCKET
155		155
156	Identifier dw ?	156	Identifier dw ?
157		157
158	ends	158	ends
159		159
160		160
161	struct RING_BUFFER	161	struct RING_BUFFER
162		162
163	mutex MUTEX	163	mutex MUTEX
164	start_ptr dd ? ; Pointer to start of buffer	164	start_ptr dd ? ; Pointer to start of buffer
165	end_ptr dd ? ; pointer to end of buffer	165	end_ptr dd ? ; pointer to end of buffer
166	read_ptr dd ? ; Read pointer	166	read_ptr dd ? ; Read pointer
167	write_ptr dd ? ; Write pointer	167	write_ptr dd ? ; Write pointer
168	size dd ? ; Number of bytes buffered	168	size dd ? ; Number of bytes buffered
169		169
170	ends	170	ends
171		171
172	struct STREAM_SOCKET TCP_SOCKET	172	struct STREAM_SOCKET TCP_SOCKET
173		173
174	rcv RING_BUFFER	174	rcv RING_BUFFER
175	snd RING_BUFFER	175	snd RING_BUFFER
176		176
177	ends	177	ends
178		178
179	struct socket_queue_entry	179	struct socket_queue_entry
180		180
181	data_ptr dd ?	181	data_ptr dd ?
182	buf_ptr dd ?	182	buf_ptr dd ?
183	data_size dd ?	183	data_size dd ?
184		184
185	ends	185	ends
186		186
187		187
188	SOCKETBUFFSIZE = 4096 ; in bytes	188	SOCKETBUFFSIZE = 4096 ; in bytes
189		189
190	SOCKET_QUEUE_SIZE = 10 ; maximum number of incoming packets queued for 1 socket	190	SOCKET_QUEUE_SIZE = 10 ; maximum number of incoming packets queued for 1 socket
191	; the incoming packet queue for sockets is placed in the socket struct itself, at this location from start	191	; the incoming packet queue for sockets is placed in the socket struct itself, at this location from start
192	SOCKET_QUEUE_LOCATION = (SOCKETBUFFSIZE - SOCKET_QUEUE_SIZE*sizeof.socket_queue_entry - sizeof.queue)	192	SOCKET_QUEUE_LOCATION = (SOCKETBUFFSIZE - SOCKET_QUEUE_SIZE*sizeof.socket_queue_entry - sizeof.queue)
193		193
194	uglobal	194	uglobal
195	align 4	195	align 4
196		196
197	net_sockets rd 4	197	net_sockets rd 4
198	last_socket_num dd ?	198	last_socket_num dd ?
199	last_UDP_port dw ? ; These values give the number of the last used ephemeral port	199	last_UDP_port dw ? ; These values give the number of the last used ephemeral port
200	last_TCP_port dw ? ;	200	last_TCP_port dw ? ;
201	socket_mutex MUTEX	201	socket_mutex MUTEX
202		202
203	endg	203	endg
204		204
205		205
206	;-----------------------------------------------------------------	206	;-----------------------------------------------------------------
207	;	207	;
208	; SOCKET_init	208	; SOCKET_init
209	;	209	;
210	;-----------------------------------------------------------------	210	;-----------------------------------------------------------------
211	macro SOCKET_init {	211	macro SOCKET_init {
212		212
213	xor eax, eax	213	xor eax, eax
214	mov edi, net_sockets	214	mov edi, net_sockets
215	mov ecx, 5	215	mov ecx, 5
216	rep stosd	216	rep stosd
217		217
218	@@:	218	@@:
219	pseudo_random eax	219	pseudo_random eax
220	cmp ax, EPHEMERAL_PORT_MIN	220	cmp ax, EPHEMERAL_PORT_MIN
221	jb @r	221	jb @r
222	cmp ax, EPHEMERAL_PORT_MAX	222	cmp ax, EPHEMERAL_PORT_MAX
223	ja @r	223	ja @r
224	xchg al, ah	224	xchg al, ah
225	mov [last_UDP_port], ax	225	mov [last_UDP_port], ax
226		226
227	@@:	227	@@:
228	pseudo_random eax	228	pseudo_random eax
229	cmp ax, EPHEMERAL_PORT_MIN	229	cmp ax, EPHEMERAL_PORT_MIN
230	jb @r	230	jb @r
231	cmp ax, EPHEMERAL_PORT_MAX	231	cmp ax, EPHEMERAL_PORT_MAX
232	ja @r	232	ja @r
233	xchg al, ah	233	xchg al, ah
234	mov [last_TCP_port], ax	234	mov [last_TCP_port], ax
235		235
236	mov ecx, socket_mutex	236	mov ecx, socket_mutex
237	call mutex_init	237	call mutex_init
238		238
239	}	239	}
240		240
241	;-----------------------------------------------------------------	241	;-----------------------------------------------------------------
242	;	242	;
243	; Socket API (function 74)	243	; Socket API (function 74)
244	;	244	;
245	;-----------------------------------------------------------------	245	;-----------------------------------------------------------------
246	align 4	246	align 4
247	sys_socket:	247	sys_socket:
248		248
249	mov dword[esp+20], 0 ; Set error code to 0	249	mov dword[esp+20], 0 ; Set error code to 0
250		250
251	cmp ebx, 255	251	cmp ebx, 255
252	jz SOCKET_debug	252	jz SOCKET_debug
253		253
254	cmp ebx, .number	254	cmp ebx, .number
255	ja .error	255	ja .error
256	jmp dword [.table + 4*ebx]	256	jmp dword [.table + 4*ebx]
257		257
258	.table:	258	.table:
259	dd SOCKET_open ; 0	259	dd SOCKET_open ; 0
260	dd SOCKET_close ; 1	260	dd SOCKET_close ; 1
261	dd SOCKET_bind ; 2	261	dd SOCKET_bind ; 2
262	dd SOCKET_listen ; 3	262	dd SOCKET_listen ; 3
263	dd SOCKET_connect ; 4	263	dd SOCKET_connect ; 4
264	dd SOCKET_accept ; 5	264	dd SOCKET_accept ; 5
265	dd SOCKET_send ; 6	265	dd SOCKET_send ; 6
266	dd SOCKET_receive ; 7	266	dd SOCKET_receive ; 7
267	dd SOCKET_set_opt ; 8	267	dd SOCKET_set_opt ; 8
268	dd SOCKET_get_opt ; 9	268	dd SOCKET_get_opt ; 9
269	dd SOCKET_pair ; 10	269	dd SOCKET_pair ; 10
270	.number = ($ - .table) / 4 - 1	270	.number = ($ - .table) / 4 - 1
271		271
272	.error:	272	.error:
273	mov dword[esp+32], -1	273	mov dword[esp+32], -1
274	mov dword[esp+20], EINVAL	274	mov dword[esp+20], EINVAL
275		275
276	ret	276	ret
277		277
278	;-----------------------------------------------------------------	278	;-----------------------------------------------------------------
279	;	279	;
280	; SOCKET_open	280	; SOCKET_open
281	;	281	;
282	; IN: domain in ecx	282	; IN: domain in ecx
283	; type in edx	283	; type in edx
284	; protocol in esi	284	; protocol in esi
285	; OUT: eax is socket num, -1 on error	285	; OUT: eax is socket num, -1 on error
286	;	286	;
287	;-----------------------------------------------------------------	287	;-----------------------------------------------------------------
288	align 4	288	align 4
289	SOCKET_open:	289	SOCKET_open:
290		290
291	DEBUGF DEBUG_NETWORK_VERBOSE, "SOCKET_open: domain=%u type=%u protocol=%x ", ecx, edx, esi	291	DEBUGF DEBUG_NETWORK_VERBOSE, "SOCKET_open: domain=%u type=%u protocol=%x ", ecx, edx, esi
292		292
293	push ecx edx esi	293	push ecx edx esi
294	call SOCKET_alloc	294	call SOCKET_alloc
295	pop esi edx ecx	295	pop esi edx ecx
-		296	test eax, eax
296	jz .nobuffs	297	jz .nobuffs
297		298
298	mov [esp+32], edi ; return socketnumber	299	mov [esp+32], edi ; return socketnumber
299	DEBUGF DEBUG_NETWORK_VERBOSE, "socknum=%u\n", edi	300	DEBUGF DEBUG_NETWORK_VERBOSE, "socknum=%u\n", edi
300		301
301	test edx, SO_NONBLOCK	302	test edx, SO_NONBLOCK
302	jz @f	303	jz @f
303	or [eax + SOCKET.options], SO_NONBLOCK	304	or [eax + SOCKET.options], SO_NONBLOCK
304	and edx, not SO_NONBLOCK	305	and edx, not SO_NONBLOCK
305	@@:	306	@@:
306		307
307	mov [eax + SOCKET.Domain], ecx	308	mov [eax + SOCKET.Domain], ecx
308	mov [eax + SOCKET.Type], edx	309	mov [eax + SOCKET.Type], edx
309	mov [eax + SOCKET.Protocol], esi	310	mov [eax + SOCKET.Protocol], esi
310	mov [eax + SOCKET.connect_proc], connect_notsupp	311	mov [eax + SOCKET.connect_proc], connect_notsupp
311		312
312	cmp ecx, AF_INET4	313	cmp ecx, AF_INET4
313	jne .no_inet4	314	jne .no_inet4
314		315
315	cmp edx, SOCK_DGRAM	316	cmp edx, SOCK_DGRAM
316	je .udp	317	je .udp
317		318
318	cmp edx, SOCK_STREAM	319	cmp edx, SOCK_STREAM
319	je .tcp	320	je .tcp
320		321
321	cmp edx, SOCK_RAW	322	cmp edx, SOCK_RAW
322	je .raw	323	je .raw
323		324
324	.no_inet4:	325	.no_inet4:
325	cmp ecx, AF_PPP	326	cmp ecx, AF_PPP
326	jne .no_ppp	327	jne .no_ppp
327		328
328	cmp esi, PPP_PROTO_ETHERNET	329	cmp esi, PPP_PROTO_ETHERNET
329	je .pppoe	330	je .pppoe
330		331
331	.no_ppp:	332	.no_ppp:
332	.unsupported:	333	.unsupported:
333	push eax	334	push eax
334	call SOCKET_free	335	call SOCKET_free
335	pop eax	336	pop eax
336	mov dword[esp+20], EOPNOTSUPP	337	mov dword[esp+20], EOPNOTSUPP
337	mov dword[esp+32], -1	338	mov dword[esp+32], -1
338	ret	339	ret
339		340
340	.nobuffs:	341	.nobuffs:
341	mov dword[esp+20], ENOBUFS	342	mov dword[esp+20], ENOBUFS
342	mov dword[esp+32], -1	343	mov dword[esp+32], -1
343	ret	344	ret
344		345
345	.raw:	346	.raw:
346	test esi, esi ; IP_PROTO_IP	347	test esi, esi ; IP_PROTO_IP
347	jz .raw_ip	348	jz .raw_ip
348		349
349	cmp esi, IP_PROTO_ICMP	350	cmp esi, IP_PROTO_ICMP
350	je .raw_icmp	351	je .raw_icmp
351		352
352	jmp .unsupported	353	jmp .unsupported
353		354
354	align 4	355	align 4
355	.udp:	356	.udp:
356	mov [eax + SOCKET.Protocol], IP_PROTO_UDP	357	mov [eax + SOCKET.Protocol], IP_PROTO_UDP
357	mov [eax + SOCKET.snd_proc], SOCKET_send_udp	358	mov [eax + SOCKET.snd_proc], SOCKET_send_udp
358	mov [eax + SOCKET.rcv_proc], SOCKET_receive_dgram	359	mov [eax + SOCKET.rcv_proc], SOCKET_receive_dgram
359	mov [eax + SOCKET.connect_proc], UDP_connect	360	mov [eax + SOCKET.connect_proc], UDP_connect
360	ret	361	ret
361		362
362	align 4	363	align 4
363	.tcp:	364	.tcp:
364	mov [eax + SOCKET.Protocol], IP_PROTO_TCP	365	mov [eax + SOCKET.Protocol], IP_PROTO_TCP
365	mov [eax + SOCKET.snd_proc], SOCKET_send_tcp	366	mov [eax + SOCKET.snd_proc], SOCKET_send_tcp
366	mov [eax + SOCKET.rcv_proc], SOCKET_receive_stream	367	mov [eax + SOCKET.rcv_proc], SOCKET_receive_stream
367	mov [eax + SOCKET.connect_proc], TCP_connect	368	mov [eax + SOCKET.connect_proc], TCP_connect
368		369
369	TCP_init_socket eax	370	TCP_init_socket eax
370	ret	371	ret
371		372
372		373
373	align 4	374	align 4
374	.raw_ip:	375	.raw_ip:
375	mov [eax + SOCKET.snd_proc], SOCKET_send_ip	376	mov [eax + SOCKET.snd_proc], SOCKET_send_ip
376	mov [eax + SOCKET.rcv_proc], SOCKET_receive_dgram	377	mov [eax + SOCKET.rcv_proc], SOCKET_receive_dgram
377	mov [eax + SOCKET.connect_proc], IPv4_connect	378	mov [eax + SOCKET.connect_proc], IPv4_connect
378	ret	379	ret
379		380
380		381
381	align 4	382	align 4
382	.raw_icmp:	383	.raw_icmp:
383	mov [eax + SOCKET.snd_proc], SOCKET_send_icmp	384	mov [eax + SOCKET.snd_proc], SOCKET_send_icmp
384	mov [eax + SOCKET.rcv_proc], SOCKET_receive_dgram	385	mov [eax + SOCKET.rcv_proc], SOCKET_receive_dgram
385	mov [eax + SOCKET.connect_proc], IPv4_connect	386	mov [eax + SOCKET.connect_proc], IPv4_connect
386	ret	387	ret
387		388
388	align 4	389	align 4
389	.pppoe:	390	.pppoe:
390	push eax	391	push eax
391	init_queue (eax + SOCKET_QUEUE_LOCATION) ; Set up data receiving queue	392	init_queue (eax + SOCKET_QUEUE_LOCATION) ; Set up data receiving queue
392	pop eax	393	pop eax
393		394
394	mov [eax + SOCKET.snd_proc], SOCKET_send_pppoe	395	mov [eax + SOCKET.snd_proc], SOCKET_send_pppoe
395	mov [eax + SOCKET.rcv_proc], SOCKET_receive_dgram	396	mov [eax + SOCKET.rcv_proc], SOCKET_receive_dgram
396	ret	397	ret
397		398
398		399
399	;-----------------------------------------------------------------	400	;-----------------------------------------------------------------
400	;	401	;
401	; SOCKET_bind	402	; SOCKET_bind
402	;	403	;
403	; IN: socket number in ecx	404	; IN: socket number in ecx
404	; pointer to sockaddr struct in edx	405	; pointer to sockaddr struct in edx
405	; length of that struct in esi	406	; length of that struct in esi
406	; OUT: 0 on success	407	; OUT: 0 on success
407	;	408	;
408	;-----------------------------------------------------------------	409	;-----------------------------------------------------------------
409	align 4	410	align 4
410	SOCKET_bind:	411	SOCKET_bind:
411		412
412	DEBUGF DEBUG_NETWORK_VERBOSE, "SOCKET_bind: socknum=%u sockaddr=%x length=%u\n", ecx, edx, esi	413	DEBUGF DEBUG_NETWORK_VERBOSE, "SOCKET_bind: socknum=%u sockaddr=%x length=%u\n", ecx, edx, esi
413		414
414	call SOCKET_num_to_ptr	415	call SOCKET_num_to_ptr
415	jz .invalid	416	jz .invalid
416		417
417	cmp esi, 2	418	cmp esi, 2
418	jb .invalid	419	jb .invalid
419		420
420	cmp [eax + UDP_SOCKET.LocalPort], 0 ; Socket can only be bound once	421	cmp [eax + UDP_SOCKET.LocalPort], 0 ; Socket can only be bound once
421	jnz .invalid	422	jnz .invalid
422		423
423	cmp word [edx], AF_INET4	424	cmp word [edx], AF_INET4
424	je .af_inet4	425	je .af_inet4
425		426
426	cmp word [edx], AF_LOCAL	427	cmp word [edx], AF_LOCAL
427	je .af_local	428	je .af_local
428		429
429	.notsupp:	430	.notsupp:
430	mov dword[esp+20], EOPNOTSUPP	431	mov dword[esp+20], EOPNOTSUPP
431	mov dword[esp+32], -1	432	mov dword[esp+32], -1
432	ret	433	ret
433		434
434	.invalid:	435	.invalid:
435	mov dword[esp+20], EINVAL	436	mov dword[esp+20], EINVAL
436	mov dword[esp+32], -1	437	mov dword[esp+32], -1
437	ret	438	ret
438		439
439	.af_local:	440	.af_local:
440	; TODO: write code here	441	; TODO: write code here
441	mov dword[esp+32], 0	442	mov dword[esp+32], 0
442	ret	443	ret
443		444
444	.af_inet4:	445	.af_inet4:
445	cmp esi, 6	446	cmp esi, 6
446	jb .invalid	447	jb .invalid
447		448
448	cmp [eax + SOCKET.Protocol], IP_PROTO_UDP	449	cmp [eax + SOCKET.Protocol], IP_PROTO_UDP
449	je .udp	450	je .udp
450		451
451	cmp [eax + SOCKET.Protocol], IP_PROTO_TCP	452	cmp [eax + SOCKET.Protocol], IP_PROTO_TCP
452	je .tcp	453	je .tcp
453		454
454	jmp .notsupp	455	jmp .notsupp
455		456
456	.tcp:	457	.tcp:
457	.udp:	458	.udp:
458		459
459	pushd [edx + 4] ; First, fill in the IP	460	pushd [edx + 4] ; First, fill in the IP
460	popd [eax + IP_SOCKET.LocalIP]	461	popd [eax + IP_SOCKET.LocalIP]
461		462
462	mov bx, [edx + 2] ; Did caller specify a local port?	463	mov bx, [edx + 2] ; Did caller specify a local port?
463	test bx, bx	464	test bx, bx
464	jnz .just_check	465	jnz .just_check
465	call SOCKET_find_port ; Nope, find an ephemeral one	466	call SOCKET_find_port ; Nope, find an ephemeral one
466	jmp .done	467	jmp .done
467		468
468	.just_check:	469	.just_check:
469	call SOCKET_check_port ; Yes, check if it's still available	470	call SOCKET_check_port ; Yes, check if it's still available
470	jz .addrinuse ; ZF is set by socket_check_port on error	471	jz .addrinuse ; ZF is set by socket_check_port on error
471		472
472	.done:	473	.done:
473	DEBUGF DEBUG_NETWORK_VERBOSE, "SOCKET_bind: local ip=%u.%u.%u.%u\n",\	474	DEBUGF DEBUG_NETWORK_VERBOSE, "SOCKET_bind: local ip=%u.%u.%u.%u\n",\
474	[eax + IP_SOCKET.LocalIP + 0]:1,[eax + IP_SOCKET.LocalIP + 1]:1,\	475	[eax + IP_SOCKET.LocalIP + 0]:1,[eax + IP_SOCKET.LocalIP + 1]:1,\
475	[eax + IP_SOCKET.LocalIP + 2]:1,[eax + IP_SOCKET.LocalIP + 3]:1	476	[eax + IP_SOCKET.LocalIP + 2]:1,[eax + IP_SOCKET.LocalIP + 3]:1
476		477
477	mov dword[esp+32], 0	478	mov dword[esp+32], 0
478	ret	479	ret
479		480
480	.addrinuse:	481	.addrinuse:
481	mov dword[esp+32], -1	482	mov dword[esp+32], -1
482	mov dword[esp+20], EADDRINUSE	483	mov dword[esp+20], EADDRINUSE
483	ret	484	ret
484		485
485		486
486		487
487		488
488	;-----------------------------------------------------------------	489	;-----------------------------------------------------------------
489	;	490	;
490	; SOCKET_connect	491	; SOCKET_connect
491	;	492	;
492	; IN: socket number in ecx	493	; IN: socket number in ecx
493	; pointer to sockaddr struct in edx	494	; pointer to sockaddr struct in edx
494	; length of that struct in esi	495	; length of that struct in esi
495	; OUT: 0 on success	496	; OUT: 0 on success
496	;	497	;
497	;-----------------------------------------------------------------	498	;-----------------------------------------------------------------
498	align 4	499	align 4
499	SOCKET_connect:	500	SOCKET_connect:

Subversion Repositories Kolibri OS

(root)/kernel/branches/Kolibri-acpi/network/socket.inc – Rev 4423 → 5201