| /kernel/branches/hid/keyboard.inc |
|---|
| 0,0 → 1,343 |
| ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; |
| ;; ;; |
| ;; Copyright (C) KolibriOS team 2004-2007. All rights reserved. ;; |
| ;; Copyright (C) MenuetOS 2000-2004 Ville Mikael Turjanmaa ;; |
| ;; Distributed under terms of the GNU General Public License ;; |
| ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; |
| $Revision: 641 $ |
| ;// mike.dld [ |
| VKEY_LSHIFT = 0000000000000001b |
| VKEY_RSHIFT = 0000000000000010b |
| VKEY_LCONTROL = 0000000000000100b |
| VKEY_RCONTROL = 0000000000001000b |
| VKEY_LALT = 0000000000010000b |
| VKEY_RALT = 0000000000100000b |
| VKEY_CAPSLOCK = 0000000001000000b |
| VKEY_NUMLOCK = 0000000010000000b |
| VKEY_SCRLOCK = 0000000100000000b |
| VKEY_SHIFT = 0000000000000011b |
| VKEY_CONTROL = 0000000000001100b |
| VKEY_ALT = 0000000000110000b |
| uglobal |
| align 4 |
| kb_state dd 0 |
| ext_code db 0 |
| keyboard_mode db 0 |
| keyboard_data db 0 |
| altmouseb db 0 |
| ctrl_alt_del db 0 |
| kb_lights db 0 |
| align 4 |
| hotkey_scancodes rd 256 ; we have 256 scancodes |
| hotkey_list rd 256*4 ; max 256 defined hotkeys |
| hotkey_buffer rd 120*2 ; buffer for 120 hotkeys |
| endg |
| iglobal |
| hotkey_tests dd hotkey_test0 |
| dd hotkey_test1 |
| dd hotkey_test2 |
| dd hotkey_test3 |
| dd hotkey_test4 |
| hotkey_tests_num = 5 |
| endg |
| hotkey_test0: |
| test al, al |
| setz al |
| ret |
| hotkey_test1: |
| test al, al |
| setnp al |
| ret |
| hotkey_test2: |
| cmp al, 3 |
| setz al |
| ret |
| hotkey_test3: |
| cmp al, 1 |
| setz al |
| ret |
| hotkey_test4: |
| cmp al, 2 |
| setz al |
| ret |
| hotkey_do_test: |
| push eax |
| mov edx, [kb_state] |
| shr edx, cl |
| add cl, cl |
| mov eax, [eax+4] |
| shr eax, cl |
| and eax, 15 |
| cmp al, hotkey_tests_num |
| jae .fail |
| xchg eax, edx |
| and al, 3 |
| call [hotkey_tests + edx*4] |
| cmp al, 1 |
| pop eax |
| ret |
| .fail: |
| stc |
| pop eax |
| ret |
| align 4 |
| irq1: |
| ; save_ring3_context |
| ; mov ax, os_data |
| ; mov ds, ax |
| ; mov es, ax |
| movzx eax,word[TASK_COUNT] ; top window process |
| movzx eax,word[WIN_POS+eax*2] |
| shl eax,8 |
| mov al,[SLOT_BASE+eax+APPDATA.keyboard_mode] |
| mov [keyboard_mode],al |
| in al,0x60 |
| mov [keyboard_data],al |
| ; ch = scancode |
| ; cl = ext_code |
| ; bh = 0 - normal key |
| ; bh = 1 - modifier (Shift/Ctrl/Alt) |
| ; bh = 2 - extended code |
| mov ch,al |
| cmp al,0xE0 |
| je @f |
| cmp al,0xE1 |
| jne .normal_code |
| @@: |
| mov bh, 2 |
| mov [ext_code], al |
| jmp .writekey |
| .normal_code: |
| mov cl, 0 |
| xchg cl, [ext_code] |
| and al,0x7F |
| mov bh, 1 |
| @@: cmp al,0x2A |
| jne @f |
| cmp cl,0xE0 |
| je .writekey |
| mov eax,VKEY_LSHIFT |
| jmp .modifier |
| @@: cmp al,0x36 |
| jne @f |
| cmp cl,0xE0 |
| je .writekey |
| mov eax,VKEY_RSHIFT |
| jmp .modifier |
| @@: cmp al,0x38 |
| jne @f |
| mov eax, VKEY_LALT |
| test cl, cl |
| jz .modifier |
| mov al, VKEY_RALT |
| jmp .modifier |
| @@: cmp al,0x1D |
| jne @f |
| mov eax, VKEY_LCONTROL |
| test cl, cl |
| jz .modifier |
| mov al, VKEY_RCONTROL |
| cmp cl, 0xE0 |
| jz .modifier |
| mov [ext_code], cl |
| jmp .writekey |
| @@: cmp al,0x3A |
| jne @f |
| mov bl,4 |
| mov eax,VKEY_CAPSLOCK |
| jmp .no_key.xor |
| @@: cmp al,0x45 |
| jne @f |
| test cl, cl |
| jnz .writekey |
| mov bl,2 |
| mov eax,VKEY_NUMLOCK |
| jmp .no_key.xor |
| @@: cmp al,0x46 |
| jne @f |
| mov bl,1 |
| mov eax,VKEY_SCRLOCK |
| jmp .no_key.xor |
| @@: |
| test ch,ch |
| js .writekey |
| movzx eax,ch ; plain key |
| mov bl,[keymap+eax] |
| mov edx,[kb_state] |
| test dl,VKEY_CONTROL ; ctrl alt del |
| jz .noctrlaltdel |
| test dl,VKEY_ALT |
| jz .noctrlaltdel |
| cmp ch,53h |
| jne .noctrlaltdel |
| mov [ctrl_alt_del],1 |
| .noctrlaltdel: |
| test dl,VKEY_CONTROL ; ctrl on ? |
| jz @f |
| sub bl,0x60 |
| @@: test dl,VKEY_SHIFT ; shift on ? |
| jz @f |
| mov bl,[keymap_shift+eax] |
| @@: test dl,VKEY_ALT ; alt on ? |
| jz @f |
| mov bl,[keymap_alt+eax] |
| @@: |
| mov bh, 0 |
| jmp .writekey |
| .modifier: |
| test ch, ch |
| js .modifier.up |
| or [kb_state], eax |
| jmp .writekey |
| .modifier.up: |
| not eax |
| and [kb_state], eax |
| jmp .writekey |
| .no_key.xor: |
| mov bh, 0 |
| test ch, ch |
| js .writekey |
| xor [kb_state], eax |
| xor [kb_lights], bl |
| call set_lights |
| .writekey: |
| ; test for system hotkeys |
| movzx eax, ch |
| cmp bh, 1 |
| ja .nohotkey |
| jb @f |
| xor eax, eax |
| @@: |
| mov eax, [hotkey_scancodes + eax*4] |
| .hotkey_loop: |
| test eax, eax |
| jz .nohotkey |
| mov cl, 0 |
| call hotkey_do_test |
| jc .hotkey_cont |
| mov cl, 2 |
| call hotkey_do_test |
| jc .hotkey_cont |
| mov cl, 4 |
| call hotkey_do_test |
| jnc .hotkey_found |
| .hotkey_cont: |
| mov eax, [eax] |
| jmp .hotkey_loop |
| .hotkey_found: |
| mov eax, [eax+8] |
| ; put key in buffer for process in slot eax |
| mov edi, hotkey_buffer |
| @@: |
| cmp dword [edi], 0 |
| jz .found_free |
| add edi, 8 |
| cmp edi, hotkey_buffer+120*8 |
| jb @b |
| ; no free space - replace first entry |
| mov edi, hotkey_buffer |
| .found_free: |
| mov [edi], eax |
| movzx eax, ch |
| cmp bh, 1 |
| jnz @f |
| xor eax, eax |
| @@: |
| mov [edi+4], ax |
| mov eax, [kb_state] |
| mov [edi+6], ax |
| jmp .exit.irq1 |
| .nohotkey: |
| cmp [keyboard_mode],0 ; return from keymap |
| jne .scancode |
| test bh, bh |
| jnz .exit.irq1 |
| test bl, bl |
| jz .exit.irq1 |
| ;.........................Part1 Start.......Code by Rus, optimize by Ghost................................... |
| test [kb_state], VKEY_NUMLOCK |
| jz .dowrite |
| cmp cl, 0xE0 |
| jz .dowrite |
| cmp ch, 55 |
| jnz @f |
| mov bl, 0x2A ;* |
| jmp .dowrite |
| @@: |
| cmp ch, 71 |
| jb .dowrite |
| cmp ch, 83 |
| ja .dowrite |
| ;push eax |
| movzx eax, ch |
| mov bl, [numlock_map + eax - 71] |
| ;pop eax |
| ;.........................Part1 End................................................. |
| jmp .dowrite |
| .scancode: |
| mov bl, ch |
| .dowrite: |
| movzx eax,byte[KEY_COUNT] |
| cmp al,120 |
| jae .exit.irq1 |
| inc eax |
| mov [KEY_COUNT],al |
| mov [KEY_COUNT+eax],bl |
| .exit.irq1: |
| mov [check_idle_semaphore],5 |
| ; mov al,0x20 ; ready for next irq |
| ; out 0x20,al |
| ; restore_ring3_context |
| ; iret |
| ret |
| set_lights: |
| mov al,0xED |
| call kb_write |
| mov al,[kb_lights] |
| call kb_write |
| ret |
| ;// mike.dld ] |
| ;..........................Part2 Start.......Code by Rus....................................... |
| numlock_map: |
| db 0x37 ;Num 7 |
| db 0x38 ;Num 8 |
| db 0x39 ;Num 9 |
| db 0x2D ;Num - |
| db 0x34 ;Num 4 |
| db 0x35 ;Num 5 |
| db 0x36 ;Num 6 |
| db 0x2B ;Num + |
| db 0x31 ;Num 1 |
| db 0x32 ;Num 2 |
| db 0x33 ;Num 3 |
| db 0x30 ;Num 0 |
| db 0x2E ;Num . |
| ;..........................Part2 End................................................ |
| /kernel/branches/hid/mousedrv.inc |
|---|
| 0,0 → 1,458 |
| ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; |
| ;; ;; |
| ;; Copyright (C) KolibriOS team 2004-2008. All rights reserved. ;; |
| ;; Distributed under terms of the GNU General Public License ;; |
| ;; ;; |
| ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; |
| $Revision: 983 $ |
| ; check mouse |
| ; |
| ; |
| ; FB00 -> FB0F mouse memory 00 chunk count - FB0A-B x - FB0C-D y |
| ; FB10 -> FB17 mouse color mem |
| ; FB21 x move |
| ; FB22 y move |
| ; FB30 color temp |
| ; FB28 high bits temp |
| ; FB4A -> FB4D FB4A-B x-under - FB4C-D y-under |
| ; FC00 -> FCFE com1/ps2 buffer |
| ; FCFF com1/ps2 buffer count starting from FC00 |
| uglobal |
| mousecount dd 0x0 |
| mousedata dd 0x0 |
| endg |
| iglobal |
| mouse_delay dd 10 |
| mouse_speed_factor: dd 3 |
| mouse_timer_ticks dd 0 |
| endg |
| ;include 'm_com.inc' |
| ;test_mario79: |
| ; push esi |
| ; push eax |
| ; mov [write_error_to],process_test_m79+43 |
| ; movzx eax,al ;[DevErrorCode] |
| ; call writehex |
| ; mov esi,process_test_m79 |
| ; call sys_msg_board_str |
| ; pop eax |
| ; pop esi |
| ; ret |
| ;process_test_m79 db 'K : Process - test Mario79 error 00000000',13,10,0 |
| draw_mouse_under: |
| ; return old picture |
| cmp [set_hw_cursor], 0 |
| jz @F |
| pushad |
| movzx eax,word [X_UNDER] |
| movzx ebx,word [Y_UNDER] |
| stdcall [hw_restore], eax, ebx |
| popad |
| ret |
| @@: |
| pushad |
| xor ecx,ecx |
| xor edx,edx |
| align 4 |
| mres: |
| movzx eax,word [X_UNDER] |
| movzx ebx,word [Y_UNDER] |
| add eax,ecx |
| add ebx,edx |
| push ecx |
| push edx |
| push eax |
| push ebx |
| mov eax,edx |
| shl eax,6 |
| shl ecx,2 |
| add eax,ecx |
| add eax,mouseunder |
| mov ecx,[eax] |
| pop ebx |
| pop eax |
| mov edi, 1 ;force |
| call [putpixel] |
| pop edx |
| pop ecx |
| inc ecx |
| cmp ecx, 16 |
| jnz mres |
| xor ecx, ecx |
| inc edx |
| cmp edx, 24 |
| jnz mres |
| popad |
| ret |
| save_draw_mouse: |
| cmp [set_hw_cursor], 0 |
| je .no_hw_cursor |
| pushad |
| mov [X_UNDER],ax |
| mov [Y_UNDER],bx |
| movzx eax,word [MOUSE_Y] |
| movzx ebx,word [MOUSE_X] |
| push eax |
| push ebx |
| mov ecx, [Screen_Max_X] |
| inc ecx |
| mul ecx |
| movzx edx, byte [display_data+ebx+eax] |
| shl edx, 8 |
| mov esi, [edx+SLOT_BASE+APPDATA.cursor] |
| cmp esi, [current_cursor] |
| je .draw |
| ; cmp [esi+CURSOR.magic], 'CURS' |
| ; jne .fail |
| push esi |
| call [select_hw_cursor] |
| mov [current_cursor], esi |
| .draw: |
| stdcall [set_hw_cursor], esi |
| popad |
| ret |
| .fail: |
| mov ecx, [def_cursor] |
| mov [edx+SLOT_BASE+APPDATA.cursor], ecx |
| stdcall [set_hw_cursor], ecx ; stdcall: [esp]=ebx,eax |
| popad |
| ret |
| .no_hw_cursor: |
| pushad |
| ; save & draw |
| mov [X_UNDER],ax |
| mov [Y_UNDER],bx |
| push eax |
| push ebx |
| mov ecx,0 |
| mov edx,0 |
| align 4 |
| drm: |
| push eax |
| push ebx |
| push ecx |
| push edx |
| ; helloworld |
| push ecx |
| add eax,ecx ; save picture under mouse |
| add ebx,edx |
| push ecx |
| call getpixel |
| mov [COLOR_TEMP],ecx |
| pop ecx |
| mov eax,edx |
| shl eax,6 |
| shl ecx,2 |
| add eax,ecx |
| add eax,mouseunder |
| mov ebx,[COLOR_TEMP] |
| mov [eax],ebx |
| pop ecx |
| mov edi,edx ; y cycle |
| shl edi,4 ; *16 bytes per row |
| add edi,ecx ; x cycle |
| mov esi, edi |
| add edi, esi |
| add edi, esi ; *3 |
| add edi,[MOUSE_PICTURE] ; we have our str address |
| mov esi, edi |
| add esi, 16*24*3 |
| push ecx |
| mov ecx, [COLOR_TEMP] |
| call combine_colors |
| mov [MOUSE_COLOR_MEM], ecx |
| pop ecx |
| pop edx |
| pop ecx |
| pop ebx |
| pop eax |
| add eax,ecx ; we have x coord+cycle |
| add ebx,edx ; and y coord+cycle |
| push ecx |
| mov ecx, [MOUSE_COLOR_MEM] |
| mov edi, 1 |
| call [putpixel] |
| pop ecx |
| mov ebx,[esp+0] ; pure y coord again |
| mov eax,[esp+4] ; and x |
| inc ecx ; +1 cycle |
| cmp ecx,16 ; if more than 16 |
| jnz drm |
| xor ecx, ecx |
| inc edx |
| cmp edx,24 |
| jnz drm |
| add esp,8 |
| popad |
| ret |
| combine_colors: |
| ; in |
| ; ecx - color ( 00 RR GG BB ) |
| ; edi - ref to new color byte |
| ; esi - ref to alpha byte |
| ; |
| ; out |
| ; ecx - new color ( roughly (ecx*[esi]>>8)+([edi]*[esi]>>8) ) |
| push eax |
| push ebx |
| push edx |
| push ecx |
| xor ecx, ecx |
| ; byte 2 |
| mov eax, 0xff |
| sub al, [esi+0] |
| mov ebx, [esp] |
| shr ebx, 16 |
| and ebx, 0xff |
| mul ebx |
| shr eax, 8 |
| add ecx, eax |
| xor eax, eax |
| xor ebx, ebx |
| mov al, [edi+0] |
| mov bl, [esi+0] |
| mul ebx |
| shr eax, 8 |
| add ecx, eax |
| shl ecx, 8 |
| ; byte 1 |
| mov eax, 0xff |
| sub al, [esi+1] |
| mov ebx, [esp] |
| shr ebx, 8 |
| and ebx, 0xff |
| mul ebx |
| shr eax, 8 |
| add ecx, eax |
| xor eax, eax |
| xor ebx, ebx |
| mov al, [edi+1] |
| mov bl, [esi+1] |
| mul ebx |
| shr eax, 8 |
| add ecx, eax |
| shl ecx, 8 |
| ; byte 2 |
| mov eax, 0xff |
| sub al, [esi+2] |
| mov ebx, [esp] |
| and ebx, 0xff |
| mul ebx |
| shr eax, 8 |
| add ecx, eax |
| xor eax, eax |
| xor ebx, ebx |
| mov al, [edi+2] |
| mov bl, [esi+2] |
| mul ebx |
| shr eax, 8 |
| add ecx, eax |
| pop eax |
| pop edx |
| pop ebx |
| pop eax |
| ret |
| __sys_disable_mouse: |
| cmp dword [MOUSE_VISIBLE],dword 0 |
| je @f |
| ret |
| @@: |
| pushad |
| cmp [CURRENT_TASK],dword 1 |
| je disable_m |
| mov edx,[CURRENT_TASK] |
| shl edx,5 |
| add edx,window_data |
| movzx eax, word [MOUSE_X] |
| movzx ebx, word [MOUSE_Y] |
| mov ecx,[Screen_Max_X] |
| inc ecx |
| imul ecx,ebx |
| add ecx,eax |
| add ecx, display_data |
| mov eax, [CURRENT_TASK] |
| movzx ebx, byte [ecx] |
| cmp eax,ebx |
| je yes_mouse_disable |
| movzx ebx, byte [ecx+16] |
| cmp eax,ebx |
| je yes_mouse_disable |
| mov ebx,[Screen_Max_X] |
| inc ebx |
| imul ebx,10 |
| add ecx,ebx |
| movzx ebx, byte [ecx] |
| cmp eax,ebx |
| je yes_mouse_disable |
| movzx ebx, byte [ecx+16] |
| cmp eax,ebx |
| je yes_mouse_disable |
| jmp no_mouse_disable |
| yes_mouse_disable: |
| mov edx,[CURRENT_TASK] |
| shl edx,5 |
| add edx,window_data |
| movzx eax, word [MOUSE_X] |
| movzx ebx, word [MOUSE_Y] |
| mov ecx,[edx+0] ; mouse inside the area ? |
| add eax,10 |
| cmp eax,ecx |
| jb no_mouse_disable |
| sub eax,10 |
| add ecx,[edx+8] |
| cmp eax,ecx |
| jg no_mouse_disable |
| mov ecx,[edx+4] |
| add ebx,14 |
| cmp ebx,ecx |
| jb no_mouse_disable |
| sub ebx,14 |
| add ecx,[edx+12] |
| cmp ebx,ecx |
| jg no_mouse_disable |
| disable_m: |
| cmp dword [MOUSE_VISIBLE],dword 0 |
| jne no_mouse_disable |
| pushf |
| cli |
| call draw_mouse_under |
| popf |
| mov [MOUSE_VISIBLE],dword 1 |
| no_mouse_disable: |
| popad |
| ret |
| __sys_draw_pointer: |
| cmp [mouse_pause],0 |
| je @f |
| ret |
| @@: |
| push eax |
| mov eax,[timer_ticks] |
| sub eax,[MouseTickCounter] |
| cmp eax,1 |
| ja @f |
| pop eax |
| ret |
| @@: |
| mov eax,[timer_ticks] |
| mov [MouseTickCounter],eax |
| pop eax |
| pushad |
| cmp dword [MOUSE_VISIBLE],dword 0 ; mouse visible ? |
| je chms00 |
| mov [MOUSE_VISIBLE], dword 0 |
| movzx ebx,word [MOUSE_Y] |
| movzx eax,word [MOUSE_X] |
| pushfd |
| cli |
| call save_draw_mouse |
| popfd |
| nodmu2: |
| popad |
| ret |
| chms00: |
| movzx ecx,word [X_UNDER] |
| movzx edx,word [Y_UNDER] |
| movzx ebx,word [MOUSE_Y] |
| movzx eax,word [MOUSE_X] |
| cmp eax,ecx |
| jne redrawmouse |
| cmp ebx,edx |
| jne redrawmouse |
| jmp nodmp |
| redrawmouse: |
| pushfd |
| cli |
| call draw_mouse_under |
| call save_draw_mouse |
| popfd |
| nodmp: |
| popad |
| ret |
| proc set_mouse_data stdcall, BtnState:dword, XMoving:dword, YMoving:dword, VScroll:dword, HScroll:dword |
| mov eax,[BtnState] |
| mov [BTN_DOWN],eax |
| mov eax,[XMoving] |
| call mouse_acceleration |
| add ax,[MOUSE_X] ;[XCoordinate] |
| cmp ax,0 |
| jge @@M1 |
| mov eax,0 |
| jmp @@M2 |
| @@M1: |
| cmp ax,[Screen_Max_X] ;ScreenLength |
| jl @@M2 |
| mov ax,[Screen_Max_X] ;ScreenLength-1 |
| @@M2: |
| mov [MOUSE_X],ax ;[XCoordinate] |
| mov eax,[YMoving] |
| neg eax |
| call mouse_acceleration |
| add ax,[MOUSE_Y] ;[YCoordinate] |
| cmp ax,0 |
| jge @@M3 |
| mov ax,0 |
| jmp @@M4 |
| @@M3: |
| cmp ax,[Screen_Max_Y] ;ScreenHeigth |
| jl @@M4 |
| mov ax,[Screen_Max_Y] ;ScreenHeigth-1 |
| @@M4: |
| mov [MOUSE_Y],ax ;[YCoordinate] |
| mov eax,[VScroll] |
| add [MOUSE_SCROLL_V],ax |
| mov eax,[HScroll] |
| add [MOUSE_SCROLL_H],ax |
| mov [mouse_active],1 |
| mov eax,[timer_ticks] |
| mov [mouse_timer_ticks],eax |
| ret |
| endp |
| mouse_acceleration: |
| push eax |
| mov eax,[timer_ticks] |
| sub eax,[mouse_timer_ticks] |
| cmp eax,[mouse_delay] |
| pop eax |
| ja @f |
| ;push edx |
| imul eax,[mouse_speed_factor] |
| ;pop edx |
| @@: |
| ret |
| /kernel/branches/hid/set_dtc.inc |
|---|
| 0,0 → 1,201 |
| ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; |
| ;; ;; |
| ;; Copyright (C) KolibriOS team 2004-2007. All rights reserved. ;; |
| ;; Distributed under terms of the GNU General Public License ;; |
| ;; ;; |
| ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; |
| $Revision: 593 $ |
| ;setting date,time,clock and alarm-clock |
| ;add sys_settime at servetable as for ex. 22 fcn: |
| ; 22 - SETTING DATE TIME, CLOCK AND ALARM-CLOCK |
| ; ebx =0 - set time ecx - 00SSMMHH |
| ; ebx =1 - set date ecx=00DDMMYY |
| ; ebx =2 - set day of week ecx- 1-7 |
| ; ebx =3 - set alarm-clock ecx - 00SSMMHH |
| ; out: 0 -Ok 1 -wrong format 2 -battery low |
| sys_settime: |
| mov ecx,eax |
| cli |
| mov al,0x0d |
| out 0x70,al |
| in al,0x71 |
| bt ax,7 |
| jnc bat_low |
| cmp ecx,2 ;day of week |
| jne nosetweek |
| test ebx,ebx ;test day of week |
| je wrongtime |
| cmp ebx,7 |
| ja wrongtime |
| mov dx,0x70 |
| call startstopclk |
| dec edx |
| mov al,6 |
| out dx,al |
| inc edx |
| mov al,bl |
| out dx,al |
| jmp endsettime |
| nosetweek: ;set date |
| cmp ecx,1 |
| jne nosetdate |
| cmp bl,0x99 ;test year |
| ja wrongtime |
| shl ebx,4 |
| cmp bl,0x90 |
| ja wrongtime |
| cmp bh,0x99 ;test month |
| ja wrongtime |
| shr ebx,4 |
| test bh,bh |
| je wrongtime |
| cmp bh,0x12 |
| ja wrongtime |
| shl ebx,8 |
| bswap ebx ;ebx=00YYMMDD |
| test bl,bl ;test day |
| je wrongtime |
| shl ebx,4 |
| cmp bl,0x90 |
| ja wrongtime |
| shr ebx,4 |
| cmp bh,2 ;February |
| jne testday |
| cmp bl,0x29 |
| ja wrongtime |
| jmp setdate |
| testday: |
| cmp bh,8 |
| jb testday1 ;Aug-Dec |
| bt bx,8 |
| jnc days31 |
| jmp days30 |
| testday1: |
| bt bx,8 ;Jan-Jul ex.Feb |
| jnc days30 |
| days31: |
| cmp bl,0x31 |
| ja wrongtime |
| jmp setdate |
| days30: |
| cmp bl,0x30 |
| ja wrongtime |
| setdate: |
| mov dx,0x70 |
| call startstopclk |
| dec edx |
| mov al,7 ;set days |
| out dx,al |
| inc edx |
| mov al,bl |
| out dx,al |
| dec edx |
| mov al,8 ;set months |
| out dx,al |
| inc edx |
| mov al,bh |
| out dx,al |
| dec edx |
| mov al,9 ;set years |
| out dx,al |
| inc edx |
| shr ebx,8 |
| mov al,bh |
| out dx,al |
| jmp endsettime |
| nosetdate: ;set time or alarm-clock |
| cmp ecx,3 |
| ja wrongtime |
| cmp bl,0x23 |
| ja wrongtime |
| cmp bh,0x59 |
| ja wrongtime |
| shl ebx,4 |
| cmp bl,0x90 |
| ja wrongtime |
| cmp bh,0x92 |
| ja wrongtime |
| shl ebx,4 |
| bswap ebx ;00HHMMSS |
| cmp bl,0x59 |
| ja wrongtime |
| shl ebx,4 |
| cmp bl,0x90 |
| ja wrongtime |
| shr ebx,4 |
| mov dx,0x70 |
| call startstopclk |
| dec edx |
| cmp ecx,3 |
| je setalarm |
| xor eax,eax ;al=0-set seconds |
| out dx,al |
| inc edx |
| mov al,bl |
| out dx,al |
| dec edx |
| mov al,2 ;set minutes |
| out dx,al |
| inc edx |
| mov al,bh |
| out dx,al |
| dec edx |
| mov al,4 ;set hours |
| out dx,al |
| inc edx |
| shr ebx,8 |
| mov al,bh |
| out dx,al |
| jmp endsettime |
| setalarm: |
| mov al,1 ;set seconds for al. |
| out dx,al |
| inc edx |
| mov al,bl |
| out dx,al |
| dec edx |
| mov al,3 ;set minutes for al. |
| out dx,al |
| inc edx |
| mov al,bh |
| out dx,al |
| dec edx |
| mov al,5 ;set hours for al. |
| out dx,al |
| inc edx |
| shr ebx,8 |
| mov al,bh |
| out dx,al |
| dec edx |
| mov al,0x0b ;enable irq's |
| out dx,al |
| inc dx |
| in al,dx |
| bts ax,5 ;set bit 5 |
| out dx,al |
| endsettime: |
| dec edx |
| call startstopclk |
| sti |
| mov [esp+36],dword 0 |
| ret |
| bat_low: |
| sti |
| mov [esp+36],dword 2 |
| ret |
| wrongtime: |
| sti |
| mov [esp+36],dword 1 |
| ret |
| startstopclk: |
| mov al,0x0b |
| out dx,al |
| inc dx |
| in al,dx |
| btc ax,7 |
| out dx,al |
| ret |