Subversion Repositories Kolibri OS

use32

	org 0

	db 'MENUET01'

	dd 1,start,i_end,mem,stacktop,0,sys_path

include '../../../macros.inc'

include '../../../proc32.inc'

include '../../../KOSfuncs.inc'

include '../../../load_img.inc'

include '../../../load_lib.mac'

;include 'lang.inc'

@use_library mem.Alloc,mem.Free,mem.ReAlloc,dll.Load

hed db 'Life 18.11.20',0 ;������� ����

run_file_70 FileInfoBlock

image_data dd 0 ;㪠��⥫� �� �६����� ������. ��� �㦥� �८�ࠧ������ ����ࠦ����

ICONSIZE = 21

TBTNSIZE = ICONSIZE-2

IMAGE_TOOLBAR_ICON_SIZE equ ICONSIZE*ICONSIZE*3

image_data_toolbar dd 0

;--------------------------------------

struct Cell

	x dd ? ;+0

	y dd ? ;+4

	tc  dd ? ;+8 ��������� � ���஬ த����� �ᮡ�

	liv db ? ;+12 ����� �祩�� ��� ���

	so  db ? ;+13 �᫮ �ᥤ��

ends

MAX_CELL equ 90000 ;������ ���� ��⭮ 4

COL_MEM equ 64 ;�᫮ 梥⮢ ��� �⫨�� ������� � �����

cell dd 0 ;㪠��⥫� �� ������ � ������ࠬ� �祥�

memCell dd 0

CellColors dd 0

macro get_cell_offset reg,ind

{

	mov reg,ind

	imul reg,sizeof.Cell

	add reg,dword[cell]

}

er_oom db 0 ;�� ��砩 ���௠��� �����

tim_ch db 0 ;��⮬���᪨ �����뢠�� ���������

poc_stop dd 1 ;����� �� �᫮ ���������

Cor_x dd 0

Cor_y dd 0

tim dd 0 ;�६� (���������)

b_sort dd 0 ;�࠭�� ��� ���஢����� �祥�

osob dd 0 ;�᫮ �ᮡ��

zoom db 3 ;����⠡ ����

if lang eq ru

txt_zoom db '   ����⠡:',0

txt_gen db '  ���������:',0

txt_osob db '    �ᮡ��:',0

else

txt_zoom db '      Zoom:',0

txt_gen db  'Generation:',0

txt_osob db 'Population:',0

end if

;����ன�� ���ᨢ� � 梥⠬�

; col_pole - 梥� ����

; col_cell_n - 梥� ����� �祩��

; col_cell_o - 梥� ��ன �祩��

align 4

proc pole_init_colors uses eax ebx ecx edx esi edi, col_pole:dword, col_cell_n:dword, col_cell_o:dword

	mov esi,[CellColors]

	mov ebx,[col_pole]

	mov [esi],ebx

	lea edi,[esi+4*COL_MEM]

	add esi,4

	; esi - 㪠��⥫� �� 1-� �ࠤ����� 梥�

	; edi - 㪠��⥫� �� ��᫥���� �ࠤ����� 梥�

	mov eax,[col_cell_n]

	mov ebx,[col_cell_o]

	mov [esi],eax

	mov [edi],ebx

	;need save ecx edx

	stdcall middle_colors, esi,edi

	ret

endp

;�ᯮ����⥫쭠� �㭪�� ��� ��室����� �।���� 梥� � ����� ��� � ���ᨢ

;input:

; eax - 梥� ��砫��

; ebx - 梥� ������

;�����������: ecx, edx

align 4

proc middle_colors uses edi esi, i0:dword, i1:dword

	mov esi,[i0]

	mov edi,[i1]

	;��। �맮��� �㭪樨

	;dword[esi]=eax

	;dword[edi]=ebx

	sub edi,esi

	shr edi,1

	btr edi,1 ;���㣫塞 �� 4-�, �. �. �㦭� ������� ���� (���㣫���� ��஥ - 㡨ࠥ� ���� ��� ����� �।���������� 2-�)

	add edi,esi

	cmp edi,esi

	je @f

		push eax ebx

		mov ecx,eax

		mov edx,ebx

		;��室�� �।��� 梥� ����� eax � ebx

		and ebx,111111101111111011111110b ;㡨ࠥ� ��᫥���� ���� � 梥�� r, g, b

		and eax,111111101111111011111110b

		add eax,ebx ;�㬨�㥬 梥� �� r, g, b

		shr eax,1   ;����� �� 2

		mov dword[edi],eax

		;४��ᨢ�� �맮� ��� �஡����� ���孥� ��������

		mov ebx,eax

		mov eax,ecx

		stdcall middle_colors, [i0],edi

		;४��ᨢ�� �맮� ��� �஡����� ������ ��������

		mov eax,ebx

		mov ebx,edx

		stdcall middle_colors, edi,[i1]

		pop ebx eax

	@@:

	ret

