WebSVN – Kolibri OS – Diff – /kernel/branches/net/network/socket.inc


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;                                                                 ;;
;; Copyright (C) KolibriOS team 2004-2012. All rights reserved.    ;;
;; Distributed under terms of the GNU General Public License       ;;
;;                                                                 ;;
;;  Part of the tcp/ip network stack for KolibriOS                 ;;
;;                                                                 ;;
;;   Written by hidnplayr@kolibrios.org,                           ;;
;;     and Clevermouse.                                            ;;
;;                                                                 ;;
;;       Based on code by mike.dld                                 ;;
;;                                                                 ;;
;;         GNU GENERAL PUBLIC LICENSE                              ;;
;;          Version 2, June 1991                                   ;;
;;                                                                 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 
$Revision: 2994 $
 
 
struct  SOCKET
 
        NextPtr                 dd ? ; pointer to next socket in list
        PrevPtr                 dd ? ; pointer to previous socket in list
        Number                  dd ? ; socket number
 
        mutex                   MUTEX
 
        PID                     dd ? ; application process id
        Domain                  dd ? ; INET/UNIX/..
        Type                    dd ? ; RAW/STREAM/DGRAP
        Protocol                dd ? ; ICMP/IPv4/ARP/TCP/UDP
        errorcode               dd ?
        device                  dd ?
 
        options                 dd ?
        state                   dd ?
        backlog                 dw ? ; how many incomming connections that can be queued
 
        snd_proc                dd ?
        rcv_proc                dd ?
 
ends
 
struct  IP_SOCKET               SOCKET
 
        LocalIP                 rd 4
        RemoteIP                rd 4
 
ends
 
struct  TCP_SOCKET              IP_SOCKET
 
        LocalPort               dw ?
        RemotePort              dw ?
 
        t_state                 dd ? ; TCB state
        t_rxtshift              db ?
                                rb 3 ; align
        t_rxtcur                dd ?
        t_dupacks               dd ?
        t_maxseg                dd ?
        t_force                 dd ?
        t_flags                 dd ?
 
;---------------
; RFC783 page 21
 
; send sequence
        SND_UNA                 dd ? ; sequence number of unack'ed sent Packets
        SND_NXT                 dd ? ; next send sequence number to use
        SND_UP                  dd ? ; urgent pointer
        SND_WL1                 dd ? ; window minus one
        SND_WL2                 dd ? ;
        ISS                     dd ? ; initial send sequence number
        SND_WND                 dd ? ; send window
 
; receive sequence
        RCV_WND                 dd ? ; receive window
        RCV_NXT                 dd ? ; next receive sequence number to use
        RCV_UP                  dd ? ; urgent pointer
        IRS                     dd ? ; initial receive sequence number
 
;---------------------
; Additional variables
 
; receive variables
        RCV_ADV                 dd ?
 
; retransmit variables
        SND_MAX                 dd ?
 
; congestion control
        SND_CWND                dd ?
        SND_SSTHRESH            dd ?
 
;----------------------
; Transmit timing stuff
        t_idle                  dd ?
        t_rtt                   dd ?
        t_rtseq                 dd ?
        t_srtt                  dd ?
        t_rttvar                dd ?
        t_rttmin                dd ?
        max_sndwnd              dd ?
 
;-----------------
; Out-of-band data
        t_oobflags              dd ?
        t_iobc                  dd ?
        t_softerror             dd ?
 
 
;---------
; RFC 1323                              ; the order of next 4 elements may not change
 
        SND_SCALE               db ?
        RCV_SCALE               db ?
        requested_s_scale       db ?
        request_r_scale         db ?
 
        ts_recent               dd ?    ; a copy of the most-recent valid timestamp from the other end
        ts_recent_age           dd ?
        last_ack_sent           dd ?
 
 
;-------
; Timers
        timer_retransmission    dd ? ; rexmt
        timer_persist           dd ?
        timer_keepalive         dd ? ; keepalive/syn timeout
        timer_timed_wait        dd ? ; also used as 2msl timer
 
; extra
 
        ts_ecr                  dd ? ; timestamp echo reply
        ts_val                  dd ?
        temp_bits               db ?
 
ends
 
struct  UDP_SOCKET              IP_SOCKET
 
        LocalPort               dw ?
        RemotePort              dw ?
        firstpacket             db ?
 
ends
 
 
struct  ICMP_SOCKET             IP_SOCKET
 
        Identifier              dw ?
 
ends
 
 
struct  RING_BUFFER
 
        start_ptr               dd ? ; Pointer to start of buffer
        end_ptr                 dd ? ; pointer to end of buffer
        read_ptr                dd ? ; Read pointer
        write_ptr               dd ? ; Write pointer
        size                    dd ? ; Number of bytes buffered
 
ends
 
struct  STREAM_SOCKET           TCP_SOCKET
 
        rcv                     RING_BUFFER
        snd                     RING_BUFFER
 
ends
 
struct  socket_queue_entry
 
        data_ptr                dd ?
        buf_ptr                 dd ?
        data_size               dd ?
 
ends
 
 
SOCKETBUFFSIZE          = 4096     ; in bytes
 
SOCKET_QUEUE_SIZE       = 10       ; maximum number ofincoming packets queued for 1 socket
; the incoming packet queue for sockets is placed in the socket struct itself, at this location from start
SOCKET_QUEUE_LOCATION   = (SOCKETBUFFSIZE - SOCKET_QUEUE_SIZE*sizeof.socket_queue_entry - sizeof.queue)
 
uglobal
        net_sockets     rd 4
        last_socket_num dd ?
        last_UDP_port   dw ? ; These values give the number of the last used ephemeral port
        last_TCP_port   dw ? ;
endg
 
 
;-----------------------------------------------------------------
;
; SOCKET_init
;
;-----------------------------------------------------------------
macro   SOCKET_init {
 
        xor     eax, eax
        mov     edi, net_sockets
        mov     ecx, 5
        rep     stosd
 
       @@:
        pseudo_random eax
        cmp     ax, MIN_EPHEMERAL_PORT
        jb      @r
        cmp     ax, MAX_EPHEMERAL_PORT
        ja      @r
        mov     [last_UDP_port], ax
 
       @@:
        pseudo_random eax
        cmp     ax, MIN_EPHEMERAL_PORT
        jb      @r
        cmp     ax, MAX_EPHEMERAL_PORT
        ja      @r
        mov     [last_TCP_port], ax
 
}
 
 
;-----------------------------------------------------------------
;
; SOCKET_block
;
;-----------------------------------------------------------------
macro   SOCKET_block socket, loop, done {
 
        test    [socket + SOCKET.options], SO_BLOCK     ; Is this a blocking socket?
        jz      done                                    ; No, return immediately
 
        push    esi
        mov     esi, 5                                  ; yes, wait for event
        call    delay_ms
        pop     esi
 
        jmp     loop
 
}
 
 
;-----------------------------------------------------------------
;
; Socket API (function 74)
;
;-----------------------------------------------------------------
align 4
sys_socket:
 
        cmp     ebx, 255
        jz      SOCKET_debug
 
        cmp     ebx, .number
        ja      s_error
        jmp     dword [.table + 4*ebx]
 
  .table:
        dd      SOCKET_open     ; 0
        dd      SOCKET_close    ; 1
        dd      SOCKET_bind     ; 2
        dd      SOCKET_listen   ; 3
        dd      SOCKET_connect  ; 4
        dd      SOCKET_accept   ; 5
        dd      SOCKET_send     ; 6
        dd      SOCKET_receive  ; 7
        dd      SOCKET_set_opt  ; 8
        dd      SOCKET_get_opt  ; 9
  .number = ($ - .table) / 4 - 1
 
s_error:
        DEBUGF  1,"socket error\n"
        mov     dword [esp+32], -1
 
        ret
 
 
 
;-----------------------------------------------------------------
;
; SOCKET_open
;
;  IN:  domain in ecx
;       type in edx
;       protocol in esi
;  OUT: eax is socket num, -1 on error
;
;-----------------------------------------------------------------
align 4
SOCKET_open:
 
        DEBUGF  1,"SOCKET_open: domain=%u type=%u protocol=%x\n", ecx, edx, esi
 
        push    ecx edx esi
        call    SOCKET_alloc
        pop     esi edx ecx
        jz      s_error
 
        mov     [esp+32], edi                   ; return socketnumber
 
        mov     [eax + SOCKET.Domain], ecx
        mov     [eax + SOCKET.Type], edx
        mov     [eax + SOCKET.Protocol], esi
 
        cmp     ecx, AF_INET4
        jne     .no_inet4
 
        cmp     edx, SOCK_DGRAM
        je      .udp
 
        cmp     edx, SOCK_STREAM
        je      .tcp
 
        cmp     edx, SOCK_RAW
        je      .raw
 
  .no_inet4:
        cmp     ecx, AF_PPP
        jne     .no_ppp
 
        cmp     esi, PPP_PROTO_ETHERNET
        je      .pppoe
 
  .no_ppp:
        ret
 
align 4
  .raw:
        test    esi, esi       ; IP_PROTO_IP
        jz      .ip
 
        cmp     esi, IP_PROTO_ICMP
        je      .icmp
 
        cmp     esi, IP_PROTO_UDP
        je      .udp
 
        cmp     esi, IP_PROTO_TCP
        je      .tcp
 
        ret
 
align 4
  .udp:
        mov     [eax + SOCKET.Protocol], IP_PROTO_UDP
        mov     [eax + SOCKET.snd_proc], SOCKET_send_udp
        mov     [eax + SOCKET.rcv_proc], SOCKET_receive_dgram
        ret
 
align 4
  .tcp:
        mov     [eax + SOCKET.Protocol], IP_PROTO_TCP
        mov     [eax + SOCKET.snd_proc], SOCKET_send_tcp
        mov     [eax + SOCKET.rcv_proc], SOCKET_receive_tcp
 
        TCP_init_socket eax
        ret
 
 
align 4
  .ip:
        mov     [eax + SOCKET.snd_proc], SOCKET_send_ip
        mov     [eax + SOCKET.rcv_proc], SOCKET_receive_dgram
        ret
 
 
