Subversion Repositories Kolibri OS

Compare Revisions

No changes between revisions

Regard whitespace Rev 108 → Rev 109

/programs/system/end/trunk/end.asm
0,0 → 1,211
;
; END
;
; <diamond> note that 'mov al,xx' is shorter than 'mov eax,xx'
; and if we know that high 24 bits of eax are zero, we can use 1st form
; the same about ebx,ecx,edx
 
include "lang.inc"
include "macros.inc"
 
meos_app_start
code
 
do_draw:
 
mov eax,48
mov ebx,3
mov ecx,sc
mov edx,sizeof.system_colors
int 0x40
 
mov al,12 ; eax=12 - tell os about redraw start
mov bl,1
int 0x40
 
mov al,14 ; eax=14 - get screen max x & max y
int 0x40
 
movzx ecx,ax
 
shr eax,17
; sub eax,110
shl eax,16
; mov ebx,eax
; add ebx,220
lea ebx,[eax-110*10000h+220]
 
shr ecx,1
; sub ecx,50
shl ecx,16
; add ecx,100
sub ecx,50*10000h - 100
 
mov eax,0 ; define and draw window
mov edx,[sc.work_button]
mov esi,edx ;[sc.work_button]
xor edi,edi
int 0x40
 
xor edx,edx
mov al,13
mcall ,14 shl 16+90,25 shl 16+27
push ebx
mcall ,117 shl 16+90,
xchg ebx,[esp]
mcall ,,59 shl 16+27
pop ebx
mcall
 
mov al,8
inc edx
mcall ,15 shl 16+87,26 shl 16+24,,0xdd7700
inc edx
mcall ,118 shl 16+87,,,0xbbbb ;cccc
inc edx
mcall ,15 shl 16+87,60 shl 16+24,,0xbb00
inc edx
mcall ,118 shl 16+87,,,0xbbbbbb ;cccccc
 
mov al,4 ; 0x00000004 = write text
mov ebx,75*65536+10
mov ecx,[sc.work_button_text] ; 8b window nro - RR GG BB color
or ecx,0x10000000
mov edx,label1 ; pointer to text beginning
mov esi,label1_len ; text length
int 0x40
 
mov ecx,0x10ffffff
mov ebx,25*65536+30
mov edx,label2 ; pointer to text beginning
mov esi,label2_len ; text length
int 0x40
 
mov ebx,20*65536+64
mov edx,label3 ; pointer to text beginning
mov esi,label3_len ; text length
int 0x40
 
mov ecx,0xffffff
mov ebx,45*65536+41
mov edx,label4 ; pointer to text beginning
mov esi,label4_len ; text length
int 0x40
 
mov ebx,40*65536+75
mov edx,label5 ; pointer to text beginning
mov esi,label5_len ; text length
int 0x40
 
mov al,12 ; tell os about redraw end
mov ebx,2
int 0x40
 
still:
 
mov eax,10 ; wait here for event
int 0x40
 
dec eax
jz do_draw
dec eax
jnz button
key:
mov al,2 ; now eax=2 - get key code
int 40h
mov al,ah
cmp al,13
jz restart
cmp al,27
jz close_1
cmp al,180
jz restart_kernel
cmp al,181
jz power_off
jmp still
 
button:
mov al,17 ; now eax=17 - get pressed button id
int 0x40
xchg al,ah
dec eax
jz power_off
dec eax
jz restart_kernel
dec eax
jz restart
; we have only one button left, this is close button
; dec eax
; jnz still
close_1:
or eax,-1
int 40h
 
power_off:
push 2
jmp mcall_and_close
 
restart:
push 3
jmp mcall_and_close
 
restart_kernel:
push 4
mcall_and_close:
pop ecx
mcall 18,9
jmp close_1
 
data
 
if lang eq ru
 
label1:
db '‚€˜ ‚›Ž:'
label1_len = $ - label1
 
label2:
db '‚›Š‹ž—ˆ’œ Ÿ„Ž'
label2_len = $ - label2
 
label3:
db '……‡€“‘Š Ž’Œ…€'
label3_len = $ - label3
 
label4:
db '(End) (Home)'
label4_len = $ - label4
 
label5:
db '(Enter) (Esc)'
label5_len = $ - label5
 
else
 
label1:
db ' SELECT:'
label1_len = $ - label1
 
label2:
db 'POWER OFF KERNEL'
label2_len = $ - label2
 
label3:
db ' RESTART CANCEL'
label3_len = $ - label3
 
label4:
db '(End) (Home)'
label4_len = $ - label4
 
label5:
db '(Enter) (Esc)'
label5_len = $ - label5
 
end if
 
 
udata
sc system_colors
 
