Subversion Repositories Kolibri OS

;

; Kolibrios FTP Daemon

;

; hidnplayr@gmail.com

;

; GPLv2

;

DEBUG                   = 0             ; if set to one, program will run in a single thread

BUFFERSIZE              = 8192

; using multiple's of 4

STATE_CONNECTED         = 4*0

STATE_LOGIN             = 4*1

STATE_LOGIN_FAIL        = 4*2           ; When an invalid username was given

STATE_ACTIVE            = 4*3

TYPE_UNDEF              = 0

TYPE_ASCII              = 00000100b

TYPE_EBDIC              = 00001000b

; subtypes for ascii & ebdic (np = default)

TYPE_NP                 = 00000001b     ; non printable

TYPE_TELNET             = 00000010b

TYPE_ASA                = 00000011b

TYPE_IMAGE              = 01000000b     ; binary data

TYPE_LOCAL              = 10000000b     ; bits per byte must be specified

                                        ; lower 4 bits will hold this value

MODE_NOTREADY           = 0

MODE_ACTIVE             = 1

MODE_PASSIVE_WAIT       = 2

MODE_PASSIVE_OK         = 3

MODE_PASSIVE_FAILED     = 4

PERMISSION_EXEC         = 1b            ; LIST

PERMISSION_READ         = 10b

PERMISSION_WRITE        = 100b

PERMISSION_DELETE       = 1000b

PERMISSION_CD           = 10000b        ; Change Directory

ABORT                   = 1 shl 31

format binary as ""

use32

        db      'MENUET01'      ; signature

        dd      1               ; header version

        dd      start           ; entry point

        dd      i_end           ; initialized size

        dd      mem+0x1000      ; required memory

        dd      mem+0x1000      ; stack pointer

        dd      params          ; parameters

        dd      path            ; path

include '../macros.inc'

purge mov,add,sub

include '../proc32.inc'

include '../dll.inc'

include '../struct.inc'

include '../libio.inc'

include '../network.inc'

macro sendFTP str {

local string, length

        xor     edi, edi

        mcall   send, [ebp + thread_data.socketnum], string, length

iglobal

string db str, 13, 10

length = $ - string

\}

}

include 'commands.inc'

start:

        mcall   68, 11                  ; init heap

        mcall   40, 1 shl 7             ; we only want network events

; load libraries

        stdcall dll.Load, @IMPORT

        test    eax, eax

        jnz     exit

; find path to main settings file (ftpd.ini)

        mov     edi, path               ; Calculate the length of zero-terminated string

        xor     al, al

        mov     ecx, 1024

        repne   scasb

        dec     edi

        mov     esi, str_ini            ; append it with '.ini', 0

        movsd

        movsb

; now create the second path (users.ini)

        std

        mov     al, '/'

        repne   scasb

        lea     ecx, [edi - path + 2]

        cld

        mov     esi, path

        mov     edi, path2

        rep     movsb

        mov     esi, str_users

        movsd

        movsd

        movsw

; initialize console

        invoke  con_start, 1

        invoke  con_init, -1, -1, -1, -1, title

        invoke  ini.get_str, path, str_ftpd, str_ip, ini_buf, 16, 0

        mov     esi, ini_buf

        mov     cl, '.'

        call    ip_to_dword

        mov     [serverip], ebx

        invoke  ini.get_int, path, str_ftpd, str_port, 21

        mov     [sockaddr1.port], ax

        invoke  con_printf, str1, eax

        add     esp, 8

        mcall   socket, AF_INET4, SOCK_STREAM, 0

        cmp     eax, -1

        je      sock_err

        mov     [socketnum], eax

        invoke  con_write_asciiz, str2

;        mcall   setsockopt, [socketnum], SOL_SOCKET, SO_REUSEADDR, &yes,

;        cmp     eax, -1

;        je      opt_err

        mcall   bind, [socketnum], sockaddr1, sockaddr1.length

        cmp     eax, -1

        je      bind_err

        invoke  con_write_asciiz, str2

        invoke  ini.get_int, path, str_ftpd, str_conn, 1        ; Backlog (max connections)

        mov     edx, eax

        invoke  con_write_asciiz, str2

        mcall   listen, [socketnum]

        cmp     eax, -1

        je      listen_err

        invoke  con_write_asciiz, str2b

        invoke  ini.get_int, path, str_pasv, str_start, 2000

        mov     [pasv_start], ax

        invoke  ini.get_int, path, str_pasv, str_end, 5000

        mov     [pasv_end], ax

        mov     [alive], 1

mainloop:

        mcall   23, 100                         ; Wait here for incoming connections on the base socket (socketnum)

                                                ; One second timeout, we will use this to check if console is still working

        test    eax, eax                        ; network event?

        jz      .checkconsole

if DEBUG

        jmp     threadstart

else

        mcall   51, 1, threadstart, 0           ; Start a new thread for every incoming connection

                                                ; NOTE: upon initialisation of the thread, stack will not be available!

end if

        jmp     mainloop

  .checkconsole:

        invoke  con_get_flags                   ; Is console still running?

        test    eax, 0x0200

        jz      mainloop

        mcall   close, [socketnum]              ; kill the listening socket

        mov     [alive], 0

        mcall   -1                              ; and exit

        diff16  "threadstart", 0, $

threadstart:

;;;        mcall   68, 11                          ; init heap

        mcall   68, 12, sizeof.thread_data      ; allocate the thread data struct

        test    eax, eax

        je      exit

        lea     esp, [eax + thread_data.stack]  ; init stack

        mov     ebp, eax