align 4
  .icmp:
        mov     [eax + SOCKET.snd_proc], SOCKET_send_icmp
        mov     [eax + SOCKET.rcv_proc], SOCKET_receive_dgram
        ret
 
align 4
  .pppoe:
        push    eax
        init_queue (eax + SOCKET_QUEUE_LOCATION)        ; Set up data receiving queue
        pop     eax
 
        mov     [eax + SOCKET.snd_proc], SOCKET_send_pppoe
        mov     [eax + SOCKET.rcv_proc], SOCKET_receive_dgram
        ret
 
 
;-----------------------------------------------------------------
;
; SOCKET_bind
;
;  IN:  socket number in ecx
;       pointer to sockaddr struct in edx
;       length of that struct in esi
;  OUT: 0 on success
;
;-----------------------------------------------------------------
align 4
SOCKET_bind:
 
        DEBUGF  1,"SOCKET_bind: socknum=%u sockaddr=%x length=%u\n", ecx, edx, esi
 
        call    SOCKET_num_to_ptr
        jz      s_error
 
        cmp     esi, 2
        jb      s_error
 
        cmp     word [edx], AF_INET4
        je      .af_inet4
 
        cmp     word [edx], AF_UNIX
        je      .af_unix
 
        jmp     s_error
 
  .af_unix:
        ; TODO: write code here
 
        mov     dword [esp+32], 0
        ret
 
  .af_inet4:
 
        cmp     esi, 6
        jb      s_error
 
        cmp     [eax + SOCKET.Protocol], IP_PROTO_UDP
        je      .udp
 
        cmp     [eax + SOCKET.Protocol], IP_PROTO_TCP
        je      .tcp
 
        jmp     s_error
 
  .tcp:
  .udp:
 
        mov     ebx, [edx + 4]                  ; First, fill in the IP
        test    ebx, ebx                        ; If IP is 0, use default
        jnz     @f
        mov     ebx, [NET_DEFAULT]
        mov     ebx, [IP_LIST + 4*ebx]
       @@:
        mov     [eax + IP_SOCKET.LocalIP], ebx
 
        mov     bx, [edx + 2]                   ; Now fill in the port if it's still available
        call    SOCKET_check_port
        jz      s_error                         ; ZF is set by socket_check_port, on error
 
        DEBUGF  1,"SOCKET_bind: local ip=%u.%u.%u.%u\n",\
        [eax + IP_SOCKET.LocalIP + 0]:1,[eax + IP_SOCKET.LocalIP + 1]:1,\
        [eax + IP_SOCKET.LocalIP + 2]:1,[eax + IP_SOCKET.LocalIP + 3]:1
 
        mov     dword [esp+32], 0
        ret
 
 
 
 
;-----------------------------------------------------------------
;
; SOCKET_connect
;
;  IN:  socket number in ecx
;       pointer to sockaddr struct in edx
;       length of that struct in esi
;  OUT: 0 on success
;
;-----------------------------------------------------------------
align 4
SOCKET_connect:
 
        DEBUGF  1,"SOCKET_connect: socknum=%u sockaddr=%x length=%u\n", ecx, edx, esi
 
        call    SOCKET_num_to_ptr
        jz      s_error
 
        cmp     esi, 8
        jb      s_error
 
        cmp     word [edx], AF_INET4
        je      .af_inet4
 
        jmp     s_error
 
  .af_inet4:
        cmp     [eax + IP_SOCKET.LocalIP], 0
        jne     @f
        push    [IP_LIST]
        pop     [eax + IP_SOCKET.LocalIP]
       @@:
 
        cmp     [eax + SOCKET.Protocol], IP_PROTO_UDP
        je      .udp
 
        cmp     [eax + SOCKET.Protocol], IP_PROTO_TCP
        je      .tcp
 
        cmp     [eax + SOCKET.Protocol], IP_PROTO_IP
        je      .ip
 
        cmp     [eax + SOCKET.Protocol], IP_PROTO_ICMP
        je      .ip
 
        jmp     s_error
 
align 4
  .udp:
        pusha
        lea     ecx, [eax + SOCKET.mutex]
        call    mutex_lock
        popa
 
        pushw   [edx + 2]
        pop     [eax + UDP_SOCKET.RemotePort]
 
        pushd   [edx + 4]
        pop     [eax + IP_SOCKET.RemoteIP]
 
        cmp     [eax + UDP_SOCKET.LocalPort], 0
        jne     @f
        call    SOCKET_find_port
       @@:
 
        mov     [eax + UDP_SOCKET.firstpacket], 0
 
        push    eax
        init_queue (eax + SOCKET_QUEUE_LOCATION)        ; Set up data receiving queue
        pop     eax
 
        lea     ecx, [eax + SOCKET.mutex]
        call    mutex_unlock
 
        mov     dword [esp+32], 0
        ret
 
align 4
  .tcp:
        pusha
        lea     ecx, [eax + SOCKET.mutex]
        call    mutex_lock
        popa
 
        pushw   [edx + 2]
        pop     [eax + TCP_SOCKET.RemotePort]
 
        pushd   [edx + 4]
        pop     [eax + IP_SOCKET.RemoteIP]
 
        cmp     [eax + TCP_SOCKET.LocalPort], 0
        jne     @f
        call    SOCKET_find_port
       @@:
 
        mov     [eax + TCP_SOCKET.timer_persist], 0
        mov     [eax + TCP_SOCKET.t_state], TCPS_SYN_SENT
 
        push    [TCP_sequence_num]
        add     [TCP_sequence_num], 6400
        pop     [eax + TCP_SOCKET.ISS]
        mov     [eax + TCP_SOCKET.timer_keepalive], TCP_time_keep_init
 
 
        TCP_sendseqinit eax
 
;        mov     [ebx + TCP_SOCKET.timer_retransmission],   ;; todo: create macro to set retransmission timer
 
        mov     ebx, eax
 
        lea     eax, [ebx + STREAM_SOCKET.snd]
        call    SOCKET_ring_create
 
        lea     eax, [ebx + STREAM_SOCKET.rcv]
        call    SOCKET_ring_create
 
        pusha
        lea     ecx, [ebx + SOCKET.mutex]
        call    mutex_unlock
        popa
 
        mov     eax, ebx
        call    TCP_output
 
;;; TODO: wait for successfull connection if blocking socket
 
        mov     dword [esp+32], 0
        ret
 
align 4
  .ip:
        pusha
        lea     ecx, [eax + SOCKET.mutex]
        call    mutex_lock
        popa
 
        pushd   [edx + 4]
        pop     [eax + IP_SOCKET.RemoteIP]
 
        push    eax
        init_queue (eax + SOCKET_QUEUE_LOCATION)        ; Set up data receiving queue
        pop     eax
 
        lea     ecx, [eax + SOCKET.mutex]
        call    mutex_unlock
 
        mov     dword [esp+32], 0
        ret
 
 
;-----------------------------------------------------------------
;
; SOCKET_listen
;
;  IN:  socket number in ecx
;       backlog in edx
;  OUT: eax is socket num, -1 on error
;
;-----------------------------------------------------------------
align 4
SOCKET_listen:
 
        DEBUGF  1,"SOCKET_listen: socknum=%u backlog=%u\n", ecx, edx
 
        call    SOCKET_num_to_ptr
        jz      s_error
 
        cmp     [eax + SOCKET.Domain], AF_INET4
        jne     s_error
 
        cmp     [eax + SOCKET.Protocol], IP_PROTO_TCP
        jne     s_error
 
        cmp     [eax + TCP_SOCKET.LocalPort], 0
        je      s_error
 
        cmp     [eax + IP_SOCKET.LocalIP], 0
        jne     @f
        push    [IP_LIST]
        pop     [eax + IP_SOCKET.LocalIP]
       @@:
 
        cmp     edx, MAX_backlog
        jbe     @f
        mov     edx, MAX_backlog
       @@:
 
        mov     [eax + SOCKET.backlog], dx
        or      [eax + SOCKET.options], SO_ACCEPTCON
        mov     [eax + TCP_SOCKET.t_state], TCPS_LISTEN
        mov     [eax + TCP_SOCKET.timer_keepalive], 0           ; disable keepalive timer
 
        push    eax
        init_queue (eax + SOCKET_QUEUE_LOCATION)                ; Set up sockets queue
        pop     eax
 
        mov     dword [esp+32], 0
 
        ret
 
 
;-----------------------------------------------------------------
;
; SOCKET_accept
;
;  IN:  socket number in ecx
;       addr in edx
;       addrlen in esi
;  OUT: eax is socket num, -1 on error
;
;-----------------------------------------------------------------
align 4
SOCKET_accept:
 
        DEBUGF  1,"SOCKET_accept: socknum=%u sockaddr=%x length=%u\n", ecx, edx, esi
 
        call    SOCKET_num_to_ptr
        jz      s_error
 
        test    [eax + SOCKET.options], SO_ACCEPTCON
        jz      s_error
 
        cmp     [eax + SOCKET.Domain], AF_INET4
        jne     s_error
 
        cmp     [eax + SOCKET.Protocol], IP_PROTO_TCP
        jne     s_error
 
  .loop:
        get_from_queue (eax + SOCKET_QUEUE_LOCATION), MAX_backlog, 4, .block
 
; Ok, we got a socket ptr
        mov     eax, [esi]
 
; Change PID to that of the current process
        mov     ebx, [TASK_BASE]
        mov     ebx, [ebx + TASKDATA.pid]
        mov     [eax + SOCKET.PID], ebx
 
; Convert it to a socket number
        call    SOCKET_ptr_to_num
        jz      s_error
; and return it to caller
        mov     [esp+32], eax
        ret
 
  .block:
        SOCKET_block    eax, .loop, s_error
 