meos_app_end
Property changes:
Added: svn:eol-style
+native
\ No newline at end of property
/programs/system/end/trunk/build_en.bat
0,0 → 1,4
@erase lang.inc
@echo lang fix en >lang.inc
@fasm end.asm end
@pause
/programs/system/end/trunk/build_ru.bat
0,0 → 1,4
@erase lang.inc
@echo lang fix ru >lang.inc
@fasm end.asm end
@pause
/programs/system/end/trunk/macros.inc
0,0 → 1,267
; new application structure
macro meos_app_start
{
use32
org 0x0
 
db 'MENUET01'
dd 0x01
dd __start
dd __end
dd __memory
dd __stack
 
if used __params & ~defined __params
dd __params
else
dd 0x0
end if
 
dd 0x0
}
MEOS_APP_START fix meos_app_start
 
macro code
{
__start:
}
CODE fix code
 
macro data
{
__data:
}
DATA fix data
 
macro udata
{
if used __params & ~defined __params
__params:
db 0
__end:
rb 255
else
__end:
end if
__udata:
}
UDATA fix udata
 
macro meos_app_end
{
align 32
rb 2048
__stack:
__memory:
}
MEOS_APP_END fix meos_app_end
 
 
; macro for defining multiline text data
struc mstr [sstring]
{
forward
local ssize
virtual at 0
db sstring
ssize = $
end virtual
dd ssize
db sstring
common
dd -1
}
 
 
; strings
macro sz name,[data] { ; from MFAR [mike.dld]
common
if used name
label name
end if
forward
if used name
db data
end if
common
if used name
.size = $-name
end if
}
 
macro lsz name,[lng,data] { ; from MFAR [mike.dld]
common
if used name
label name
end if
forward
if (used name)&(lang eq lng)
db data
end if
common
if used name
.size = $-name
end if
}
 
 
 
; easy system call macro
macro mpack dest, hsrc, lsrc
{
if (hsrc eqtype 0) & (lsrc eqtype 0)
mov dest, (hsrc) shl 16 + lsrc
else
if (hsrc eqtype 0) & (~lsrc eqtype 0)
mov dest, (hsrc) shl 16
add dest, lsrc
else
mov dest, hsrc
shl dest, 16
add dest, lsrc
end if
end if
}
 
macro __mov reg,a,b { ; mike.dld
if (~a eq)&(~b eq)
mpack reg,a,b
else if (~a eq)&(b eq)
mov reg,a
end if
}
 
macro mcall a,b,c,d,e,f { ; mike.dld
__mov eax,a
__mov ebx,b
__mov ecx,c
__mov edx,d
__mov esi,e
__mov edi,f
int 0x40
}
 
 
 
 
 
 
 
; optimize the code for size
__regs fix <eax,ebx,ecx,edx,esi,edi,ebp,esp>
 
macro add arg1,arg2
{
if (arg2 eqtype 0)
if (arg2) = 1
inc arg1
else
add arg1,arg2
end if
else
add arg1,arg2
end if
}
 
macro sub arg1,arg2
{
if (arg2 eqtype 0)
if (arg2) = 1
dec arg1
else
sub arg1,arg2
end if
else
sub arg1,arg2
end if
}
 
macro mov arg1,arg2
{
if (arg1 in __regs) & (arg2 eqtype 0)
if (arg2) = 0
xor arg1,arg1
else if (arg2) = 1
xor arg1,arg1
inc arg1
else if (arg2) = -1
or arg1,-1
else if (arg2) > -128 & (arg2) < 128
push arg2
pop arg1
else
mov arg1,arg2
end if
else
mov arg1,arg2
end if
}
 
 
macro struct name
{
virtual at 0
name name
sizeof.#name = $ - name
end virtual
}
 
; structures used in MeOS
struc process_information
{
.cpu_usage dd ? ; +0
.window_stack_position dw ? ; +4
.window_stack_value dw ? ; +6
.not_used1 dw ? ; +8
.process_name rb 12 ; +10
.memory_start dd ? ; +22
.used_memory dd ? ; +26
.PID dd ? ; +30
.x_start dd ? ; +34
.y_start dd ? ; +38
.x_size dd ? ; +42
.y_size dd ? ; +46
.slot_state dw ? ; +50
rb (1024-52)
}
struct process_information
 
struc system_colors
{
.frame dd ?
.grab dd ?
.grab_button dd ?
.grab_button_text dd ?
.grab_text dd ?
.work dd ?
.work_button dd ?
.work_button_text dd ?
.work_text dd ?
.work_graph dd ?
}
struct system_colors
 
 
; constants
 
; events
EV_IDLE = 0
EV_TIMER = 0
EV_REDRAW = 1
EV_KEY = 2
EV_BUTTON = 3
EV_EXIT = 4
EV_BACKGROUND = 5
EV_MOUSE = 6
EV_IPC = 7
EV_STACK = 8
 
; event mask bits for function 40
EVM_REDRAW = 1b
EVM_KEY = 10b
EVM_BUTTON = 100b
EVM_EXIT = 1000b
EVM_BACKGROUND = 10000b
EVM_MOUSE = 100000b
EVM_IPC = 1000000b
EVM_STACK = 10000000b
Property changes:
Added: svn:eol-style
+native
\ No newline at end of property