endp

align 4

proc pole_clear uses eax ecx edi

	xor eax,eax

	mov dword[tim],eax

	mov dword[osob],eax

	mov  byte[tim_ch],al

	mov dword[Cor_x],eax

	mov dword[Cor_y],eax

	mov dword[b_sort],eax

	mov  byte[er_oom],al

	cld

	mov ecx,(MAX_CELL*sizeof.Cell)/4

	mov edi,[cell]

	rep stosd ;memset(cell,0,sizeof(Cell)*MAX_CELL);

	mov edi,[memCell]

	mov ecx,MAX_CELL

	@@:

		stosd ;for(i=0;i

		inc eax

		loop @b

	ret

endp

align 4

proc pole_cell_creat, x:dword, y:dword, li:dword

	pushad ;eax ebx ecx edx edi

	; *** �᫨ ���⪠ 㦥 �뫠 ᮧ����

	stdcall pole_cell_find, [x],[y]

	or eax,eax

	jz @f ;if(i){

		get_cell_offset ebx,eax

		cmp dword[li],0

		jne .else_if ;if(!li)

			; �᫨ ᮧ������ ����� ���⪠

			inc byte[ebx+Cell.so]

			jmp .fun_e

		.else_if: ;else if(!(cell[i].liv&1) ){

		bt word[ebx+Cell.liv],0

			; �᫨ ᮧ������ ����� ���⪠

			; � ࠭�� ���⪠ �뫠 ᮧ���� �� ��������� ���⮩

			jae .creat_border_cells

		jmp .fun_e

	@@:

	; *** ᮧ����� ����� �祩��

	; ��室�� ����� ᢮������ �祩�� (i) ��� ���������� �����

	mov edi,[memCell]

	inc dword[edi]

	cmp dword[edi],MAX_CELL

	jne @f

		dec dword[edi]

		mov byte[tim_ch],0

		;... need call message: "eror out of memory" ...

		;... �뢮� ᮮ�饭�� ��९������� ���� ��������  ...

		mov byte[er_oom],0

		jmp .fun_e ;return;

	@@:

	mov eax,[edi]

	shl eax,2

	add eax,[memCell] ;eax -> memCell[firstC]

	get_cell_offset ebx,[eax]

	mov ecx,[x]

	mov dword[ebx],ecx ;+0 = .x

	mov edx,[y]

	mov dword[ebx+Cell.y],edx

	mov eax,[tim]

	mov dword[ebx+Cell.tc],eax

	mov byte[ebx+Cell.liv],0

	cmp dword[li],0

	jne @f

		mov byte[ebx+Cell.so],1

		jmp .fun_e

	@@:

	mov byte[ebx+Cell.so],0

	.creat_border_cells:

		inc dword[osob]

		or byte[ebx+Cell.liv],1

		mov ecx,[x]

		dec ecx

		mov edx,[y]

		dec edx

		stdcall pole_cell_creat,ecx,edx,0

		inc edx

		stdcall pole_cell_creat,ecx,edx,0

		inc edx

		stdcall pole_cell_creat,ecx,edx,0

		inc ecx

		stdcall pole_cell_creat,ecx,edx,0

		sub edx,2

		stdcall pole_cell_creat,ecx,edx,0

		inc ecx

		stdcall pole_cell_creat,ecx,edx,0

		inc edx

		stdcall pole_cell_creat,ecx,edx,0

		inc edx

		stdcall pole_cell_creat,ecx,edx,0

	.fun_e:

	popad ;edi edx ecx ebx eax

	ret

endp

;output:

; eax - index

align 4

proc pole_cell_find, x:dword, y:dword

	mov eax,[memCell]

	cmp dword[eax],0

	jne @f

		xor eax,eax ;if(!fristC) return 0;

		jmp .fun_e

	@@:

	xor eax,eax ;fnd=0;

	cmp dword[b_sort],0

	je @f

		stdcall pole_bin_find, [memCell], [x],[y], [b_sort] ;i=BinFind(memCell, x,y, b_sort);

		cmp eax,0

		je @f

			shl eax,2

			add eax,[memCell]

			mov eax,[eax] ;if(i) fnd=memCell[i];

			jmp .fun_e

	@@:

	cmp eax,0

	jne @f ;if(!fnd){ // ���� �祩�� �� ������ ��ॢ��

		push ebx ecx edx edi esi

		;ebx -> i

		;ecx -> firstC

		;edx -> &memCell[i]

		;edi -> cell[memCell[i]]

		mov ecx,[memCell]

		mov ebx,[b_sort]

		lea edx,[ebx*4]

		add edx,ecx

		mov ecx,[ecx]

		.cycle_b: ;for(i=b_sort+1;i<=fristC;i++)

			inc ebx

			cmp ebx,ecx

			jg .cycle_e

			add edx,4

			get_cell_offset edi,[edx]

			mov esi,[x]

			cmp dword[edi],esi ;+0 = .x

			jne .if_e

			mov esi,[y]

			cmp dword[edi+Cell.y],esi

			jne .if_e

				;if(cell[memCell[i]].x==x && cell[memCell[i]].y==y){

				mov eax,[edx] ;fnd=memCell[i];

				jmp .cycle_e ;break;

			.if_e:

			jmp .cycle_b

		.cycle_e:

		pop esi edi edx ecx ebx

	@@:

	.fun_e:

	ret

endp

;output:

; eax - index

align 4

proc pole_bin_find, mas:dword, fx:dword, fy:dword, k:dword

	push ebx ecx edx edi

	xor eax,eax

	mov ebx,1 ;ebx - ���ᨬ���� ���冷� ��� ��ॢ�

	@@:

	cmp dword[k],ebx

	jle @f ;while(k>por)

		shl ebx,1 ;por<<=1;

		jmp @b

	@@:

	cmp dword[k],ebx

	jge @f ;if(k

		shr ebx,1 ;por>>=1;

	@@:

	mov ecx,ebx ;i=por;

	;ecx -> i

	;edi -> mas[i]

	.cycle_b: ;do{

		shr ebx,1 ;por>>=1;

		lea edi,[ecx*4]

		add edi,[mas]

		;if(compare_cells_mb(mas[i],fx,fy)){

		stdcall pole_compare_cells_mb_coords, dword[edi],[fx],[fy]

		cmp dl,0

		je .if_u0_e

			@@: ;while(i+por>k)

			mov edx,ecx

			add edx,ebx

			cmp edx,[k] ;i+por>k

			jle @f

				shr ebx,1 ;por>>=1;

				jmp @b

			@@:

			add ecx,ebx ;i+=por;

			jmp .if_e

		.if_u0_e:

		;else if(compare_cells_bm(mas[i],fx,fy))i-=por;

		stdcall pole_compare_cells_bm_coords, dword[edi],[fx],[fy]

		cmp dl,0

		je .if_u1_e

			sub ecx,ebx

			jmp .if_e

		.if_u1_e:

		;else { m=i; por=0; }

			mov eax,ecx

			xor ebx,ebx

		.if_e:

	cmp ebx,0

	jne .cycle_b ;}while(por);

	pop edi edx ecx ebx

	ret

endp

;description:

; �ᯮ����⥫쭠� �㭪�� ��� ���஢�� �祥�� �� ���न��⠬

;output:

; dl

align 4

proc pole_compare_cells_bm_coords, i0:dword, fx:dword, fy:dword

	push eax ebx ecx

	get_cell_offset eax,[i0]

	;eax -> cell[i0]

	mov ebx,[fx]

	cmp dword[eax],ebx

	jle @f

		mov dl,1

		jmp .fun_e

	@@:

	mov ecx,[fy]

	cmp dword[eax+Cell.y],ecx

	jle @f

	cmp dword[eax],ebx

	jne @f

		mov dl,1

		jmp .fun_e

	@@:

	xor dl,dl

	.fun_e:

	pop ecx ebx eax

	ret

endp

;description:

; �ᯮ����⥫쭠� �㭪�� ��� ���஢�� �祥�� �� ���न��⠬

;output:

; dl

align 4

proc pole_compare_cells_mb_coords, i0:dword, fx:dword, fy:dword

	push eax ebx ecx

	get_cell_offset eax,[i0]

	;eax -> cell[i0]

	mov ebx,[fx]

	cmp dword[eax],ebx

	jge @f

		mov dl,1

		jmp .fun_e

	@@:

	mov ecx,[fy]

	cmp dword[eax+Cell.y],ecx

	jge @f

	cmp dword[eax],ebx

	jne @f

		mov dl,1

		jmp .fun_e

	@@:

	xor dl,dl

	.fun_e:

	pop ecx ebx eax

	ret

endp

;output:

; dl

align 4

proc pole_compare_cells_bm, i0:dword, i1:dword

	push eax ebx ecx

	get_cell_offset eax,[i0] ;eax -> cell[i0]

	get_cell_offset ebx,[i1] ;ebx -> cell[i1]

	mov ecx,[ebx] ;+0 = .x

	cmp dword[eax],ecx

	jle @f ;x0>x1

		mov dl,1

		jmp .fun_e

	@@:

	jne @f ;x0==x1

	mov ecx,[ebx+Cell.y]

	cmp dword[eax+Cell.y],ecx

	jle @f ;y0>y1

		mov dl,1

		jmp .fun_e

	@@:

	xor dl,dl

	.fun_e:

	pop ecx ebx eax

	ret

endp

align 4

pole_paint:

	pushad

	;eax -> firstC

	;ebx -> i

	;ecx -> cell[memCell[i]]

	;edx -> color

	;edi -> coord_x

	;esi -> coord_y

	mov eax,[memCell]

	cmp dword[eax],0

	je .no_draw

	mov eax,[eax]

	mov ebx,1

;---

	@@: ;while(i

		cmp ebx,[b_sort]

		jge @f ;���室�� �� ��砫� ������� 横��

		lea ecx,[ebx*4]

		add ecx,[memCell]

		get_cell_offset ecx,[ecx]

		mov edx,[ecx] ;+0 = .x

		add edx,[Cor_x]

		cmp edx,0

		jge @f ;���室�� �� ��砫� ������� 横��

			inc ebx ;i++; // ��� �ய�᪠ �祥� �� ����� ᫥��

		jmp @b

	@@:

	cmp byte[zoom],2

	jge .zoom2

	@@: ;for(;i<=fristC;i++){

		lea ecx,[ebx*4]

		add ecx,[memCell]

		get_cell_offset ecx,[ecx]

;...

		mov edi,[Cor_x]

		add edi,[ecx] ;+0 = .x

		mov esi,[Cor_y]

		add esi,[ecx+Cell.y]

		bt word[ecx+Cell.liv],0

		jc .cell_1

			;�� ����� �祩��

			mov edx,[CellColors]

			mov edx,[edx]

			jmp .cell_0

		.cell_1:

			;����� �祩��

			mov edx,[tim]

			inc edx

			sub edx,[ecx+Cell.tc]

			cmp edx,COL_MEM

			jle .in_color

				mov edx,COL_MEM

			.in_color:

			shl edx,2

			add edx,[CellColors]

			mov edx,[edx]

		.cell_0:

		stdcall [buf2d_set_pixel], buf_0, edi, esi, edx

;...

		inc ebx

		cmp ebx,eax

		jle @b

	jmp .no_draw

	.zoom2:

	@@: ;for(;i<=fristC;i++){

		lea ecx,[ebx*4]

		add ecx,[memCell]

		get_cell_offset ecx,[ecx]

		xor edx,edx

		mov dl,byte[zoom] ;edx �ᯮ������ ��� ���ᥭ�� zoom � 4 ���⭮� �᫮

		mov edi,[ecx] ;+0 = .x

		add edi,[Cor_x]

		imul edi,edx

		mov esi,[ecx+Cell.y]

		add esi,[Cor_y]

		imul esi,edx

		bt word[ecx+Cell.liv],0

		jc .z2_cell_1

			;�� ����� �祩��

			mov edx,[CellColors]

			mov edx,[edx]

			jmp .z2_cell_0

		.z2_cell_1:

			;����� �祩��

			mov edx,[tim]

			inc edx

			sub edx,[ecx+Cell.tc]

			cmp edx,COL_MEM

			jle .z2_in_color

				mov edx,COL_MEM

			.z2_in_color:

			shl edx,2

			add edx,[CellColors]

			mov edx,[edx]

		.z2_cell_0:

		xor ecx,ecx

		mov cl,byte[zoom] ;ecx �ᯮ������ ��� ���ᥭ�� zoom � 4 ���⭮� �᫮

		;;;dec ecx

		stdcall [buf2d_filled_rect_by_size], buf_0, edi, esi, ecx, ecx, edx

		inc ebx

		cmp ebx,eax

		jle @b

	.no_draw:

	popad

	ret

align 4

pole_next_gen:

	pushad

	;eax -> firstC

	;ebx -> i

	;ecx -> &memCell[i]

	;edx -> cell[memCell[i]]

	mov eax,[memCell]

	mov ecx,eax

	mov eax,[eax]

	cmp eax,1

	jl .fun_e

	inc dword[tim]

	mov ebx,1

	@@: ;for(i=1;i<=firstC;i++)

		add ecx,4

		get_cell_offset edx,[ecx]

		bt word[edx+Cell.liv],0

		jae .if_0_e

			; ��࠭���� �祩�� (�ᥤ�� 2 ��� 3)

			cmp byte[edx+Cell.so],2

			je .if_2_e

			cmp byte[edx+Cell.so],3

			je .if_2_e

			jmp .change

		.if_0_e:

			; ᮧ����� �祩�� (�ᥤ�� 3)

			cmp byte[edx+Cell.so],3

			jne .if_1_e

			.change:

				or byte[edx+Cell.liv],2

				jmp .if_2_e

		.if_1_e:

			; 㤠����� ���⮩ �祩�� ��� �᢮�������� �����

			cmp byte[edx+Cell.so],0

			jne .if_2_e

			mov edi,[edx+Cell.tc]

			add edi,5 ; 5 - �६� ��࠭���� ���⮩ �祩��, �� �� 㤠�����

			cmp edi,[tim]

			jge .if_2_e

				lea edi,[eax*4]

				add edi,[memCell] ;edi -> &memCell[fristC]

				mov esi,[edi] ;swp=memCell[fristC];

				mov edx,[ecx] ;edx - 㦥 �� �ᯮ��㥬, ��⮬� ����� ������

				mov [edi],edx ;memCell[fristC]=memCell[i];

				mov [ecx],esi ;memCell[i]=swp;

				dec eax

				dec ebx

				sub ecx,4

		.if_2_e:

		inc ebx

		cmp ebx,eax

		jle @b

	mov ebx,[memCell]

	mov [ebx],eax ;firstC <- eax

	mov [b_sort],eax

	stdcall pole_fl_sort, [memCell],eax

	mov ecx,[memCell]

	mov ebx,1

	@@: ;for(i=1;i<=firstC;i++)

		add ecx,4

		get_cell_offset edx,[ecx]

		bt word[edx+Cell.liv],1

		jae .no_change

			xor byte[edx+Cell.liv],3

			mov edi,[tim]

			mov [edx+Cell.tc],edi

			bt word[edx+Cell.liv],0

			jc .new_cell

				push eax

				mov edi,[edx]

				dec edi

				mov esi,[edx+Cell.y]

				dec esi

				dec dword[osob]

				;����� ���祭�� edx �������

				stdcall pole_cell_find,edi,esi

				get_cell_offset edx,eax

				dec byte[edx+Cell.so]

				inc esi

				stdcall pole_cell_find,edi,esi

				get_cell_offset edx,eax

				dec byte[edx+Cell.so]

				inc esi

				stdcall pole_cell_find,edi,esi

				get_cell_offset edx,eax

				dec byte[edx+Cell.so]

				inc edi

				stdcall pole_cell_find,edi,esi

				get_cell_offset edx,eax

				dec byte[edx+Cell.so]

				sub esi,2

				stdcall pole_cell_find,edi,esi

				get_cell_offset edx,eax

				dec byte[edx+Cell.so]

				inc edi

				stdcall pole_cell_find,edi,esi

				get_cell_offset edx,eax

				dec byte[edx+Cell.so]

				inc esi

				stdcall pole_cell_find,edi,esi

				get_cell_offset edx,eax

				dec byte[edx+Cell.so]

				inc esi

				stdcall pole_cell_find,edi,esi

				get_cell_offset edx,eax

				dec byte[edx+Cell.so]

				pop eax

				jmp .no_change

			.new_cell: ; ������ ����� �祩��

				inc dword[osob]

				mov edi,[edx]

				dec edi

				mov esi,[edx+Cell.y]

				dec esi

				stdcall pole_cell_creat,edi,esi,0

				inc esi

				stdcall pole_cell_creat,edi,esi,0

				inc esi

				stdcall pole_cell_creat,edi,esi,0

				inc edi

				stdcall pole_cell_creat,edi,esi,0

				sub esi,2

				stdcall pole_cell_creat,edi,esi,0

				inc edi

				stdcall pole_cell_creat,edi,esi,0

				inc esi

				stdcall pole_cell_creat,edi,esi,0

				inc esi

				stdcall pole_cell_creat,edi,esi,0

		.no_change:

		inc ebx

		cmp ebx,eax

		jle @b

	.fun_e:

	popad

	ret

;����஢�� ����� a[1..n] ��⮤�� ������

align 4

proc pole_fl_sort, a:dword, n:dword

	pushad

	mov ecx,[a]

	;��ନ஢��� ��室��� ���筮 㯮�冷祭��� ��ॢ�

	mov eax,[n]

	shr eax,1

	@@: ;for(i=n>>1; i>=2; i--)

		stdcall pole_fl_surface, ecx,eax,[n] ;(a,i,n)

		dec eax

		cmp eax,2

		jge @b

	;�믮����� ��楤��� �ᯫ��� ������ ��� ������� �����ॢ�

	mov eax,[n]

	@@: ;for(i=n; i>=2; i--){

		stdcall pole_fl_surface, ecx,1,eax ;(a,1,i)

		;�������� �������� ���ᨬ���� ������� � ����� ᯨ᪠

		lea edi,[eax*4]

		add edi,ecx ;edi -> &a[i]

		mov esi,[edi] ;w=a[i];

		mov edx,[ecx+4]

		mov [edi],edx ;a[i]=a[1];

		mov [ecx+4],esi ;a[1]=w;

		dec eax

		cmp eax,2

		jge @b

	popad

	ret

endp

;��楤�� �ᯫ��� ������ �� ��ॢ� a[1..k]

align 4

proc pole_fl_surface, a:dword, i:dword, k:dword

locals

	copy dd ?

endl

	pushad

	;edx -> ...

	;edi -> m

	;esi -> j

	mov eax,[a]

	mov ebx,[i]

	mov ecx,[k]

	lea edx,[ebx*4]

	add edx,eax

	mov edx,[edx]

	mov [copy],edx ;copy=a[i];

	mov edi,ebx

	shl edi,1 ;m=i<<1;

	.cycle_b: ;while (m<=k) {

		cmp edi,ecx

		jg .cycle_e

		jne @f ;if (m==k) j=m;

			mov esi,edi

			jmp .else_e

		@@: ;else if (pole_compare_cells_bm(a[m],a[m+1])) j=m;

		lea edx,[edi*4]

		add edx,eax

		stdcall pole_compare_cells_bm, dword[edx],dword[edx+4]

		cmp dl,0

		je @f

			mov esi,edi

			jmp .else_e

		@@: ;else j=m+1;

			mov esi,edi

			inc esi

		.else_e:

		;if (pole_compare_cells_bm(a[j],copy)) {

		lea edx,[esi*4]

		add edx,eax

		stdcall pole_compare_cells_bm, dword[edx],[copy]

		cmp dl,0

		je .cycle_e ;} else break; //��室 �� 横��

		lea edx,[esi*4]

		add edx,eax

		push dword[edx] ;push a[j];

		lea edx,[ebx*4]

		add edx,eax

		pop dword[edx] ;a[i]=a[j];

		mov ebx,esi ;i=j;

		mov edi,ebx

		shl edi,1 ;m=i<<1;

		jmp .cycle_b

	.cycle_e:

	;���祭�� ������ ॣ���஢ 㦥 �� ����� �. �. ����� �㭪樨

	shl ebx,2

	add eax,ebx

	mov edx,[copy]

	mov [eax],edx ;a[i]=copy;

	popad

	ret

endp

;--------------------------------------

align 4

start:

	load_libraries l_libs_start,l_libs_end

	;�஢�ઠ �� ᪮�쪮 㤠筮 ���㧨���� ��� ����

	mov	ebp,lib2

	cmp	dword [ebp+ll_struc_size-4],0

	jz	@f

		mcall SF_TERMINATE_PROCESS ;exit not correct

	@@:

	mcall SF_STYLE_SETTINGS,SSF_GET_COLORS,sc,sizeof.system_colors

	mcall SF_SET_EVENTS_MASK,0x27

	stdcall [OpenDialog_Init],OpenDialog_data ;�����⮢�� �������

	stdcall [buf2d_create], buf_0 ;ᮧ����� ����

	stdcall mem.Alloc,MAX_CELL*sizeof.Cell

	mov [cell],eax

	stdcall mem.Alloc,MAX_CELL*4

	mov [memCell],eax

	stdcall mem.Alloc,(COL_MEM+1)*4

	mov [CellColors],eax

	include_image_file 'life3tb.png', image_data_toolbar

	;����ன�� 梥⮢ �祥�

	stdcall pole_init_colors, 0xffffd0,0xff0000,0x0000ff

	call pole_clear

	call pole_paint ;�ᮢ���� ���� � ���� (�� �� ��࠭�)

	mcall SF_SYSTEM_GET,SSF_TIME_COUNT

	mov [last_time],eax

align 4

red_win:

	call draw_window

align 4

still:

	mcall SF_SYSTEM_GET,SSF_TIME_COUNT

	mov ebx,[last_time]

	add ebx,10 ;����প�

	cmp ebx,eax

	jge @f

		mov ebx,eax

	@@:

	sub ebx,eax

	mcall SF_WAIT_EVENT_TIMEOUT

	cmp eax,0

	je timer_funct

	cmp al,1

	jz red_win

	cmp al,2

	jz key

	cmp al,3

	jz button

	cmp al,6

	jne @f

		mcall SF_THREAD_INFO,procinfo,-1

		cmp ax,word[procinfo.window_stack_position]

		jne @f ;���� �� ��⨢��

		call mouse

	@@:

	jmp still

align 4

mouse:

	push eax ebx ecx

	mcall SF_MOUSE_GET,SSF_BUTTON_EXT

	bt eax,8

	jnc @f

		;mouse l. but. press

		;call mouse_left_d

		;jmp .end_l

	@@:

	bt eax,16

	jnc .end_l

		;mouse l. but. up

		;call mouse_left_u

		;jmp .end_l

	.end_l:

	call buf_get_mouse_coord

	cmp eax,-1

	je .end0

		shl eax,1

		sub eax,[buf_0.w]

		sar eax,1

		;mov [mouse_prop_x],eax

		shl ebx,1

		sub ebx,[buf_0.h]

		sar ebx,1

		;mov [mouse_prop_y],ebx

		mcall SF_MOUSE_GET,SSF_SCROLL_DATA

		test ax,ax

		jz .end0

		test ax,0x8000

		jnz .decr

			;㢥��祭�� ����⠡�

			call but_zoom_p

			jmp .end0

		.decr:

			;㬥��襭�� ����⠡�

			call but_zoom_m

	.end0:

	pop ecx ebx eax

	ret

;output:

; eax - buffer coord X (�᫨ ����� �� ���஬ -1)

; ebx - buffer coord Y (�᫨ ����� �� ���஬ -1)

align 4

proc buf_get_mouse_coord

	mcall SF_MOUSE_GET,SSF_WINDOW_POSITION

	cmp ax,word[buf_0.t]

	jl .no_buf ;�� ������ � ���� ���� �� �� y

	mov ebx,eax

	shr ebx,16

	cmp bx,word[buf_0.l]

	jl .no_buf ;�� ������ � ���� ���� �� �� x

	and eax,0xffff ;��⠢�塞 ���न���� y

	sub ax,word[buf_0.t]

	cmp eax,[buf_0.h]

	jg .no_buf

	sub bx,word[buf_0.l]

	cmp ebx,[buf_0.w]

	jg .no_buf

	xchg eax,ebx

	jmp .end_f

	.no_buf:

		xor eax,eax

		not eax

		xor ebx,ebx

		not ebx

	.end_f:

	ret

endp

align 4

timer_funct:

	pushad

	mcall SF_SYSTEM_GET,SSF_TIME_COUNT

	mov [last_time],eax

	cmp byte[tim_ch],0

	je @f

		;call but_next_gen

		cld

		mov ecx,[poc_stop]

		cmp ecx,1

		jg .clear

			mov ecx,1 ;��ࠢ����� ecx �� ��砩 �ᥫ ������ 1

			jmp .cycle

		.clear: ;��⨬ ���� �᫨ ���� ����� �� ��᪮�쪮 ��������� �� 1 ⠪� ⠩���

			stdcall [buf2d_clear], buf_0, [buf_0.color]

		.cycle:

			call pole_next_gen

			loop .cycle

		call pole_paint

		stdcall [buf2d_draw], buf_0

		call draw_pok

	@@:

	popad

	jmp still

align 4

draw_window:

pushad

	mcall SF_REDRAW,SSF_BEGIN_DRAW

	mcall SF_CREATE_WINDOW,(50 shl 16)+485,(50 shl 16)+415,0x73000000,0,hed

	mcall SF_THREAD_INFO,procinfo,-1

	mov eax,[procinfo.box.height]

	cmp eax,120

	jge @f

		mov eax,120 ;min size

	@@:

	sub eax,63

	mov ebx,[procinfo.box.width]

	cmp ebx,270

	jge @f

		mov ebx,270

	@@:

	sub ebx,9

	cmp eax,[buf_0.h] ;ᬮ�ਬ ࠧ��� ����

	jne @f

	cmp ebx,[buf_0.w]

	jne @f

		jmp .end0

	@@:

		stdcall [buf2d_resize], buf_0, ebx,eax,1

		stdcall [buf2d_clear], buf_0, [buf_0.color]

		call pole_paint

	.end0:

	mov edx,[sc.work]

	mov ebx, 0 shl 16

	add ebx, [buf_0.w]

	mcall SF_DRAW_RECT,,<0,35>

	mcall SF_DEFINE_BUTTON,(6 shl 16)+TBTNSIZE,(6 shl 16)+TBTNSIZE,4+0x40000000, [sc.work_button]

	mov ebx,(36 shl 16)+TBTNSIZE

	mov edx,6+0x40000000

	int 0x40

	mov ebx,(61 shl 16)+TBTNSIZE

	mov edx,7+0x40000000

	int 0x40

	mov ebx,(86 shl 16)+TBTNSIZE

	mov edx,8+0x40000000

	int 0x40

	mov ebx,(116 shl 16)+TBTNSIZE

	mov edx,9+0x40000000

	int 0x40

	mov ebx,(141 shl 16)+TBTNSIZE

	mov edx,10+0x40000000

	int 0x40

	mov ebx,(171 shl 16)+TBTNSIZE

	mov edx,11+0x40000000

	int 0x40

	mov ebx,(196 shl 16)+TBTNSIZE

	mov edx,12+0x40000000

	int 0x40

	mov ebx,(221 shl 16)+TBTNSIZE

	mov edx,13+0x40000000

	int 0x40

	mov ebx,(246 shl 16)+TBTNSIZE

	mov edx,14+0x40000000

	int 0x40

	mcall SF_PUT_IMAGE,[image_data_toolbar],(ICONSIZE shl 16)+ICONSIZE,(5 shl 16)+5

	add ebx,IMAGE_TOOLBAR_ICON_SIZE

	mov edx,(35 shl 16)+5 ;run once

	int 0x40

	add ebx,IMAGE_TOOLBAR_ICON_SIZE

	mov edx,(60 shl 16)+5 ;run auto

	int 0x40

	add ebx,IMAGE_TOOLBAR_ICON_SIZE

	mov edx,(85 shl 16)+5 ;stop

	int 0x40

	add ebx,IMAGE_TOOLBAR_ICON_SIZE

	mov edx,(115 shl 16)+5 ;-

	int 0x40

	add ebx,IMAGE_TOOLBAR_ICON_SIZE

	mov edx,(140 shl 16)+5 ;+

	int 0x40

	add ebx,IMAGE_TOOLBAR_ICON_SIZE

	mov edx,(170 shl 16)+5 ;move up

	int 0x40

	add ebx,IMAGE_TOOLBAR_ICON_SIZE

	mov edx,(195 shl 16)+5 ;move doun

	int 0x40

	add ebx,IMAGE_TOOLBAR_ICON_SIZE

	mov edx,(220 shl 16)+5 ;move left

	int 0x40

	add ebx,IMAGE_TOOLBAR_ICON_SIZE

	mov edx,(245 shl 16)+5 ;move right

	int 0x40

	; add ebx,IMAGE_TOOLBAR_ICON_SIZE

	; mov edx,(270 shl 16)+5

	; int 0x40

	; add ebx,IMAGE_TOOLBAR_ICON_SIZE

	; mov edx,(295 shl 16)+5

	; int 0x40