;-----------------------------------------------------------------
;
; SOCKET_close
;
;  IN:  socket number in ecx
;  OUT: eax is socket num, -1 on error
;
;-----------------------------------------------------------------
align 4
SOCKET_close:
 
        DEBUGF  1,"SOCKET_close: %u\n", ecx
 
        call    SOCKET_num_to_ptr
        jz      s_error
 
        cmp     [eax + SOCKET.Domain], AF_INET4
        jne     s_error
 
        cmp     [eax + SOCKET.Protocol], IP_PROTO_UDP
        je      .free
 
        cmp     [eax + SOCKET.Protocol], IP_PROTO_ICMP
        je      .free
 
        cmp     [eax + SOCKET.Protocol], IP_PROTO_IP
        je      .free
 
        cmp     [eax + SOCKET.Protocol], IP_PROTO_TCP
        je      .tcp
 
        jmp     s_error
 
  .tcp:
        cmp     [eax + TCP_SOCKET.t_state], TCPS_SYN_RECEIVED    ; state must be LISTEN, SYN_SENT or CLOSED
        jb      .free
 
        call    TCP_usrclosed
        call    TCP_output      ;;;; Fixme: is this nescessary??
 
;;; TODO: wait for successfull termination if blocking socket
        mov     dword [esp+32], 0
 
        ret
 
  .free:
        call    SOCKET_free
        mov     dword [esp+32], 0
 
        ret
 
 
;-----------------------------------------------------------------
;
; SOCKET_receive
;
;  IN:  socket number in ecx
;       addr to buffer in edx
;       length of buffer in esi
;       flags in edi
;  OUT: eax is number of bytes copied, -1 on error
;
;-----------------------------------------------------------------
align 4
SOCKET_receive:
 
        DEBUGF  1,"SOCKET_receive: socknum=%u bufaddr=%x buflength=%u flags=%x\n", ecx, edx, esi, edi
 
        call    SOCKET_num_to_ptr
        jz      s_error
 
        jmp     [eax + SOCKET.rcv_proc]
 
 
align 4
SOCKET_receive_dgram:
 
        DEBUGF  1,"SOCKET_receive: DGRAM\n"
 
        mov     ebx, esi
        mov     edi, edx                                        ; addr to buffer
 
  .loop:
        get_from_queue (eax + SOCKET_QUEUE_LOCATION), SOCKET_QUEUE_SIZE, sizeof.socket_queue_entry, .block      ; destroys esi and ecx
 
        mov     ecx, [esi + socket_queue_entry.data_size]
        DEBUGF  1,"SOCKET_receive: %u bytes data\n", ecx
 
        cmp     ecx, ebx
        ja      .too_small
 
        push    [esi + socket_queue_entry.buf_ptr]              ; save the buffer addr so we can clear it later
        mov     esi, [esi + socket_queue_entry.data_ptr]
        DEBUGF  1,"SOCKET_receive: Source buffer=%x real addr=%x\n", [esp], esi
        mov     [esp+32+4], ecx                                 ; return number of bytes copied
 
; copy the data
        shr     ecx, 1
        jnc     .nb
        movsb
  .nb:
        shr     ecx, 1
        jnc     .nw
        movsw
  .nw:
        test    ecx, ecx
        jz      .nd
        rep     movsd
  .nd:
 
        call    kernel_free                                     ; remove the packet
        ret
 
  .too_small:
 
        DEBUGF  1,"SOCKET_receive: Buffer too small\n"
        jmp     s_error
 
  .block:
        SOCKET_block    eax, .loop, s_error
 
 
align 4
SOCKET_receive_tcp:
 
        DEBUGF  1,"SOCKET_receive: TCP\n"
 
        mov     ecx, esi
        mov     edi, edx
 
        xor     edx, edx
        add     eax, STREAM_SOCKET.rcv
  .loop:                            ;;;; FIXME: ecx!
        call    SOCKET_ring_read
        test    ecx, ecx
        jz      .block
        call    SOCKET_ring_free
 
        mov     [esp+32], ecx                                   ; return number of bytes copied
 
        ret
 
  .block:
        SOCKET_block    (eax - STREAM_SOCKET.rcv), .loop, s_error
 
 
;-----------------------------------------------------------------
;
; SOCKET_send
;
;
;  IN:  socket number in ecx
;       pointer to data in edx
;       datalength in esi
;       flags in edi
;  OUT: -1 on error
;
;-----------------------------------------------------------------
align 4
SOCKET_send:
 
        DEBUGF  1,"SOCKET_send: socknum=%u data ptr=%x length=%u flags=%x\n", ecx, edx, esi, edi
 
        call    SOCKET_num_to_ptr
        jz      s_error
 
        mov     ecx, esi
        mov     esi, edx
 
        jmp     [eax + SOCKET.snd_proc]
 
 
align 4
SOCKET_send_udp:
 
        DEBUGF  1,"SOCKET_send: UDP\n"
 
        mov     [esp+32], ecx
        call    UDP_output
        cmp     eax, -1
        je      s_error
        ret
 
 
align 4
SOCKET_send_tcp:
 
        DEBUGF  1,"SOCKET_send: TCP\n"
 
        push    eax
        add     eax, STREAM_SOCKET.snd
        call    SOCKET_ring_write
        pop     eax
 
        mov     [esp+32], ecx
 
        call    TCP_output
        ret
 
 
align 4
SOCKET_send_ip:
 
        DEBUGF  1,"SOCKET_send: IPv4\n"
 
        mov     [esp+32], ecx
        call    IPv4_output_raw
        cmp     eax, -1
        je      s_error
        ret
 
 
align 4
SOCKET_send_icmp:
 
        DEBUGF  1,"SOCKET_send: ICMP\n"
 
        mov     [esp+32], ecx
        call    ICMP_output_raw
        cmp     eax, -1
        je      s_error
        ret
 
 
align 4
SOCKET_send_pppoe:
 
        DEBUGF  1,"SOCKET_send: PPPoE\n"
 
        mov     [esp+32], ecx
        mov     ebx, [eax + SOCKET.device]
 
        call    PPPoE_discovery_output
        cmp     eax, -1
        je      s_error
        ret
 
 
 
 
;-----------------------------------------------------------------
;
; SOCKET_get_options
;
;  IN:  ecx = socket number
;       edx = pointer to the options:
;               dd      level, optname, optval, optlen
;  OUT: -1 on error
;
; At moment, uses only pseudo-optname -2 for get last_ack_number for TCP.
; TODO: find best way to notify that send()'ed data were acknowledged
; Also pseudo-optname -3 is valid and returns socket state, one of TCPS_*.
;
;-----------------------------------------------------------------
align 4
SOCKET_get_opt:
 
        DEBUGF  1,"SOCKET_get_opt\n"
 
        call    SOCKET_num_to_ptr
        jz      s_error
 
        cmp     dword [edx], IP_PROTO_TCP
        jne     s_error
        cmp     dword [edx+4], -2
        je      @f
        cmp     dword [edx+4], -3
        jne     s_error
@@:
;        mov     eax, [edx+12]
;        test    eax, eax
;        jz      .fail
;        cmp     dword [eax], 4
;        mov     dword [eax], 4
;        jb      .fail
;        stdcall net_socket_num_to_addr, ecx
;        test    eax, eax
;        jz      .fail
;        ; todo: check that eax is really TCP socket
;        mov     ecx, [eax + TCP_SOCKET.last_ack_number]
;        cmp     dword [edx+4], -2
;        jz      @f
;        mov     ecx, [eax + TCP_SOCKET.state]
@@:
        mov     eax, [edx+8]
        test    eax, eax
        jz      @f
        mov     [eax], ecx
@@:
        mov     dword [esp+32], 0
        ret
 
 
 
;-----------------------------------------------------------------
;
; SOCKET_set_options
;
;  IN:  ecx = socket number
;       edx = pointer to the options:
;               dd      level, optname, optlen, optval
;  OUT: -1 on error
;
;-----------------------------------------------------------------
align 4
SOCKET_set_opt:
 
        DEBUGF  1,"SOCKET_set_opt\n"
 
        call    SOCKET_num_to_ptr
        jz      s_error
 
        cmp     dword [edx], SOL_SOCKET
        jne     s_error
 
        cmp     dword [edx+4], SO_BINDTODEVICE
        je      .bind
 
        jmp     s_error
 
  .bind:
        cmp     dword [edx+8], 0
        je      .unbind
 
        movzx   edx, byte [edx + 9]
        cmp     edx, MAX_NET_DEVICES
        ja      s_error
 
        mov     edx, [NET_DRV_LIST + 4*edx]
        test    edx, edx
        jz      s_error
        mov     [eax + SOCKET.device], edx
 
        DEBUGF  1,"SOCKET_set_opt: Bound socket %x to device %x\n",eax, edx
 
        mov     dword [esp+32], 0       ; success!
        ret
 
  .unbind:
        mov     [eax + SOCKET.device], 0
 
        mov     dword [esp+32], 0       ; success!
        ret
 
 
 
;-----------------------------------------------------------------
;
; SOCKET_debug
;
;  Copies socket variables to application buffer
;
;  IN:  ecx = socket number
;       edx = pointer to buffer
;
;  OUT: -1 on error
;-----------------------------------------------------------------
align 4
SOCKET_debug:
 
        DEBUGF  1,"SOCKET_debug\n"
 
        call    SOCKET_num_to_ptr
        jz      s_error
 
        mov     esi, eax
        mov     edi, edx
        mov     ecx, SOCKETBUFFSIZE/4
        rep     movsd
 
        mov     dword [esp+32], 0
        ret
 
 
;-----------------------------------------------------------------
;
; SOCKET_find_port
;
; Fills in the local port number for TCP and UDP sockets
; This procedure always works because the number of sockets is
; limited to a smaller number then the number of possible ports
;
;  IN:  eax = socket pointer
;  OUT: /
;
;-----------------------------------------------------------------
align 4
SOCKET_find_port:
 
        DEBUGF  1,"SOCKET_find_port\n"
 
        push    ebx esi ecx
 
        cmp     [eax + SOCKET.Protocol], IP_PROTO_UDP
        je      .udp
 
        cmp     [eax + SOCKET.Protocol], IP_PROTO_TCP
        je      .tcp
 
        jmp     .error
 
  .done:
        mov     [eax + UDP_SOCKET.LocalPort], bx
  .error:
        pop     ecx esi ebx
        ret
 
  .udp:
        mov     bx, [last_UDP_port]
        call    .findit
        mov     [last_UDP_port], bx
        jmp     .done
 
  .tcp:
        mov     bx, [last_TCP_port]
        call    .findit
        mov     [last_TCP_port], bx
        jmp     .done
 
 
  .restart:
        mov     bx, MIN_EPHEMERAL_PORT
  .findit:
        inc     bx
 
        cmp     bx, MAX_EPHEMERAL_PORT
        jz      .restart
 
        call    SOCKET_check_port
        jz      .findit
 
        ret
 
 
 
