| 74,6 → 74,14 |
|---|
| cmp al,10 |
| jz pci_write_reg ;dword |
| |
| cmp al,11 ; <<< user-level MMIO functions <<< NEW! |
| jz pci_mmio_init |
| cmp al,12 |
| jz pci_mmio_map |
| cmp al,13 |
| jz pci_mmio_unmap |
| |
| |
| no_pci_access_for_applications: |
| |
| mov eax,-1 |
| 366,6 → 374,139 |
|---|
| dec eax |
| ret |
| |
| ;*************************************************************************** |
| ; Function |
| ; pci_mmio_init ; NEW! |
| ; |
| ; Description |
| ; IN: bx = device's PCI bus address (bbbbbbbbdddddfff) |
| ; returns ax = user heap space available (bytes) |
| ; Error codes |
| ; eax = -1 : PCI user access blocked, |
| ; eax = -2 : device not registered for uMMIO service |
| ; eax = -3 : user heap initialization failure |
| ;*************************************************************************** |
| align 4 |
| pci_mmio_init: |
| cmp bx, word [mmio_pci_addr] ; must be set in kernel/data32.inc |
| jz @f |
| mov eax,-2 |
| ret |
| @@: |
| call init_heap ; (if not initialized yet) |
| or eax,eax |
| jz @f |
| ret |
| @@: |
| mov eax,-3 |
| ret |
| |
| |
| ;*************************************************************************** |
| ; Function |
| ; pci_mmio_map ; NEW! |
| ; |
| ; Description |
| ; maps a block of PCI memory to user-accessible linear address |
| ; |
| ; WARNING! This VERY EXPERIMENTAL service is for one chosen PCI device only! |
| ; The target device address should be set in kernel var mmio_pci_addr |
| ; |
| ; IN: ah = BAR#; |
| ; IN: ebx = block size (bytes); |
| ; IN: ecx = offset in MMIO block (in 4K-pages, to avoid misaligned pages); |
| ; |
| ; Returns eax = MMIO block's linear address in the userspace (if no error) |
| ; |
| ; |
| ; Error codes |
| ; eax = -1 : user access to PCI blocked, |
| ; eax = -2 : an invalid BAR register referred |
| ; eax = -3 : no i/o space on that BAR |
| ; eax = -4 : a port i/o BAR register referred |
| ; eax = -5 : dynamic userspace allocation problem |
| ;*************************************************************************** |
| |
| align 4 |
| pci_mmio_map: |
| and edx,0x0ffff |
| cmp ah,6 |
| jc @f |
| mov eax,-2 |
| ret |
| @@: |
| push ecx |
| add ebx, 4095 |
| and ebx,-4096 |
| push ebx |
| mov bl, ah ; bl = BAR# (0..5) |
| shl bl, 1 |
| shl bl, 1 |
| add bl, 0x10 ; bl = BARs offset in PCI config. space |
| mov ax,word [mmio_pci_addr] |
| mov bh, al ; bh = dddddfff |
| mov al, 2 ; al : DW to read |
| call pci_read_reg |
| or eax, eax |
| jnz @f |
| mov eax,-3 ; empty I/O space |
| jmp mmio_ret_fail |
| @@: |
| test eax, 1 |
| jz @f |
| mov eax,-4 ; damned ports (not MMIO space) |
| jmp mmio_ret_fail |
| @@: |
| pop ecx ; ecx = block size, bytes (expanded to whole page) |
| mov ebx, ecx ; user_alloc destroys eax, ecx, edx, but saves ebx |
| push eax ; store MMIO physical address + keep 2DWords in the stack |
| stdcall user_alloc, ecx |
| or eax, eax |
| jnz mmio_map_over |
| mov eax,-5 ; problem with page allocation |
| |
| mmio_ret_fail: |
| pop ecx |
| pop edx |
| ret |
| |
| mmio_map_over: |
| mov ecx, ebx ; ecx = size (bytes, expanded to whole page) |
| shr ecx, 12 ; ecx = number of pages |
| mov ebx, eax ; ebx = linear address |
| pop eax ; eax = MMIO start |
| pop edx ; edx = MMIO shift (pages) |
| shl edx, 12 ; edx = MMIO shift (bytes) |
| add eax, edx ; eax = uMMIO physical address |
| or eax, PG_SHARED |
| or eax, PG_UW |
| or eax, PG_NOCACHE |
| mov edi, ebx |
| call commit_pages |
| mov eax, edi |
| ret |
| |
| ;*************************************************************************** |
| ; Function |
| ; pci_mmio_unmap_page ; NEW! |
| ; |
| ; Description |
| ; unmaps the linear space previously tied to a PCI memory block |
| ; |
| ; IN: ebx = linear address of space previously allocated by pci_mmio_map |
| ; returns eax = 1 if successfully unmapped |
| ; |
| ; Error codes |
| ; eax = -1 if no user PCI access allowed, |
| ; eax = 0 if unmapping failed |
| ;*************************************************************************** |
| |
| align 4 |
| pci_mmio_unmap: |
| stdcall user_free, ebx |
| ret |
| |
| |
| ;-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-= |
| |
| ; VendID (2), DevID (2), Revision = 0 (1), Class Code (3), FNum (1), Bus (1) |