;-----------------------------------------------------------------
;
; SOCKET_check_port (to be used with AF_INET only!)
;
; Checks if a local port number is unused
; If the proposed port number is unused, it is filled in in the socket structure
;
;  IN:  eax = socket ptr (to find out if its a TCP/UDP socket)
;        bx = proposed socket number
;
;  OUT:  ZF = cleared on error
;
;-----------------------------------------------------------------
align 4
SOCKET_check_port:
 
        DEBUGF  1,"SOCKET_check_port: "
 
        mov     ecx, [eax + SOCKET.Protocol]
        mov     edx, [eax + IP_SOCKET.LocalIP]
        mov     esi, net_sockets
 
  .next_socket:
        mov     esi, [esi + SOCKET.NextPtr]
        or      esi, esi
        jz      .port_ok
 
        cmp     [esi + SOCKET.Protocol], ecx
        jne     .next_socket
 
        cmp     [esi + IP_SOCKET.LocalIP], edx
        jne     .next_socket
 
        cmp     [esi + UDP_SOCKET.LocalPort], bx
        jne     .next_socket
 
        DEBUGF  1,"local port %u already in use\n", bx
        ret
 
  .port_ok:
        DEBUGF  1,"local port %u is free\n", bx
        mov     [eax + UDP_SOCKET.LocalPort], bx
        or      bx, bx                                  ; set the zero-flag
 
        ret
 
 
 
;-----------------------------------------------------------------
;
; SOCKET_input
;
; Updates a (stateless) socket with received data
;
; Note: the mutex should already be set !
;
;  IN:  eax = socket ptr
;       ecx = data size
;       esi = ptr to data
;       [esp] = ptr to buf
;       [esp + 4] = buf size
;
;  OUT: /
;
;-----------------------------------------------------------------
align 4
SOCKET_input:
 
        DEBUGF  1,"SOCKET_input: socket=%x, data=%x size=%u\n", eax, esi, ecx
 
        mov     [esp+4], ecx
        push    esi
        mov     esi, esp
 
        add_to_queue (eax + SOCKET_QUEUE_LOCATION), SOCKET_QUEUE_SIZE, sizeof.socket_queue_entry, SOCKET_input.full
 
        DEBUGF  1,"SOCKET_input: queued packet successfully\n"
        add     esp, sizeof.socket_queue_entry
 
        pusha
        lea     ecx, [eax + SOCKET.mutex]
        call    mutex_unlock
        popa
 
        jmp     SOCKET_notify_owner
 
  .full:
        DEBUGF  2,"SOCKET_input: socket %x is full!\n", eax
 
        pusha
        lea     ecx, [eax + SOCKET.mutex]
        call    mutex_unlock
        popa
 
        call    kernel_free
        add     esp, 8
 
        ret
 
 
;--------------------------
;
; eax = ptr to ring struct (just a buffer of the right size)
;
align 4
SOCKET_ring_create:
 
        push    esi
        mov     esi, eax
 
        push    edx
        stdcall create_ring_buffer, SOCKET_MAXDATA, PG_SW
        pop     edx
 
        DEBUGF  1,"SOCKET_ring_created: %x\n", eax
        mov     [esi + RING_BUFFER.start_ptr], eax
        mov     [esi + RING_BUFFER.write_ptr], eax
        mov     [esi + RING_BUFFER.read_ptr], eax
        mov     [esi + RING_BUFFER.size], 0
        add     eax, SOCKET_MAXDATA
        mov     [esi + RING_BUFFER.end_ptr], eax
        mov     eax, esi
        pop     esi
 
        ret
 
;-----------------------------------------------------------------
;
; SOCKET_ring_write
;
; Adds data to a stream socket, and updates write pointer and size
;
;  IN:  eax = ptr to ring struct
;       ecx = data size
;       esi = ptr to data
;
;  OUT: ecx = number of bytes stored
;
;-----------------------------------------------------------------
align 4
SOCKET_ring_write:
 
        DEBUGF  1,"SOCKET_ring_write: ringbuff=%x ptr=%x size=%u\n", eax, esi, ecx
 
        add     [eax + RING_BUFFER.size], ecx
        jc      .way_too_large
        cmp     [eax + RING_BUFFER.size], SOCKET_MAXDATA
        ja      .too_large
 
  .copy:
        mov     edi, [eax + RING_BUFFER.write_ptr]
        DEBUGF  2,"SOCKET_ring_write: %u bytes from %x to %x\n", ecx, esi, edi
 
        push    ecx
        shr     ecx, 1
        jnc     .nb
        movsb
  .nb:
        shr     ecx, 1
        jnc     .nw
        movsw
  .nw:
        test    ecx, ecx
        jz      .nd
        rep     movsd
  .nd:
        pop     ecx
 
        cmp     edi, [eax + RING_BUFFER.end_ptr]
        jae     .wrap
        mov     [eax + RING_BUFFER.write_ptr], edi
 
        ret
 
  .wrap:
        sub     edi, SOCKET_MAXDATA
        mov     [eax + RING_BUFFER.write_ptr], edi
 
        ret
 
  .too_large:                                                           ; update size, we will fill buffer completely
        sub     [eax + RING_BUFFER.size], SOCKET_MAXDATA
        sub     ecx, [eax + RING_BUFFER.size]
        mov     [eax + RING_BUFFER.size], SOCKET_MAXDATA
        ja      .copy
 
  .full:
        DEBUGF  2,"SOCKET_ring_write: ring buffer is full!\n"
        xor     ecx, ecx
        ret
 
  .way_too_large:
        sub     [eax + RING_BUFFER.size], ecx
        mov     ecx, SOCKET_MAXDATA
        sub     ecx, [eax + RING_BUFFER.size]
        ja      .copy
        jmp     .full
 
 
 
;-----------------------------------------------------------------
;
; SOCKET_ring_read
;
;  IN:  eax = ring struct ptr
;       ecx = bytes to read
;       edx = offset
;       edi = ptr to buffer start
;
;  OUT: eax = unchanged
;       ecx = number of bytes read (0 on error)
;       edx = destroyed
;       esi = destroyed
;       edi = ptr to buffer end
;
;-----------------------------------------------------------------
align 4
SOCKET_ring_read:
 
        DEBUGF  1,"SOCKET_ring_read: ringbuff=%x ptr=%x size=%u offset=%x\n", eax, edi, ecx, edx
 
        mov     esi, [eax + RING_BUFFER.read_ptr]
        add     esi, edx                                        ; esi = start_ptr + offset
 
        neg     edx
        add     edx, [eax + RING_BUFFER.size]                   ; edx = snd.size - offset
        jle     .no_data_at_all
 
        cmp     ecx, edx
        ja      .less_data
 
  .copy:
        DEBUGF  2,"SOCKET_ring_read: %u bytes from %x to %x\n", ecx, esi, edi
        push    ecx
        shr     ecx, 1
        jnc     .nb
        movsb
  .nb:
        shr     ecx, 1
        jnc     .nw
        movsw
  .nw:
        test    ecx, ecx
        jz      .nd
        rep     movsd
  .nd:
        pop     ecx
        ret
 
  .no_data_at_all:
        DEBUGF  1,"SOCKET_ring_read: no data at all!\n"
        xor     ecx, ecx
        ret
 
  .less_data:
        mov     ecx, edx
        jmp     .copy
 
 
;-----------------------------------------------------------------
;
; SOCKET_ring_free
;
; Free's some bytes from the ringbuffer
;
;  IN:  eax = ptr to ring struct
;       ecx = data size
;
;  OUT: ecx = number of bytes free-ed
;
;-----------------------------------------------------------------
align 4
SOCKET_ring_free:
 
        DEBUGF  1,"SOCKET_ring_free: %u bytes from ring %x\n", ecx, eax
 
        sub     [eax + RING_BUFFER.size], ecx
        jb      .error
        add     [eax + RING_BUFFER.read_ptr], ecx
 
        mov     edx, [eax + RING_BUFFER.end_ptr]
        cmp     [eax + RING_BUFFER.read_ptr], edx
        jb      @f
        sub     [eax + RING_BUFFER.read_ptr], SOCKET_MAXDATA
       @@:
        ret
 
  .error:       ; we could free all available bytes, but that would be stupid, i guess..
        DEBUGF  1,"SOCKET_ring_free: buffer=%x error!\n", eax
        add     [eax + RING_BUFFER.size], ecx
        xor     ecx, ecx
        ret
 
 
;-----------------------------------------------------------------
;
; SOCKET_notify_owner
;
; notify's the owner of a socket that something happened
;
;  IN:  eax = socket ptr
;  OUT: /
;
;-----------------------------------------------------------------
align 4
SOCKET_notify_owner:
 
        DEBUGF  1,"SOCKET_notify_owner: %x\n", eax
 
        call    SOCKET_check
        jz      .error
 
        push    eax ecx esi
 
; socket exists, now try to flag an event to the application
 
        mov     eax, [eax + SOCKET.PID]
        test    eax, eax
        jz      .error2
        mov     ecx, 1
        mov     esi, TASK_DATA + TASKDATA.pid
 
       .next_pid:
        cmp     [esi], eax
        je      .found_pid
        inc     ecx
        add     esi, 0x20
        cmp     ecx, [TASK_COUNT]
        jbe     .next_pid
 
; PID not found, TODO: close socket!
 
        jmp     .error2
 
       .found_pid:
        shl     ecx, 8
        or      [ecx + SLOT_BASE + APPDATA.event_mask], EVENT_NETWORK
        mov     [check_idle_semaphore], 200
 
        DEBUGF  1,"SOCKET_notify_owner: succes!\n"
 
  .error2:
        pop     esi ecx eax
 
  .error:
 
        ret
 
 
;--------------------------------------------------------------------
;
; SOCKET_alloc
;
; Allocate memory for socket data and put new socket into the list
; Newly created socket is initialized with calling PID and number and
; put into beginning of list (which is a fastest way).
;
; IN:  /
; OUT: eax = 0 on error, socket ptr otherwise
;      edi = socket number
;       ZF = cleared on error
;
;--------------------------------------------------------------------
align 4
SOCKET_alloc:
 
        push    ebx
 
        stdcall kernel_alloc, SOCKETBUFFSIZE
        DEBUGF  1, "SOCKET_alloc: ptr=%x\n", eax
        or      eax, eax
        jz      .exit
 
; zero-initialize allocated memory
        push    eax
        mov     edi, eax
        mov     ecx, SOCKETBUFFSIZE / 4
        xor     eax, eax
        rep     stosd
        pop     eax
 
; set send-and receive procedures to return -1
        mov     [eax + SOCKET.snd_proc], s_error
        mov     [eax + SOCKET.rcv_proc], s_error
 
; find first free socket number and use it
        mov     edi, [last_socket_num]
  .next_socket_number:
        inc     edi
        jz      .next_socket_number     ; avoid socket nr 0
        cmp     edi, -1
        je      .next_socket_number     ; avoid socket nr -1
        mov     ebx, net_sockets
  .next_socket:
        mov     ebx, [ebx + SOCKET.NextPtr]
        test    ebx, ebx
        jz      .last_socket
 
        cmp     [ebx + SOCKET.Number], edi
        jne     .next_socket
        jmp     .next_socket_number
 
  .last_socket:
        mov     [last_socket_num], edi
        mov     [eax + SOCKET.Number], edi
        DEBUGF  1, "SOCKET_alloc: number=%u\n", edi
 
; Fill in PID
        mov     ebx, [TASK_BASE]
        mov     ebx, [ebx + TASKDATA.pid]
        mov     [eax + SOCKET.PID], ebx
 
; init mutex
        pusha
        lea     ecx, [eax + SOCKET.mutex]
        call    mutex_init
        popa
 
; add socket to the list by re-arranging some pointers
        mov     ebx, [net_sockets + SOCKET.NextPtr]
 
        mov     [eax + SOCKET.PrevPtr], net_sockets
        mov     [eax + SOCKET.NextPtr], ebx
 
        test    ebx, ebx
        jz      @f
 
        pusha
        lea     ecx, [ebx + SOCKET.mutex]
        call    mutex_lock
        popa
 
        mov     [ebx + SOCKET.PrevPtr], eax
 
        pusha
        lea     ecx, [ebx + SOCKET.mutex]
        call    mutex_unlock
        popa
       @@:
 
        mov     [net_sockets + SOCKET.NextPtr], eax
        or      eax, eax                ; used to clear zero flag
  .exit:
        pop     ebx
 
        ret
 
 
;----------------------------------------------------
;
; SOCKET_free
;
; Free socket data memory and remove socket from the list
;
; IN:  eax = socket ptr
; OUT: /
;
;----------------------------------------------------
align 4
SOCKET_free:
 
        DEBUGF  1, "SOCKET_free: %x\n", eax
 
        call    SOCKET_check
        jz      .error
 
        push    ebx
 
        pusha
        lea     ecx, [eax + SOCKET.mutex]
        call    mutex_lock
        popa
 
        cmp     [eax + SOCKET.Domain], AF_INET4
        jnz     .no_tcp
 
        cmp     [eax + SOCKET.Protocol], IP_PROTO_TCP
        jnz     .no_tcp
 
        mov     ebx, eax
        stdcall kernel_free, [ebx + STREAM_SOCKET.rcv.start_ptr]
        stdcall kernel_free, [ebx + STREAM_SOCKET.snd.start_ptr]
        mov     eax, ebx
  .no_tcp:
 
        push    eax                             ; this will be passed to kernel_free
        mov     ebx, [eax + SOCKET.NextPtr]
        mov     eax, [eax + SOCKET.PrevPtr]
 
        DEBUGF  1, "SOCKET_free: linking socket %x to socket %x\n", eax, ebx
 
        test    eax, eax
        jz      @f
        mov     [eax + SOCKET.NextPtr], ebx
       @@:
 
        test    ebx, ebx
        jz      @f
        mov     [ebx + SOCKET.PrevPtr], eax
       @@:
 
        call    kernel_free
        pop     ebx
 
        DEBUGF  1, "SOCKET_free: success!\n"
 
  .error:
        ret
 
;------------------------------------
;
; SOCKET_fork
;
; Create a child socket
;
; IN:  socket nr in ebx
; OUT: child socket nr in eax
;
;-----------------------------------
align 4
SOCKET_fork:
 
        DEBUGF  1,"SOCKET_fork: %x\n", ebx
 
; Exit if backlog queue is full
        mov     eax, [ebx + SOCKET_QUEUE_LOCATION + queue.size]
        cmp     ax, [ebx + SOCKET.backlog]
        jae     .fail
 
; Allocate new socket
        push    ebx
        call    SOCKET_alloc
        pop     ebx
        jz      .fail
 
        push    eax
        mov     esi, esp
        add_to_queue (ebx + SOCKET_QUEUE_LOCATION), MAX_backlog, 4, .fail2
        pop     eax
 
; Copy structure from current socket to new
; We start at PID to preserve the socket num, and the 2 pointers at beginning of socket
        lea     esi, [ebx + SOCKET.PID]
        lea     edi, [eax + SOCKET.PID]
        mov     ecx, (SOCKET_QUEUE_LOCATION - SOCKET.PID + 3)/4
        rep     movsd
 
        and     [eax + SOCKET.options], not SO_ACCEPTCON
 
        ret
 
  .fail2:
        add     esp, 4+4+4
  .fail:
        DEBUGF  1,"SOCKET_fork: failed\n"
        xor     eax, eax
        ret
 
 
;---------------------------------------------------
;
; SOCKET_num_to_ptr
;
; Get socket structure address by its number
;
; IN:  ecx = socket number
; OUT: eax = 0 on error, socket ptr otherwise
;       ZF = set on error
;
;---------------------------------------------------
align 4
SOCKET_num_to_ptr:
 
        DEBUGF  1,"SOCKET_num_to_ptr: num=%u ", ecx
 
        mov     eax, net_sockets
 
  .next_socket:
        mov     eax, [eax + SOCKET.NextPtr]
        or      eax, eax
        jz      .error
        cmp     [eax + SOCKET.Number], ecx
        jne     .next_socket
 
        test    eax, eax
 
        DEBUGF  1,"ptr=%x\n", eax
        ret
 
  .error:
        DEBUGF  1,"not found\n", eax
        ret
 
 
;---------------------------------------------------
;
; SOCKET_ptr_to_num
;
; Get socket number by its address
;
; IN:  eax = socket ptr
; OUT: eax = 0 on error, socket num otherwise
;       ZF = set on error
;
;---------------------------------------------------
align 4
SOCKET_ptr_to_num:
 
        DEBUGF  1,"SOCKET_ptr_to_num: ptr=%x ", eax
 
        call    SOCKET_check
        jz      .error
 
        mov     eax, [eax + SOCKET.Number]
 
        DEBUGF  1,"num=%u\n", eax
        ret
 
  .error:
        DEBUGF  1,"not found\n", eax
        ret
 
 
;---------------------------------------------------
;
; SOCKET_check
;
; checks if the given value is really a socket ptr
;
; IN:  eax = socket ptr
; OUT: eax = 0 on error, unchanged otherwise
;       ZF = set on error
;
;---------------------------------------------------
align 4
SOCKET_check:
 
        DEBUGF  1,"SOCKET_check: %x\n", eax
 
        push    ebx
        mov     ebx, net_sockets
 
  .next_socket:
        mov     ebx, [ebx + SOCKET.NextPtr]
        or      ebx, ebx
        jz      .done
        cmp     ebx, eax
        jnz     .next_socket
 
  .done:
        mov     eax, ebx
        test    eax, eax
        pop     ebx
 
        ret
 
 
 
;---------------------------------------------------
;
; SOCKET_check_owner
;
; checks if the caller application owns the socket
;
; IN:  eax = socket ptr
; OUT:  ZF = true/false
;
;---------------------------------------------------
align 4
SOCKET_check_owner:
 
        DEBUGF  1,"SOCKET_check_owner: %x\n", eax
 
        push    ebx
        mov     ebx, [TASK_BASE]
        mov     ebx, [ecx + TASKDATA.pid]
        cmp     [eax + SOCKET.PID], ebx
        pop      ebx
 
        ret
 
 
 
 
;------------------------------------------------------
;
; SOCKET_process_end
;
; Kernel calls this function when a certain process ends
; This function will check if the process had any open sockets
; And update them accordingly
;
; IN:  edx = pid
; OUT: /
;
;------------------------------------------------------
align 4
SOCKET_process_end:
 
        DEBUGF  1,"SOCKET_process_end: %x\n", edx
 
        push    ebx
        mov     ebx, net_sockets
 
  .next_socket:
        mov     ebx, [ebx + SOCKET.NextPtr]
  .test_socket:
        test    ebx, ebx
        jz      .done
 
        cmp     [ebx + SOCKET.PID], edx
        jne     .next_socket
 
        DEBUGF  1,"SOCKET_process_end: killing socket %x\n", ebx
 
        mov     [ebx + SOCKET.PID], 0
 
        cmp     [ebx + SOCKET.Protocol], IP_PROTO_TCP
        je      .tcp
 
; The socket is stateless, just kill it right away!
 
        mov     eax, ebx
        mov     ebx, [ebx + SOCKET.NextPtr]
        call    SOCKET_free
        jmp     .test_socket
 
  .tcp:
        push    [ebx + SOCKET.NextPtr]
        mov     eax, ebx
        call    TCP_disconnect
        pop     ebx
        jmp     .test_socket
 
  .done:
        pop     ebx
 
        ret
 
 
 
 
;-----------------------------------------------------------------
;
; SOCKET_is_connecting
;
;  IN:  eax = socket ptr
;  OUT: /
;
;-----------------------------------------------------------------
 
align 4
SOCKET_is_connecting:
 
        DEBUGF  1,"SOCKET_is_connecting: %x\n", eax
 
        and     [eax + SOCKET.options], not (SS_ISCONNECTED + SS_ISDISCONNECTING + SS_ISCONFIRMING)
        or      [eax + SOCKET.options], SS_ISCONNECTING
 
        jmp     SOCKET_notify_owner
 
 
 
;-----------------------------------------------------------------
;
; SOCKET_is_connected
;
;  IN:  eax = socket ptr
;  OUT: /
;
;-----------------------------------------------------------------
 
align 4
SOCKET_is_connected:
 
        DEBUGF  1,"SOCKET_is_connected: %x\n", eax
 
        and     [eax + SOCKET.options], not (SS_ISCONNECTING + SS_ISDISCONNECTING + SS_ISCONFIRMING)
        or      [eax + SOCKET.options], SS_ISCONNECTED
 
        jmp     SOCKET_notify_owner
 
 
 
 
;-----------------------------------------------------------------
;
; SOCKET_is_disconnecting
;
;  IN:  eax = socket ptr
;  OUT: /
;
;-----------------------------------------------------------------
 
align 4
SOCKET_is_disconnecting:
 
        DEBUGF  1,"SOCKET_is_disconnecting: %x\n", eax
 
        and     [eax + SOCKET.options], not (SS_ISCONNECTING)
        or      [eax + SOCKET.options], SS_ISDISCONNECTING + SS_CANTRCVMORE + SS_CANTSENDMORE
 
        jmp     SOCKET_notify_owner
 
 
 
;-----------------------------------------------------------------
;
; SOCKET_is_disconnected
;
;  IN:  eax = socket ptr
;  OUT: /
;
;-----------------------------------------------------------------
 
align 4
SOCKET_is_disconnected:
 
        DEBUGF  1,"SOCKET_is_disconnected: %x\n", eax
 
        and     [eax + SOCKET.options], not (SS_ISCONNECTING + SS_ISCONNECTED + SS_ISDISCONNECTING)
        or      [eax + SOCKET.options], SS_CANTRCVMORE + SS_CANTSENDMORE
 
        jmp     SOCKET_notify_owner
 
 
;-----------------------------------------------------------------
;
; SOCKET_cant_recv_more
;
;  IN:  eax = socket ptr
;  OUT: /
;
;-----------------------------------------------------------------
 
align 4
SOCKET_cant_recv_more:
 
        DEBUGF  1,"SOCKET_cant_recv_more: %x\n", eax
 
        or      [eax + SOCKET.options], SS_CANTRCVMORE
 
        ret
 
 
 
;-----------------------------------------------------------------
;
; SOCKET_cant_send_more
;
;  IN:  eax = socket ptr
;  OUT: /
;
;-----------------------------------------------------------------
 
align 4
SOCKET_cant_send_more:
 
        DEBUGF  1,"SOCKET_cant_send_more: %x\n", eax
 
        or      [eax + SOCKET.options], SS_CANTSENDMORE
 
        ret

Rev 2993	Rev 2994
1	;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;	1	;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2	;; ;;	2	;; ;;
3	;; Copyright (C) KolibriOS team 2004-2012. All rights reserved. ;;	3	;; Copyright (C) KolibriOS team 2004-2012. All rights reserved. ;;
4	;; Distributed under terms of the GNU General Public License ;;	4	;; Distributed under terms of the GNU General Public License ;;
5	;; ;;	5	;; ;;
6	;; Part of the tcp/ip network stack for KolibriOS ;;	6	;; Part of the tcp/ip network stack for KolibriOS ;;
7	;; ;;	7	;; ;;
8	;; Written by hidnplayr@kolibrios.org, ;;	8	;; Written by hidnplayr@kolibrios.org, ;;
9	;; and Clevermouse. ;;	9	;; and Clevermouse. ;;
10	;; ;;	10	;; ;;
11	;; Based on code by mike.dld ;;	11	;; Based on code by mike.dld ;;
12	;; ;;	12	;; ;;
13	;; GNU GENERAL PUBLIC LICENSE ;;	13	;; GNU GENERAL PUBLIC LICENSE ;;
14	;; Version 2, June 1991 ;;	14	;; Version 2, June 1991 ;;
15	;; ;;	15	;; ;;
16	;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;	16	;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
17		17
18	$Revision: 2993 $	18	$Revision: 2994 $
19		19
20		20
21	struct SOCKET	21	struct SOCKET
22		22
23	NextPtr dd ? ; pointer to next socket in list	23	NextPtr dd ? ; pointer to next socket in list
24	PrevPtr dd ? ; pointer to previous socket in list	24	PrevPtr dd ? ; pointer to previous socket in list
25	Number dd ? ; socket number	25	Number dd ? ; socket number
26		26
27	mutex MUTEX	27	mutex MUTEX
28		28
29	PID dd ? ; application process id	29	PID dd ? ; application process id
30	Domain dd ? ; INET/UNIX/..	30	Domain dd ? ; INET/UNIX/..
31	Type dd ? ; RAW/STREAM/DGRAP	31	Type dd ? ; RAW/STREAM/DGRAP
32	Protocol dd ? ; ICMP/IPv4/ARP/TCP/UDP	32	Protocol dd ? ; ICMP/IPv4/ARP/TCP/UDP
33	errorcode dd ?	33	errorcode dd ?
34	device dd ?	34	device dd ?
35		35
36	options dd ?	36	options dd ?
37	state dd ?	37	state dd ?
38	backlog dw ? ; how many incomming connections that can be queued	38	backlog dw ? ; how many incomming connections that can be queued
39		39
40	snd_proc dd ?	40	snd_proc dd ?
41	rcv_proc dd ?	41	rcv_proc dd ?
42		42
43	ends	43	ends
44		44
45	struct IP_SOCKET SOCKET	45	struct IP_SOCKET SOCKET
46		46
47	LocalIP rd 4	47	LocalIP rd 4
48	RemoteIP rd 4	48	RemoteIP rd 4
49		49
50	ends	50	ends
51		51
52	struct TCP_SOCKET IP_SOCKET	52	struct TCP_SOCKET IP_SOCKET
53		53
54	LocalPort dw ?	54	LocalPort dw ?
55	RemotePort dw ?	55	RemotePort dw ?
56		56
57	t_state dd ? ; TCB state	57	t_state dd ? ; TCB state
58	t_rxtshift db ?	58	t_rxtshift db ?
59	rb 3 ; align	59	rb 3 ; align
60	t_rxtcur dd ?	60	t_rxtcur dd ?
61	t_dupacks dd ?	61	t_dupacks dd ?
62	t_maxseg dd ?	62	t_maxseg dd ?
63	t_force dd ?	63	t_force dd ?
64	t_flags dd ?	64	t_flags dd ?
65		65
66	;---------------	66	;---------------
67	; RFC783 page 21	67	; RFC783 page 21
68		68
69	; send sequence	69	; send sequence
70	SND_UNA dd ? ; sequence number of unack'ed sent Packets	70	SND_UNA dd ? ; sequence number of unack'ed sent Packets
71	SND_NXT dd ? ; next send sequence number to use	71	SND_NXT dd ? ; next send sequence number to use
72	SND_UP dd ? ; urgent pointer	72	SND_UP dd ? ; urgent pointer
73	SND_WL1 dd ? ; window minus one	73	SND_WL1 dd ? ; window minus one
74	SND_WL2 dd ? ;	74	SND_WL2 dd ? ;
75	ISS dd ? ; initial send sequence number	75	ISS dd ? ; initial send sequence number
76	SND_WND dd ? ; send window	76	SND_WND dd ? ; send window
77		77
78	; receive sequence	78	; receive sequence
79	RCV_WND dd ? ; receive window	79	RCV_WND dd ? ; receive window
80	RCV_NXT dd ? ; next receive sequence number to use	80	RCV_NXT dd ? ; next receive sequence number to use
81	RCV_UP dd ? ; urgent pointer	81	RCV_UP dd ? ; urgent pointer
82	IRS dd ? ; initial receive sequence number	82	IRS dd ? ; initial receive sequence number
83		83
84	;---------------------	84	;---------------------
85	; Additional variables	85	; Additional variables
86		86
87	; receive variables	87	; receive variables
88	RCV_ADV dd ?	88	RCV_ADV dd ?
89		89
90	; retransmit variables	90	; retransmit variables
91	SND_MAX dd ?	91	SND_MAX dd ?
92		92
93	; congestion control	93	; congestion control
94	SND_CWND dd ?	94	SND_CWND dd ?
95	SND_SSTHRESH dd ?	95	SND_SSTHRESH dd ?
96		96
97	;----------------------	97	;----------------------
98	; Transmit timing stuff	98	; Transmit timing stuff
99	t_idle dd ?	99	t_idle dd ?
100	t_rtt dd ?	100	t_rtt dd ?
101	t_rtseq dd ?	101	t_rtseq dd ?
102	t_srtt dd ?	102	t_srtt dd ?
103	t_rttvar dd ?	103	t_rttvar dd ?
104	t_rttmin dd ?	104	t_rttmin dd ?
105	max_sndwnd dd ?	105	max_sndwnd dd ?
106		106
107	;-----------------	107	;-----------------
108	; Out-of-band data	108	; Out-of-band data
109	t_oobflags dd ?	109	t_oobflags dd ?
110	t_iobc dd ?	110	t_iobc dd ?
111	t_softerror dd ?	111	t_softerror dd ?
112		112
113		113
114	;---------	114	;---------
115	; RFC 1323 ; the order of next 4 elements may not change	115	; RFC 1323 ; the order of next 4 elements may not change
116		116
117	SND_SCALE db ?	117	SND_SCALE db ?
118	RCV_SCALE db ?	118	RCV_SCALE db ?
119	requested_s_scale db ?	119	requested_s_scale db ?
120	request_r_scale db ?	120	request_r_scale db ?
121		121
122	ts_recent dd ? ; a copy of the most-recent valid timestamp from the other end	122	ts_recent dd ? ; a copy of the most-recent valid timestamp from the other end
123	ts_recent_age dd ?	123	ts_recent_age dd ?
124	last_ack_sent dd ?	124	last_ack_sent dd ?
125		125
126		126
127	;-------	127	;-------
128	; Timers	128	; Timers
129	timer_retransmission dd ? ; rexmt	129	timer_retransmission dd ? ; rexmt
130	timer_persist dd ?	130	timer_persist dd ?
131	timer_keepalive dd ? ; keepalive/syn timeout	131	timer_keepalive dd ? ; keepalive/syn timeout
132	timer_timed_wait dd ? ; also used as 2msl timer	132	timer_timed_wait dd ? ; also used as 2msl timer
133		133
134	; extra	134	; extra
135		135
136	ts_ecr dd ? ; timestamp echo reply	136	ts_ecr dd ? ; timestamp echo reply
137	ts_val dd ?	137	ts_val dd ?
138	temp_bits db ?	138	temp_bits db ?
139		139
140	ends	140	ends
141		141
142	struct UDP_SOCKET IP_SOCKET	142	struct UDP_SOCKET IP_SOCKET
143		143
144	LocalPort dw ?	144	LocalPort dw ?
145	RemotePort dw ?	145	RemotePort dw ?
146	firstpacket db ?	146	firstpacket db ?
147		147
148	ends	148	ends
149		149
150		150
151	struct ICMP_SOCKET IP_SOCKET	151	struct ICMP_SOCKET IP_SOCKET
152		152
153	Identifier dw ?	153	Identifier dw ?
154		154
155	ends	155	ends
156		156
157		157
158	struct RING_BUFFER	158	struct RING_BUFFER
159		159
160	start_ptr dd ? ; Pointer to start of buffer	160	start_ptr dd ? ; Pointer to start of buffer
161	end_ptr dd ? ; pointer to end of buffer	161	end_ptr dd ? ; pointer to end of buffer
162	read_ptr dd ? ; Read pointer	162	read_ptr dd ? ; Read pointer
163	write_ptr dd ? ; Write pointer	163	write_ptr dd ? ; Write pointer
164	size dd ? ; Number of bytes buffered	164	size dd ? ; Number of bytes buffered
165		165
166	ends	166	ends
167		167
168	struct STREAM_SOCKET TCP_SOCKET	168	struct STREAM_SOCKET TCP_SOCKET
169		169
170	rcv RING_BUFFER	170	rcv RING_BUFFER
171	snd RING_BUFFER	171	snd RING_BUFFER
172		172
173	ends	173	ends
174		174
175	struct socket_queue_entry	175	struct socket_queue_entry
176		176
177	data_ptr dd ?	177	data_ptr dd ?
178	buf_ptr dd ?	178	buf_ptr dd ?
179	data_size dd ?	179	data_size dd ?
180		180
181	ends	181	ends
182		182
183		183
184	SOCKETBUFFSIZE = 4096 ; in bytes	184	SOCKETBUFFSIZE = 4096 ; in bytes
185		185
186	SOCKET_QUEUE_SIZE = 10 ; maximum number ofincoming packets queued for 1 socket	186	SOCKET_QUEUE_SIZE = 10 ; maximum number ofincoming packets queued for 1 socket
187	; the incoming packet queue for sockets is placed in the socket struct itself, at this location from start	187	; the incoming packet queue for sockets is placed in the socket struct itself, at this location from start
188	SOCKET_QUEUE_LOCATION = (SOCKETBUFFSIZE - SOCKET_QUEUE_SIZE*sizeof.socket_queue_entry - sizeof.queue)	188	SOCKET_QUEUE_LOCATION = (SOCKETBUFFSIZE - SOCKET_QUEUE_SIZE*sizeof.socket_queue_entry - sizeof.queue)
189		189
190	uglobal	190	uglobal
191	net_sockets rd 4	191	net_sockets rd 4
192	last_socket_num dd ?	192	last_socket_num dd ?
193	last_UDP_port dw ? ; These values give the number of the last used ephemeral port	193	last_UDP_port dw ? ; These values give the number of the last used ephemeral port
194	last_TCP_port dw ? ;	194	last_TCP_port dw ? ;
195	endg	195	endg
196		196
197		197
198	;-----------------------------------------------------------------	198	;-----------------------------------------------------------------
199	;	199	;
200	; SOCKET_init	200	; SOCKET_init
201	;	201	;
202	;-----------------------------------------------------------------	202	;-----------------------------------------------------------------
203	macro SOCKET_init {	203	macro SOCKET_init {
204		204
205	xor eax, eax	205	xor eax, eax
206	mov edi, net_sockets	206	mov edi, net_sockets
207	mov ecx, 5	207	mov ecx, 5
208	rep stosd	208	rep stosd
209		209
210	@@:	210	@@:
211	pseudo_random eax	211	pseudo_random eax
212	cmp ax, MIN_EPHEMERAL_PORT	212	cmp ax, MIN_EPHEMERAL_PORT
213	jb @r	213	jb @r
214	cmp ax, MAX_EPHEMERAL_PORT	214	cmp ax, MAX_EPHEMERAL_PORT
215	ja @r	215	ja @r
216	mov [last_UDP_port], ax	216	mov [last_UDP_port], ax
217		217
218	@@:	218	@@:
219	pseudo_random eax	219	pseudo_random eax
220	cmp ax, MIN_EPHEMERAL_PORT	220	cmp ax, MIN_EPHEMERAL_PORT
221	jb @r	221	jb @r
222	cmp ax, MAX_EPHEMERAL_PORT	222	cmp ax, MAX_EPHEMERAL_PORT
223	ja @r	223	ja @r
224	mov [last_TCP_port], ax	224	mov [last_TCP_port], ax
225		225
226	}	226	}
227		227
228		228
229	;-----------------------------------------------------------------	229	;-----------------------------------------------------------------
230	;	230	;
-		231	; SOCKET_block
-		232	;
-		233	;-----------------------------------------------------------------
-		234	macro SOCKET_block socket, loop, done {
-		235
-		236	test [socket + SOCKET.options], SO_BLOCK ; Is this a blocking socket?
-		237	jz done ; No, return immediately
-		238
-		239	push esi
-		240	mov esi, 5 ; yes, wait for event
-		241	call delay_ms
-		242	pop esi
-		243
-		244	jmp loop
-		245
-		246	}
-		247
-		248
-		249	;-----------------------------------------------------------------
-		250	;
231	; Socket API (function 74)	251	; Socket API (function 74)
232	;	252	;
233	;-----------------------------------------------------------------	253	;-----------------------------------------------------------------
234	align 4	254	align 4
235	sys_socket:	255	sys_socket:
236		256
237	cmp ebx, 255	257	cmp ebx, 255
238	jz SOCKET_debug	258	jz SOCKET_debug
239		259
240	cmp ebx, .number	260	cmp ebx, .number
241	ja s_error	261	ja s_error
242	jmp dword [.table + 4*ebx]	262	jmp dword [.table + 4*ebx]
243		263
244	.table:	264	.table:
245	dd SOCKET_open ; 0	265	dd SOCKET_open ; 0
246	dd SOCKET_close ; 1	266	dd SOCKET_close ; 1
247	dd SOCKET_bind ; 2	267	dd SOCKET_bind ; 2
248	dd SOCKET_listen ; 3	268	dd SOCKET_listen ; 3
249	dd SOCKET_connect ; 4	269	dd SOCKET_connect ; 4
250	dd SOCKET_accept ; 5	270	dd SOCKET_accept ; 5
251	dd SOCKET_send ; 6	271	dd SOCKET_send ; 6
252	dd SOCKET_receive ; 7	272	dd SOCKET_receive ; 7
253	dd SOCKET_set_opt ; 8	273	dd SOCKET_set_opt ; 8
254	dd SOCKET_get_opt ; 9	274	dd SOCKET_get_opt ; 9
255	.number = ($ - .table) / 4 - 1	275	.number = ($ - .table) / 4 - 1
256		276
257	s_error:	277	s_error:
258	DEBUGF 1,"socket error\n"	278	DEBUGF 1,"socket error\n"
259	mov dword [esp+32], -1	279	mov dword [esp+32], -1
260		280
261	ret	281	ret
262		282
263		283
264		284
265	;-----------------------------------------------------------------	285	;-----------------------------------------------------------------
266	;	286	;
267	; SOCKET_open	287	; SOCKET_open
268	;	288	;
269	; IN: domain in ecx	289	; IN: domain in ecx
270	; type in edx	290	; type in edx
271	; protocol in esi	291	; protocol in esi
272	; OUT: eax is socket num, -1 on error	292	; OUT: eax is socket num, -1 on error
273	;	293	;
274	;-----------------------------------------------------------------	294	;-----------------------------------------------------------------
275	align 4	295	align 4
276	SOCKET_open:	296	SOCKET_open:
277		297
278	DEBUGF 1,"SOCKET_open: domain=%u type=%u protocol=%x\n", ecx, edx, esi	298	DEBUGF 1,"SOCKET_open: domain=%u type=%u protocol=%x\n", ecx, edx, esi
279		299
280	push ecx edx esi	300	push ecx edx esi
281	call SOCKET_alloc	301	call SOCKET_alloc
282	pop esi edx ecx	302	pop esi edx ecx
283	jz s_error	303	jz s_error
284		304
285	mov [esp+32], edi ; return socketnumber	305	mov [esp+32], edi ; return socketnumber
286		306
287	mov [eax + SOCKET.Domain], ecx	307	mov [eax + SOCKET.Domain], ecx
288	mov [eax + SOCKET.Type], edx	308	mov [eax + SOCKET.Type], edx
289	mov [eax + SOCKET.Protocol], esi	309	mov [eax + SOCKET.Protocol], esi
290		310
291	cmp ecx, AF_INET4	311	cmp ecx, AF_INET4
292	jne .no_inet4	312	jne .no_inet4
293		313
294	cmp edx, SOCK_DGRAM	314	cmp edx, SOCK_DGRAM
295	je .udp	315	je .udp
296		316
297	cmp edx, SOCK_STREAM	317	cmp edx, SOCK_STREAM
298	je .tcp	318	je .tcp
299		319
300	cmp edx, SOCK_RAW	320	cmp edx, SOCK_RAW
301	je .raw	321	je .raw
302		322
303	.no_inet4:	323	.no_inet4:
304	cmp ecx, AF_PPP	324	cmp ecx, AF_PPP
305	jne .no_ppp	325	jne .no_ppp
306		326
307	cmp esi, PPP_PROTO_ETHERNET	327	cmp esi, PPP_PROTO_ETHERNET
308	je .pppoe	328	je .pppoe
309		329
310	.no_ppp:	330	.no_ppp:
311	ret	331	ret
312		332
313	align 4	333	align 4
314	.raw:	334	.raw:
315	test esi, esi ; IP_PROTO_IP	335	test esi, esi ; IP_PROTO_IP
316	jz .ip	336	jz .ip
317		337
318	cmp esi, IP_PROTO_ICMP	338	cmp esi, IP_PROTO_ICMP
319	je .icmp	339	je .icmp
320		340
321	cmp esi, IP_PROTO_UDP	341	cmp esi, IP_PROTO_UDP
322	je .udp	342	je .udp
323		343
324	cmp esi, IP_PROTO_TCP	344	cmp esi, IP_PROTO_TCP
325	je .tcp	345	je .tcp
326		346
327	ret	347	ret
328		348
329	align 4	349	align 4
330	.udp:	350	.udp:
331	mov [eax + SOCKET.Protocol], IP_PROTO_UDP	351	mov [eax + SOCKET.Protocol], IP_PROTO_UDP
332	mov [eax + SOCKET.snd_proc], SOCKET_send_udp	352	mov [eax + SOCKET.snd_proc], SOCKET_send_udp
333	mov [eax + SOCKET.rcv_proc], SOCKET_receive_dgram	353	mov [eax + SOCKET.rcv_proc], SOCKET_receive_dgram
334	ret	354	ret
335		355
336	align 4	356	align 4
337	.tcp:	357	.tcp:
338	mov [eax + SOCKET.Protocol], IP_PROTO_TCP	358	mov [eax + SOCKET.Protocol], IP_PROTO_TCP
339	mov [eax + SOCKET.snd_proc], SOCKET_send_tcp	359	mov [eax + SOCKET.snd_proc], SOCKET_send_tcp
340	mov [eax + SOCKET.rcv_proc], SOCKET_receive_tcp	360	mov [eax + SOCKET.rcv_proc], SOCKET_receive_tcp
341		361
342	TCP_init_socket eax	362	TCP_init_socket eax
343	ret	363	ret
344		364
345		365
346	align 4	366	align 4
347	.ip:	367	.ip:
348	mov [eax + SOCKET.snd_proc], SOCKET_send_ip	368	mov [eax + SOCKET.snd_proc], SOCKET_send_ip
349	mov [eax + SOCKET.rcv_proc], SOCKET_receive_dgram	369	mov [eax + SOCKET.rcv_proc], SOCKET_receive_dgram
350	ret	370	ret
351		371
352		372
353	align 4	373	align 4
354	.icmp:	374	.icmp:
355	mov [eax + SOCKET.snd_proc], SOCKET_send_icmp	375	mov [eax + SOCKET.snd_proc], SOCKET_send_icmp
356	mov [eax + SOCKET.rcv_proc], SOCKET_receive_dgram	376	mov [eax + SOCKET.rcv_proc], SOCKET_receive_dgram
357	ret	377	ret
358		378
359	align 4	379	align 4
360	.pppoe:	380	.pppoe:
361	push eax	381	push eax
362	init_queue (eax + SOCKET_QUEUE_LOCATION) ; Set up data receiving queue	382	init_queue (eax + SOCKET_QUEUE_LOCATION) ; Set up data receiving queue
363	pop eax	383	pop eax
364		384
365	mov [eax + SOCKET.snd_proc], SOCKET_send_pppoe	385	mov [eax + SOCKET.snd_proc], SOCKET_send_pppoe
366	mov [eax + SOCKET.rcv_proc], SOCKET_receive_dgram	386	mov [eax + SOCKET.rcv_proc], SOCKET_receive_dgram
367	ret	387	ret
368		388
369		389
370	;-----------------------------------------------------------------	390	;-----------------------------------------------------------------
371	;	391	;
372	; SOCKET_bind	392	; SOCKET_bind
373	;	393	;
374	; IN: socket number in ecx	394	; IN: socket number in ecx
375	; pointer to sockaddr struct in edx	395	; pointer to sockaddr struct in edx
376	; length of that struct in esi	396	; length of that struct in esi
377	; OUT: 0 on success	397	; OUT: 0 on success
378	;	398	;
379	;-----------------------------------------------------------------	399	;-----------------------------------------------------------------
380	align 4	400	align 4
381	SOCKET_bind:	401	SOCKET_bind:
382		402
383	DEBUGF 1,"SOCKET_bind: socknum=%u sockaddr=%x length=%u\n", ecx, edx, esi	403	DEBUGF 1,"SOCKET_bind: socknum=%u sockaddr=%x length=%u\n", ecx, edx, esi
384		404
385	call SOCKET_num_to_ptr	405	call SOCKET_num_to_ptr
386	jz s_error	406	jz s_error
387		407
388	cmp esi, 2	408	cmp esi, 2
389	jb s_error	409	jb s_error
390		410
391	cmp word [edx], AF_INET4	411	cmp word [edx], AF_INET4
392	je .af_inet4	412	je .af_inet4
393		413
394	cmp word [edx], AF_UNIX	414	cmp word [edx], AF_UNIX
395	je .af_unix	415	je .af_unix
396		416
397	jmp s_error	417	jmp s_error
398		418
399	.af_unix:	419	.af_unix:
400	; TODO: write code here	420	; TODO: write code here
401		421
402	mov dword [esp+32], 0	422	mov dword [esp+32], 0
403	ret	423	ret
404		424
405	.af_inet4:	425	.af_inet4:
406		426
407	cmp esi, 6	427	cmp esi, 6
408	jb s_error	428	jb s_error
409		429
410	cmp [eax + SOCKET.Protocol], IP_PROTO_UDP	430	cmp [eax + SOCKET.Protocol], IP_PROTO_UDP
411	je .udp	431	je .udp
412		432
413	cmp [eax + SOCKET.Protocol], IP_PROTO_TCP	433	cmp [eax + SOCKET.Protocol], IP_PROTO_TCP
414	je .tcp	434	je .tcp
415		435
416	jmp s_error	436	jmp s_error
417		437
418	.tcp:	438	.tcp:
419	.udp:	439	.udp:
420		440
421	mov ebx, [edx + 4] ; First, fill in the IP	441	mov ebx, [edx + 4] ; First, fill in the IP
422	test ebx, ebx ; If IP is 0, use default	442	test ebx, ebx ; If IP is 0, use default
423	jnz @f	443	jnz @f
424	mov ebx, [NET_DEFAULT]	444	mov ebx, [NET_DEFAULT]
425	mov ebx, [IP_LIST + 4*ebx]	445	mov ebx, [IP_LIST + 4*ebx]
426	@@:	446	@@:
427	mov [eax + IP_SOCKET.LocalIP], ebx	447	mov [eax + IP_SOCKET.LocalIP], ebx
428		448
429	mov bx, [edx + 2] ; Now fill in the port if it's still available	449	mov bx, [edx + 2] ; Now fill in the port if it's still available
430	call SOCKET_check_port	450	call SOCKET_check_port
431	jz s_error ; ZF is set by socket_check_port, on error	451	jz s_error ; ZF is set by socket_check_port, on error
432		452
433	DEBUGF 1,"SOCKET_bind: local ip=%u.%u.%u.%u\n",\	453	DEBUGF 1,"SOCKET_bind: local ip=%u.%u.%u.%u\n",\
434	[eax + IP_SOCKET.LocalIP + 0]:1,[eax + IP_SOCKET.LocalIP + 1]:1,\	454	[eax + IP_SOCKET.LocalIP + 0]:1,[eax + IP_SOCKET.LocalIP + 1]:1,\
435	[eax + IP_SOCKET.LocalIP + 2]:1,[eax + IP_SOCKET.LocalIP + 3]:1	455	[eax + IP_SOCKET.LocalIP + 2]:1,[eax + IP_SOCKET.LocalIP + 3]:1
436		456
437	mov dword [esp+32], 0	457	mov dword [esp+32], 0
438	ret	458	ret
439		459
440		460
441		461
442		462
443	;-----------------------------------------------------------------	463	;-----------------------------------------------------------------
444	;	464	;
445	; SOCKET_connect	465	; SOCKET_connect
446	;	466	;
447	; IN: socket number in ecx	467	; IN: socket number in ecx
448	; pointer to sockaddr struct in edx	468	; pointer to sockaddr struct in edx
449	; length of that struct in esi	469	; length of that struct in esi
450	; OUT: 0 on success	470	; OUT: 0 on success
451	;	471	;
452	;-----------------------------------------------------------------	472	;-----------------------------------------------------------------
453	align 4	473	align 4
454	SOCKET_connect:	474	SOCKET_connect:
455		475
456	DEBUGF 1,"SOCKET_connect: socknum=%u sockaddr=%x length=%u\n", ecx, edx, esi	476	DEBUGF 1,"SOCKET_connect: socknum=%u sockaddr=%x length=%u\n", ecx, edx, esi
457		477
458	call SOCKET_num_to_ptr	478	call SOCKET_num_to_ptr
459	jz s_error	479	jz s_error
460		480
461	cmp esi, 8	481	cmp esi, 8
462	jb s_error	482	jb s_error
463		483
464	cmp word [edx], AF_INET4	484	cmp word [edx], AF_INET4
465	je .af_inet4	485	je .af_inet4
466		486
467	jmp s_error	487	jmp s_error
468		488
469	.af_inet4:	489	.af_inet4:
470	cmp [eax + IP_SOCKET.LocalIP], 0	490	cmp [eax + IP_SOCKET.LocalIP], 0
471	jne @f	491	jne @f
472	push [IP_LIST]	492	push [IP_LIST]
473	pop [eax + IP_SOCKET.LocalIP]	493	pop [eax + IP_SOCKET.LocalIP]
474	@@:	494	@@:
475		495
476	cmp [eax + SOCKET.Protocol], IP_PROTO_UDP	496	cmp [eax + SOCKET.Protocol], IP_PROTO_UDP
477	je .udp	497	je .udp
478		498
479	cmp [eax + SOCKET.Protocol], IP_PROTO_TCP	499	cmp [eax + SOCKET.Protocol], IP_PROTO_TCP
480	je .tcp	500	je .tcp

Subversion Repositories Kolibri OS

(root)/kernel/branches/net/network/socket.inc @ 2995 – Rev 2993 → 2994